| blob | 528ce8320e69abcd4e5f60b3d97b949589645f18 |
1 dnl
2 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
3 dnl
4 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
5 dnl end of configure. This lets tested variables be reassigned, and the
6 dnl conditional will depend on the final state of the variable. For a simple
7 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
8 dnl
9 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
10 AC_DEFUN([GLIBCXX_CONDITIONAL], [dnl
11 m4_divert_text([glibcxx_diversion],dnl
12 AM_CONDITIONAL([$1],[$2])
13 )dnl
14 ])dnl
15 AC_DEFUN([GLIBCXX_EVALUATE_CONDITIONALS], [m4_undivert([glibcxx_diversion])])dnl
18 dnl
19 dnl Check to see what architecture and operating system we are compiling
20 dnl for. Also, if architecture- or OS-specific flags are required for
21 dnl compilation, pick them up here.
22 dnl
23 AC_DEFUN([GLIBCXX_CHECK_HOST], [
24 . $glibcxx_srcdir/configure.host
25 AC_MSG_NOTICE([CPU config directory is $cpu_include_dir])
26 AC_MSG_NOTICE([OS config directory is $os_include_dir])
27 ])
29 dnl
30 dnl Initialize the rest of the library configury. At this point we have
31 dnl variables like $host.
32 dnl
33 dnl Sets:
34 dnl SUBDIRS
35 dnl Substs:
36 dnl glibcxx_builddir (absolute path)
37 dnl glibcxx_srcdir (absolute path)
38 dnl toplevel_builddir (absolute path)
39 dnl toplevel_srcdir (absolute path)
40 dnl with_cross_host
41 dnl with_newlib
42 dnl with_target_subdir
43 dnl plus
44 dnl - the variables in GLIBCXX_CHECK_HOST / configure.host
45 dnl - default settings for all AM_CONFITIONAL test variables
46 dnl - lots of tools, like CC and CXX
47 dnl
48 AC_DEFUN([GLIBCXX_CONFIGURE], [
49 # Keep these sync'd with the list in Makefile.am. The first provides an
50 # expandable list at autoconf time; the second provides an expandable list
51 # (i.e., shell variable) at configure time.
52 m4_define([glibcxx_SUBDIRS],[include libsupc++ python src src/c++98 src/c++11 doc po testsuite])
53 SUBDIRS='glibcxx_SUBDIRS'
55 # These need to be absolute paths, yet at the same time need to
56 # canonicalize only relative paths, because then amd will not unmount
57 # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
58 glibcxx_builddir=`${PWDCMD-pwd}`
59 case $srcdir in
60 [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
61 *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
62 esac
63 toplevel_builddir=${glibcxx_builddir}/..
64 toplevel_srcdir=${glibcxx_srcdir}/..
65 AC_SUBST(glibcxx_builddir)
66 AC_SUBST(glibcxx_srcdir)
67 AC_SUBST(toplevel_builddir)
68 AC_SUBST(toplevel_srcdir)
70 # We use these options to decide which functions to include. They are
71 # set from the top level.
72 AC_ARG_WITH([target-subdir],
73 AC_HELP_STRING([--with-target-subdir=SUBDIR],
74 [configuring in a subdirectory]))
76 AC_ARG_WITH([cross-host],
77 AC_HELP_STRING([--with-cross-host=HOST],
78 [configuring with a cross compiler]))
80 AC_ARG_WITH([newlib],
81 AC_HELP_STRING([--with-newlib],
82 [assume newlib as a system C library]))
84 # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
85 # available). Uncomment the next line to force a particular method.
86 AC_PROG_LN_S
87 #LN_S='cp -p'
89 AC_CHECK_TOOL(AS, as)
90 AC_CHECK_TOOL(AR, ar)
91 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
93 AM_MAINTAINER_MODE
95 # Set up safe default values for all subsequent AM_CONDITIONAL tests
96 # which are themselves conditionally expanded.
97 ## (Right now, this only matters for enable_wchar_t, but nothing prevents
98 ## other macros from doing the same. This should be automated.) -pme
100 # Check for C library flavor since GNU/Linux platforms use different
101 # configuration directories depending on the C library in use.
102 AC_EGREP_CPP([_using_uclibc], [
103 #include <stdio.h>
104 #if __UCLIBC__
105 _using_uclibc
106 #endif
107 ], uclibc=yes, uclibc=no)
109 AC_EGREP_CPP([_using_bionic], [
110 #include <stdio.h>
111 #if __BIONIC__
112 _using_bionic
113 #endif
114 ], bionic=yes, bionic=no)
116 # Find platform-specific directories containing configuration info.
117 # Also possibly modify flags used elsewhere, as needed by the platform.
118 GLIBCXX_CHECK_HOST
119 ])
122 dnl
123 dnl Tests for newer compiler features, or features that are present in newer
124 dnl compiler versions but not older compiler versions still in use, should
125 dnl be placed here.
126 dnl
127 dnl Defines:
128 dnl WERROR='-Werror' if requested and possible; g++'s that lack the
129 dnl new inlining code or the new system_header pragma will die on -Werror.
130 dnl Leave it out by default and use maint-mode to use it.
131 dnl SECTION_FLAGS='-ffunction-sections -fdata-sections' if
132 dnl compiler supports it and the user has not requested debug mode.
133 dnl
134 AC_DEFUN([GLIBCXX_CHECK_COMPILER_FEATURES], [
135 # All these tests are for C++; save the language and the compiler flags.
136 # The CXXFLAGS thing is suspicious, but based on similar bits previously
137 # found in GLIBCXX_CONFIGURE.
138 AC_LANG_SAVE
139 AC_LANG_CPLUSPLUS
140 ac_test_CXXFLAGS="${CXXFLAGS+set}"
141 ac_save_CXXFLAGS="$CXXFLAGS"
143 # Check for maintainer-mode bits.
144 if test x"$USE_MAINTAINER_MODE" = xno; then
145 WERROR=''
146 else
147 WERROR='-Werror'
148 fi
150 # Check for -ffunction-sections -fdata-sections
151 AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
152 CXXFLAGS='-g -Werror -ffunction-sections -fdata-sections'
153 AC_TRY_COMPILE([int foo; void bar() { };],, [ac_fdsections=yes], [ac_fdsections=no])
154 if test "$ac_test_CXXFLAGS" = set; then
155 CXXFLAGS="$ac_save_CXXFLAGS"
156 else
157 # this is the suspicious part
158 CXXFLAGS=''
159 fi
160 if test x"$ac_fdsections" = x"yes"; then
161 SECTION_FLAGS='-ffunction-sections -fdata-sections'
162 fi
163 AC_MSG_RESULT($ac_fdsections)
165 AC_LANG_RESTORE
166 AC_SUBST(WERROR)
167 AC_SUBST(SECTION_FLAGS)
168 ])
171 dnl
172 dnl Check if the assembler used supports disabling generation of hardware
173 dnl capabilities. This is only supported by Sun as at the moment.
174 dnl
175 dnl Defines:
176 dnl HWCAP_FLAGS='-Wa,-nH' if possible.
177 dnl
178 AC_DEFUN([GLIBCXX_CHECK_ASSEMBLER_HWCAP], [
179 test -z "$HWCAP_FLAGS" && HWCAP_FLAGS=''
181 # Restrict the test to Solaris, other assemblers (e.g. AIX as) have -nH
182 # with a different meaning.
183 case ${target_os} in
184 solaris2*)
185 ac_save_CFLAGS="$CFLAGS"
186 CFLAGS="$CFLAGS -Wa,-nH"
188 AC_MSG_CHECKING([for as that supports -Wa,-nH])
189 AC_TRY_COMPILE([], [return 0;], [ac_hwcap_flags=yes],[ac_hwcap_flags=no])
190 if test "$ac_hwcap_flags" = "yes"; then
191 HWCAP_FLAGS="-Wa,-nH $HWCAP_FLAGS"
192 fi
193 AC_MSG_RESULT($ac_hwcap_flags)
195 CFLAGS="$ac_save_CFLAGS"
196 ;;
197 esac
199 AC_SUBST(HWCAP_FLAGS)
200 ])
203 dnl
204 dnl If GNU ld is in use, check to see if tricky linker opts can be used. If
205 dnl the native linker is in use, all variables will be defined to something
206 dnl safe (like an empty string).
207 dnl
208 dnl Defines:
209 dnl SECTION_LDFLAGS='-Wl,--gc-sections' if possible
210 dnl OPT_LDFLAGS='-Wl,-O1' and '-z,relro' if possible
211 dnl LD (as a side effect of testing)
212 dnl Sets:
213 dnl with_gnu_ld
214 dnl glibcxx_ld_is_gold (set to "no" or "yes")
215 dnl glibcxx_gnu_ld_version (possibly)
216 dnl
217 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
218 dnl set glibcxx_gnu_ld_version to 12345. Zeros cause problems.
219 dnl
220 AC_DEFUN([GLIBCXX_CHECK_LINKER_FEATURES], [
221 # If we're not using GNU ld, then there's no point in even trying these
222 # tests. Check for that first. We should have already tested for gld
223 # by now (in libtool), but require it now just to be safe...
224 test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
225 test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
226 AC_REQUIRE([AC_PROG_LD])
227 AC_REQUIRE([AC_PROG_AWK])
229 # The name set by libtool depends on the version of libtool. Shame on us
230 # for depending on an impl detail, but c'est la vie. Older versions used
231 # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
232 # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
233 # makes sense). We'll test with_gnu_ld everywhere else, so if that isn't
234 # set (hence we're using an older libtool), then set it.
235 if test x${with_gnu_ld+set} != xset; then
236 if test x${ac_cv_prog_gnu_ld+set} != xset; then
237 # We got through "ac_require(ac_prog_ld)" and still not set? Huh?
238 with_gnu_ld=no
239 else
240 with_gnu_ld=$ac_cv_prog_gnu_ld
241 fi
242 fi
244 # Start by getting the version number. I think the libtool test already
245 # does some of this, but throws away the result.
246 glibcxx_ld_is_gold=no
247 if test x"$with_gnu_ld" = x"yes"; then
248 AC_MSG_CHECKING([for ld version])
249 changequote(,)
250 if $LD --version 2>/dev/null | grep 'GNU gold' >/dev/null 2>&1; then
251 glibcxx_ld_is_gold=yes
252 fi
253 ldver=`$LD --version 2>/dev/null |
254 sed -e 's/GNU gold /GNU ld /;s/GNU ld version /GNU ld /;s/GNU ld ([^)]*) /GNU ld /;s/GNU ld \([0-9.][0-9.]*\).*/\1/; q'`
255 changequote([,])
256 glibcxx_gnu_ld_version=`echo $ldver | \
257 $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
258 AC_MSG_RESULT($glibcxx_gnu_ld_version)
259 fi
261 # Set --gc-sections.
262 glibcxx_have_gc_sections=no
263 if test "$glibcxx_ld_is_gold" = "yes"; then
264 if $LD --help 2>/dev/null | grep gc-sections >/dev/null 2>&1; then
265 glibcxx_have_gc_sections=yes
266 fi
267 else
268 glibcxx_gcsections_min_ld=21602
269 if test x"$with_gnu_ld" = x"yes" &&
270 test $glibcxx_gnu_ld_version -gt $glibcxx_gcsections_min_ld ; then
271 glibcxx_have_gc_sections=yes
272 fi
273 fi
274 if test "$glibcxx_have_gc_sections" = "yes"; then
275 # Sufficiently young GNU ld it is! Joy and bunny rabbits!
276 # NB: This flag only works reliably after 2.16.1. Configure tests
277 # for this are difficult, so hard wire a value that should work.
279 ac_test_CFLAGS="${CFLAGS+set}"
280 ac_save_CFLAGS="$CFLAGS"
281 CFLAGS='-Wl,--gc-sections'
283 # Check for -Wl,--gc-sections
284 AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
285 AC_TRY_LINK([ int one(void) { return 1; }
286 int two(void) { return 2; }
287 ], [ two(); ] , [ac_gcsections=yes], [ac_gcsections=no])
288 if test "$ac_gcsections" = "yes"; then
289 rm -f conftest.c
290 touch conftest.c
291 if $CC -c conftest.c; then
292 if $LD --gc-sections -o conftest conftest.o 2>&1 | \
293 grep "Warning: gc-sections option ignored" > /dev/null; then
294 ac_gcsections=no
295 fi
296 fi
297 rm -f conftest.c conftest.o conftest
298 fi
299 if test "$ac_gcsections" = "yes"; then
300 SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
301 fi
302 AC_MSG_RESULT($ac_gcsections)
304 if test "$ac_test_CFLAGS" = set; then
305 CFLAGS="$ac_save_CFLAGS"
306 else
307 # this is the suspicious part
308 CFLAGS=''
309 fi
310 fi
312 # Set -z,relro.
313 # Note this is only for shared objects.
314 ac_ld_relro=no
315 if test x"$with_gnu_ld" = x"yes"; then
316 AC_MSG_CHECKING([for ld that supports -Wl,-z,relro])
317 cxx_z_relo=`$LD -v --help 2>/dev/null | grep "z relro"`
318 if test -n "$cxx_z_relo"; then
319 OPT_LDFLAGS="-Wl,-z,relro"
320 ac_ld_relro=yes
321 fi
322 AC_MSG_RESULT($ac_ld_relro)
323 fi
325 # Set linker optimization flags.
326 if test x"$with_gnu_ld" = x"yes"; then
327 OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
328 fi
330 AC_SUBST(SECTION_LDFLAGS)
331 AC_SUBST(OPT_LDFLAGS)
332 ])
335 dnl
336 dnl Check for headers for, and arguments to, the setrlimit() function.
337 dnl Used only in testsuite_hooks.h. Called from GLIBCXX_CONFIGURE_TESTSUITE.
338 dnl
339 dnl Defines:
340 dnl _GLIBCXX_RES_LIMITS if we can set artificial resource limits
341 dnl various HAVE_LIMIT_* for individual limit names
342 dnl
343 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT_ancilliary], [
344 AC_MSG_CHECKING([for RLIMIT_$1])
345 AC_TRY_COMPILE(
346 [#include <unistd.h>
347 #include <sys/time.h>
348 #include <sys/resource.h>
349 ],
350 [ int f = RLIMIT_$1 ; ],
351 [glibcxx_mresult=1], [glibcxx_mresult=0])
352 AC_DEFINE_UNQUOTED(HAVE_LIMIT_$1, $glibcxx_mresult,
353 [Only used in build directory testsuite_hooks.h.])
354 if test $glibcxx_mresult = 1 ; then res=yes ; else res=no ; fi
355 AC_MSG_RESULT($res)
356 ])
358 AC_DEFUN([GLIBCXX_CHECK_SETRLIMIT], [
359 setrlimit_have_headers=yes
360 AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
361 [],
362 [setrlimit_have_headers=no])
363 # If don't have the headers, then we can't run the tests now, and we
364 # won't be seeing any of these during testsuite compilation.
365 if test $setrlimit_have_headers = yes; then
366 # Can't do these in a loop, else the resulting syntax is wrong.
367 GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
368 GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
369 GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
370 GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
371 GLIBCXX_CHECK_SETRLIMIT_ancilliary(FSIZE)
373 # Check for rlimit, setrlimit.
374 AC_CACHE_VAL(glibcxx_cv_setrlimit, [
375 AC_TRY_COMPILE(
376 [#include <unistd.h>
377 #include <sys/time.h>
378 #include <sys/resource.h>
379 ],
380 [struct rlimit r;
381 setrlimit(0, &r);],
382 [glibcxx_cv_setrlimit=yes], [glibcxx_cv_setrlimit=no])
383 ])
384 fi
386 AC_MSG_CHECKING([for testsuite resource limits support])
387 if test $setrlimit_have_headers = yes && test $glibcxx_cv_setrlimit = yes; then
388 ac_res_limits=yes
389 AC_DEFINE(_GLIBCXX_RES_LIMITS, 1,
390 [Define if using setrlimit to set resource limits during
391 "make check"])
392 else
393 ac_res_limits=no
394 fi
395 AC_MSG_RESULT($ac_res_limits)
396 ])
399 dnl
400 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
401 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
402 dnl
403 AC_DEFUN([GLIBCXX_CHECK_S_ISREG_OR_S_IFREG], [
405 AC_LANG_SAVE
406 AC_LANG_CPLUSPLUS
407 ac_save_CXXFLAGS="$CXXFLAGS"
408 CXXFLAGS="$CXXFLAGS -fno-exceptions"
410 AC_MSG_CHECKING([for S_ISREG or S_IFREG])
411 AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
412 GCC_TRY_COMPILE_OR_LINK(
413 [#include <sys/stat.h>],
414 [struct stat buffer;
415 fstat(0, &buffer);
416 S_ISREG(buffer.st_mode);],
417 [glibcxx_cv_S_ISREG=yes],
418 [glibcxx_cv_S_ISREG=no])
419 ])
420 AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
421 GCC_TRY_COMPILE_OR_LINK(
422 [#include <sys/stat.h>],
423 [struct stat buffer;
424 fstat(0, &buffer);
425 S_IFREG & buffer.st_mode;],
426 [glibcxx_cv_S_IFREG=yes],
427 [glibcxx_cv_S_IFREG=no])
428 ])
429 res=no
430 if test $glibcxx_cv_S_ISREG = yes; then
431 AC_DEFINE(HAVE_S_ISREG, 1,
432 [Define if S_IFREG is available in <sys/stat.h>.])
433 res=S_ISREG
434 elif test $glibcxx_cv_S_IFREG = yes; then
435 AC_DEFINE(HAVE_S_IFREG, 1,
436 [Define if S_IFREG is available in <sys/stat.h>.])
437 res=S_IFREG
438 fi
439 AC_MSG_RESULT($res)
441 CXXFLAGS="$ac_save_CXXFLAGS"
442 AC_LANG_RESTORE
443 ])
446 dnl
447 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
448 dnl
449 AC_DEFUN([GLIBCXX_CHECK_POLL], [
451 AC_LANG_SAVE
452 AC_LANG_CPLUSPLUS
453 ac_save_CXXFLAGS="$CXXFLAGS"
454 CXXFLAGS="$CXXFLAGS -fno-exceptions"
456 AC_MSG_CHECKING([for poll])
457 AC_CACHE_VAL(glibcxx_cv_POLL, [
458 GCC_TRY_COMPILE_OR_LINK(
459 [#include <poll.h>],
460 [struct pollfd pfd[1];
461 pfd[0].events = POLLIN;
462 poll(pfd, 1, 0);],
463 [glibcxx_cv_POLL=yes],
464 [glibcxx_cv_POLL=no])
465 ])
466 if test $glibcxx_cv_POLL = yes; then
467 AC_DEFINE(HAVE_POLL, 1, [Define if poll is available in <poll.h>.])
468 fi
469 AC_MSG_RESULT($glibcxx_cv_POLL)
471 CXXFLAGS="$ac_save_CXXFLAGS"
472 AC_LANG_RESTORE
473 ])
476 dnl
477 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
478 dnl
479 AC_DEFUN([GLIBCXX_CHECK_WRITEV], [
481 AC_LANG_SAVE
482 AC_LANG_CPLUSPLUS
483 ac_save_CXXFLAGS="$CXXFLAGS"
484 CXXFLAGS="$CXXFLAGS -fno-exceptions"
486 AC_MSG_CHECKING([for writev])
487 AC_CACHE_VAL(glibcxx_cv_WRITEV, [
488 GCC_TRY_COMPILE_OR_LINK(
489 [#include <sys/uio.h>],
490 [struct iovec iov[2];
491 writev(0, iov, 0);],
492 [glibcxx_cv_WRITEV=yes],
493 [glibcxx_cv_WRITEV=no])
494 ])
495 if test $glibcxx_cv_WRITEV = yes; then
496 AC_DEFINE(HAVE_WRITEV, 1, [Define if writev is available in <sys/uio.h>.])
497 fi
498 AC_MSG_RESULT($glibcxx_cv_WRITEV)
500 CXXFLAGS="$ac_save_CXXFLAGS"
501 AC_LANG_RESTORE
502 ])
505 dnl
506 dnl Check whether int64_t is available in <stdint.h>, and define HAVE_INT64_T.
507 dnl Also check whether int64_t is actually a typedef to long or long long.
508 dnl
509 AC_DEFUN([GLIBCXX_CHECK_INT64_T], [
511 AC_LANG_SAVE
512 AC_LANG_CPLUSPLUS
514 AC_MSG_CHECKING([for int64_t])
515 AC_CACHE_VAL(glibcxx_cv_INT64_T, [
516 AC_TRY_COMPILE(
517 [#include <stdint.h>],
518 [int64_t var;],
519 [glibcxx_cv_INT64_T=yes],
520 [glibcxx_cv_INT64_T=no])
521 ])
523 if test $glibcxx_cv_INT64_T = yes; then
524 AC_DEFINE(HAVE_INT64_T, 1, [Define if int64_t is available in <stdint.h>.])
525 AC_MSG_RESULT($glibcxx_cv_INT64_T)
527 AC_MSG_CHECKING([for int64_t as long])
528 AC_CACHE_VAL(glibcxx_cv_int64_t_long, [
529 AC_TRY_COMPILE(
530 [#include <stdint.h>
531 template<typename, typename> struct same { enum { value = -1 }; };
532 template<typename Tp> struct same<Tp, Tp> { enum { value = 1 }; };
533 int array[same<int64_t, long>::value];], [],
534 [glibcxx_cv_int64_t_long=yes], [glibcxx_cv_int64_t_long=no])
535 ])
537 if test $glibcxx_cv_int64_t_long = yes; then
538 AC_DEFINE(HAVE_INT64_T_LONG, 1, [Define if int64_t is a long.])
539 AC_MSG_RESULT($glibcxx_cv_int64_t_long)
540 fi
542 AC_MSG_CHECKING([for int64_t as long long])
543 AC_CACHE_VAL(glibcxx_cv_int64_t_long_long, [
544 AC_TRY_COMPILE(
545 [#include <stdint.h>
546 template<typename, typename> struct same { enum { value = -1 }; };
547 template<typename Tp> struct same<Tp, Tp> { enum { value = 1 }; };
548 int array[same<int64_t, long long>::value];], [],
549 [glibcxx_cv_int64_t_long_long=yes], [glibcxx_cv_int64_t_long_long=no])
550 ])
552 if test $glibcxx_cv_int64_t_long_long = yes; then
553 AC_DEFINE(HAVE_INT64_T_LONG_LONG, 1, [Define if int64_t is a long long.])
554 AC_MSG_RESULT($glibcxx_cv_int64_t_long_long)
555 fi
556 fi
558 AC_LANG_RESTORE
559 ])
562 dnl
563 dnl Check whether LFS support is available.
564 dnl
565 AC_DEFUN([GLIBCXX_CHECK_LFS], [
566 AC_LANG_SAVE
567 AC_LANG_CPLUSPLUS
568 ac_save_CXXFLAGS="$CXXFLAGS"
569 CXXFLAGS="$CXXFLAGS -fno-exceptions"
570 AC_MSG_CHECKING([for LFS support])
571 AC_CACHE_VAL(glibcxx_cv_LFS, [
572 GCC_TRY_COMPILE_OR_LINK(
573 [#include <unistd.h>
574 #include <stdio.h>
575 #include <sys/stat.h>
576 ],
577 [FILE* fp;
578 fopen64("t", "w");
579 fseeko64(fp, 0, SEEK_CUR);
580 ftello64(fp);
581 lseek64(1, 0, SEEK_CUR);
582 struct stat64 buf;
583 fstat64(1, &buf);],
584 [glibcxx_cv_LFS=yes],
585 [glibcxx_cv_LFS=no])
586 ])
587 if test $glibcxx_cv_LFS = yes; then
588 AC_DEFINE(_GLIBCXX_USE_LFS, 1, [Define if LFS support is available.])
589 fi
590 AC_MSG_RESULT($glibcxx_cv_LFS)
591 CXXFLAGS="$ac_save_CXXFLAGS"
592 AC_LANG_RESTORE
593 ])
596 dnl
597 dnl Check for whether a fully dynamic basic_string implementation should
598 dnl be turned on, that does not put empty objects in per-process static
599 dnl memory (mostly useful together with shared memory allocators, see PR
600 dnl libstdc++/16612 for details).
601 dnl
602 dnl --enable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING to 1
603 dnl --disable-fully-dynamic-string defines _GLIBCXX_FULLY_DYNAMIC_STRING to 0
604 dnl otherwise undefined
605 dnl + Usage: GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING[(DEFAULT)]
606 dnl Where DEFAULT is either `yes' or `no'.
607 dnl
608 AC_DEFUN([GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING], [
609 GLIBCXX_ENABLE(fully-dynamic-string,$1,,[do not put empty strings in per-process static memory])
610 if test $enable_fully_dynamic_string = yes; then
611 enable_fully_dynamic_string_def=1
612 else
613 enable_fully_dynamic_string_def=0
614 fi
615 AC_DEFINE_UNQUOTED([_GLIBCXX_FULLY_DYNAMIC_STRING], [${enable_fully_dynamic_string_def}],
616 [Define to 1 if a fully dynamic basic_string is wanted, 0 to disable, undefined for platform defaults])
617 ])
620 dnl
621 dnl Does any necessary configuration of the testsuite directory. Generates
622 dnl the testsuite_hooks.h header.
623 dnl
624 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
625 dnl
626 dnl Sets:
627 dnl enable_abi_check
628 dnl GLIBCXX_TEST_WCHAR_T
629 dnl GLIBCXX_TEST_THREAD
630 dnl Substs:
631 dnl baseline_dir
632 dnl baseline_subdir_switch
633 dnl
634 AC_DEFUN([GLIBCXX_CONFIGURE_TESTSUITE], [
635 if $GLIBCXX_IS_NATIVE ; then
636 # Do checks for resource limit functions.
637 GLIBCXX_CHECK_SETRLIMIT
639 # Look for setenv, so that extended locale tests can be performed.
640 GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
641 fi
643 if $GLIBCXX_IS_NATIVE && test $is_hosted = yes &&
644 test $enable_symvers != no; then
645 case "$host" in
646 *-*-cygwin*)
647 enable_abi_check=no ;;
648 *)
649 enable_abi_check=yes ;;
650 esac
651 else
652 # Only build this as native, since automake does not understand
653 # CXX_FOR_BUILD.
654 enable_abi_check=no
655 fi
657 # Export file names for ABI checking.
658 baseline_dir="$glibcxx_srcdir/config/abi/post/${abi_baseline_pair}"
659 AC_SUBST(baseline_dir)
660 baseline_subdir_switch="$abi_baseline_subdir_switch"
661 AC_SUBST(baseline_subdir_switch)
662 ])
665 dnl
666 dnl Does any necessary configuration for docbook in the docs directory.
667 dnl
668 dnl XSLTPROC must be set before this
669 dnl
670 dnl Sets:
671 dnl glibcxx_stylesheets
672 dnl Substs:
673 dnl XSL_STYLE_DIR
674 dnl
675 AC_DEFUN([GLIBCXX_CONFIGURE_DOCBOOK], [
677 AC_MSG_CHECKING([for docbook stylesheets for documentation creation])
678 glibcxx_stylesheets=no
679 if test x${XSLTPROC} = xyes && echo '<title/>' | xsltproc --noout --nonet --xinclude http://docbook.sourceforge.net/release/xsl-ns/current/xhtml-1_1/docbook.xsl - 2>/dev/null; then
680 glibcxx_stylesheets=yes
681 fi
682 AC_MSG_RESULT($glibcxx_stylesheets)
684 AC_MSG_CHECKING([for local stylesheet directory])
685 glibcxx_local_stylesheets=no
686 if test x"$glibcxx_stylesheets" = x"yes"; then
687 if test -d /usr/share/sgml/docbook/xsl-ns-stylesheets; then
688 glibcxx_local_stylesheets=yes
689 XSL_STYLE_DIR=/usr/share/sgml/docbook/xsl-ns-stylesheets
690 fi
691 if test -d /usr/share/xml/docbook/stylesheet/docbook-xsl-ns; then
692 glibcxx_local_stylesheets=yes
693 XSL_STYLE_DIR=/usr/share/xml/docbook/stylesheet/docbook-xsl-ns
694 fi
695 if test -d /usr/share/xml/docbook/stylesheet/nwalsh5/current; then
696 glibcxx_local_stylesheets=yes
697 XSL_STYLE_DIR=/usr/share/xml/docbook/stylesheet/nwalsh5/current
698 fi
699 fi
700 AC_MSG_RESULT($glibcxx_local_stylesheets)
702 if test x"$glibcxx_local_stylesheets" = x"yes"; then
703 AC_SUBST(XSL_STYLE_DIR)
704 AC_MSG_NOTICE($XSL_STYLE_DIR)
705 else
706 glibcxx_stylesheets=no
707 fi
709 # Check for epub3 dependencies.
710 AC_MSG_CHECKING([for epub3 stylesheets for documentation creation])
711 glibcxx_epub_stylesheets=no
712 if test x"$glibcxx_local_stylesheets" = x"yes"; then
713 if test -f "$XSL_STYLE_DIR/epub3/chunk.xsl"; then
714 glibcxx_epub_stylesheets=yes
715 fi
716 fi
717 AC_MSG_RESULT($glibcxx_epub_stylesheets)
718 AM_CONDITIONAL(BUILD_EPUB, test x"$glibcxx_epub_stylesheets" = x"yes")
720 ])
723 dnl
724 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
725 dnl
726 dnl Substs:
727 dnl GLIBCXX_INCLUDES
728 dnl TOPLEVEL_INCLUDES
729 dnl
730 AC_DEFUN([GLIBCXX_EXPORT_INCLUDES], [
731 # Used for every C++ compile we perform.
732 GLIBCXX_INCLUDES="\
733 -I$glibcxx_builddir/include/$host_alias \
734 -I$glibcxx_builddir/include \
735 -I$glibcxx_srcdir/libsupc++"
737 # For Canadian crosses, pick this up too.
738 if test $CANADIAN = yes; then
739 GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
740 fi
742 # Stuff in the actual top level. Currently only used by libsupc++ to
743 # get unwind* headers from the libgcc dir.
744 #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/libgcc -I$(toplevel_srcdir)/include'
745 TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/libgcc'
747 # Now, export this to all the little Makefiles....
748 AC_SUBST(GLIBCXX_INCLUDES)
749 AC_SUBST(TOPLEVEL_INCLUDES)
750 ])
753 dnl
754 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
755 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
756 dnl
757 dnl Substs:
758 dnl OPTIMIZE_CXXFLAGS
759 dnl WARN_FLAGS
760 dnl
761 AC_DEFUN([GLIBCXX_EXPORT_FLAGS], [
762 # Optimization flags that are probably a good idea for thrill-seekers. Just
763 # uncomment the lines below and make, everything else is ready to go...
764 # Alternatively OPTIMIZE_CXXFLAGS can be set in configure.host.
765 # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
766 AC_SUBST(OPTIMIZE_CXXFLAGS)
768 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual -Wabi'
769 AC_SUBST(WARN_FLAGS)
770 ])
773 dnl
774 dnl All installation directory information is determined here.
775 dnl
776 dnl Substs:
777 dnl gxx_install_dir
778 dnl glibcxx_prefixdir
779 dnl glibcxx_toolexecdir
780 dnl glibcxx_toolexeclibdir
781 dnl
782 dnl Assumes cross_compiling bits already done, and with_cross_host in
783 dnl particular.
784 dnl
785 dnl This logic must match gcc/configure.ac's setting of gcc_gxx_include_dir.
786 dnl config/gxx-include-dir.m4 must be kept consistant with this as well.
787 AC_DEFUN([GLIBCXX_EXPORT_INSTALL_INFO], [
788 glibcxx_toolexecdir=no
789 glibcxx_toolexeclibdir=no
790 glibcxx_prefixdir=$prefix
792 AC_MSG_CHECKING([for gxx-include-dir])
793 AC_ARG_WITH([gxx-include-dir],
794 AC_HELP_STRING([--with-gxx-include-dir=DIR],
795 [installation directory for include files]),
796 [case "$withval" in
797 yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
798 no) gxx_include_dir=no ;;
799 *) gxx_include_dir=$withval ;;
800 esac],
801 [gxx_include_dir=no])
802 AC_MSG_RESULT($gxx_include_dir)
804 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
805 AC_ARG_ENABLE([version-specific-runtime-libs],
806 AC_HELP_STRING([--enable-version-specific-runtime-libs],
807 [Specify that runtime libraries should be installed in a compiler-specific directory]),
808 [case "$enableval" in
809 yes) version_specific_libs=yes ;;
810 no) version_specific_libs=no ;;
811 *) AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
812 esac],
813 [version_specific_libs=no])
814 AC_MSG_RESULT($version_specific_libs)
816 # Default case for install directory for include files.
817 if test $version_specific_libs = no && test $gxx_include_dir = no; then
818 gxx_include_dir='include/c++/${gcc_version}'
819 if test -n "$with_cross_host" &&
820 test x"$with_cross_host" != x"no"; then
821 gxx_include_dir='${prefix}/${target_alias}/'"$gxx_include_dir"
822 else
823 gxx_include_dir='${prefix}/'"$gxx_include_dir"
824 fi
825 fi
827 # Version-specific runtime libs processing.
828 if test $version_specific_libs = yes; then
829 # Need the gcc compiler version to know where to install libraries
830 # and header files if --enable-version-specific-runtime-libs option
831 # is selected. FIXME: these variables are misnamed, there are
832 # no executables installed in _toolexecdir or _toolexeclibdir.
833 if test x"$gxx_include_dir" = x"no"; then
834 gxx_include_dir='${libdir}/gcc/${host_alias}/${gcc_version}/include/c++'
835 fi
836 glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
837 glibcxx_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
838 fi
840 # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
841 # Install a library built with a cross compiler in tooldir, not libdir.
842 if test x"$glibcxx_toolexecdir" = x"no"; then
843 if test -n "$with_cross_host" &&
844 test x"$with_cross_host" != x"no"; then
845 glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
846 glibcxx_toolexeclibdir='${toolexecdir}/lib'
847 else
848 glibcxx_toolexecdir='${libdir}/gcc/${host_alias}'
849 glibcxx_toolexeclibdir='${libdir}'
850 fi
851 multi_os_directory=`$CXX -print-multi-os-directory`
852 case $multi_os_directory in
853 .) ;; # Avoid trailing /.
854 *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
855 esac
856 fi
858 AC_MSG_CHECKING([for install location])
859 AC_MSG_RESULT($gxx_include_dir)
861 AC_SUBST(glibcxx_prefixdir)
862 AC_SUBST(gxx_include_dir)
863 AC_SUBST(glibcxx_toolexecdir)
864 AC_SUBST(glibcxx_toolexeclibdir)
865 ])
868 dnl
869 dnl GLIBCXX_ENABLE
870 dnl (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
871 dnl (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
872 dnl (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
873 dnl
874 dnl See docs/html/17_intro/configury.html#enable for documentation.
875 dnl
876 m4_define([GLIBCXX_ENABLE],[dnl
877 m4_define([_g_switch],[--enable-$1])dnl
878 m4_define([_g_help],[AC_HELP_STRING([_g_switch$3],[$4 @<:@default=$2@:>@])])dnl
879 AC_ARG_ENABLE([$1],m4_dquote(_g_help),
880 m4_bmatch([$5],
881 [^permit ],
882 [[
883 case "$enableval" in
884 m4_bpatsubst([$5],[permit ])) ;;
885 *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
886 dnl Idea for future: generate a URL pointing to
887 dnl "onlinedocs/configopts.html#whatever"
888 esac
889 ]],
890 [^$],
891 [[
892 case "$enableval" in
893 yes|no) ;;
894 *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
895 esac
896 ]],
897 [[$5]]),
898 [enable_]m4_bpatsubst([$1],-,_)[=][$2])
899 m4_undefine([_g_switch])dnl
900 m4_undefine([_g_help])dnl
901 ])
904 dnl
905 dnl Check for ISO/IEC 9899:1999 "C99" support.
906 dnl
907 dnl --enable-c99 defines _GLIBCXX_USE_C99
908 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
909 dnl + Usage: GLIBCXX_ENABLE_C99[(DEFAULT)]
910 dnl Where DEFAULT is either `yes' or `no'.
911 dnl + If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
912 dnl
913 AC_DEFUN([GLIBCXX_ENABLE_C99], [
914 GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
916 if test x"$enable_c99" = x"yes"; then
918 AC_LANG_SAVE
919 AC_LANG_CPLUSPLUS
921 # Use -std=c++98 because the default (-std=gnu++98) leaves __STRICT_ANSI__
922 # undefined and fake C99 facilities - like pre-standard snprintf - may be
923 # spuriously enabled.
924 # Long term, -std=c++0x could be even better, could manage to explicitely
925 # request C99 facilities to the underlying C headers.
926 ac_save_CXXFLAGS="$CXXFLAGS"
927 CXXFLAGS="$CXXFLAGS -std=c++98"
928 ac_save_LIBS="$LIBS"
929 ac_save_gcc_no_link="$gcc_no_link"
931 if test x$gcc_no_link != xyes; then
932 # Use -fno-exceptions to that the C driver can link these tests without
933 # hitting undefined references to personality routines.
934 CXXFLAGS="$CXXFLAGS -fno-exceptions"
935 AC_CHECK_LIB(m, sin, [
936 LIBS="$LIBS -lm"
937 ], [
938 # Use the default compile-only tests in GCC_TRY_COMPILE_OR_LINK
939 gcc_no_link=yes
940 ])
941 fi
943 # Check for the existence of <math.h> functions used if C99 is enabled.
944 AC_MSG_CHECKING([for ISO C99 support in <math.h>])
945 AC_CACHE_VAL(glibcxx_cv_c99_math, [
946 GCC_TRY_COMPILE_OR_LINK(
947 [#include <math.h>
948 volatile double d1, d2;
949 volatile int i;],
950 [i = fpclassify(d1);
951 i = isfinite(d1);
952 i = isinf(d1);
953 i = isnan(d1);
954 i = isnormal(d1);
955 i = signbit(d1);
956 i = isgreater(d1, d2);
957 i = isgreaterequal(d1, d2);
958 i = isless(d1, d2);
959 i = islessequal(d1, d2);
960 i = islessgreater(d1, d2);
961 i = islessgreater(d1, d2);
962 i = isunordered(d1, d2);
963 ],[glibcxx_cv_c99_math=yes], [glibcxx_cv_c99_math=no])
964 ])
965 AC_MSG_RESULT($glibcxx_cv_c99_math)
966 if test x"$glibcxx_cv_c99_math" = x"yes"; then
967 AC_DEFINE(_GLIBCXX_USE_C99_MATH, 1,
968 [Define if C99 functions or macros in <math.h> should be imported
969 in <cmath> in namespace std.])
970 fi
972 # Check for the existence of <complex.h> complex math functions.
973 # This is necessary even though libstdc++ uses the builtin versions
974 # of these functions, because if the builtin cannot be used, a reference
975 # to the library function is emitted.
976 AC_CHECK_HEADERS(tgmath.h, ac_has_tgmath_h=yes, ac_has_tgmath_h=no)
977 AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
978 glibcxx_cv_c99_complex=no;
979 if test x"$ac_has_complex_h" = x"yes"; then
980 AC_MSG_CHECKING([for ISO C99 support in <complex.h>])
981 GCC_TRY_COMPILE_OR_LINK(
982 [#include <complex.h>
983 typedef __complex__ float float_type;
984 typedef __complex__ double double_type;
985 typedef __complex__ long double ld_type;
986 volatile float_type tmpf;
987 volatile double_type tmpd;
988 volatile ld_type tmpld;
989 volatile float f;
990 volatile double d;
991 volatile long double ld;],
992 [f = cabsf(tmpf);
993 f = cargf(tmpf);
994 tmpf = ccosf(tmpf);
995 tmpf = ccoshf(tmpf);
996 tmpf = cexpf(tmpf);
997 tmpf = clogf(tmpf);
998 tmpf = csinf(tmpf);
999 tmpf = csinhf(tmpf);
1000 tmpf = csqrtf(tmpf);
1001 tmpf = ctanf(tmpf);
1002 tmpf = ctanhf(tmpf);
1003 tmpf = cpowf(tmpf, tmpf);
1004 tmpf = cprojf(tmpf);
1005 d = cabs(tmpd);
1006 d = carg(tmpd);
1007 tmpd = ccos(tmpd);
1008 tmpd = ccosh(tmpd);
1009 tmpd = cexp(tmpd);
1010 tmpd = clog(tmpd);
1011 tmpd = csin(tmpd);
1012 tmpd = csinh(tmpd);
1013 tmpd = csqrt(tmpd);
1014 tmpd = ctan(tmpd);
1015 tmpd = ctanh(tmpd);
1016 tmpd = cpow(tmpd, tmpd);
1017 tmpd = cproj(tmpd);
1018 ld = cabsl(tmpld);
1019 ld = cargl(tmpld);
1020 tmpld = ccosl(tmpld);
1021 tmpld = ccoshl(tmpld);
1022 tmpld = cexpl(tmpld);
1023 tmpld = clogl(tmpld);
1024 tmpld = csinl(tmpld);
1025 tmpld = csinhl(tmpld);
1026 tmpld = csqrtl(tmpld);
1027 tmpld = ctanl(tmpld);
1028 tmpld = ctanhl(tmpld);
1029 tmpld = cpowl(tmpld, tmpld);
1030 tmpld = cprojl(tmpld);
1031 ],[glibcxx_cv_c99_complex=yes], [glibcxx_cv_c99_complex=no])
1032 fi
1033 AC_MSG_RESULT($glibcxx_cv_c99_complex)
1034 if test x"$glibcxx_cv_c99_complex" = x"yes"; then
1035 AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX, 1,
1036 [Define if C99 functions in <complex.h> should be used in
1037 <complex>. Using compiler builtins for these functions requires
1038 corresponding C99 library functions to be present.])
1039 fi
1041 # Check for the existence in <stdio.h> of vscanf, et. al.
1042 AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
1043 AC_CACHE_VAL(glibcxx_cv_c99_stdio, [
1044 GCC_TRY_COMPILE_OR_LINK(
1045 [#include <stdio.h>
1046 #include <stdarg.h>
1047 void foo(char* fmt, ...)
1048 {
1049 va_list args; va_start(args, fmt);
1050 vfscanf(stderr, "%i", args);
1051 vscanf("%i", args);
1052 vsnprintf(fmt, 0, "%i", args);
1053 vsscanf(fmt, "%i", args);
1054 }],
1055 [snprintf("12", 0, "%i");],
1056 [glibcxx_cv_c99_stdio=yes], [glibcxx_cv_c99_stdio=no])
1057 ])
1058 AC_MSG_RESULT($glibcxx_cv_c99_stdio)
1060 # Check for the existence in <stdlib.h> of lldiv_t, et. al.
1061 AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
1062 AC_CACHE_VAL(glibcxx_cv_c99_stdlib, [
1063 GCC_TRY_COMPILE_OR_LINK(
1064 [#include <stdlib.h>
1065 volatile float f;
1066 volatile long double ld;
1067 volatile unsigned long long ll;
1068 lldiv_t mydivt;],
1069 [char* tmp;
1070 f = strtof("gnu", &tmp);
1071 ld = strtold("gnu", &tmp);
1072 ll = strtoll("gnu", &tmp, 10);
1073 ll = strtoull("gnu", &tmp, 10);
1074 ll = llabs(10);
1075 mydivt = lldiv(10,1);
1076 ll = mydivt.quot;
1077 ll = mydivt.rem;
1078 ll = atoll("10");
1079 _Exit(0);
1080 ],[glibcxx_cv_c99_stdlib=yes], [glibcxx_cv_c99_stdlib=no])
1081 ])
1082 AC_MSG_RESULT($glibcxx_cv_c99_stdlib)
1084 # Check for the existence in <wchar.h> of wcstold, etc.
1085 glibcxx_cv_c99_wchar=no;
1086 if test x"$ac_has_wchar_h" = xyes &&
1087 test x"$ac_has_wctype_h" = xyes; then
1088 AC_MSG_CHECKING([for ISO C99 support in <wchar.h>])
1089 AC_TRY_COMPILE([#include <wchar.h>
1090 namespace test
1091 {
1092 using ::wcstold;
1093 using ::wcstoll;
1094 using ::wcstoull;
1095 }
1096 ],[],[glibcxx_cv_c99_wchar=yes], [glibcxx_cv_c99_wchar=no])
1098 # Checks for wide character functions that may not be present.
1099 # Injection of these is wrapped with guard macros.
1100 # NB: only put functions here, instead of immediately above, if
1101 # absolutely necessary.
1102 AC_TRY_COMPILE([#include <wchar.h>
1103 namespace test { using ::vfwscanf; } ], [],
1104 [AC_DEFINE(HAVE_VFWSCANF,1,
1105 [Defined if vfwscanf exists.])],[])
1107 AC_TRY_COMPILE([#include <wchar.h>
1108 namespace test { using ::vswscanf; } ], [],
1109 [AC_DEFINE(HAVE_VSWSCANF,1,
1110 [Defined if vswscanf exists.])],[])
1112 AC_TRY_COMPILE([#include <wchar.h>
1113 namespace test { using ::vwscanf; } ], [],
1114 [AC_DEFINE(HAVE_VWSCANF,1,[Defined if vwscanf exists.])],[])
1116 AC_TRY_COMPILE([#include <wchar.h>
1117 namespace test { using ::wcstof; } ], [],
1118 [AC_DEFINE(HAVE_WCSTOF,1,[Defined if wcstof exists.])],[])
1120 AC_TRY_COMPILE([#include <wctype.h>],
1121 [ wint_t t; int i = iswblank(t);],
1122 [AC_DEFINE(HAVE_ISWBLANK,1,
1123 [Defined if iswblank exists.])],[])
1125 AC_MSG_RESULT($glibcxx_cv_c99_wchar)
1126 fi
1128 # Option parsed, now set things appropriately.
1129 if test x"$glibcxx_cv_c99_math" = x"no" ||
1130 test x"$glibcxx_cv_c99_complex" = x"no" ||
1131 test x"$glibcxx_cv_c99_stdio" = x"no" ||
1132 test x"$glibcxx_cv_c99_stdlib" = x"no" ||
1133 test x"$glibcxx_cv_c99_wchar" = x"no"; then
1134 enable_c99=no;
1135 else
1136 AC_DEFINE(_GLIBCXX_USE_C99, 1,
1137 [Define if C99 functions or macros from <wchar.h>, <math.h>,
1138 <complex.h>, <stdio.h>, and <stdlib.h> can be used or exposed.])
1139 fi
1141 gcc_no_link="$ac_save_gcc_no_link"
1142 LIBS="$ac_save_LIBS"
1143 CXXFLAGS="$ac_save_CXXFLAGS"
1144 AC_LANG_RESTORE
1145 fi
1147 AC_MSG_CHECKING([for fully enabled ISO C99 support])
1148 AC_MSG_RESULT($enable_c99)
1149 ])
1152 dnl
1153 dnl Check for clock_gettime, nanosleep and sched_yield, used in the
1154 dnl implementation of 20.11.7 [time.clock], and 30.3.2 [thread.thread.this]
1155 dnl in the C++11 standard.
1156 dnl
1157 dnl --enable-libstdcxx-time
1158 dnl --enable-libstdcxx-time=yes
1159 dnl checks for the availability of monotonic and realtime clocks,
1160 dnl nanosleep and sched_yield in libc and libposix4 and, if needed,
1161 dnl links in the latter.
1162 dnl --enable-libstdcxx-time=rt
1163 dnl also searches (and, if needed, links) librt. Note that this is
1164 dnl not always desirable because, in glibc, for example, in turn it
1165 dnl triggers the linking of libpthread too, which activates locking,
1166 dnl a large overhead for single-thread programs.
1167 dnl --enable-libstdcxx-time=no
1168 dnl --disable-libstdcxx-time
1169 dnl disables the checks completely
1170 dnl
1171 dnl N.B. Darwin provides nanosleep but doesn't support the whole POSIX
1172 dnl Timers option, so doesn't define _POSIX_TIMERS. Because the test
1173 dnl below fails Darwin unconditionally defines _GLIBCXX_USE_NANOSLEEP in
1174 dnl os_defines.h and also defines _GLIBCXX_USE_SCHED_YIELD.
1175 dnl
1176 AC_DEFUN([GLIBCXX_ENABLE_LIBSTDCXX_TIME], [
1178 AC_MSG_CHECKING([for clock_gettime, nanosleep and sched_yield])
1179 GLIBCXX_ENABLE(libstdcxx-time,$1,[[[=KIND]]],
1180 [use KIND for check type],
1181 [permit yes|no|rt])
1183 AC_LANG_SAVE
1184 AC_LANG_CPLUSPLUS
1185 ac_save_CXXFLAGS="$CXXFLAGS"
1186 CXXFLAGS="$CXXFLAGS -fno-exceptions"
1187 ac_save_LIBS="$LIBS"
1189 ac_has_clock_monotonic=no
1190 ac_has_clock_realtime=no
1191 AC_MSG_RESULT($enable_libstdcxx_time)
1193 if test x"$enable_libstdcxx_time" != x"no"; then
1195 if test x"$enable_libstdcxx_time" = x"rt"; then
1196 AC_SEARCH_LIBS(clock_gettime, [rt posix4])
1197 AC_SEARCH_LIBS(nanosleep, [rt posix4])
1198 else
1199 AC_SEARCH_LIBS(clock_gettime, [posix4])
1200 AC_SEARCH_LIBS(nanosleep, [posix4])
1201 fi
1203 case "$ac_cv_search_clock_gettime" in
1204 -l*) GLIBCXX_LIBS=$ac_cv_search_clock_gettime
1205 ;;
1206 esac
1207 case "$ac_cv_search_nanosleep" in
1208 -l*) GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_nanosleep"
1209 ;;
1210 esac
1212 AC_SEARCH_LIBS(sched_yield, [rt posix4])
1214 case "$ac_cv_search_sched_yield" in
1215 -lposix4*)
1216 GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_sched_yield"
1217 AC_DEFINE(_GLIBCXX_USE_SCHED_YIELD, 1,
1218 [ Defined if sched_yield is available. ])
1219 ;;
1220 -lrt*)
1221 if test x"$enable_libstdcxx_time" = x"rt"; then
1222 GLIBCXX_LIBS="$GLIBCXX_LIBS $ac_cv_search_sched_yield"
1223 AC_DEFINE(_GLIBCXX_USE_SCHED_YIELD, 1,
1224 [ Defined if sched_yield is available. ])
1225 fi
1226 ;;
1227 *)
1228 AC_DEFINE(_GLIBCXX_USE_SCHED_YIELD, 1,
1229 [ Defined if sched_yield is available. ])
1230 ;;
1231 esac
1233 AC_CHECK_HEADERS(unistd.h, ac_has_unistd_h=yes, ac_has_unistd_h=no)
1235 if test x"$ac_has_unistd_h" = x"yes"; then
1236 AC_MSG_CHECKING([for monotonic clock])
1237 AC_TRY_LINK(
1238 [#include <unistd.h>
1239 #include <time.h>
1240 ],
1241 [#if _POSIX_TIMERS > 0 && defined(_POSIX_MONOTONIC_CLOCK)
1242 timespec tp;
1243 #endif
1244 clock_gettime(CLOCK_MONOTONIC, &tp);
1245 ], [ac_has_clock_monotonic=yes], [ac_has_clock_monotonic=no])
1247 AC_MSG_RESULT($ac_has_clock_monotonic)
1249 AC_MSG_CHECKING([for realtime clock])
1250 AC_TRY_LINK(
1251 [#include <unistd.h>
1252 #include <time.h>
1253 ],
1254 [#if _POSIX_TIMERS > 0
1255 timespec tp;
1256 #endif
1257 clock_gettime(CLOCK_REALTIME, &tp);
1258 ], [ac_has_clock_realtime=yes], [ac_has_clock_realtime=no])
1260 AC_MSG_RESULT($ac_has_clock_realtime)
1262 AC_MSG_CHECKING([for nanosleep])
1263 AC_TRY_LINK(
1264 [#include <unistd.h>
1265 #include <time.h>
1266 ],
1267 [#if _POSIX_TIMERS > 0
1268 timespec tp;
1269 #endif
1270 nanosleep(&tp, 0);
1271 ], [ac_has_nanosleep=yes], [ac_has_nanosleep=no])
1273 AC_MSG_RESULT($ac_has_nanosleep)
1274 fi
1275 fi
1277 if test x"$ac_has_clock_monotonic" = x"yes"; then
1278 AC_DEFINE(_GLIBCXX_USE_CLOCK_MONOTONIC, 1,
1279 [ Defined if clock_gettime has monotonic clock support. ])
1280 fi
1282 if test x"$ac_has_clock_realtime" = x"yes"; then
1283 AC_DEFINE(_GLIBCXX_USE_CLOCK_REALTIME, 1,
1284 [ Defined if clock_gettime has realtime clock support. ])
1285 fi
1287 if test x"$ac_has_nanosleep" = x"yes"; then
1288 AC_DEFINE(_GLIBCXX_USE_NANOSLEEP, 1,
1289 [ Defined if nanosleep is available. ])
1290 else
1291 AC_MSG_CHECKING([for sleep])
1292 AC_TRY_COMPILE([#include <unistd.h>],
1293 [sleep(1)],
1294 [ac_has_sleep=yes],[ac_has_sleep=no])
1295 if test x"$ac_has_sleep" = x"yes"; then
1296 AC_DEFINE(HAVE_SLEEP,1, [Defined if sleep exists.])
1297 fi
1298 AC_MSG_RESULT($ac_has_sleep)
1299 AC_MSG_CHECKING([for usleep])
1300 AC_TRY_COMPILE([#include <unistd.h>],
1301 [sleep(1);
1302 usleep(100);],
1303 [ac_has_usleep=yes],[ac_has_usleep=no])
1304 if test x"$ac_has_usleep" = x"yes"; then
1305 AC_DEFINE(HAVE_USLEEP,1, [Defined if usleep exists.])
1306 fi
1307 AC_MSG_RESULT($ac_has_usleep)
1308 fi
1310 if test x"$ac_has_nanosleep$ac_has_sleep" = x"nono"; then
1311 AC_MSG_CHECKING([for Sleep])
1312 AC_TRY_COMPILE([#include <windows.h>],
1313 [Sleep(1)],
1314 [ac_has_win32_sleep=yes],[ac_has_win32_sleep=no])
1315 if test x"$ac_has_win32_sleep" = x"yes"; then
1316 AC_DEFINE(HAVE_WIN32_SLEEP,1, [Defined if Sleep exists.])
1317 fi
1318 AC_MSG_RESULT($ac_has_win32_sleep)
1319 fi
1321 AC_SUBST(GLIBCXX_LIBS)
1323 CXXFLAGS="$ac_save_CXXFLAGS"
1324 LIBS="$ac_save_LIBS"
1325 AC_LANG_RESTORE
1326 ])
1328 dnl
1329 dnl Check for gettimeofday, used in the implementation of 20.11.7
1330 dnl [time.clock] in the C++11 standard.
1331 dnl
1332 AC_DEFUN([GLIBCXX_CHECK_GETTIMEOFDAY], [
1334 AC_MSG_CHECKING([for gettimeofday])
1336 AC_LANG_SAVE
1337 AC_LANG_CPLUSPLUS
1338 ac_save_CXXFLAGS="$CXXFLAGS"
1339 CXXFLAGS="$CXXFLAGS -fno-exceptions"
1341 ac_has_gettimeofday=no;
1342 AC_CHECK_HEADERS(sys/time.h, ac_has_sys_time_h=yes, ac_has_sys_time_h=no)
1343 if test x"$ac_has_sys_time_h" = x"yes"; then
1344 AC_MSG_CHECKING([for gettimeofday])
1345 GCC_TRY_COMPILE_OR_LINK([#include <sys/time.h>],
1346 [timeval tv; gettimeofday(&tv, 0);],
1347 [ac_has_gettimeofday=yes], [ac_has_gettimeofday=no])
1349 AC_MSG_RESULT($ac_has_gettimeofday)
1350 fi
1352 if test x"$ac_has_gettimeofday" = x"yes"; then
1353 AC_DEFINE(_GLIBCXX_USE_GETTIMEOFDAY, 1,
1354 [ Defined if gettimeofday is available. ])
1355 fi
1357 CXXFLAGS="$ac_save_CXXFLAGS"
1358 AC_LANG_RESTORE
1359 ])
1361 dnl
1362 dnl Check for ISO/IEC 9899:1999 "C99" support to ISO/IEC DTR 19768 "TR1"
1363 dnl facilities in Chapter 8, "C compatibility".
1364 dnl
1365 AC_DEFUN([GLIBCXX_CHECK_C99_TR1], [
1367 AC_LANG_SAVE
1368 AC_LANG_CPLUSPLUS
1370 # Use -std=c++98 because the default (-std=gnu++98) leaves __STRICT_ANSI__
1371 # undefined and fake C99 facilities may be spuriously enabled.
1372 ac_save_CXXFLAGS="$CXXFLAGS"
1373 CXXFLAGS="$CXXFLAGS -std=c++98"
1375 # Check for the existence of <complex.h> complex math functions used
1376 # by tr1/complex.
1377 AC_CHECK_HEADERS(complex.h, ac_has_complex_h=yes, ac_has_complex_h=no)
1378 ac_c99_complex_tr1=no;
1379 if test x"$ac_has_complex_h" = x"yes"; then
1380 AC_MSG_CHECKING([for ISO C99 support to TR1 in <complex.h>])
1381 AC_TRY_COMPILE([#include <complex.h>],
1382 [typedef __complex__ float float_type; float_type tmpf;
1383 cacosf(tmpf);
1384 casinf(tmpf);
1385 catanf(tmpf);
1386 cacoshf(tmpf);
1387 casinhf(tmpf);
1388 catanhf(tmpf);
1389 typedef __complex__ double double_type; double_type tmpd;
1390 cacos(tmpd);
1391 casin(tmpd);
1392 catan(tmpd);
1393 cacosh(tmpd);
1394 casinh(tmpd);
1395 catanh(tmpd);
1396 typedef __complex__ long double ld_type; ld_type tmpld;
1397 cacosl(tmpld);
1398 casinl(tmpld);
1399 catanl(tmpld);
1400 cacoshl(tmpld);
1401 casinhl(tmpld);
1402 catanhl(tmpld);
1403 ],[ac_c99_complex_tr1=yes], [ac_c99_complex_tr1=no])
1404 fi
1405 AC_MSG_RESULT($ac_c99_complex_tr1)
1406 if test x"$ac_c99_complex_tr1" = x"yes"; then
1407 AC_DEFINE(_GLIBCXX_USE_C99_COMPLEX_TR1, 1,
1408 [Define if C99 functions in <complex.h> should be used in
1409 <tr1/complex>. Using compiler builtins for these functions
1410 requires corresponding C99 library functions to be present.])
1411 fi
1413 # Check for the existence of <ctype.h> functions.
1414 AC_MSG_CHECKING([for ISO C99 support to TR1 in <ctype.h>])
1415 AC_CACHE_VAL(glibcxx_cv_c99_ctype_tr1, [
1416 AC_TRY_COMPILE([#include <ctype.h>],
1417 [int ch;
1418 int ret;
1419 ret = isblank(ch);
1420 ],[glibcxx_cv_c99_ctype_tr1=yes],
1421 [glibcxx_cv_c99_ctype_tr1=no])
1422 ])
1423 AC_MSG_RESULT($glibcxx_cv_c99_ctype_tr1)
1424 if test x"$glibcxx_cv_c99_ctype_tr1" = x"yes"; then
1425 AC_DEFINE(_GLIBCXX_USE_C99_CTYPE_TR1, 1,
1426 [Define if C99 functions in <ctype.h> should be imported in
1427 <tr1/cctype> in namespace std::tr1.])
1428 fi
1430 # Check for the existence of <fenv.h> functions.
1431 AC_CHECK_HEADERS(fenv.h, ac_has_fenv_h=yes, ac_has_fenv_h=no)
1432 ac_c99_fenv_tr1=no;
1433 if test x"$ac_has_fenv_h" = x"yes"; then
1434 AC_MSG_CHECKING([for ISO C99 support to TR1 in <fenv.h>])
1435 AC_TRY_COMPILE([#include <fenv.h>],
1436 [int except, mode;
1437 fexcept_t* pflag;
1438 fenv_t* penv;
1439 int ret;
1440 ret = feclearexcept(except);
1441 ret = fegetexceptflag(pflag, except);
1442 ret = feraiseexcept(except);
1443 ret = fesetexceptflag(pflag, except);
1444 ret = fetestexcept(except);
1445 ret = fegetround();
1446 ret = fesetround(mode);
1447 ret = fegetenv(penv);
1448 ret = feholdexcept(penv);
1449 ret = fesetenv(penv);
1450 ret = feupdateenv(penv);
1451 ],[ac_c99_fenv_tr1=yes], [ac_c99_fenv_tr1=no])
1452 fi
1453 AC_MSG_RESULT($ac_c99_fenv_tr1)
1454 if test x"$ac_c99_fenv_tr1" = x"yes"; then
1455 AC_DEFINE(_GLIBCXX_USE_C99_FENV_TR1, 1,
1456 [Define if C99 functions in <fenv.h> should be imported in
1457 <tr1/cfenv> in namespace std::tr1.])
1458 fi
1460 # Check for the existence of <stdint.h> types.
1461 AC_MSG_CHECKING([for ISO C99 support to TR1 in <stdint.h>])
1462 AC_CACHE_VAL(glibcxx_cv_c99_stdint_tr1, [
1463 AC_TRY_COMPILE([#define __STDC_LIMIT_MACROS
1464 #define __STDC_CONSTANT_MACROS
1465 #include <stdint.h>],
1466 [typedef int8_t my_int8_t;
1467 my_int8_t i8 = INT8_MIN;
1468 i8 = INT8_MAX;
1469 typedef int16_t my_int16_t;
1470 my_int16_t i16 = INT16_MIN;
1471 i16 = INT16_MAX;
1472 typedef int32_t my_int32_t;
1473 my_int32_t i32 = INT32_MIN;
1474 i32 = INT32_MAX;
1475 typedef int64_t my_int64_t;
1476 my_int64_t i64 = INT64_MIN;
1477 i64 = INT64_MAX;
1478 typedef int_fast8_t my_int_fast8_t;
1479 my_int_fast8_t if8 = INT_FAST8_MIN;
1480 if8 = INT_FAST8_MAX;
1481 typedef int_fast16_t my_int_fast16_t;
1482 my_int_fast16_t if16 = INT_FAST16_MIN;
1483 if16 = INT_FAST16_MAX;
1484 typedef int_fast32_t my_int_fast32_t;
1485 my_int_fast32_t if32 = INT_FAST32_MIN;
1486 if32 = INT_FAST32_MAX;
1487 typedef int_fast64_t my_int_fast64_t;
1488 my_int_fast64_t if64 = INT_FAST64_MIN;
1489 if64 = INT_FAST64_MAX;
1490 typedef int_least8_t my_int_least8_t;
1491 my_int_least8_t il8 = INT_LEAST8_MIN;
1492 il8 = INT_LEAST8_MAX;
1493 typedef int_least16_t my_int_least16_t;
1494 my_int_least16_t il16 = INT_LEAST16_MIN;
1495 il16 = INT_LEAST16_MAX;
1496 typedef int_least32_t my_int_least32_t;
1497 my_int_least32_t il32 = INT_LEAST32_MIN;
1498 il32 = INT_LEAST32_MAX;
1499 typedef int_least64_t my_int_least64_t;
1500 my_int_least64_t il64 = INT_LEAST64_MIN;
1501 il64 = INT_LEAST64_MAX;
1502 typedef intmax_t my_intmax_t;
1503 my_intmax_t im = INTMAX_MAX;
1504 im = INTMAX_MIN;
1505 typedef intptr_t my_intptr_t;
1506 my_intptr_t ip = INTPTR_MAX;
1507 ip = INTPTR_MIN;
1508 typedef uint8_t my_uint8_t;
1509 my_uint8_t ui8 = UINT8_MAX;
1510 ui8 = UINT8_MAX;
1511 typedef uint16_t my_uint16_t;
1512 my_uint16_t ui16 = UINT16_MAX;
1513 ui16 = UINT16_MAX;
1514 typedef uint32_t my_uint32_t;
1515 my_uint32_t ui32 = UINT32_MAX;
1516 ui32 = UINT32_MAX;
1517 typedef uint64_t my_uint64_t;
1518 my_uint64_t ui64 = UINT64_MAX;
1519 ui64 = UINT64_MAX;
1520 typedef uint_fast8_t my_uint_fast8_t;
1521 my_uint_fast8_t uif8 = UINT_FAST8_MAX;
1522 uif8 = UINT_FAST8_MAX;
1523 typedef uint_fast16_t my_uint_fast16_t;
1524 my_uint_fast16_t uif16 = UINT_FAST16_MAX;
1525 uif16 = UINT_FAST16_MAX;
1526 typedef uint_fast32_t my_uint_fast32_t;
1527 my_uint_fast32_t uif32 = UINT_FAST32_MAX;
1528 uif32 = UINT_FAST32_MAX;
1529 typedef uint_fast64_t my_uint_fast64_t;
1530 my_uint_fast64_t uif64 = UINT_FAST64_MAX;
1531 uif64 = UINT_FAST64_MAX;
1532 typedef uint_least8_t my_uint_least8_t;
1533 my_uint_least8_t uil8 = UINT_LEAST8_MAX;
1534 uil8 = UINT_LEAST8_MAX;
1535 typedef uint_least16_t my_uint_least16_t;
1536 my_uint_least16_t uil16 = UINT_LEAST16_MAX;
1537 uil16 = UINT_LEAST16_MAX;
1538 typedef uint_least32_t my_uint_least32_t;
1539 my_uint_least32_t uil32 = UINT_LEAST32_MAX;
1540 uil32 = UINT_LEAST32_MAX;
1541 typedef uint_least64_t my_uint_least64_t;
1542 my_uint_least64_t uil64 = UINT_LEAST64_MAX;
1543 uil64 = UINT_LEAST64_MAX;
1544 typedef uintmax_t my_uintmax_t;
1545 my_uintmax_t uim = UINTMAX_MAX;
1546 uim = UINTMAX_MAX;
1547 typedef uintptr_t my_uintptr_t;
1548 my_uintptr_t uip = UINTPTR_MAX;
1549 uip = UINTPTR_MAX;
1550 ],[glibcxx_cv_c99_stdint_tr1=yes],
1551 [glibcxx_cv_c99_stdint_tr1=no])
1552 ])
1553 AC_MSG_RESULT($glibcxx_cv_c99_stdint_tr1)
1554 if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
1555 AC_DEFINE(_GLIBCXX_USE_C99_STDINT_TR1, 1,
1556 [Define if C99 types in <stdint.h> should be imported in
1557 <tr1/cstdint> in namespace std::tr1.])
1558 fi
1560 # Check for the existence of <math.h> functions.
1561 AC_MSG_CHECKING([for ISO C99 support to TR1 in <math.h>])
1562 AC_CACHE_VAL(glibcxx_cv_c99_math_tr1, [
1563 AC_TRY_COMPILE([#include <math.h>],
1564 [typedef double_t my_double_t;
1565 typedef float_t my_float_t;
1566 acosh(0.0);
1567 acoshf(0.0f);
1568 acoshl(0.0l);
1569 asinh(0.0);
1570 asinhf(0.0f);
1571 asinhl(0.0l);
1572 atanh(0.0);
1573 atanhf(0.0f);
1574 atanhl(0.0l);
1575 cbrt(0.0);
1576 cbrtf(0.0f);
1577 cbrtl(0.0l);
1578 copysign(0.0, 0.0);
1579 copysignf(0.0f, 0.0f);
1580 copysignl(0.0l, 0.0l);
1581 erf(0.0);
1582 erff(0.0f);
1583 erfl(0.0l);
1584 erfc(0.0);
1585 erfcf(0.0f);
1586 erfcl(0.0l);
1587 exp2(0.0);
1588 exp2f(0.0f);
1589 exp2l(0.0l);
1590 expm1(0.0);
1591 expm1f(0.0f);
1592 expm1l(0.0l);
1593 fdim(0.0, 0.0);
1594 fdimf(0.0f, 0.0f);
1595 fdiml(0.0l, 0.0l);
1596 fma(0.0, 0.0, 0.0);
1597 fmaf(0.0f, 0.0f, 0.0f);
1598 fmal(0.0l, 0.0l, 0.0l);
1599 fmax(0.0, 0.0);
1600 fmaxf(0.0f, 0.0f);
1601 fmaxl(0.0l, 0.0l);
1602 fmin(0.0, 0.0);
1603 fminf(0.0f, 0.0f);
1604 fminl(0.0l, 0.0l);
1605 hypot(0.0, 0.0);
1606 hypotf(0.0f, 0.0f);
1607 hypotl(0.0l, 0.0l);
1608 ilogb(0.0);
1609 ilogbf(0.0f);
1610 ilogbl(0.0l);
1611 lgamma(0.0);
1612 lgammaf(0.0f);
1613 lgammal(0.0l);
1614 llrint(0.0);
1615 llrintf(0.0f);
1616 llrintl(0.0l);
1617 llround(0.0);
1618 llroundf(0.0f);
1619 llroundl(0.0l);
1620 log1p(0.0);
1621 log1pf(0.0f);
1622 log1pl(0.0l);
1623 log2(0.0);
1624 log2f(0.0f);
1625 log2l(0.0l);
1626 logb(0.0);
1627 logbf(0.0f);
1628 logbl(0.0l);
1629 lrint(0.0);
1630 lrintf(0.0f);
1631 lrintl(0.0l);
1632 lround(0.0);
1633 lroundf(0.0f);
1634 lroundl(0.0l);
1635 nan(0);
1636 nanf(0);
1637 nanl(0);
1638 nearbyint(0.0);
1639 nearbyintf(0.0f);
1640 nearbyintl(0.0l);
1641 nextafter(0.0, 0.0);
1642 nextafterf(0.0f, 0.0f);
1643 nextafterl(0.0l, 0.0l);
1644 nexttoward(0.0, 0.0);
1645 nexttowardf(0.0f, 0.0f);
1646 nexttowardl(0.0l, 0.0l);
1647 remainder(0.0, 0.0);
1648 remainderf(0.0f, 0.0f);
1649 remainderl(0.0l, 0.0l);
1650 remquo(0.0, 0.0, 0);
1651 remquof(0.0f, 0.0f, 0);
1652 remquol(0.0l, 0.0l, 0);
1653 rint(0.0);
1654 rintf(0.0f);
1655 rintl(0.0l);
1656 round(0.0);
1657 roundf(0.0f);
1658 roundl(0.0l);
1659 scalbln(0.0, 0l);
1660 scalblnf(0.0f, 0l);
1661 scalblnl(0.0l, 0l);
1662 scalbn(0.0, 0);
1663 scalbnf(0.0f, 0);
1664 scalbnl(0.0l, 0);
1665 tgamma(0.0);
1666 tgammaf(0.0f);
1667 tgammal(0.0l);
1668 trunc(0.0);
1669 truncf(0.0f);
1670 truncl(0.0l);
1671 ],[glibcxx_cv_c99_math_tr1=yes], [glibcxx_cv_c99_math_tr1=no])
1672 ])
1673 AC_MSG_RESULT($glibcxx_cv_c99_math_tr1)
1674 if test x"$glibcxx_cv_c99_math_tr1" = x"yes"; then
1675 AC_DEFINE(_GLIBCXX_USE_C99_MATH_TR1, 1,
1676 [Define if C99 functions or macros in <math.h> should be imported
1677 in <tr1/cmath> in namespace std::tr1.])
1678 fi
1680 # Check for the existence of <inttypes.h> functions (NB: doesn't make
1681 # sense if the glibcxx_cv_c99_stdint_tr1 check fails, per C99, 7.8/1).
1682 ac_c99_inttypes_tr1=no;
1683 if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
1684 AC_MSG_CHECKING([for ISO C99 support to TR1 in <inttypes.h>])
1685 AC_TRY_COMPILE([#include <inttypes.h>],
1686 [intmax_t i, numer, denom, base;
1687 const char* s;
1688 char** endptr;
1689 intmax_t ret = imaxabs(i);
1690 imaxdiv_t dret = imaxdiv(numer, denom);
1691 ret = strtoimax(s, endptr, base);
1692 uintmax_t uret = strtoumax(s, endptr, base);
1693 ],[ac_c99_inttypes_tr1=yes], [ac_c99_inttypes_tr1=no])
1694 fi
1695 AC_MSG_RESULT($ac_c99_inttypes_tr1)
1696 if test x"$ac_c99_inttypes_tr1" = x"yes"; then
1697 AC_DEFINE(_GLIBCXX_USE_C99_INTTYPES_TR1, 1,
1698 [Define if C99 functions in <inttypes.h> should be imported in
1699 <tr1/cinttypes> in namespace std::tr1.])
1700 fi
1702 # Check for the existence of whcar_t <inttypes.h> functions (NB: doesn't
1703 # make sense if the glibcxx_cv_c99_stdint_tr1 check fails, per C99, 7.8/1).
1704 ac_c99_inttypes_wchar_t_tr1=no;
1705 if test x"$glibcxx_cv_c99_stdint_tr1" = x"yes"; then
1706 AC_MSG_CHECKING([for wchar_t ISO C99 support to TR1 in <inttypes.h>])
1707 AC_TRY_COMPILE([#include <inttypes.h>],
1708 [intmax_t base;
1709 const wchar_t* s;
1710 wchar_t** endptr;
1711 intmax_t ret = wcstoimax(s, endptr, base);
1712 uintmax_t uret = wcstoumax(s, endptr, base);
1713 ],[ac_c99_inttypes_wchar_t_tr1=yes],
1714 [ac_c99_inttypes_wchar_t_tr1=no])
1715 fi
1716 AC_MSG_RESULT($ac_c99_inttypes_wchar_t_tr1)
1717 if test x"$ac_c99_inttypes_wchar_t_tr1" = x"yes"; then
1718 AC_DEFINE(_GLIBCXX_USE_C99_INTTYPES_WCHAR_T_TR1, 1,
1719 [Define if wchar_t C99 functions in <inttypes.h> should be
1720 imported in <tr1/cinttypes> in namespace std::tr1.])
1721 fi
1723 # Check for the existence of the <stdbool.h> header.
1724 AC_CHECK_HEADERS(stdbool.h)
1726 # Check for the existence of the <stdalign.h> header.
1727 AC_CHECK_HEADERS(stdalign.h)
1729 CXXFLAGS="$ac_save_CXXFLAGS"
1730 AC_LANG_RESTORE
1731 ])
1733 dnl
1734 dnl Check whether "/dev/random" and "/dev/urandom" are available for the
1735 dnl random_device of "TR1" (Chapter 5.1, "Random number generation").
1736 dnl
1737 AC_DEFUN([GLIBCXX_CHECK_RANDOM_TR1], [
1739 AC_MSG_CHECKING([for "/dev/random" and "/dev/urandom" for TR1 random_device])
1740 AC_CACHE_VAL(glibcxx_cv_random_tr1, [
1741 if test -r /dev/random && test -r /dev/urandom; then
1742 glibcxx_cv_random_tr1=yes;
1743 else
1744 glibcxx_cv_random_tr1=no;
1745 fi
1746 ])
1747 AC_MSG_RESULT($glibcxx_cv_random_tr1)
1749 if test x"$glibcxx_cv_random_tr1" = x"yes"; then
1750 AC_DEFINE(_GLIBCXX_USE_RANDOM_TR1, 1,
1751 [Define if /dev/random and /dev/urandom are available for
1752 the random_device of TR1 (Chapter 5.1).])
1753 fi
1755 ])
1757 dnl
1758 dnl Compute the EOF, SEEK_CUR, and SEEK_END integer constants.
1759 dnl
1760 AC_DEFUN([GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS], [
1762 AC_CACHE_CHECK([for the value of EOF], glibcxx_cv_stdio_eof, [
1763 AC_COMPUTE_INT([glibcxx_cv_stdio_eof], [[EOF]],
1764 [#include <stdio.h>],
1765 [AC_MSG_ERROR([computing EOF failed])])
1766 ])
1767 AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_EOF, $glibcxx_cv_stdio_eof,
1768 [Define to the value of the EOF integer constant.])
1770 AC_CACHE_CHECK([for the value of SEEK_CUR], glibcxx_cv_stdio_seek_cur, [
1771 AC_COMPUTE_INT([glibcxx_cv_stdio_seek_cur], [[SEEK_CUR]],
1772 [#include <stdio.h>],
1773 [AC_MSG_ERROR([computing SEEK_CUR failed])])
1774 ])
1775 AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_SEEK_CUR, $glibcxx_cv_stdio_seek_cur,
1776 [Define to the value of the SEEK_CUR integer constant.])
1778 AC_CACHE_CHECK([for the value of SEEK_END], glibcxx_cv_stdio_seek_end, [
1779 AC_COMPUTE_INT([glibcxx_cv_stdio_seek_end], [[SEEK_END]],
1780 [#include <stdio.h>],
1781 [AC_MSG_ERROR([computing SEEK_END failed])])
1782 ])
1783 AC_DEFINE_UNQUOTED(_GLIBCXX_STDIO_SEEK_END, $glibcxx_cv_stdio_seek_end,
1784 [Define to the value of the SEEK_END integer constant.])
1785 ])
1787 dnl
1788 dnl Check whether required C++ overloads are present in <stdio.h>.
1789 dnl
1790 AC_DEFUN([GLIBCXX_CHECK_STDIO_PROTO], [
1792 AC_LANG_SAVE
1793 AC_LANG_CPLUSPLUS
1795 AC_MSG_CHECKING([for gets declaration])
1796 AC_CACHE_VAL(glibcxx_cv_gets, [
1797 AC_COMPILE_IFELSE([AC_LANG_SOURCE(
1798 [#include <stdio.h>
1799 namespace test
1800 {
1801 using ::gets;
1802 }
1803 ])],
1804 [glibcxx_cv_gets=yes],
1805 [glibcxx_cv_gets=no]
1806 )])
1808 if test $glibcxx_cv_gets = yes; then
1809 AC_DEFINE(HAVE_GETS, 1, [Define if gets is available in <stdio.h>.])
1810 fi
1811 AC_MSG_RESULT($glibcxx_cv_gets)
1813 AC_LANG_RESTORE
1814 ])
1816 dnl
1817 dnl Check whether macros, etc are present for <system_error>
1818 dnl
1819 AC_DEFUN([GLIBCXX_CHECK_SYSTEM_ERROR], [
1821 m4_pushdef([n_syserr], [1])dnl
1822 m4_foreach([syserr], [EOWNERDEAD, ENOTRECOVERABLE, ENOLINK, EPROTO, ENODATA,
1823 ENOSR, ENOSTR, ETIME, EBADMSG, ECANCELED,
1824 EOVERFLOW, ENOTSUP, EIDRM, ETXTBSY,
1825 ECHILD, ENOSPC, EPERM,
1826 ETIMEDOUT, EWOULDBLOCK],
1827 [m4_pushdef([SYSERR], m4_toupper(syserr))dnl
1828 AC_MSG_CHECKING([for syserr])
1829 AC_CACHE_VAL([glibcxx_cv_system_error[]n_syserr], [
1830 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <errno.h>]],
1831 [int i = syserr;])],
1832 [glibcxx_cv_system_error[]n_syserr=yes],
1833 [glibcxx_cv_system_error[]n_syserr=no])
1834 ])
1835 AC_MSG_RESULT([$glibcxx_cv_system_error[]n_syserr])
1836 if test x"$glibcxx_cv_system_error[]n_syserr" = x"yes"; then
1837 AC_DEFINE([HAVE_]SYSERR, 1, [Define if ]syserr[ exists.])
1838 fi
1839 m4_define([n_syserr], m4_incr(n_syserr))dnl
1840 m4_popdef([SYSERR])dnl
1841 ])
1842 m4_popdef([n_syserr])dnl
1843 ])
1845 dnl
1846 dnl Check for what type of C headers to use.
1847 dnl
1848 dnl --enable-cheaders= [does stuff].
1849 dnl --disable-cheaders [does not do anything, really].
1850 dnl + Usage: GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
1851 dnl Where DEFAULT is either 'c' or 'c_std' or 'c_global'.
1852 dnl
1853 AC_DEFUN([GLIBCXX_ENABLE_CHEADERS], [
1854 GLIBCXX_ENABLE(cheaders,$1,[[[=KIND]]],
1855 [construct "C" headers for g++], [permit c|c_std|c_global])
1856 AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
1858 C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
1860 # Allow overrides to configure.host here.
1861 if test $enable_cheaders = c_global; then
1862 c_compatibility=yes
1863 fi
1865 AC_SUBST(C_INCLUDE_DIR)
1866 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
1867 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
1868 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_GLOBAL, test $enable_cheaders = c_global)
1869 GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
1870 ])
1873 dnl
1874 dnl Check for which locale library to use. The choice is mapped to
1875 dnl a subdirectory of config/locale.
1876 dnl
1877 dnl Default is generic.
1878 dnl
1879 AC_DEFUN([GLIBCXX_ENABLE_CLOCALE], [
1880 GLIBCXX_ENABLE(clocale,auto,[[[=MODEL]]],
1881 [use MODEL for target locale package],
1882 [permit generic|gnu|ieee_1003.1-2001|newlib|yes|no|auto])
1884 # Deal with gettext issues. Default to not using it (=no) until we detect
1885 # support for it later. Let the user turn it off via --e/d, but let that
1886 # default to on for easier handling.
1887 USE_NLS=no
1888 AC_ARG_ENABLE(nls,
1889 AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1890 [],
1891 [enable_nls=yes])
1893 # Either a known package, or "auto"
1894 if test $enable_clocale = no || test $enable_clocale = yes; then
1895 enable_clocale=auto
1896 fi
1897 enable_clocale_flag=$enable_clocale
1899 # Probe for locale model to use if none specified.
1900 # Default to "generic".
1901 if test $enable_clocale_flag = auto; then
1902 case ${target_os} in
1903 linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
1904 enable_clocale_flag=gnu
1905 ;;
1906 darwin* | freebsd*)
1907 enable_clocale_flag=darwin
1908 ;;
1909 openbsd*)
1910 enable_clocale_flag=newlib
1911 ;;
1912 *)
1913 if test x"$with_newlib" = x"yes"; then
1914 enable_clocale_flag=newlib
1915 else
1916 enable_clocale_flag=generic
1917 fi
1918 ;;
1919 esac
1920 fi
1922 # Sanity check model, and test for special functionality.
1923 if test $enable_clocale_flag = gnu; then
1924 AC_EGREP_CPP([_GLIBCXX_ok], [
1925 #include <features.h>
1926 #if (__GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 3)) && !defined(__UCLIBC__)
1927 _GLIBCXX_ok
1928 #endif
1929 ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
1931 # Set it to scream when it hurts.
1932 ac_save_CFLAGS="$CFLAGS"
1933 CFLAGS="-Wimplicit-function-declaration -Werror"
1935 # Use strxfrm_l if available.
1936 AC_TRY_COMPILE([#define _GNU_SOURCE 1
1937 #include <string.h>
1938 #include <locale.h>],
1939 [char s[128]; __locale_t loc; strxfrm_l(s, "C", 5, loc);],
1940 AC_DEFINE(HAVE_STRXFRM_L, 1,
1941 [Define if strxfrm_l is available in <string.h>.]),)
1943 # Use strerror_l if available.
1944 AC_TRY_COMPILE([#define _GNU_SOURCE 1
1945 #include <string.h>
1946 #include <locale.h>],
1947 [__locale_t loc; strerror_l(5, loc);],
1948 AC_DEFINE(HAVE_STRERROR_L, 1,
1949 [Define if strerror_l is available in <string.h>.]),)
1951 CFLAGS="$ac_save_CFLAGS"
1952 fi
1954 # Perhaps use strerror_r if available, and strerror_l isn't.
1955 ac_save_CFLAGS="$CFLAGS"
1956 CFLAGS="-Wimplicit-function-declaration -Werror"
1957 AC_TRY_COMPILE([#define _GNU_SOURCE 1
1958 #include <string.h>
1959 #include <locale.h>],
1960 [char s[128]; strerror_r(5, s, 128);],
1961 AC_DEFINE(HAVE_STRERROR_R, 1,
1962 [Define if strerror_r is available in <string.h>.]),)
1963 CFLAGS="$ac_save_CFLAGS"
1965 # Set configure bits for specified locale package
1966 AC_MSG_CHECKING([for C locale to use])
1967 case ${enable_clocale_flag} in
1968 generic)
1969 AC_MSG_RESULT(generic)
1971 CLOCALE_H=config/locale/generic/c_locale.h
1972 CLOCALE_CC=config/locale/generic/c_locale.cc
1973 CCODECVT_CC=config/locale/generic/codecvt_members.cc
1974 CCOLLATE_CC=config/locale/generic/collate_members.cc
1975 CCTYPE_CC=config/locale/generic/ctype_members.cc
1976 CMESSAGES_H=config/locale/generic/messages_members.h
1977 CMESSAGES_CC=config/locale/generic/messages_members.cc
1978 CMONEY_CC=config/locale/generic/monetary_members.cc
1979 CNUMERIC_CC=config/locale/generic/numeric_members.cc
1980 CTIME_H=config/locale/generic/time_members.h
1981 CTIME_CC=config/locale/generic/time_members.cc
1982 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1983 ;;
1984 darwin)
1985 AC_MSG_RESULT(darwin or freebsd)
1987 CLOCALE_H=config/locale/generic/c_locale.h
1988 CLOCALE_CC=config/locale/generic/c_locale.cc
1989 CCODECVT_CC=config/locale/generic/codecvt_members.cc
1990 CCOLLATE_CC=config/locale/generic/collate_members.cc
1991 CCTYPE_CC=config/locale/darwin/ctype_members.cc
1992 CMESSAGES_H=config/locale/generic/messages_members.h
1993 CMESSAGES_CC=config/locale/generic/messages_members.cc
1994 CMONEY_CC=config/locale/generic/monetary_members.cc
1995 CNUMERIC_CC=config/locale/generic/numeric_members.cc
1996 CTIME_H=config/locale/generic/time_members.h
1997 CTIME_CC=config/locale/generic/time_members.cc
1998 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1999 ;;
2001 gnu)
2002 AC_MSG_RESULT(gnu)
2004 # Declare intention to use gettext, and add support for specific
2005 # languages.
2006 # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
2007 ALL_LINGUAS="de fr"
2009 # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
2010 AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
2011 if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
2012 USE_NLS=yes
2013 fi
2014 # Export the build objects.
2015 for ling in $ALL_LINGUAS; do \
2016 glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
2017 glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
2018 done
2019 AC_SUBST(glibcxx_MOFILES)
2020 AC_SUBST(glibcxx_POFILES)
2022 CLOCALE_H=config/locale/gnu/c_locale.h
2023 CLOCALE_CC=config/locale/gnu/c_locale.cc
2024 CCODECVT_CC=config/locale/gnu/codecvt_members.cc
2025 CCOLLATE_CC=config/locale/gnu/collate_members.cc
2026 CCTYPE_CC=config/locale/gnu/ctype_members.cc
2027 CMESSAGES_H=config/locale/gnu/messages_members.h
2028 CMESSAGES_CC=config/locale/gnu/messages_members.cc
2029 CMONEY_CC=config/locale/gnu/monetary_members.cc
2030 CNUMERIC_CC=config/locale/gnu/numeric_members.cc
2031 CTIME_H=config/locale/gnu/time_members.h
2032 CTIME_CC=config/locale/gnu/time_members.cc
2033 CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
2034 ;;
2035 ieee_1003.1-2001)
2036 AC_MSG_RESULT(IEEE 1003.1)
2038 CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
2039 CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
2040 CCODECVT_CC=config/locale/generic/codecvt_members.cc
2041 CCOLLATE_CC=config/locale/generic/collate_members.cc
2042 CCTYPE_CC=config/locale/generic/ctype_members.cc
2043 CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
2044 CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
2045 CMONEY_CC=config/locale/generic/monetary_members.cc
2046 CNUMERIC_CC=config/locale/generic/numeric_members.cc
2047 CTIME_H=config/locale/generic/time_members.h
2048 CTIME_CC=config/locale/generic/time_members.cc
2049 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
2050 ;;
2051 newlib)
2052 AC_MSG_RESULT(newlib)
2054 CLOCALE_H=config/locale/generic/c_locale.h
2055 CLOCALE_CC=config/locale/generic/c_locale.cc
2056 CCODECVT_CC=config/locale/generic/codecvt_members.cc
2057 CCOLLATE_CC=config/locale/generic/collate_members.cc
2058 CCTYPE_CC=config/locale/newlib/ctype_members.cc
2059 CMESSAGES_H=config/locale/generic/messages_members.h
2060 CMESSAGES_CC=config/locale/generic/messages_members.cc
2061 CMONEY_CC=config/locale/generic/monetary_members.cc
2062 CNUMERIC_CC=config/locale/generic/numeric_members.cc
2063 CTIME_H=config/locale/generic/time_members.h
2064 CTIME_CC=config/locale/generic/time_members.cc
2065 CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
2066 ;;
2067 esac
2069 # This is where the testsuite looks for locale catalogs, using the
2070 # -DLOCALEDIR define during testsuite compilation.
2071 glibcxx_localedir=${glibcxx_builddir}/po/share/locale
2072 AC_SUBST(glibcxx_localedir)
2074 # A standalone libintl (e.g., GNU libintl) may be in use.
2075 if test $USE_NLS = yes; then
2076 AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
2077 AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
2078 fi
2079 if test $USE_NLS = yes; then
2080 AC_DEFINE(_GLIBCXX_USE_NLS, 1,
2081 [Define if NLS translations are to be used.])
2082 fi
2084 AC_SUBST(USE_NLS)
2085 AC_SUBST(CLOCALE_H)
2086 AC_SUBST(CMESSAGES_H)
2087 AC_SUBST(CCODECVT_CC)
2088 AC_SUBST(CCOLLATE_CC)
2089 AC_SUBST(CCTYPE_CC)
2090 AC_SUBST(CMESSAGES_CC)
2091 AC_SUBST(CMONEY_CC)
2092 AC_SUBST(CNUMERIC_CC)
2093 AC_SUBST(CTIME_H)
2094 AC_SUBST(CTIME_CC)
2095 AC_SUBST(CLOCALE_CC)
2096 AC_SUBST(CLOCALE_INTERNAL_H)
2097 ])
2100 dnl
2101 dnl Check for which std::allocator base class to use. The choice is
2102 dnl mapped from a subdirectory of include/ext.
2103 dnl
2104 dnl Default is new.
2105 dnl
2106 AC_DEFUN([GLIBCXX_ENABLE_ALLOCATOR], [
2107 AC_MSG_CHECKING([for std::allocator base class])
2108 GLIBCXX_ENABLE(libstdcxx-allocator,auto,[[[=KIND]]],
2109 [use KIND for target std::allocator base],
2110 [permit new|malloc|mt|bitmap|pool|yes|no|auto])
2112 # If they didn't use this option switch, or if they specified --enable
2113 # with no specific model, we'll have to look for one. If they
2114 # specified --disable (???), do likewise.
2115 if test $enable_libstdcxx_allocator = no ||
2116 test $enable_libstdcxx_allocator = yes;
2117 then
2118 enable_libstdcxx_allocator=auto
2119 fi
2121 # Either a known package, or "auto". Auto implies the default choice
2122 # for a particular platform.
2123 enable_libstdcxx_allocator_flag=$enable_libstdcxx_allocator
2125 # Probe for host-specific support if no specific model is specified.
2126 # Default to "new".
2127 if test $enable_libstdcxx_allocator_flag = auto; then
2128 case ${target_os} in
2129 linux* | gnu* | kfreebsd*-gnu | knetbsd*-gnu)
2130 enable_libstdcxx_allocator_flag=new
2131 ;;
2132 *)
2133 enable_libstdcxx_allocator_flag=new
2134 ;;
2135 esac
2136 fi
2137 AC_MSG_RESULT($enable_libstdcxx_allocator_flag)
2140 # Set configure bits for specified locale package
2141 case ${enable_libstdcxx_allocator_flag} in
2142 bitmap)
2143 ALLOCATOR_H=config/allocator/bitmap_allocator_base.h
2144 ALLOCATOR_NAME=__gnu_cxx::bitmap_allocator
2145 ;;
2146 malloc)
2147 ALLOCATOR_H=config/allocator/malloc_allocator_base.h
2148 ALLOCATOR_NAME=__gnu_cxx::malloc_allocator
2149 ;;
2150 mt)
2151 ALLOCATOR_H=config/allocator/mt_allocator_base.h
2152 ALLOCATOR_NAME=__gnu_cxx::__mt_alloc
2153 ;;
2154 new)
2155 ALLOCATOR_H=config/allocator/new_allocator_base.h
2156 ALLOCATOR_NAME=__gnu_cxx::new_allocator
2157 ;;
2158 pool)
2159 ALLOCATOR_H=config/allocator/pool_allocator_base.h
2160 ALLOCATOR_NAME=__gnu_cxx::__pool_alloc
2161 ;;
2162 esac
2164 AC_SUBST(ALLOCATOR_H)
2165 AC_SUBST(ALLOCATOR_NAME)
2166 ])
2169 dnl
2170 dnl Check for whether the Boost-derived checks should be turned on.
2171 dnl
2172 dnl --enable-concept-checks turns them on.
2173 dnl --disable-concept-checks leaves them off.
2174 dnl + Usage: GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
2175 dnl Where DEFAULT is either `yes' or `no'.
2176 dnl
2177 AC_DEFUN([GLIBCXX_ENABLE_CONCEPT_CHECKS], [
2178 GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
2179 if test $enable_concept_checks = yes; then
2180 AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS, 1,
2181 [Define to use concept checking code from the boost libraries.])
2182 fi
2183 ])
2185 dnl
2186 dnl Use extern templates.
2187 dnl
2188 dnl --enable-extern-template defines _GLIBCXX_EXTERN_TEMPLATE to 1
2189 dnl --disable-extern-template defines _GLIBCXX_EXTERN_TEMPLATE to 0
2191 dnl + Usage: GLIBCXX_ENABLE_TEMPLATE[(DEFAULT)]
2192 dnl Where DEFAULT is `yes' or `no'.
2193 dnl
2194 AC_DEFUN([GLIBCXX_ENABLE_EXTERN_TEMPLATE], [
2196 GLIBCXX_ENABLE(extern-template,$1,,[enable extern template])
2198 AC_MSG_CHECKING([for extern template support])
2199 AC_MSG_RESULT([$enable_extern_template])
2201 GLIBCXX_CONDITIONAL(ENABLE_EXTERN_TEMPLATE, test $enable_extern_template = yes)
2202 ])
2204 dnl
2205 dnl Check for parallel mode pre-requisites, including OpenMP support.
2206 dnl
2207 dnl + Usage: GLIBCXX_ENABLE_PARALLEL
2208 dnl
2209 AC_DEFUN([GLIBCXX_ENABLE_PARALLEL], [
2211 enable_parallel=no;
2213 # See if configured libgomp/omp.h exists. (libgomp may be in
2214 # noconfigdirs but not explicitly disabled.)
2215 if echo " ${TARGET_CONFIGDIRS} " | grep " libgomp " > /dev/null 2>&1 ; then
2216 enable_parallel=yes;
2217 else
2218 AC_MSG_NOTICE([target-libgomp not built])
2219 fi
2221 AC_MSG_CHECKING([for parallel mode support])
2222 AC_MSG_RESULT([$enable_parallel])
2223 ])
2226 dnl
2227 dnl Check for which I/O library to use: stdio, or something specific.
2228 dnl
2229 dnl Default is stdio.
2230 dnl
2231 AC_DEFUN([GLIBCXX_ENABLE_CSTDIO], [
2232 AC_MSG_CHECKING([for underlying I/O to use])
2233 GLIBCXX_ENABLE(cstdio,stdio,[[[=PACKAGE]]],
2234 [use target-specific I/O package], [permit stdio])
2236 # Now that libio has been removed, you can have any color you want as long
2237 # as it's black. This is one big no-op until other packages are added, but
2238 # showing the framework never hurts.
2239 case ${enable_cstdio} in
2240 stdio)
2241 CSTDIO_H=config/io/c_io_stdio.h
2242 BASIC_FILE_H=config/io/basic_file_stdio.h
2243 BASIC_FILE_CC=config/io/basic_file_stdio.cc
2244 AC_MSG_RESULT(stdio)
2245 ;;
2246 esac
2248 AC_SUBST(CSTDIO_H)
2249 AC_SUBST(BASIC_FILE_H)
2250 AC_SUBST(BASIC_FILE_CC)
2251 ])
2254 dnl
2255 dnl Check for "unusual" flags to pass to the compiler while building.
2256 dnl
2257 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
2258 dnl experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
2259 dnl --disable-cxx-flags passes nothing.
2260 dnl + See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
2261 dnl http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
2262 dnl http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
2263 dnl + Usage: GLIBCXX_ENABLE_CXX_FLAGS(default flags)
2264 dnl If "default flags" is an empty string, the effect is the same
2265 dnl as --disable or --enable=no.
2266 dnl
2267 AC_DEFUN([GLIBCXX_ENABLE_CXX_FLAGS], [dnl
2268 AC_MSG_CHECKING([for extra compiler flags for building])
2269 GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
2270 [pass compiler FLAGS when building library],
2271 [case "x$enable_cxx_flags" in
2272 xno | x) enable_cxx_flags= ;;
2273 x-*) ;;
2274 *) AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
2275 esac])
2277 # Run through flags (either default or command-line) and set anything
2278 # extra (e.g., #defines) that must accompany particular g++ options.
2279 if test -n "$enable_cxx_flags"; then
2280 for f in $enable_cxx_flags; do
2281 case "$f" in
2282 -fhonor-std) ;;
2283 -*) ;;
2284 *) # and we're trying to pass /what/ exactly?
2285 AC_MSG_ERROR([compiler flags start with a -]) ;;
2286 esac
2287 done
2288 fi
2290 EXTRA_CXX_FLAGS="$enable_cxx_flags"
2291 AC_MSG_RESULT($EXTRA_CXX_FLAGS)
2292 AC_SUBST(EXTRA_CXX_FLAGS)
2293 ])
2296 dnl
2297 dnl Check to see if debugging libraries are to be built.
2298 dnl
2299 dnl --enable-libstdcxx-debug
2300 dnl builds a separate set of debugging libraries in addition to the
2301 dnl normal (shared, static) libstdc++ binaries.
2302 dnl
2303 dnl --disable-libstdcxx-debug
2304 dnl builds only one (non-debug) version of libstdc++.
2305 dnl
2306 dnl --enable-libstdcxx-debug-flags=FLAGS
2307 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
2308 dnl
2309 dnl + Usage: GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
2310 dnl Where DEFAULT is either `yes' or `no'.
2311 dnl
2312 AC_DEFUN([GLIBCXX_ENABLE_DEBUG], [
2313 AC_MSG_CHECKING([for additional debug build])
2314 GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
2315 AC_MSG_RESULT($enable_libstdcxx_debug)
2316 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
2317 ])
2320 dnl
2321 dnl Check for explicit debug flags.
2322 dnl
2323 dnl --enable-libstdcxx-debug-flags='-O1'
2324 dnl is a general method for passing flags to be used when
2325 dnl building debug libraries with --enable-debug.
2326 dnl
2327 dnl --disable-libstdcxx-debug-flags does nothing.
2328 dnl + Usage: GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
2329 dnl If "default flags" is an empty string, the effect is the same
2330 dnl as --disable or --enable=no.
2331 dnl
2332 AC_DEFUN([GLIBCXX_ENABLE_DEBUG_FLAGS], [
2333 GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
2334 [pass compiler FLAGS when building debug library],
2335 [case "x$enable_libstdcxx_debug_flags" in
2336 xno | x) enable_libstdcxx_debug_flags= ;;
2337 x-*) ;;
2338 *) AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
2339 esac])
2341 # Option parsed, now set things appropriately
2342 DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
2343 AC_SUBST(DEBUG_FLAGS)
2345 AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
2346 ])
2349 dnl
2350 dnl Check if the user only wants a freestanding library implementation.
2351 dnl
2352 dnl --disable-hosted-libstdcxx will turn off most of the library build,
2353 dnl installing only the headers required by [17.4.1.3] and the language
2354 dnl support library. More than that will be built (to keep the Makefiles
2355 dnl conveniently clean), but not installed.
2356 dnl
2357 dnl Sets:
2358 dnl is_hosted (yes/no)
2359 dnl
2360 dnl Defines:
2361 dnl _GLIBCXX_HOSTED (always defined, either to 1 or 0)
2362 dnl
2363 AC_DEFUN([GLIBCXX_ENABLE_HOSTED], [
2364 AC_ARG_ENABLE([hosted-libstdcxx],
2365 AC_HELP_STRING([--disable-hosted-libstdcxx],
2366 [only build freestanding C++ runtime support]),,
2367 [case "$host" in
2368 arm*-*-symbianelf*)
2369 enable_hosted_libstdcxx=no
2370 ;;
2371 *)
2372 enable_hosted_libstdcxx=yes
2373 ;;
2374 esac])
2375 if test "$enable_hosted_libstdcxx" = no; then
2376 AC_MSG_NOTICE([Only freestanding libraries will be built])
2377 is_hosted=no
2378 hosted_define=0
2379 enable_abi_check=no
2380 enable_libstdcxx_pch=no
2381 else
2382 is_hosted=yes
2383 hosted_define=1
2384 fi
2385 GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
2386 AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
2387 [Define to 1 if a full hosted library is built, or 0 if freestanding.])
2388 ])
2391 dnl
2392 dnl Check if the user wants a non-verbose library implementation.
2393 dnl
2394 dnl --disable-libstdcxx-verbose will turn off descriptive messages to
2395 dnl standard error on termination.
2396 dnl
2397 dnl Defines:
2398 dnl _GLIBCXX_VERBOSE (always defined, either to 1 or 0)
2399 dnl
2400 AC_DEFUN([GLIBCXX_ENABLE_VERBOSE], [
2401 AC_ARG_ENABLE([libstdcxx-verbose],
2402 AC_HELP_STRING([--disable-libstdcxx-verbose],
2403 [disable termination messages to standard error]),,
2404 [enable_libstdcxx_verbose=yes])
2405 if test x"$enable_libstdcxx_verbose" = xyes; then
2406 verbose_define=1
2407 else
2408 AC_MSG_NOTICE([verbose termination messages are disabled])
2409 verbose_define=0
2410 fi
2411 AC_DEFINE_UNQUOTED(_GLIBCXX_VERBOSE, $verbose_define,
2412 [Define to 1 if a verbose library is built, or 0 otherwise.])
2413 ])
2416 dnl
2417 dnl Check for template specializations for the 'long long' type.
2418 dnl The result determines only whether 'long long' I/O is enabled; things
2419 dnl like numeric_limits<> specializations are always available.
2420 dnl
2421 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
2422 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
2423 dnl + Usage: GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
2424 dnl Where DEFAULT is either `yes' or `no'.
2425 dnl
2426 AC_DEFUN([GLIBCXX_ENABLE_LONG_LONG], [
2427 GLIBCXX_ENABLE(long-long,$1,,[enable template specializations for 'long long'])
2428 if test $enable_long_long = yes; then
2429 AC_DEFINE(_GLIBCXX_USE_LONG_LONG, 1,
2430 [Define if code specialized for long long should be used.])
2431 fi
2432 AC_MSG_CHECKING([for enabled long long specializations])
2433 AC_MSG_RESULT([$enable_long_long])
2434 ])
2437 dnl
2438 dnl Check for decimal floating point.
2439 dnl See:
2440 dnl http://gcc.gnu.org/onlinedocs/gcc/Decimal-Float.html#Decimal-Float
2441 dnl
2442 dnl This checks to see if the host supports decimal floating point types.
2443 dnl
2444 dnl Defines:
2445 dnl _GLIBCXX_USE_DECIMAL_FLOAT
2446 dnl
2447 AC_DEFUN([GLIBCXX_ENABLE_DECIMAL_FLOAT], [
2449 # Fake what AC_TRY_COMPILE does, without linking as this is
2450 # unnecessary for this test.
2452 cat > conftest.$ac_ext << EOF
2453 [#]line __oline__ "configure"
2454 int main()
2455 {
2456 _Decimal32 d1;
2457 _Decimal64 d2;
2458 _Decimal128 d3;
2459 return 0;
2460 }
2461 EOF
2463 AC_MSG_CHECKING([for ISO/IEC TR 24733 ])
2464 if AC_TRY_EVAL(ac_compile); then
2465 AC_DEFINE(_GLIBCXX_USE_DECIMAL_FLOAT, 1,
2466 [Define if ISO/IEC TR 24733 decimal floating point types are supported on this host.])
2467 enable_dfp=yes
2468 else
2469 enable_dfp=no
2470 fi
2471 AC_MSG_RESULT($enable_dfp)
2472 rm -f conftest*
2473 ])
2475 dnl
2476 dnl Check for GNU 128-bit integer and floating point types.
2477 dnl
2478 dnl Note: also checks that the types aren't standard types.
2479 dnl
2480 dnl Defines:
2481 dnl _GLIBCXX_USE_INT128
2482 dnl _GLIBCXX_USE_FLOAT128
2483 dnl
2484 AC_DEFUN([GLIBCXX_ENABLE_INT128_FLOAT128], [
2486 AC_LANG_SAVE
2487 AC_LANG_CPLUSPLUS
2489 # Fake what AC_TRY_COMPILE does, without linking as this is
2490 # unnecessary for this test.
2492 cat > conftest.$ac_ext << EOF
2493 [#]line __oline__ "configure"
2494 template<typename T1, typename T2>
2495 struct same
2496 { typedef T2 type; };
2498 template<typename T>
2499 struct same<T, T>;
2501 int main()
2502 {
2503 typename same<long, __int128>::type i1;
2504 typename same<long long, __int128>::type i2;
2505 }
2506 EOF
2508 AC_MSG_CHECKING([for __int128])
2509 if AC_TRY_EVAL(ac_compile); then
2510 AC_DEFINE(_GLIBCXX_USE_INT128, 1,
2511 [Define if __int128 is supported on this host.])
2512 enable_int128=yes
2513 else
2514 enable_int128=no
2515 fi
2516 AC_MSG_RESULT($enable_int128)
2517 rm -f conftest*
2519 cat > conftest.$ac_ext << EOF
2520 [#]line __oline__ "configure"
2521 template<typename T1, typename T2>
2522 struct same
2523 { typedef T2 type; };
2525 template<typename T>
2526 struct same<T, T>;
2528 int main()
2529 {
2530 typename same<double, __float128>::type f1;
2531 typename same<long double, __float128>::type f2;
2532 }
2533 EOF
2535 AC_MSG_CHECKING([for __float128])
2536 if AC_TRY_EVAL(ac_compile); then
2537 AC_DEFINE(_GLIBCXX_USE_FLOAT128, 1,
2538 [Define if __float128 is supported on this host.])
2539 enable_float128=yes
2540 else
2541 enable_float128=no
2542 fi
2543 AC_MSG_RESULT($enable_float128)
2544 rm -f conftest*
2546 AC_LANG_RESTORE
2547 ])
2549 dnl
2550 dnl Check for template specializations for the 'wchar_t' type.
2551 dnl
2552 dnl --enable-wchar_t defines _GLIBCXX_USE_WCHAR_T
2553 dnl --disable-wchar_t leaves _GLIBCXX_USE_WCHAR_T undefined
2554 dnl + Usage: GLIBCXX_ENABLE_WCHAR_T[(DEFAULT)]
2555 dnl Where DEFAULT is either `yes' or `no'.
2556 dnl
2557 dnl Necessary support must also be present.
2558 dnl
2559 AC_DEFUN([GLIBCXX_ENABLE_WCHAR_T], [
2560 GLIBCXX_ENABLE(wchar_t,$1,,[enable template specializations for 'wchar_t'])
2562 # Test wchar.h for mbstate_t, which is needed for char_traits and fpos.
2563 AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
2564 AC_MSG_CHECKING([for mbstate_t])
2565 AC_TRY_COMPILE([#include <wchar.h>],
2566 [mbstate_t teststate;],
2567 have_mbstate_t=yes, have_mbstate_t=no)
2568 AC_MSG_RESULT($have_mbstate_t)
2569 if test x"$have_mbstate_t" = xyes; then
2570 AC_DEFINE(HAVE_MBSTATE_T,1,[Define if mbstate_t exists in wchar.h.])
2571 fi
2573 # Test it always, for use in GLIBCXX_ENABLE_C99, together with
2574 # ac_has_wchar_h.
2575 AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
2577 if test x"$enable_wchar_t" = x"yes"; then
2579 AC_LANG_SAVE
2580 AC_LANG_CPLUSPLUS
2582 if test x"$ac_has_wchar_h" = xyes &&
2583 test x"$ac_has_wctype_h" = xyes; then
2584 AC_TRY_COMPILE([#include <wchar.h>
2585 #include <stddef.h>
2586 wint_t i;
2587 long l = WEOF;
2588 long j = WCHAR_MIN;
2589 long k = WCHAR_MAX;
2590 namespace test
2591 {
2592 using ::btowc;
2593 using ::fgetwc;
2594 using ::fgetws;
2595 using ::fputwc;
2596 using ::fputws;
2597 using ::fwide;
2598 using ::fwprintf;
2599 using ::fwscanf;
2600 using ::getwc;
2601 using ::getwchar;
2602 using ::mbrlen;
2603 using ::mbrtowc;
2604 using ::mbsinit;
2605 using ::mbsrtowcs;
2606 using ::putwc;
2607 using ::putwchar;
2608 using ::swprintf;
2609 using ::swscanf;
2610 using ::ungetwc;
2611 using ::vfwprintf;
2612 using ::vswprintf;
2613 using ::vwprintf;
2614 using ::wcrtomb;
2615 using ::wcscat;
2616 using ::wcschr;
2617 using ::wcscmp;
2618 using ::wcscoll;
2619 using ::wcscpy;
2620 using ::wcscspn;
2621 using ::wcsftime;
2622 using ::wcslen;
2623 using ::wcsncat;
2624 using ::wcsncmp;
2625 using ::wcsncpy;
2626 using ::wcspbrk;
2627 using ::wcsrchr;
2628 using ::wcsrtombs;
2629 using ::wcsspn;
2630 using ::wcsstr;
2631 using ::wcstod;
2632 using ::wcstok;
2633 using ::wcstol;
2634 using ::wcstoul;
2635 using ::wcsxfrm;
2636 using ::wctob;
2637 using ::wmemchr;
2638 using ::wmemcmp;
2639 using ::wmemcpy;
2640 using ::wmemmove;
2641 using ::wmemset;
2642 using ::wprintf;
2643 using ::wscanf;
2644 }
2645 ],[],[], [enable_wchar_t=no])
2646 else
2647 enable_wchar_t=no
2648 fi
2650 AC_LANG_RESTORE
2651 fi
2653 if test x"$enable_wchar_t" = x"yes"; then
2654 AC_DEFINE(_GLIBCXX_USE_WCHAR_T, 1,
2655 [Define if code specialized for wchar_t should be used.])
2656 fi
2658 AC_MSG_CHECKING([for enabled wchar_t specializations])
2659 AC_MSG_RESULT([$enable_wchar_t])
2660 ])
2663 dnl
2664 dnl Check to see if building and using a C++ precompiled header can be done.
2665 dnl
2666 dnl --enable-libstdcxx-pch=yes
2667 dnl default, this shows intent to use stdc++.h.gch If it looks like it
2668 dnl may work, after some light-hearted attempts to puzzle out compiler
2669 dnl support, flip bits on in include/Makefile.am
2670 dnl
2671 dnl --disable-libstdcxx-pch
2672 dnl turns off attempts to use or build stdc++.h.gch.
2673 dnl
2674 dnl Substs:
2675 dnl glibcxx_PCHFLAGS
2676 dnl
2677 AC_DEFUN([GLIBCXX_ENABLE_PCH], [
2678 GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
2679 if test $enable_libstdcxx_pch = yes; then
2680 AC_CACHE_CHECK([for compiler with PCH support],
2681 [glibcxx_cv_prog_CXX_pch],
2682 [ac_save_CXXFLAGS="$CXXFLAGS"
2683 CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
2684 AC_LANG_SAVE
2685 AC_LANG_CPLUSPLUS
2686 echo '#include <math.h>' > conftest.h
2687 if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
2688 -o conftest.h.gch 1>&5 2>&1 &&
2689 echo '#error "pch failed"' > conftest.h &&
2690 echo '#include "conftest.h"' > conftest.cc &&
2691 $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
2692 then
2693 glibcxx_cv_prog_CXX_pch=yes
2694 else
2695 glibcxx_cv_prog_CXX_pch=no
2696 fi
2697 rm -f conftest*
2698 CXXFLAGS=$ac_save_CXXFLAGS
2699 AC_LANG_RESTORE
2700 ])
2701 enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
2702 fi
2704 AC_MSG_CHECKING([for enabled PCH])
2705 AC_MSG_RESULT([$enable_libstdcxx_pch])
2707 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
2708 if test $enable_libstdcxx_pch = yes; then
2709 glibcxx_PCHFLAGS="-include bits/stdc++.h"
2710 else
2711 glibcxx_PCHFLAGS=""
2712 fi
2713 AC_SUBST(glibcxx_PCHFLAGS)
2714 ])
2717 dnl
2718 dnl Check for atomic builtins.
2719 dnl See:
2720 dnl http://gcc.gnu.org/onlinedocs/gcc/_005f_005fatomic-Builtins.html
2721 dnl
2722 dnl This checks to see if the host supports the compiler-generated
2723 dnl builtins for atomic operations for various integral sizes. Note, this
2724 dnl is intended to be an all-or-nothing switch, so all the atomic operations
2725 dnl that are used should be checked.
2726 dnl
2727 dnl Note:
2728 dnl libgomp and libgfortran use a link test, see CHECK_SYNC_FETCH_AND_ADD.
2729 dnl
2730 AC_DEFUN([GLIBCXX_ENABLE_ATOMIC_BUILTINS], [
2731 AC_LANG_SAVE
2732 AC_LANG_CPLUSPLUS
2733 old_CXXFLAGS="$CXXFLAGS"
2735 # Do link tests if possible, instead asm tests, limited to some platforms
2736 # see discussion in PR target/40134, PR libstdc++/40133 and the thread
2737 # starting at http://gcc.gnu.org/ml/gcc-patches/2009-07/msg00322.html
2738 atomic_builtins_link_tests=no
2739 if test x$gcc_no_link != xyes; then
2740 # Can do link tests. Limit to some tested platforms
2741 case "$host" in
2742 *-*-linux* | *-*-uclinux* | *-*-kfreebsd*-gnu | *-*-gnu*)
2743 atomic_builtins_link_tests=yes
2744 ;;
2745 esac
2746 fi
2748 if test x$atomic_builtins_link_tests = xyes; then
2750 # Do link tests.
2752 CXXFLAGS="$CXXFLAGS -fno-exceptions"
2754 AC_MSG_CHECKING([for atomic builtins for bool])
2755 AC_CACHE_VAL(glibcxx_cv_atomic_bool, [
2756 AC_TRY_LINK(
2757 [ ],
2758 [typedef bool atomic_type;
2759 atomic_type c1;
2760 atomic_type c2;
2761 atomic_type c3(0);
2762 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2763 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2764 __ATOMIC_RELAXED);
2765 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2766 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2767 ],
2768 [glibcxx_cv_atomic_bool=yes],
2769 [glibcxx_cv_atomic_bool=no])
2770 ])
2771 AC_MSG_RESULT($glibcxx_cv_atomic_bool)
2773 AC_MSG_CHECKING([for atomic builtins for short])
2774 AC_CACHE_VAL(glibcxx_cv_atomic_short, [
2775 AC_TRY_LINK(
2776 [ ],
2777 [typedef short atomic_type;
2778 atomic_type c1;
2779 atomic_type c2;
2780 atomic_type c3(0);
2781 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2782 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2783 __ATOMIC_RELAXED);
2784 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2785 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2786 ],
2787 [glibcxx_cv_atomic_short=yes],
2788 [glibcxx_cv_atomic_short=no])
2789 ])
2790 AC_MSG_RESULT($glibcxx_cv_atomic_short)
2792 AC_MSG_CHECKING([for atomic builtins for int])
2793 AC_CACHE_VAL(glibcxx_cv_atomic_int, [
2794 AC_TRY_LINK(
2795 [ ],
2796 [typedef int atomic_type;
2797 atomic_type c1;
2798 atomic_type c2;
2799 atomic_type c3(0);
2800 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2801 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2802 __ATOMIC_RELAXED);
2803 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2804 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2805 ],
2806 [glibcxx_cv_atomic_int=yes],
2807 [glibcxx_cv_atomic_int=no])
2808 ])
2809 AC_MSG_RESULT($glibcxx_cv_atomic_int)
2811 AC_MSG_CHECKING([for atomic builtins for long long])
2812 AC_CACHE_VAL(glibcxx_cv_atomic_long_long, [
2813 AC_TRY_LINK(
2814 [ ],
2815 [typedef long long atomic_type;
2816 atomic_type c1;
2817 atomic_type c2;
2818 atomic_type c3(0);
2819 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2820 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2821 __ATOMIC_RELAXED);
2822 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2823 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2824 ],
2825 [glibcxx_cv_atomic_long_long=yes],
2826 [glibcxx_cv_atomic_long_long=no])
2827 ])
2828 AC_MSG_RESULT($glibcxx_cv_atomic_long_long)
2830 else
2832 # Do asm tests.
2834 # Compile unoptimized.
2835 CXXFLAGS='-O0 -S'
2837 # Fake what AC_TRY_COMPILE does.
2839 cat > conftest.$ac_ext << EOF
2840 [#]line __oline__ "configure"
2841 int main()
2842 {
2843 typedef bool atomic_type;
2844 atomic_type c1;
2845 atomic_type c2;
2846 atomic_type c3(0);
2847 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2848 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2849 __ATOMIC_RELAXED);
2850 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2851 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2853 return 0;
2854 }
2855 EOF
2857 AC_MSG_CHECKING([for atomic builtins for bool])
2858 if AC_TRY_EVAL(ac_compile); then
2859 if grep __atomic_ conftest.s >/dev/null 2>&1 ; then
2860 glibcxx_cv_atomic_bool=no
2861 else
2862 glibcxx_cv_atomic_bool=yes
2863 fi
2864 fi
2865 AC_MSG_RESULT($glibcxx_cv_atomic_bool)
2866 rm -f conftest*
2868 cat > conftest.$ac_ext << EOF
2869 [#]line __oline__ "configure"
2870 int main()
2871 {
2872 typedef short atomic_type;
2873 atomic_type c1;
2874 atomic_type c2;
2875 atomic_type c3(0);
2876 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2877 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2878 __ATOMIC_RELAXED);
2879 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2880 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2882 return 0;
2883 }
2884 EOF
2886 AC_MSG_CHECKING([for atomic builtins for short])
2887 if AC_TRY_EVAL(ac_compile); then
2888 if grep __atomic_ conftest.s >/dev/null 2>&1 ; then
2889 glibcxx_cv_atomic_short=no
2890 else
2891 glibcxx_cv_atomic_short=yes
2892 fi
2893 fi
2894 AC_MSG_RESULT($glibcxx_cv_atomic_short)
2895 rm -f conftest*
2897 cat > conftest.$ac_ext << EOF
2898 [#]line __oline__ "configure"
2899 int main()
2900 {
2901 // NB: _Atomic_word not necessarily int.
2902 typedef int atomic_type;
2903 atomic_type c1;
2904 atomic_type c2;
2905 atomic_type c3(0);
2906 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2907 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2908 __ATOMIC_RELAXED);
2909 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2910 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2912 return 0;
2913 }
2914 EOF
2916 AC_MSG_CHECKING([for atomic builtins for int])
2917 if AC_TRY_EVAL(ac_compile); then
2918 if grep __atomic_ conftest.s >/dev/null 2>&1 ; then
2919 glibcxx_cv_atomic_int=no
2920 else
2921 glibcxx_cv_atomic_int=yes
2922 fi
2923 fi
2924 AC_MSG_RESULT($glibcxx_cv_atomic_int)
2925 rm -f conftest*
2927 cat > conftest.$ac_ext << EOF
2928 [#]line __oline__ "configure"
2929 int main()
2930 {
2931 typedef long long atomic_type;
2932 atomic_type c1;
2933 atomic_type c2;
2934 atomic_type c3(0);
2935 __atomic_fetch_add(&c1, c2, __ATOMIC_RELAXED);
2936 __atomic_compare_exchange_n(&c1, &c2, c3, true, __ATOMIC_ACQ_REL,
2937 __ATOMIC_RELAXED);
2938 __atomic_test_and_set(&c1, __ATOMIC_RELAXED);
2939 __atomic_load_n(&c1, __ATOMIC_RELAXED);
2941 return 0;
2942 }
2943 EOF
2945 AC_MSG_CHECKING([for atomic builtins for long long])
2946 if AC_TRY_EVAL(ac_compile); then
2947 if grep __atomic_ conftest.s >/dev/null 2>&1 ; then
2948 glibcxx_cv_atomic_long_long=no
2949 else
2950 glibcxx_cv_atomic_long_long=yes
2951 fi
2952 fi
2953 AC_MSG_RESULT($glibcxx_cv_atomic_long_long)
2954 rm -f conftest*
2956 fi
2958 CXXFLAGS="$old_CXXFLAGS"
2959 AC_LANG_RESTORE
2961 # Set atomicity_dir to builtins if all but the long long test above passes.
2962 if test $glibcxx_cv_atomic_bool = yes \
2963 && test $glibcxx_cv_atomic_short = yes \
2964 && test $glibcxx_cv_atomic_int = yes; then
2965 AC_DEFINE(_GLIBCXX_ATOMIC_BUILTINS, 1,
2966 [Define if the compiler supports C++11 atomics.])
2967 atomicity_dir=cpu/generic/atomicity_builtins
2968 fi
2970 # If still generic, set to mutex.
2971 if test $atomicity_dir = "cpu/generic" ; then
2972 atomicity_dir=cpu/generic/atomicity_mutex
2973 AC_MSG_WARN([No native atomic operations are provided for this platform.])
2974 if test "x$target_thread_file" = xsingle; then
2975 AC_MSG_WARN([They cannot be faked when thread support is disabled.])
2976 AC_MSG_WARN([Thread-safety of certain classes is not guaranteed.])
2977 else
2978 AC_MSG_WARN([They will be faked using a mutex.])
2979 AC_MSG_WARN([Performance of certain classes will degrade as a result.])
2980 fi
2981 fi
2983 ])
2986 dnl
2987 dnl Check for exception handling support. If an explicit enable/disable
2988 dnl sjlj exceptions is given, we don't have to detect. Otherwise the
2989 dnl target may or may not support call frame exceptions.
2990 dnl
2991 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
2992 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
2993 dnl Neither one forces an attempt at detection.
2994 dnl
2995 dnl Defines:
2996 dnl _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
2997 dnl
2998 AC_DEFUN([GLIBCXX_ENABLE_SJLJ_EXCEPTIONS], [
2999 AC_MSG_CHECKING([for exception model to use])
3000 AC_LANG_SAVE
3001 AC_LANG_CPLUSPLUS
3002 GLIBCXX_ENABLE(sjlj-exceptions,auto,,
3003 [force use of builtin_setjmp for exceptions],
3004 [permit yes|no|auto])
3006 if test $enable_sjlj_exceptions = auto; then
3007 # Botheration. Now we've got to detect the exception model. Link tests
3008 # against libgcc.a are problematic since we've not been given proper -L
3009 # bits for single-tree newlib and libgloss.
3010 #
3011 # Fake what AC_TRY_COMPILE does. XXX Look at redoing this new-style.
3012 cat > conftest.$ac_ext << EOF
3013 [#]line __oline__ "configure"
3014 struct S { ~S(); };
3015 void bar();
3016 void foo()
3017 {
3018 S s;
3019 bar();
3020 }
3021 EOF
3022 old_CXXFLAGS="$CXXFLAGS"
3023 CXXFLAGS=-S
3024 if AC_TRY_EVAL(ac_compile); then
3025 if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
3026 enable_sjlj_exceptions=yes
3027 elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
3028 enable_sjlj_exceptions=no
3029 elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
3030 enable_sjlj_exceptions=no
3031 fi
3032 fi
3033 CXXFLAGS="$old_CXXFLAGS"
3034 rm -f conftest*
3035 fi
3037 # This is a tad weird, for hysterical raisins. We have to map
3038 # enable/disable to two different models.
3039 case $enable_sjlj_exceptions in
3040 yes)
3041 AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
3042 [Define if the compiler is configured for setjmp/longjmp exceptions.])
3043 ac_exception_model_name=sjlj
3044 ;;
3045 no)
3046 ac_exception_model_name="call frame"
3047 ;;
3048 *)
3049 AC_MSG_ERROR([unable to detect exception model])
3050 ;;
3051 esac
3052 AC_LANG_RESTORE
3053 AC_MSG_RESULT($ac_exception_model_name)
3054 ])
3057 dnl
3058 dnl Allow visibility attributes to be used on namespaces, objects, etc.
3059 dnl
3060 dnl --enable-libstdcxx-visibility enables attempt to use visibility attributes.
3061 dnl --disable-libstdcxx-visibility turns off all use of visibility attributes.
3062 dnl + Usage: GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY[(DEFAULT)]
3063 dnl Where DEFAULT is 'yes'.
3064 dnl
3065 AC_DEFUN([GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY], [
3066 GLIBCXX_ENABLE(libstdcxx-visibility,$1,,[enables visibility safe usage])
3068 if test x$enable_libstdcxx_visibility = xyes ; then
3069 dnl all hail libgfortran
3070 dnl Check whether the target supports hidden visibility.
3071 AC_CACHE_CHECK([whether the target supports hidden visibility],
3072 glibcxx_cv_have_attribute_visibility, [
3073 save_CFLAGS="$CFLAGS"
3074 CFLAGS="$CFLAGS -Werror"
3075 AC_TRY_COMPILE([void __attribute__((visibility("hidden"))) foo(void) { }],
3076 [], glibcxx_cv_have_attribute_visibility=yes,
3077 glibcxx_cv_have_attribute_visibility=no)
3078 CFLAGS="$save_CFLAGS"])
3079 if test $glibcxx_cv_have_attribute_visibility = no; then
3080 enable_libstdcxx_visibility=no
3081 fi
3082 fi
3084 GLIBCXX_CONDITIONAL(ENABLE_VISIBILITY, test $enable_libstdcxx_visibility = yes)
3085 AC_MSG_NOTICE([visibility supported: $enable_libstdcxx_visibility])
3086 ])
3089 dnl
3090 dnl Add version tags to symbols in shared library (or not), additionally
3091 dnl marking other symbols as private/local (or not).
3092 dnl
3093 dnl Sets libtool_VERSION, and determines shared library SONAME.
3094 dnl
3095 dnl This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
3096 dnl
3097 dnl --enable-symvers=style adds a version script to the linker call when
3098 dnl creating the shared library. The choice of version script is
3099 dnl controlled by 'style'.
3100 dnl --disable-symvers does not.
3101 dnl
3102 dnl + Usage: GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
3103 dnl Where DEFAULT is either 'yes' or 'no'. Passing `yes' tries to
3104 dnl choose a default style based on linker characteristics. Passing
3105 dnl 'no' disables versioning.
3106 dnl
3107 AC_DEFUN([GLIBCXX_ENABLE_SYMVERS], [
3109 GLIBCXX_ENABLE(symvers,$1,[[[=STYLE]]],
3110 [enables symbol versioning of the shared library],
3111 [permit yes|no|gnu|gnu-versioned-namespace|darwin|darwin-export|sun])
3113 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
3114 # don't know enough about $LD to do tricks...
3115 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
3116 # Sun style symbol versions needs GNU c++filt for make_sunver.pl to work
3117 # with extern "C++" in version scripts.
3118 AC_REQUIRE([GCC_PROG_GNU_CXXFILT])
3120 # Turn a 'yes' into a suitable default.
3121 if test x$enable_symvers = xyes ; then
3122 if test $enable_shared = no || test "x$LD" = x || test x$gcc_no_link = xyes; then
3123 enable_symvers=no
3124 else
3125 if test $with_gnu_ld = yes ; then
3126 case ${target_os} in
3127 hpux*)
3128 enable_symvers=no ;;
3129 *)
3130 enable_symvers=gnu ;;
3131 esac
3132 else
3133 case ${target_os} in
3134 darwin*)
3135 enable_symvers=darwin ;;
3136 # Sun symbol versioning exists since Solaris 2.5.
3137 solaris2.[[5-9]]* | solaris2.1[[0-9]]*)
3138 # make_sunver.pl needs GNU c++filt to support extern "C++" in
3139 # version scripts, so disable symbol versioning if none can be
3140 # found.
3141 if test -z "$ac_cv_path_CXXFILT"; then
3142 AC_MSG_WARN([=== You have requested Sun symbol versioning, but])
3143 AC_MSG_WARN([=== no GNU c++filt could be found.])
3144 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3145 enable_symvers=no
3146 else
3147 enable_symvers=sun
3148 fi
3149 ;;
3150 *)
3151 enable_symvers=no ;;
3152 esac
3153 fi
3154 fi
3155 fi
3157 # Check to see if 'darwin' or 'darwin-export' can win.
3158 if test x$enable_symvers = xdarwin-export ; then
3159 enable_symvers=darwin
3160 fi
3162 # Check if 'sun' was requested on non-Solaris 2 platforms.
3163 if test x$enable_symvers = xsun ; then
3164 case ${target_os} in
3165 solaris2*)
3166 # All fine.
3167 ;;
3168 *)
3169 # Unlikely to work.
3170 AC_MSG_WARN([=== You have requested Sun symbol versioning, but])
3171 AC_MSG_WARN([=== you are not targetting Solaris 2.])
3172 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3173 enable_symvers=no
3174 ;;
3175 esac
3176 fi
3178 # Check to see if 'gnu' can win.
3179 if test $enable_symvers = gnu ||
3180 test $enable_symvers = gnu-versioned-namespace ||
3181 test $enable_symvers = sun; then
3182 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
3183 AC_MSG_CHECKING([for shared libgcc])
3184 ac_save_CFLAGS="$CFLAGS"
3185 CFLAGS=' -lgcc_s'
3186 AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
3187 CFLAGS="$ac_save_CFLAGS"
3188 if test $glibcxx_shared_libgcc = no; then
3189 cat > conftest.c <<EOF
3190 int main (void) { return 0; }
3191 EOF
3192 changequote(,)dnl
3193 glibcxx_libgcc_s_suffix=`${CC-cc} $CFLAGS $CPPFLAGS $LDFLAGS \
3194 -shared -shared-libgcc -o conftest.so \
3195 conftest.c -v 2>&1 >/dev/null \
3196 | sed -n 's/^.* -lgcc_s\([^ ]*\) .*$/\1/p'`
3197 changequote([,])dnl
3198 rm -f conftest.c conftest.so
3199 if test x${glibcxx_libgcc_s_suffix+set} = xset; then
3200 CFLAGS=" -lgcc_s$glibcxx_libgcc_s_suffix"
3201 AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes)
3202 CFLAGS="$ac_save_CFLAGS"
3203 fi
3204 fi
3205 AC_MSG_RESULT($glibcxx_shared_libgcc)
3207 # For GNU ld, we need at least this version. The format is described in
3208 # GLIBCXX_CHECK_LINKER_FEATURES above.
3209 glibcxx_min_gnu_ld_version=21400
3211 # If no shared libgcc, can't win.
3212 if test $glibcxx_shared_libgcc != yes; then
3213 AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
3214 AC_MSG_WARN([=== you are not building a shared libgcc_s.])
3215 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3216 enable_symvers=no
3217 elif test $with_gnu_ld != yes && test $enable_symvers = sun; then
3218 : All interesting versions of Sun ld support sun style symbol versioning.
3219 elif test $with_gnu_ld != yes ; then
3220 # just fail for now
3221 AC_MSG_WARN([=== You have requested GNU symbol versioning, but])
3222 AC_MSG_WARN([=== you are not using the GNU linker.])
3223 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3224 enable_symvers=no
3225 elif test $glibcxx_ld_is_gold = yes ; then
3226 : All versions of gold support symbol versioning.
3227 elif test $glibcxx_gnu_ld_version -lt $glibcxx_min_gnu_ld_version ; then
3228 # The right tools, the right setup, but too old. Fallbacks?
3229 AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
3230 AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
3231 AC_MSG_WARN(=== You would need to upgrade your binutils to version)
3232 AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
3233 AC_MSG_WARN([=== Symbol versioning will be disabled.])
3234 enable_symvers=no
3235 fi
3236 fi
3238 # For libtool versioning info, format is CURRENT:REVISION:AGE
3239 libtool_VERSION=6:18:0
3241 # Everything parsed; figure out what files and settings to use.
3242 case $enable_symvers in
3243 no)
3244 SYMVER_FILE=config/abi/pre/none.ver
3245 ;;
3246 gnu)
3247 SYMVER_FILE=config/abi/pre/gnu.ver
3248 AC_DEFINE(_GLIBCXX_SYMVER_GNU, 1,
3249 [Define to use GNU versioning in the shared library.])
3250 ;;
3251 gnu-versioned-namespace)
3252 libtool_VERSION=7:0:0
3253 SYMVER_FILE=config/abi/pre/gnu-versioned-namespace.ver
3254 AC_DEFINE(_GLIBCXX_SYMVER_GNU_NAMESPACE, 1,
3255 [Define to use GNU namespace versioning in the shared library.])
3256 ;;
3257 darwin)
3258 SYMVER_FILE=config/abi/pre/gnu.ver
3259 AC_DEFINE(_GLIBCXX_SYMVER_DARWIN, 1,
3260 [Define to use darwin versioning in the shared library.])
3261 ;;
3262 sun)
3263 SYMVER_FILE=config/abi/pre/gnu.ver
3264 AC_DEFINE(_GLIBCXX_SYMVER_SUN, 1,
3265 [Define to use Sun versioning in the shared library.])
3266 ;;
3267 esac
3269 if test x$enable_symvers != xno ; then
3270 AC_DEFINE(_GLIBCXX_SYMVER, 1,
3271 [Define to use symbol versioning in the shared library.])
3272 fi
3274 AC_CACHE_CHECK([whether the target supports .symver directive],
3275 glibcxx_cv_have_as_symver_directive, [
3276 AC_TRY_COMPILE([void foo (void); __asm (".symver foo, bar@SYMVER");],
3277 [], glibcxx_cv_have_as_symver_directive=yes,
3278 glibcxx_cv_have_as_symver_directive=no)])
3279 if test $glibcxx_cv_have_as_symver_directive = yes; then
3280 AC_DEFINE(HAVE_AS_SYMVER_DIRECTIVE, 1,
3281 [Define to 1 if the target assembler supports .symver directive.])
3282 fi
3284 AC_SUBST(SYMVER_FILE)
3285 AC_SUBST(port_specific_symbol_files)
3286 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS, test $enable_symvers != no)
3287 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU, test $enable_symvers = gnu)
3288 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_GNU_NAMESPACE, test $enable_symvers = gnu-versioned-namespace)
3289 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_DARWIN, test $enable_symvers = darwin)
3290 GLIBCXX_CONDITIONAL(ENABLE_SYMVERS_SUN, test $enable_symvers = sun)
3291 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
3293 if test $enable_symvers != no ; then
3294 case ${target_os} in
3295 # The Solaris 2 runtime linker doesn't support the GNU extension of
3296 # binding the same symbol to different versions
3297 solaris2*)
3298 ;;
3299 # Other platforms with GNU symbol versioning (GNU/Linux, more?) do.
3300 *)
3301 AC_DEFINE(HAVE_SYMVER_SYMBOL_RENAMING_RUNTIME_SUPPORT, 1,
3302 [Define to 1 if the target runtime linker supports binding the same symbol to different versions.])
3303 ;;
3304 esac
3305 fi
3307 # Now, set up compatibility support, if any.
3308 # In addition, need this to deal with std::size_t mangling in
3309 # src/compatibility.cc. In a perfect world, could use
3310 # typeid(std::size_t).name()[0] to do direct substitution.
3311 AC_MSG_CHECKING([for size_t as unsigned int])
3312 ac_save_CFLAGS="$CFLAGS"
3313 CFLAGS="-Werror"
3314 AC_TRY_COMPILE(, [__SIZE_TYPE__* stp; unsigned int* uip; stp = uip;],
3315 [glibcxx_size_t_is_i=yes], [glibcxx_size_t_is_i=no])
3316 CFLAGS=$ac_save_CFLAGS
3317 if test "$glibcxx_size_t_is_i" = yes; then
3318 AC_DEFINE(_GLIBCXX_SIZE_T_IS_UINT, 1, [Define if size_t is unsigned int.])
3319 fi
3320 AC_MSG_RESULT([$glibcxx_size_t_is_i])
3322 AC_MSG_CHECKING([for ptrdiff_t as int])
3323 ac_save_CFLAGS="$CFLAGS"
3324 CFLAGS="-Werror"
3325 AC_TRY_COMPILE(, [__PTRDIFF_TYPE__* ptp; int* ip; ptp = ip;],
3326 [glibcxx_ptrdiff_t_is_i=yes], [glibcxx_ptrdiff_t_is_i=no])
3327 CFLAGS=$ac_save_CFLAGS
3328 if test "$glibcxx_ptrdiff_t_is_i" = yes; then
3329 AC_DEFINE(_GLIBCXX_PTRDIFF_T_IS_INT, 1, [Define if ptrdiff_t is int.])
3330 fi
3331 AC_MSG_RESULT([$glibcxx_ptrdiff_t_is_i])
3332 ])
3335 dnl
3336 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
3337 dnl We must stage the required headers so that they will be installed
3338 dnl with the library (unlike libgcc, the STL implementation is provided
3339 dnl solely within headers). Since we must not inject random user-space
3340 dnl macro names into user-provided C++ code, we first stage into <file>-in
3341 dnl and process to <file> with an output command. The reason for a two-
3342 dnl stage process here is to correctly handle $srcdir!=$objdir without
3343 dnl having to write complex code (the sed commands to clean the macro
3344 dnl namespace are complex and fragile enough as it is). We must also
3345 dnl add a relative path so that -I- is supported properly.
3346 dnl
3347 dnl Substs:
3348 dnl thread_header
3349 dnl
3350 AC_DEFUN([GLIBCXX_ENABLE_THREADS], [
3351 AC_MSG_CHECKING([for thread model used by GCC])
3352 target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
3353 AC_MSG_RESULT([$target_thread_file])
3354 GCC_AC_THREAD_HEADER([$target_thread_file])
3355 ])
3358 dnl
3359 dnl Check if gthread implementation defines the types and functions
3360 dnl required by the c++0x thread library. Conforming gthread
3361 dnl implementations can define __GTHREADS_CXX0X to enable use with c++0x.
3362 dnl
3363 dnl GLIBCXX_ENABLE_SYMVERS must be done before this.
3364 dnl
3365 AC_DEFUN([GLIBCXX_CHECK_GTHREADS], [
3366 GLIBCXX_ENABLE(libstdcxx-threads,auto,,[enable C++11 threads support])
3368 if test x$enable_libstdcxx_threads = xauto ||
3369 test x$enable_libstdcxx_threads = xyes; then
3371 AC_LANG_SAVE
3372 AC_LANG_CPLUSPLUS
3374 ac_save_CXXFLAGS="$CXXFLAGS"
3375 CXXFLAGS="$CXXFLAGS -fno-exceptions \
3376 -I${toplevel_srcdir}/libgcc -I${toplevel_builddir}/libgcc"
3378 target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
3379 case $target_thread_file in
3380 posix)
3381 CXXFLAGS="$CXXFLAGS -DSUPPORTS_WEAK -DGTHREAD_USE_WEAK -D_PTHREADS"
3382 esac
3384 AC_MSG_CHECKING([whether it can be safely assumed that mutex_timedlock is available])
3386 AC_TRY_COMPILE([#include <unistd.h>],
3387 [
3388 // In case of POSIX threads check _POSIX_TIMEOUTS.
3389 #if (defined(_PTHREADS) \
3390 && (!defined(_POSIX_TIMEOUTS) || _POSIX_TIMEOUTS <= 0))
3391 #error
3392 #endif
3393 ], [ac_gthread_use_mutex_timedlock=1], [ac_gthread_use_mutex_timedlock=0])
3395 AC_DEFINE_UNQUOTED(_GTHREAD_USE_MUTEX_TIMEDLOCK, $ac_gthread_use_mutex_timedlock,
3396 [Define to 1 if mutex_timedlock is available.])
3398 if test $ac_gthread_use_mutex_timedlock = 1 ; then res_mutex_timedlock=yes ;
3399 else res_mutex_timedlock=no ; fi
3400 AC_MSG_RESULT([$res_mutex_timedlock])
3402 AC_MSG_CHECKING([for gthreads library])
3404 AC_TRY_COMPILE([#include "gthr.h"],
3405 [
3406 #ifndef __GTHREADS_CXX0X
3407 #error
3408 #endif
3409 ], [case $target_os in
3410 # gthreads support breaks symbol versioning on Solaris 9 (PR
3411 # libstdc++/52189).
3412 solaris2.9*)
3413 if test x$enable_symvers = xno; then
3414 ac_has_gthreads=yes
3415 elif test x$enable_libstdcxx_threads = xyes; then
3416 AC_MSG_WARN([You have requested C++11 threads support, but])
3417 AC_MSG_WARN([this breaks symbol versioning.])
3418 ac_has_gthreads=yes
3419 else
3420 ac_has_gthreads=no
3421 fi
3422 ;;
3423 *)
3424 ac_has_gthreads=yes
3425 ;;
3426 esac],
3427 [ac_has_gthreads=no])
3428 else
3429 ac_has_gthreads=no
3430 fi
3432 AC_MSG_RESULT([$ac_has_gthreads])
3434 if test x"$ac_has_gthreads" = x"yes"; then
3435 AC_DEFINE(_GLIBCXX_HAS_GTHREADS, 1,
3436 [Define if gthreads library is available.])
3437 fi
3439 CXXFLAGS="$ac_save_CXXFLAGS"
3440 AC_LANG_RESTORE
3441 ])
3444 # Check whether LC_MESSAGES is available in <locale.h>.
3445 # Ulrich Drepper <drepper@cygnus.com>, 1995.
3446 #
3447 # This file file be copied and used freely without restrictions. It can
3448 # be used in projects which are not available under the GNU Public License
3449 # but which still want to provide support for the GNU gettext functionality.
3450 # Please note that the actual code is *not* freely available.
3451 AC_DEFUN([AC_LC_MESSAGES], [
3452 AC_CHECK_HEADER(locale.h, [
3453 AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
3454 [AC_TRY_COMPILE([#include <locale.h>], [return LC_MESSAGES],
3455 ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
3456 if test $ac_cv_val_LC_MESSAGES = yes; then
3457 AC_DEFINE(HAVE_LC_MESSAGES, 1,
3458 [Define if LC_MESSAGES is available in <locale.h>.])
3459 fi
3460 ])
3461 ])
3463 dnl
3464 dnl Check whether rdrand is supported in the assembler.
3465 AC_DEFUN([GLIBCXX_CHECK_X86_RDRAND], [
3466 AC_MSG_CHECKING([for rdrand support in assembler])
3467 AC_CACHE_VAL(ac_cv_x86_rdrand, [
3468 ac_cv_x86_rdrand=no
3469 case "$target" in
3470 i?86-*-* | \
3471 x86_64-*-*)
3472 AC_TRY_COMPILE(, [asm("rdrand %eax");],
3473 [ac_cv_x86_rdrand=yes], [ac_cv_x86_rdrand=no])
3474 esac
3475 ])
3476 if test $ac_cv_x86_rdrand = yes; then
3477 AC_DEFINE(_GLIBCXX_X86_RDRAND, 1,
3478 [ Defined if as can handle rdrand. ])
3479 fi
3480 AC_MSG_RESULT($ac_cv_x86_rdrand)
3481 ])
3483 dnl
3484 dnl Check whether get_nprocs is available in <sys/sysinfo.h>, and define _GLIBCXX_USE_GET_NPROCS.
3485 dnl
3486 AC_DEFUN([GLIBCXX_CHECK_GET_NPROCS], [
3488 AC_LANG_SAVE
3489 AC_LANG_CPLUSPLUS
3490 ac_save_CXXFLAGS="$CXXFLAGS"
3491 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3493 AC_MSG_CHECKING([for get_nprocs])
3494 AC_CACHE_VAL(glibcxx_cv_GET_NPROCS, [
3495 GCC_TRY_COMPILE_OR_LINK(
3496 [#include <sys/sysinfo.h>],
3497 [int n = get_nprocs();],
3498 [glibcxx_cv_GET_NPROCS=yes],
3499 [glibcxx_cv_GET_NPROCS=no])
3500 ])
3501 if test $glibcxx_cv_GET_NPROCS = yes; then
3502 AC_DEFINE(_GLIBCXX_USE_GET_NPROCS, 1, [Define if get_nprocs is available in <sys/sysinfo.h>.])
3503 fi
3504 AC_MSG_RESULT($glibcxx_cv_GET_NPROCS)
3506 CXXFLAGS="$ac_save_CXXFLAGS"
3507 AC_LANG_RESTORE
3508 ])
3510 dnl
3511 dnl Check whether sysconf(_SC_NPROCESSORS_ONLN) is available in <unistd.h>, and define _GLIBCXX_USE_SC_NPROCESSORS_ONLN.
3512 dnl
3513 AC_DEFUN([GLIBCXX_CHECK_SC_NPROCESSORS_ONLN], [
3515 AC_LANG_SAVE
3516 AC_LANG_CPLUSPLUS
3517 ac_save_CXXFLAGS="$CXXFLAGS"
3518 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3520 AC_MSG_CHECKING([for _SC_NPROCESSORS_ONLN])
3521 AC_CACHE_VAL(glibcxx_cv_SC_NPROCESSORS_ONLN, [
3522 GCC_TRY_COMPILE_OR_LINK(
3523 [#include <unistd.h>],
3524 [int n = sysconf(_SC_NPROCESSORS_ONLN);],
3525 [glibcxx_cv_SC_NPROCESSORS_ONLN=yes],
3526 [glibcxx_cv_SC_NPROCESSORS_ONLN=no])
3527 ])
3528 if test $glibcxx_cv_SC_NPROCESSORS_ONLN = yes; then
3529 AC_DEFINE(_GLIBCXX_USE_SC_NPROCESSORS_ONLN, 1, [Define if _SC_NPROCESSORS_ONLN is available in <unistd.h>.])
3530 fi
3531 AC_MSG_RESULT($glibcxx_cv_SC_NPROCESSORS_ONLN)
3533 CXXFLAGS="$ac_save_CXXFLAGS"
3534 AC_LANG_RESTORE
3535 ])
3537 dnl
3538 dnl Check whether sysconf(_SC_NPROC_ONLN) is available in <unistd.h>, and define _GLIBCXX_USE_SC_NPROC_ONLN.
3539 dnl
3540 AC_DEFUN([GLIBCXX_CHECK_SC_NPROC_ONLN], [
3542 AC_LANG_SAVE
3543 AC_LANG_CPLUSPLUS
3544 ac_save_CXXFLAGS="$CXXFLAGS"
3545 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3547 AC_MSG_CHECKING([for _SC_NPROC_ONLN])
3548 AC_CACHE_VAL(glibcxx_cv_SC_NPROC_ONLN, [
3549 GCC_TRY_COMPILE_OR_LINK(
3550 [#include <unistd.h>],
3551 [int n = sysconf(_SC_NPROC_ONLN);],
3552 [glibcxx_cv_SC_NPROC_ONLN=yes],
3553 [glibcxx_cv_SC_NPROC_ONLN=no])
3554 ])
3555 if test $glibcxx_cv_SC_NPROC_ONLN = yes; then
3556 AC_DEFINE(_GLIBCXX_USE_SC_NPROC_ONLN, 1, [Define if _SC_NPROC_ONLN is available in <unistd.h>.])
3557 fi
3558 AC_MSG_RESULT($glibcxx_cv_SC_NPROC_ONLN)
3560 CXXFLAGS="$ac_save_CXXFLAGS"
3561 AC_LANG_RESTORE
3562 ])
3564 dnl
3565 dnl Check whether pthread_num_processors_np is available in <pthread.h>, and define _GLIBCXX_USE_PTHREADS_NUM_PROCESSORS_NP.
3566 dnl
3567 AC_DEFUN([GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP], [
3569 AC_LANG_SAVE
3570 AC_LANG_CPLUSPLUS
3571 ac_save_CXXFLAGS="$CXXFLAGS"
3572 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3574 AC_MSG_CHECKING([for pthreads_num_processors_np])
3575 AC_CACHE_VAL(glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP, [
3576 GCC_TRY_COMPILE_OR_LINK(
3577 [#include <pthread.h>],
3578 [int n = pthread_num_processors_np();],
3579 [glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP=yes],
3580 [glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP=no])
3581 ])
3582 if test $glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP = yes; then
3583 AC_DEFINE(_GLIBCXX_USE_PTHREADS_NUM_PROCESSORS_NP, 1, [Define if pthreads_num_processors_np is available in <pthread.h>.])
3584 fi
3585 AC_MSG_RESULT($glibcxx_cv_PTHREADS_NUM_PROCESSORS_NP)
3587 CXXFLAGS="$ac_save_CXXFLAGS"
3588 AC_LANG_RESTORE
3589 ])
3591 dnl
3592 dnl Check whether sysctl is available in <pthread.h>, and define _GLIBCXX_USE_SYSCTL_HW_NCPU.
3593 dnl
3594 AC_DEFUN([GLIBCXX_CHECK_SYSCTL_HW_NCPU], [
3596 AC_LANG_SAVE
3597 AC_LANG_CPLUSPLUS
3598 ac_save_CXXFLAGS="$CXXFLAGS"
3599 CXXFLAGS="$CXXFLAGS -fno-exceptions"
3601 AC_MSG_CHECKING([for hw.ncpu sysctl])
3602 AC_CACHE_VAL(glibcxx_cv_SYSCTL_HW_NCPU, [
3603 GCC_TRY_COMPILE_OR_LINK(
3604 [
3605 #include <stddef.h>
3606 #include <sys/sysctl.h>
3607 ],
3608 [
3609 int count;
3610 size_t size = sizeof(count);
3611 int mib[] = { CTL_HW, HW_NCPU };
3612 sysctl(mib, 2, &count, &size, NULL, 0);
3613 ],
3614 [glibcxx_cv_SYSCTL_HW_NCPU=yes],
3615 [glibcxx_cv_SYSCTL_HW_NCPU=no])
3616 ])
3617 if test $glibcxx_cv_SYSCTL_HW_NCPU = yes; then
3618 AC_DEFINE(_GLIBCXX_USE_SYSCTL_HW_NCPU, 1, [Define if sysctl(), CTL_HW and HW_NCPU are available in <sys/sysctl.h>.])
3619 fi
3620 AC_MSG_RESULT($glibcxx_cv_SYSCTL_HW_NCPU)
3622 CXXFLAGS="$ac_save_CXXFLAGS"
3623 AC_LANG_RESTORE
3624 ])
3626 dnl
3627 dnl Check to see if python pretty printing can be activated.
3628 dnl
3629 dnl --with-python-dir=dir
3630 dnl installs directory into $prefix/dir
3631 AC_DEFUN([GLIBCXX_ENABLE_PYTHON], [
3633 AC_MSG_CHECKING([for custom python install directory])
3634 AC_ARG_WITH([python-dir],
3635 AS_HELP_STRING([--with-python-dir],
3636 [the location to install Python modules. This path is relative starting from the prefix.]),
3637 [with_python_dir=$withval], [with_python_dir="no"])
3638 AC_MSG_RESULT(${with_python_dir})
3640 # Needed for installing Python modules during make install.
3641 python_mod_dir="${with_python_dir}"
3642 AC_SUBST(python_mod_dir)
3643 GLIBCXX_CONDITIONAL(ENABLE_PYTHONDIR, test $python_mod_dir != no)
3644 ])
3646 dnl
3647 dnl Check to see if -Werror is disabled.
3648 dnl
3649 dnl --enable-werror/--disable-werror
3650 AC_DEFUN([GLIBCXX_ENABLE_WERROR], [
3651 AC_MSG_CHECKING([for -Werror])
3652 GLIBCXX_ENABLE(werror,$1,,[turns on -Werror])
3653 AC_MSG_RESULT($enable_werror)
3654 GLIBCXX_CONDITIONAL(ENABLE_WERROR, test $enable_werror = yes)
3655 ])
3658 # Macros from the top-level gcc directory.
3659 m4_include([../config/gc++filt.m4])
3660 m4_include([../config/tls.m4])
3661 m4_include([../config/gthr.m4])