gcc/ada/sem_aux.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                              S E M _ A U X                               --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2016, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- As a special exception,  if other files  instantiate  generics from this --
  22 -- unit, or you link  this unit with other files  to produce an executable, --
  23 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  24 -- covered  by the  GNU  General  Public  License.  This exception does not --
  25 -- however invalidate  any other reasons why  the executable file  might be --
  26 -- covered by the  GNU Public License.                                      --
  27 --                                                                          --
  28 -- GNAT was originally developed  by the GNAT team at  New York University. --
  29 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  30 --                                                                          --
  31 ------------------------------------------------------------------------------
  32
  33 with Atree;  use Atree;
  34 with Einfo;  use Einfo;
  35 with Snames; use Snames;
  36 with Stand;  use Stand;
  37 with Uintp;  use Uintp;
  38
  39 package body Sem_Aux is
  40
  41    ----------------------
  42    -- Ancestor_Subtype --
  43    ----------------------
  44
  45    function Ancestor_Subtype (Typ : Entity_Id) return Entity_Id is
  46    begin
  47       --  If this is first subtype, or is a base type, then there is no
  48       --  ancestor subtype, so we return Empty to indicate this fact.
  49
  50       if Is_First_Subtype (Typ) or else Is_Base_Type (Typ) then
  51          return Empty;
  52       end if;
  53
  54       declare
  55          D : constant Node_Id := Declaration_Node (Typ);
  56
  57       begin
  58          --  If we have a subtype declaration, get the ancestor subtype
  59
  60          if Nkind (D) = N_Subtype_Declaration then
  61             if Nkind (Subtype_Indication (D)) = N_Subtype_Indication then
  62                return Entity (Subtype_Mark (Subtype_Indication (D)));
  63             else
  64                return Entity (Subtype_Indication (D));
  65             end if;
  66
  67          --  If not, then no subtype indication is available
  68
  69          else
  70             return Empty;
  71          end if;
  72       end;
  73    end Ancestor_Subtype;
  74
  75    --------------------
  76    -- Available_View --
  77    --------------------
  78
  79    function Available_View (Ent : Entity_Id) return Entity_Id is
  80    begin
  81       --  Obtain the non-limited view (if available)
  82
  83       if Has_Non_Limited_View (Ent) then
  84          return Get_Full_View (Non_Limited_View (Ent));
  85
  86       --  In all other cases, return entity unchanged
  87
  88       else
  89          return Ent;
  90       end if;
  91    end Available_View;
  92
  93    --------------------
  94    -- Constant_Value --
  95    --------------------
  96
  97    function Constant_Value (Ent : Entity_Id) return Node_Id is
  98       D      : constant Node_Id := Declaration_Node (Ent);
  99       Full_D : Node_Id;
 100
 101    begin
 102       --  If we have no declaration node, then return no constant value. Not
 103       --  clear how this can happen, but it does sometimes and this is the
 104       --  safest approach.
 105
 106       if No (D) then
 107          return Empty;
 108
 109       --  Normal case where a declaration node is present
 110
 111       elsif Nkind (D) = N_Object_Renaming_Declaration then
 112          return Renamed_Object (Ent);
 113
 114       --  If this is a component declaration whose entity is a constant, it is
 115       --  a prival within a protected function (and so has no constant value).
 116
 117       elsif Nkind (D) = N_Component_Declaration then
 118          return Empty;
 119
 120       --  If there is an expression, return it
 121
 122       elsif Present (Expression (D)) then
 123          return Expression (D);
 124
 125       --  For a constant, see if we have a full view
 126
 127       elsif Ekind (Ent) = E_Constant
 128         and then Present (Full_View (Ent))
 129       then
 130          Full_D := Parent (Full_View (Ent));
 131
 132          --  The full view may have been rewritten as an object renaming
 133
 134          if Nkind (Full_D) = N_Object_Renaming_Declaration then
 135             return Name (Full_D);
 136          else
 137             return Expression (Full_D);
 138          end if;
 139
 140       --  Otherwise we have no expression to return
 141
 142       else
 143          return Empty;
 144       end if;
 145    end Constant_Value;
 146
 147    ---------------------------------
 148    -- Corresponding_Unsigned_Type --
 149    ---------------------------------
 150
 151    function Corresponding_Unsigned_Type (Typ : Entity_Id) return Entity_Id is
 152       pragma Assert (Is_Signed_Integer_Type (Typ));
 153       Siz : constant Uint := Esize (Base_Type (Typ));
 154    begin
 155       if Siz = Esize (Standard_Short_Short_Integer) then
 156          return Standard_Short_Short_Unsigned;
 157       elsif Siz = Esize (Standard_Short_Integer) then
 158          return Standard_Short_Unsigned;
 159       elsif Siz = Esize (Standard_Unsigned) then
 160          return Standard_Unsigned;
 161       elsif Siz = Esize (Standard_Long_Integer) then
 162          return Standard_Long_Unsigned;
 163       elsif Siz = Esize (Standard_Long_Long_Integer) then
 164          return Standard_Long_Long_Unsigned;
 165       else
 166          raise Program_Error;
 167       end if;
 168    end Corresponding_Unsigned_Type;
 169
 170    -----------------------------
 171    -- Enclosing_Dynamic_Scope --
 172    -----------------------------
 173
 174    function Enclosing_Dynamic_Scope (Ent : Entity_Id) return Entity_Id is
 175       S : Entity_Id;
 176
 177    begin
 178       --  The following test is an error defense against some syntax errors
 179       --  that can leave scopes very messed up.
 180
 181       if Ent = Standard_Standard then
 182          return Ent;
 183       end if;
 184
 185       --  Normal case, search enclosing scopes
 186
 187       --  Note: the test for Present (S) should not be required, it defends
 188       --  against an ill-formed tree.
 189
 190       S := Scope (Ent);
 191       loop
 192          --  If we somehow got an empty value for Scope, the tree must be
 193          --  malformed. Rather than blow up we return Standard in this case.
 194
 195          if No (S) then
 196             return Standard_Standard;
 197
 198          --  Quit if we get to standard or a dynamic scope. We must also
 199          --  handle enclosing scopes that have a full view; required to
 200          --  locate enclosing scopes that are synchronized private types
 201          --  whose full view is a task type.
 202
 203          elsif S = Standard_Standard
 204            or else Is_Dynamic_Scope (S)
 205            or else (Is_Private_Type (S)
 206                      and then Present (Full_View (S))
 207                      and then Is_Dynamic_Scope (Full_View (S)))
 208          then
 209             return S;
 210
 211          --  Otherwise keep climbing
 212
 213          else
 214             S := Scope (S);
 215          end if;
 216       end loop;
 217    end Enclosing_Dynamic_Scope;
 218
 219    ------------------------
 220    -- First_Discriminant --
 221    ------------------------
 222
 223    function First_Discriminant (Typ : Entity_Id) return Entity_Id is
 224       Ent : Entity_Id;
 225
 226    begin
 227       pragma Assert
 228         (Has_Discriminants (Typ) or else Has_Unknown_Discriminants (Typ));
 229
 230       Ent := First_Entity (Typ);
 231
 232       --  The discriminants are not necessarily contiguous, because access
 233       --  discriminants will generate itypes. They are not the first entities
 234       --  either because the tag must be ahead of them.
 235
 236       if Chars (Ent) = Name_uTag then
 237          Ent := Next_Entity (Ent);
 238       end if;
 239
 240       --  Skip all hidden stored discriminants if any
 241
 242       while Present (Ent) loop
 243          exit when Ekind (Ent) = E_Discriminant
 244            and then not Is_Completely_Hidden (Ent);
 245
 246          Ent := Next_Entity (Ent);
 247       end loop;
 248
 249       --  Call may be on a private type with unknown discriminants, in which
 250       --  case Ent is Empty, and as per the spec, we return Empty in this case.
 251
 252       --  Historical note: The assertion in previous versions that Ent is a
 253       --  discriminant was overly cautious and prevented convenient application
 254       --  of this function in the gnatprove context.
 255
 256       return Ent;
 257    end First_Discriminant;
 258
 259    -------------------------------
 260    -- First_Stored_Discriminant --
 261    -------------------------------
 262
 263    function First_Stored_Discriminant (Typ : Entity_Id) return Entity_Id is
 264       Ent : Entity_Id;
 265
 266       function Has_Completely_Hidden_Discriminant
 267         (Typ : Entity_Id) return Boolean;
 268       --  Scans the Discriminants to see whether any are Completely_Hidden
 269       --  (the mechanism for describing non-specified stored discriminants)
 270       --  Note that the entity list for the type may contain anonymous access
 271       --  types created by expressions that constrain access discriminants.
 272
 273       ----------------------------------------
 274       -- Has_Completely_Hidden_Discriminant --
 275       ----------------------------------------
 276
 277       function Has_Completely_Hidden_Discriminant
 278         (Typ : Entity_Id) return Boolean
 279       is
 280          Ent : Entity_Id;
 281
 282       begin
 283          pragma Assert (Ekind (Typ) = E_Discriminant);
 284
 285          Ent := Typ;
 286          while Present (Ent) loop
 287
 288             --  Skip anonymous types that may be created by expressions
 289             --  used as discriminant constraints on inherited discriminants.
 290
 291             if Is_Itype (Ent) then
 292                null;
 293
 294             elsif Ekind (Ent) = E_Discriminant
 295               and then Is_Completely_Hidden (Ent)
 296             then
 297                return True;
 298             end if;
 299
 300             Ent := Next_Entity (Ent);
 301          end loop;
 302
 303          return False;
 304       end Has_Completely_Hidden_Discriminant;
 305
 306    --  Start of processing for First_Stored_Discriminant
 307
 308    begin
 309       pragma Assert
 310         (Has_Discriminants (Typ)
 311           or else Has_Unknown_Discriminants (Typ));
 312
 313       Ent := First_Entity (Typ);
 314
 315       if Chars (Ent) = Name_uTag then
 316          Ent := Next_Entity (Ent);
 317       end if;
 318
 319       if Has_Completely_Hidden_Discriminant (Ent) then
 320          while Present (Ent) loop
 321             exit when Ekind (Ent) = E_Discriminant
 322               and then Is_Completely_Hidden (Ent);
 323             Ent := Next_Entity (Ent);
 324          end loop;
 325       end if;
 326
 327       pragma Assert (Ekind (Ent) = E_Discriminant);
 328
 329       return Ent;
 330    end First_Stored_Discriminant;
 331
 332    -------------------
 333    -- First_Subtype --
 334    -------------------
 335
 336    function First_Subtype (Typ : Entity_Id) return Entity_Id is
 337       B   : constant Entity_Id := Base_Type (Typ);
 338       F   : constant Node_Id   := Freeze_Node (B);
 339       Ent : Entity_Id;
 340
 341    begin
 342       --  If the base type has no freeze node, it is a type in Standard, and
 343       --  always acts as its own first subtype, except where it is one of the
 344       --  predefined integer types. If the type is formal, it is also a first
 345       --  subtype, and its base type has no freeze node. On the other hand, a
 346       --  subtype of a generic formal is not its own first subtype. Its base
 347       --  type, if anonymous, is attached to the formal type decl. from which
 348       --  the first subtype is obtained.
 349
 350       if No (F) then
 351          if B = Base_Type (Standard_Integer) then
 352             return Standard_Integer;
 353
 354          elsif B = Base_Type (Standard_Long_Integer) then
 355             return Standard_Long_Integer;
 356
 357          elsif B = Base_Type (Standard_Short_Short_Integer) then
 358             return Standard_Short_Short_Integer;
 359
 360          elsif B = Base_Type (Standard_Short_Integer) then
 361             return Standard_Short_Integer;
 362
 363          elsif B = Base_Type (Standard_Long_Long_Integer) then
 364             return Standard_Long_Long_Integer;
 365
 366          elsif Is_Generic_Type (Typ) then
 367             if Present (Parent (B)) then
 368                return Defining_Identifier (Parent (B));
 369             else
 370                return Defining_Identifier (Associated_Node_For_Itype (B));
 371             end if;
 372
 373          else
 374             return B;
 375          end if;
 376
 377       --  Otherwise we check the freeze node, if it has a First_Subtype_Link
 378       --  then we use that link, otherwise (happens with some Itypes), we use
 379       --  the base type itself.
 380
 381       else
 382          Ent := First_Subtype_Link (F);
 383
 384          if Present (Ent) then
 385             return Ent;
 386          else
 387             return B;
 388          end if;
 389       end if;
 390    end First_Subtype;
 391
 392    -------------------------
 393    -- First_Tag_Component --
 394    -------------------------
 395
 396    function First_Tag_Component (Typ : Entity_Id) return Entity_Id is
 397       Comp : Entity_Id;
 398       Ctyp : Entity_Id;
 399
 400    begin
 401       Ctyp := Typ;
 402       pragma Assert (Is_Tagged_Type (Ctyp));
 403
 404       if Is_Class_Wide_Type (Ctyp) then
 405          Ctyp := Root_Type (Ctyp);
 406       end if;
 407
 408       if Is_Private_Type (Ctyp) then
 409          Ctyp := Underlying_Type (Ctyp);
 410
 411          --  If the underlying type is missing then the source program has
 412          --  errors and there is nothing else to do (the full-type declaration
 413          --  associated with the private type declaration is missing).
 414
 415          if No (Ctyp) then
 416             return Empty;
 417          end if;
 418       end if;
 419
 420       Comp := First_Entity (Ctyp);
 421       while Present (Comp) loop
 422          if Is_Tag (Comp) then
 423             return Comp;
 424          end if;
 425
 426          Comp := Next_Entity (Comp);
 427       end loop;
 428
 429       --  No tag component found
 430
 431       return Empty;
 432    end First_Tag_Component;
 433
 434    ---------------------
 435    -- Get_Binary_Nkind --
 436    ---------------------
 437
 438    function Get_Binary_Nkind (Op : Entity_Id) return Node_Kind is
 439    begin
 440       case Chars (Op) is
 441          when Name_Op_Add =>
 442             return N_Op_Add;
 443          when Name_Op_Concat =>
 444             return N_Op_Concat;
 445          when Name_Op_Expon =>
 446             return N_Op_Expon;
 447          when Name_Op_Subtract =>
 448             return N_Op_Subtract;
 449          when Name_Op_Mod =>
 450             return N_Op_Mod;
 451          when Name_Op_Multiply =>
 452             return N_Op_Multiply;
 453          when Name_Op_Divide =>
 454             return N_Op_Divide;
 455          when Name_Op_Rem =>
 456             return N_Op_Rem;
 457          when Name_Op_And =>
 458             return N_Op_And;
 459          when Name_Op_Eq =>
 460             return N_Op_Eq;
 461          when Name_Op_Ge =>
 462             return N_Op_Ge;
 463          when Name_Op_Gt =>
 464             return N_Op_Gt;
 465          when Name_Op_Le =>
 466             return N_Op_Le;
 467          when Name_Op_Lt =>
 468             return N_Op_Lt;
 469          when Name_Op_Ne =>
 470             return N_Op_Ne;
 471          when Name_Op_Or =>
 472             return N_Op_Or;
 473          when Name_Op_Xor =>
 474             return N_Op_Xor;
 475          when others =>
 476             raise Program_Error;
 477       end case;
 478    end Get_Binary_Nkind;
 479
 480    -------------------
 481    -- Get_Low_Bound --
 482    -------------------
 483
 484    function Get_Low_Bound (E : Entity_Id) return Node_Id is
 485    begin
 486       if Ekind (E) = E_String_Literal_Subtype then
 487          return String_Literal_Low_Bound (E);
 488       else
 489          return Type_Low_Bound (E);
 490       end if;
 491    end Get_Low_Bound;
 492
 493    ------------------
 494    -- Get_Rep_Item --
 495    ------------------
 496
 497    function Get_Rep_Item
 498      (E             : Entity_Id;
 499       Nam           : Name_Id;
 500       Check_Parents : Boolean := True) return Node_Id
 501    is
 502       N : Node_Id;
 503
 504    begin
 505       N := First_Rep_Item (E);
 506       while Present (N) loop
 507
 508          --  Only one of Priority / Interrupt_Priority can be specified, so
 509          --  return whichever one is present to catch illegal duplication.
 510
 511          if Nkind (N) = N_Pragma
 512            and then
 513              (Pragma_Name (N) = Nam
 514                or else (Nam = Name_Priority
 515                          and then Pragma_Name (N) = Name_Interrupt_Priority)
 516                or else (Nam = Name_Interrupt_Priority
 517                          and then Pragma_Name (N) = Name_Priority))
 518          then
 519             if Check_Parents then
 520                return N;
 521
 522             --  If Check_Parents is False, return N if the pragma doesn't
 523             --  appear in the Rep_Item chain of the parent.
 524
 525             else
 526                declare
 527                   Par : constant Entity_Id := Nearest_Ancestor (E);
 528                   --  This node represents the parent type of type E (if any)
 529
 530                begin
 531                   if No (Par) then
 532                      return N;
 533
 534                   elsif not Present_In_Rep_Item (Par, N) then
 535                      return N;
 536                   end if;
 537                end;
 538             end if;
 539
 540          elsif Nkind (N) = N_Attribute_Definition_Clause
 541            and then
 542              (Chars (N) = Nam
 543                or else (Nam = Name_Priority
 544                          and then Chars (N) = Name_Interrupt_Priority))
 545          then
 546             if Check_Parents or else Entity (N) = E then
 547                return N;
 548             end if;
 549
 550          elsif Nkind (N) = N_Aspect_Specification
 551            and then
 552              (Chars (Identifier (N)) = Nam
 553                or else
 554                  (Nam = Name_Priority
 555                    and then Chars (Identifier (N)) = Name_Interrupt_Priority))
 556          then
 557             if Check_Parents then
 558                return N;
 559
 560             elsif Entity (N) = E then
 561                return N;
 562             end if;
 563          end if;
 564
 565          Next_Rep_Item (N);
 566       end loop;
 567
 568       return Empty;
 569    end Get_Rep_Item;
 570
 571    function Get_Rep_Item
 572      (E             : Entity_Id;
 573       Nam1          : Name_Id;
 574       Nam2          : Name_Id;
 575       Check_Parents : Boolean := True) return Node_Id
 576    is
 577       Nam1_Item : constant Node_Id := Get_Rep_Item (E, Nam1, Check_Parents);
 578       Nam2_Item : constant Node_Id := Get_Rep_Item (E, Nam2, Check_Parents);
 579
 580       N : Node_Id;
 581
 582    begin
 583       --  Check both Nam1_Item and Nam2_Item are present
 584
 585       if No (Nam1_Item) then
 586          return Nam2_Item;
 587       elsif No (Nam2_Item) then
 588          return Nam1_Item;
 589       end if;
 590
 591       --  Return the first node encountered in the list
 592
 593       N := First_Rep_Item (E);
 594       while Present (N) loop
 595          if N = Nam1_Item or else N = Nam2_Item then
 596             return N;
 597          end if;
 598
 599          Next_Rep_Item (N);
 600       end loop;
 601
 602       return Empty;
 603    end Get_Rep_Item;
 604
 605    --------------------
 606    -- Get_Rep_Pragma --
 607    --------------------
 608
 609    function Get_Rep_Pragma
 610      (E             : Entity_Id;
 611       Nam           : Name_Id;
 612       Check_Parents : Boolean := True) return Node_Id
 613    is
 614       N : constant Node_Id := Get_Rep_Item (E, Nam, Check_Parents);
 615
 616    begin
 617       if Present (N) and then Nkind (N) = N_Pragma then
 618          return N;
 619       end if;
 620
 621       return Empty;
 622    end Get_Rep_Pragma;
 623
 624    function Get_Rep_Pragma
 625      (E             : Entity_Id;
 626       Nam1          : Name_Id;
 627       Nam2          : Name_Id;
 628       Check_Parents : Boolean := True) return Node_Id
 629    is
 630       Nam1_Item : constant Node_Id := Get_Rep_Pragma (E, Nam1, Check_Parents);
 631       Nam2_Item : constant Node_Id := Get_Rep_Pragma (E, Nam2, Check_Parents);
 632
 633       N : Node_Id;
 634
 635    begin
 636       --  Check both Nam1_Item and Nam2_Item are present
 637
 638       if No (Nam1_Item) then
 639          return Nam2_Item;
 640       elsif No (Nam2_Item) then
 641          return Nam1_Item;
 642       end if;
 643
 644       --  Return the first node encountered in the list
 645
 646       N := First_Rep_Item (E);
 647       while Present (N) loop
 648          if N = Nam1_Item or else N = Nam2_Item then
 649             return N;
 650          end if;
 651
 652          Next_Rep_Item (N);
 653       end loop;
 654
 655       return Empty;
 656    end Get_Rep_Pragma;
 657
 658    ---------------------
 659    -- Get_Unary_Nkind --
 660    ---------------------
 661
 662    function Get_Unary_Nkind (Op : Entity_Id) return Node_Kind is
 663    begin
 664       case Chars (Op) is
 665          when Name_Op_Abs =>
 666             return N_Op_Abs;
 667          when Name_Op_Subtract =>
 668             return N_Op_Minus;
 669          when Name_Op_Not =>
 670             return N_Op_Not;
 671          when Name_Op_Add =>
 672             return N_Op_Plus;
 673          when others =>
 674             raise Program_Error;
 675       end case;
 676    end Get_Unary_Nkind;
 677
 678    ---------------------------------
 679    -- Has_External_Tag_Rep_Clause --
 680    ---------------------------------
 681
 682    function Has_External_Tag_Rep_Clause (T : Entity_Id) return Boolean is
 683    begin
 684       pragma Assert (Is_Tagged_Type (T));
 685       return Has_Rep_Item (T, Name_External_Tag, Check_Parents => False);
 686    end Has_External_Tag_Rep_Clause;
 687
 688    ------------------
 689    -- Has_Rep_Item --
 690    ------------------
 691
 692    function Has_Rep_Item
 693      (E             : Entity_Id;
 694       Nam           : Name_Id;
 695       Check_Parents : Boolean := True) return Boolean
 696    is
 697    begin
 698       return Present (Get_Rep_Item (E, Nam, Check_Parents));
 699    end Has_Rep_Item;
 700
 701    function Has_Rep_Item
 702      (E             : Entity_Id;
 703       Nam1          : Name_Id;
 704       Nam2          : Name_Id;
 705       Check_Parents : Boolean := True) return Boolean
 706    is
 707    begin
 708       return Present (Get_Rep_Item (E, Nam1, Nam2, Check_Parents));
 709    end Has_Rep_Item;
 710
 711    function Has_Rep_Item (E : Entity_Id; N : Node_Id) return Boolean is
 712       Item : Node_Id;
 713
 714    begin
 715       pragma Assert
 716         (Nkind_In (N, N_Aspect_Specification,
 717                       N_Attribute_Definition_Clause,
 718                       N_Enumeration_Representation_Clause,
 719                       N_Pragma,
 720                       N_Record_Representation_Clause));
 721
 722       Item := First_Rep_Item (E);
 723       while Present (Item) loop
 724          if Item = N then
 725             return True;
 726          end if;
 727
 728          Item := Next_Rep_Item (Item);
 729       end loop;
 730
 731       return False;
 732    end Has_Rep_Item;
 733
 734    --------------------
 735    -- Has_Rep_Pragma --
 736    --------------------
 737
 738    function Has_Rep_Pragma
 739      (E             : Entity_Id;
 740       Nam           : Name_Id;
 741       Check_Parents : Boolean := True) return Boolean
 742    is
 743    begin
 744       return Present (Get_Rep_Pragma (E, Nam, Check_Parents));
 745    end Has_Rep_Pragma;
 746
 747    function Has_Rep_Pragma
 748      (E             : Entity_Id;
 749       Nam1          : Name_Id;
 750       Nam2          : Name_Id;
 751       Check_Parents : Boolean := True) return Boolean
 752    is
 753    begin
 754       return Present (Get_Rep_Pragma (E, Nam1, Nam2, Check_Parents));
 755    end Has_Rep_Pragma;
 756
 757    --------------------------------
 758    -- Has_Unconstrained_Elements --
 759    --------------------------------
 760
 761    function Has_Unconstrained_Elements (T : Entity_Id) return Boolean is
 762       U_T : constant Entity_Id := Underlying_Type (T);
 763    begin
 764       if No (U_T) then
 765          return False;
 766       elsif Is_Record_Type (U_T) then
 767          return Has_Discriminants (U_T) and then not Is_Constrained (U_T);
 768       elsif Is_Array_Type (U_T) then
 769          return Has_Unconstrained_Elements (Component_Type (U_T));
 770       else
 771          return False;
 772       end if;
 773    end Has_Unconstrained_Elements;
 774
 775    ----------------------
 776    -- Has_Variant_Part --
 777    ----------------------
 778
 779    function Has_Variant_Part (Typ : Entity_Id) return Boolean is
 780       FSTyp : Entity_Id;
 781       Decl  : Node_Id;
 782       TDef  : Node_Id;
 783       CList : Node_Id;
 784
 785    begin
 786       if not Is_Type (Typ) then
 787          return False;
 788       end if;
 789
 790       FSTyp := First_Subtype (Typ);
 791
 792       if not Has_Discriminants (FSTyp) then
 793          return False;
 794       end if;
 795
 796       --  Proceed with cautious checks here, return False if tree is not
 797       --  as expected (may be caused by prior errors).
 798
 799       Decl := Declaration_Node (FSTyp);
 800
 801       if Nkind (Decl) /= N_Full_Type_Declaration then
 802          return False;
 803       end if;
 804
 805       TDef := Type_Definition (Decl);
 806
 807       if Nkind (TDef) /= N_Record_Definition then
 808          return False;
 809       end if;
 810
 811       CList := Component_List (TDef);
 812
 813       if Nkind (CList) /= N_Component_List then
 814          return False;
 815       else
 816          return Present (Variant_Part (CList));
 817       end if;
 818    end Has_Variant_Part;
 819
 820    ---------------------
 821    -- In_Generic_Body --
 822    ---------------------
 823
 824    function In_Generic_Body (Id : Entity_Id) return Boolean is
 825       S : Entity_Id;
 826
 827    begin
 828       --  Climb scopes looking for generic body
 829
 830       S := Id;
 831       while Present (S) and then S /= Standard_Standard loop
 832
 833          --  Generic package body
 834
 835          if Ekind (S) = E_Generic_Package
 836            and then In_Package_Body (S)
 837          then
 838             return True;
 839
 840          --  Generic subprogram body
 841
 842          elsif Is_Subprogram (S)
 843            and then Nkind (Unit_Declaration_Node (S)) =
 844                       N_Generic_Subprogram_Declaration
 845          then
 846             return True;
 847          end if;
 848
 849          S := Scope (S);
 850       end loop;
 851
 852       --  False if top of scope stack without finding a generic body
 853
 854       return False;
 855    end In_Generic_Body;
 856
 857    -------------------------------
 858    -- Initialization_Suppressed --
 859    -------------------------------
 860
 861    function Initialization_Suppressed (Typ : Entity_Id) return Boolean is
 862    begin
 863       return Suppress_Initialization (Typ)
 864         or else Suppress_Initialization (Base_Type (Typ));
 865    end Initialization_Suppressed;
 866
 867    ----------------
 868    -- Initialize --
 869    ----------------
 870
 871    procedure Initialize is
 872    begin
 873       Obsolescent_Warnings.Init;
 874    end Initialize;
 875
 876    -------------
 877    -- Is_Body --
 878    -------------
 879
 880    function Is_Body (N : Node_Id) return Boolean is
 881    begin
 882       return
 883         Nkind (N) in N_Body_Stub
 884           or else Nkind_In (N, N_Entry_Body,
 885                                N_Package_Body,
 886                                N_Protected_Body,
 887                                N_Subprogram_Body,
 888                                N_Task_Body);
 889    end Is_Body;
 890
 891    ---------------------
 892    -- Is_By_Copy_Type --
 893    ---------------------
 894
 895    function Is_By_Copy_Type (Ent : Entity_Id) return Boolean is
 896    begin
 897       --  If Id is a private type whose full declaration has not been seen,
 898       --  we assume for now that it is not a By_Copy type. Clearly this
 899       --  attribute should not be used before the type is frozen, but it is
 900       --  needed to build the associated record of a protected type. Another
 901       --  place where some lookahead for a full view is needed ???
 902
 903       return
 904         Is_Elementary_Type (Ent)
 905           or else (Is_Private_Type (Ent)
 906                      and then Present (Underlying_Type (Ent))
 907                      and then Is_Elementary_Type (Underlying_Type (Ent)));
 908    end Is_By_Copy_Type;
 909
 910    --------------------------
 911    -- Is_By_Reference_Type --
 912    --------------------------
 913
 914    function Is_By_Reference_Type (Ent : Entity_Id) return Boolean is
 915       Btype : constant Entity_Id := Base_Type (Ent);
 916
 917    begin
 918       if Error_Posted (Ent) or else Error_Posted (Btype) then
 919          return False;
 920
 921       elsif Is_Private_Type (Btype) then
 922          declare
 923             Utyp : constant Entity_Id := Underlying_Type (Btype);
 924          begin
 925             if No (Utyp) then
 926                return False;
 927             else
 928                return Is_By_Reference_Type (Utyp);
 929             end if;
 930          end;
 931
 932       elsif Is_Incomplete_Type (Btype) then
 933          declare
 934             Ftyp : constant Entity_Id := Full_View (Btype);
 935          begin
 936             if No (Ftyp) then
 937                return False;
 938             else
 939                return Is_By_Reference_Type (Ftyp);
 940             end if;
 941          end;
 942
 943       elsif Is_Concurrent_Type (Btype) then
 944          return True;
 945
 946       elsif Is_Record_Type (Btype) then
 947          if Is_Limited_Record (Btype)
 948            or else Is_Tagged_Type (Btype)
 949            or else Is_Volatile (Btype)
 950          then
 951             return True;
 952
 953          else
 954             declare
 955                C : Entity_Id;
 956
 957             begin
 958                C := First_Component (Btype);
 959                while Present (C) loop
 960
 961                   --  For each component, test if its type is a by reference
 962                   --  type and if its type is volatile. Also test the component
 963                   --  itself for being volatile. This happens for example when
 964                   --  a Volatile aspect is added to a component.
 965
 966                   if Is_By_Reference_Type (Etype (C))
 967                     or else Is_Volatile (Etype (C))
 968                     or else Is_Volatile (C)
 969                   then
 970                      return True;
 971                   end if;
 972
 973                   C := Next_Component (C);
 974                end loop;
 975             end;
 976
 977             return False;
 978          end if;
 979
 980       elsif Is_Array_Type (Btype) then
 981          return
 982            Is_Volatile (Btype)
 983              or else Is_By_Reference_Type (Component_Type (Btype))
 984              or else Is_Volatile (Component_Type (Btype))
 985              or else Has_Volatile_Components (Btype);
 986
 987       else
 988          return False;
 989       end if;
 990    end Is_By_Reference_Type;
 991
 992    -------------------------
 993    -- Is_Definite_Subtype --
 994    -------------------------
 995
 996    function Is_Definite_Subtype (T : Entity_Id) return Boolean is
 997       pragma Assert (Is_Type (T));
 998       K : constant Entity_Kind := Ekind (T);
 999
1000    begin
1001       if Is_Constrained (T) then
1002          return True;
1003
1004       elsif K in Array_Kind
1005         or else K in Class_Wide_Kind
1006         or else Has_Unknown_Discriminants (T)
1007       then
1008          return False;
1009
1010       --  Known discriminants: definite if there are default values. Note that
1011       --  if any discriminant has a default, they all do.
1012
1013       elsif Has_Discriminants (T) then
1014          return Present (Discriminant_Default_Value (First_Discriminant (T)));
1015
1016       else
1017          return True;
1018       end if;
1019    end Is_Definite_Subtype;
1020
1021    ---------------------
1022    -- Is_Derived_Type --
1023    ---------------------
1024
1025    function Is_Derived_Type (Ent : E) return B is
1026       Par : Node_Id;
1027
1028    begin
1029       if Is_Type (Ent)
1030         and then Base_Type (Ent) /= Root_Type (Ent)
1031         and then not Is_Class_Wide_Type (Ent)
1032
1033         --  An access_to_subprogram whose result type is a limited view can
1034         --  appear in a return statement, without the full view of the result
1035         --  type being available. Do not interpret this as a derived type.
1036
1037         and then Ekind (Ent) /= E_Subprogram_Type
1038       then
1039          if not Is_Numeric_Type (Root_Type (Ent)) then
1040             return True;
1041
1042          else
1043             Par := Parent (First_Subtype (Ent));
1044
1045             return Present (Par)
1046               and then Nkind (Par) = N_Full_Type_Declaration
1047               and then Nkind (Type_Definition (Par)) =
1048                          N_Derived_Type_Definition;
1049          end if;
1050
1051       else
1052          return False;
1053       end if;
1054    end Is_Derived_Type;
1055
1056    -----------------------
1057    -- Is_Generic_Formal --
1058    -----------------------
1059
1060    function Is_Generic_Formal (E : Entity_Id) return Boolean is
1061       Kind : Node_Kind;
1062    begin
1063       if No (E) then
1064          return False;
1065       else
1066          Kind := Nkind (Parent (E));
1067          return
1068            Nkind_In (Kind, N_Formal_Object_Declaration,
1069                            N_Formal_Package_Declaration,
1070                            N_Formal_Type_Declaration)
1071              or else Is_Formal_Subprogram (E);
1072       end if;
1073    end Is_Generic_Formal;
1074
1075    -------------------------------
1076    -- Is_Immutably_Limited_Type --
1077    -------------------------------
1078
1079    function Is_Immutably_Limited_Type (Ent : Entity_Id) return Boolean is
1080       Btype : constant Entity_Id := Available_View (Base_Type (Ent));
1081
1082    begin
1083       if Is_Limited_Record (Btype) then
1084          return True;
1085
1086       elsif Ekind (Btype) = E_Limited_Private_Type
1087         and then Nkind (Parent (Btype)) = N_Formal_Type_Declaration
1088       then
1089          return not In_Package_Body (Scope ((Btype)));
1090
1091       elsif Is_Private_Type (Btype) then
1092
1093          --  AI05-0063: A type derived from a limited private formal type is
1094          --  not immutably limited in a generic body.
1095
1096          if Is_Derived_Type (Btype)
1097            and then Is_Generic_Type (Etype (Btype))
1098          then
1099             if not Is_Limited_Type (Etype (Btype)) then
1100                return False;
1101
1102             --  A descendant of a limited formal type is not immutably limited
1103             --  in the generic body, or in the body of a generic child.
1104
1105             elsif Ekind (Scope (Etype (Btype))) = E_Generic_Package then
1106                return not In_Package_Body (Scope (Btype));
1107
1108             else
1109                return False;
1110             end if;
1111
1112          else
1113             declare
1114                Utyp : constant Entity_Id := Underlying_Type (Btype);
1115             begin
1116                if No (Utyp) then
1117                   return False;
1118                else
1119                   return Is_Immutably_Limited_Type (Utyp);
1120                end if;
1121             end;
1122          end if;
1123
1124       elsif Is_Concurrent_Type (Btype) then
1125          return True;
1126
1127       else
1128          return False;
1129       end if;
1130    end Is_Immutably_Limited_Type;
1131
1132    ---------------------
1133    -- Is_Limited_Type --
1134    ---------------------
1135
1136    function Is_Limited_Type (Ent : Entity_Id) return Boolean is
1137       Btype : constant E := Base_Type (Ent);
1138       Rtype : constant E := Root_Type (Btype);
1139
1140    begin
1141       if not Is_Type (Ent) then
1142          return False;
1143
1144       elsif Ekind (Btype) = E_Limited_Private_Type
1145         or else Is_Limited_Composite (Btype)
1146       then
1147          return True;
1148
1149       elsif Is_Concurrent_Type (Btype) then
1150          return True;
1151
1152          --  The Is_Limited_Record flag normally indicates that the type is
1153          --  limited. The exception is that a type does not inherit limitedness
1154          --  from its interface ancestor. So the type may be derived from a
1155          --  limited interface, but is not limited.
1156
1157       elsif Is_Limited_Record (Ent)
1158         and then not Is_Interface (Ent)
1159       then
1160          return True;
1161
1162       --  Otherwise we will look around to see if there is some other reason
1163       --  for it to be limited, except that if an error was posted on the
1164       --  entity, then just assume it is non-limited, because it can cause
1165       --  trouble to recurse into a murky entity resulting from other errors.
1166
1167       elsif Error_Posted (Ent) then
1168          return False;
1169
1170       elsif Is_Record_Type (Btype) then
1171
1172          if Is_Limited_Interface (Ent) then
1173             return True;
1174
1175          --  AI-419: limitedness is not inherited from a limited interface
1176
1177          elsif Is_Limited_Record (Rtype) then
1178             return not Is_Interface (Rtype)
1179               or else Is_Protected_Interface (Rtype)
1180               or else Is_Synchronized_Interface (Rtype)
1181               or else Is_Task_Interface (Rtype);
1182
1183          elsif Is_Class_Wide_Type (Btype) then
1184             return Is_Limited_Type (Rtype);
1185
1186          else
1187             declare
1188                C : E;
1189
1190             begin
1191                C := First_Component (Btype);
1192                while Present (C) loop
1193                   if Is_Limited_Type (Etype (C)) then
1194                      return True;
1195                   end if;
1196
1197                   C := Next_Component (C);
1198                end loop;
1199             end;
1200
1201             return False;
1202          end if;
1203
1204       elsif Is_Array_Type (Btype) then
1205          return Is_Limited_Type (Component_Type (Btype));
1206
1207       else
1208          return False;
1209       end if;
1210    end Is_Limited_Type;
1211
1212    ---------------------
1213    -- Is_Limited_View --
1214    ---------------------
1215
1216    function Is_Limited_View (Ent : Entity_Id) return Boolean is
1217       Btype : constant Entity_Id := Available_View (Base_Type (Ent));
1218
1219    begin
1220       if Is_Limited_Record (Btype) then
1221          return True;
1222
1223       elsif Ekind (Btype) = E_Limited_Private_Type
1224         and then Nkind (Parent (Btype)) = N_Formal_Type_Declaration
1225       then
1226          return not In_Package_Body (Scope ((Btype)));
1227
1228       elsif Is_Private_Type (Btype) then
1229
1230          --  AI05-0063: A type derived from a limited private formal type is
1231          --  not immutably limited in a generic body.
1232
1233          if Is_Derived_Type (Btype)
1234            and then Is_Generic_Type (Etype (Btype))
1235          then
1236             if not Is_Limited_Type (Etype (Btype)) then
1237                return False;
1238
1239             --  A descendant of a limited formal type is not immutably limited
1240             --  in the generic body, or in the body of a generic child.
1241
1242             elsif Ekind (Scope (Etype (Btype))) = E_Generic_Package then
1243                return not In_Package_Body (Scope (Btype));
1244
1245             else
1246                return False;
1247             end if;
1248
1249          else
1250             declare
1251                Utyp : constant Entity_Id := Underlying_Type (Btype);
1252             begin
1253                if No (Utyp) then
1254                   return False;
1255                else
1256                   return Is_Limited_View (Utyp);
1257                end if;
1258             end;
1259          end if;
1260
1261       elsif Is_Concurrent_Type (Btype) then
1262          return True;
1263
1264       elsif Is_Record_Type (Btype) then
1265
1266          --  Note that we return True for all limited interfaces, even though
1267          --  (unsynchronized) limited interfaces can have descendants that are
1268          --  nonlimited, because this is a predicate on the type itself, and
1269          --  things like functions with limited interface results need to be
1270          --  handled as build in place even though they might return objects
1271          --  of a type that is not inherently limited.
1272
1273          if Is_Class_Wide_Type (Btype) then
1274             return Is_Limited_View (Root_Type (Btype));
1275
1276          else
1277             declare
1278                C : Entity_Id;
1279
1280             begin
1281                C := First_Component (Btype);
1282                while Present (C) loop
1283
1284                   --  Don't consider components with interface types (which can
1285                   --  only occur in the case of a _parent component anyway).
1286                   --  They don't have any components, plus it would cause this
1287                   --  function to return true for nonlimited types derived from
1288                   --  limited interfaces.
1289
1290                   if not Is_Interface (Etype (C))
1291                     and then Is_Limited_View (Etype (C))
1292                   then
1293                      return True;
1294                   end if;
1295
1296                   C := Next_Component (C);
1297                end loop;
1298             end;
1299
1300             return False;
1301          end if;
1302
1303       elsif Is_Array_Type (Btype) then
1304          return Is_Limited_View (Component_Type (Btype));
1305
1306       else
1307          return False;
1308       end if;
1309    end Is_Limited_View;
1310
1311    ----------------------
1312    -- Nearest_Ancestor --
1313    ----------------------
1314
1315    function Nearest_Ancestor (Typ : Entity_Id) return Entity_Id is
1316       D : constant Node_Id := Declaration_Node (Typ);
1317
1318    begin
1319       --  If we have a subtype declaration, get the ancestor subtype
1320
1321       if Nkind (D) = N_Subtype_Declaration then
1322          if Nkind (Subtype_Indication (D)) = N_Subtype_Indication then
1323             return Entity (Subtype_Mark (Subtype_Indication (D)));
1324          else
1325             return Entity (Subtype_Indication (D));
1326          end if;
1327
1328       --  If derived type declaration, find who we are derived from
1329
1330       elsif Nkind (D) = N_Full_Type_Declaration
1331         and then Nkind (Type_Definition (D)) = N_Derived_Type_Definition
1332       then
1333          declare
1334             DTD : constant Entity_Id := Type_Definition (D);
1335             SI  : constant Entity_Id := Subtype_Indication (DTD);
1336          begin
1337             if Is_Entity_Name (SI) then
1338                return Entity (SI);
1339             else
1340                return Entity (Subtype_Mark (SI));
1341             end if;
1342          end;
1343
1344       --  If derived type and private type, get the full view to find who we
1345       --  are derived from.
1346
1347       elsif Is_Derived_Type (Typ)
1348         and then Is_Private_Type (Typ)
1349         and then Present (Full_View (Typ))
1350       then
1351          return Nearest_Ancestor (Full_View (Typ));
1352
1353       --  Otherwise, nothing useful to return, return Empty
1354
1355       else
1356          return Empty;
1357       end if;
1358    end Nearest_Ancestor;
1359
1360    ---------------------------
1361    -- Nearest_Dynamic_Scope --
1362    ---------------------------
1363
1364    function Nearest_Dynamic_Scope (Ent : Entity_Id) return Entity_Id is
1365    begin
1366       if Is_Dynamic_Scope (Ent) then
1367          return Ent;
1368       else
1369          return Enclosing_Dynamic_Scope (Ent);
1370       end if;
1371    end Nearest_Dynamic_Scope;
1372
1373    ------------------------
1374    -- Next_Tag_Component --
1375    ------------------------
1376
1377    function Next_Tag_Component (Tag : Entity_Id) return Entity_Id is
1378       Comp : Entity_Id;
1379
1380    begin
1381       pragma Assert (Is_Tag (Tag));
1382
1383       --  Loop to look for next tag component
1384
1385       Comp := Next_Entity (Tag);
1386       while Present (Comp) loop
1387          if Is_Tag (Comp) then
1388             pragma Assert (Chars (Comp) /= Name_uTag);
1389             return Comp;
1390          end if;
1391
1392          Comp := Next_Entity (Comp);
1393       end loop;
1394
1395       --  No tag component found
1396
1397       return Empty;
1398    end Next_Tag_Component;
1399
1400    -----------------------
1401    -- Number_Components --
1402    -----------------------
1403
1404    function Number_Components (Typ : Entity_Id) return Nat is
1405       N    : Nat := 0;
1406       Comp : Entity_Id;
1407
1408    begin
1409       --  We do not call Einfo.First_Component_Or_Discriminant, as this
1410       --  function does not skip completely hidden discriminants, which we
1411       --  want to skip here.
1412
1413       if Has_Discriminants (Typ) then
1414          Comp := First_Discriminant (Typ);
1415       else
1416          Comp := First_Component (Typ);
1417       end if;
1418
1419       while Present (Comp) loop
1420          N := N + 1;
1421          Comp := Next_Component_Or_Discriminant (Comp);
1422       end loop;
1423
1424       return N;
1425    end Number_Components;
1426
1427    --------------------------
1428    -- Number_Discriminants --
1429    --------------------------
1430
1431    function Number_Discriminants (Typ : Entity_Id) return Pos is
1432       N     : Nat       := 0;
1433       Discr : Entity_Id := First_Discriminant (Typ);
1434
1435    begin
1436       while Present (Discr) loop
1437          N := N + 1;
1438          Discr := Next_Discriminant (Discr);
1439       end loop;
1440
1441       return N;
1442    end Number_Discriminants;
1443
1444    ----------------------------------------------
1445    -- Object_Type_Has_Constrained_Partial_View --
1446    ----------------------------------------------
1447
1448    function Object_Type_Has_Constrained_Partial_View
1449      (Typ  : Entity_Id;
1450       Scop : Entity_Id) return Boolean
1451    is
1452    begin
1453       return Has_Constrained_Partial_View (Typ)
1454         or else (In_Generic_Body (Scop)
1455                   and then Is_Generic_Type (Base_Type (Typ))
1456                   and then Is_Private_Type (Base_Type (Typ))
1457                   and then not Is_Tagged_Type (Typ)
1458                   and then not (Is_Array_Type (Typ)
1459                                  and then not Is_Constrained (Typ))
1460                   and then Has_Discriminants (Typ));
1461    end Object_Type_Has_Constrained_Partial_View;
1462
1463    ------------------
1464    -- Package_Body --
1465    ------------------
1466
1467    function Package_Body (E : Entity_Id) return Node_Id is
1468       N : Node_Id;
1469
1470    begin
1471       if Ekind (E) = E_Package_Body then
1472          N := Parent (E);
1473
1474          if Nkind (N) = N_Defining_Program_Unit_Name then
1475             N := Parent (N);
1476          end if;
1477
1478       else
1479          N := Package_Spec (E);
1480
1481          if Present (Corresponding_Body (N)) then
1482             N := Parent (Corresponding_Body (N));
1483
1484             if Nkind (N) = N_Defining_Program_Unit_Name then
1485                N := Parent (N);
1486             end if;
1487          else
1488             N := Empty;
1489          end if;
1490       end if;
1491
1492       return N;
1493    end Package_Body;
1494
1495    ------------------
1496    -- Package_Spec --
1497    ------------------
1498
1499    function Package_Spec (E : Entity_Id) return Node_Id is
1500    begin
1501       return Parent (Package_Specification (E));
1502    end Package_Spec;
1503
1504    ---------------------------
1505    -- Package_Specification --
1506    ---------------------------
1507
1508    function Package_Specification (E : Entity_Id) return Node_Id is
1509       N : Node_Id;
1510
1511    begin
1512       N := Parent (E);
1513
1514       if Nkind (N) = N_Defining_Program_Unit_Name then
1515          N := Parent (N);
1516       end if;
1517
1518       return N;
1519    end Package_Specification;
1520
1521    ---------------------
1522    -- Subprogram_Body --
1523    ---------------------
1524
1525    function Subprogram_Body (E : Entity_Id) return Node_Id is
1526       Body_E : constant Entity_Id := Subprogram_Body_Entity (E);
1527
1528    begin
1529       if No (Body_E) then
1530          return Empty;
1531       else
1532          return Parent (Subprogram_Specification (Body_E));
1533       end if;
1534    end Subprogram_Body;
1535
1536    ----------------------------
1537    -- Subprogram_Body_Entity --
1538    ----------------------------
1539
1540    function Subprogram_Body_Entity (E : Entity_Id) return Entity_Id is
1541       N : constant Node_Id := Parent (Subprogram_Specification (E));
1542       --  Declaration for E
1543
1544    begin
1545       --  If this declaration is not a subprogram body, then it must be a
1546       --  subprogram declaration or body stub, from which we can retrieve the
1547       --  entity for the corresponding subprogram body if any, or an abstract
1548       --  subprogram declaration, for which we return Empty.
1549
1550       case Nkind (N) is
1551          when N_Subprogram_Body =>
1552             return E;
1553
1554          when N_Subprogram_Declaration | N_Subprogram_Body_Stub =>
1555             return Corresponding_Body (N);
1556
1557          when others =>
1558             return Empty;
1559       end case;
1560    end Subprogram_Body_Entity;
1561
1562    ---------------------
1563    -- Subprogram_Spec --
1564    ---------------------
1565
1566    function Subprogram_Spec (E : Entity_Id) return Node_Id is
1567       N : constant Node_Id := Parent (Subprogram_Specification (E));
1568       --  Declaration for E
1569
1570    begin
1571       --  This declaration is either subprogram declaration or a subprogram
1572       --  body, in which case return Empty.
1573
1574       if Nkind (N) = N_Subprogram_Declaration then
1575          return N;
1576       else
1577          return Empty;
1578       end if;
1579    end Subprogram_Spec;
1580
1581    ------------------------------
1582    -- Subprogram_Specification --
1583    ------------------------------
1584
1585    function Subprogram_Specification (E : Entity_Id) return Node_Id is
1586       N : Node_Id;
1587
1588    begin
1589       N := Parent (E);
1590
1591       if Nkind (N) = N_Defining_Program_Unit_Name then
1592          N := Parent (N);
1593       end if;
1594
1595       --  If the Parent pointer of E is not a subprogram specification node
1596       --  (going through an intermediate N_Defining_Program_Unit_Name node
1597       --  for subprogram units), then E is an inherited operation. Its parent
1598       --  points to the type derivation that produces the inheritance: that's
1599       --  the node that generates the subprogram specification. Its alias
1600       --  is the parent subprogram, and that one points to a subprogram
1601       --  declaration, or to another type declaration if this is a hierarchy
1602       --  of derivations.
1603
1604       if Nkind (N) not in N_Subprogram_Specification then
1605          pragma Assert (Present (Alias (E)));
1606          N := Subprogram_Specification (Alias (E));
1607       end if;
1608
1609       return N;
1610    end Subprogram_Specification;
1611
1612    ---------------
1613    -- Tree_Read --
1614    ---------------
1615
1616    procedure Tree_Read is
1617    begin
1618       Obsolescent_Warnings.Tree_Read;
1619    end Tree_Read;
1620
1621    ----------------
1622    -- Tree_Write --
1623    ----------------
1624
1625    procedure Tree_Write is
1626    begin
1627       Obsolescent_Warnings.Tree_Write;
1628    end Tree_Write;
1629
1630    --------------------
1631    -- Ultimate_Alias --
1632    --------------------
1633
1634    function Ultimate_Alias (Prim : Entity_Id) return Entity_Id is
1635       E : Entity_Id := Prim;
1636
1637    begin
1638       while Present (Alias (E)) loop
1639          pragma Assert (Alias (E) /= E);
1640          E := Alias (E);
1641       end loop;
1642
1643       return E;
1644    end Ultimate_Alias;
1645
1646    --------------------------
1647    -- Unit_Declaration_Node --
1648    --------------------------
1649
1650    function Unit_Declaration_Node (Unit_Id : Entity_Id) return Node_Id is
1651       N : Node_Id := Parent (Unit_Id);
1652
1653    begin
1654       --  Predefined operators do not have a full function declaration
1655
1656       if Ekind (Unit_Id) = E_Operator then
1657          return N;
1658       end if;
1659
1660       --  Isn't there some better way to express the following ???
1661
1662       while Nkind (N) /= N_Abstract_Subprogram_Declaration
1663         and then Nkind (N) /= N_Entry_Body
1664         and then Nkind (N) /= N_Entry_Declaration
1665         and then Nkind (N) /= N_Formal_Package_Declaration
1666         and then Nkind (N) /= N_Function_Instantiation
1667         and then Nkind (N) /= N_Generic_Package_Declaration
1668         and then Nkind (N) /= N_Generic_Subprogram_Declaration
1669         and then Nkind (N) /= N_Package_Declaration
1670         and then Nkind (N) /= N_Package_Body
1671         and then Nkind (N) /= N_Package_Instantiation
1672         and then Nkind (N) /= N_Package_Renaming_Declaration
1673         and then Nkind (N) /= N_Procedure_Instantiation
1674         and then Nkind (N) /= N_Protected_Body
1675         and then Nkind (N) /= N_Subprogram_Declaration
1676         and then Nkind (N) /= N_Subprogram_Body
1677         and then Nkind (N) /= N_Subprogram_Body_Stub
1678         and then Nkind (N) /= N_Subprogram_Renaming_Declaration
1679         and then Nkind (N) /= N_Task_Body
1680         and then Nkind (N) /= N_Task_Type_Declaration
1681         and then Nkind (N) not in N_Formal_Subprogram_Declaration
1682         and then Nkind (N) not in N_Generic_Renaming_Declaration
1683       loop
1684          N := Parent (N);
1685
1686          --  We don't use Assert here, because that causes an infinite loop
1687          --  when assertions are turned off. Better to crash.
1688
1689          if No (N) then
1690             raise Program_Error;
1691          end if;
1692       end loop;
1693
1694       return N;
1695    end Unit_Declaration_Node;
1696
1697 end Sem_Aux;