gcc/ada/a-szuzti.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT RUN-TIME COMPONENTS                         --
   4 --                                                                          --
   5 --             ADA.STRINGS.WIDE_WIDE_UNBOUNDED.WIDE_WIDE_TEXT_IO            --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1997-2007, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 with Ada.Wide_Wide_Text_IO; use Ada.Wide_Wide_Text_IO;
  35
  36 package body Ada.Strings.Wide_Wide_Unbounded.Wide_Wide_Text_IO is
  37
  38    --------------
  39    -- Get_Line --
  40    --------------
  41
  42    function Get_Line return Unbounded_Wide_Wide_String is
  43       Buffer : Wide_Wide_String (1 .. 1000);
  44       Last   : Natural;
  45       Str1   : Wide_Wide_String_Access;
  46       Str2   : Wide_Wide_String_Access;
  47       Result : Unbounded_Wide_Wide_String;
  48
  49    begin
  50       Get_Line (Buffer, Last);
  51       Str1 := new Wide_Wide_String'(Buffer (1 .. Last));
  52       while Last = Buffer'Last loop
  53          Get_Line (Buffer, Last);
  54          Str2 := new Wide_Wide_String (1 .. Str1'Last + Last);
  55          Str2 (Str1'Range) := Str1.all;
  56          Str2 (Str1'Last + 1 .. Str2'Last) := Buffer (1 .. Last);
  57          Free (Str1);
  58          Str1 := Str2;
  59       end loop;
  60
  61       Result.Reference := Str1;
  62       Result.Last      := Str1'Length;
  63       return Result;
  64    end Get_Line;
  65
  66    function Get_Line
  67      (File : Ada.Wide_Wide_Text_IO.File_Type) return Unbounded_Wide_Wide_String
  68    is
  69       Buffer : Wide_Wide_String (1 .. 1000);
  70       Last   : Natural;
  71       Str1   : Wide_Wide_String_Access;
  72       Str2   : Wide_Wide_String_Access;
  73       Result : Unbounded_Wide_Wide_String;
  74
  75    begin
  76       Get_Line (File, Buffer, Last);
  77       Str1 := new Wide_Wide_String'(Buffer (1 .. Last));
  78
  79       while Last = Buffer'Last loop
  80          Get_Line (File, Buffer, Last);
  81          Str2 := new Wide_Wide_String (1 .. Str1'Last + Last);
  82          Str2 (Str1'Range) := Str1.all;
  83          Str2 (Str1'Last + 1 .. Str2'Last) := Buffer (1 .. Last);
  84          Free (Str1);
  85          Str1 := Str2;
  86       end loop;
  87
  88       Result.Reference := Str1;
  89       Result.Last      := Str1'Length;
  90       return Result;
  91    end Get_Line;
  92
  93    procedure Get_Line (Item : out Unbounded_Wide_Wide_String) is
  94    begin
  95       Get_Line (Current_Input, Item);
  96    end Get_Line;
  97
  98    procedure Get_Line
  99      (File : Ada.Wide_Wide_Text_IO.File_Type;
 100       Item : out Unbounded_Wide_Wide_String)
 101    is
 102    begin
 103       --  We are going to read into the string that is already there and
 104       --  allocated. Hopefully it is big enough now, if not, we will extend
 105       --  it in the usual manner using Realloc_For_Chunk.
 106
 107       --  Make sure we start with at least 80 characters
 108
 109       if Item.Reference'Last < 80 then
 110          Realloc_For_Chunk (Item, 80);
 111       end if;
 112
 113       --  Loop to read data, filling current string as far as possible.
 114       --  Item.Last holds the number of characters read so far.
 115
 116       Item.Last := 0;
 117       loop
 118          Get_Line
 119            (File,
 120             Item.Reference (Item.Last + 1 .. Item.Reference'Last),
 121             Item.Last);
 122
 123          --  If we hit the end of the line before the end of the buffer, then
 124          --  we are all done, and the result length is properly set.
 125
 126          if Item.Last < Item.Reference'Last then
 127             return;
 128          end if;
 129
 130          --  If not enough room, double it and keep reading
 131
 132          Realloc_For_Chunk (Item, Item.Last);
 133       end loop;
 134    end Get_Line;
 135
 136    ---------
 137    -- Put --
 138    ---------
 139
 140    procedure Put (U : Unbounded_Wide_Wide_String) is
 141    begin
 142       Put (U.Reference (1 .. U.Last));
 143    end Put;
 144
 145    procedure Put (File : File_Type; U : Unbounded_Wide_Wide_String) is
 146    begin
 147       Put (File, U.Reference (1 .. U.Last));
 148    end Put;
 149
 150    --------------
 151    -- Put_Line --
 152    --------------
 153
 154    procedure Put_Line (U : Unbounded_Wide_Wide_String) is
 155    begin
 156       Put_Line (U.Reference (1 .. U.Last));
 157    end Put_Line;
 158
 159    procedure Put_Line (File : File_Type; U : Unbounded_Wide_Wide_String) is
 160    begin
 161       Put_Line (File, U.Reference (1 .. U.Last));
 162    end Put_Line;
 163
 164 end Ada.Strings.Wide_Wide_Unbounded.Wide_Wide_Text_IO;