gcc/gdbinit.in

   1 define pr
   2 set debug_rtx ($)
   3 end
   4
   5 document pr
   6 Print the full structure of the rtx that is $.
   7 Works only when an inferior is executing.
   8 end
   9
  10 define prl
  11 set debug_rtx_list ($, debug_rtx_count)
  12 end
  13
  14 document prl
  15 Print the full structure of all rtx insns beginning at $.
  16 Works only when an inferior is executing.
  17 Uses variable debug_rtx_count to control number of insns printed:
  18   debug_rtx_count > 0: print from $ on.
  19   debug_rtx_count < 0: print a window around $.
  20
  21 There is also debug_rtx_find (rtx, uid) that will scan a list for UID and print
  22 it using debug_rtx_list. Usage example: set $foo=debug_rtx_find(first, 42)
  23 end
  24
  25 define pt
  26 set debug_tree ($)
  27 end
  28
  29 document pt
  30 Print the full structure of the tree that is $.
  31 Works only when an inferior is executing.
  32 end
  33
  34 define pct
  35 set debug_c_tree ($)
  36 end
  37
  38 document pct
  39 Print the tree that is $ in C syntax.
  40 Works only when an inferior is executing.
  41 end
  42
  43 define pgs
  44 set debug_generic_stmt ($)
  45 end
  46
  47 document pgs
  48 Print the statement that is $ in C syntax.
  49 Works only when an inferior is executing.
  50 end
  51
  52 define pge
  53 set debug_generic_expr ($)
  54 end
  55
  56 document pge
  57 Print the expression that is $ in C syntax.
  58 Works only when an inferior is executing.
  59 end
  60
  61 define ptc
  62 output (enum tree_code) $.common.code
  63 echo \n
  64 end
  65
  66 document ptc
  67 Print the tree-code of the tree node that is $.
  68 end
  69
  70 define pdn
  71 output $.decl_minimal.name->identifier.id.str
  72 echo \n
  73 end
  74
  75 document pdn
  76 Print the name of the decl-node that is $.
  77 end
  78
  79 define ptn
  80 output $.type.name->decl_minimal.name->identifier.id.str
  81 echo \n
  82 end
  83
  84 document ptn
  85 Print the name of the type-node that is $.
  86 end
  87
  88 define prc
  89 output (enum rtx_code) $.code
  90 echo \ (
  91 output $.mode
  92 echo )\n
  93 end
  94
  95 document prc
  96 Print the rtx-code and machine mode of the rtx that is $.
  97 end
  98
  99 define pi
 100 print $.u.fld[0].rt_rtx@7
 101 end
 102
 103 document pi
 104 Print the fields of an instruction that is $.
 105 end
 106
 107 define pbs
 108 set print_binding_stack ()
 109 end
 110
 111 document pbs
 112 In cc1plus, print the current binding stack, frame by frame, up to and
 113 including the global binding level.
 114 end
 115
 116 define pbb
 117 set dump_bb ($, stderr, 0)
 118 end
 119
 120 document pbb
 121 Dump the basic block that is in $, including rtx.
 122 end
 123
 124 define pbm
 125 set bitmap_print (stderr, $, "", "\n")
 126 end
 127
 128 document pbm
 129 Dump the bitmap that is in $ as a comma-separated list of numbers.
 130 end
 131
 132 # Put breakpoints at exit and fancy_abort in case abort is mapped
 133 # to either fprintf/exit or fancy_abort.
 134 b fancy_abort
 135
 136 # Put a breakpoint on internal_error to help with debugging ICEs.
 137 b internal_error
 138
 139 set complaints 0
 140 # Don't let abort actually run, as it will make
 141 # stdio stop working and therefore the `pr' command above as well.
 142 # Put this last because gcc does not reference it any more unless
 143 # USE_SYSTEM_ABORT is defined, so gdb may complain and bail out.
 144 b exit
 145 b abort