gcc/ada/a-ciorma.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --                      A D A . C O N T A I N E R S .                       --
   6 --             I N D E F I N I T E _ O R D E R E D _ M A P S                --
   7 --                                                                          --
   8 --                                 S p e c                                  --
   9 --                                                                          --
  10 --          Copyright (C) 2004-2006, Free Software Foundation, Inc.         --
  11 --                                                                          --
  12 -- This specification is derived from the Ada Reference Manual for use with --
  13 -- GNAT. The copyright notice above, and the license provisions that follow --
  14 -- apply solely to the  contents of the part following the private keyword. --
  15 --                                                                          --
  16 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  17 -- terms of the  GNU General Public License as published  by the Free Soft- --
  18 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  19 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  20 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  21 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  22 -- for  more details.  You should have  received  a copy of the GNU General --
  23 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  24 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  25 -- Boston, MA 02110-1301, USA.                                              --
  26 --                                                                          --
  27 -- As a special exception,  if other files  instantiate  generics from this --
  28 -- unit, or you link  this unit with other files  to produce an executable, --
  29 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  30 -- covered  by the  GNU  General  Public  License.  This exception does not --
  31 -- however invalidate  any other reasons why  the executable file  might be --
  32 -- covered by the  GNU Public License.                                      --
  33 --                                                                          --
  34 -- This unit was originally developed by Matthew J Heaney.                  --
  35 ------------------------------------------------------------------------------
  36
  37 with Ada.Containers.Red_Black_Trees;
  38 with Ada.Finalization;
  39 with Ada.Streams;
  40
  41 generic
  42    type Key_Type (<>) is private;
  43    type Element_Type (<>) is private;
  44
  45    with function "<" (Left, Right : Key_Type) return Boolean is <>;
  46    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  47
  48 package Ada.Containers.Indefinite_Ordered_Maps is
  49    pragma Preelaborate;
  50
  51    function Equivalent_Keys (Left, Right : Key_Type) return Boolean;
  52
  53    type Map is tagged private;
  54    pragma Preelaborable_Initialization (Map);
  55
  56    type Cursor is private;
  57    pragma Preelaborable_Initialization (Cursor);
  58
  59    Empty_Map : constant Map;
  60
  61    No_Element : constant Cursor;
  62
  63    function "=" (Left, Right : Map) return Boolean;
  64
  65    function Length (Container : Map) return Count_Type;
  66
  67    function Is_Empty (Container : Map) return Boolean;
  68
  69    procedure Clear (Container : in out Map);
  70
  71    function Key (Position : Cursor) return Key_Type;
  72
  73    function Element (Position : Cursor) return Element_Type;
  74
  75    procedure Replace_Element
  76      (Container : in out Map;
  77       Position  : Cursor;
  78       New_Item  : Element_Type);
  79
  80    procedure Query_Element
  81      (Position : Cursor;
  82       Process  : not null access procedure (Key     : Key_Type;
  83                                             Element : Element_Type));
  84
  85    procedure Update_Element
  86      (Container : in out Map;
  87       Position  : Cursor;
  88       Process   : not null access procedure (Key     : Key_Type;
  89                                              Element : in out Element_Type));
  90
  91    procedure Move (Target : in out Map; Source : in out Map);
  92
  93    procedure Insert
  94      (Container : in out Map;
  95       Key       : Key_Type;
  96       New_Item  : Element_Type;
  97       Position  : out Cursor;
  98       Inserted  : out Boolean);
  99
 100    procedure Insert
 101      (Container : in out Map;
 102       Key       : Key_Type;
 103       New_Item  : Element_Type);
 104
 105    procedure Include
 106      (Container : in out Map;
 107       Key       : Key_Type;
 108       New_Item  : Element_Type);
 109
 110    procedure Replace
 111      (Container : in out Map;
 112       Key       : Key_Type;
 113       New_Item  : Element_Type);
 114
 115    procedure Exclude (Container : in out Map; Key : Key_Type);
 116
 117    procedure Delete (Container : in out Map; Key : Key_Type);
 118
 119    procedure Delete (Container : in out Map; Position : in out Cursor);
 120
 121    procedure Delete_First (Container : in out Map);
 122
 123    procedure Delete_Last (Container : in out Map);
 124
 125    function First (Container : Map) return Cursor;
 126
 127    function First_Element (Container : Map) return Element_Type;
 128
 129    function First_Key (Container : Map) return Key_Type;
 130
 131    function Last (Container : Map) return Cursor;
 132
 133    function Last_Element (Container : Map) return Element_Type;
 134
 135    function Last_Key (Container : Map) return Key_Type;
 136
 137    function Next (Position : Cursor) return Cursor;
 138
 139    procedure Next (Position : in out Cursor);
 140
 141    function Previous (Position : Cursor) return Cursor;
 142
 143    procedure Previous (Position : in out Cursor);
 144
 145    function Find (Container : Map; Key : Key_Type) return Cursor;
 146
 147    function Element (Container : Map; Key : Key_Type) return Element_Type;
 148
 149    function Floor (Container : Map; Key : Key_Type) return Cursor;
 150
 151    function Ceiling (Container : Map; Key : Key_Type) return Cursor;
 152
 153    function Contains (Container : Map; Key : Key_Type) return Boolean;
 154
 155    function Has_Element (Position : Cursor) return Boolean;
 156
 157    function "<" (Left, Right : Cursor) return Boolean;
 158
 159    function ">" (Left, Right : Cursor) return Boolean;
 160
 161    function "<" (Left : Cursor; Right : Key_Type) return Boolean;
 162
 163    function ">" (Left : Cursor; Right : Key_Type) return Boolean;
 164
 165    function "<" (Left : Key_Type; Right : Cursor) return Boolean;
 166
 167    function ">" (Left : Key_Type; Right : Cursor) return Boolean;
 168
 169    procedure Iterate
 170      (Container : Map;
 171       Process   : not null access procedure (Position : Cursor));
 172
 173    procedure Reverse_Iterate
 174      (Container : Map;
 175       Process   : not null access procedure (Position : Cursor));
 176
 177 private
 178
 179    type Node_Type;
 180    type Node_Access is access Node_Type;
 181
 182    type Key_Access is access Key_Type;
 183    type Element_Access is access Element_Type;
 184
 185    type Node_Type is limited record
 186       Parent  : Node_Access;
 187       Left    : Node_Access;
 188       Right   : Node_Access;
 189       Color   : Red_Black_Trees.Color_Type := Red_Black_Trees.Red;
 190       Key     : Key_Access;
 191       Element : Element_Access;
 192    end record;
 193
 194    package Tree_Types is new Red_Black_Trees.Generic_Tree_Types
 195      (Node_Type,
 196       Node_Access);
 197
 198    type Map is new Ada.Finalization.Controlled with record
 199       Tree : Tree_Types.Tree_Type;
 200    end record;
 201
 202    procedure Adjust (Container : in out Map);
 203
 204    procedure Finalize (Container : in out Map) renames Clear;
 205
 206    use Red_Black_Trees;
 207    use Tree_Types;
 208    use Ada.Finalization;
 209    use Ada.Streams;
 210
 211    type Map_Access is access all Map;
 212    for Map_Access'Storage_Size use 0;
 213
 214    type Cursor is record
 215       Container : Map_Access;
 216       Node      : Node_Access;
 217    end record;
 218
 219    procedure Write
 220      (Stream : not null access Root_Stream_Type'Class;
 221       Item   : Cursor);
 222
 223    for Cursor'Write use Write;
 224
 225    procedure Read
 226      (Stream : not null access Root_Stream_Type'Class;
 227       Item   : out Cursor);
 228
 229    for Cursor'Read use Read;
 230
 231    No_Element : constant Cursor := Cursor'(null, null);
 232
 233    procedure Write
 234      (Stream    : not null access Root_Stream_Type'Class;
 235       Container : Map);
 236
 237    for Map'Write use Write;
 238
 239    procedure Read
 240      (Stream    : not null access Root_Stream_Type'Class;
 241       Container : out Map);
 242
 243    for Map'Read use Read;
 244
 245    Empty_Map : constant Map :=
 246                  (Controlled with Tree => (First  => null,
 247                                            Last   => null,
 248                                            Root   => null,
 249                                            Length => 0,
 250                                            Busy   => 0,
 251                                            Lock   => 0));
 252
 253 end Ada.Containers.Indefinite_Ordered_Maps;