gcc/ada/s-tpoben.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --               GNU ADA RUN-TIME LIBRARY (GNARL) COMPONENTS                --
   4 --                                                                          --
   5 --                 SYSTEM.TASKING.PROTECTED_OBJECTS.ENTRIES                 --
   6 --                                                                          --
   7 --                                  S p e c                                 --
   8 --                                                                          --
   9 --                                                                          --
  10 --          Copyright (C) 1992-2001, Free Software Foundation, Inc.         --
  11 --                                                                          --
  12 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  13 -- terms of the  GNU General Public License as published  by the Free Soft- --
  14 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  15 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  16 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  17 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  18 -- for  more details.  You should have  received  a copy of the GNU General --
  19 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  20 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  21 -- MA 02111-1307, USA.                                                      --
  22 --                                                                          --
  23 -- As a special exception,  if other files  instantiate  generics from this --
  24 -- unit, or you link  this unit with other files  to produce an executable, --
  25 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  26 -- covered  by the  GNU  General  Public  License.  This exception does not --
  27 -- however invalidate  any other reasons why  the executable file  might be --
  28 -- covered by the  GNU Public License.                                      --
  29 --                                                                          --
  30 -- GNARL was developed by the GNARL team at Florida State University. It is --
  31 -- now maintained by Ada Core Technologies Inc. in cooperation with Florida --
  32 -- State University (http://www.gnat.com).                                  --
  33 --                                                                          --
  34 ------------------------------------------------------------------------------
  35
  36 --  This package contains all the simple primitives related to
  37 --  Protected_Objects with entries (i.e init, lock, unlock).
  38 --  The handling of protected objects with no entries is done in
  39 --  System.Tasking.Protected_Objects, the complex routines for protected
  40 --  objects with entries in System.Tasking.Protected_Objects.Operations.
  41 --  The split between Entries and Operations is needed to break circular
  42 --  dependencies inside the run time.
  43
  44 --  Note: the compiler generates direct calls to this interface, via Rtsfind.
  45 --  Any changes to this interface may require corresponding compiler changes.
  46
  47 with Ada.Finalization;
  48 --  used for Limited_Controlled
  49
  50 with Unchecked_Conversion;
  51
  52 package System.Tasking.Protected_Objects.Entries is
  53    pragma Elaborate_Body;
  54
  55    subtype Positive_Protected_Entry_Index is
  56      Protected_Entry_Index range  1 .. Protected_Entry_Index'Last;
  57
  58    type Find_Body_Index_Access is access
  59      function
  60        (O : System.Address;
  61         E : Protected_Entry_Index)
  62         return Protected_Entry_Index;
  63
  64    type Protected_Entry_Body_Array is
  65      array (Positive_Protected_Entry_Index range <>) of Entry_Body;
  66    --  This is an array of the executable code for all entry bodies of
  67    --  a protected type.
  68
  69    type Protected_Entry_Body_Access is access all Protected_Entry_Body_Array;
  70
  71    type Protected_Entry_Queue_Array is
  72      array (Protected_Entry_Index range <>) of Entry_Queue;
  73
  74    --  This type contains the GNARL state of a protected object. The
  75    --  application-defined portion of the state (i.e. private objects)
  76    --  is maintained by the compiler-generated code.
  77    --  note that there is a simplified version of this type declared in
  78    --  System.Tasking.PO_Simple that handle the simple case (no entries).
  79
  80    type Protection_Entries (Num_Entries : Protected_Entry_Index) is new
  81      Ada.Finalization.Limited_Controlled
  82    with record
  83       L                 : aliased Task_Primitives.Lock;
  84       --  The underlying lock associated with a Protection_Entries.
  85       --  Note that you should never (un)lock Object.L directly, but instead
  86       --  use Lock_Entries/Unlock_Entries.
  87
  88       Compiler_Info     : System.Address;
  89       Call_In_Progress  : Entry_Call_Link;
  90       Ceiling           : System.Any_Priority;
  91       Old_Base_Priority : System.Any_Priority;
  92       Pending_Action    : Boolean;
  93       --  Flag indicating that priority has been dipped temporarily
  94       --  in order to avoid violating the priority ceiling of the lock
  95       --  associated with this protected object, in Lock_Server.
  96       --  The flag tells Unlock_Server or Unlock_And_Update_Server to
  97       --  restore the old priority to Old_Base_Priority. This is needed
  98       --  because of situations (bad language design?) where one
  99       --  needs to lock a PO but to do so would violate the priority
 100       --  ceiling.  For example, this can happen when an entry call
 101       --  has been requeued to a lower-priority object, and the caller
 102       --  then tries to cancel the call while its own priority is higher
 103       --  than the ceiling of the new PO.
 104       Finalized         : Boolean := False;
 105       --  Set to True by Finalize to make this routine idempotent.
 106
 107       Entry_Bodies      : Protected_Entry_Body_Access;
 108
 109       --  The following function maps the entry index in a call (which denotes
 110       --  the queue to the proper entry) into the body of the entry.
 111
 112       Find_Body_Index   : Find_Body_Index_Access;
 113       Entry_Queues      : Protected_Entry_Queue_Array (1 .. Num_Entries);
 114    end record;
 115    pragma Volatile (Protection_Entries);
 116
 117    --  No default initial values for this type, since call records
 118    --  will need to be re-initialized before every use.
 119
 120    type Protection_Entries_Access is access all Protection_Entries'Class;
 121    --  See comments in s-tassta.adb about the implicit call to Current_Master
 122    --  generated by this declaration.
 123
 124    function To_Protection_Entries is new Unchecked_Conversion
 125      (Protection_Access, Protection_Entries_Access);
 126
 127    function To_Address is
 128      new Unchecked_Conversion (Protection_Entries_Access, System.Address);
 129    function To_Protection is
 130      new Unchecked_Conversion (System.Address, Protection_Entries_Access);
 131
 132    function Has_Interrupt_Or_Attach_Handler
 133      (Object : Protection_Entries_Access) return Boolean;
 134    --  Returns True if an Interrupt_Handler or Attach_Handler pragma applies
 135    --  to the protected object. That is to say this primitive returns False for
 136    --  Protection, but is overriden to return True when interrupt handlers are
 137    --  declared so the check required by C.3.1(11) can be implemented in
 138    --  System.Tasking.Protected_Objects.Initialize_Protection.
 139
 140    procedure Initialize_Protection_Entries
 141      (Object           : Protection_Entries_Access;
 142       Ceiling_Priority : Integer;
 143       Compiler_Info    : System.Address;
 144       Entry_Bodies     : Protected_Entry_Body_Access;
 145       Find_Body_Index  : Find_Body_Index_Access);
 146    --  Initialize the Object parameter so that it can be used by the runtime
 147    --  to keep track of the runtime state of a protected object.
 148
 149    procedure Lock_Entries (Object : Protection_Entries_Access);
 150    --  Lock a protected object for write access. Upon return, the caller
 151    --  owns the lock to this object, and no other call to Lock or
 152    --  Lock_Read_Only with the same argument will return until the
 153    --  corresponding call to Unlock has been made by the caller.
 154    --  Program_Error is raised in case of ceiling violation.
 155
 156    procedure Lock_Entries
 157      (Object : Protection_Entries_Access; Ceiling_Violation : out Boolean);
 158    --  Same as above, but return the ceiling violation status instead of
 159    --  raising Program_Error.
 160
 161    procedure Lock_Read_Only_Entries (Object : Protection_Entries_Access);
 162    --  Lock a protected object for read access. Upon return, the caller
 163    --  owns the lock for read access, and no other calls to Lock with the
 164    --  same argument will return until the corresponding call to Unlock
 165    --  has been made by the caller. Other calls to Lock_Read_Only may (but
 166    --  need not) return before the call to Unlock, and the corresponding
 167    --  callers will also own the lock for read access.
 168    --
 169    --  Note: we are not currently using this interface, it is provided
 170    --  for possible future use. At the current time, everyone uses Lock
 171    --  for both read and write locks.
 172
 173    procedure Unlock_Entries (Object : Protection_Entries_Access);
 174    --  Relinquish ownership of the lock for the object represented by
 175    --  the Object parameter. If this ownership was for write access, or
 176    --  if it was for read access where there are no other read access
 177    --  locks outstanding, one (or more, in the case of Lock_Read_Only)
 178    --  of the tasks waiting on this lock (if any) will be given the
 179    --  lock and allowed to return from the Lock or Lock_Read_Only call.
 180
 181 private
 182
 183    procedure Finalize (Object : in out Protection_Entries);
 184    --  Clean up a Protection object; in particular, finalize the associated
 185    --  Lock object.
 186
 187 end System.Tasking.Protected_Objects.Entries;