libmpx/configure.ac

   1 # -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ([2.64])
   5 AC_INIT(package-unused, version-unused, libmpx)
   6
   7 # -------
   8 # Options
   9 # -------
  10 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  11 AC_ARG_ENABLE(version-specific-runtime-libs,
  12 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
  13 [case "$enableval" in
  14  yes) version_specific_libs=yes ;;
  15  no)  version_specific_libs=no ;;
  16  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  17  esac],
  18 [version_specific_libs=no])
  19 AC_MSG_RESULT($version_specific_libs)
  20
  21 # Do not delete or change the following two lines.  For why, see
  22 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  23 AC_CANONICAL_SYSTEM
  24 target_alias=${target_alias-$host_alias}
  25 AC_SUBST(target_alias)
  26 GCC_LIBSTDCXX_RAW_CXX_FLAGS
  27
  28 # See if supported.
  29 unset LIBMPX_SUPPORTED
  30 AC_MSG_CHECKING([for target support for Intel MPX runtime library])
  31 echo "int i[[sizeof (void *) == 4 ? 1 : -1]] = { __x86_64__ };" > conftest.c
  32 if AC_TRY_COMMAND([${CC} ${CFLAGS} -c -o conftest.o conftest.c 1>&AS_MESSAGE_LOG_FD])
  33 then
  34     LIBMPX_SUPPORTED=no
  35 else
  36     LIBMPX_SUPPORTED=yes
  37 fi
  38 rm -f conftest.o conftest.c
  39 AC_MSG_RESULT($LIBMPX_SUPPORTED)
  40 AM_CONDITIONAL(LIBMPX_SUPPORTED, [test "x$LIBMPX_SUPPORTED" = "xyes"])
  41
  42 link_libmpx="-lpthread"
  43 AC_SUBST(link_libmpx)
  44
  45 AM_INIT_AUTOMAKE(foreign no-dist no-dependencies)
  46 AM_ENABLE_MULTILIB(, ..)
  47 AM_MAINTAINER_MODE
  48
  49 AC_GNU_SOURCE
  50 AC_CHECK_FUNCS([secure_getenv])
  51
  52 # Calculate toolexeclibdir
  53 # Also toolexecdir, though it's only used in toolexeclibdir
  54 case ${version_specific_libs} in
  55   yes)
  56     # Need the gcc compiler version to know where to install libraries
  57     # and header files if --enable-version-specific-runtime-libs option
  58     # is selected.
  59     toolexecdir='$(libdir)/gcc/$(target_alias)'
  60     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  61     ;;
  62   no)
  63     if test -n "$with_cross_host" &&
  64        test x"$with_cross_host" != x"no"; then
  65       # Install a library built with a cross compiler in tooldir, not libdir.
  66       toolexecdir='$(exec_prefix)/$(target_alias)'
  67       toolexeclibdir='$(toolexecdir)/lib'
  68     else
  69       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
  70       toolexeclibdir='$(libdir)'
  71     fi
  72     multi_os_directory=`$CC -print-multi-os-directory`
  73     case $multi_os_directory in
  74       .) ;; # Avoid trailing /.
  75       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
  76     esac
  77     ;;
  78 esac
  79 AC_SUBST(toolexecdir)
  80 AC_SUBST(toolexeclibdir)
  81
  82 # Check for programs.
  83 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  84 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  85 AC_PROG_CC
  86 AC_PROG_CXX
  87 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  88
  89 AM_PROG_CC_C_O
  90
  91 AC_SUBST(CFLAGS)
  92
  93 # Newer automakes demand CCAS and CCASFLAGS.
  94 : ${CCAS='$(CC)'}
  95 : ${CCASFLAGS='$(CFLAGS)'}
  96 AC_SUBST(CCAS)
  97 AC_SUBST(CCASFLAGS)
  98
  99 AC_CHECK_TOOL(AS, as)
 100 AC_CHECK_TOOL(AR, ar)
 101 AC_CHECK_TOOL(RANLIB, ranlib, :)
 102
 103 # Check we may build wrappers library
 104 echo "test:  bndmov %bnd0, %bnd1" > conftest.s
 105 if AC_TRY_COMMAND([$AS -o conftest.o conftest.s 1>&AS_MESSAGE_LOG_FD])
 106 then
 107     mpx_as=yes
 108 else
 109     mpx_as=no
 110     echo "configure: no MPX support fo as" >&AS_MESSAGE_LOG_FD
 111 fi
 112 rm -f conftest.o conftest.s
 113 AM_CONDITIONAL(MPX_AS_SUPPORTED, [test "x$mpx_as" = "xyes"])
 114
 115 # Configure libtool
 116 AC_LIBTOOL_DLOPEN
 117 AM_PROG_LIBTOOL
 118 AC_SUBST(enable_shared)
 119 AC_SUBST(enable_static)
 120
 121 XCFLAGS="-Wall -Wextra"
 122 AC_SUBST(XCFLAGS)
 123
 124 if test "${multilib}" = "yes"; then
 125   multilib_arg="--enable-multilib"
 126 else
 127   multilib_arg=
 128 fi
 129
 130 AC_CONFIG_FILES([Makefile libmpx.spec])
 131 AC_CONFIG_HEADERS(config.h)
 132 AC_CONFIG_FILES(AC_FOREACH([DIR], [mpxrt mpxwrap], [DIR/Makefile ]),
 133   [cat > vpsed$$ << \_EOF
 134 s!`test -f '$<' || echo '$(srcdir)/'`!!
 135 _EOF
 136    sed -f vpsed$$ $ac_file > tmp$$
 137    mv tmp$$ $ac_file
 138    rm vpsed$$
 139    echo 'MULTISUBDIR =' >> $ac_file
 140    ml_norecursion=yes
 141    . ${multi_basedir}/config-ml.in
 142    AS_UNSET([ml_norecursion])
 143 ])
 144
 145 AC_OUTPUT