libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.64)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 AC_CANONICAL_SYSTEM
  22 _GCC_TOPLEV_NONCANONICAL_BUILD
  23 _GCC_TOPLEV_NONCANONICAL_TARGET
  24
  25 AC_SUBST(target_noncanonical)
  26
  27 GCC_LIBSTDCXX_RAW_CXX_FLAGS
  28
  29 # This works around the fact that libtool configuration may change LD
  30 # for this particular configuration, but some shells, instead of
  31 # keeping the changes in LD private, export them just because LD is
  32 # exported.
  33 ORIGINAL_LD_FOR_MULTILIBS=$LD
  34
  35 AC_PROG_LN_S
  36
  37 # This works around an automake problem.
  38 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  39 AC_SUBST(mkinstalldirs)
  40
  41 AC_ARG_WITH(cross-host,
  42   AS_HELP_STRING([--with-cross-host=HOST],
  43                  [configure with a cross compiler from HOST]))
  44
  45 AC_ARG_WITH(newlib,
  46   AS_HELP_STRING([--with-newlib],
  47                  [configure with newlib]))
  48
  49 AC_ARG_ENABLE(version-specific-runtime-libs,
  50   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  51                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  52     [case "$enableval" in
  53       yes) version_specific_libs=yes ;;
  54       no)  version_specific_libs=no ;;
  55       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  56      esac],
  57     [version_specific_libs=no]
  58 )
  59
  60 AC_ARG_ENABLE(browser-plugin,
  61   AS_HELP_STRING([--enable-browser-plugin],
  62                  [build gcjwebplugin web browser plugin]),
  63     [case "$enableval" in
  64       yes) browser_plugin_enabled=yes ;;
  65       no)  browser_plugin_enabled=no ;;
  66       *)   AC_MSG_ERROR([Unknown argument to enable/disable browser plugin]);;
  67      esac],
  68     [browser_plugin_enabled=no]
  69 )
  70
  71 AC_ARG_ENABLE(gconf-peer,
  72   AS_HELP_STRING([--enable-gconf-peer],
  73                  [compile GConf native peers for util.preferences]),
  74     [case "$enableval" in
  75       yes) gconf_enabled=yes ;;
  76       no)  gconf_enabled=no ;;
  77       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
  78      esac],
  79     [gconf_enabled=no]
  80 )
  81
  82 AC_ARG_WITH([antlr-jar],
  83             [AS_HELP_STRING([--with-antlr-jar=file],[Use ANTLR from the specified jar file])],
  84             [
  85              ANTLR_JAR=$withval
  86             ],
  87             [
  88              ANTLR_JAR=
  89             ])
  90
  91 AC_MSG_CHECKING([for antlr.jar])
  92 if test "x$ANTLR_JAR" = x; then
  93     for antlr_lib_home in `ls -d /usr/local/share/antlr* 2> /dev/null` \
  94         /usr/share/antlr/lib /usr/share/java /usr/lib;
  95     do
  96         if test -f "$antlr_lib_home/antlr.jar"; then
  97             # FIXME: version check for antlr needed without using a VM
  98             ANTLR_JAR="$antlr_lib_home/antlr.jar"
  99             break
 100         fi
 101     done
 102     if test "x$ANTLR_JAR" = x; then
 103         AC_MSG_RESULT([not found])
 104     else
 105         AC_MSG_RESULT($ANTLR_JAR)
 106     fi
 107 else
 108     if test -f "${ANTLR_JAR}"; then
 109         AC_MSG_RESULT($ANTLR_JAR)
 110     else
 111         AC_MSG_ERROR([antlr jar file not found: $ANTLR_JAR])
 112     fi
 113 fi
 114 AC_SUBST(ANTLR_JAR)
 115
 116 AC_ARG_ENABLE([gjdoc],
 117               [AS_HELP_STRING(--disable-gjdoc,compile GJDoc (disabled by --disable-gjdoc) [default=yes])],
 118               [case "${enableval}" in
 119                 yes) BUILD_GJDOC=yes ;;
 120                 no) BUILD_GJDOC=no ;;
 121                 *) BUILD_GJDOC=yes ;;
 122               esac],
 123               [BUILD_GJDOC=maybe])
 124
 125 AC_MSG_CHECKING([whether to build gjdoc])
 126 if test "x$BUILD_GJDOC" = xmaybe; then
 127     if test -f "${ANTLR_JAR}"; then
 128         BUILD_GJDOC=yes
 129         AC_MSG_RESULT(yes)
 130     else
 131         BUILD_GJDOC=no
 132         AC_MSG_RESULT([no, antlr.jar not found])
 133     fi
 134 else
 135     AC_MSG_RESULT($BUILD_GJDOC)
 136 fi
 137 AM_CONDITIONAL(CREATE_GJDOC, test "x${BUILD_GJDOC}" = xyes)
 138
 139 AC_ARG_ENABLE(java-maintainer-mode,
 140         AS_HELP_STRING([--enable-java-maintainer-mode],
 141         [allow rebuilding of .class and .h files]))
 142 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
 143
 144 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
 145 GCC_NO_EXECUTABLES
 146
 147 # For libstdc++-v3, -fno-builtin must be present here so that a
 148 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
 149 # used in later tests.  This may not be necessary in libjava; I don't know.
 150 save_CXXFLAGS="$CXXFLAGS"
 151 CXXFLAGS="$CXXFLAGS -fno-builtin"
 152 AC_PROG_CC
 153 AC_PROG_CXX
 154 CXXFLAGS="$save_CXXFLAGS"
 155
 156 AM_INIT_AUTOMAKE([no-dist 1.9.0])
 157
 158 AC_CHECK_TOOL(AS, as)
 159 AC_CHECK_TOOL(LD, ld)
 160 AC_CHECK_TOOL(AR, ar)
 161 AC_CHECK_TOOL(RANLIB, ranlib, :)
 162 AC_CHECK_TOOL(DLLTOOL, dlltool, :)
 163 AC_PROG_AWK
 164 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 165 AC_PATH_PROG([ZIP], [zip], no)
 166 AC_PATH_PROG([UNZIP], [unzip], unzip)
 167
 168 # We need a jar that supports -@.  This is a GNU extension.
 169 if test "$JAR" != no; then
 170    rm -f config-test.jar
 171    echo $srcdir/configure.ac | $JAR -cf@ config-test.jar >/dev/null 2>&1
 172    if test -f config-test.jar; then
 173      rm -f config-test.jar
 174    else
 175      JAR=no
 176    fi
 177 fi
 178
 179 # Prefer the jar we found, but fall back to our jar script.
 180 if test "$JAR" = no; then
 181   if test "$ZIP" = no; then
 182     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 183   else
 184     # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 185     JAR=`pwd`/scripts/jar
 186   fi
 187 fi
 188
 189 AC_PROG_INSTALL
 190
 191 AM_MAINTAINER_MODE
 192
 193 AC_EXEEXT
 194
 195 # configure.host sets the following important variables
 196 #       libgcj_cflags    - host specific C compiler flags
 197 #       libgcj_cxxflags  - host specific C++ compiler flags
 198 #       libgcj_javaflags - host specific Java compiler flags
 199 #       libgcj_sublib_ltflags - host specific Libtool flags
 200 #       libgcj_sublib_core_extra_deps - host specific extra
 201 #                          dependencies for core sublib
 202 #       (these last two only used when building sublibs)
 203 # and a number of others; see the list at the start of the file.
 204
 205 libgcj_cflags=
 206 libgcj_cxxflags=
 207 libgcj_javaflags=
 208 libgcj_sublib_ltflags=
 209 libgcj_sublib_core_extra_deps=
 210
 211 . ${srcdir}/configure.host
 212
 213 ACX_PROG_LD_GNU_SYMBOLIC
 214 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
 215 if test -z "$libgcj_ld_symbolic"; then
 216   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
 217 fi
 218
 219 # for windows native targets enforce export of all symbols for shared libgcj.
 220 libgcj_ld_export_all=
 221 case "$host" in
 222       *mingw*)
 223         libgcj_ld_export_all=-Wl,--export-all-symbols
 224         ;;
 225       *)
 226         ;;
 227 esac
 228
 229 LIBGCJ_CFLAGS="${libgcj_cflags}"
 230 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 231 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 232 LIBGCJ_SUBLIB_LTFLAGS="${libgcj_sublib_ltflags}"
 233 LIBGCJ_SUBLIB_CORE_EXTRA_DEPS="${libgcj_sublib_core_extra_deps}"
 234 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 235 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
 236 LIBGCJ_LD_EXPORT_ALL="${libgcj_ld_export_all}"
 237 AC_SUBST(LIBGCJ_CFLAGS)
 238 AC_SUBST(LIBGCJ_CXXFLAGS)
 239 AC_SUBST(LIBGCJ_JAVAFLAGS)
 240 AC_SUBST(LIBGCJ_SUBLIB_LTFLAGS)
 241 AC_SUBST(LIBGCJ_SUBLIB_CORE_EXTRA_DEPS)
 242 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 243 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
 244 AC_SUBST(LIBGCJ_LD_EXPORT_ALL)
 245
 246 # Only use libltdl for non-newlib builds.
 247 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 248    AC_LTDL_SHLIBPATH
 249 fi
 250
 251 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 252
 253 # Possibly build libgcj as many sub-libraries.
 254 AC_ARG_ENABLE(libgcj-sublibs,
 255   AS_HELP_STRING([--enable-libgcj-sublibs],
 256                  [build libgcj as many sub-libraries]))
 257
 258 if test -z "$enable_libgcj_sublibs"; then
 259    enable_libgcj_sublibs=$enable_libgcj_sublibs_default
 260 fi
 261 AM_CONDITIONAL(BUILD_SUBLIBS, test "$enable_libgcj_sublibs" = yes)
 262 if test "$enable_libgcj_sublibs" = yes ; then
 263   # In theory we could make do with only one override and simply
 264   # tag "_bc" onto the end of it when we use it to generate the
 265   # spec, but that's an ugly thing to do when there are multiple
 266   # words in the string and you're relying on the ordering to
 267   # append the correct one.
 268   libgcj_spec_lgcj_override="-lgcj-noncore -lgcj"
 269   libgcj_spec_lgcj_bc_override="-lgcj-noncore -lgcj_bc"
 270 fi
 271
 272
 273 # See if the user has requested runtime debugging.
 274 LIBGCJDEBUG="disable"
 275 AC_SUBST(LIBGCJDEBUG)
 276 AC_ARG_ENABLE(libgcj-debug,
 277   AS_HELP_STRING([--enable-libgcj-debug],
 278                  [enable runtime debugging code]),
 279   [if test "$enable_libgcj_debug" = yes; then
 280     AC_DEFINE(__GCJ_DEBUG, 1, [Define this if you want runtime debugging enabled.])
 281     LIBGCJDEBUG="enable"
 282   fi])
 283
 284 AC_ARG_WITH([escher],
 285          AS_HELP_STRING([--with-escher=ABS.PATH],
 286                         [specify path to escher dir or JAR for X peers]))
 287 case "$with_escher" in
 288 "")
 289         use_escher=false
 290         ;;
 291 "no")
 292         use_escher=false
 293         ;;
 294 "yes")
 295         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 296         ;;
 297 *)
 298         use_escher=true
 299         ;;
 300 esac
 301
 302 # Determine which AWT peer libraries to build
 303 AC_ARG_ENABLE(java-awt,
 304   AS_HELP_STRING([--enable-java-awt],
 305                  [list of AWT peer implementations to be built]))
 306
 307 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 308 use_xlib_awt=""
 309 use_gtk_awt=""
 310 use_qt_awt=""
 311 use_x_awt=""
 312 # The default toolkit to use is the first one specified.
 313 TOOLKIT=
 314 AC_SUBST(TOOLKIT)
 315
 316 for peer in $peerlibs ; do
 317   case $peer in
 318     xlib)
 319       if test "$no_x" = yes; then
 320         echo "*** xlib peers requested but no X library available" 1>&2
 321         exit 1
 322       else
 323         use_xlib_awt="yes"
 324         if test -z "$TOOLKIT"; then
 325            TOOLKIT=gnu.awt.xlib.XToolkit
 326         fi
 327       fi
 328       ;;
 329     gtk)
 330       if test "$no_x" = yes; then
 331          echo "*** gtk peers requested but no X library available" 1>&2
 332          exit 1
 333       else
 334          use_gtk_awt=yes
 335          if test -z "$TOOLKIT"; then
 336             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 337          fi
 338       fi
 339       ;;
 340     qt)
 341       if test "$no_x" = yes; then
 342          # Perhaps we should admit the possibility of embedded Qt.
 343          echo "*** Qt peers requested but no X library available" 1>&2
 344          exit 1
 345       else
 346          use_qt_awt=yes
 347          if test -z "$TOOLKIT"; then
 348             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 349          fi
 350       fi
 351       ;;
 352     x)
 353       use_x_awt=yes
 354       if test -z "$TOOLKIT"; then
 355          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 356       fi
 357       ;;
 358     no)
 359       use_xlib_awt=
 360       use_gtk_awt=
 361       use_qt_awt=
 362       use_x_awt=
 363       break
 364       ;;
 365     *)
 366       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 367       exit 1
 368   esac
 369 done
 370
 371 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 372 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 373
 374 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 375
 376 expanded_prefix=$prefix
 377 if test "X$prefix" = XNONE; then
 378   expanded_prefix=${ac_default_prefix}
 379 fi
 380
 381 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$expanded_prefix", [Installation prefix])
 382
 383 # Create standard.omit based on decisions we just made.
 384 cp $srcdir/standard.omit.in standard.omit
 385 if test "$use_xlib_awt" != yes; then
 386    echo gnu/awt/xlib >> standard.omit
 387    echo gnu/gcj/xlib >> standard.omit
 388 fi
 389 if test "$use_x_awt" != yes; then
 390    echo gnu/java/awt/peer/x >> standard.omit
 391 fi
 392
 393 # Tools that need to be compiled against classpath's tools classes
 394 : > vm-tools-packages
 395 for package in gnu/gcj/tools/gc_analyze ; do
 396     echo $package >> standard.omit
 397     echo $package >> vm-tools-packages
 398 done
 399
 400 if test -z "${with_multisubdir}"; then
 401    builddotdot=.
 402 else
 403    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 404 fi
 405
 406 NATIVE=yes
 407
 408 # Which gcj and host gcj (for ecjx) do we use?
 409 which_gcj=default
 410 host_exeext=${ac_exeext}
 411 GCJ_FOR_ECJX='$(GCJ)'
 412 GCC_FOR_ECJX='$(CXX)'
 413 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 414 if test -n "${with_cross_host}"; then
 415   # We are being configured with a cross compiler. We can't
 416   # use ac_exeext, because that is for the target platform.
 417   NATIVE=no
 418   cross_host_exeext=
 419   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 420   GCC_FOR_ECJX="${with_cross_host}-gcc"
 421   case "${with_cross_host}" in
 422      *mingw* | *cygwin*)
 423          cross_host_exeext=.exe
 424      ;;
 425   esac
 426   host_exeext=${cross_host_exeext}
 427   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 428      if test x"$build_noncanonical" = x"$with_cross_host"; then
 429         # Ordinary cross (host!=target and host=build)
 430         which_gcj=built
 431      else
 432         # Canadian cross (host!=target and host!=build)
 433         which_gcj=cross
 434      fi
 435   else
 436      which_gcj=cross
 437   fi
 438 else
 439   # We are being configured with a native or crossed-native compiler
 440   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 441      if test x"$build" = x"$host"; then
 442         # True native build (host=target and host=build)
 443         which_gcj=built
 444      else
 445         # Crossed-native build (host=target and host!=build)
 446         which_gcj=cross
 447      fi
 448   else
 449      which_gcj=path
 450   fi
 451 fi
 452 libgcjdir=`${PWDCMD-pwd}`
 453 case $GCJ in
 454 *" -B"*)
 455   # Just in case there is a comma in the build dir, quote it for the
 456   # sed command below.
 457   case $libgcjdir in
 458   *[[,\\]]*) qlibgcjdir=`echo "$libgcjdir" | sed 's:[[,\\]]:\\&:g'`;;
 459   *) qlibgcjdir=$libgcjdir;;
 460   esac
 461   GCJ=`echo "$GCJ" | sed "s, -B, -B$qlibgcjdir/&,"`
 462   ;;
 463 *)
 464   GCJ=$GCJ" -B$libgcjdir/"
 465   ;;
 466 esac
 467 case "${which_gcj}" in
 468    built)
 469       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 470    ;;
 471    cross)
 472       if test "x${with_newlib}" = "xyes"; then
 473          # FIXME (comment): Why is this needed?
 474          LIBGCC_UNWIND_INCLUDE=
 475       fi
 476       GCJH='$(target_noncanonical)-gcjh'
 477    ;;
 478    path)
 479       GCJH=gcjh
 480    ;;
 481 esac
 482 JAVAC="$GCJ -C"
 483 export JAVAC
 484
 485 AC_SUBST(GCJ_FOR_ECJX)
 486 AC_SUBST(GCC_FOR_ECJX)
 487 AC_SUBST(GCJH)
 488 AC_SUBST(host_exeext)
 489
 490 # Create it, so that compile/link tests don't fail
 491 test -f libgcj.spec || touch libgcj.spec
 492
 493
 494
 495 # Set up to configure Classpath.
 496 # FIXME: no supported way to pass args in autoconf.
 497 # Disable tool wrappers to avoid ltdl.h configure check.
 498 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 499 ac_configure_args="$ac_configure_args --disable-load-library"
 500 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 501 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 502 dir1=`cd $srcdir && pwd`
 503 dir2=`pwd`
 504 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 505 ac_configure_args="$ac_configure_args --disable-core-jni"
 506 dnl FIXME?
 507 ac_configure_args="$ac_configure_args --disable-examples"
 508 ac_configure_args="$ac_configure_args --with-glibj=build"
 509 if test "$browser_plugin_enabled" != yes; then
 510   ac_configure_args="$ac_configure_args --disable-plugin"
 511 else
 512   ac_configure_args="$ac_configure_args --enable-plugin"
 513 fi
 514 if test "$gconf_enabled" != yes; then
 515   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 516   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 517 fi
 518 if test "$use_gtk_awt" != yes; then
 519   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 520 fi
 521 if test "$use_qt_awt" != yes; then
 522   ac_configure_args="$ac_configure_args --disable-qt-peer"
 523 else
 524   # We need this as qt is disabled by default in classpath.
 525   ac_configure_args="$ac_configure_args --enable-qt-peer"
 526 fi
 527 if test "$use_x_awt" != yes; then
 528   ac_configure_args="$ac_configure_args --without-escher"
 529 else
 530   # We need this as escher is disabled by default in classpath.
 531   if test "$use_escher" != true; then
 532     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 533   else
 534     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 535   fi
 536 fi
 537 if test "x$BUILD_GJDOC" = xno; then
 538   ac_configure_args="$ac_configure_args --disable-gjdoc"
 539 fi
 540 # -Werror causes unavoidable problems in code using alsa.
 541 ac_configure_args="$ac_configure_args --disable-regen-headers"
 542 ac_configure_args="$ac_configure_args --disable-Werror"
 543 dnl --with-gcj=$GCJ
 544 dnl --with-javah=$GCJH
 545 dnl gtk-cairo -- just export here...
 546 dnl --enable-regen-headers?
 547
 548 # Only use libltdl for non-newlib builds.
 549 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 550    AC_LIBLTDL_CONVENIENCE
 551    AC_LIBTOOL_DLOPEN
 552    DIRLTDL=libltdl
 553    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 554    # Sigh.  Libtool's macro doesn't do the right thing.
 555    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 556    # FIXME: this is a hack.
 557    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 558    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 559 fi
 560 AC_SUBST(INCLTDL)
 561 AC_SUBST(LIBLTDL)
 562 AC_SUBST(DIRLTDL)
 563 AC_PROG_LIBTOOL
 564 ACX_LT_HOST_FLAGS
 565 AM_PROG_GCJ
 566 AM_PROG_CC_C_O
 567
 568 AC_CONFIG_SUBDIRS(classpath libltdl)
 569
 570 # The -no-testsuite modules omit the test subdir.
 571 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 572
 573 # Should the runtime set system properties by examining the
 574 # environment variable GCJ_PROPERTIES?
 575 AC_ARG_ENABLE(getenv-properties,
 576   AS_HELP_STRING([--disable-getenv-properties],
 577                  [don't set system properties from GCJ_PROPERTIES]))
 578
 579 # Whether GCJ_PROPERTIES is used depends on the target.
 580 if test -z "$enable_getenv_properties"; then
 581    enable_getenv_properties=${enable_getenv_properties_default-yes}
 582 fi
 583 if test "$enable_getenv_properties" = no; then
 584    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 585      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 586 fi
 587
 588 # Whether we should use arguments to main()
 589 if test -z "$enable_main_args"; then
 590    enable_main_args=${enable_main_args_default-yes}
 591 fi
 592 if test "$enable_main_args" = no; then
 593    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 594 fi
 595
 596
 597 # Should we use hashtable-based synchronization?
 598 # Currently works only for Linux X86/ia64
 599 # Typically faster and more space-efficient
 600 AC_ARG_ENABLE(hash-synchronization,
 601   AS_HELP_STRING([--enable-hash-synchronization],
 602                  [use global hash table for monitor locks]))
 603
 604 if test -z "$enable_hash_synchronization"; then
 605    enable_hash_synchronization=$enable_hash_synchronization_default
 606 fi
 607
 608
 609 install_ecj_jar=no
 610 ECJ_BUILD_JAR=
 611 ECJ_JAR=
 612 AC_ARG_WITH(ecj-jar,
 613         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 614         [ECJ_JAR=$withval],
 615         [if test -f $multi_basedir/ecj.jar; then
 616            ECJ_BUILD_JAR=$multi_basedir/ecj.jar
 617            ECJ_JAR='$(jardir)/ecj.jar'
 618            install_ecj_jar=yes
 619          fi])
 620 AC_SUBST(ECJ_BUILD_JAR)
 621 AC_SUBST(ECJ_JAR)
 622 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 623 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 624
 625 AC_ARG_WITH(java-home,
 626   AS_HELP_STRING([--with-java-home=DIRECTORY],
 627                  [value of java.home system property]),
 628                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 629 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 630 AC_SUBST(JAVA_HOME)
 631
 632 suppress_libgcj_bc=no
 633 AC_ARG_ENABLE(libgcj-bc,
 634   AS_HELP_STRING([--enable-libgcj-bc],
 635                  [enable(default) or disable BC ABI for portions of libgcj]),
 636   [if test "$enable_libgcj_bc" = "no"; then
 637      suppress_libgcj_bc=yes
 638    fi])
 639 AM_CONDITIONAL(SUPPRESS_LIBGCJ_BC, test "$suppress_libgcj_bc" = "yes")
 640
 641 build_libgcj_reduced_reflection=no
 642 AC_ARG_ENABLE(reduced-reflection,
 643   AS_HELP_STRING([--enable-reduced-reflection],
 644                  [enable or disable(default) -freduced-reflection when building portions of libgcj]),
 645   [if test "$enable_reduced_reflection" = "yes"; then
 646      build_libgcj_reduced_reflection=yes
 647    fi])
 648 AM_CONDITIONAL(BUILD_LIBGCJ_REDUCED_REFLECTION, test "$build_libgcj_reduced_reflection" = "yes")
 649
 650 # What is the native OS API for MinGW?
 651 AC_ARG_WITH(win32-nlsapi,
 652   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 653                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 654 [case "${withval}" in
 655   ansi) with_win32_nlsapi=ansi ;;
 656   unicows) with_win32_nlsapi=unicows ;;
 657   unicode) with_win32_nlsapi=unicode ;;
 658   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 659 esac],[with_win32_nlsapi=ansi])
 660
 661 case "${with_win32_nlsapi}" in
 662   unicows | unicode)
 663     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 664       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 665     ;;
 666 esac
 667
 668 # configure.host sets slow_pthread_self if the synchronization code should
 669 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 670 if test "${slow_pthread_self}" = "yes"; then
 671   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 672     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 673 fi
 674
 675 # Check for gc debugging.  This option is handled both here and in the GC.
 676 AC_ARG_ENABLE(gc-debug,
 677    AS_HELP_STRING([--enable-gc-debug],
 678                   [include full support for pointer backtracing etc.]),
 679 [ if test "$enable_gc_debug" = "yes"; then
 680     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 681               [Define if we want to use debug calls into the garbage collector.])
 682   fi])
 683
 684 # See if the user has the interpreter included.
 685 AC_ARG_ENABLE(interpreter,
 686   AS_HELP_STRING([--enable-interpreter],
 687                  [enable interpreter]),
 688   [if test "$enable_interpreter" = yes; then
 689     # This can also be set in configure.host.
 690     libgcj_interpreter=yes
 691   elif test "$enable_interpreter" = no; then
 692     libgcj_interpreter=no
 693   fi])
 694
 695 if test "$libgcj_interpreter" = yes; then
 696    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 697 fi
 698 INTERPRETER="$libgcj_interpreter"
 699 AC_SUBST(INTERPRETER)
 700 AM_CONDITIONAL(INTERPRETER, test "$libgcj_interpreter" = yes)
 701
 702 AC_MSG_CHECKING([for exception model to use])
 703 AC_LANG_PUSH(C++)
 704 AC_ARG_ENABLE(sjlj-exceptions,
 705   AS_HELP_STRING([--enable-sjlj-exceptions],
 706                  [force use of builtin_setjmp for exceptions]),
 707 [:],
 708 [dnl Botheration.  Now we've got to detect the exception model.
 709 dnl Link tests against libgcc.a are problematic since -- at least
 710 dnl as of this writing -- we've not been given proper -L bits for
 711 dnl single-tree newlib and libgloss.
 712 dnl
 713 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 714 dnl conftest files before we got a change to grep them first.
 715 cat > conftest.$ac_ext << EOF
 716 [#]line __oline__ "configure"
 717 struct S { ~S(); };
 718 void bar();
 719 void foo()
 720 {
 721   S s;
 722   bar();
 723 }
 724 EOF
 725 old_CXXFLAGS="$CXXFLAGS"
 726 CXXFLAGS=-S
 727 if AC_TRY_EVAL(ac_compile); then
 728   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 729     enable_sjlj_exceptions=yes
 730   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 731     enable_sjlj_exceptions=no
 732   elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
 733     # ARM EH ABI.
 734     enable_sjlj_exceptions=no
 735   fi
 736 fi
 737 CXXFLAGS="$old_CXXFLAGS"
 738 rm -f conftest*])
 739 if test x$enable_sjlj_exceptions = xyes; then
 740   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 741         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 742   ac_exception_model_name=sjlj
 743 elif test x$enable_sjlj_exceptions = xno; then
 744   ac_exception_model_name="call frame"
 745 else
 746   AC_MSG_ERROR([unable to detect exception model])
 747 fi
 748 AC_LANG_POP(C++)
 749 AC_MSG_RESULT($ac_exception_model_name)
 750
 751 # If we are non using SJLJ exceptions, and this host does not have support
 752 # for unwinding from a signal handler, enable checked dereferences and divides.
 753 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 754   CHECKREFSPEC=-fcheck-references
 755   DIVIDESPEC=-fuse-divide-subroutine
 756   EXCEPTIONSPEC=
 757 fi
 758
 759 # See if the user wants to disable java.net.  This is the mildly
 760 # ugly way that we admit that target-side configuration sucks.
 761 AC_ARG_ENABLE(java-net,
 762   AS_HELP_STRING([--disable-java-net],
 763                  [disable java.net]))
 764
 765 # Whether java.net is built by default can depend on the target.
 766 if test -z "$enable_java_net"; then
 767    enable_java_net=${enable_java_net_default-yes}
 768 fi
 769 if test "$enable_java_net" = no; then
 770    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 771 fi
 772
 773 # See if the user wants to configure without libffi.  Some
 774 # architectures don't support it, and default values are set in
 775 # configure.host.
 776 AC_ARG_WITH(libffi,
 777   AS_HELP_STRING([--without-libffi],
 778                  [don't use libffi]),
 779   [:],
 780   [with_libffi=${with_libffi_default-yes}])
 781
 782 LIBFFI=
 783 LIBFFIINCS=
 784 if test "$with_libffi" != no; then
 785    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 786    LIBFFI=../libffi/libffi_convenience.la
 787    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 788 fi
 789 AC_SUBST(LIBFFI)
 790 AC_SUBST(LIBFFIINCS)
 791
 792 # See if the user wants to disable JVMPI support.
 793 AC_ARG_ENABLE(jvmpi,
 794   AS_HELP_STRING([--disable-jvmpi],
 795                  [disable JVMPI support]))
 796
 797 if test "$enable_jvmpi" != no; then
 798     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 799 fi
 800
 801 # If the target is an eCos system, use the appropriate eCos
 802 # I/O routines.
 803 # FIXME: this should not be a local option but a global target
 804 # system; at present there is no eCos target.
 805 TARGET_ECOS=${PROCESS-"no"}
 806 AC_ARG_WITH(ecos,
 807 [  --with-ecos             enable runtime eCos target support],
 808 TARGET_ECOS="$with_ecos"
 809 )
 810
 811 case "$TARGET_ECOS" in
 812    no) case "$host" in
 813       *mingw*)
 814             PLATFORM=Win32
 815             PLATFORMNET=Win32
 816             PLATFORMH=win32.h
 817         CHECK_FOR_BROKEN_MINGW_LD
 818       ;;
 819       *)
 820             PLATFORM=Posix
 821             PLATFORMNET=Posix
 822             PLATFORMH=posix.h
 823       ;;
 824       esac
 825       ;;
 826    *)
 827       PLATFORM=Ecos
 828       PLATFORMNET=NoNet
 829       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 830       PLATFORMH=posix.h
 831       ;;
 832 esac
 833 AC_SUBST(PLATFORM)
 834 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 835
 836 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 837                                       [Define if you have int32_t and uint32_t.]))
 838 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 839                                         [Define if you have int32_t and uint32_t.]))
 840 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 841                                           [Define if you have u_int32_t]))
 842 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 843                                            [Define if you have u_int32_t]))
 844
 845 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 846 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 847
 848 case "$host" in
 849   *-darwin*) DARWIN_CRT=true ;;
 850   *) DARWIN_CRT=false ;;
 851 esac
 852 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 853
 854 # This may not be defined in a non-ANS conformant embedded system.
 855 # FIXME: Should these case a runtime exception in that case?
 856 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 857                                   [Define is you have 'localtime' in <time.h>]))
 858
 859 # Create the subdirectory for natFile.cc, or the attempt
 860 # to create the link will fail.
 861 test -d java || mkdir java
 862 test -d java/io || mkdir java/io
 863 test -d gnu || mkdir gnu
 864 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 865
 866 # Likewise for natConcreteProcess.cc.
 867 test -d java/lang || mkdir java/lang
 868 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 869
 870 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 871 test -d java/net || mkdir java/net
 872 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 873 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 874
 875 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 876 test -d gnu/java || mkdir gnu/java
 877 test -d gnu/java/net || mkdir gnu/java/net
 878 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 879 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 880
 881 # Likewise for natVMPipe.cc and natVMSelector.cc.
 882 test -d gnu/java/nio || mkdir gnu/java/nio
 883 AC_CONFIG_LINKS(gnu/java/nio/natVMPipe.cc:gnu/java/nio/natVMPipe${PLATFORM}.cc)
 884 AC_CONFIG_LINKS(gnu/java/nio/natVMSelector.cc:gnu/java/nio/natVMSelector${PLATFORM}.cc)
 885
 886 # Likewise for natFileChannelImpl.cc
 887 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 888 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 889
 890 # Likewise for natVMSecureRandom.cc
 891 test -d gnu/java/security || mkdir gnu/java/security
 892 test -d gnu/java/security/jce || mkdir gnu/java/security/jce
 893 test -d gnu/java/security/jce/prng || mkdir gnu/java/security/jce/prng
 894 AC_CONFIG_LINKS(gnu/java/security/jce/prng/natVMSecureRandom.cc:gnu/java/security/jce/prng/natVMSecureRandom${FILE-${PLATFORM}}.cc)
 895
 896 case "${host}" in
 897     *mingw*)
 898       SYSTEMSPEC="-lgdi32 -lws2_32"
 899       if test "${with_win32_nlsapi}" = "unicows"; then
 900         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 901       fi
 902     ;;
 903     *-*-darwin[[912]]*)
 904       SYSTEMSPEC="%{!Zdynamiclib:%{!Zbundle:-allow_stack_execute}}"
 905     ;;
 906     *)
 907       SYSTEMSPEC=
 908     ;;
 909 esac
 910 AC_SUBST(SYSTEMSPEC)
 911
 912 AC_ARG_WITH(system-zlib,
 913   AS_HELP_STRING([--with-system-zlib],
 914                  [use installed libz]))
 915 ZLIBSPEC=
 916 AC_SUBST(ZLIBSPEC)
 917 ZLIBTESTSPEC=
 918 AC_SUBST(ZLIBTESTSPEC)
 919
 920 AC_PATH_XTRA
 921
 922 # FIXME: this should be _libs on some hosts.
 923 libsubdir=.libs
 924
 925 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 926
 927 LIBSTDCXXSPEC=
 928 # extra LD Flags which are required for targets
 929 case "${host}" in
 930 *-*-darwin[[0-7]].*)
 931     # For now we have to disable it on darwin[8-9] because it slows down
 932     # the linking phase. A possible bug in ld?
 933     # on Darwin -single_module speeds up loading of the dynamic libraries.
 934     extra_ldflags_libjava=-Wl,-single_module
 935     ;;
 936 arm*-*-linux-*)
 937     # Some of the ARM unwinder code is actually in libstdc++.  We
 938     # could in principle replicate it in libgcj, but it's better to
 939     # have a dependency on libstdc++.
 940     extra_ldflags='-L$(here)/../libstdc++-v3/src/.libs -lstdc++'
 941     LIBSTDCXXSPEC=-lstdc++
 942     LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -L`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -rpath `${PWDCMD-pwd}`/.libs:`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -lstdc++"
 943     ;;
 944 *-*-cygwin)
 945     extra_ldflags_libjava=-liconv
 946     ;;
 947 *-*-mingw*)
 948     extra_ldflags_libjava=-lws2_32
 949     ;;
 950 esac
 951
 952 LIBMATHSPEC=
 953 # extra LD Flags which are required for targets
 954 case "${host}" in
 955 *-*-darwin*)
 956      ;;
 957 *)
 958      LIBMATHSPEC=-lm
 959      ;;
 960 esac
 961
 962 # Check for --no-merge-exidx-entries, an ARM-specific linker option.
 963 AC_CACHE_CHECK([for --no-merge-exidx-entries], [libgcj_cv_exidx],
 964   [saved_ldflags="$LDFLAGS"
 965    LDFLAGS="${LDFLAGS} -Wl,--no-merge-exidx-entries"
 966    AC_LINK_IFELSE([int main(void){ return 0;} ],
 967                       [eval "libgcj_cv_exidx=yes"],
 968                       [eval "libgcj_cv_exidx=no"])
 969    LDFLAGS="${saved_ldflags}"]
 970 )
 971 if test "${libgcj_cv_exidx}" = "yes"; then
 972   SYSTEMSPEC="${SYSTEMSPEC} --no-merge-exidx-entries"
 973   extra_ldflags="${extra_ldflags} -Wl,--no-merge-exidx-entries"
 974 fi
 975
 976 AC_SUBST(extra_ldflags_libjava)
 977 AC_SUBST(extra_ldflags)
 978 AC_SUBST(LIBSTDCXXSPEC)
 979 AC_SUBST(LIBMATHSPEC)
 980
 981 AC_SUBST(LIBGCJTESTSPEC)
 982
 983 # Allow the GC to be disabled.  Can be useful when debugging.
 984 AC_MSG_CHECKING([for garbage collector to use])
 985 AC_ARG_ENABLE(java-gc,
 986   AS_HELP_STRING([--enable-java-gc=TYPE],
 987                  [choose garbage collector (default is boehm)]),
 988   [GC=$enableval],
 989   [GC=boehm])
 990 GCLIBS=
 991 GCINCS=
 992 GCDEPS=
 993 GCSPEC=
 994 JC1GCSPEC=
 995 GCTESTSPEC=
 996 case "$GC" in
 997  boehm)
 998     AC_MSG_RESULT(boehm)
 999     GCLIBS=../boehm-gc/libgcjgc_convenience.la
1000     JC1GCSPEC='-fuse-boehm-gc'
1001     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
1002     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
1003     GCOBJS=boehm.lo
1004     GCHDR=boehm-gc.h
1005     # The POSIX thread support needs to know this.
1006     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
1007     ;;
1008  no)
1009     AC_MSG_RESULT(none)
1010     GCHDR=no-gc.h
1011     ;;
1012  *)
1013     AC_MSG_ERROR([unrecognized collector "$GC"])
1014     ;;
1015 esac
1016 AC_SUBST(GCLIBS)
1017 AC_SUBST(GCINCS)
1018 AC_SUBST(GCDEPS)
1019 AC_SUBST(GCSPEC)
1020 AC_SUBST(JC1GCSPEC)
1021 AC_SUBST(GCTESTSPEC)
1022 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
1023 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
1024 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
1025
1026
1027 AC_MSG_CHECKING([for thread model used by GCC])
1028 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
1029 AC_MSG_RESULT([$THREADS])
1030
1031 case "$THREADS" in
1032  no | none | single)
1033     THREADS=none
1034     ;;
1035  aix | posix | pthreads)
1036     THREADS=posix
1037     case "$host" in
1038      *-*-linux*)
1039         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
1040         ;;
1041     esac
1042     ;;
1043  win32)
1044     ;;
1045  dce | vxworks)
1046     AC_MSG_ERROR(thread package $THREADS not yet supported)
1047     ;;
1048  *)
1049     AC_MSG_ERROR($THREADS is an unknown thread package)
1050     ;;
1051 esac
1052
1053 THREADCXXFLAGS=
1054 THREADLDFLAGS=
1055 THREADLIBS=
1056 THREADINCS=
1057 THREADDEPS=
1058 THREADH=
1059 THREADSPEC=
1060 THREADSTARTFILESPEC=
1061 case "$THREADS" in
1062  posix)
1063     case "$host" in
1064      *-*-cygwin*)
1065         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
1066         ;;
1067      *-*-freebsd[[34]].*)
1068         # Before FreeBSD 5, it didn't have -lpthread (or any library which
1069         # merely adds pthread_* functions) but it does have a -pthread switch
1070         # which is required at link-time to select -lc_r *instead* of -lc.
1071         THREADLDFLAGS=-pthread
1072         # Don't set THREADSPEC here as might be expected since -pthread is
1073         # not processed when found within a spec file, it must come from
1074         # the command line.  For now, the user must provide the -pthread
1075         # switch to link code compiled with gcj.  In future, consider adding
1076         # support for weak references to pthread_* functions ala gthr.h API.
1077         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
1078         ;;
1079      *-*-freebsd*)
1080         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
1081         # systems which support threads and -lpthread.
1082         THREADLDFLAGS=-pthread
1083         THREADSPEC=-lpthread
1084         ;;
1085      hppa*-hp-hpux*)
1086         THREADCXXFLAGS=-pthread
1087         # boehm-gc needs some functions from librt, so link that too.
1088         THREADLIBS='-lpthread -lrt'
1089         THREADSPEC='-lpthread -lrt'
1090         ;;
1091      *-*-solaris2.9)
1092         # Need libthread for TLS support.
1093         THREADLIBS='-lpthread -lthread'
1094         THREADSPEC='-lpthread -lthread'
1095         ;;
1096      *-*-darwin*)
1097         # Don't set THREADLIBS or THREADSPEC as Darwin already
1098         # provides pthread via libSystem.
1099         ;;
1100      *)
1101         THREADLIBS=-lpthread
1102         THREADSPEC=-lpthread
1103         ;;
1104     esac
1105     THREADH=posix-threads.h
1106     # MIT pthreads doesn't seem to have the mutexattr functions.
1107     # But for now we don't check for it.  We just assume you aren't
1108     # using MIT pthreads.
1109     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1110
1111     # If we're using the Boehm GC, then we happen to know that it
1112     # defines _REENTRANT, so we don't bother.  Eww.
1113     if test "$GC" != boehm; then
1114        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1115     fi
1116     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
1117     ;;
1118
1119  win32)
1120     THREADH=win32-threads.h
1121     THREADCXXFLAGS=-mthreads
1122     # We need thread-safe exception handling so _CRT_MT should be set to 1.
1123     # But we do not want the executables created to be dependent on
1124     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
1125     # exception handling contexts.  The following kludge achieves this effect
1126     # and causes a dummy __mingwthr_key_dtor() to be linked in from
1127     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
1128     # A workaround is to explicitly use -mthreads while linking Java programs.
1129     # See PR libgcj/28263.
1130     #
1131     # FIXME: In Java we are able to detect thread death at the end of
1132     # Thread.run() so we should be able to clean up the exception handling
1133     # contexts ourselves.
1134     case "$host" in
1135     *-w64-mingw*)
1136       ;;
1137     *)
1138       THREADSTARTFILESPEC='crtmt%O%s'
1139       ;;
1140     esac
1141     ;;
1142  none)
1143     THREADH=no-threads.h
1144     ;;
1145 esac
1146 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
1147 AC_SUBST(THREADLIBS)
1148 AC_SUBST(THREADINCS)
1149 AC_SUBST(THREADDEPS)
1150 AC_SUBST(THREADSPEC)
1151 AC_SUBST(THREADSTARTFILESPEC)
1152 AC_SUBST(THREADLDFLAGS)
1153 AC_SUBST(THREADCXXFLAGS)
1154 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
1155 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
1156 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
1157 if test "$enable_shared" != yes; then
1158   use_libgcj_bc=no
1159 fi
1160 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
1161
1162 if test -d sysdep; then true; else mkdir sysdep; fi
1163 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
1164 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
1165 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
1166
1167 LIBGCJ_SPEC_LGCJ=-lgcj
1168 LIBGCJ_SPEC_LGCJ_BC=-lgcj_bc
1169 if test x"$libgcj_spec_lgcj_override" != x ; then
1170   LIBGCJ_SPEC_LGCJ=$libgcj_spec_lgcj_override
1171 fi
1172 if test x"$libgcj_spec_lgcj_bc_override" != x ; then
1173   LIBGCJ_SPEC_LGCJ_BC=$libgcj_spec_lgcj_bc_override
1174 fi
1175 LIBGCJ_SPEC="%{s-bc-abi:} $LIBGCJ_SPEC_LGCJ"
1176 if test "$use_libgcj_bc" = yes; then
1177   LIBGCJ_SPEC="%{static|static-libgcj|!s-bc-abi:$LIBGCJ_SPEC_LGCJ;:$LIBGCJ_SPEC_LGCJ_BC}"
1178   LIBGCJ_BC_SPEC="%{findirect-dispatch:-fPIC}"
1179 fi
1180 AC_SUBST(LIBGCJ_SPEC)
1181 AC_SUBST(LIBGCJ_BC_SPEC)
1182
1183 HASH_SYNC_SPEC=
1184 # Hash synchronization is only useful with posix threads right now.
1185 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
1186    HASH_SYNC_SPEC=-fhash-synchronization
1187    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
1188 fi
1189 AC_SUBST(HASH_SYNC_SPEC)
1190
1191 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
1192
1193 # We're in the tree with libgcc, and need to include some of its headers.
1194 LIBGCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../libgcc'
1195
1196 if test "x${with_newlib}" = "xyes"; then
1197    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
1198    # may not work correctly, because the compiler may not be able to
1199    # link executables.
1200
1201    # We assume newlib.  This lets us hard-code the functions we know
1202    # we'll have.
1203    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
1204    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
1205    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
1206    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
1207    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
1208    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
1209    # This is only for POSIX threads.
1210    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1211
1212    # Assume we do not have getuid and friends.
1213    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
1214    PLATFORMNET=NoNet
1215 else
1216    AC_CHECK_FUNCS([strerror_r select fstat open fsync sleep opendir \
1217                    localtime_r getpwuid_r getcwd \
1218                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1219                    nl_langinfo setlocale \
1220                    inet_pton uname inet_ntoa \
1221                    getrlimit sigaction ftruncate mmap \
1222                    getifaddrs])
1223    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1224    AC_CHECK_HEADERS(unistd.h dlfcn.h sys/resource.h)
1225    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1226    AC_CHECK_LIB(dl, dladdr, [
1227        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1228        AC_CHECK_LIB(dld, dladdr, [
1229        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1230
1231    if test x"$cross_compiling" = x"no"; then
1232      AC_CHECK_FILES(/proc/self/exe, [
1233        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1234      AC_CHECK_FILES(/proc/self/maps, [
1235        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1,
1236          [Define if you have /proc/self/maps])])
1237    else
1238      case $host in
1239      *-linux*)
1240        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1241        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1, [Define if you have /proc/self/maps])
1242        ;;
1243      esac
1244    fi
1245
1246    AM_ICONV
1247    AM_LC_MESSAGES
1248    AC_STRUCT_TIMEZONE
1249    LDLIBICONV=`echo " $LIBICONV " | sed "s/${acl_cv_wl--Wl,}/ /g; s/,/ /g"`
1250    AC_SUBST([LDLIBICONV])
1251
1252    AC_CHECK_FUNCS(gethostbyname_r, [
1253      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1254        [Define if you have the 'gethostbyname_r' function.])
1255      # There are two different kinds of gethostbyname_r.
1256      # We look for the one that returns `int'.
1257      # Hopefully this check is robust enough.
1258      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1259        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1260
1261      case " $GCINCS " in
1262      *" -D_REENTRANT "*) ;;
1263      *)
1264         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1265         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1266         [libjava_cv_gethostbyname_r_needs_reentrant],
1267         [ AC_LANG_PUSH(C++)
1268           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1269             [[gethostbyname_r("", 0, 0);]])],
1270             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1271                 CPPFLAGS_SAVE="$CPPFLAGS"
1272                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1273                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1274                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1275                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1276                 CPPFLAGS="$CPPFLAGS_SAVE"
1277           ])
1278           AC_LANG_POP(C++)
1279         ])
1280         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1281           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1282         fi
1283      ;;
1284      esac
1285
1286      AC_CACHE_CHECK([for struct hostent_data],
1287         [libjava_cv_struct_hostent_data], [dnl
1288         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1289 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1290 # define _REENTRANT 1
1291 #endif
1292 #include <netdb.h>]], [[struct hostent_data data;]])],
1293           [libjava_cv_struct_hostent_data=yes],
1294           [libjava_cv_struct_hostent_data=no])])
1295      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1296        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1297          [Define if struct hostent_data is defined in netdb.h])
1298      fi
1299    ])
1300
1301    # FIXME: libjava source code expects to find a prototype for
1302    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1303    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1304    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1305    # linkage check is enough, yet C++ code requires proper prototypes.)
1306    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1307    AC_CHECK_FUNCS(gethostbyaddr_r, [
1308      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1309        [Define if you have the 'gethostbyaddr_r' function.])
1310      # There are two different kinds of gethostbyaddr_r.
1311      # We look for the one that returns `int'.
1312      # Hopefully this check is robust enough.
1313      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1314        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1315          [Define if gethostbyaddr_r returns 'int'.])])])])
1316
1317    AC_CHECK_FUNCS(gethostname, [
1318      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1319        [Define if you have the 'gethostname' function.])
1320      AC_EGREP_HEADER(gethostname, unistd.h, [
1321        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1322          [Define if gethostname is declared in <unistd.h>.])])])
1323
1324    AC_CHECK_FUNCS(usleep, [
1325      AC_EGREP_HEADER(usleep, unistd.h, [
1326        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1327           [Define if usleep is declared in <unistd.h>.])])])
1328
1329    # Look for these functions in the thread library, but only bother
1330    # if using POSIX threads.
1331    if test "$THREADS" = posix; then
1332       save_LIBS="$LIBS"
1333       LIBS="$LIBS $THREADLIBS"
1334
1335       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1336       # Solaris 7 the name librt is preferred.
1337       AC_CHECK_FUNCS(sched_yield, , [
1338         AC_CHECK_LIB(rt, sched_yield, [
1339           AC_DEFINE(HAVE_SCHED_YIELD)
1340           THREADLIBS="$THREADLIBS -lrt"
1341           THREADSPEC="$THREADSPEC -lrt"], [
1342           AC_CHECK_LIB(posix4, sched_yield, [
1343             AC_DEFINE(HAVE_SCHED_YIELD)
1344             THREADLIBS="$THREADLIBS -lposix4"
1345             THREADSPEC="$THREADSPEC -lposix4"])])])
1346
1347       AC_CHECK_LIB(rt, clock_gettime, [
1348          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1349          case "$THREADSPEC" in
1350            *-lrt*) ;;
1351            *)
1352              THREADSPEC="$THREADSPEC -lrt"
1353              THREADLIBS="$THREADLIBS -lrt"
1354              ;;
1355          esac])
1356
1357       LIBS="$save_LIBS"
1358
1359       # We can save a little space at runtime if the mutex has m_count
1360       # or __m_count.  This is a nice hack for Linux.
1361       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1362           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1363         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1364              [Define if pthread_mutex_t has m_count member.]), [
1365         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1366             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1367           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1368             [Define if pthread_mutex_t has __m_count member.]))])
1369    fi
1370
1371    # We require a way to get the time.
1372    time_found=no
1373    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1374    if test "$time_found" = no; then
1375       AC_MSG_ERROR([no function found to get the time])
1376    fi
1377
1378    AC_CHECK_FUNCS(memmove)
1379
1380    # We require memcpy.
1381    memcpy_found=no
1382    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1383    if test "$memcpy_found" = no; then
1384       AC_MSG_ERROR([memcpy is required])
1385    fi
1386    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1387    AC_CHECK_LIB(dl, dlopen, [
1388        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1389        AC_CHECK_LIB(dld, dlopen, [
1390        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1391
1392    # Some library-finding code we stole from Tcl.
1393    #--------------------------------------------------------------------
1394    #    Check for the existence of the -lsocket and -lnsl libraries.
1395    #    The order here is important, so that they end up in the right
1396    #    order in the command line generated by make.  Here are some
1397    #    special considerations:
1398    #    1. Use "connect" and "accept" to check for -lsocket, and
1399    #       "gethostbyname" to check for -lnsl.
1400    #    2. Use each function name only once:  can't redo a check because
1401    #       autoconf caches the results of the last check and won't redo it.
1402    #    3. Use -lnsl and -lsocket only if they supply procedures that
1403    #       aren't already present in the normal libraries.  This is because
1404    #       IRIX 5.2 has libraries, but they aren't needed and they're
1405    #       bogus:  they goof up name resolution if used.
1406    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1407    #       To get around this problem, check for both libraries together
1408    #       if -lsocket doesn't work by itself.
1409    #--------------------------------------------------------------------
1410
1411    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1412     [gcj_cv_lib_sockets=
1413      gcj_checkBoth=0
1414      unset ac_cv_func_connect
1415      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1416      if test "$gcj_checkSocket" = 1; then
1417          unset ac_cv_func_connect
1418          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1419                       gcj_checkBoth=1)
1420      fi
1421      if test "$gcj_checkBoth" = 1; then
1422          gcj_oldLibs=$LIBS
1423          LIBS="$LIBS -lsocket -lnsl"
1424          unset ac_cv_func_accept
1425          AC_CHECK_FUNC(accept,
1426                        [gcj_checkNsl=0
1427                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1428          unset ac_cv_func_accept
1429          LIBS=$gcj_oldLibs
1430      fi
1431      unset ac_cv_func_gethostbyname
1432      gcj_oldLibs=$LIBS
1433      LIBS="$LIBS $gcj_cv_lib_sockets"
1434      AC_CHECK_FUNC(gethostbyname, ,
1435                    [AC_CHECK_LIB(nsl, main,
1436                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1437      unset ac_cv_func_gethostbyname
1438      LIBS=$gcj_oldLIBS
1439    ])
1440    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1441
1442    if test "$with_system_zlib" = yes; then
1443       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1444    fi
1445
1446    # Test for Gtk stuff, if asked for.
1447    if test "$use_gtk_awt" = yes; then
1448       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1449       AC_SUBST(GTK_CFLAGS)
1450       AC_SUBST(GTK_LIBS)
1451
1452       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1453       AC_SUBST(GLIB_CFLAGS)
1454       AC_SUBST(GLIB_LIBS)
1455
1456       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1457       AC_SUBST(LIBART_CFLAGS)
1458       AC_SUBST(LIBART_LIBS)
1459
1460       # We require the XTest Extension to support java.awt.Robot.
1461       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1462                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1463                    [${X_LIBS}])
1464    fi
1465
1466    # On Solaris, and maybe other architectures, the Boehm collector
1467    # requires -ldl.
1468    if test "$GC" = boehm; then
1469       case "${host}" in
1470           *-*-darwin*)
1471             ;;
1472           *)
1473             AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1474             ;;
1475       esac
1476    fi
1477 fi
1478
1479 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1480 case $build in
1481     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1482     *)         CLASSPATH_SEPARATOR=':' ;;
1483 esac
1484 AC_SUBST(CLASSPATH_SEPARATOR)
1485
1486 # We must search the source tree for java.lang, since we still don't
1487 # have libgcj.jar nor java/lang/*.class
1488 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1489 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1490
1491 # Since some classes depend on this one, we need its source available
1492 # before we can do any GCJ compilation test :-(
1493 if test ! -f gnu/classpath/Configuration.java; then
1494   test -d gnu || mkdir gnu
1495   test -d gnu/classpath || mkdir gnu/classpath
1496   # Note that it is not crucial that all the values here be correct.
1497   sed -e "s,@prefix@,$expanded_prefix," \
1498       -e "s,@VERSION@,$VERSION," \
1499       -e "s,@LIBDEBUG@,false," \
1500       -e "s,@INIT_LOAD_LIBRARY@,false," \
1501       -e "s,@@,$LIBGCJDEBUG," \
1502       -e "s,@default_toolkit@,$TOOLKIT," \
1503       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1504       -e "s,@GTK_CAIRO_ENABLED@,false," \
1505       -e "s,@ECJ_JAR@,," \
1506       -e "s,@WANT_NATIVE_BIG_INTEGER@,false," \
1507         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1508         > gnu/classpath/Configuration.java
1509   # We do not want to redirect the output of the grep below to /dev/null,
1510   # but we add /dev/null to the input list so that grep will print the
1511   # filename of Configuration.java in case it finds any matches.
1512   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1513     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1514   fi
1515 fi
1516
1517 LT_AC_PROG_GCJ
1518
1519 # Now remove it.
1520 rm -f gnu/classpath/Configuration.java
1521
1522 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1523
1524 AC_CHECK_SIZEOF(void *)
1525
1526 AC_C_BIGENDIAN
1527
1528 ZLIBS=
1529 SYS_ZLIBS=
1530 ZINCS=
1531
1532 if test -z "$ZLIBSPEC"; then
1533    # Use zlib from the GCC tree.
1534    ZINCS='-I$(top_srcdir)/../zlib'
1535    ZLIBS=../zlib/libzgcj_convenience.la
1536 else
1537    # System's zlib.
1538    SYS_ZLIBS="$ZLIBSPEC"
1539 fi
1540 AC_SUBST(ZLIBS)
1541 AC_SUBST(SYS_ZLIBS)
1542 AC_SUBST(ZINCS)
1543 AC_SUBST(DIVIDESPEC)
1544 AC_SUBST(CHECKREFSPEC)
1545 AC_SUBST(EXCEPTIONSPEC)
1546 AC_SUBST(BACKTRACESPEC)
1547 AC_SUBST(IEEESPEC)
1548 AC_SUBST(ATOMICSPEC)
1549
1550 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1551 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1552 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1553 AM_CONDITIONAL(INSTALL_BINARIES, test -z "${with_multisubdir}")
1554 AC_SUBST(LIBGCC_UNWIND_INCLUDE)
1555
1556 # Process the option "--enable-version-specific-runtime-libs"
1557 # Calculate toolexeclibdir
1558 case ${version_specific_libs} in
1559   yes)
1560     # Need the gcc compiler version to know where to install libraries
1561     # and header files if --enable-version-specific-runtime-libs option
1562     # is selected.
1563     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1564     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1565     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1566     toolexeclibdir=$toolexecmainlibdir
1567     ;;
1568   no)
1569     if test -n "$with_cross_host" &&
1570        test x"$with_cross_host" != x"no"; then
1571       # Install a library built with a cross compiler in tooldir, not libdir.
1572       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1573       toolexecmainlibdir='$(toolexecdir)/lib'
1574     else
1575       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1576       toolexecmainlibdir='$(libdir)'
1577     fi
1578     multi_os_directory=`$CC -print-multi-os-directory`
1579     case $multi_os_directory in
1580       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1581       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1582     esac
1583     ;;
1584 esac
1585 AC_SUBST(toolexecdir)
1586 AC_SUBST(toolexecmainlibdir)
1587 AC_SUBST(toolexeclibdir)
1588
1589 # Determine gcj and libgcj version number.
1590 gcjversion=`cat "$srcdir/../gcc/BASE-VER"`
1591 libgcj_soversion=`awk -F: '/^[[^#]].*:/ { print $1 }' $srcdir/libtool-version`
1592 GCJVERSION=$gcjversion
1593 AC_SUBST(GCJVERSION)
1594 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1595
1596 # Determine where the standard .db file and GNU Classpath JNI
1597 # libraries are found.
1598 gcjsubdir=gcj-$gcjversion-$libgcj_soversion
1599 multi_os_directory=`$CC -print-multi-os-directory`
1600 case $multi_os_directory in
1601   .)
1602    dbexecdir='$(toolexeclibdir)/'$gcjsubdir # Avoid /.
1603    ;;
1604   *)
1605    dbexecdir='$(toolexeclibdir)/'$multi_os_directory/$gcjsubdir
1606    ;;
1607 esac
1608 AC_SUBST(dbexecdir)
1609 AC_SUBST(gcjsubdir)
1610
1611 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1612 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1613
1614 TL_AC_GXX_INCLUDE_DIR
1615
1616 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1617 # On that system, sys/ioctl.h will not include sys/filio.h unless
1618 # BSD_COMP is defined; just including sys/filio.h is simpler.
1619 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1620 # for now.  If you change this, you also must update natFile.cc.
1621 AC_CHECK_HEADERS([unistd.h sys/time.h sys/types.h fcntl.h \
1622                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1623                   sys/socket.h netinet/in.h arpa/inet.h netdb.h \
1624                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1625                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1626
1627 # sys/socket.h is a prerequisite for net/if.h on Solaris.
1628 AC_CHECK_HEADERS(net/if.h, [], [], [
1629 #ifdef HAVE_SYS_SOCKET_H
1630 #include <sys/socket.h>
1631 #endif
1632 ])
1633
1634 AC_CHECK_HEADERS(inttypes.h, [
1635     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1636     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1637 ])
1638
1639 AC_CHECK_TYPE([ssize_t], [int])
1640 AC_CHECK_TYPE([magic_t], [
1641     AC_DEFINE(HAVE_MAGIC_T, 1, [Define if magic.h declares magic_t])], [], [
1642 #ifdef HAVE_MAGIC_H
1643 #include <magic.h>
1644 #endif])
1645
1646 AC_MSG_CHECKING([for in_addr_t])
1647 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1648 #if STDC_HEADERS
1649 #include <stdlib.h>
1650 #include <stddef.h>
1651 #endif
1652 #if HAVE_NETINET_IN_H
1653 #include <netinet/in.h>
1654 #endif]], [[in_addr_t foo;]])],
1655   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1656      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1657    AC_MSG_RESULT(yes)],
1658   [AC_MSG_RESULT(no)])
1659
1660 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1661 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1662   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1663      [Define if struct ip_mreq is defined in netinet/in.h.])
1664    AC_MSG_RESULT(yes)],
1665   [AC_MSG_RESULT(no)])
1666
1667 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1668 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1669   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1670      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1671    AC_MSG_RESULT(yes)],
1672   [AC_MSG_RESULT(no)])
1673
1674 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1675 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1676   [AC_DEFINE(HAVE_INET6, 1,
1677      [Define if inet6 structures are defined in netinet/in.h.])
1678    AC_MSG_RESULT(yes)],
1679   [AC_MSG_RESULT(no)])
1680
1681 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1682 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1683 #include <sys/types.h>
1684 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1685   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1686    AC_MSG_RESULT(yes)],
1687   [AC_MSG_RESULT(no)])
1688
1689 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1690 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1691   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1692    AC_MSG_RESULT(yes)],
1693   [AC_MSG_RESULT(no)
1694    AC_MSG_CHECKING([for global timezone variable])
1695    dnl FIXME: we don't want a link check here because that won't work
1696    dnl when cross-compiling.  So instead we make an assumption that
1697    dnl the header file will mention timezone if it exists.
1698    dnl Don't find the win32 function timezone
1699    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1700      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1701       AC_MSG_RESULT(yes)],
1702      [AC_MSG_RESULT(no)
1703        AC_MSG_CHECKING([for global _timezone variable])
1704        dnl FIXME: As above, don't want link check
1705        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1706          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1707             [Define if your platform has the global _timezone variable.])
1708           AC_MSG_RESULT(yes)],
1709           [AC_MSG_RESULT(no)])])])
1710
1711 AC_CHECK_PROGS(PERL, perl, false)
1712
1713 SYSDEP_SOURCES=
1714 SIGNAL_HANDLER_AUX=
1715
1716 case "${host}" in
1717  *-*-solaris2*)
1718     SIGNAL_HANDLER=include/posix-signal.h
1719     ;;
1720  i?86-*-linux*)
1721     SIGNAL_HANDLER=include/i386-signal.h
1722     SIGNAL_HANDLER_AUX=include/x86_64-signal.h
1723     ;;
1724 # ia64-*)
1725 #    SYSDEP_SOURCES=sysdep/ia64.c
1726 #    test -d sysdep || mkdir sysdep
1727 #    ;;
1728  hppa*-*-linux*)
1729     SIGNAL_HANDLER=include/pa-signal.h
1730     ;;
1731  hppa*-hp-hpux*)
1732     SIGNAL_HANDLER=include/hppa-signal.h
1733     ;;
1734  ia64-*-linux*)
1735     SIGNAL_HANDLER=include/dwarf2-signal.h
1736     ;;
1737  powerpc*-*-linux*)
1738     SIGNAL_HANDLER=include/powerpc-signal.h
1739     ;;
1740  alpha*-*-linux*)
1741     SIGNAL_HANDLER=include/dwarf2-signal.h
1742     ;;
1743  s390*-*-linux*)
1744     SIGNAL_HANDLER=include/s390-signal.h
1745     ;;
1746  x86_64*-*-linux*)
1747     SIGNAL_HANDLER=include/x86_64-signal.h
1748     SIGNAL_HANDLER_AUX=include/i386-signal.h
1749     ;;
1750  sparc*-*-linux*)
1751     SIGNAL_HANDLER=include/dwarf2-signal.h
1752     ;;
1753  sh*-*-linux*)
1754     SIGNAL_HANDLER=include/sh-signal.h
1755     ;;
1756  *mingw*)
1757     SIGNAL_HANDLER=include/win32-signal.h
1758     ;;
1759  mips*-*-linux*)
1760     SIGNAL_HANDLER=include/mips-signal.h
1761     ;;
1762  m68*-*-linux*)
1763     SIGNAL_HANDLER=include/dwarf2-signal.h
1764     ;;
1765  powerpc*-*-darwin* | i?86-*-darwin[[912]]* | x86_64-*-darwin[[912]]*)
1766     SIGNAL_HANDLER=include/darwin-signal.h
1767     ;;
1768  powerpc*-*-aix*)
1769     SIGNAL_HANDLER=include/aix-signal.h
1770     ;;
1771  *)
1772     SIGNAL_HANDLER=include/default-signal.h
1773     ;;
1774 esac
1775
1776 # If we're using sjlj exceptions, forget what we just learned.
1777 if test "$enable_sjlj_exceptions" = yes; then
1778    SIGNAL_HANDLER=include/default-signal.h
1779    SIGNAL_HANDLER_AUX=
1780 fi
1781
1782 AC_SUBST(SYSDEP_SOURCES)
1783
1784 if test -z "$SIGNAL_HANDLER_AUX"; then
1785   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1786 fi
1787
1788 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1789                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1790
1791 if test "${multilib}" = "yes"; then
1792   multilib_arg="--enable-multilib"
1793 else
1794   multilib_arg=
1795 fi
1796
1797 # See if we support thread-local storage.
1798 GCC_CHECK_TLS
1799
1800 # For _Unwind_GetIPInfo.
1801 GCC_CHECK_UNWIND_GETIPINFO
1802
1803 # See if linker supports anonymous version scripts.
1804 AC_CACHE_CHECK([whether ld supports anonymous version scripts],
1805   [libjava_cv_anon_version_script],
1806   [AC_ARG_ENABLE(symvers,
1807      AS_HELP_STRING([--disable-symvers],
1808                     [disable symbol versioning for libjava]),
1809        [case "$enableval" in
1810          yes|gnu*) libjava_cv_anon_version_script=yes ;;
1811          no)  libjava_cv_anon_version_script=no ;;
1812          *)   AC_MSG_ERROR([Unknown argument to enable/disable symvers]);;
1813         esac],
1814        [libjava_cv_anon_version_script=yes]
1815    )
1816    if test x$libjava_cv_anon_version_script = xyes; then
1817      save_CFLAGS="$CFLAGS"; save_LDFLAGS="$LDFLAGS"
1818      CFLAGS="$CFLAGS -fPIC";
1819      LDFLAGS="$LDFLAGS -shared -Wl,--version-script,conftest.map"
1820      echo '{ global: globalsymb*; local: *; };' > conftest.map
1821      AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1822                  [libjava_cv_anon_version_script=gnu],
1823                  [libjava_cv_anon_version_script=no])
1824      if test x$libjava_cv_anon_version_script = xno; then
1825        case "$target_os" in
1826          solaris2*)
1827            LDFLAGS="$save_LDFLAGS"
1828            LDFLAGS="$LDFLAGS -shared -Wl,-M,conftest.map"
1829            # Sun ld doesn't understand wildcards here.
1830            echo '{ global: globalsymbol; local: *; };' > conftest.map
1831            AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1832                        [libjava_cv_anon_version_script=sun], [])
1833            ;;
1834        esac
1835      fi
1836      CFLAGS="$save_CFLAGS"; LDFLAGS="$save_LDFLAGS"
1837    fi
1838   ])
1839 AM_CONDITIONAL(ANONVERSCRIPT, test "$libjava_cv_anon_version_script" != no)
1840 AM_CONDITIONAL(ANONVERSCRIPT_GNU, test "$libjava_cv_anon_version_script" = gnu)
1841 AM_CONDITIONAL(ANONVERSCRIPT_SUN, test "$libjava_cv_anon_version_script" = sun)
1842
1843 # Check if linker supports static linking on a per library basis
1844 LD_START_STATIC_SPEC=
1845 LD_FINISH_STATIC_SPEC=
1846 if $LD --help 2>&1 | grep -- -call_shared >/dev/null 2>&1; then
1847   if $LD --help 2>&1 | grep -- -non_shared >/dev/null 2>&1; then
1848     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1849     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1850   fi
1851 fi
1852 AC_SUBST(LD_START_STATIC_SPEC)
1853 AC_SUBST(LD_FINISH_STATIC_SPEC)
1854
1855 here=`${PWDCMD-pwd}`
1856 AC_SUBST(here)
1857
1858 # We get this from the environment.
1859 AC_SUBST(GCJFLAGS)
1860
1861 default_python_dir="/share/gcc-`cat ${srcdir}/../gcc/BASE-VER`/python/libjava"
1862 AC_ARG_WITH([python-dir],
1863             AS_HELP_STRING([--with-python-dir],
1864                            [the location to install Python modules. This path should NOT include the prefix.]),
1865             [with_python_dir=$withval], [with_python_dir="${default_python_dir}"])
1866
1867 # Needed for installing Python modules during make install.
1868 python_mod_dir="\${prefix}${with_python_dir}"
1869
1870 # Needed for substituting into aot-compile*
1871 python_mod_dir_expanded="${expanded_prefix}${with_python_dir}"
1872
1873 AC_MSG_RESULT(Python modules dir: ${python_mod_dir_expanded});
1874 AC_SUBST(python_mod_dir)
1875 AC_SUBST(python_mod_dir_expanded)
1876
1877 # needed for aot-compile-rpm
1878 MAKE=`which make`
1879 AC_SUBST(MAKE)
1880
1881 AC_ARG_ENABLE([aot-compile-rpm],
1882   [AS_HELP_STRING([--enable-aot-compile-rpm],
1883                  [enable installation of aot-compile-rpm [default=no]])],
1884   [case "${enableval}" in
1885     yes) AOT_RPM_ENABLED=yes ;;
1886     no)  AOT_RPM_ENABLED=no ;;
1887     *)   AC_MSG_ERROR([Unknown argument to enable/disable aot-compile-rpm]) ;;
1888   esac],
1889   [AOT_RPM_ENABLED=no]
1890 )
1891 AM_CONDITIONAL(INSTALL_AOT_RPM, test "x${AOT_RPM_ENABLED}" = xyes)
1892
1893 AC_ARG_ENABLE([java-home],
1894   [AS_HELP_STRING([--enable-java-home],
1895                  [create a standard JDK-style directory layout in the install tree [default=no]])],
1896   [case "${enableval}" in
1897     yes) JAVA_HOME_ENABLED=yes ;;
1898     no)  JAVA_HOME_ENABLED=no ;;
1899     *)   AC_MSG_ERROR([Unknown argument to enable/disable java-home]) ;;
1900   esac],
1901   [JAVA_HOME_ENABLED=no]
1902 )
1903 AM_CONDITIONAL(CREATE_JAVA_HOME, test "x${JAVA_HOME_ENABLED}" = xyes)
1904
1905 # Only do these checks if java-home above is enabled.
1906 if test "x${JAVA_HOME_ENABLED}" = xyes
1907 then
1908
1909   AC_ARG_WITH([gcc-suffix],
1910               AS_HELP_STRING([--with-gcc-suffix],
1911                              [the GCC tool suffix (defaults to empty string)]),
1912               [gcc_suffix=$withval], [gcc_suffix=""])
1913   AC_MSG_RESULT(GCC suffix: ${gcc_suffix})
1914   AC_SUBST(gcc_suffix)
1915
1916   AC_ARG_WITH([arch-directory],
1917               AS_HELP_STRING([--with-arch-directory],
1918                              [the arch directory under jre/lib (defaults to auto-detect)]),
1919               [host_cpu=$withval], [host_cpu=""])
1920
1921   AC_ARG_WITH([os-directory],
1922               AS_HELP_STRING([--with-os-directory],
1923                              [the os directory under include (defaults to auto-detect)]),
1924               [host_os=$withval], [host_os=""])
1925
1926   AC_ARG_WITH([origin-name],
1927               AS_HELP_STRING([--with-origin-name],
1928                              [the JPackage origin name of this package (default is gcj${gcc_suffix}]),
1929               [origin_name=$withval], [origin_name=gcj${gcc_suffix}])
1930   AC_MSG_RESULT(JPackage origin name: ${origin_name})
1931
1932   AC_ARG_WITH([arch-suffix],
1933               AS_HELP_STRING([--with-arch-suffix],
1934                              [the arch directory suffix (default is the empty string]),
1935               [arch_suffix=$withval], [arch_suffix=""])
1936   AC_MSG_RESULT(arch suffix: ${arch_suffix})
1937
1938   AC_ARG_WITH([jvm-root-dir],
1939               AS_HELP_STRING([--with-jvm-root-dir],
1940                              [where to install SDK (default is ${prefix}/lib/jvm)]),
1941               [jvm_root_dir=$withval], [jvm_root_dir="\${prefix}/lib/jvm"])
1942   AC_MSG_RESULT(JVM root installation directory: ${jvm_root_dir})
1943
1944   AC_ARG_WITH([jvm-jar-dir],
1945               AS_HELP_STRING([--with-jvm-jar-dir],
1946                                          [where to install jars (default is ${prefix}/lib/jvm-exports)]),
1947               [jvm_jar_dir=$withval], [jvm_jar_dir=\${prefix}/lib/jvm-exports])
1948   AC_MSG_RESULT(JAR root installation directory: ${jvm_jar_dir})
1949
1950   JAVA_VERSION=1.5.0
1951   BUILD_VERSION=0
1952   AC_SUBST(JAVA_VERSION)
1953   AC_SUBST(BUILD_VERSION)
1954   AC_MSG_RESULT(Java version: ${JAVA_VERSION})
1955
1956   jre_dir=jre
1957   jre_lnk=jre-${JAVA_VERSION}-${origin_name}
1958   sdk_lnk=java-${JAVA_VERSION}-${origin_name}
1959
1960   JVM_ROOT_DIR=${jvm_root_dir}
1961   AC_SUBST(JVM_ROOT_DIR)
1962   AC_MSG_RESULT(JVM ROOT directory: ${JVM_ROOT_DIR})
1963
1964   JVM_JAR_ROOT_DIR=${jvm_jar_dir}
1965   AC_SUBST(JVM_JAR_ROOT_DIR)
1966   AC_MSG_RESULT(JVM JAR ROOT directory: ${JVM_JAR_ROOT_DIR})
1967
1968   JVM_JAR_DIR=${jvm_jar_dir}
1969   AC_SUBST(JVM_JAR_DIR)
1970   AC_MSG_RESULT(JVM JAR directory: ${JVM_JAR_DIR})
1971
1972   JRE_DIR=${jre_dir}
1973   AC_SUBST(JRE_DIR)
1974
1975   JRE_LNK=${jre_lnk}
1976   AC_SUBST(JRE_LNK)
1977
1978   SDK_LNK=${sdk_lnk}
1979   AC_SUBST(SDK_LNK)
1980
1981   SDK_BIN_DIR=${jvm_root_dir}/bin
1982   AC_SUBST(SDK_BIN_DIR)
1983   AC_MSG_RESULT(SDK tools directory: ${SDK_BIN_DIR})
1984
1985   SDK_LIB_DIR=${jvm_root_dir}/lib
1986   AC_SUBST(SDK_LIB_DIR)
1987   AC_MSG_RESULT(SDK jar directory: ${SDK_LIB_DIR})
1988
1989   SDK_INCLUDE_DIR=${jvm_root_dir}/include
1990   AC_SUBST(SDK_INCLUDE_DIR)
1991   AC_MSG_RESULT(SDK include directory: ${SDK_INCLUDE_DIR})
1992
1993   JRE_BIN_DIR=${jvm_root_dir}/${jre_dir}/bin
1994   AC_SUBST(JRE_BIN_DIR)
1995   AC_MSG_RESULT(JRE tools directory: ${JRE_BIN_DIR})
1996
1997   JRE_LIB_DIR=${jvm_root_dir}/${jre_dir}/lib
1998   AC_SUBST(JRE_LIB_DIR)
1999   AC_MSG_RESULT(JRE lib directory: ${JRE_LIB_DIR})
2000
2001   # Find gcj prefix using gcj found in PATH.
2002   gcj_prefix=`which gcj${gcc_suffix} | sed "s%/bin/gcj${gcc_suffix}%%"`
2003
2004   # Where do the gcj binaries live?
2005   # For jhbuild based builds, they all live in a sibling of bin called
2006   # gcj-bin.  Check for gcj-bin first, and use bin otherwise.
2007   GCJ_BIN_DIR=`if test -d ${gcj_prefix}/gcj-bin; then echo ${gcj_prefix}/gcj-bin; else echo ${gcj_prefix}/bin; fi`
2008   AC_SUBST(GCJ_BIN_DIR)
2009   AC_MSG_RESULT(GCJ tools directory: ${GCJ_BIN_DIR})
2010
2011   AC_MSG_RESULT(host is ${host})
2012   if test "x${host_cpu}" = "x"
2013   then
2014     case ${host} in
2015       *-mingw* | *-cygwin*)
2016         host_cpu=x86;;
2017       i486-* | i586-* | i686-*)
2018         host_cpu=i386;;
2019       x86_64-*)
2020         host_cpu=amd64;;
2021       *)
2022         host_cpu=${host_cpu};;
2023     esac
2024   fi
2025   AC_MSG_RESULT(arch directory: ${host_cpu})
2026   CPU=${host_cpu}
2027   AC_SUBST(CPU)
2028
2029   if test "x${host_os}" = "x"
2030   then
2031     case ${host} in
2032       *-mingw* | *-cygwin*)
2033         host_os=win32;;
2034       *-linux*)
2035         host_os=linux;;
2036       *)
2037         host_os=${host_os};;
2038     esac
2039   fi
2040   echo os directory: ${host_os}
2041   OS=${host_os}
2042   AC_SUBST(OS)
2043
2044   # make an expanded $libdir, for substituting into
2045   # scripts (and other non-Makefile things).
2046   LIBDIR=$libdir
2047   if test "x${exec_prefix}" = "xNONE"
2048   then
2049       lib_exec_prefix=$expanded_prefix
2050   else
2051       lib_exec_prefix=$exec_prefix
2052   fi
2053   LIBDIR=`echo $libdir | sed "s:\\\${exec_prefix}:$lib_exec_prefix:g"`
2054   AC_SUBST(LIBDIR)
2055 fi
2056
2057 AC_CONFIG_FILES([
2058 Makefile
2059 libgcj.pc
2060 libgcj.spec
2061 libgcj-test.spec
2062 gcj/Makefile
2063 include/Makefile
2064 testsuite/Makefile
2065 contrib/aotcompile.py
2066 contrib/aot-compile
2067 contrib/aot-compile-rpm
2068 contrib/generate-cacerts.pl
2069 contrib/rebuild-gcj-db
2070 ])
2071
2072 if test ${multilib} = yes; then
2073   multilib_arg="--enable-multilib"
2074 else
2075   multilib_arg=
2076 fi
2077
2078 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
2079 AC_OUTPUT