configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019, 2022 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/ax_cxx_compile_stdcxx.m4)
  27 m4_include(config/gcc-plugin.m4)
  28 m4_include([libtool.m4])
  29 m4_include([ltoptions.m4])
  30 m4_include([ltsugar.m4])
  31 m4_include([ltversion.m4])
  32 m4_include([lt~obsolete.m4])
  33 m4_include([config/isl.m4])
  34
  35 AC_INIT(move-if-change)
  36 AC_DISABLE_OPTION_CHECKING
  37
  38 progname=$0
  39 # if PWD already has a value, it is probably wrong.
  40 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  41
  42 # Export original configure arguments for use by sub-configures.
  43 # Quote arguments with shell meta charatcers.
  44 TOPLEVEL_CONFIGURE_ARGUMENTS=
  45 set -- "$progname" "$@"
  46 for ac_arg
  47 do
  48   case "$ac_arg" in
  49   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  50     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  51     # if the argument is of the form -foo=baz, quote the baz part only
  52     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  53   *) ;;
  54   esac
  55   # Add the quoted argument to the list.
  56   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  57 done
  58 if test "$silent" = yes; then
  59   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  60 fi
  61 # Remove the initial space we just introduced and, as these will be
  62 # expanded by make, quote '$'.
  63 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  64 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  65
  66 # Find the build, host, and target systems.
  67 ACX_NONCANONICAL_BUILD
  68 ACX_NONCANONICAL_HOST
  69 ACX_NONCANONICAL_TARGET
  70
  71 dnl Autoconf 2.5x and later will set a default program prefix if
  72 dnl --target was used, even if it was the same as --host.  Disable
  73 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  74 dnl to take effect.
  75 test "$host_noncanonical" = "$target_noncanonical" &&
  76   test "$program_prefix$program_suffix$program_transform_name" = \
  77     NONENONEs,x,x, &&
  78   program_transform_name=s,y,y,
  79
  80 AC_CANONICAL_SYSTEM
  81 AC_ARG_PROGRAM
  82
  83 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  84 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  85
  86 # Get 'install' or 'install-sh' and its variants.
  87 AC_PROG_INSTALL
  88 ACX_PROG_LN
  89 AC_PROG_LN_S
  90 AC_PROG_SED
  91 AC_PROG_AWK
  92
  93 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  94
  95 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  96 # a relative path.
  97 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  98   INSTALL="${srcpwd}/install-sh -c"
  99 fi
 100
 101 # Set srcdir to "." if that's what it is.
 102 # This is important for multilib support.
 103 pwd=`${PWDCMD-pwd}`
 104 if test "${pwd}" = "${srcpwd}" ; then
 105   srcdir=.
 106 fi
 107
 108 topsrcdir=$srcpwd
 109
 110 extra_host_args=
 111
 112 ### To add a new directory to the tree, first choose whether it is a target
 113 ### or a host dependent tool.  Then put it into the appropriate list
 114 ### (library or tools, host or target), doing a dependency sort.
 115
 116 # Subdirs will be configured in the order listed in build_configdirs,
 117 # configdirs, or target_configdirs; see the serialization section below.
 118
 119 # Dependency sorting is only needed when *configuration* must be done in
 120 # a particular order.  In all cases a dependency should be specified in
 121 # the Makefile, whether or not it's implicitly specified here.
 122
 123 # Double entries in build_configdirs, configdirs, or target_configdirs may
 124 # cause circular dependencies and break everything horribly.
 125
 126 # these library is used by various programs built for the build
 127 # environment
 128 #
 129 build_libs="build-libiberty build-libcpp"
 130
 131 # these tools are built for the build environment
 132 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 133
 134 # these libraries are used by various programs built for the host environment
 135 #f
 136 host_libs="gettext libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libcody libdecnumber gmp mpfr mpc isl libiconv libctf libsframe"
 137
 138 # these tools are built for the host environment
 139 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 140 # know that we are building the simulator.
 141 # binutils, gas and ld appear in that order because it makes sense to run
 142 # "make check" in that particular order.
 143 # If --enable-gold is used, "gold" may replace "ld".
 144 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gm2tools gotools c++tools"
 145
 146 # these libraries are built for the target environment, and are built after
 147 # the host libraries and the host tools (which may be a cross compiler)
 148 # Note that libiberty is not a target library.
 149 target_libraries="target-libgcc \
 150                 target-libbacktrace \
 151                 target-libgloss \
 152                 target-newlib \
 153                 target-libgomp \
 154                 target-libatomic \
 155                 target-libitm \
 156                 target-libstdc++-v3 \
 157                 target-libsanitizer \
 158                 target-libvtv \
 159                 target-libssp \
 160                 target-libquadmath \
 161                 target-libgfortran \
 162                 target-libffi \
 163                 target-libobjc \
 164                 target-libada \
 165                 target-libgm2 \
 166                 target-libgo \
 167                 target-libphobos \
 168                 target-zlib"
 169
 170 # these tools are built using the target libraries, and are intended to
 171 # run only in the target environment
 172 #
 173 # note: any program that *uses* libraries that are in the "target_libraries"
 174 # list belongs in this list.
 175 #
 176 target_tools="target-rda"
 177
 178 ################################################################################
 179
 180 ## All tools belong in one of the four categories, and are assigned above
 181 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 182 ## is important because configure will choke if they ever get through.
 183 ## ${configdirs} is directories we build using the host tools.
 184 ## ${target_configdirs} is directories we build using the target tools.
 185 configdirs=`echo ${host_libs} ${host_tools}`
 186 target_configdirs=`echo ${target_libraries} ${target_tools}`
 187 build_configdirs=`echo ${build_libs} ${build_tools}`
 188
 189 m4_divert_text([PARSE_ARGS],
 190 [case $srcdir in
 191   *" "*)
 192 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 193     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 194 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 195     ;;
 196 esac
 197 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 198 ])
 199
 200 ################################################################################
 201
 202 srcname="gnu development package"
 203
 204 # This gets set non-empty for some net releases of packages.
 205 appdirs=""
 206
 207 # Define is_cross_compiler to save on calls to 'test'.
 208 is_cross_compiler=
 209 if test x"${host}" = x"${target}" ; then
 210   is_cross_compiler=no
 211 else
 212   is_cross_compiler=yes
 213 fi
 214
 215 # Find the build and target subdir names.
 216 GCC_TOPLEV_SUBDIRS
 217 # Be sure to cover against remnants of an in-tree build.
 218 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 219   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 220 Use a pristine source tree when building in a separate tree])
 221 fi
 222
 223 # Skipdirs are removed silently.
 224 skipdirs=
 225 # Noconfigdirs are removed loudly.
 226 noconfigdirs=""
 227
 228 use_gnu_ld=
 229 # Make sure we don't let GNU ld be added if we didn't want it.
 230 if test x$with_gnu_ld = xno ; then
 231   use_gnu_ld=no
 232   noconfigdirs="$noconfigdirs ld gold"
 233 fi
 234
 235 use_gnu_as=
 236 # Make sure we don't let GNU as be added if we didn't want it.
 237 if test x$with_gnu_as = xno ; then
 238   use_gnu_as=no
 239   noconfigdirs="$noconfigdirs gas"
 240 fi
 241
 242 use_included_zlib=
 243 AC_ARG_WITH(system-zlib,
 244 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 245 # Make sure we don't let ZLIB be added if we didn't want it.
 246 if test x$with_system_zlib = xyes ; then
 247   use_included_zlib=no
 248   noconfigdirs="$noconfigdirs zlib"
 249 fi
 250
 251 # Don't compile the bundled readline/libreadline.a if --with-system-readline
 252 # is provided.
 253 if test x$with_system_readline = xyes ; then
 254   noconfigdirs="$noconfigdirs readline"
 255 fi
 256
 257 AC_ARG_WITH(zstd,
 258 [AS_HELP_STRING([--with-zstd], [Support zstd compressed debug sections (default=auto)])])
 259
 260 # some tools are so dependent upon X11 that if we're not building with X,
 261 # it's not even worth trying to configure, much less build, that tool.
 262
 263 case ${with_x} in
 264   yes | "") ;; # the default value for this tree is that X11 is available
 265   no)
 266     skipdirs="${skipdirs} tk itcl libgui"
 267     # We won't be able to build gdbtk without X.
 268     enable_gdbtk=no
 269     ;;
 270   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 271 esac
 272
 273 # Some are only suitable for cross toolchains.
 274 # Remove these if host=target.
 275 cross_only="target-libgloss target-newlib target-opcodes"
 276
 277 case $is_cross_compiler in
 278   no) skipdirs="${skipdirs} ${cross_only}" ;;
 279 esac
 280
 281 # If both --with-headers and --with-libs are specified, default to
 282 # --without-newlib.
 283 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 284    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 285   if test x"${with_newlib}" = x ; then
 286     with_newlib=no
 287   fi
 288 fi
 289
 290 # Recognize --with-newlib/--without-newlib.
 291 case ${with_newlib} in
 292   no) skipdirs="${skipdirs} target-newlib" ;;
 293   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 294 esac
 295
 296 AC_ARG_ENABLE(as-accelerator-for,
 297 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 298                 [build as offload target compiler.
 299                 Specify offload host triple by ARG])])
 300
 301 AC_ARG_ENABLE(offload-targets,
 302 [AS_HELP_STRING([--enable-offload-targets=LIST],
 303                 [enable offloading to devices from comma-separated LIST of
 304                 TARGET[=DIR]. Use optional path to find offload target compiler
 305                 during the build])],
 306 [
 307   if test x"$enable_offload_targets" = x; then
 308     AC_MSG_ERROR([no offload targets specified])
 309   fi
 310 ], [enable_offload_targets=])
 311
 312 AC_ARG_ENABLE(offload-defaulted,
 313 [AS_HELP_STRING([--enable-offload-defaulted]
 314                 [If enabled, configured but not installed offload compilers and
 315                 libgomp plugins are silently ignored.  Useful for distribution
 316                 compilers where those are in separate optional packages.])],
 317 [enable_offload_defaulted=$enableval],
 318 [enable_offload_defaulted=])
 319
 320 # Handle --enable-gold, --enable-ld.
 321 # --disable-gold [--enable-ld]
 322 #     Build only ld.  Default option.
 323 # --enable-gold [--enable-ld]
 324 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 325 #     as "ld.bfd" and "ld".
 326 # --enable-gold=default [--enable-ld]
 327 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 328 #     install ld as "ld.bfd".
 329 # --enable-gold[=default] --disable-ld
 330 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 331 # --enable-gold --enable-ld=default
 332 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 333 #     and ld.bfd).
 334 #     In other words, ld is default
 335 # --enable-gold=default --enable-ld=default
 336 #     Error.
 337
 338 default_ld=
 339 AC_ARG_ENABLE(gold,
 340 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 341                 [build gold @<:@ARG={default,yes,no}@:>@])],
 342 ENABLE_GOLD=$enableval,
 343 ENABLE_GOLD=no)
 344 case "${ENABLE_GOLD}" in
 345   yes|default)
 346     # Check for ELF target.
 347     is_elf=no
 348     case "${target}" in
 349       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 350       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 351       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 352       | *-*-solaris2* | *-*-nto* | *-*-nacl* | *-*-haiku*)
 353         case "${target}" in
 354           *-*-linux*aout* | *-*-linux*oldld*)
 355             ;;
 356           *)
 357             is_elf=yes
 358             ;;
 359         esac
 360     esac
 361
 362     if test "$is_elf" = "yes"; then
 363       # Check for target supported by gold.
 364       case "${target}" in
 365         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 366         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-* | loongarch*-*-*)
 367           configdirs="$configdirs gold"
 368           if test x${ENABLE_GOLD} = xdefault; then
 369             default_ld=gold
 370           fi
 371           ENABLE_GOLD=yes
 372           ;;
 373       esac
 374     fi
 375     ;;
 376   no)
 377     ;;
 378   *)
 379     AC_MSG_ERROR([invalid --enable-gold argument])
 380     ;;
 381 esac
 382
 383 AC_ARG_ENABLE(ld,
 384 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 385                 [build ld @<:@ARG={default,yes,no}@:>@])],
 386 ENABLE_LD=$enableval,
 387 ENABLE_LD=yes)
 388
 389 case "${ENABLE_LD}" in
 390   default)
 391     if test x${default_ld} != x; then
 392       AC_MSG_ERROR([either gold or ld can be the default ld])
 393     fi
 394     ;;
 395   yes)
 396     ;;
 397   no)
 398     if test x${ENABLE_GOLD} != xyes; then
 399       AC_MSG_WARN([neither ld nor gold are enabled])
 400     fi
 401     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 402     ;;
 403   *)
 404     AC_MSG_ERROR([invalid --enable-ld argument])
 405     ;;
 406 esac
 407
 408 AC_ARG_ENABLE(gprofng,
 409 [AS_HELP_STRING([[--enable-gprofng[=ARG]]],
 410                 [build gprofng @<:@ARG={yes,no}@:>@])],
 411 enable_gprofng=$enableval,
 412 enable_gprofng=yes)
 413 if test "$enable_gprofng" = "yes"; then
 414   case "${target}" in
 415     x86_64-*-linux* | i?86-*-linux* | aarch64-*-linux*)
 416     configdirs="$configdirs gprofng"
 417     ;;
 418   esac
 419 fi
 420
 421
 422 # PR gas/19109
 423 # Decide the default method for compressing debug sections.
 424 # Provide a configure time option to override our default.
 425 AC_ARG_ENABLE(compressed_debug_sections,
 426 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 427                 [Enable compressed debug sections for gas, gold or ld by
 428                  default])],
 429 [
 430   if test x"$enable_compressed_debug_sections" = xyes; then
 431     AC_MSG_ERROR([no program with compressed debug sections specified])
 432   fi
 433 ], [enable_compressed_debug_sections=])
 434
 435 # Select default compression algorithm.
 436 AC_ARG_ENABLE(default_compressed_debug_sections_algorithm,
 437 [AS_HELP_STRING([--enable-default-compressed-debug-sections-algorithm={zlib,zstd}],
 438                 [Default compression algorithm for --enable-compressed-debug-sections.])],
 439 [], [default_compressed_debug_sections_algorithm=])
 440
 441 # Configure extra directories which are host specific
 442
 443 case "${host}" in
 444   *-cygwin*)
 445     configdirs="$configdirs libtermcap" ;;
 446 esac
 447
 448 # A target can indicate whether a language isn't supported for some reason.
 449 # Only spaces may be used in this macro; not newlines or tabs.
 450 unsupported_languages=
 451
 452 # Remove more programs from consideration, based on the host or
 453 # target this usually means that a port of the program doesn't
 454 # exist yet.
 455
 456 case "${host}" in
 457   i[[3456789]]86-*-msdosdjgpp*)
 458     noconfigdirs="$noconfigdirs tcl tk itcl"
 459     ;;
 460 esac
 461
 462 # Default to --disable-year2038 until we can handle differences between
 463 # projects that use gnulib (which understands year 2038) and projects that
 464 # do not (like BFD).
 465 AC_ARG_ENABLE(year2038,
 466 AS_HELP_STRING([--enable-year2038],
 467   [enable support for timestamps past the year 2038]),
 468 ENABLE_YEAR2038=$enableval,
 469 ENABLE_YEAR2038=no)
 470 enable_year2038=
 471 if test "${ENABLE_YEAR2038}" = "no" ; then
 472   enable_year2038=no
 473 fi
 474
 475 AC_ARG_ENABLE(libquadmath,
 476 AS_HELP_STRING([--disable-libquadmath],
 477   [do not build libquadmath directory]),
 478 ENABLE_LIBQUADMATH=$enableval,
 479 ENABLE_LIBQUADMATH=yes)
 480 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 481   noconfigdirs="$noconfigdirs target-libquadmath"
 482 fi
 483
 484
 485 AC_ARG_ENABLE(libquadmath-support,
 486 AS_HELP_STRING([--disable-libquadmath-support],
 487   [disable libquadmath support for Fortran]),
 488 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 489 ENABLE_LIBQUADMATH_SUPPORT=yes)
 490 enable_libquadmath_support=
 491 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 492   enable_libquadmath_support=no
 493 fi
 494
 495
 496 AC_ARG_ENABLE(libada,
 497 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 498 ENABLE_LIBADA=$enableval,
 499 ENABLE_LIBADA=yes)
 500 if test "${ENABLE_LIBADA}" != "yes" ; then
 501   noconfigdirs="$noconfigdirs gnattools"
 502 fi
 503
 504 AC_ARG_ENABLE(libgm2,
 505 [AS_HELP_STRING([--enable-libgm2], [build libgm2 directory])],
 506 ENABLE_LIBGM2=$enableval,
 507 ENABLE_LIBGM2=no)
 508 if test "${ENABLE_LIBGM2}" != "yes" ; then
 509   noconfigdirs="$noconfigdirs gm2tools"
 510 fi
 511
 512 AC_ARG_ENABLE(libssp,
 513 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 514 ENABLE_LIBSSP=$enableval,
 515 ENABLE_LIBSSP=yes)
 516
 517 AC_ARG_ENABLE(libstdcxx,
 518 AS_HELP_STRING([--disable-libstdcxx],
 519   [do not build libstdc++-v3 directory]),
 520 ENABLE_LIBSTDCXX=$enableval,
 521 ENABLE_LIBSTDCXX=default)
 522 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 523   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 524 fi]
 525
 526 # Enable libgomp by default on hosted POSIX systems, and a few others.
 527 if test x$enable_libgomp = x ; then
 528     case "${target}" in
 529     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 530         ;;
 531     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 532         ;;
 533     *-*-solaris2* | *-*-hpux11*)
 534         ;;
 535     *-*-darwin* | *-*-aix*)
 536         ;;
 537     nvptx*-*-* | amdgcn*-*-*)
 538         ;;
 539     *)
 540         noconfigdirs="$noconfigdirs target-libgomp"
 541         ;;
 542     esac
 543 fi
 544
 545 # Disable libatomic on unsupported systems.
 546 if test -d ${srcdir}/libatomic; then
 547     if test x$enable_libatomic = x; then
 548         AC_MSG_CHECKING([for libatomic support])
 549         if (srcdir=${srcdir}/libatomic; \
 550                 . ${srcdir}/configure.tgt; \
 551                 test -n "$UNSUPPORTED")
 552         then
 553             AC_MSG_RESULT([no])
 554             noconfigdirs="$noconfigdirs target-libatomic"
 555         else
 556             AC_MSG_RESULT([yes])
 557         fi
 558     fi
 559 fi
 560
 561 # Disable libitm on unsupported systems.
 562 if test -d ${srcdir}/libitm; then
 563     if test x$enable_libitm = x; then
 564         AC_MSG_CHECKING([for libitm support])
 565         if (srcdir=${srcdir}/libitm; \
 566                 . ${srcdir}/configure.tgt; \
 567                 test -n "$UNSUPPORTED")
 568         then
 569             AC_MSG_RESULT([no])
 570             noconfigdirs="$noconfigdirs target-libitm"
 571         else
 572             AC_MSG_RESULT([yes])
 573         fi
 574     fi
 575 fi
 576
 577 # Disable libsanitizer on unsupported systems.
 578 if test -d ${srcdir}/libsanitizer; then
 579     if test x$enable_libsanitizer = x; then
 580         AC_MSG_CHECKING([for libsanitizer support])
 581         if (srcdir=${srcdir}/libsanitizer; \
 582                 . ${srcdir}/configure.tgt; \
 583                 test -n "$UNSUPPORTED")
 584         then
 585             AC_MSG_RESULT([no])
 586             noconfigdirs="$noconfigdirs target-libsanitizer"
 587         else
 588             AC_MSG_RESULT([yes])
 589         fi
 590     fi
 591 fi
 592
 593 # Disable libvtv on unsupported systems.
 594 if test -d ${srcdir}/libvtv; then
 595     if test x$enable_libvtv = x; then
 596         AC_MSG_CHECKING([for libvtv support])
 597         if (srcdir=${srcdir}/libvtv; \
 598                 . ${srcdir}/configure.tgt; \
 599                 test "$VTV_SUPPORTED" != "yes")
 600         then
 601             AC_MSG_RESULT([no])
 602             noconfigdirs="$noconfigdirs target-libvtv"
 603         else
 604             AC_MSG_RESULT([yes])
 605         fi
 606     fi
 607 fi
 608
 609 # Disable libquadmath for some systems.
 610 case "${target}" in
 611   avr-*-*)
 612     noconfigdirs="$noconfigdirs target-libquadmath"
 613     ;;
 614   # libquadmath is unused on AIX and libquadmath build process use of
 615   # LD_LIBRARY_PATH can break AIX bootstrap.
 616   powerpc-*-aix* | rs6000-*-aix*)
 617     noconfigdirs="$noconfigdirs target-libquadmath"
 618     ;;
 619 esac
 620
 621 # Disable libssp for some systems.
 622 case "${target}" in
 623   avr-*-*)
 624     # No hosted I/O support.
 625     noconfigdirs="$noconfigdirs target-libssp"
 626     ;;
 627   bpf-*-*)
 628     noconfigdirs="$noconfigdirs target-libssp"
 629     ;;
 630   powerpc-*-aix* | rs6000-*-aix*)
 631     noconfigdirs="$noconfigdirs target-libssp"
 632     ;;
 633   pru-*-*)
 634     # No hosted I/O support.
 635     noconfigdirs="$noconfigdirs target-libssp"
 636     ;;
 637   rl78-*-*)
 638     # libssp uses a misaligned load to trigger a fault, but the RL78
 639     # doesn't fault for those - instead, it gives a build-time error
 640     # for explicit misaligned loads.
 641     noconfigdirs="$noconfigdirs target-libssp"
 642     ;;
 643   visium-*-*)
 644     # No hosted I/O support.
 645     noconfigdirs="$noconfigdirs target-libssp"
 646     ;;
 647 esac
 648
 649 # Disable libstdc++-v3 for some systems.
 650 # Allow user to override this if they pass --enable-libstdcxx
 651 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 652   case "${target}" in
 653     *-*-vxworks*)
 654       # VxWorks uses the Dinkumware C++ library.
 655       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 656       ;;
 657     amdgcn*-*-*)
 658       # Not ported/fails to build when using newlib.
 659       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 660       ;;
 661     arm*-wince-pe*)
 662       # the C++ libraries don't build on top of CE's C libraries
 663       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 664       ;;
 665     avr-*-*)
 666       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 667       ;;
 668     bpf-*-*)
 669       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 670       ;;
 671     ft32-*-*)
 672       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 673       ;;
 674   esac
 675 fi
 676
 677 # Disable C++ on systems where it is known to not work.
 678 # For testing, you can override this with --enable-languages=c++.
 679 case ,${enable_languages}, in
 680   *,c++,*)
 681     ;;
 682   *)
 683       case "${target}" in
 684         bpf-*-*)
 685           unsupported_languages="$unsupported_languages c++"
 686           ;;
 687       esac
 688       ;;
 689 esac
 690
 691 # Disable Objc on systems where it is known to not work.
 692 # For testing, you can override this with --enable-languages=objc.
 693 case ,${enable_languages}, in
 694   *,objc,*)
 695     ;;
 696   *)
 697       case "${target}" in
 698         bpf-*-*)
 699           unsupported_languages="$unsupported_languages objc"
 700           ;;
 701       esac
 702       ;;
 703 esac
 704
 705 # Disable D on systems where it is known to not work.
 706 # For testing, you can override this with --enable-languages=d.
 707 case ,${enable_languages}, in
 708   *,d,*)
 709     ;;
 710   *)
 711     case "${target}" in
 712       bpf-*-*)
 713         unsupported_languages="$unsupported_languages d"
 714         ;;
 715     esac
 716     ;;
 717 esac
 718
 719 # Disable libphobos on unsupported systems.
 720 # For testing, you can override this with --enable-libphobos.
 721 if test -d ${srcdir}/libphobos; then
 722     if test x$enable_libphobos = x; then
 723         AC_MSG_CHECKING([for libphobos support])
 724         if (srcdir=${srcdir}/libphobos; \
 725                 . ${srcdir}/configure.tgt; \
 726                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 727         then
 728             AC_MSG_RESULT([no])
 729             noconfigdirs="$noconfigdirs target-libphobos"
 730         else
 731             AC_MSG_RESULT([yes])
 732         fi
 733     fi
 734 fi
 735
 736 # Disable Fortran for some systems.
 737 case "${target}" in
 738   mmix-*-*)
 739     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 740     unsupported_languages="$unsupported_languages fortran"
 741     ;;
 742   bpf-*-*)
 743     unsupported_languages="$unsupported_languages fortran"
 744     ;;
 745 esac
 746
 747 # Disable libffi for some systems.
 748 case "${target}" in
 749   powerpc-*-darwin*)
 750     ;;
 751   i[[3456789]]86-*-darwin*)
 752     ;;
 753   x86_64-*-darwin[[912]]*)
 754     ;;
 755   *-*-darwin*)
 756     noconfigdirs="$noconfigdirs target-libffi"
 757     ;;
 758   *-*-netware*)
 759     noconfigdirs="$noconfigdirs target-libffi"
 760     ;;
 761   *-*-phoenix*)
 762     noconfigdirs="$noconfigdirs target-libffi"
 763     ;;
 764   *-*-rtems*)
 765     noconfigdirs="$noconfigdirs target-libffi"
 766     ;;
 767   *-*-tpf*)
 768     noconfigdirs="$noconfigdirs target-libffi"
 769     ;;
 770   *-*-uclinux*)
 771     noconfigdirs="$noconfigdirs target-libffi"
 772     ;;
 773   *-*-vxworks*)
 774     noconfigdirs="$noconfigdirs target-libffi"
 775     ;;
 776   aarch64*-*-freebsd*)
 777     noconfigdirs="$noconfigdirs target-libffi"
 778     ;;
 779   alpha*-*-*vms*)
 780     noconfigdirs="$noconfigdirs target-libffi"
 781     ;;
 782   arm*-*-freebsd*)
 783     noconfigdirs="$noconfigdirs target-libffi"
 784     ;;
 785   arm-wince-pe)
 786     noconfigdirs="$noconfigdirs target-libffi"
 787     ;;
 788   arm*-*-symbianelf*)
 789     noconfigdirs="$noconfigdirs target-libffi"
 790     ;;
 791   bpf-*-*)
 792     noconfigdirs="$noconfigdirs target-libffi"
 793     ;;
 794   cris-*-* | crisv32-*-*)
 795     case "${target}" in
 796       *-*-linux*)
 797         ;;
 798       *) # See PR46792 regarding target-libffi.
 799         noconfigdirs="$noconfigdirs target-libffi";;
 800     esac
 801     ;;
 802   hppa*64*-*-hpux*)
 803     noconfigdirs="$noconfigdirs target-libffi"
 804     ;;
 805   hppa*-hp-hpux11*)
 806     ;;
 807   hppa*-*-hpux*)
 808     noconfigdirs="$noconfigdirs target-libffi"
 809     ;;
 810   ia64*-*-*vms*)
 811     noconfigdirs="$noconfigdirs target-libffi"
 812     ;;
 813   i[[3456789]]86-w64-mingw*)
 814     noconfigdirs="$noconfigdirs target-libffi"
 815     ;;
 816   i[[3456789]]86-*-mingw*)
 817     noconfigdirs="$noconfigdirs target-libffi"
 818     ;;
 819   x86_64-*-mingw*)
 820     noconfigdirs="$noconfigdirs target-libffi"
 821     ;;
 822   mmix-*-*)
 823     noconfigdirs="$noconfigdirs target-libffi"
 824     ;;
 825   powerpc-*-aix*)
 826     ;;
 827   rs6000-*-aix*)
 828     ;;
 829   ft32-*-*)
 830     noconfigdirs="$noconfigdirs target-libffi"
 831     ;;
 832   *-*-lynxos*)
 833     noconfigdirs="$noconfigdirs target-libffi"
 834     ;;
 835 esac
 836
 837 # Disable the go frontend on systems where it is known to not work. Please keep
 838 # this in sync with contrib/config-list.mk.
 839 case "${target}" in
 840 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 841     unsupported_languages="$unsupported_languages go"
 842     ;;
 843 esac
 844
 845 # Only allow gdbserver on some systems.
 846 if test -d ${srcdir}/gdbserver; then
 847     if test x$enable_gdbserver = x; then
 848         AC_MSG_CHECKING([for gdbserver support])
 849         if (srcdir=${srcdir}/gdbserver; \
 850                 . ${srcdir}/configure.srv; \
 851                 test -n "$UNSUPPORTED")
 852         then
 853             AC_MSG_RESULT([no])
 854             noconfigdirs="$noconfigdirs gdbserver"
 855         else
 856             AC_MSG_RESULT([yes])
 857         fi
 858     fi
 859 fi
 860
 861 # Disable libgo for some systems where it is known to not work.
 862 # For testing, you can easily override this with --enable-libgo.
 863 if test x$enable_libgo = x; then
 864     case "${target}" in
 865     *-*-darwin*)
 866         # PR 46986
 867         noconfigdirs="$noconfigdirs target-libgo"
 868         ;;
 869     *-*-cygwin* | *-*-mingw*)
 870         noconfigdirs="$noconfigdirs target-libgo"
 871         ;;
 872     bpf-*-*)
 873         noconfigdirs="$noconfigdirs target-libgo"
 874         ;;
 875     esac
 876 fi
 877
 878 # Default libgloss CPU subdirectory.
 879 libgloss_dir="$target_cpu"
 880
 881 case "${target}" in
 882   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 883     libgloss_dir=wince
 884     ;;
 885   aarch64*-*-* )
 886     libgloss_dir=aarch64
 887     ;;
 888   arm*-*-*)
 889     libgloss_dir=arm
 890     ;;
 891   cris-*-* | crisv32-*-*)
 892     libgloss_dir=cris
 893     ;;
 894   hppa*-*-*)
 895     libgloss_dir=pa
 896     ;;
 897   i[[3456789]]86-*-*)
 898     libgloss_dir=i386
 899     ;;
 900   loongarch*-*-*)
 901     libgloss_dir=loongarch
 902     ;;
 903   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 904     libgloss_dir=m68hc11
 905     ;;
 906   m68*-*-* | fido-*-*)
 907     libgloss_dir=m68k
 908     ;;
 909   mips*-*-*)
 910     libgloss_dir=mips
 911     ;;
 912   powerpc*-*-*)
 913     libgloss_dir=rs6000
 914     ;;
 915   pru-*-*)
 916     libgloss_dir=pru
 917     ;;
 918   sparc*-*-*)
 919     libgloss_dir=sparc
 920     ;;
 921 esac
 922
 923 # Disable newlib and libgloss for various target OSes.
 924 case "${target}" in
 925   alpha*-dec-osf*)
 926     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 927     ;;
 928   i[[3456789]]86-*-linux*)
 929     # This section makes it possible to build newlib natively on linux.
 930     # If we are using a cross compiler then don't configure newlib.
 931     if test x${is_cross_compiler} != xno ; then
 932       noconfigdirs="$noconfigdirs target-newlib"
 933     fi
 934     noconfigdirs="$noconfigdirs target-libgloss"
 935     # If we are not using a cross compiler, do configure newlib.
 936     # Note however, that newlib will only be configured in this situation
 937     # if the --with-newlib option has been given, because otherwise
 938     # 'target-newlib' will appear in skipdirs.
 939     ;;
 940   i[[3456789]]86-*-rdos*)
 941     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 942     ;;
 943   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 944     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 945     ;;
 946   sparc-*-sunos4*)
 947     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 948     ;;
 949   bpf-*-*)
 950     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 951     ;;
 952   *-*-aix*)
 953     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 954     ;;
 955   *-*-beos*)
 956     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 957     ;;
 958   *-*-chorusos)
 959     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 960     ;;
 961   *-*-dragonfly*)
 962     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 963     ;;
 964   *-*-freebsd*)
 965     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 966     ;;
 967   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 968     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 969     ;;
 970   *-*-lynxos*)
 971     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 972     ;;
 973   *-*-mingw*)
 974     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 975     ;;
 976   *-*-netbsd*)
 977     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 978     ;;
 979   *-*-netware*)
 980     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 981     ;;
 982   *-*-tpf*)
 983     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 984     ;;
 985   *-*-uclinux*)
 986     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 987     ;;
 988   *-*-vxworks*)
 989     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 990     ;;
 991 esac
 992
 993 case "${target}" in
 994   *-*-chorusos)
 995     ;;
 996   aarch64-*-darwin*)
 997     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 998     noconfigdirs="$noconfigdirs sim target-rda"
 999     ;;
1000   amdgcn*-*-*)
1001     ;;
1002   arm-*-darwin*)
1003     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1004     noconfigdirs="$noconfigdirs sim target-rda"
1005     ;;
1006   powerpc-*-darwin*)
1007     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1008     noconfigdirs="$noconfigdirs sim target-rda"
1009     ;;
1010   i[[3456789]]86-*-darwin*)
1011     noconfigdirs="$noconfigdirs ld gprof"
1012     noconfigdirs="$noconfigdirs sim target-rda"
1013     ;;
1014   x86_64-*-darwin[[912]]*)
1015     noconfigdirs="$noconfigdirs ld gas gprof"
1016     noconfigdirs="$noconfigdirs sim target-rda"
1017     ;;
1018   *-*-darwin*)
1019     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1020     noconfigdirs="$noconfigdirs sim target-rda"
1021     ;;
1022   *-*-dragonfly*)
1023     ;;
1024   *-*-freebsd*)
1025     if test "x$with_gmp" = x \
1026         && ! test -d ${srcdir}/gmp \
1027         && test -f /usr/local/include/gmp.h; then
1028       with_gmp=/usr/local
1029     fi
1030     ;;
1031   *-*-kaos*)
1032     # Remove unsupported stuff on all kaOS configurations.
1033     noconfigdirs="$noconfigdirs target-libgloss"
1034     ;;
1035   *-*-netbsd*)
1036     ;;
1037   *-*-netware*)
1038     ;;
1039   *-*-phoenix*)
1040     noconfigdirs="$noconfigdirs target-libgloss"
1041     ;;
1042   *-*-rtems*)
1043     noconfigdirs="$noconfigdirs target-libgloss"
1044     ;;
1045     # The tpf target doesn't support gdb yet.
1046   *-*-tpf*)
1047     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1048     ;;
1049   *-*-uclinux*)
1050     noconfigdirs="$noconfigdirs target-rda"
1051     ;;
1052   *-*-vxworks*)
1053     ;;
1054   alpha*-dec-osf*)
1055     # ld works, but does not support shared libraries.
1056     # gas doesn't generate exception information.
1057     noconfigdirs="$noconfigdirs gas ld"
1058     ;;
1059   alpha*-*-*vms*)
1060     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1061     ;;
1062   alpha*-*-*)
1063     # newlib is not 64 bit ready
1064     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1065     ;;
1066   bpf-*-*)
1067     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1068     ;;
1069   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1070     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1071     ;;
1072   arc*-*-*)
1073     noconfigdirs="$noconfigdirs sim"
1074     ;;
1075   arm-*-pe*)
1076     noconfigdirs="$noconfigdirs target-libgloss"
1077     ;;
1078   arm-*-riscix*)
1079     noconfigdirs="$noconfigdirs ld target-libgloss"
1080     ;;
1081   avr-*-*)
1082     if test x${with_avrlibc} != xno; then
1083       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1084     fi
1085     ;;
1086   c4x-*-* | tic4x-*-*)
1087     noconfigdirs="$noconfigdirs target-libgloss"
1088     ;;
1089   tic54x-*-*)
1090     noconfigdirs="$noconfigdirs target-libgloss gdb"
1091     ;;
1092   d10v-*-*)
1093     noconfigdirs="$noconfigdirs target-libgloss"
1094     ;;
1095   d30v-*-*)
1096     noconfigdirs="$noconfigdirs gdb"
1097     ;;
1098   fr30-*-elf*)
1099     noconfigdirs="$noconfigdirs gdb"
1100     ;;
1101   ft32-*-*)
1102     noconfigdirs="$noconfigdirs target-rda gprof"
1103     ;;
1104   moxie-*-*)
1105     noconfigdirs="$noconfigdirs"
1106     ;;
1107   h8300*-*-*)
1108     noconfigdirs="$noconfigdirs target-libgloss"
1109     ;;
1110   h8500-*-*)
1111     noconfigdirs="$noconfigdirs target-libgloss"
1112     ;;
1113   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1114     ;;
1115   hppa*64*-*-hpux*)
1116     noconfigdirs="$noconfigdirs gdb"
1117     ;;
1118   hppa*-*-hpux11*)
1119     noconfigdirs="$noconfigdirs gdb ld"
1120     ;;
1121   hppa*64*-*-linux*)
1122     ;;
1123   hppa*-*-linux*)
1124     ;;
1125   hppa*-*-*elf* | \
1126   hppa*-*-lites* | \
1127   hppa*-*-openbsd* | \
1128   hppa*64*-*-*)
1129     ;;
1130   hppa*-*-pro*)
1131     ;;
1132   hppa*-*-*)
1133     noconfigdirs="$noconfigdirs ld"
1134     ;;
1135   i960-*-*)
1136     noconfigdirs="$noconfigdirs gdb"
1137     ;;
1138   ia64*-*-elf*)
1139     # No gdb support yet.
1140     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1141     ;;
1142   ia64*-**-hpux*)
1143     # No ld support yet.
1144     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1145     ;;
1146   ia64*-*-*vms*)
1147     # No ld support yet.
1148     noconfigdirs="$noconfigdirs libgui itcl ld"
1149     ;;
1150   i[[3456789]]86-w64-mingw*)
1151     ;;
1152   i[[3456789]]86-*-mingw*)
1153     target_configdirs="$target_configdirs target-winsup"
1154     ;;
1155   *-*-cygwin*)
1156     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1157     noconfigdirs="$noconfigdirs target-libgloss"
1158     # always build newlib if winsup directory is present.
1159     if test -d "$srcdir/winsup/cygwin"; then
1160       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1161     elif test -d "$srcdir/newlib"; then
1162       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1163     fi
1164     ;;
1165   i[[3456789]]86-*-pe)
1166     noconfigdirs="$noconfigdirs target-libgloss"
1167     ;;
1168   i[[3456789]]86-*-sco3.2v5*)
1169     # The linker does not yet know about weak symbols in COFF,
1170     # and is not configured to handle mixed ELF and COFF.
1171     noconfigdirs="$noconfigdirs ld target-libgloss"
1172     ;;
1173   i[[3456789]]86-*-sco*)
1174     noconfigdirs="$noconfigdirs gprof target-libgloss"
1175     ;;
1176   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1177     noconfigdirs="$noconfigdirs target-libgloss"
1178     ;;
1179   i[[3456789]]86-*-sysv4*)
1180     noconfigdirs="$noconfigdirs target-libgloss"
1181     ;;
1182   i[[3456789]]86-*-beos*)
1183     noconfigdirs="$noconfigdirs gdb"
1184     ;;
1185   i[[3456789]]86-*-rdos*)
1186     noconfigdirs="$noconfigdirs gdb"
1187     ;;
1188   mmix-*-*)
1189     noconfigdirs="$noconfigdirs gdb"
1190     ;;
1191   mt-*-*)
1192     noconfigdirs="$noconfigdirs sim"
1193     ;;
1194   nfp-*-*)
1195     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1196     noconfigdirs="$noconfigdirs $target_libraries"
1197     ;;
1198   pdp11-*-*)
1199     noconfigdirs="$noconfigdirs gdb gprof"
1200     ;;
1201   powerpc-*-aix*)
1202     # copied from rs6000-*-* entry
1203     noconfigdirs="$noconfigdirs gprof"
1204     ;;
1205   powerpc*-*-winnt* | powerpc*-*-pe*)
1206     target_configdirs="$target_configdirs target-winsup"
1207     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1208     # always build newlib.
1209     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1210     ;;
1211     # This is temporary until we can link against shared libraries
1212   powerpcle-*-solaris*)
1213     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1214     ;;
1215   powerpc-*-beos*)
1216     noconfigdirs="$noconfigdirs gdb"
1217     ;;
1218   rs6000-*-lynxos*)
1219     noconfigdirs="$noconfigdirs gprof"
1220     ;;
1221   rs6000-*-aix*)
1222     noconfigdirs="$noconfigdirs gprof"
1223     ;;
1224   rs6000-*-*)
1225     noconfigdirs="$noconfigdirs gprof"
1226     ;;
1227   m68k-apollo-*)
1228     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1229     ;;
1230   microblaze*)
1231     noconfigdirs="$noconfigdirs gprof"
1232     ;;
1233   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1234     if test x$with_newlib = xyes; then
1235       noconfigdirs="$noconfigdirs gprof"
1236     fi
1237     ;;
1238   mips*-*-irix5*)
1239     noconfigdirs="$noconfigdirs gprof target-libgloss"
1240     ;;
1241   mips*-*-irix6*)
1242     noconfigdirs="$noconfigdirs gprof target-libgloss"
1243     ;;
1244   mips*-*-bsd*)
1245     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1246     ;;
1247   mips*-*-linux*)
1248     ;;
1249   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1250   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1251     noconfigdirs="$noconfigdirs ld gas gprof"
1252     ;;
1253   mips*-*-*)
1254     noconfigdirs="$noconfigdirs gprof"
1255     ;;
1256   nvptx*-*-*)
1257     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1258     ;;
1259   sh-*-*)
1260     case "${target}" in
1261       sh*-*-elf)
1262          ;;
1263       *)
1264          noconfigdirs="$noconfigdirs target-libgloss" ;;
1265     esac
1266     ;;
1267   sparc-*-sunos4*)
1268     if test x${is_cross_compiler} = xno ; then
1269            use_gnu_ld=no
1270     fi
1271     ;;
1272   tic6x-*-*)
1273     noconfigdirs="$noconfigdirs sim"
1274     ;;
1275   tilepro*-*-* | tilegx*-*-*)
1276     noconfigdirs="$noconfigdirs sim"
1277     ;;
1278   v810-*-*)
1279     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1280     ;;
1281   vax-*-*)
1282     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1283     ;;
1284   wasm32-*-*)
1285     noconfigdirs="$noconfigdirs ld"
1286     ;;
1287   loongarch*-*-linux*)
1288     ;;
1289   loongarch*-*-*)
1290     noconfigdirs="$noconfigdirs gprof"
1291     ;;
1292 esac
1293
1294 # If we aren't building newlib, then don't build libgloss, since libgloss
1295 # depends upon some newlib header files.
1296 case "${noconfigdirs}" in
1297   *target-libgloss*) ;;
1298   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1299 esac
1300
1301 # Work in distributions that contain no compiler tools, like Autoconf.
1302 host_makefile_frag=/dev/null
1303 if test -d ${srcdir}/config ; then
1304 case "${host}" in
1305   i[[3456789]]86-*-msdosdjgpp*)
1306     host_makefile_frag="config/mh-djgpp"
1307     ;;
1308   *-cygwin*)
1309     ACX_CHECK_CYGWIN_CAT_WORKS
1310     host_makefile_frag="config/mh-cygwin"
1311     ;;
1312   *-mingw*)
1313     host_makefile_frag="config/mh-mingw"
1314     ;;
1315   alpha*-linux*)
1316     host_makefile_frag="config/mh-alpha-linux"
1317     ;;
1318   hppa*-hp-hpux*)
1319     host_makefile_frag="config/mh-pa"
1320     ;;
1321   hppa*-*)
1322     host_makefile_frag="config/mh-pa"
1323     ;;
1324   i?86-*-darwin[[89]]* | i?86-*-darwin1[[0-7]]* | powerpc*-*-darwin*)
1325     host_makefile_frag="config/mh-darwin"
1326     ;;
1327   powerpc-*-aix*)
1328     host_makefile_frag="config/mh-ppc-aix"
1329     ;;
1330   rs6000-*-aix*)
1331     host_makefile_frag="config/mh-ppc-aix"
1332     ;;
1333 esac
1334 fi
1335
1336 if test "${build}" != "${host}" ; then
1337   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1338   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1339   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1340   CPP_FOR_BUILD="${CPP_FOR_BUILD-\$(CC_FOR_BUILD) -E}"
1341   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1342   DSYMUTIL_FOR_BUILD=${DSYMUTIL_FOR_BUILD-dsymutil}
1343   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1344   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1345   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1346   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1347   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1348   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1349   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1350   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1351   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1352 else
1353   AR_FOR_BUILD="\$(AR)"
1354   AS_FOR_BUILD="\$(AS)"
1355   CC_FOR_BUILD="\$(CC)"
1356   CXX_FOR_BUILD="\$(CXX)"
1357   DSYMUTIL_FOR_BUILD="\$(DSYMUTIL)"
1358   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1359   GOC_FOR_BUILD="\$(GOC)"
1360   GDC_FOR_BUILD="\$(GDC)"
1361   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1362   LD_FOR_BUILD="\$(LD)"
1363   NM_FOR_BUILD="\$(NM)"
1364   RANLIB_FOR_BUILD="\$(RANLIB)"
1365   WINDRES_FOR_BUILD="\$(WINDRES)"
1366   WINDMC_FOR_BUILD="\$(WINDMC)"
1367 fi
1368
1369 AC_PROG_CC_C99
1370 AC_PROG_CXX
1371
1372 # We must set the default linker to the linker used by gcc for the correct
1373 # operation of libtool.  If LD is not defined and we are using gcc, try to
1374 # set the LD default to the ld used by gcc.
1375 if test -z "$LD"; then
1376   if test "$GCC" = yes; then
1377     case $build in
1378     *-*-mingw*)
1379       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1380     *)
1381       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1382     esac
1383     case $gcc_prog_ld in
1384     # Accept absolute paths.
1385     [[\\/]* | [A-Za-z]:[\\/]*)]
1386       LD="$gcc_prog_ld" ;;
1387     esac
1388   fi
1389 fi
1390
1391 # Check whether -static-libstdc++ -static-libgcc is supported.
1392 have_static_libs=no
1393 if test "$GCC" = yes; then
1394   saved_LDFLAGS="$LDFLAGS"
1395
1396   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1397   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1398   AC_LANG_PUSH(C++)
1399   AC_LINK_IFELSE([AC_LANG_SOURCE([
1400 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1401 #error -static-libstdc++ not implemented
1402 #endif
1403 int main() {}])],
1404     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1405     [AC_MSG_RESULT([no])])
1406   AC_LANG_POP(C++)
1407
1408   LDFLAGS="$saved_LDFLAGS"
1409 fi
1410
1411 ACX_PROG_GNAT
1412 ACX_PROG_GDC
1413 ACX_PROG_CMP_IGNORE_INITIAL
1414
1415 AC_ARG_ENABLE([bootstrap],
1416 [AS_HELP_STRING([--enable-bootstrap],
1417                 [enable bootstrapping @<:@yes if native build@:>@])],,
1418 enable_bootstrap=default)
1419
1420 # Issue errors and warnings for invalid/strange bootstrap combinations.
1421 if test -r $srcdir/gcc/configure; then
1422   have_compiler=yes
1423 else
1424   have_compiler=no
1425 fi
1426
1427 case "$have_compiler:$host:$target:$enable_bootstrap" in
1428   *:*:*:no) ;;
1429
1430   # Default behavior.  Enable bootstrap if we have a compiler
1431   # and we are in a native configuration.
1432   yes:$build:$build:default)
1433     enable_bootstrap=yes ;;
1434
1435   *:*:*:default)
1436     enable_bootstrap=no ;;
1437
1438   # We have a compiler and we are in a native configuration, bootstrap is ok
1439   yes:$build:$build:yes)
1440     ;;
1441
1442   # Other configurations, but we have a compiler.  Assume the user knows
1443   # what he's doing.
1444   yes:*:*:yes)
1445     AC_MSG_WARN([trying to bootstrap a cross compiler])
1446     ;;
1447
1448   # No compiler: if they passed --enable-bootstrap explicitly, fail
1449   no:*:*:yes)
1450     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1451
1452   # Fail if wrong command line
1453   *)
1454     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1455     ;;
1456 esac
1457
1458 # When bootstrapping with GCC, build stage 1 in C++11 mode to ensure that a
1459 # C++11 compiler can still start the bootstrap.  Otherwise, if building GCC,
1460 # require C++11 (or higher).
1461 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1462   CXX="$CXX -std=c++11"
1463 elif test "$have_compiler" = yes; then
1464   AX_CXX_COMPILE_STDCXX(11)
1465
1466   if test "${build}" != "${host}"; then
1467     AX_CXX_COMPILE_STDCXX(11, [], [], [_FOR_BUILD])
1468   fi
1469 fi
1470
1471 AC_ARG_ENABLE([pgo-build],
1472 [AS_HELP_STRING([--enable-pgo-build[[=lto]]],
1473                 [enable the PGO build])],
1474 [enable_pgo_build=$enableval],
1475 [enable_pgo_build=no])
1476
1477 # Issue errors and warnings for invalid/strange PGO build combinations.
1478 case "$have_compiler:$host:$target:$enable_pgo_build" in
1479   *:*:*:no) ;;
1480
1481   # Allow the PGO build only if we aren't building a compiler and
1482   # we are in a native configuration.
1483   no:$build:$build:yes | no:$build:$build:lto) ;;
1484
1485   # Disallow the PGO bootstrap if we are building a compiler.
1486   yes:*:*:yes | yes:*:*:lto)
1487     AC_MSG_ERROR([cannot perform the PGO bootstrap when building a compiler]) ;;
1488
1489   *)
1490     AC_MSG_ERROR([invalid option for --enable-pgo-build])
1491     ;;
1492 esac
1493
1494 if test "$enable_pgo_build" != "no"; then
1495   AC_MSG_CHECKING([whether the compiler supports -fprofile-generate])
1496   old_CFLAGS="$CFLAGS"
1497   PGO_BUILD_GEN_CFLAGS="-fprofile-generate"
1498   CFLAGS="$CFLAGS $PGO_BUILD_CFLAGS"
1499   AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1500                     [PGO_BUILD_GEN_CFLAGS=])
1501   CFLAGS="$old_CFLAGS"
1502   if test -n "$PGO_BUILD_GEN_CFLAGS"; then
1503     AC_MSG_RESULT([yes])
1504     PGO_BUILD_USE_CFLAGS="-fprofile-use"
1505   else
1506     AC_MSG_RESULT([no])
1507     AC_MSG_ERROR([cannot perform the PGO build without -fprofile-generate])
1508   fi
1509
1510   if test "$enable_pgo_build" = "lto"; then
1511     AC_MSG_CHECKING([whether the compiler supports -flto=jobserver -ffat-lto-objects])
1512     old_CFLAGS="$CFLAGS"
1513     PGO_BUILD_LTO_CFLAGS="-flto=jobserver -ffat-lto-objects"
1514     CFLAGS="$CFLAGS $PGO_BUILD_LTO_CFLAGS"
1515     AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1516                       [PGO_BUILD_LTO_CFLAGS=])
1517     CFLAGS="$old_CFLAGS"
1518     if test -n "$PGO_BUILD_LTO_CFLAGS"; then
1519       AC_MSG_RESULT([yes])
1520     else
1521       AC_MSG_RESULT([no])
1522       AC_MSG_WARN([LTO is disabled for the PGO build])
1523     fi
1524   fi
1525 fi
1526 AC_SUBST(PGO_BUILD_GEN_CFLAGS)
1527 AC_SUBST(PGO_BUILD_USE_CFLAGS)
1528 AC_SUBST(PGO_BUILD_LTO_CFLAGS)
1529
1530 # Used for setting $lt_cv_objdir
1531 _LT_CHECK_OBJDIR
1532
1533 # Check for GMP, MPFR and MPC
1534 require_gmp=no
1535 require_mpc=no
1536 if test -d ${srcdir}/gcc ; then
1537   require_gmp=yes
1538   require_mpc=yes
1539 fi
1540 if test -d ${srcdir}/gdb ; then
1541   if test "x$enable_gdb" != xno; then
1542    require_gmp=yes
1543   fi
1544 fi
1545
1546 gmplibs="-lmpfr -lgmp"
1547 if test x"$require_mpc" = "xyes" ; then
1548   gmplibs="-lmpc $gmplibs"
1549 fi
1550 gmpinc=
1551 have_gmp=no
1552
1553 # Specify a location for mpc
1554 # check for this first so it ends up on the link line before mpfr.
1555 AC_ARG_WITH(mpc,
1556 [AS_HELP_STRING([--with-mpc=PATH],
1557                 [specify prefix directory for installed MPC package.
1558                  Equivalent to --with-mpc-include=PATH/include
1559                  plus --with-mpc-lib=PATH/lib])])
1560 AC_ARG_WITH(mpc-include,
1561 [AS_HELP_STRING([--with-mpc-include=PATH],
1562                 [specify directory for installed MPC include files])])
1563 AC_ARG_WITH(mpc-lib,
1564 [AS_HELP_STRING([--with-mpc-lib=PATH],
1565                 [specify directory for the installed MPC library])])
1566
1567 if test "x$with_mpc" != x; then
1568   gmplibs="-L$with_mpc/lib $gmplibs"
1569   gmpinc="-I$with_mpc/include $gmpinc"
1570 fi
1571 if test "x$with_mpc_include" != x; then
1572   gmpinc="-I$with_mpc_include $gmpinc"
1573 fi
1574 if test "x$with_mpc_lib" != x; then
1575   gmplibs="-L$with_mpc_lib $gmplibs"
1576 fi
1577 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1578   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1579   gmpinc='-I$$s/mpc/src '"$gmpinc"
1580   # Do not test the mpc version.  Assume that it is sufficient, since
1581   # it is in the source tree, and the library has not been built yet
1582   # but it would be included on the link line in the version check below
1583   # hence making the test fail.
1584   have_gmp=yes
1585 fi
1586
1587 # Specify a location for mpfr
1588 # check for this first so it ends up on the link line before gmp.
1589 AC_ARG_WITH(mpfr,
1590 [AS_HELP_STRING([--with-mpfr=PATH],
1591                 [specify prefix directory for installed MPFR package.
1592                  Equivalent to --with-mpfr-include=PATH/include
1593                  plus --with-mpfr-lib=PATH/lib])])
1594 AC_ARG_WITH(mpfr-include,
1595 [AS_HELP_STRING([--with-mpfr-include=PATH],
1596                 [specify directory for installed MPFR include files])])
1597 AC_ARG_WITH(mpfr-lib,
1598 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1599                 [specify directory for the installed MPFR library])])
1600
1601 if test "x$with_mpfr" != x; then
1602   gmplibs="-L$with_mpfr/lib $gmplibs"
1603   gmpinc="-I$with_mpfr/include $gmpinc"
1604 fi
1605 if test "x$with_mpfr_include" != x; then
1606   gmpinc="-I$with_mpfr_include $gmpinc"
1607 fi
1608 if test "x$with_mpfr_lib" != x; then
1609   gmplibs="-L$with_mpfr_lib $gmplibs"
1610 fi
1611 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1612   # MPFR v3.1.0 moved the sources into a src sub-directory.
1613   if ! test -d ${srcdir}/mpfr/src; then
1614     AC_MSG_ERROR([dnl
1615 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1616   fi
1617   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1618   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1619   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1620   # Do not test the mpfr version.  Assume that it is sufficient, since
1621   # it is in the source tree, and the library has not been built yet
1622   # but it would be included on the link line in the version check below
1623   # hence making the test fail.
1624   have_gmp=yes
1625 fi
1626
1627 # Specify a location for gmp
1628 AC_ARG_WITH(gmp,
1629 [AS_HELP_STRING([--with-gmp=PATH],
1630                 [specify prefix directory for the installed GMP package.
1631                  Equivalent to --with-gmp-include=PATH/include
1632                  plus --with-gmp-lib=PATH/lib])])
1633 AC_ARG_WITH(gmp-include,
1634 [AS_HELP_STRING([--with-gmp-include=PATH],
1635                 [specify directory for installed GMP include files])])
1636 AC_ARG_WITH(gmp-lib,
1637 [AS_HELP_STRING([--with-gmp-lib=PATH],
1638                 [specify directory for the installed GMP library])])
1639
1640
1641 if test "x$with_gmp" != x; then
1642   gmplibs="-L$with_gmp/lib $gmplibs"
1643   gmpinc="-I$with_gmp/include $gmpinc"
1644 fi
1645 if test "x$with_gmp_include" != x; then
1646   gmpinc="-I$with_gmp_include $gmpinc"
1647 fi
1648 if test "x$with_gmp_lib" != x; then
1649   gmplibs="-L$with_gmp_lib $gmplibs"
1650 fi
1651 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1652   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1653   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1654   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1655   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1656   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1657   # Do not test the gmp version.  Assume that it is sufficient, since
1658   # it is in the source tree, and the library has not been built yet
1659   # but it would be included on the link line in the version check below
1660   # hence making the test fail.
1661   have_gmp=yes
1662 fi
1663
1664 if test "x$require_gmp" = xyes && test "x$have_gmp" = xno; then
1665   have_gmp=yes
1666   saved_CFLAGS="$CFLAGS"
1667   CFLAGS="$CFLAGS $gmpinc"
1668   # Check for the recommended and required versions of GMP.
1669   AC_MSG_CHECKING([for the correct version of gmp.h])
1670   AC_TRY_COMPILE([#include "gmp.h"],[
1671   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1672   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1673   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1674   choke me
1675   #endif
1676   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1677   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1678   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1679   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1680   choke me
1681   #endif
1682   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1683    [AC_MSG_RESULT([no]); have_gmp=no])
1684
1685   # If we have GMP, check the MPFR version.
1686   if test x"$have_gmp" = xyes; then
1687     # Check for the recommended and required versions of MPFR.
1688     AC_MSG_CHECKING([for the correct version of mpfr.h])
1689     AC_TRY_COMPILE([#include <gmp.h>
1690     #include <mpfr.h>],[
1691     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1692     choke me
1693     #endif
1694     ], [AC_TRY_COMPILE([#include <gmp.h>
1695     #include <mpfr.h>],[
1696     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1697     choke me
1698     #endif
1699     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1700      [AC_MSG_RESULT([no]); have_gmp=no])
1701   fi
1702
1703   # Check for the MPC header version.
1704   if test "x$require_mpc" = xyes && test x"$have_gmp" = xyes ; then
1705     # Check for the recommended and required versions of MPC.
1706     AC_MSG_CHECKING([for the correct version of mpc.h])
1707     AC_TRY_COMPILE([#include <mpc.h>],[
1708     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1709     choke me
1710     #endif
1711     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1712     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1713     choke me
1714     #endif
1715     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1716      [AC_MSG_RESULT([no]); have_gmp=no])
1717   fi
1718
1719   # Now check the MPFR library.
1720   if test x"$have_gmp" = xyes; then
1721     saved_LIBS="$LIBS"
1722     LIBS="$LIBS $gmplibs"
1723     AC_MSG_CHECKING([for the correct version of the gmp/mpfr libraries])
1724     AC_TRY_LINK([#include <mpfr.h>],[
1725     mpfr_t n;
1726     mpfr_t x;
1727     int t;
1728     mpfr_init (n);
1729     mpfr_init (x);
1730     mpfr_atan2 (n, n, x, MPFR_RNDN);
1731     mpfr_erfc (n, x, MPFR_RNDN);
1732     mpfr_subnormalize (x, t, MPFR_RNDN);
1733     mpfr_clear(n);
1734     mpfr_clear(x);
1735     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1736     LIBS="$saved_LIBS"
1737   fi
1738
1739   # Now check the MPC library
1740   if test "x$require_mpc" = xyes && test x"$have_gmp" = xyes; then
1741     saved_LIBS="$LIBS"
1742     LIBS="$LIBS $gmplibs"
1743     AC_MSG_CHECKING([for the correct version of the mpc libraries])
1744     AC_TRY_LINK([#include <mpc.h>],[
1745     mpc_t c;
1746     mpc_init2 (c, 53);
1747     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1748     mpc_cosh (c, c, MPC_RNDNN);
1749     mpc_pow (c, c, c, MPC_RNDNN);
1750     mpc_acosh (c, c, MPC_RNDNN);
1751     mpc_clear (c);
1752     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1753     LIBS="$saved_LIBS"
1754   fi
1755
1756   CFLAGS="$saved_CFLAGS"
1757
1758 # The library versions listed in the error message below should match
1759 # the HARD-minimums enforced above.
1760   if test x$have_gmp != xyes; then
1761     if test -d ${srcdir}/gcc ; then
1762       AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1763 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1764 their locations.  Source code for these libraries can be found at
1765 their respective hosting sites as well as at
1766 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1767 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1768 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1769 make sure that you have installed both the libraries and the header
1770 files.  They may be located in separate packages.])
1771     else
1772       AC_MSG_ERROR([Building GDB requires GMP 4.2+, and MPFR 3.1.0+.
1773 Try the --with-gmp and/or --with-mpfr options to specify
1774 their locations.  If you obtained GMP and/or MPFR from a vendor
1775 distribution package, make sure that you have installed both the libraries
1776 and the header files.  They may be located in separate packages.])
1777     fi
1778   fi
1779 fi
1780
1781 # Flags needed for both GMP, MPFR and/or MPC.
1782 AC_SUBST(gmplibs)
1783 AC_SUBST(gmpinc)
1784 AC_SUBST(extra_mpfr_configure_flags)
1785 AC_SUBST(extra_mpc_gmp_configure_flags)
1786 AC_SUBST(extra_mpc_mpfr_configure_flags)
1787 AC_SUBST(extra_isl_gmp_configure_flags)
1788
1789 # Libraries to use for stage1 or when not bootstrapping.
1790 AC_ARG_WITH(stage1-libs,
1791 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1792 [if test "$withval" = "no" -o "$withval" = "yes"; then
1793    stage1_libs=
1794  else
1795    stage1_libs=$withval
1796  fi],
1797 [stage1_libs=])
1798 AC_SUBST(stage1_libs)
1799
1800 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1801 # default is yes if gcc is being built; no otherwise.  The reason for
1802 # this default is that gdb is sometimes linked against GNU Source
1803 # Highlight, which is a shared library that uses C++ exceptions.  In
1804 # this case, -static-libstdc++ will cause crashes.
1805 AC_ARG_WITH(static-standard-libraries,
1806 [AS_HELP_STRING([--with-static-standard-libraries],
1807                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1808 [], [with_static_standard_libraries=auto])
1809 if test "$with_static_standard_libraries" = auto; then
1810   with_static_standard_libraries=$have_compiler
1811 fi
1812
1813 # Linker flags to use for stage1 or when not bootstrapping.
1814 AC_ARG_WITH(stage1-ldflags,
1815 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1816 [if test "$withval" = "no" -o "$withval" = "yes"; then
1817    stage1_ldflags=
1818  else
1819    stage1_ldflags=$withval
1820  fi],
1821 [stage1_ldflags=
1822  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1823  # if supported.  But if the user explicitly specified the libraries to use,
1824  # trust that they are doing what they want.
1825  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1826      -a "$have_static_libs" = yes; then
1827    stage1_ldflags="-static-libstdc++ -static-libgcc"
1828  fi])
1829 AC_SUBST(stage1_ldflags)
1830
1831 # Libraries to use for stage2 and later builds.
1832 AC_ARG_WITH(boot-libs,
1833 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1834 [if test "$withval" = "no" -o "$withval" = "yes"; then
1835    poststage1_libs=
1836  else
1837    poststage1_libs=$withval
1838  fi],
1839 [poststage1_libs=])
1840 AC_SUBST(poststage1_libs)
1841
1842 # Linker flags to use for stage2 and later builds.
1843 AC_ARG_WITH(boot-ldflags,
1844 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1845                 [linker flags for stage2 and later])],
1846 [if test "$withval" = "no" -o "$withval" = "yes"; then
1847    poststage1_ldflags=
1848  else
1849    poststage1_ldflags=$withval
1850  fi],
1851 [poststage1_ldflags=
1852  # In stages 2 and 3, default to linking libstdc++ and libgcc
1853  # statically.  But if the user explicitly specified the libraries to
1854  # use, trust that they are doing what they want.
1855  if test "$poststage1_libs" = ""; then
1856    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1857  fi])
1858 case $target in
1859   *-darwin2* | *-darwin1[[56789]]*)
1860     # For these versions, we default to using embedded rpaths.
1861     if test "x$enable_darwin_at_rpath" != "xno"; then
1862       poststage1_ldflags="$poststage1_ldflags -nodefaultrpaths"
1863     fi
1864   ;;
1865   *-darwin*)
1866     # For these versions, we only use embedded rpaths on demand.
1867     if test "x$enable_darwin_at_rpath" = "xyes"; then
1868       poststage1_ldflags="$poststage1_ldflags -nodefaultrpaths"
1869     fi
1870   ;;
1871 esac
1872 AC_SUBST(poststage1_ldflags)
1873
1874 # GCC GRAPHITE dependency isl.
1875 # Basic setup is inlined here, actual checks are in config/isl.m4
1876
1877 AC_ARG_WITH(isl,
1878   [AS_HELP_STRING(
1879    [--with-isl=PATH],
1880    [Specify prefix directory for the installed isl package.
1881     Equivalent to --with-isl-include=PATH/include
1882     plus --with-isl-lib=PATH/lib])])
1883
1884 # Treat --without-isl as a request to disable
1885 # GRAPHITE support and skip all following checks.
1886 if test "x$with_isl" != "xno"; then
1887   # Check for isl
1888   dnl Provide configure switches and initialize islinc & isllibs
1889   dnl with user input.
1890   ISL_INIT_FLAGS
1891   dnl The versions of isl that work for Graphite
1892   ISL_CHECK_VERSION()
1893   dnl Only execute fail-action, if isl has been requested.
1894   ISL_IF_FAILED([
1895     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1896 fi
1897
1898 # If the isl check failed, disable builds of in-tree variant of isl
1899 if test "x$with_isl" = xno ||
1900    test "x$gcc_cv_isl" = xno; then
1901   noconfigdirs="$noconfigdirs isl"
1902   islinc=
1903 fi
1904
1905 AC_SUBST(isllibs)
1906 AC_SUBST(islinc)
1907
1908 # Check for LTO support.
1909 AC_ARG_ENABLE(lto,
1910 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1911 enable_lto=$enableval,
1912 enable_lto=yes; default_enable_lto=yes)
1913
1914 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1915   build_lto_plugin=yes
1916 ],[if test x"$default_enable_lto" = x"yes" ; then
1917     case $target in
1918       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1919       # On other non-ELF platforms, LTO has yet to be validated.
1920       *) enable_lto=no ;;
1921     esac
1922   else
1923   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1924   # It would also be nice to check the binutils support, but we don't
1925   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1926   # warn during gcc/ subconfigure; unless you're bootstrapping with
1927   # -flto it won't be needed until after installation anyway.
1928     case $target in
1929       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1930       *) if test x"$enable_lto" = x"yes"; then
1931         AC_MSG_ERROR([LTO support is not enabled for this target.])
1932         fi
1933       ;;
1934     esac
1935   fi
1936   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1937   # Build it unless LTO was explicitly disabled.
1938   case $target in
1939     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1940     *) ;;
1941   esac
1942 ])
1943
1944 AC_ARG_ENABLE(linker-plugin-configure-flags,
1945   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1946     [additional flags for configuring linker plugins @<:@none@:>@])],
1947   extra_linker_plugin_configure_flags=$enableval,
1948   extra_linker_plugin_configure_flags=)
1949 AC_SUBST(extra_linker_plugin_configure_flags)
1950 AC_ARG_ENABLE(linker-plugin-flags,
1951   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1952     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1953   extra_linker_plugin_flags=$enableval,
1954   extra_linker_plugin_flags=)
1955 AC_SUBST(extra_linker_plugin_flags)
1956
1957 # Handle --enable-host-pie
1958 # If host PIE executables are the default (or must be forced on) for some host,
1959 # we must pass that configuration to the gcc directory.
1960 gcc_host_pie=
1961 AC_ARG_ENABLE(host-pie,
1962 [AS_HELP_STRING([--enable-host-pie],
1963                 [build position independent host executables])],
1964 [host_pie=$enableval
1965  case $host in
1966    *-*-darwin2*)
1967      if test x$host_pie != xyes ; then
1968        # for Darwin20+ this is required.
1969        AC_MSG_WARN([PIE executables are required for the configured host, host-pie setting ignored.])
1970        host_pie=yes
1971        gcc_host_pie=--enable-host-pie
1972      fi ;;
1973   *) ;;
1974  esac],
1975 [case $host in
1976   *-*-darwin2*)
1977     # Default to PIE (mandatory for aarch64).
1978     host_pie=yes
1979     gcc_host_pie=--enable-host-pie
1980     ;;
1981   *) host_pie=no ;;
1982  esac])
1983
1984 AC_SUBST(host_pie)
1985 AC_SUBST(gcc_host_pie)
1986
1987 # Enable --enable-host-shared.
1988 # Checked early to determine whether jit is an 'all' language
1989 AC_ARG_ENABLE(host-shared,
1990 [AS_HELP_STRING([--enable-host-shared],
1991                 [build host code as shared libraries])],
1992 [host_shared=$enableval
1993  case $host in
1994    x86_64-*-darwin* | aarch64-*-darwin*)
1995      if test x$host_shared != xyes ; then
1996        # PIC is the default, and actually cannot be switched off.
1997        AC_MSG_WARN([PIC code is required for the configured host; host-shared setting ignored.])
1998        host_shared=yes
1999      fi ;;
2000    *-*-darwin*)
2001      if test x$host_pie = xyes -a x$host_shared != xyes ; then
2002        AC_MSG_WARN([PIC code is required for PIE host executables host-shared setting ignored.])
2003        host_shared=yes
2004      fi ;;
2005   *) ;;
2006  esac],
2007 [case $host in
2008   # 64B x86_64 and Aarch64 Darwin default to PIC.
2009   x86_64-*-darwin* | aarch64-*-darwin*) host_shared=yes ;;
2010   # 32B and powerpc64 Darwin must use PIC to link PIE exes.
2011   *-*-darwin*) host_shared=$host_pie ;;
2012   *) host_shared=no;;
2013  esac])
2014
2015 AC_SUBST(host_shared)
2016
2017 if test x$host_shared = xyes; then
2018   case $host in
2019     *-*-darwin*)
2020       # Since host shared is the default for 64b Darwin, and also enabled for
2021       # host_pie, ensure that we present the PIE flag when host_pie is active.
2022       if test x$host_pie = xyes; then
2023         PICFLAG=-fPIE
2024       fi
2025       ;;
2026     *)
2027       PICFLAG=-fPIC
2028       ;;
2029   esac
2030 elif test x$host_pie = xyes; then
2031   PICFLAG=-fPIE
2032 else
2033   PICFLAG=
2034 fi
2035
2036 AC_SUBST(PICFLAG)
2037
2038 # If we are building PIC/PIE host executables, and we are building dependent
2039 # libs (e.g. GMP) in-tree those libs need to be configured to generate PIC
2040 # code.
2041 host_libs_picflag=
2042 if test "$host_shared" = "yes" -o "$host_pie" = "yes"; then
2043 host_libs_picflag='--with-pic'
2044 fi
2045 AC_SUBST(host_libs_picflag)
2046
2047 # By default, C and C++ are the only stage 1 languages.
2048 stage1_languages=,c,
2049
2050 # Target libraries that we bootstrap.
2051 bootstrap_target_libs=,target-libgcc,
2052
2053 # Figure out what language subdirectories are present.
2054 # Look if the user specified --enable-languages="..."; if not, use
2055 # the environment variable $LANGUAGES if defined. $LANGUAGES might
2056 # go away some day.
2057 # NB:  embedded tabs in this IF block -- do not untabify
2058 if test -d ${srcdir}/gcc; then
2059   if test x"${enable_languages+set}" != xset; then
2060     if test x"${LANGUAGES+set}" = xset; then
2061       enable_languages="${LANGUAGES}"
2062         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
2063     else
2064       enable_languages=default
2065     fi
2066   else
2067     if test x"${enable_languages}" = x ||
2068        test x"${enable_languages}" = xyes;
2069        then
2070       echo configure.ac: --enable-languages needs at least one language argument 1>&2
2071       exit 1
2072     fi
2073   fi
2074   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
2075
2076   # 'f95' is the old name for the 'fortran' language. We issue a warning
2077   # and make the substitution.
2078   case ,${enable_languages}, in
2079     *,f95,*)
2080       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
2081       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
2082       ;;
2083   esac
2084
2085   # If bootstrapping, C++ must be enabled.
2086   case ",$enable_languages,:$enable_bootstrap" in
2087     *,c++,*:*) ;;
2088     *:yes)
2089       if test -f ${srcdir}/gcc/cp/config-lang.in; then
2090         enable_languages="${enable_languages},c++"
2091       else
2092         AC_MSG_ERROR([bootstrapping requires c++ sources])
2093       fi
2094       ;;
2095   esac
2096
2097   # First scan to see if an enabled language requires some other language.
2098   # We assume that a given config-lang.in will list all the language
2099   # front ends it requires, even if some are required indirectly.
2100   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2101     case ${lang_frag} in
2102       ..) ;;
2103       # The odd quoting in the next line works around
2104       # an apparent bug in bash 1.12 on linux.
2105       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2106       *)
2107         # From the config-lang.in, get $language, $lang_requires, and
2108         # $lang_requires_boot_languages.
2109         language=
2110         lang_requires=
2111         lang_requires_boot_languages=
2112         # set srcdir during sourcing lang_frag to the gcc dir.
2113         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
2114         # polutes this shell
2115         saved_srcdir=${srcdir}
2116         srcdir=${srcdir}/gcc . ${lang_frag}
2117         srcdir=${saved_srcdir}
2118         for other in ${lang_requires} ${lang_requires_boot_languages}; do
2119           case ,${enable_languages}, in
2120             *,$other,*) ;;
2121             *,default,*) ;;
2122             *,all,*) ;;
2123             *,$language,*)
2124               echo " \`$other' language required by \`$language'; enabling" 1>&2
2125               enable_languages="${enable_languages},${other}"
2126               ;;
2127           esac
2128         done
2129         for other in ${lang_requires_boot_languages} ; do
2130           if test "$other" != "c"; then
2131             case ,${enable_stage1_languages}, in
2132               *,$other,*) ;;
2133               *,default,*) ;;
2134               *,all,*) ;;
2135               *)
2136                 case ,${enable_languages}, in
2137                   *,$language,*)
2138                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
2139                     enable_stage1_languages="$enable_stage1_languages,${other}"
2140                     ;;
2141                 esac
2142                 ;;
2143             esac
2144           fi
2145         done
2146         ;;
2147     esac
2148   done
2149
2150   new_enable_languages=,c,
2151
2152   # If LTO is enabled, add the LTO front end.
2153   if test "$enable_lto" = "yes" ; then
2154     case ,${enable_languages}, in
2155       *,lto,*) ;;
2156       *) enable_languages="${enable_languages},lto" ;;
2157     esac
2158     if test "${build_lto_plugin}" = "yes" ; then
2159       configdirs="$configdirs lto-plugin"
2160     fi
2161   fi
2162
2163   # If we're building an offloading compiler, add the LTO front end.
2164   if test x"$enable_as_accelerator_for" != x ; then
2165     case ,${enable_languages}, in
2166       *,lto,*) ;;
2167       *) enable_languages="${enable_languages},lto" ;;
2168     esac
2169   fi
2170
2171   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
2172   potential_languages=,c,
2173
2174   enabled_target_libs=
2175   disabled_target_libs=
2176
2177   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2178     case ${lang_frag} in
2179       ..) ;;
2180       # The odd quoting in the next line works around
2181       # an apparent bug in bash 1.12 on linux.
2182       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2183       *)
2184         # From the config-lang.in, get $language, $target_libs,
2185         # $lang_dirs, $boot_language, and $build_by_default
2186         language=
2187         target_libs=
2188         lang_dirs=
2189         subdir_requires=
2190         boot_language=no
2191         build_by_default=yes
2192         # set srcdir during sourcing.  See above about save & restore
2193         saved_srcdir=${srcdir}
2194         srcdir=${srcdir}/gcc . ${lang_frag}
2195         srcdir=${saved_srcdir}
2196         if test x${language} = x; then
2197           echo "${lang_frag} doesn't set \$language." 1>&2
2198           exit 1
2199         fi
2200
2201         if test "$language" = "c++"; then
2202           boot_language=yes
2203         fi
2204
2205         add_this_lang=no
2206         # C is always enabled, so no need to add it again
2207         if test "$language" != "c"; then
2208           case ,${enable_languages}, in
2209             *,${language},*)
2210               # Language was explicitly selected; include it
2211               add_this_lang=yes
2212               ;;
2213             *,all,*)
2214               # All languages are enabled
2215               add_this_lang=all
2216               ;;
2217             *,default,*)
2218               # 'default' was selected, select it if it is a default language
2219               add_this_lang=${build_by_default}
2220               ;;
2221           esac
2222         fi
2223
2224         # Disable languages that need other directories if these aren't available.
2225         for i in $subdir_requires; do
2226           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2227           case ${add_this_lang} in
2228             yes)
2229               # Specifically requested language; tell them.
2230               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2231               ;;
2232             all)
2233               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2234               add_this_lang=unsupported
2235               ;;
2236             *)
2237               # Silently disable.
2238               add_this_lang=unsupported
2239               ;;
2240           esac
2241         done
2242
2243         # Disable Ada if no preexisting GNAT is available.
2244         case ${add_this_lang}:${language}:${have_gnat} in
2245           yes:ada:no)
2246             # Specifically requested language; tell them.
2247             AC_MSG_ERROR([GNAT is required to build $language])
2248             ;;
2249           all:ada:no)
2250             AC_MSG_WARN([GNAT is required to build $language])
2251             add_this_lang=unsupported
2252             ;;
2253           *:ada:no)
2254             # Silently disable.
2255             add_this_lang=unsupported
2256             ;;
2257         esac
2258
2259         # Disable D if no preexisting GDC is available.
2260         case ${add_this_lang}:${language}:${have_gdc} in
2261           yes:d:no)
2262             # Specifically requested language; tell them.
2263             AC_MSG_ERROR([GDC is required to build $language])
2264            ;;
2265           all:d:no)
2266             AC_MSG_WARN([GDC is required to build $language])
2267             add_this_lang=unsupported
2268             ;;
2269           *:d:no)
2270             # Silently disable.
2271             add_this_lang=unsupported
2272             ;;
2273         esac
2274
2275         # Disable jit if -enable-host-shared not specified
2276         # but not if building for Mingw. All code in Windows
2277         # is position independent code (PIC).
2278         case $target in
2279           *mingw*) ;;
2280           *)
2281           case ${add_this_lang}:${language}:${host_shared} in
2282             yes:jit:no)
2283                    # PR jit/64780: explicitly specify --enable-host-shared
2284             AC_MSG_ERROR([
2285 Enabling language "jit" requires --enable-host-shared.
2286
2287 --enable-host-shared typically slows the rest of the compiler down by
2288 a few %, so you must explicitly enable it.
2289
2290 If you want to build both the jit and the regular compiler, it is often
2291 best to do this via two separate configure/builds, in separate
2292 directories, to avoid imposing the performance cost of
2293 --enable-host-shared on the regular compiler.])
2294                     ;;
2295             all:jit:no)
2296               AC_MSG_WARN([--enable-host-shared required to build $language])
2297               add_this_lang=unsupported
2298               ;;
2299             *:jit:no)
2300               # Silently disable.
2301               add_this_lang=unsupported
2302               ;;
2303                 esac
2304           ;;
2305         esac
2306
2307         # Disable a language that is unsupported by the target.
2308         case "${add_this_lang}: $unsupported_languages " in
2309           no:*) ;;
2310           unsupported:*) ;;
2311           *:*" $language "*)
2312             AC_MSG_WARN([${language} not supported for this target])
2313             add_this_lang=unsupported
2314             ;;
2315         esac
2316
2317         case $add_this_lang in
2318           unsupported)
2319             # Remove language-dependent dirs.
2320             disabled_target_libs="$disabled_target_libs $target_libs"
2321             noconfigdirs="$noconfigdirs $lang_dirs"
2322             ;;
2323           no)
2324             # Remove language-dependent dirs; still show language as supported.
2325             disabled_target_libs="$disabled_target_libs $target_libs"
2326             noconfigdirs="$noconfigdirs $lang_dirs"
2327             potential_languages="${potential_languages}${language},"
2328             ;;
2329           all|yes)
2330             new_enable_languages="${new_enable_languages}${language},"
2331             potential_languages="${potential_languages}${language},"
2332             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2333             enabled_target_libs="$enabled_target_libs $target_libs"
2334             case "${boot_language}:,$enable_stage1_languages," in
2335               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2336                 # Add to (comma-separated) list of stage 1 languages.
2337                 case ",$stage1_languages," in
2338                   *,$language,* | ,yes, | ,all,) ;;
2339                   *) stage1_languages="${stage1_languages}${language}," ;;
2340                 esac
2341                 # We need to bootstrap any supporting libraries.
2342                 bootstrap_target_libs=`echo "${bootstrap_target_libs}${target_libs}," | sed "s/ /,/g"`
2343                 ;;
2344             esac
2345             ;;
2346         esac
2347         ;;
2348     esac
2349   done
2350
2351   # Add target libraries which are only needed for disabled languages
2352   # to noconfigdirs.
2353   if test -n "$disabled_target_libs"; then
2354     for dir in $disabled_target_libs; do
2355       case " $enabled_target_libs " in
2356       *" ${dir} "*) ;;
2357       *) noconfigdirs="$noconfigdirs $dir" ;;
2358       esac
2359     done
2360   fi
2361
2362   AC_ARG_ENABLE(stage1-languages,
2363   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2364                   [choose additional languages to build during
2365                   stage1.  Mostly useful for compiler development])],
2366   [case ,${enable_stage1_languages}, in
2367     ,no,|,,)
2368       # Set it to something that will have no effect in the loop below
2369       enable_stage1_languages=c ;;
2370     ,yes,)
2371       enable_stage1_languages=`echo $new_enable_languages | \
2372         sed -e "s/^,//" -e "s/,$//" ` ;;
2373     *,all,*)
2374       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2375         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2376   esac
2377
2378   # Add "good" languages from enable_stage1_languages to stage1_languages,
2379   # while "bad" languages go in missing_languages.  Leave no duplicates.
2380   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2381     case $potential_languages in
2382       *,$i,*)
2383         case $stage1_languages in
2384           *,$i,*) ;;
2385           *) stage1_languages="$stage1_languages$i," ;;
2386         esac ;;
2387       *)
2388         case $missing_languages in
2389           *,$i,*) ;;
2390           *) missing_languages="$missing_languages$i," ;;
2391         esac ;;
2392      esac
2393   done])
2394
2395   # Remove leading/trailing commas that were added for simplicity
2396   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2397   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2398   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2399   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2400
2401   if test "x$missing_languages" != x; then
2402     AC_MSG_ERROR([
2403 The following requested languages could not be built: ${missing_languages}
2404 Supported languages are: ${potential_languages}])
2405   fi
2406   if test "x$new_enable_languages" != "x$enable_languages"; then
2407     echo The following languages will be built: ${new_enable_languages}
2408     enable_languages="$new_enable_languages"
2409   fi
2410
2411   AC_SUBST(stage1_languages)
2412   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2413 fi
2414
2415 # Handle --disable-<component> generically.
2416 for dir in $configdirs $build_configdirs $target_configdirs ; do
2417   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2418   varname=`echo $dirname | sed -e s/+/_/g`
2419   if eval test x\${enable_${varname}} "=" xno ; then
2420     noconfigdirs="$noconfigdirs $dir"
2421   fi
2422 done
2423
2424 # Check for Boehm's garbage collector
2425 AC_ARG_ENABLE(objc-gc,
2426 [AS_HELP_STRING([--enable-objc-gc],
2427                 [enable use of Boehm's garbage collector with the
2428                  GNU Objective-C runtime])])
2429 AC_ARG_WITH([target-bdw-gc],
2430 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2431                 [specify prefix directory for installed bdw-gc package.
2432                  Equivalent to --with-target-bdw-gc-include=PATH/include
2433                  plus --with-target-bdw-gc-lib=PATH/lib])])
2434 AC_ARG_WITH([target-bdw-gc-include],
2435 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2436                 [specify directories for installed bdw-gc include files])])
2437 AC_ARG_WITH([target-bdw-gc-lib],
2438 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2439                 [specify directories for installed bdw-gc library])])
2440
2441 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2442   AC_MSG_CHECKING([for bdw garbage collector])
2443   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2444     dnl no bdw-gw options, assume default locations
2445     AC_MSG_RESULT([using bdw-gc in default locations])
2446   else
2447     dnl bdw-gw options, first error checking, complete checking in libobjc
2448     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2449       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2450     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2451       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2452     else
2453       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2454     fi
2455   fi
2456 esac
2457
2458 # Disable libitm, libsanitizer, libvtv if we're not building C++
2459 case ,${enable_languages}, in
2460   *,c++,*)
2461     # Disable libitm, libsanitizer if we're not building libstdc++
2462     case "${noconfigdirs}" in
2463       *target-libstdc++-v3*)
2464         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2465         ;;
2466       *) ;;
2467     esac
2468     ;;
2469   *)
2470     noconfigdirs="$noconfigdirs target-libitm target-libsanitizer target-libvtv"
2471     ;;
2472 esac
2473
2474 # If gcc/ is not in the source tree then we'll not be building a
2475 # target compiler, assume in that case we don't want to build any
2476 # target libraries or tools.
2477 #
2478 # This was added primarily for the benefit for binutils-gdb who reuse
2479 # this configure script, but don't always have target tools available.
2480 if test ! -d ${srcdir}/gcc; then
2481    skipdirs="${skipdirs} ${target_configdirs}"
2482 fi
2483
2484 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2485 # $build_configdirs and $target_configdirs.
2486 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2487
2488 notsupp=""
2489 for dir in . $skipdirs $noconfigdirs ; do
2490   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2491   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2492     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2493     if test -r $srcdir/$dirname/configure ; then
2494       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2495         true
2496       else
2497         notsupp="$notsupp $dir"
2498       fi
2499     fi
2500   fi
2501   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2502     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2503     if test -r $srcdir/$dirname/configure ; then
2504       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2505         true
2506       else
2507         notsupp="$notsupp $dir"
2508       fi
2509     fi
2510   fi
2511   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2512     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2513     if test -r $srcdir/$dirname/configure ; then
2514       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2515         true
2516       else
2517         notsupp="$notsupp $dir"
2518       fi
2519     fi
2520   fi
2521 done
2522
2523 # Quietly strip out all directories which aren't configurable in this tree.
2524 # This relies on all configurable subdirectories being autoconfiscated, which
2525 # is now the case.
2526 build_configdirs_all="$build_configdirs"
2527 build_configdirs=
2528 for i in ${build_configdirs_all} ; do
2529   j=`echo $i | sed -e s/build-//g`
2530   if test -f ${srcdir}/$j/configure ; then
2531     build_configdirs="${build_configdirs} $i"
2532   fi
2533 done
2534
2535 configdirs_all="$configdirs"
2536 configdirs=
2537 for i in ${configdirs_all} ; do
2538   if test -f ${srcdir}/$i/configure ; then
2539     configdirs="${configdirs} $i"
2540   fi
2541 done
2542
2543 target_configdirs_all="$target_configdirs"
2544 target_configdirs=
2545 for i in ${target_configdirs_all} ; do
2546   j=`echo $i | sed -e s/target-//g`
2547   if test -f ${srcdir}/$j/configure ; then
2548     target_configdirs="${target_configdirs} $i"
2549   fi
2550 done
2551
2552 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2553 # so we have to add it after the preceding checks.
2554 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2555 then
2556   case " $configdirs " in
2557     *" libiberty "*)
2558       # If we can build libiberty, we can also build libiberty-linker-plugin.
2559       configdirs="$configdirs libiberty-linker-plugin"
2560       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2561         --with-libiberty=../libiberty-linker-plugin";;
2562     *)
2563       AC_MSG_ERROR([libiberty missing]);;
2564   esac
2565 fi
2566
2567 # Sometimes we have special requirements for the host libiberty.
2568 extra_host_libiberty_configure_flags=
2569 case " $configdirs " in
2570   *" lto-plugin "* | *" libcc1 "* | *" gdbserver "*)
2571     # When these are to be built as shared libraries, the same applies to
2572     # libiberty.
2573     extra_host_libiberty_configure_flags=--enable-shared
2574     ;;
2575 esac
2576 AC_SUBST(extra_host_libiberty_configure_flags)
2577
2578 # Sometimes we have special requirements for the host zlib.
2579 extra_host_zlib_configure_flags=
2580 case " $configdirs " in
2581   *" bfd "*)
2582     # When bfd is to be built as a shared library, the same applies to
2583     # zlib.
2584     if test "$enable_shared" = "yes"; then
2585       extra_host_zlib_configure_flags=--enable-host-shared
2586     fi
2587     ;;
2588 esac
2589 AC_SUBST(extra_host_zlib_configure_flags)
2590
2591 # Produce a warning message for the subdirs we can't configure.
2592 # This isn't especially interesting in the Cygnus tree, but in the individual
2593 # FSF releases, it's important to let people know when their machine isn't
2594 # supported by the one or two programs in a package.
2595
2596 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2597   # If $appdirs is non-empty, at least one of those directories must still
2598   # be configured, or we error out.  (E.g., if the gas release supports a
2599   # specified target in some subdirs but not the gas subdir, we shouldn't
2600   # pretend that all is well.)
2601   if test -n "$appdirs" ; then
2602     for dir in $appdirs ; do
2603       if test -r $dir/Makefile.in ; then
2604         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2605           appdirs=""
2606           break
2607         fi
2608         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2609           appdirs=""
2610           break
2611         fi
2612       fi
2613     done
2614     if test -n "$appdirs" ; then
2615       echo "*** This configuration is not supported by this package." 1>&2
2616       exit 1
2617     fi
2618   fi
2619   # Okay, some application will build, or we don't care to check.  Still
2620   # notify of subdirs not getting built.
2621   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2622   echo "    ${notsupp}" 1>&2
2623   echo "    (Any other directories should still work fine.)" 1>&2
2624 fi
2625
2626 case "$host" in
2627   *msdosdjgpp*)
2628     enable_gdbtk=no ;;
2629 esac
2630
2631 # To find our prefix, in gcc_cv_tool_prefix.
2632 ACX_TOOL_DIRS
2633
2634 copy_dirs=
2635
2636 AC_ARG_WITH([build-sysroot],
2637   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2638                   [use sysroot as the system root during the build])],
2639   [if test x"$withval" != x ; then
2640      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2641    fi],
2642   [SYSROOT_CFLAGS_FOR_TARGET=])
2643 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2644
2645 AC_ARG_WITH([debug-prefix-map],
2646   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2647                   [map A to B, C to D ... in debug information])],
2648   [if test x"$withval" != x; then
2649      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2650      for debug_map in $withval; do
2651        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2652      done
2653    fi],
2654   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2655 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2656
2657 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2658 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2659 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2660 # We want to ensure that TARGET libraries (which we know are built with
2661 # gcc) are built with "-O2 -g", so include those options when setting
2662 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2663 if test "x$CFLAGS_FOR_TARGET" = x; then
2664   if test "x${is_cross_compiler}" = xyes; then
2665     CFLAGS_FOR_TARGET="-g -O2"
2666   else
2667     CFLAGS_FOR_TARGET=$CFLAGS
2668     case " $CFLAGS " in
2669       *" -O2 "*) ;;
2670       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2671     esac
2672     case " $CFLAGS " in
2673       *" -g "* | *" -g3 "*) ;;
2674       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2675     esac
2676   fi
2677 fi
2678 AC_SUBST(CFLAGS_FOR_TARGET)
2679
2680 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2681   if test "x${is_cross_compiler}" = xyes; then
2682     CXXFLAGS_FOR_TARGET="-g -O2"
2683   else
2684     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2685     case " $CXXFLAGS " in
2686       *" -O2 "*) ;;
2687       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2688     esac
2689     case " $CXXFLAGS " in
2690       *" -g "* | *" -g3 "*) ;;
2691       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2692     esac
2693   fi
2694 fi
2695 AC_SUBST(CXXFLAGS_FOR_TARGET)
2696
2697 AC_SUBST(LDFLAGS_FOR_TARGET)
2698
2699 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2700 # the named directory are copied to $(tooldir)/sys-include.
2701 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2702   if test x${is_cross_compiler} = xno ; then
2703     echo 1>&2 '***' --with-headers is only supported when cross compiling
2704     exit 1
2705   fi
2706   if test x"${with_headers}" != xyes ; then
2707     x=${gcc_cv_tool_prefix}
2708     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2709   fi
2710 fi
2711
2712 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2713 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2714 # are permitted.
2715 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2716   if test x${is_cross_compiler} = xno ; then
2717     echo 1>&2 '***' --with-libs is only supported when cross compiling
2718     exit 1
2719   fi
2720   if test x"${with_libs}" != xyes ; then
2721     # Copy the libraries in reverse order, so that files in the first named
2722     # library override files in subsequent libraries.
2723     x=${gcc_cv_tool_prefix}
2724     for l in ${with_libs}; do
2725       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2726     done
2727   fi
2728 fi
2729
2730 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2731 #
2732 # This is done by determining whether or not the appropriate directory
2733 # is available, and by checking whether or not specific configurations
2734 # have requested that this magic not happen.
2735 #
2736 # The command line options always override the explicit settings in
2737 # configure.ac, and the settings in configure.ac override this magic.
2738 #
2739 # If the default for a toolchain is to use GNU as and ld, and you don't
2740 # want to do that, then you should use the --without-gnu-as and
2741 # --without-gnu-ld options for the configure script.  Similarly, if
2742 # the default is to use the included zlib and you don't want to do that,
2743 # you should use the --with-system-zlib option for the configure script.
2744
2745 if test x${use_gnu_as} = x &&
2746    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2747   with_gnu_as=yes
2748   extra_host_args="$extra_host_args --with-gnu-as"
2749 fi
2750
2751 if test x${use_gnu_ld} = x &&
2752    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2753   with_gnu_ld=yes
2754   extra_host_args="$extra_host_args --with-gnu-ld"
2755 fi
2756
2757 if test x${use_included_zlib} = x &&
2758    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2759   :
2760 else
2761   with_system_zlib=yes
2762   extra_host_args="$extra_host_args --with-system-zlib"
2763 fi
2764
2765 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2766 # can detect this case.
2767
2768 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2769   with_newlib=yes
2770   extra_host_args="$extra_host_args --with-newlib"
2771 fi
2772
2773 # Handle ${copy_dirs}
2774 set fnord ${copy_dirs}
2775 shift
2776 while test $# != 0 ; do
2777   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2778     :
2779   else
2780     echo Copying $1 to $2
2781
2782     # Use the install script to create the directory and all required
2783     # parent directories.
2784     if test -d $2 ; then
2785       :
2786     else
2787       echo >config.temp
2788       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2789     fi
2790
2791     # Copy the directory, assuming we have tar.
2792     # FIXME: Should we use B in the second tar?  Not all systems support it.
2793     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2794
2795     # It is the responsibility of the user to correctly adjust all
2796     # symlinks.  If somebody can figure out how to handle them correctly
2797     # here, feel free to add the code.
2798
2799     echo $1 > $2/COPIED
2800   fi
2801   shift; shift
2802 done
2803
2804 # Determine a target-dependent exec_prefix that the installed
2805 # gcc will search in.  Keep this list sorted by triplet, with
2806 # the *-*-osname triplets last.
2807 md_exec_prefix=
2808 case "${target}" in
2809   i[[34567]]86-pc-msdosdjgpp*)
2810     md_exec_prefix=/dev/env/DJDIR/bin
2811     ;;
2812   *-*-hpux* | \
2813   *-*-nto-qnx* | \
2814   *-*-solaris2*)
2815     md_exec_prefix=/usr/ccs/bin
2816     ;;
2817 esac
2818
2819 extra_arflags_for_target=
2820 extra_nmflags_for_target=
2821 extra_ranlibflags_for_target=
2822 target_makefile_frag=/dev/null
2823 case "${target}" in
2824   spu-*-*)
2825     target_makefile_frag="config/mt-spu"
2826     ;;
2827   loongarch*-*linux* | loongarch*-*gnu*)
2828     target_makefile_frag="config/mt-loongarch-gnu"
2829     ;;
2830   loongarch*-*elf*)
2831     target_makefile_frag="config/mt-loongarch-elf"
2832     ;;
2833   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2834     target_makefile_frag="config/mt-sde"
2835     ;;
2836   mipsisa*-*-elfoabi*)
2837     target_makefile_frag="config/mt-mips-elfoabi"
2838     ;;
2839   mips*-*-*linux* | mips*-*-gnu*)
2840     target_makefile_frag="config/mt-mips-gnu"
2841     ;;
2842   nios2-*-elf*)
2843     target_makefile_frag="config/mt-nios2-elf"
2844     ;;
2845   *-*-linux-android*)
2846     target_makefile_frag="config/mt-android"
2847     ;;
2848   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2849     target_makefile_frag="config/mt-gnu"
2850     ;;
2851   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2852     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2853     # commands to handle both 32-bit and 64-bit objects.  These flags are
2854     # harmless if we're using GNU nm or ar.
2855     extra_arflags_for_target=" -X32_64"
2856     extra_nmflags_for_target=" -B -X32_64"
2857     ;;
2858 esac
2859
2860 alphaieee_frag=/dev/null
2861 case $target in
2862   alpha*-*-*)
2863     # This just makes sure to use the -mieee option to build target libs.
2864     # This should probably be set individually by each library.
2865     alphaieee_frag="config/mt-alphaieee"
2866     ;;
2867 esac
2868
2869 # If --enable-target-optspace always use -Os instead of -O2 to build
2870 # the target libraries, similarly if it is not specified, use -Os
2871 # on selected platforms.
2872 ospace_frag=/dev/null
2873 case "${enable_target_optspace}:${target}" in
2874   yes:*)
2875     ospace_frag="config/mt-ospace"
2876     ;;
2877   :d30v-*)
2878     ospace_frag="config/mt-d30v"
2879     ;;
2880   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2881     ospace_frag="config/mt-ospace"
2882     ;;
2883   no:* | :*)
2884     ;;
2885   *)
2886     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2887     ;;
2888 esac
2889
2890 # Some systems (e.g., one of the i386-aix systems the gas testers are
2891 # using) don't handle "\$" correctly, so don't use it here.
2892 tooldir='${exec_prefix}'/${target_noncanonical}
2893 build_tooldir=${tooldir}
2894
2895 # Create a .gdbinit file which runs the one in srcdir
2896 # and tells GDB to look there for source files.
2897
2898 if test -r ${srcdir}/.gdbinit ; then
2899   case ${srcdir} in
2900     .) ;;
2901     *) cat > ./.gdbinit <<EOF
2902 # ${NO_EDIT}
2903 dir ${srcdir}
2904 dir .
2905 source ${srcdir}/.gdbinit
2906 EOF
2907     ;;
2908   esac
2909 fi
2910
2911 # Make sure that the compiler is able to generate an executable.  If it
2912 # can't, we are probably in trouble.  We don't care whether we can run the
2913 # executable--we might be using a cross compiler--we only care whether it
2914 # can be created.  At this point the main configure script has set CC.
2915 we_are_ok=no
2916 echo "int main () { return 0; }" > conftest.c
2917 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2918 if test $? = 0 ; then
2919   if test -s conftest || test -s conftest.exe ; then
2920     we_are_ok=yes
2921   fi
2922 fi
2923 case $we_are_ok in
2924   no)
2925     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2926     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2927     rm -f conftest*
2928     exit 1
2929     ;;
2930 esac
2931 rm -f conftest*
2932
2933 # Decide which environment variable is used to find dynamic libraries.
2934 case "${host}" in
2935   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2936   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2937   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2938   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2939 esac
2940
2941 # On systems where the dynamic library environment variable is PATH,
2942 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2943 # built executables to PATH.
2944 if test "$RPATH_ENVVAR" = PATH; then
2945   GCC_SHLIB_SUBDIR=/shlib
2946 else
2947   GCC_SHLIB_SUBDIR=
2948 fi
2949
2950 # Adjust the toplevel makefile according to whether bootstrap was selected.
2951 case $enable_bootstrap in
2952   yes)
2953     bootstrap_suffix=bootstrap
2954     BUILD_CONFIG=bootstrap-debug
2955     ;;
2956   no)
2957     bootstrap_suffix=no-bootstrap
2958     BUILD_CONFIG=
2959     ;;
2960 esac
2961
2962 AC_MSG_CHECKING(for default BUILD_CONFIG)
2963
2964 AC_ARG_WITH([build-config],
2965   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2966                   [use config/NAME.mk build configuration])],
2967   [case $with_build_config in
2968    yes) with_build_config= ;;
2969    no) with_build_config= BUILD_CONFIG= ;;
2970    esac])
2971
2972 if test "x${with_build_config}" != x; then
2973   BUILD_CONFIG=$with_build_config
2974 else
2975   case $BUILD_CONFIG in
2976   bootstrap-debug)
2977     if echo "int f (void) { return 0; }" > conftest.c &&
2978        ${CC} -c conftest.c &&
2979        mv conftest.o conftest.o.g0 &&
2980        ${CC} -c -g conftest.c &&
2981        mv conftest.o conftest.o.g &&
2982        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2983       :
2984     else
2985       BUILD_CONFIG=
2986     fi
2987     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2988     ;;
2989   esac
2990 fi
2991 AC_MSG_RESULT($BUILD_CONFIG)
2992 AC_SUBST(BUILD_CONFIG)
2993
2994 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2995 AC_MSG_CHECKING([for --enable-vtable-verify])
2996 AC_ARG_ENABLE(vtable-verify,
2997 [AS_HELP_STRING([--enable-vtable-verify],
2998                 [Enable vtable verification feature])],
2999 [case "$enableval" in
3000  yes) enable_vtable_verify=yes ;;
3001  no)  enable_vtable_verify=no ;;
3002  *)   enable_vtable_verify=no;;
3003  esac],
3004 [enable_vtable_verify=no])
3005 AC_MSG_RESULT($enable_vtable_verify)
3006
3007 # Record target_configdirs and the configure arguments for target and
3008 # build configuration in Makefile.
3009 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
3010 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
3011 bootstrap_fixincludes=no
3012
3013 # If we are building libgomp, bootstrap it.
3014 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
3015   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
3016 fi
3017
3018 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
3019 # or bootstrap-ubsan, bootstrap it.
3020 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
3021   case "$BUILD_CONFIG" in
3022     *bootstrap-hwasan* | *bootstrap-asan* | *bootstrap-ubsan* )
3023       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
3024       bootstrap_fixincludes=yes
3025       ;;
3026   esac
3027 fi
3028
3029 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
3030 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
3031    test "$enable_vtable_verify" != no; then
3032   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
3033 fi
3034
3035 # If we are building libatomic and the list of enabled languages includes the
3036 # D frontend, bootstrap it.
3037 if echo " ${target_configdirs} " | grep " libatomic " > /dev/null 2>&1; then
3038   case ,${enable_languages}, in
3039     *,d,*)
3040       bootstrap_target_libs=${bootstrap_target_libs}target-libatomic,
3041       ;;
3042   esac
3043 fi
3044
3045 # Determine whether gdb needs tk/tcl or not.
3046 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
3047 # and in that case we want gdb to be built without tk.  Ugh!
3048 # In fact I believe gdb is the *only* package directly dependent on tk,
3049 # so we should be able to put the 'maybe's in unconditionally and
3050 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
3051 # 100% sure that that's safe though.
3052
3053 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
3054 case "$enable_gdbtk" in
3055   no)
3056     GDB_TK="" ;;
3057   yes)
3058     GDB_TK="${gdb_tk}" ;;
3059   *)
3060     # Only add the dependency on gdbtk when GDBtk is part of the gdb
3061     # distro.  Eventually someone will fix this and move Insight, nee
3062     # gdbtk to a separate directory.
3063     if test -d ${srcdir}/gdb/gdbtk ; then
3064       GDB_TK="${gdb_tk}"
3065     else
3066       GDB_TK=""
3067     fi
3068     ;;
3069 esac
3070 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
3071 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
3072
3073 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
3074 # else does, only include them if one of these is built.  The Makefile
3075 # provides the ordering, so it's enough here to add to the list.
3076 case " ${configdirs} " in
3077   *\ gdb\ *)
3078     configdirs="${configdirs} gnulib gdbsupport"
3079     ;;
3080   *\ gdbserver\ *)
3081     configdirs="${configdirs} gnulib gdbsupport"
3082     ;;
3083   *\ sim\ *)
3084     configdirs="${configdirs} gnulib"
3085     ;;
3086 esac
3087
3088 # Strip out unwanted targets.
3089
3090 # While at that, we remove Makefiles if we were started for recursive
3091 # configuration, so that the top-level Makefile reconfigures them,
3092 # like we used to do when configure itself was recursive.
3093
3094 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
3095 # but now we're fixing up the Makefile ourselves with the additional
3096 # commands passed to AC_CONFIG_FILES.  Use separate variables
3097 # extrasub-{build,host,target} not because there is any reason to split
3098 # the substitutions up that way, but only to remain below the limit of
3099 # 99 commands in a script, for HP-UX sed.
3100
3101 # Do not nest @if/@endif or @unless/@endunless pairs, because
3102 # configure will not warn you at all.
3103
3104 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
3105   yes:yes:*\ gold\ *:*,c++,*) ;;
3106   yes:yes:*\ gold\ *:*)
3107     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
3108     ;;
3109 esac
3110
3111 extrasub_build=
3112 for module in ${build_configdirs} ; do
3113   if test -z "${no_recursion}" \
3114      && test -f ${build_subdir}/${module}/Makefile; then
3115     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
3116     rm -f ${build_subdir}/${module}/Makefile
3117   fi
3118   extrasub_build="$extrasub_build
3119 /^@if build-$module\$/d
3120 /^@endif build-$module\$/d
3121 /^@unless build-$module\$/,/^@endunless build-$module\$/d
3122 /^@if build-$module-$bootstrap_suffix\$/d
3123 /^@endif build-$module-$bootstrap_suffix\$/d
3124 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
3125 done
3126 extrasub_host=
3127 for module in ${configdirs} ; do
3128   if test -z "${no_recursion}"; then
3129     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
3130       if test -f ${file}; then
3131         echo 1>&2 "*** removing ${file} to force reconfigure"
3132         rm -f ${file}
3133       fi
3134     done
3135   fi
3136   case ${module},${bootstrap_fixincludes} in
3137     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
3138     *) host_bootstrap_suffix=$bootstrap_suffix ;;
3139   esac
3140   extrasub_host="$extrasub_host
3141 /^@if $module\$/d
3142 /^@endif $module\$/d
3143 /^@unless $module\$/,/^@endunless $module\$/d
3144 /^@if $module-$host_bootstrap_suffix\$/d
3145 /^@endif $module-$host_bootstrap_suffix\$/d
3146 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
3147 done
3148 extrasub_target=
3149 for module in ${target_configdirs} ; do
3150   if test -z "${no_recursion}" \
3151      && test -f ${target_subdir}/${module}/Makefile; then
3152     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
3153     rm -f ${target_subdir}/${module}/Makefile
3154   fi
3155
3156   # We only bootstrap target libraries listed in bootstrap_target_libs.
3157   case $bootstrap_target_libs in
3158     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
3159     *) target_bootstrap_suffix=no-bootstrap ;;
3160   esac
3161
3162   extrasub_target="$extrasub_target
3163 /^@if target-$module\$/d
3164 /^@endif target-$module\$/d
3165 /^@unless target-$module\$/,/^@endunless target-$module\$/d
3166 /^@if target-$module-$target_bootstrap_suffix\$/d
3167 /^@endif target-$module-$target_bootstrap_suffix\$/d
3168 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
3169 done
3170
3171 # Do the final fixup along with target modules.
3172 extrasub_target="$extrasub_target
3173 /^@if /,/^@endif /d
3174 /^@unless /d
3175 /^@endunless /d"
3176
3177 if test "$enable_pgo_build" != "no"; then
3178   extrasub_build="$extrasub_build
3179 /^@if pgo-build\$/d
3180 /^@endif pgo-build\$/d"
3181 fi
3182
3183 # Create the serialization dependencies.  This uses a temporary file.
3184
3185 AC_ARG_ENABLE([serial-configure],
3186 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
3187                 [force sequential configuration of
3188                  sub-packages for the host, target or build
3189                  machine, or all sub-packages])])
3190
3191 case ${enable_serial_configure} in
3192   yes)
3193     enable_serial_build_configure=yes
3194     enable_serial_host_configure=yes
3195     enable_serial_target_configure=yes
3196     ;;
3197 esac
3198
3199 # These force 'configure's to be done one at a time, to avoid problems
3200 # with contention over a shared config.cache.
3201 rm -f serdep.tmp
3202 if test "x${enable_serial_build_configure}" = xyes || test "x${enable_serial_host_configure}" = xyes || test "x${enable_serial_target_configure}" = xyes; then
3203 echo '# serdep.tmp' > serdep.tmp
3204 fi
3205 olditem=
3206 test "x${enable_serial_build_configure}" = xyes &&
3207 for item in ${build_configdirs} ; do
3208   case ${olditem} in
3209     "") ;;
3210     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
3211   esac
3212   olditem=${item}
3213 done
3214 olditem=
3215 test "x${enable_serial_host_configure}" = xyes &&
3216 for item in ${configdirs} ; do
3217   case ${olditem} in
3218     "") ;;
3219     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
3220   esac
3221   olditem=${item}
3222 done
3223 olditem=
3224 test "x${enable_serial_target_configure}" = xyes &&
3225 for item in ${target_configdirs} ; do
3226   case ${olditem} in
3227     "") ;;
3228     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
3229   esac
3230   olditem=${item}
3231 done
3232 serialization_dependencies=serdep.tmp
3233 AC_SUBST_FILE(serialization_dependencies)
3234
3235 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
3236 # target, nonopt, and variable assignments.  These are the ones we
3237 # might not want to pass down to subconfigures.  The exception being
3238 # --cache-file=/dev/null, which is used to turn off the use of cache
3239 # files altogether, and which should be passed on to subconfigures.
3240 # Also strip program-prefix, program-suffix, and program-transform-name,
3241 # so that we can pass down a consistent program-transform-name.
3242 hbaseargs=
3243 bbaseargs=
3244 tbaseargs=
3245 keep_next=no
3246 skip_next=no
3247 eval "set -- $ac_configure_args"
3248 for ac_arg
3249 do
3250   if test X"$skip_next" = X"yes"; then
3251     skip_next=no
3252     continue
3253   fi
3254   if test X"$keep_next" = X"yes"; then
3255     case $ac_arg in
3256       *\'*)
3257         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3258     esac
3259     hbaseargs="$hbaseargs '$ac_arg'"
3260     bbaseargs="$bbaseargs '$ac_arg'"
3261     tbaseargs="$tbaseargs '$ac_arg'"
3262     keep_next=no
3263     continue
3264   fi
3265
3266   # Handle separated arguments.  Based on the logic generated by
3267   # autoconf 2.59.
3268   case $ac_arg in
3269     *=* | --config-cache | -C | -disable-* | --disable-* \
3270       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3271       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3272       | -with-* | --with-* | -without-* | --without-* | --x)
3273       separate_arg=no
3274       ;;
3275     -*)
3276       separate_arg=yes
3277       ;;
3278     *)
3279       separate_arg=no
3280       ;;
3281   esac
3282
3283   skip_targ=no
3284   skip_barg=no
3285   case $ac_arg in
3286 changequote(,)
3287   --with-* | --without-*)
3288     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3289
3290     case $libopt in
3291     *[-_]include)
3292       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3293       ;;
3294     *[-_]lib)
3295       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3296       ;;
3297     *[-_]prefix)
3298       lib=`echo "$libopt" | sed 's,[-_]prefix$,,'`
3299       ;;
3300     *[-_]type)
3301       lib=`echo "$libopt" | sed 's,[-_]type$,,'`
3302       ;;
3303     *)
3304       lib=$libopt
3305       ;;
3306     esac
3307 changequote([,])
3308
3309     case $lib in
3310     mpc | mpfr | gmp | isl)
3311       # If we're processing --with-$lib, --with-$lib-include or
3312       # --with-$lib-lib, for one of the libs above, and target is
3313       # different from host, don't pass the current argument to any
3314       # target library's configure.
3315       if test x$is_cross_compiler = xyes; then
3316         skip_targ=yes
3317       fi
3318       ;;
3319     libintl | libiconv)
3320       # We don't want libintl (and co.) in anything but the host arguments.
3321       skip_targ=yes
3322       skip_barg=yes
3323       ;;
3324     esac
3325     ;;
3326   esac
3327
3328   case "$ac_arg" in
3329     --cache-file=/dev/null | \
3330     -cache-file=/dev/null )
3331       # Handled here to avoid the test to skip args below.
3332       hbaseargs="$hbaseargs '$ac_arg'"
3333       bbaseargs="$bbaseargs '$ac_arg'"
3334       tbaseargs="$tbaseargs '$ac_arg'"
3335       # Assert: $separate_arg should always be no.
3336       keep_next=$separate_arg
3337       ;;
3338     --no*)
3339       continue
3340       ;;
3341     --c* | \
3342     --sr* | \
3343     --ho* | \
3344     --bu* | \
3345     --t* | \
3346     --program-* | \
3347     -cache_file* | \
3348     -srcdir* | \
3349     -host* | \
3350     -build* | \
3351     -target* | \
3352     -program-prefix* | \
3353     -program-suffix* | \
3354     -program-transform-name* )
3355       skip_next=$separate_arg
3356       continue
3357       ;;
3358     -*)
3359       # An option.  Add it.
3360       case $ac_arg in
3361         *\'*)
3362           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3363       esac
3364       hbaseargs="$hbaseargs '$ac_arg'"
3365       if test X"$skip_barg" = Xno; then
3366         bbaseargs="$bbaseargs '$ac_arg'"
3367       fi
3368       if test X"$skip_targ" = Xno; then
3369         tbaseargs="$tbaseargs '$ac_arg'"
3370       fi
3371       keep_next=$separate_arg
3372       ;;
3373     *)
3374       # Either a variable assignment, or a nonopt (triplet).  Don't
3375       # pass it down; let the Makefile handle this.
3376       continue
3377       ;;
3378   esac
3379 done
3380 # Remove the initial space we just introduced and, as these will be
3381 # expanded by make, quote '$'.
3382 hbaseargs=`echo "x$hbaseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3383 bbaseargs=`echo "x$bbaseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3384
3385 # Add in --program-transform-name, after --program-prefix and
3386 # --program-suffix have been applied to it.  Autoconf has already
3387 # doubled dollar signs and backslashes in program_transform_name; we want
3388 # the backslashes un-doubled, and then the entire thing wrapped in single
3389 # quotes, because this will be expanded first by make and then by the shell.
3390 # Also, because we want to override the logic in subdir configure scripts to
3391 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3392 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3393 ${program_transform_name}
3394 EOF_SED
3395 gcc_transform_name=`cat conftestsed.out`
3396 rm -f conftestsed.out
3397 hbaseargs="$hbaseargs --program-transform-name='${gcc_transform_name}'"
3398 bbaseargs="$bbaseargs --program-transform-name='${gcc_transform_name}'"
3399 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3400 if test "$silent" = yes; then
3401   bbaseargs="$bbaseargs --silent"
3402   hbaseargs="$hbaseargs --silent"
3403   tbaseargs="$tbaseargs --silent"
3404 fi
3405
3406 bbaseargs="$bbaseargs --disable-option-checking"
3407 hbaseargs="$hbaseargs --disable-option-checking"
3408 tbaseargs="$tbaseargs --disable-option-checking"
3409
3410 if test "$enable_year2038" = no; then
3411   baseargs="$baseargs --disable-year2038"
3412   tbaseargs="$tbaseargs --disable-year2038"
3413 fi
3414
3415 # Record and document user additions to sub configure arguments.
3416 AC_ARG_VAR([build_configargs],
3417            [additional configure arguments for build directories])
3418 AC_ARG_VAR([host_configargs],
3419            [additional configure arguments for host directories])
3420 AC_ARG_VAR([target_configargs],
3421            [additional configure arguments for target directories])
3422
3423 # For the build-side libraries, we just need to pretend we're native,
3424 # and not use the same cache file.  Multilibs are neither needed nor
3425 # desired.  We can't even use the same cache file for all build-side
3426 # libraries, as they're compiled differently; some with C, some with
3427 # C++ or with different feature-enabling options.
3428 build_configargs="$build_configargs --cache-file=./config.cache ${bbaseargs}"
3429
3430 # For host modules, accept cache file option, or specification as blank.
3431 case "${cache_file}" in
3432 "") # empty
3433   cache_file_option="" ;;
3434 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3435   cache_file_option="--cache-file=${cache_file}" ;;
3436 *) # relative path
3437   cache_file_option="--cache-file=../${cache_file}" ;;
3438 esac
3439
3440 # Host dirs don't like to share a cache file either, horribly enough.
3441 # This seems to be due to autoconf 2.5x stupidity.
3442 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${hbaseargs}"
3443
3444 target_configargs="$target_configargs ${tbaseargs}"
3445
3446 # Passing a --with-cross-host argument lets the target libraries know
3447 # whether they are being built with a cross-compiler or being built
3448 # native.  However, it would be better to use other mechanisms to make the
3449 # sorts of decisions they want to make on this basis.  Please consider
3450 # this option to be deprecated.  FIXME.
3451 if test x${is_cross_compiler} = xyes ; then
3452   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3453 fi
3454
3455 # Special user-friendly check for native x86_64-linux build, if
3456 # multilib is not explicitly enabled.
3457 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3458   x86_64-*linux*:yes:$build:$build:)
3459     # Make sure we have a development environment that handles 32-bit
3460     dev64=no
3461     echo "int main () { return 0; }" > conftest.c
3462     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3463     if test $? = 0 ; then
3464       if test -s conftest || test -s conftest.exe ; then
3465         dev64=yes
3466       fi
3467     fi
3468     rm -f conftest*
3469     if test x${dev64} != xyes ; then
3470       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3471     fi
3472     ;;
3473 esac
3474
3475 # Default to --enable-multilib.
3476 if test x${enable_multilib} = x ; then
3477   target_configargs="--enable-multilib ${target_configargs}"
3478 fi
3479
3480 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3481 # changed from the earlier setting of with_newlib.
3482 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3483   target_configargs="--with-newlib ${target_configargs}"
3484 fi
3485
3486 # Different target subdirs use different values of certain variables
3487 # (notably CXX).  Worse, multilibs use *lots* of different values.
3488 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3489 # it doesn't automatically accept command-line overrides of them.
3490 # This means it's not safe for target subdirs to share a cache file,
3491 # which is disgusting, but there you have it.  Hopefully this can be
3492 # fixed in future.  It's still worthwhile to use a cache file for each
3493 # directory.  I think.
3494
3495 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3496 # We need to pass --target, as newer autoconf's requires consistency
3497 # for target_alias and gcc doesn't manage it consistently.
3498 target_configargs="--cache-file=./config.cache ${target_configargs}"
3499
3500 FLAGS_FOR_TARGET=
3501 case " $target_configdirs " in
3502  *" newlib "*)
3503   case " $target_configargs " in
3504   *" --with-newlib "*)
3505    case "$target" in
3506     *-cygwin*)
3507       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3508       ;;
3509    esac
3510
3511    # If we're not building GCC, don't discard standard headers.
3512    if test -d ${srcdir}/gcc; then
3513      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3514
3515      if test "${build}" != "${host}"; then
3516        # On Canadian crosses, CC_FOR_TARGET will have already been set
3517        # by `configure', so we won't have an opportunity to add -Bgcc/
3518        # to it.  This is right: we don't want to search that directory
3519        # for binaries, but we want the header files in there, so add
3520        # them explicitly.
3521        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3522
3523        # Someone might think of using the pre-installed headers on
3524        # Canadian crosses, in case the installed compiler is not fully
3525        # compatible with the compiler being built.  In this case, it
3526        # would be better to flag an error than risking having
3527        # incompatible object files being constructed.  We can't
3528        # guarantee that an error will be flagged, but let's hope the
3529        # compiler will do it, when presented with incompatible header
3530        # files.
3531      fi
3532    fi
3533
3534    case "${target}-${is_cross_compiler}" in
3535    i[[3456789]]86-*-linux*-no)
3536       # Here host == target, so we don't need to build gcc,
3537       # so we don't want to discard standard headers.
3538       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3539       ;;
3540    *)
3541       # If we're building newlib, use its generic headers last, but search
3542       # for any libc-related directories first (so make it the last -B
3543       # switch).
3544       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3545
3546       # If we're building libgloss, find the startup file, simulator library
3547       # and linker script.
3548       case " $target_configdirs " in
3549         *" libgloss "*)
3550         # Look for startup file, simulator library and maybe linker script.
3551         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3552         # Look for libnosys.a in case the target needs it.
3553         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3554         # Most targets have the linker script in the source directory.
3555         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3556         ;;
3557       esac
3558       ;;
3559    esac
3560    ;;
3561   esac
3562   ;;
3563 esac
3564
3565 case "$target" in
3566   x86_64-*mingw* | *-w64-mingw*)
3567   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3568   # however, use a symlink named 'mingw' in ${prefix} .
3569     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3570     ;;
3571   *-mingw*)
3572   # MinGW can't be handled as Cygwin above since it does not use newlib.
3573     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3574     ;;
3575 esac
3576
3577 # Allow the user to override the flags for
3578 # our build compiler if desired.
3579 if test x"${build}" = x"${host}" ; then
3580   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3581   CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-${CPPFLAGS}}
3582   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3583   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3584 fi
3585
3586 # On Canadian crosses, we'll be searching the right directories for
3587 # the previously-installed cross compiler, so don't bother to add
3588 # flags for directories within the install tree of the compiler
3589 # being built; programs in there won't even run.
3590 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3591   # Search for pre-installed headers if nothing else fits.
3592   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3593 fi
3594
3595 if test "x${use_gnu_ld}" = x &&
3596    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3597   # Arrange for us to find uninstalled linker scripts.
3598   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3599 fi
3600
3601 # Search for other target-specific linker scripts and such.
3602 case "${target}" in
3603   mep*)
3604     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3605     ;;
3606   # The VxWorks support for shared libraries is getting in
3607   # incrementally.  Make sure it doesn't get activated implicitly:
3608   *vxworks*)
3609     if test "${enable_shared-unset}" = unset ; then
3610       enable_shared=no
3611       # So the build of libraries knows ...
3612       target_configargs="${target_configargs} --disable-shared"
3613       # So gcc knows ...
3614       host_configargs="${host_configargs} --disable-shared"
3615     fi
3616     ;;
3617 esac
3618
3619 # Makefile fragments.
3620 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3621 do
3622   eval fragval=\$$frag
3623   if test $fragval != /dev/null; then
3624     eval $frag=${srcdir}/$fragval
3625   fi
3626 done
3627 AC_SUBST_FILE(host_makefile_frag)
3628 AC_SUBST_FILE(target_makefile_frag)
3629 AC_SUBST_FILE(alphaieee_frag)
3630 AC_SUBST_FILE(ospace_frag)
3631
3632 # Miscellanea: directories, flags, etc.
3633 AC_SUBST(RPATH_ENVVAR)
3634 AC_SUBST(GCC_SHLIB_SUBDIR)
3635 AC_SUBST(tooldir)
3636 AC_SUBST(build_tooldir)
3637 AC_SUBST(CONFIGURE_GDB_TK)
3638 AC_SUBST(GDB_TK)
3639 AC_SUBST(INSTALL_GDB_TK)
3640
3641 # Build module lists & subconfigure args.
3642 AC_SUBST(build_configargs)
3643 AC_SUBST(build_configdirs)
3644
3645 # Host module lists & subconfigure args.
3646 AC_SUBST(host_configargs)
3647 AC_SUBST(configdirs)
3648 AC_SUBST(target_configdirs)
3649
3650 # Target module lists & subconfigure args.
3651 AC_SUBST(target_configargs)
3652
3653
3654 # Build tools.
3655 AC_SUBST(AR_FOR_BUILD)
3656 AC_SUBST(AS_FOR_BUILD)
3657 AC_SUBST(CC_FOR_BUILD)
3658 AC_SUBST(CFLAGS_FOR_BUILD)
3659 AC_SUBST(CPP_FOR_BUILD)
3660 AC_SUBST(CPPFLAGS_FOR_BUILD)
3661 AC_SUBST(CXXFLAGS_FOR_BUILD)
3662 AC_SUBST(CXX_FOR_BUILD)
3663 AC_SUBST(DLLTOOL_FOR_BUILD)
3664 AC_SUBST(DSYMUTIL_FOR_BUILD)
3665 AC_SUBST(GFORTRAN_FOR_BUILD)
3666 AC_SUBST(GOC_FOR_BUILD)
3667 AC_SUBST(GDC_FOR_BUILD)
3668 AC_SUBST(LDFLAGS_FOR_BUILD)
3669 AC_SUBST(LD_FOR_BUILD)
3670 AC_SUBST(NM_FOR_BUILD)
3671 AC_SUBST(RANLIB_FOR_BUILD)
3672 AC_SUBST(WINDMC_FOR_BUILD)
3673 AC_SUBST(WINDRES_FOR_BUILD)
3674
3675 # Generate default definitions for YACC, M4, LEX and other programs that run
3676 # on the build machine.  These are used if the Makefile can't locate these
3677 # programs in objdir.
3678 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3679
3680 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3681 case " $build_configdirs " in
3682   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3683 esac
3684
3685 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3686 case " $build_configdirs " in
3687   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3688 esac
3689
3690 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3691 case " $build_configdirs " in
3692   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3693 esac
3694
3695 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3696 case " $build_configdirs " in
3697   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3698   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3699 esac
3700
3701 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3702 case " $build_configdirs " in
3703   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3704 esac
3705
3706 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3707 case " $build_configdirs " in
3708   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3709   *)
3710 changequote(,)
3711     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3712     # higher, else we use the "missing" dummy.
3713     if ${MAKEINFO} --version \
3714        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3715       :
3716     else
3717       MAKEINFO="$MISSING makeinfo"
3718     fi
3719     ;;
3720 changequote([,])
3721 esac
3722
3723 # FIXME: expect and dejagnu may become build tools?
3724
3725 AC_CHECK_PROGS(EXPECT, expect, expect)
3726 case " $configdirs " in
3727   *" expect "*)
3728     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3729     ;;
3730 esac
3731
3732 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3733 case " $configdirs " in
3734   *" dejagnu "*)
3735     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3736     ;;
3737 esac
3738
3739
3740 # Host tools.
3741 NCN_STRICT_CHECK_TOOLS(AR, ar)
3742 NCN_STRICT_CHECK_TOOLS(AS, as)
3743 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3744 NCN_STRICT_CHECK_TOOLS(DSYMUTIL, dsymutil)
3745 NCN_STRICT_CHECK_TOOLS(LD, ld)
3746 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3747 NCN_STRICT_CHECK_TOOLS(NM, nm)
3748 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3749 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3750 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3751 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3752 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3753 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3754 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3755 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3756 AC_SUBST(CC)
3757 AC_SUBST(CXX)
3758 AC_SUBST(CFLAGS)
3759 AC_SUBST(CXXFLAGS)
3760 AC_SUBST(GDC)
3761 AC_SUBST(GDCFLAGS)
3762 GDCFLAGS=${GDCFLAGS-${CFLAGS}}
3763 AC_SUBST(PKG_CONFIG_PATH)
3764
3765 GCC_PLUGIN_OPTION(PLUGIN_OPTION)
3766 AR_PLUGIN_OPTION=
3767 RANLIB_PLUGIN_OPTION=
3768 if test -n "$PLUGIN_OPTION"; then
3769   if $AR --help 2>&1 | grep -q "\--plugin"; then
3770     AR_PLUGIN_OPTION="$PLUGIN_OPTION"
3771   fi
3772   if $RANLIB --help 2>&1 | grep -q "\--plugin"; then
3773     RANLIB_PLUGIN_OPTION="$PLUGIN_OPTION"
3774   fi
3775 fi
3776 AC_SUBST(AR_PLUGIN_OPTION)
3777 AC_SUBST(RANLIB_PLUGIN_OPTION)
3778
3779 # Target tools.
3780 AC_ARG_WITH([build-time-tools],
3781   [AS_HELP_STRING([--with-build-time-tools=PATH],
3782                   [use given path to find target tools during the build])],
3783   [case x"$withval" in
3784      x/*) ;;
3785      *)
3786        with_build_time_tools=
3787        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3788        ;;
3789    esac],
3790   [with_build_time_tools=])
3791
3792 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3793 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3794 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3795 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3796 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3797 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3798 NCN_STRICT_CHECK_TARGET_TOOLS(GM2_FOR_TARGET, gm2)
3799
3800 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3801 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3802 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3803 ACX_CHECK_INSTALLED_TARGET_TOOL(DSYMUTIL_FOR_TARGET, dsymutil)
3804 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3805 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3806 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3807 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3808 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3809 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3810 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3811 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3812 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3813 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3814 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3815
3816 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3817
3818 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3819 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3820 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3821 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3822 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3823                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3824                 c++)
3825 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3826                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3827                 c++)
3828 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3829 GCC_TARGET_TOOL(dsymutil, DSYMUTIL_FOR_TARGET, DSYMUTIL)
3830 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3831 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3832                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3833 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3834                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3835 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3836                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3837 GCC_TARGET_TOOL(gm2, GM2_FOR_TARGET, GM2,
3838                 [gcc/gm2 -B$$r/$(HOST_SUBDIR)/gcc/], m2)
3839 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3840 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3841 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3842 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3843 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3844 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3845 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3846 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3847 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3848 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3849 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3850
3851 AC_SUBST(FLAGS_FOR_TARGET)
3852 AC_SUBST(RAW_CXX_FOR_TARGET)
3853
3854 # Certain tools may need extra flags.
3855 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3856 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3857 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3858
3859 # When building target libraries, except in a Canadian cross, we use
3860 # the same toolchain as the compiler we just built.
3861 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3862 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3863 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3864 if test $host = $build; then
3865   case " $configdirs " in
3866     *" gcc "*)
3867       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3868       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3869       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3870       ;;
3871   esac
3872 fi
3873
3874 AC_SUBST(COMPILER_AS_FOR_TARGET)
3875 AC_SUBST(COMPILER_LD_FOR_TARGET)
3876 AC_SUBST(COMPILER_NM_FOR_TARGET)
3877
3878 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3879 AC_ARG_ENABLE(maintainer-mode,
3880 [AS_HELP_STRING([--enable-maintainer-mode],
3881                 [enable make rules and dependencies not useful
3882                  (and sometimes confusing) to the casual installer])],
3883       USE_MAINTAINER_MODE=$enableval,
3884       USE_MAINTAINER_MODE=no)
3885 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3886 AC_SUBST(MAINTAINER_MODE_TRUE)
3887 AC_SUBST(MAINTAINER_MODE_FALSE)
3888 if test "$USE_MAINTAINER_MODE" = yes; then
3889   MAINTAINER_MODE_TRUE=
3890   MAINTAINER_MODE_FALSE='#'
3891 else
3892   MAINTAINER_MODE_TRUE='#'
3893   MAINTAINER_MODE_FALSE=
3894 fi
3895 MAINT=$MAINTAINER_MODE_TRUE
3896 AC_SUBST(MAINT)dnl
3897
3898 # ---------------------
3899 # GCC bootstrap support
3900 # ---------------------
3901
3902 # Stage specific cflags for build.
3903 stage1_cflags="-g"
3904 case $build in
3905   vax-*-*)
3906     case ${GCC} in
3907       yes) stage1_cflags="-g -Wa,-J" ;;
3908       *) stage1_cflags="-g -J" ;;
3909     esac ;;
3910 esac
3911
3912 AC_SUBST(stage1_cflags)
3913
3914 # Enable --enable-checking in stage1 of the compiler.
3915 AC_ARG_ENABLE(stage1-checking,
3916 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3917                 [choose additional checking for stage1 of the compiler])],
3918 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3919 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3920   # For --disable-checking or implicit --enable-checking=release, avoid
3921   # setting --enable-checking=gc in the default stage1 checking for LTO
3922   # bootstraps.  See PR62077.
3923   case $BUILD_CONFIG in
3924     *lto*)
3925       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3926     *)
3927       stage1_checking=--enable-checking=yes,types;;
3928   esac
3929   if test "x$enable_checking" = x && \
3930      test -d ${srcdir}/gcc && \
3931      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3932     stage1_checking=--enable-checking=yes,types,extra
3933   fi
3934 else
3935   stage1_checking=--enable-checking=$enable_checking,types
3936 fi])
3937 AC_SUBST(stage1_checking)
3938
3939 # Enable -Werror in bootstrap stage2 and later.
3940 AC_ARG_ENABLE(werror,
3941 [AS_HELP_STRING([--enable-werror],
3942                 [enable -Werror in bootstrap stage2 and later])],
3943 [
3944 case ${enable_werror} in
3945   yes) stage2_werror_flag="--enable-werror-always" ;;
3946   *) stage2_werror_flag="" ;;
3947 esac
3948 ],
3949 [
3950 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3951   case $BUILD_CONFIG in
3952   bootstrap-debug)
3953       stage2_werror_flag="--enable-werror-always" ;;
3954   "")
3955       stage2_werror_flag="--enable-werror-always" ;;
3956   esac
3957 fi
3958 ])
3959
3960 AC_SUBST(stage2_werror_flag)
3961
3962 # Specify what files to not compare during bootstrap.
3963
3964 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3965 compare_exclusions="$compare_exclusions | gcc/m2/gm2-compiler-boot/M2Version*"
3966 compare_exclusions="$compare_exclusions | gcc/m2/gm2-compiler-boot/SYSTEM*"
3967 compare_exclusions="$compare_exclusions | gcc/m2/gm2version*"
3968 case "$target" in
3969   hppa*64*-*-hpux*) ;;
3970   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3971 esac
3972 AC_SUBST(compare_exclusions)
3973
3974 AC_CONFIG_FILES([Makefile],
3975   [sed "$extrasub_build" Makefile |
3976    sed "$extrasub_host" |
3977    sed "$extrasub_target" > mf$$
3978    mv -f mf$$ Makefile],
3979   [extrasub_build="$extrasub_build"
3980    extrasub_host="$extrasub_host"
3981    extrasub_target="$extrasub_target"])
3982 AC_OUTPUT