gcc/mkmap-flat.awk

   1 # Generate a flat list of symbols to export.
   2 #       Contributed by Richard Henderson <rth@cygnus.com>
   3 #
   4 # This file is part of GNU CC.
   5 #
   6 # GNU CC is free software; you can redistribute it and/or modify
   7 # it under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 2, or (at your option)
   9 # any later version.
  10 #
  11 # GNU CC is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with GNU CC; see the file COPYING.  If not, write to
  18 # the Free Software Foundation, 59 Temple Place - Suite 330,
  19 # Boston MA 02111-1307, USA.
  20
  21 BEGIN {
  22   state = "nm";
  23 }
  24
  25 # Remove comment and blank lines.
  26 /^ *#/ || /^ *$/ {
  27   next;
  28 }
  29
  30 # We begin with nm input.  Collect the set of symbols that are present
  31 # so that we can elide undefined symbols.
  32
  33 state == "nm" && /^%%/ {
  34   state = "ver";
  35   next;
  36 }
  37
  38 state == "nm" && ($1 == "U" || $2 == "U") {
  39   next;
  40 }
  41
  42 state == "nm" && NF == 3 {
  43   def[$3] = 1;
  44   next;
  45 }
  46
  47 state == "nm" {
  48   next;
  49 }
  50
  51 # Now we process a simplified variant of the Solaris symbol version
  52 # script.  We have one symbol per line, no semicolons, simple markers
  53 # for beginning and ending each section, and %inherit markers for
  54 # describing version inheritence.  A symbol may appear in more than
  55 # one symbol version, and the last seen takes effect.
  56
  57 NF == 3 && $1 == "%inherit" {
  58   next;
  59 }
  60
  61 NF == 2 && $2 == "{" {
  62   next;
  63 }
  64
  65 $1 == "}" {
  66   next;
  67 }
  68
  69 {
  70   export[$1] = 1;
  71   next;
  72 }
  73
  74 END {
  75   for (sym in export)
  76     if (def[sym])
  77       print sym;
  78 }