libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.64)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 GCC_TOPLEV_SUBDIRS
   9
  10 # We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  13                  [configure in a subdirectory]))
  14
  15 # We may get other options which we don't document:
  16 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 AC_CANONICAL_SYSTEM
  22 _GCC_TOPLEV_NONCANONICAL_BUILD
  23 _GCC_TOPLEV_NONCANONICAL_TARGET
  24
  25 AC_SUBST(target_noncanonical)
  26
  27 # This works around the fact that libtool configuration may change LD
  28 # for this particular configuration, but some shells, instead of
  29 # keeping the changes in LD private, export them just because LD is
  30 # exported.
  31 ORIGINAL_LD_FOR_MULTILIBS=$LD
  32
  33 AC_PROG_LN_S
  34
  35 # This works around an automake problem.
  36 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  37 AC_SUBST(mkinstalldirs)
  38
  39 AC_ARG_WITH(cross-host,
  40   AS_HELP_STRING([--with-cross-host=HOST],
  41                  [configure with a cross compiler from HOST]))
  42
  43 AC_ARG_WITH(newlib,
  44   AS_HELP_STRING([--with-newlib],
  45                  [configure with newlib]))
  46
  47 AC_ARG_ENABLE(version-specific-runtime-libs,
  48   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  49                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  50     [case "$enableval" in
  51       yes) version_specific_libs=yes ;;
  52       no)  version_specific_libs=no ;;
  53       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  54      esac],
  55     [version_specific_libs=no]
  56 )
  57
  58 AC_ARG_ENABLE(browser-plugin,
  59   AS_HELP_STRING([--enable-browser-plugin],
  60                  [build gcjwebplugin web browser plugin]),
  61     [case "$enableval" in
  62       yes) browser_plugin_enabled=yes ;;
  63       no)  browser_plugin_enabled=no ;;
  64       *)   AC_MSG_ERROR([Unknown argument to enable/disable browser plugin]);;
  65      esac],
  66     [browser_plugin_enabled=no]
  67 )
  68
  69 AC_ARG_ENABLE(gconf-peer,
  70   AS_HELP_STRING([--enable-gconf-peer],
  71                  [compile GConf native peers for util.preferences]),
  72     [case "$enableval" in
  73       yes) gconf_enabled=yes ;;
  74       no)  gconf_enabled=no ;;
  75       *)   AC_MSG_ERROR([Unknown argument to enable/disable gconf-peer]);;
  76      esac],
  77     [gconf_enabled=no]
  78 )
  79
  80 AC_ARG_WITH([antlr-jar],
  81             [AS_HELP_STRING([--with-antlr-jar=file],[Use ANTLR from the specified jar file])],
  82             [
  83              ANTLR_JAR=$withval
  84             ],
  85             [
  86              ANTLR_JAR=
  87             ])
  88
  89 AC_MSG_CHECKING([for antlr.jar])
  90 if test "x$ANTLR_JAR" = x; then
  91     for antlr_lib_home in `ls -d /usr/local/share/antlr* 2> /dev/null` \
  92         /usr/share/antlr/lib /usr/share/java /usr/lib;
  93     do
  94         if test -f "$antlr_lib_home/antlr.jar"; then
  95             # FIXME: version check for antlr needed without using a VM
  96             ANTLR_JAR="$antlr_lib_home/antlr.jar"
  97             break
  98         fi
  99     done
 100     if test "x$ANTLR_JAR" = x; then
 101         AC_MSG_RESULT([not found])
 102     else
 103         AC_MSG_RESULT($ANTLR_JAR)
 104     fi
 105 else
 106     if test -f "${ANTLR_JAR}"; then
 107         AC_MSG_RESULT($ANTLR_JAR)
 108     else
 109         AC_MSG_ERROR([antlr jar file not found: $ANTLR_JAR])
 110     fi
 111 fi
 112 AC_SUBST(ANTLR_JAR)
 113
 114 AC_ARG_ENABLE([gjdoc],
 115               [AS_HELP_STRING(--disable-gjdoc,compile GJDoc (disabled by --disable-gjdoc) [default=yes])],
 116               [case "${enableval}" in
 117                 yes) BUILD_GJDOC=yes ;;
 118                 no) BUILD_GJDOC=no ;;
 119                 *) BUILD_GJDOC=yes ;;
 120               esac],
 121               [BUILD_GJDOC=maybe])
 122
 123 AC_MSG_CHECKING([whether to build gjdoc])
 124 if test "x$BUILD_GJDOC" = xmaybe; then
 125     if test -f "${ANTLR_JAR}"; then
 126         BUILD_GJDOC=yes
 127         AC_MSG_RESULT(yes)
 128     else
 129         BUILD_GJDOC=no
 130         AC_MSG_RESULT([no, antlr.jar not found])
 131     fi
 132 else
 133     AC_MSG_RESULT($BUILD_GJDOC)
 134 fi
 135 AM_CONDITIONAL(CREATE_GJDOC, test "x${BUILD_GJDOC}" = xyes)
 136
 137 AC_ARG_ENABLE(java-maintainer-mode,
 138         AS_HELP_STRING([--enable-java-maintainer-mode],
 139         [allow rebuilding of .class and .h files]))
 140 AM_CONDITIONAL(JAVA_MAINTAINER_MODE, test "$enable_java_maintainer_mode" = yes)
 141
 142 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
 143 GCC_NO_EXECUTABLES
 144
 145 # (1) We use an abnormal CXX (without library references), so we
 146 # must cache it under a different name.
 147 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
 148 # the non-multilib-adjusted value will be used in multilibs.
 149 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
 150 # (4) As another side effect, automake doesn't automatically include them
 151 # in Makefile.in.
 152 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
 153 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
 154 # used in later tests.  This may not be necessary in libjava; I don't know.
 155 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 156 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 157 save_CXXFLAGS="$CXXFLAGS"
 158 CXXFLAGS="$CXXFLAGS -fno-builtin"
 159 AC_PROG_CC
 160 AC_PROG_CXX
 161 CXXFLAGS="$save_CXXFLAGS"
 162 m4_rename_force([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 163 AC_SUBST(CFLAGS)
 164 AC_SUBST(CXXFLAGS)
 165 AC_SUBST(LDFLAGS)
 166
 167 AM_INIT_AUTOMAKE([1.9.0])
 168
 169 AC_CHECK_TOOL(AS, as)
 170 AC_CHECK_TOOL(LD, ld)
 171 AC_CHECK_TOOL(AR, ar)
 172 AC_CHECK_TOOL(RANLIB, ranlib, :)
 173 AC_PROG_AWK
 174 AC_CHECK_PROGS([JAR], [jar fastjar gjar], no)
 175 AC_PATH_PROG([ZIP], [zip], no)
 176 AC_PATH_PROG([UNZIP], [unzip], unzip)
 177
 178 # We need a jar that supports -@.  This is a GNU extension.
 179 if test "$JAR" != no; then
 180    rm -f config-test.jar
 181    echo $srcdir/configure.ac | $JAR -cf@ config-test.jar
 182    if test -f config-test.jar; then
 183      rm -f config-test.jar
 184    else
 185      JAR=no
 186    fi
 187 fi
 188
 189 # Prefer the jar we found, but fall back to our jar script.
 190 if test "$JAR" = no; then
 191   if test "$ZIP" = no; then
 192     AC_MSG_ERROR([cannot find neither zip nor jar, cannot continue])
 193   else
 194     # InfoZIP available, use the 'guaranteed' Bourne-shell JAR to build libjava
 195     JAR=`pwd`/scripts/jar
 196   fi
 197 fi
 198
 199 AC_PROG_INSTALL
 200
 201 AM_MAINTAINER_MODE
 202
 203 AC_EXEEXT
 204
 205 # configure.host sets the following important variables
 206 #       libgcj_cflags    - host specific C compiler flags
 207 #       libgcj_cxxflags  - host specific C++ compiler flags
 208 #       libgcj_javaflags - host specific Java compiler flags
 209 #       libgcj_sublib_ltflags - host specific Libtool flags
 210 #                          (only used when building sublibs)
 211 # and a number of others; see the list at the start of the file.
 212
 213 libgcj_cflags=
 214 libgcj_cxxflags=
 215 libgcj_javaflags=
 216 libgcj_sublib_ltflags=
 217
 218 . ${srcdir}/configure.host
 219
 220 ACX_PROG_LD_GNU_SYMBOLIC
 221 libgcj_ld_symbolic_functions=$SYMBOLIC_LDFLAGS
 222 if test -z "$libgcj_ld_symbolic"; then
 223   libgcj_ld_symbolic=$SYMBOLIC_LDFLAGS
 224 fi
 225
 226 LIBGCJ_CFLAGS="${libgcj_cflags}"
 227 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 228 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 229 LIBGCJ_SUBLIB_LTFLAGS="${libgcj_sublib_ltflags}"
 230 LIBGCJ_LD_SYMBOLIC="${libgcj_ld_symbolic}"
 231 LIBGCJ_LD_SYMBOLIC_FUNCTIONS="${libgcj_ld_symbolic_functions}"
 232 AC_SUBST(LIBGCJ_CFLAGS)
 233 AC_SUBST(LIBGCJ_CXXFLAGS)
 234 AC_SUBST(LIBGCJ_JAVAFLAGS)
 235 AC_SUBST(LIBGCJ_SUBLIB_LTFLAGS)
 236 AC_SUBST(LIBGCJ_LD_SYMBOLIC)
 237 AC_SUBST(LIBGCJ_LD_SYMBOLIC_FUNCTIONS)
 238
 239 # Only use libltdl for non-newlib builds.
 240 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 241    AC_LTDL_SHLIBPATH
 242 fi
 243
 244 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 245
 246 # Possibly build libgcj as many sub-libraries.
 247 AC_ARG_ENABLE(libgcj-sublibs,
 248   AS_HELP_STRING([--enable-libgcj-sublibs],
 249                  [build libgcj as many sub-libraries]))
 250
 251 if test -z "$enable_libgcj_sublibs"; then
 252    enable_libgcj_sublibs=$enable_libgcj_sublibs_default
 253 fi
 254 AM_CONDITIONAL(BUILD_SUBLIBS, test "$enable_libgcj_sublibs" = yes)
 255 if test "$enable_libgcj_sublibs" = yes ; then
 256   # In theory we could make do with only one override and simply
 257   # tag "_bc" onto the end of it when we use it to generate the
 258   # spec, but that's an ugly thing to do when there are multiple
 259   # words in the string and you're relying on the ordering to
 260   # append the correct one.
 261   libgcj_spec_lgcj_override="-lgcj-noncore -lgcj"
 262   libgcj_spec_lgcj_bc_override="-lgcj-noncore -lgcj_bc"
 263 fi
 264
 265
 266 # See if the user has requested runtime debugging.
 267 LIBGCJDEBUG="disable"
 268 AC_SUBST(LIBGCJDEBUG)
 269 AC_ARG_ENABLE(libgcj-debug,
 270   AS_HELP_STRING([--enable-libgcj-debug],
 271                  [enable runtime debugging code]),
 272   [if test "$enable_libgcj_debug" = yes; then
 273     AC_DEFINE(__GCJ_DEBUG, 1, [Define this if you want runtime debugging enabled.])
 274     LIBGCJDEBUG="enable"
 275   fi])
 276
 277 AC_ARG_WITH([escher],
 278          AS_HELP_STRING([--with-escher=ABS.PATH],
 279                         [specify path to escher dir or JAR for X peers]))
 280 case "$with_escher" in
 281 "")
 282         use_escher=false
 283         ;;
 284 "no")
 285         use_escher=false
 286         ;;
 287 "yes")
 288         AC_MSG_ERROR([Please supply an absolute path to Escher library])
 289         ;;
 290 *)
 291         use_escher=true
 292         ;;
 293 esac
 294
 295 # Determine which AWT peer libraries to build
 296 AC_ARG_ENABLE(java-awt,
 297   AS_HELP_STRING([--enable-java-awt],
 298                  [list of AWT peer implementations to be built]))
 299
 300 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 301 use_xlib_awt=""
 302 use_gtk_awt=""
 303 use_qt_awt=""
 304 use_x_awt=""
 305 # The default toolkit to use is the first one specified.
 306 TOOLKIT=
 307 AC_SUBST(TOOLKIT)
 308
 309 for peer in $peerlibs ; do
 310   case $peer in
 311     xlib)
 312       if test "$no_x" = yes; then
 313         echo "*** xlib peers requested but no X library available" 1>&2
 314         exit 1
 315       else
 316         use_xlib_awt="yes"
 317         if test -z "$TOOLKIT"; then
 318            TOOLKIT=gnu.awt.xlib.XToolkit
 319         fi
 320       fi
 321       ;;
 322     gtk)
 323       if test "$no_x" = yes; then
 324          echo "*** gtk peers requested but no X library available" 1>&2
 325          exit 1
 326       else
 327          use_gtk_awt=yes
 328          if test -z "$TOOLKIT"; then
 329             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 330          fi
 331       fi
 332       ;;
 333     qt)
 334       if test "$no_x" = yes; then
 335          # Perhaps we should admit the possibility of embedded Qt.
 336          echo "*** Qt peers requested but no X library available" 1>&2
 337          exit 1
 338       else
 339          use_qt_awt=yes
 340          if test -z "$TOOLKIT"; then
 341             TOOLKIT=gnu.java.awt.peer.qt.QtToolkit
 342          fi
 343       fi
 344       ;;
 345     x)
 346       use_x_awt=yes
 347       if test -z "$TOOLKIT"; then
 348          TOOLKIT=gnu.java.awt.peer.x.XToolkit
 349       fi
 350       ;;
 351     no)
 352       use_xlib_awt=
 353       use_gtk_awt=
 354       use_qt_awt=
 355       use_x_awt=
 356       break
 357       ;;
 358     *)
 359       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 360       exit 1
 361   esac
 362 done
 363
 364 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 365 AM_CONDITIONAL(X_AWT, test "$use_x_awt" = yes)
 366
 367 AC_DEFINE_UNQUOTED(AWT_TOOLKIT, "$TOOLKIT", [Name of default AWT toolkit])
 368
 369 AC_DEFINE_UNQUOTED(LIBGCJ_PREFIX, "$prefix", [Installation prefix])
 370
 371 # Create standard.omit based on decisions we just made.
 372 cp $srcdir/standard.omit.in standard.omit
 373 if test "$use_xlib_awt" != yes; then
 374    echo gnu/awt/xlib >> standard.omit
 375    echo gnu/gcj/xlib >> standard.omit
 376 fi
 377 if test "$use_x_awt" != yes; then
 378    echo gnu/java/awt/peer/x >> standard.omit
 379 fi
 380
 381 # Tools that need to be compiled against classpath's tools classes
 382 : > vm-tools-packages
 383 for package in gnu/gcj/tools/gc_analyze ; do
 384     echo $package >> standard.omit
 385     echo $package >> vm-tools-packages
 386 done
 387
 388 if test -z "${with_multisubdir}"; then
 389    builddotdot=.
 390 else
 391    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
 392 fi
 393
 394 NATIVE=yes
 395
 396 # Which gcj and host gcj (for ecjx) do we use?
 397 which_gcj=default
 398 host_exeext=${ac_exeext}
 399 GCJ_FOR_ECJX=
 400 built_gcc_dir="`cd ${builddotdot}/../../${host_subdir}/gcc && ${PWDCMD-pwd}`"
 401 if test -n "${with_cross_host}"; then
 402   # We are being configured with a cross compiler. We can't
 403   # use ac_exeext, because that is for the target platform.
 404   NATIVE=no
 405   cross_host_exeext=
 406   GCJ_FOR_ECJX="${with_cross_host}-gcj"
 407   case "${with_cross_host}" in
 408      *mingw* | *cygwin*)
 409          cross_host_exeext=.exe
 410      ;;
 411   esac
 412   host_exeext=${cross_host_exeext}
 413   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
 414      if test x"$build_noncanonical" = x"$with_cross_host"; then
 415         # Ordinary cross (host!=target and host=build)
 416         which_gcj=built
 417      else
 418         # Canadian cross (host!=target and host!=build)
 419         which_gcj=cross
 420      fi
 421   else
 422      which_gcj=cross
 423   fi
 424 else
 425   # We are being configured with a native or crossed-native compiler
 426   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
 427      if test x"$build" = x"$host"; then
 428         # True native build (host=target and host=build)
 429         which_gcj=built
 430      else
 431         # Crossed-native build (host=target and host!=build)
 432         which_gcj=cross
 433      fi
 434   else
 435      which_gcj=path
 436   fi
 437 fi
 438 libgcjdir=`${PWDCMD-pwd}`
 439 case $GCJ in
 440 *" -B"*)
 441   # Just in case there is a comma in the build dir, quote it for the
 442   # sed command below.
 443   case $libgcjdir in
 444   *[[,\\]]*) qlibgcjdir=`echo "$libgcjdir" | sed 's:[[,\\]]:\\&:g'`;;
 445   *) qlibgcjdir=$libgcjdir;;
 446   esac
 447   GCJ=`echo "$GCJ" | sed "s, -B, -B$qlibgcjdir/&,"`
 448   ;;
 449 *)
 450   GCJ=$GCJ" -B$libgcjdir/"
 451   ;;
 452 esac
 453 case "${which_gcj}" in
 454    built)
 455       GCJH='$(top_builddir)/$(MULTIBUILDTOP)../../$(host_subdir)/gcc/gcjh'
 456    ;;
 457    cross)
 458       if test "x${with_newlib}" = "xyes"; then
 459          # FIXME (comment): Why is this needed?
 460          GCC_UNWIND_INCLUDE=
 461       fi
 462       GCJH='$(target_noncanonical)-gcjh'
 463    ;;
 464    path)
 465       GCJH=gcjh
 466    ;;
 467 esac
 468 JAVAC="$GCJ -C"
 469 export JAVAC
 470
 471 AC_SUBST(GCJ_FOR_ECJX)
 472 AC_SUBST(GCJH)
 473 AC_SUBST(host_exeext)
 474
 475 # Create it, so that compile/link tests don't fail
 476 test -f libgcj.spec || touch libgcj.spec
 477
 478
 479
 480 # Set up to configure Classpath.
 481 # FIXME: no supported way to pass args in autoconf.
 482 # Disable tool wrappers to avoid ltdl.h configure check.
 483 ac_configure_args="$ac_configure_args --disable-tool-wrappers"
 484 ac_configure_args="$ac_configure_args --disable-load-library"
 485 ac_configure_args="$ac_configure_args --${LIBGCJDEBUG}-debug"
 486 ac_configure_args="$ac_configure_args --enable-default-toolkit=$TOOLKIT"
 487 dir1=`cd $srcdir && pwd`
 488 dir2=`pwd`
 489 ac_configure_args="$ac_configure_args --with-vm-classes=$dir1:$dir2"
 490 ac_configure_args="$ac_configure_args --disable-core-jni"
 491 dnl FIXME?
 492 ac_configure_args="$ac_configure_args --disable-examples"
 493 ac_configure_args="$ac_configure_args --with-glibj=build"
 494 if test "$browser_plugin_enabled" != yes; then
 495   ac_configure_args="$ac_configure_args --disable-plugin"
 496 else
 497   ac_configure_args="$ac_configure_args --enable-plugin"
 498 fi
 499 if test "$gconf_enabled" != yes; then
 500   ac_configure_args="$ac_configure_args --disable-gconf-peer"
 501   ac_configure_args="$ac_configure_args --enable-default-preferences-peer=gnu.java.util.prefs.FileBasedFactory"
 502 fi
 503 if test "$use_gtk_awt" != yes; then
 504   ac_configure_args="$ac_configure_args --disable-gtk-peer --disable-plugin"
 505 fi
 506 if test "$use_qt_awt" != yes; then
 507   ac_configure_args="$ac_configure_args --disable-qt-peer"
 508 else
 509   # We need this as qt is disabled by default in classpath.
 510   ac_configure_args="$ac_configure_args --enable-qt-peer"
 511 fi
 512 if test "$use_x_awt" != yes; then
 513   ac_configure_args="$ac_configure_args --without-escher"
 514 else
 515   # We need this as escher is disabled by default in classpath.
 516   if test "$use_escher" != true; then
 517     AC_MSG_ERROR([Please supply an absolute path to the Escher library])
 518   else
 519     ac_configure_args="$ac_configure_args --with-escher=$with_escher"
 520   fi
 521 fi
 522 if test "x$BUILD_GJDOC" = xno; then
 523   ac_configure_args="$ac_configure_args --disable-gjdoc"
 524 fi
 525 # -Werror causes unavoidable problems in code using alsa.
 526 ac_configure_args="$ac_configure_args --disable-regen-headers"
 527 ac_configure_args="$ac_configure_args --disable-Werror"
 528 dnl --with-gcj=$GCJ
 529 dnl --with-javah=$GCJH
 530 dnl gtk-cairo -- just export here...
 531 dnl --enable-regen-headers?
 532
 533 # Only use libltdl for non-newlib builds.
 534 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 535    AC_LIBLTDL_CONVENIENCE
 536    AC_LIBTOOL_DLOPEN
 537    DIRLTDL=libltdl
 538    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 539    # Sigh.  Libtool's macro doesn't do the right thing.
 540    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 541    # FIXME: this is a hack.
 542    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 543    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 544 fi
 545 AC_SUBST(INCLTDL)
 546 AC_SUBST(LIBLTDL)
 547 AC_SUBST(DIRLTDL)
 548 AC_PROG_LIBTOOL
 549 AM_PROG_GCJ
 550 AM_PROG_CC_C_O
 551
 552 AC_CONFIG_SUBDIRS(classpath libltdl)
 553
 554 # The -no-testsuite modules omit the test subdir.
 555 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 556
 557 # Should the runtime set system properties by examining the
 558 # environment variable GCJ_PROPERTIES?
 559 AC_ARG_ENABLE(getenv-properties,
 560   AS_HELP_STRING([--disable-getenv-properties],
 561                  [don't set system properties from GCJ_PROPERTIES]))
 562
 563 # Whether GCJ_PROPERTIES is used depends on the target.
 564 if test -z "$enable_getenv_properties"; then
 565    enable_getenv_properties=${enable_getenv_properties_default-yes}
 566 fi
 567 if test "$enable_getenv_properties" = no; then
 568    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 569      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 570 fi
 571
 572 # Whether we should use arguments to main()
 573 if test -z "$enable_main_args"; then
 574    enable_main_args=${enable_main_args_default-yes}
 575 fi
 576 if test "$enable_main_args" = no; then
 577    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 578 fi
 579
 580
 581 # Should we use hashtable-based synchronization?
 582 # Currently works only for Linux X86/ia64
 583 # Typically faster and more space-efficient
 584 AC_ARG_ENABLE(hash-synchronization,
 585   AS_HELP_STRING([--enable-hash-synchronization],
 586                  [use global hash table for monitor locks]))
 587
 588 if test -z "$enable_hash_synchronization"; then
 589    enable_hash_synchronization=$enable_hash_synchronization_default
 590 fi
 591
 592
 593 install_ecj_jar=no
 594 ECJ_BUILD_JAR=
 595 ECJ_JAR=
 596 AC_ARG_WITH(ecj-jar,
 597         AS_HELP_STRING([--with-ecj-jar=FILE], [use preinstalled ecj jar]),
 598         [ECJ_JAR=$withval],
 599         [if test -f $multi_basedir/ecj.jar; then
 600            ECJ_BUILD_JAR=$multi_basedir/ecj.jar
 601            ECJ_JAR='$(jardir)/ecj.jar'
 602            install_ecj_jar=yes
 603          fi])
 604 AC_SUBST(ECJ_BUILD_JAR)
 605 AC_SUBST(ECJ_JAR)
 606 AM_CONDITIONAL(BUILD_ECJ1, test "$ECJ_JAR" != "")
 607 AM_CONDITIONAL(INSTALL_ECJ_JAR, test $install_ecj_jar = yes)
 608
 609 AC_ARG_WITH(java-home,
 610   AS_HELP_STRING([--with-java-home=DIRECTORY],
 611                  [value of java.home system property]),
 612                  [JAVA_HOME="${withval}"], [JAVA_HOME=""])
 613 AM_CONDITIONAL(JAVA_HOME_SET, test ! -z "$JAVA_HOME")
 614 AC_SUBST(JAVA_HOME)
 615
 616 suppress_libgcj_bc=no
 617 AC_ARG_ENABLE(libgcj-bc,
 618   AS_HELP_STRING([--enable-libgcj-bc],
 619                  [enable(default) or disable BC ABI for portions of libgcj]),
 620   [if test "$enable_libgcj_bc" = "no"; then
 621      suppress_libgcj_bc=yes
 622    fi])
 623 AM_CONDITIONAL(SUPPRESS_LIBGCJ_BC, test "$suppress_libgcj_bc" = "yes")
 624
 625 build_libgcj_reduced_reflection=no
 626 AC_ARG_ENABLE(reduced-reflection,
 627   AS_HELP_STRING([--enable-reduced-reflection],
 628                  [enable or disable(default) -freduced-reflection when building portions of libgcj]),
 629   [if test "$enable_reduced_reflection" = "yes"; then
 630      build_libgcj_reduced_reflection=yes
 631    fi])
 632 AM_CONDITIONAL(BUILD_LIBGCJ_REDUCED_REFLECTION, test "$build_libgcj_reduced_reflection" = "yes")
 633
 634 # What is the native OS API for MinGW?
 635 AC_ARG_WITH(win32-nlsapi,
 636   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 637                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 638 [case "${withval}" in
 639   ansi) with_win32_nlsapi=ansi ;;
 640   unicows) with_win32_nlsapi=unicows ;;
 641   unicode) with_win32_nlsapi=unicode ;;
 642   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 643 esac],[with_win32_nlsapi=ansi])
 644
 645 case "${with_win32_nlsapi}" in
 646   unicows | unicode)
 647     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 648       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 649     ;;
 650 esac
 651
 652 # configure.host sets slow_pthread_self if the synchronization code should
 653 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 654 if test "${slow_pthread_self}" = "yes"; then
 655   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 656     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 657 fi
 658
 659 # Check for gc debugging.  This option is handled both here and in the GC.
 660 AC_ARG_ENABLE(gc-debug,
 661    AS_HELP_STRING([--enable-gc-debug],
 662                   [include full support for pointer backtracing etc.]),
 663 [ if test "$enable_gc_debug" = "yes"; then
 664     AC_DEFINE(LIBGCJ_GC_DEBUG, 1,
 665               [Define if we want to use debug calls into the garbage collector.])
 666   fi])
 667
 668 # See if the user has the interpreter included.
 669 AC_ARG_ENABLE(interpreter,
 670   AS_HELP_STRING([--enable-interpreter],
 671                  [enable interpreter]),
 672   [if test "$enable_interpreter" = yes; then
 673     # This can also be set in configure.host.
 674     libgcj_interpreter=yes
 675   elif test "$enable_interpreter" = no; then
 676     libgcj_interpreter=no
 677   fi])
 678
 679 if test "$libgcj_interpreter" = yes; then
 680    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 681 fi
 682 INTERPRETER="$libgcj_interpreter"
 683 AC_SUBST(INTERPRETER)
 684 AM_CONDITIONAL(INTERPRETER, test "$libgcj_interpreter" = yes)
 685
 686 AC_MSG_CHECKING([for exception model to use])
 687 AC_LANG_PUSH(C++)
 688 AC_ARG_ENABLE(sjlj-exceptions,
 689   AS_HELP_STRING([--enable-sjlj-exceptions],
 690                  [force use of builtin_setjmp for exceptions]),
 691 [:],
 692 [dnl Botheration.  Now we've got to detect the exception model.
 693 dnl Link tests against libgcc.a are problematic since -- at least
 694 dnl as of this writing -- we've not been given proper -L bits for
 695 dnl single-tree newlib and libgloss.
 696 dnl
 697 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 698 dnl conftest files before we got a change to grep them first.
 699 cat > conftest.$ac_ext << EOF
 700 [#]line __oline__ "configure"
 701 struct S { ~S(); };
 702 void bar();
 703 void foo()
 704 {
 705   S s;
 706   bar();
 707 }
 708 EOF
 709 old_CXXFLAGS="$CXXFLAGS"
 710 CXXFLAGS=-S
 711 if AC_TRY_EVAL(ac_compile); then
 712   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 713     enable_sjlj_exceptions=yes
 714   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 715     enable_sjlj_exceptions=no
 716   elif grep __cxa_end_cleanup conftest.s >/dev/null 2>&1 ; then
 717     # ARM EH ABI.
 718     enable_sjlj_exceptions=no
 719   fi
 720 fi
 721 CXXFLAGS="$old_CXXFLAGS"
 722 rm -f conftest*])
 723 if test x$enable_sjlj_exceptions = xyes; then
 724   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 725         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 726   ac_exception_model_name=sjlj
 727 elif test x$enable_sjlj_exceptions = xno; then
 728   ac_exception_model_name="call frame"
 729 else
 730   AC_MSG_ERROR([unable to detect exception model])
 731 fi
 732 AC_LANG_POP(C++)
 733 AC_MSG_RESULT($ac_exception_model_name)
 734
 735 # If we are non using SJLJ exceptions, and this host does not have support
 736 # for unwinding from a signal handler, enable checked dereferences and divides.
 737 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 738   CHECKREFSPEC=-fcheck-references
 739   DIVIDESPEC=-fuse-divide-subroutine
 740   EXCEPTIONSPEC=
 741 fi
 742
 743 # See if the user wants to disable java.net.  This is the mildly
 744 # ugly way that we admit that target-side configuration sucks.
 745 AC_ARG_ENABLE(java-net,
 746   AS_HELP_STRING([--disable-java-net],
 747                  [disable java.net]))
 748
 749 # Whether java.net is built by default can depend on the target.
 750 if test -z "$enable_java_net"; then
 751    enable_java_net=${enable_java_net_default-yes}
 752 fi
 753 if test "$enable_java_net" = no; then
 754    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 755 fi
 756
 757 # See if the user wants to configure without libffi.  Some
 758 # architectures don't support it, and default values are set in
 759 # configure.host.
 760 AC_ARG_WITH(libffi,
 761   AS_HELP_STRING([--without-libffi],
 762                  [don't use libffi]),
 763   [:],
 764   [with_libffi=${with_libffi_default-yes}])
 765
 766 LIBFFI=
 767 LIBFFIINCS=
 768 if test "$with_libffi" != no; then
 769    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 770    LIBFFI=../libffi/libffi_convenience.la
 771    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 772 fi
 773 AC_SUBST(LIBFFI)
 774 AC_SUBST(LIBFFIINCS)
 775
 776 # See if the user wants to disable JVMPI support.
 777 AC_ARG_ENABLE(jvmpi,
 778   AS_HELP_STRING([--disable-jvmpi],
 779                  [disable JVMPI support]))
 780
 781 if test "$enable_jvmpi" != no; then
 782     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 783 fi
 784
 785 # If the target is an eCos system, use the appropriate eCos
 786 # I/O routines.
 787 # FIXME: this should not be a local option but a global target
 788 # system; at present there is no eCos target.
 789 TARGET_ECOS=${PROCESS-"no"}
 790 AC_ARG_WITH(ecos,
 791 [  --with-ecos             enable runtime eCos target support],
 792 TARGET_ECOS="$with_ecos"
 793 )
 794
 795 case "$TARGET_ECOS" in
 796    no) case "$host" in
 797       *mingw*)
 798             PLATFORM=Win32
 799             PLATFORMNET=Win32
 800             PLATFORMH=win32.h
 801         CHECK_FOR_BROKEN_MINGW_LD
 802       ;;
 803       *)
 804             PLATFORM=Posix
 805             PLATFORMNET=Posix
 806             PLATFORMH=posix.h
 807       ;;
 808       esac
 809       ;;
 810    *)
 811       PLATFORM=Ecos
 812       PLATFORMNET=NoNet
 813       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 814       PLATFORMH=posix.h
 815       ;;
 816 esac
 817 AC_SUBST(PLATFORM)
 818 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 819
 820 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 821                                       [Define if you have int32_t and uint32_t.]))
 822 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 823                                         [Define if you have int32_t and uint32_t.]))
 824 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 825                                           [Define if you have u_int32_t]))
 826 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 827                                            [Define if you have u_int32_t]))
 828
 829 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 830 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix || test "$PLATFORM" = Ecos)
 831
 832 case "$host" in
 833   *-darwin*) DARWIN_CRT=true ;;
 834   *) DARWIN_CRT=false ;;
 835 esac
 836 AM_CONDITIONAL(USING_DARWIN_CRT, $DARWIN_CRT)
 837
 838 # This may not be defined in a non-ANS conformant embedded system.
 839 # FIXME: Should these case a runtime exception in that case?
 840 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 841                                   [Define is you have 'localtime' in <time.h>]))
 842
 843 # Create the subdirectory for natFile.cc, or the attempt
 844 # to create the link will fail.
 845 test -d java || mkdir java
 846 test -d java/io || mkdir java/io
 847 test -d gnu || mkdir gnu
 848 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 849
 850 # Likewise for natConcreteProcess.cc.
 851 test -d java/lang || mkdir java/lang
 852 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 853
 854 # Likewise for natVMInetAddress.cc and natVMNetworkInterface.cc.
 855 test -d java/net || mkdir java/net
 856 AC_CONFIG_LINKS(java/net/natVMInetAddress.cc:java/net/natVMInetAddress${PLATFORMNET}.cc)
 857 AC_CONFIG_LINKS(java/net/natVMNetworkInterface.cc:java/net/natVMNetworkInterface${PLATFORMNET}.cc)
 858
 859 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 860 test -d gnu/java || mkdir gnu/java
 861 test -d gnu/java/net || mkdir gnu/java/net
 862 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 863 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 864
 865 # Likewise for natVMPipe.cc and natVMSelector.cc.
 866 test -d gnu/java/nio || mkdir gnu/java/nio
 867 AC_CONFIG_LINKS(gnu/java/nio/natVMPipe.cc:gnu/java/nio/natVMPipe${PLATFORM}.cc)
 868 AC_CONFIG_LINKS(gnu/java/nio/natVMSelector.cc:gnu/java/nio/natVMSelector${PLATFORM}.cc)
 869
 870 # Likewise for natFileChannelImpl.cc
 871 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 872 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 873
 874 # Likewise for natVMSecureRandom.cc
 875 test -d gnu/java/security || mkdir gnu/java/security
 876 test -d gnu/java/security/jce || mkdir gnu/java/security/jce
 877 test -d gnu/java/security/jce/prng || mkdir gnu/java/security/jce/prng
 878 AC_CONFIG_LINKS(gnu/java/security/jce/prng/natVMSecureRandom.cc:gnu/java/security/jce/prng/natVMSecureRandom${FILE-${PLATFORM}}.cc)
 879
 880 case "${host}" in
 881     *mingw*)
 882       SYSTEMSPEC="-lgdi32 -lws2_32"
 883       if test "${with_win32_nlsapi}" = "unicows"; then
 884         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 885       fi
 886     ;;
 887     *)
 888       SYSTEMSPEC=
 889     ;;
 890 esac
 891 AC_SUBST(SYSTEMSPEC)
 892
 893 AC_ARG_WITH(system-zlib,
 894   AS_HELP_STRING([--with-system-zlib],
 895                  [use installed libz]))
 896 ZLIBSPEC=
 897 AC_SUBST(ZLIBSPEC)
 898 ZLIBTESTSPEC=
 899 AC_SUBST(ZLIBTESTSPEC)
 900
 901 AC_PATH_XTRA
 902
 903 # FIXME: this should be _libs on some hosts.
 904 libsubdir=.libs
 905
 906 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 907
 908 LIBSTDCXXSPEC=
 909 # extra LD Flags which are required for targets
 910 case "${host}" in
 911 *-*-darwin[[0-7]].*)
 912     # For now we have to disable it on darwin[8-9] because it slows down
 913     # the linking phase. A possible bug in ld?
 914     # on Darwin -single_module speeds up loading of the dynamic libraries.
 915     extra_ldflags_libjava=-Wl,-single_module
 916     ;;
 917 *-*-darwin[[912]]*)
 918     extra_gij_ldflags=-Wl,-allow_stack_execute
 919     ;;
 920 arm*linux*eabi)
 921     # Some of the ARM unwinder code is actually in libstdc++.  We
 922     # could in principle replicate it in libgcj, but it's better to
 923     # have a dependency on libstdc++.
 924     extra_ldflags='-L$(here)/../libstdc++-v3/src/.libs -lstdc++'
 925     LIBSTDCXXSPEC=-lstdc++
 926     LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -L`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -rpath `${PWDCMD-pwd}`/.libs:`${PWDCMD-pwd}`/../libstdc++-v3/src/.libs -lstdc++"
 927     ;;
 928 *-*-cygwin)
 929     extra_ldflags_libjava=-liconv
 930     ;;
 931 esac
 932 AC_SUBST(extra_ldflags_libjava)
 933 AC_SUBST(extra_gij_ldflags)
 934 AC_SUBST(extra_ldflags)
 935 AC_SUBST(LIBSTDCXXSPEC)
 936
 937 AC_SUBST(LIBGCJTESTSPEC)
 938
 939 # Allow the GC to be disabled.  Can be useful when debugging.
 940 AC_MSG_CHECKING([for garbage collector to use])
 941 AC_ARG_ENABLE(java-gc,
 942   AS_HELP_STRING([--enable-java-gc=TYPE],
 943                  [choose garbage collector (default is boehm)]),
 944   [GC=$enableval],
 945   [GC=boehm])
 946 GCLIBS=
 947 GCINCS=
 948 GCDEPS=
 949 GCSPEC=
 950 JC1GCSPEC=
 951 GCTESTSPEC=
 952 case "$GC" in
 953  boehm)
 954     AC_MSG_RESULT(boehm)
 955     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 956     JC1GCSPEC='-fuse-boehm-gc'
 957     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 958     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 959     GCOBJS=boehm.lo
 960     GCHDR=boehm-gc.h
 961     # The POSIX thread support needs to know this.
 962     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 963     ;;
 964  no)
 965     AC_MSG_RESULT(none)
 966     GCHDR=no-gc.h
 967     ;;
 968  *)
 969     AC_MSG_ERROR([unrecognized collector "$GC"])
 970     ;;
 971 esac
 972 AC_SUBST(GCLIBS)
 973 AC_SUBST(GCINCS)
 974 AC_SUBST(GCDEPS)
 975 AC_SUBST(GCSPEC)
 976 AC_SUBST(JC1GCSPEC)
 977 AC_SUBST(GCTESTSPEC)
 978 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 979 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 980 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 981
 982
 983 AC_MSG_CHECKING([for thread model used by GCC])
 984 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 985 AC_MSG_RESULT([$THREADS])
 986
 987 case "$THREADS" in
 988  no | none | single)
 989     THREADS=none
 990     ;;
 991  aix | posix | posix95 | pthreads)
 992     THREADS=posix
 993     case "$host" in
 994      *-*-linux*)
 995         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 996         ;;
 997     esac
 998     ;;
 999  win32)
1000     ;;
1001  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
1002     AC_MSG_ERROR(thread package $THREADS not yet supported)
1003     ;;
1004  *)
1005     AC_MSG_ERROR($THREADS is an unknown thread package)
1006     ;;
1007 esac
1008
1009 THREADCXXFLAGS=
1010 THREADLDFLAGS=
1011 THREADLIBS=
1012 THREADINCS=
1013 THREADDEPS=
1014 THREADH=
1015 THREADSPEC=
1016 THREADSTARTFILESPEC=
1017 case "$THREADS" in
1018  posix)
1019     case "$host" in
1020      *-*-cygwin*)
1021         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
1022         ;;
1023      *-*-freebsd[[1234]]*)
1024         # Before FreeBSD 5, it didn't have -lpthread (or any library which
1025         # merely adds pthread_* functions) but it does have a -pthread switch
1026         # which is required at link-time to select -lc_r *instead* of -lc.
1027         THREADLDFLAGS=-pthread
1028         # Don't set THREADSPEC here as might be expected since -pthread is
1029         # not processed when found within a spec file, it must come from
1030         # the command line.  For now, the user must provide the -pthread
1031         # switch to link code compiled with gcj.  In future, consider adding
1032         # support for weak references to pthread_* functions ala gthr.h API.
1033         THREADSPEC='%{!pthread: %{!shared: %eUnder this configuration, the user must provide -pthread when linking.}}'
1034         ;;
1035      *-*-freebsd*)
1036         # FreeBSD >=5.3 implements a model much closer to other modern UNIX
1037         # systems which support threads and -lpthread.
1038         THREADLDFLAGS=-pthread
1039         THREADSPEC=-lpthread
1040         ;;
1041      alpha*-dec-osf* | hppa*-hp-hpux*)
1042         THREADCXXFLAGS=-pthread
1043         # boehm-gc needs some functions from librt, so link that too.
1044         THREADLIBS='-lpthread -lrt'
1045         THREADSPEC='-lpthread -lrt'
1046         ;;
1047      *)
1048         THREADLIBS=-lpthread
1049         THREADSPEC=-lpthread
1050         ;;
1051     esac
1052     THREADH=posix-threads.h
1053     # MIT pthreads doesn't seem to have the mutexattr functions.
1054     # But for now we don't check for it.  We just assume you aren't
1055     # using MIT pthreads.
1056     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1057
1058     # If we're using the Boehm GC, then we happen to know that it
1059     # defines _REENTRANT, so we don't bother.  Eww.
1060     if test "$GC" != boehm; then
1061        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1062     fi
1063     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
1064     ;;
1065
1066  win32)
1067     THREADH=win32-threads.h
1068     THREADCXXFLAGS=-mthreads
1069     # We need thread-safe exception handling so _CRT_MT should be set to 1.
1070     # But we do not want the executables created to be dependent on
1071     # mingwm10.dll which provides a __mingwthr_key_dtor() that cleans up
1072     # exception handling contexts.  The following kludge achieves this effect
1073     # and causes a dummy __mingwthr_key_dtor() to be linked in from
1074     # libmingw32.a.  This causes a memory leak of about 24 bytes per thread.
1075     # A workaround is to explicitly use -mthreads while linking Java programs.
1076     # See PR libgcj/28263.
1077     #
1078     # FIXME: In Java we are able to detect thread death at the end of
1079     # Thread.run() so we should be able to clean up the exception handling
1080     # contexts ourselves.
1081     THREADSTARTFILESPEC='crtmt%O%s'
1082     ;;
1083
1084  none)
1085     THREADH=no-threads.h
1086     ;;
1087 esac
1088 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
1089 AC_SUBST(THREADLIBS)
1090 AC_SUBST(THREADINCS)
1091 AC_SUBST(THREADDEPS)
1092 AC_SUBST(THREADSPEC)
1093 AC_SUBST(THREADSTARTFILESPEC)
1094 AC_SUBST(THREADLDFLAGS)
1095 AC_SUBST(THREADCXXFLAGS)
1096 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
1097 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
1098 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
1099 if test "$enable_shared" != yes; then
1100   use_libgcj_bc=no
1101 fi
1102 AM_CONDITIONAL(USE_LIBGCJ_BC, test "$use_libgcj_bc" = yes)
1103
1104 if test -d sysdep; then true; else mkdir sysdep; fi
1105 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
1106 AC_CONFIG_LINKS(sysdep/backtrace.h:$fallback_backtrace_h)
1107 AC_CONFIG_LINKS(sysdep/descriptor.h:$descriptor_h)
1108
1109 LIBGCJ_SPEC_LGCJ=-lgcj
1110 LIBGCJ_SPEC_LGCJ_BC=-lgcj_bc
1111 if test x"$libgcj_spec_lgcj_override" != x ; then
1112   LIBGCJ_SPEC_LGCJ=$libgcj_spec_lgcj_override
1113 fi
1114 if test x"$libgcj_spec_lgcj_bc_override" != x ; then
1115   LIBGCJ_SPEC_LGCJ_BC=$libgcj_spec_lgcj_bc_override
1116 fi
1117 LIBGCJ_SPEC="%{s-bc-abi:} $LIBGCJ_SPEC_LGCJ"
1118 if test "$use_libgcj_bc" = yes; then
1119   LIBGCJ_SPEC="%{static|static-libgcj|!s-bc-abi:$LIBGCJ_SPEC_LGCJ;:$LIBGCJ_SPEC_LGCJ_BC}"
1120   LIBGCJ_BC_SPEC="%{findirect-dispatch:-fPIC}"
1121 fi
1122 AC_SUBST(LIBGCJ_SPEC)
1123 AC_SUBST(LIBGCJ_BC_SPEC)
1124
1125 HASH_SYNC_SPEC=
1126 # Hash synchronization is only useful with posix threads right now.
1127 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
1128    HASH_SYNC_SPEC=-fhash-synchronization
1129    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
1130 fi
1131 AC_SUBST(HASH_SYNC_SPEC)
1132
1133 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
1134
1135 # We're in the tree with gcc, and need to include some of its headers.
1136 GCC_UNWIND_INCLUDE='-I$(multi_basedir)/./libjava/../gcc'
1137
1138 if test "x${with_newlib}" = "xyes"; then
1139    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
1140    # may not work correctly, because the compiler may not be able to
1141    # link executables.
1142
1143    # We assume newlib.  This lets us hard-code the functions we know
1144    # we'll have.
1145    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
1146    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
1147    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
1148    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
1149    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
1150    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
1151    # This is only for POSIX threads.
1152    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
1153
1154    # Assume we do not have getuid and friends.
1155    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
1156    PLATFORMNET=NoNet
1157 else
1158    AC_CHECK_FUNCS([strerror_r select fstat open fsync sleep opendir \
1159                    localtime_r getpwuid_r getcwd \
1160                    access stat lstat mkdir rename rmdir unlink utime chmod readlink \
1161                    nl_langinfo setlocale \
1162                    inet_pton uname inet_ntoa \
1163                    getrlimit sigaction ftruncate mmap \
1164                    getifaddrs])
1165    AC_CHECK_FUNCS(inet_aton inet_addr, break)
1166    AC_CHECK_HEADERS(unistd.h dlfcn.h sys/resource.h)
1167    # Do an additional check on dld, HP-UX for example has dladdr in libdld.sl
1168    AC_CHECK_LIB(dl, dladdr, [
1169        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])], [
1170        AC_CHECK_LIB(dld, dladdr, [
1171        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])])])
1172
1173    if test x"$cross_compiling" = x"no"; then
1174      AC_CHECK_FILES(/proc/self/exe, [
1175        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
1176      AC_CHECK_FILES(/proc/self/maps, [
1177        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1,
1178          [Define if you have /proc/self/maps])])
1179    else
1180      case $host in
1181      *-linux*)
1182        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
1183        AC_DEFINE(HAVE_PROC_SELF_MAPS, 1, [Define if you have /proc/self/maps])
1184        ;;
1185      esac
1186    fi
1187
1188    AM_ICONV
1189    AM_LC_MESSAGES
1190    AC_STRUCT_TIMEZONE
1191
1192    AC_CHECK_FUNCS(gethostbyname_r, [
1193      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
1194        [Define if you have the 'gethostbyname_r' function.])
1195      # There are two different kinds of gethostbyname_r.
1196      # We look for the one that returns `int'.
1197      # Hopefully this check is robust enough.
1198      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
1199        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
1200
1201      case " $GCINCS " in
1202      *" -D_REENTRANT "*) ;;
1203      *)
1204         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
1205         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
1206         [libjava_cv_gethostbyname_r_needs_reentrant],
1207         [ AC_LANG_PUSH(C++)
1208           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
1209             [[gethostbyname_r("", 0, 0);]])],
1210             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
1211                 CPPFLAGS_SAVE="$CPPFLAGS"
1212                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
1213                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
1214                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
1215                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
1216                 CPPFLAGS="$CPPFLAGS_SAVE"
1217           ])
1218           AC_LANG_POP(C++)
1219         ])
1220         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
1221           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
1222         fi
1223      ;;
1224      esac
1225
1226      AC_CACHE_CHECK([for struct hostent_data],
1227         [libjava_cv_struct_hostent_data], [dnl
1228         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1229 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
1230 # define _REENTRANT 1
1231 #endif
1232 #include <netdb.h>]], [[struct hostent_data data;]])],
1233           [libjava_cv_struct_hostent_data=yes],
1234           [libjava_cv_struct_hostent_data=no])])
1235      if test "x$libjava_cv_struct_hostent_data" = xyes; then
1236        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
1237          [Define if struct hostent_data is defined in netdb.h])
1238      fi
1239    ])
1240
1241    # FIXME: libjava source code expects to find a prototype for
1242    # gethostbyaddr_r in netdb.h.  The outer check ensures that
1243    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
1244    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
1245    # linkage check is enough, yet C++ code requires proper prototypes.)
1246    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
1247    AC_CHECK_FUNCS(gethostbyaddr_r, [
1248      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
1249        [Define if you have the 'gethostbyaddr_r' function.])
1250      # There are two different kinds of gethostbyaddr_r.
1251      # We look for the one that returns `int'.
1252      # Hopefully this check is robust enough.
1253      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
1254        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
1255          [Define if gethostbyaddr_r returns 'int'.])])])])
1256
1257    AC_CHECK_FUNCS(gethostname, [
1258      AC_DEFINE(HAVE_GETHOSTNAME, 1,
1259        [Define if you have the 'gethostname' function.])
1260      AC_EGREP_HEADER(gethostname, unistd.h, [
1261        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
1262          [Define if gethostname is declared in <unistd.h>.])])])
1263
1264    AC_CHECK_FUNCS(usleep, [
1265      AC_EGREP_HEADER(usleep, unistd.h, [
1266        AC_DEFINE(HAVE_USLEEP_DECL, 1,
1267           [Define if usleep is declared in <unistd.h>.])])])
1268
1269    # Look for these functions in the thread library, but only bother
1270    # if using POSIX threads.
1271    if test "$THREADS" = posix; then
1272       save_LIBS="$LIBS"
1273       LIBS="$LIBS $THREADLIBS"
1274
1275       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
1276       # Solaris 7 the name librt is preferred.
1277       AC_CHECK_FUNCS(sched_yield, , [
1278         AC_CHECK_LIB(rt, sched_yield, [
1279           AC_DEFINE(HAVE_SCHED_YIELD)
1280           THREADLIBS="$THREADLIBS -lrt"
1281           THREADSPEC="$THREADSPEC -lrt"], [
1282           AC_CHECK_LIB(posix4, sched_yield, [
1283             AC_DEFINE(HAVE_SCHED_YIELD)
1284             THREADLIBS="$THREADLIBS -lposix4"
1285             THREADSPEC="$THREADSPEC -lposix4"])])])
1286
1287       AC_CHECK_LIB(rt, clock_gettime, [
1288          AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])
1289          case "$THREADSPEC" in
1290            *-lrt*) ;;
1291            *)
1292              THREADSPEC="$THREADSPEC -lrt"
1293              THREADLIBS="$THREADLIBS -lrt"
1294              ;;
1295          esac])
1296
1297       LIBS="$save_LIBS"
1298
1299       # We can save a little space at runtime if the mutex has m_count
1300       # or __m_count.  This is a nice hack for Linux.
1301       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1302           extern pthread_mutex_t *mutex; int q = mutex->m_count;
1303         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
1304              [Define if pthread_mutex_t has m_count member.]), [
1305         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
1306             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
1307           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
1308             [Define if pthread_mutex_t has __m_count member.]))])
1309    fi
1310
1311    # We require a way to get the time.
1312    time_found=no
1313    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
1314    if test "$time_found" = no; then
1315       AC_MSG_ERROR([no function found to get the time])
1316    fi
1317
1318    AC_CHECK_FUNCS(memmove)
1319
1320    # We require memcpy.
1321    memcpy_found=no
1322    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
1323    if test "$memcpy_found" = no; then
1324       AC_MSG_ERROR([memcpy is required])
1325    fi
1326    # Do an additional check on dld, HP-UX for example has dlopen in libdld.sl
1327    AC_CHECK_LIB(dl, dlopen, [
1328        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])], [
1329        AC_CHECK_LIB(dld, dlopen, [
1330        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])])
1331
1332    # Some library-finding code we stole from Tcl.
1333    #--------------------------------------------------------------------
1334    #    Check for the existence of the -lsocket and -lnsl libraries.
1335    #    The order here is important, so that they end up in the right
1336    #    order in the command line generated by make.  Here are some
1337    #    special considerations:
1338    #    1. Use "connect" and "accept" to check for -lsocket, and
1339    #       "gethostbyname" to check for -lnsl.
1340    #    2. Use each function name only once:  can't redo a check because
1341    #       autoconf caches the results of the last check and won't redo it.
1342    #    3. Use -lnsl and -lsocket only if they supply procedures that
1343    #       aren't already present in the normal libraries.  This is because
1344    #       IRIX 5.2 has libraries, but they aren't needed and they're
1345    #       bogus:  they goof up name resolution if used.
1346    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
1347    #       To get around this problem, check for both libraries together
1348    #       if -lsocket doesn't work by itself.
1349    #--------------------------------------------------------------------
1350
1351    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
1352     [gcj_cv_lib_sockets=
1353      gcj_checkBoth=0
1354      unset ac_cv_func_connect
1355      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
1356      if test "$gcj_checkSocket" = 1; then
1357          unset ac_cv_func_connect
1358          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
1359                       gcj_checkBoth=1)
1360      fi
1361      if test "$gcj_checkBoth" = 1; then
1362          gcj_oldLibs=$LIBS
1363          LIBS="$LIBS -lsocket -lnsl"
1364          unset ac_cv_func_accept
1365          AC_CHECK_FUNC(accept,
1366                        [gcj_checkNsl=0
1367                         gcj_cv_lib_sockets="-lsocket -lnsl"])
1368          unset ac_cv_func_accept
1369          LIBS=$gcj_oldLibs
1370      fi
1371      unset ac_cv_func_gethostbyname
1372      gcj_oldLibs=$LIBS
1373      LIBS="$LIBS $gcj_cv_lib_sockets"
1374      AC_CHECK_FUNC(gethostbyname, ,
1375                    [AC_CHECK_LIB(nsl, main,
1376                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
1377      unset ac_cv_func_gethostbyname
1378      LIBS=$gcj_oldLIBS
1379    ])
1380    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1381
1382    if test "$with_system_zlib" = yes; then
1383       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1384    fi
1385
1386    # Test for Gtk stuff, if asked for.
1387    if test "$use_gtk_awt" = yes; then
1388       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1389       AC_SUBST(GTK_CFLAGS)
1390       AC_SUBST(GTK_LIBS)
1391
1392       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1393       AC_SUBST(GLIB_CFLAGS)
1394       AC_SUBST(GLIB_LIBS)
1395
1396       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1397       AC_SUBST(LIBART_CFLAGS)
1398       AC_SUBST(LIBART_LIBS)
1399
1400       # We require the XTest Extension to support java.awt.Robot.
1401       AC_CHECK_LIB([Xtst], [XTestQueryExtension], [true],
1402                    [AC_MSG_ERROR([libXtst not found, required by java.awt.Robot])],
1403                    [${X_LIBS}])
1404    fi
1405
1406    # On Solaris, and maybe other architectures, the Boehm collector
1407    # requires -ldl.
1408    if test "$GC" = boehm; then
1409       case "${host}" in
1410           mips-sgi-irix6*)
1411             # IRIX 6 lacks a N64 libdl.so, but only the N32 (default multilib)
1412             # libgcj.spec is used, so override here
1413             SYSTEMSPEC="$SYSTEMSPEC %{!mabi=64:-ldl}"
1414           ;;
1415           *)
1416             AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1417           ;;
1418       esac
1419    fi
1420 fi
1421
1422 # Use a semicolon as CLASSPATH separator for MinGW, otherwise a colon.
1423 case $build in
1424     *-mingw32) CLASSPATH_SEPARATOR=';' ;;
1425     *)         CLASSPATH_SEPARATOR=':' ;;
1426 esac
1427 AC_SUBST(CLASSPATH_SEPARATOR)
1428
1429 # We must search the source tree for java.lang, since we still don't
1430 # have libgcj.jar nor java/lang/*.class
1431 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1432 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1433
1434 # Since some classes depend on this one, we need its source available
1435 # before we can do any GCJ compilation test :-(
1436 if test ! -f gnu/classpath/Configuration.java; then
1437   test -d gnu || mkdir gnu
1438   test -d gnu/classpath || mkdir gnu/classpath
1439   # Note that it is not crucial that all the values here be correct.
1440   sed -e "s,@prefix@,$prefix," \
1441       -e "s,@VERSION@,$VERSION," \
1442       -e "s,@LIBDEBUG@,false," \
1443       -e "s,@INIT_LOAD_LIBRARY@,false," \
1444       -e "s,@@,$LIBGCJDEBUG," \
1445       -e "s,@default_toolkit@,$TOOLKIT," \
1446       -e "s,@JAVA_LANG_SYSTEM_EXPLICIT_INITIALIZATION@,false," \
1447       -e "s,@GTK_CAIRO_ENABLED@,false," \
1448       -e "s,@ECJ_JAR@,," \
1449       -e "s,@WANT_NATIVE_BIG_INTEGER@,false," \
1450         < $srcdir/classpath/gnu/classpath/Configuration.java.in \
1451         > gnu/classpath/Configuration.java
1452   # We do not want to redirect the output of the grep below to /dev/null,
1453   # but we add /dev/null to the input list so that grep will print the
1454   # filename of Configuration.java in case it finds any matches.
1455   if grep '@.*@' gnu/classpath/Configuration.java /dev/null; then
1456     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1457   fi
1458 fi
1459
1460 LT_AC_PROG_GCJ
1461
1462 # Now remove it.
1463 rm -f gnu/classpath/Configuration.java
1464
1465 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1466
1467 AC_CHECK_SIZEOF(void *)
1468
1469 AC_C_BIGENDIAN
1470
1471 ZLIBS=
1472 SYS_ZLIBS=
1473 ZINCS=
1474
1475 if test -z "$ZLIBSPEC"; then
1476    # Use zlib from the GCC tree.
1477    ZINCS='-I$(top_srcdir)/../zlib'
1478    ZLIBS=../zlib/libzgcj_convenience.la
1479 else
1480    # System's zlib.
1481    SYS_ZLIBS="$ZLIBSPEC"
1482 fi
1483 AC_SUBST(ZLIBS)
1484 AC_SUBST(SYS_ZLIBS)
1485 AC_SUBST(ZINCS)
1486 AC_SUBST(DIVIDESPEC)
1487 AC_SUBST(CHECKREFSPEC)
1488 AC_SUBST(EXCEPTIONSPEC)
1489 AC_SUBST(BACKTRACESPEC)
1490 AC_SUBST(IEEESPEC)
1491 AC_SUBST(ATOMICSPEC)
1492
1493 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1494 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = yes)
1495 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1496 AM_CONDITIONAL(INSTALL_BINARIES, test -z "${with_multisubdir}")
1497 AC_SUBST(GCC_UNWIND_INCLUDE)
1498
1499 # Process the option "--enable-version-specific-runtime-libs"
1500 # Calculate toolexeclibdir
1501 case ${version_specific_libs} in
1502   yes)
1503     # Need the gcc compiler version to know where to install libraries
1504     # and header files if --enable-version-specific-runtime-libs option
1505     # is selected.
1506     includedir='$(libdir)/gcc/$(target_noncanonical)/$(gcc_version)/include/'
1507     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1508     toolexecmainlibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
1509     toolexeclibdir=$toolexecmainlibdir
1510     ;;
1511   no)
1512     if test -n "$with_cross_host" &&
1513        test x"$with_cross_host" != x"no"; then
1514       # Install a library built with a cross compiler in tooldir, not libdir.
1515       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1516       toolexecmainlibdir='$(toolexecdir)/lib'
1517     else
1518       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1519       toolexecmainlibdir='$(libdir)'
1520     fi
1521     multi_os_directory=`$CC -print-multi-os-directory`
1522     case $multi_os_directory in
1523       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1524       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1525     esac
1526     ;;
1527 esac
1528 AC_SUBST(toolexecdir)
1529 AC_SUBST(toolexecmainlibdir)
1530 AC_SUBST(toolexeclibdir)
1531
1532 # Determine gcj and libgcj version number.
1533 gcjversion=`cat "$srcdir/../gcc/BASE-VER"`
1534 libgcj_soversion=`awk -F: '/^[[^#]].*:/ { print $1 }' $srcdir/libtool-version`
1535 GCJVERSION=$gcjversion
1536 AC_SUBST(GCJVERSION)
1537 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1538
1539 # Determine where the standard .db file and GNU Classpath JNI
1540 # libraries are found.
1541 gcjsubdir=gcj-$gcjversion-$libgcj_soversion
1542 multi_os_directory=`$CC -print-multi-os-directory`
1543 case $multi_os_directory in
1544   .)
1545    dbexecdir='$(libdir)/'$gcjsubdir # Avoid /.
1546    ;;
1547   *)
1548    dbexecdir='$(libdir)/'$multi_os_directory/$gcjsubdir
1549    ;;
1550 esac
1551 AC_SUBST(dbexecdir)
1552 AC_SUBST(gcjsubdir)
1553
1554 AC_DEFINE(JV_VERSION, "1.5.0", [Compatibility version string])
1555 AC_DEFINE(JV_API_VERSION, "1.5", [API compatibility version string])
1556
1557 TL_AC_GXX_INCLUDE_DIR
1558
1559 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1560 # On that system, sys/ioctl.h will not include sys/filio.h unless
1561 # BSD_COMP is defined; just including sys/filio.h is simpler.
1562 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1563 # for now.  If you change this, you also must update natFile.cc.
1564 AC_CHECK_HEADERS([unistd.h bstring.h sys/time.h sys/types.h fcntl.h \
1565                   sys/ioctl.h sys/filio.h sys/stat.h sys/select.h \
1566                   sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h \
1567                   pwd.h sys/config.h stdint.h langinfo.h locale.h \
1568                   dirent.h sys/rw_lock.h magic.h ifaddrs.h])
1569 AC_CHECK_HEADERS(inttypes.h, [
1570     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1571     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1572 ])
1573
1574 AC_CHECK_TYPE([ssize_t], [int])
1575 AC_CHECK_TYPE([magic_t], [
1576     AC_DEFINE(HAVE_MAGIC_T, 1, [Define if magic.h declares magic_t])], [], [
1577 #ifdef HAVE_MAGIC_H
1578 #include <magic.h>
1579 #endif])
1580
1581 AC_MSG_CHECKING([for in_addr_t])
1582 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1583 #if STDC_HEADERS
1584 #include <stdlib.h>
1585 #include <stddef.h>
1586 #endif
1587 #if HAVE_NETINET_IN_H
1588 #include <netinet/in.h>
1589 #endif]], [[in_addr_t foo;]])],
1590   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1591      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1592    AC_MSG_RESULT(yes)],
1593   [AC_MSG_RESULT(no)])
1594
1595 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1596 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1597   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1598      [Define if struct ip_mreq is defined in netinet/in.h.])
1599    AC_MSG_RESULT(yes)],
1600   [AC_MSG_RESULT(no)])
1601
1602 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1603 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1604   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1605      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1606    AC_MSG_RESULT(yes)],
1607   [AC_MSG_RESULT(no)])
1608
1609 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1610 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1611   [AC_DEFINE(HAVE_INET6, 1,
1612      [Define if inet6 structures are defined in netinet/in.h.])
1613    AC_MSG_RESULT(yes)],
1614   [AC_MSG_RESULT(no)])
1615
1616 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1617 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1618 #include <sys/types.h>
1619 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1620   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1621    AC_MSG_RESULT(yes)],
1622   [AC_MSG_RESULT(no)])
1623
1624 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1625 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1626   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1627    AC_MSG_RESULT(yes)],
1628   [AC_MSG_RESULT(no)
1629    AC_MSG_CHECKING([for global timezone variable])
1630    dnl FIXME: we don't want a link check here because that won't work
1631    dnl when cross-compiling.  So instead we make an assumption that
1632    dnl the header file will mention timezone if it exists.
1633    dnl Don't find the win32 function timezone
1634    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1635      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1636       AC_MSG_RESULT(yes)],
1637      [AC_MSG_RESULT(no)
1638        AC_MSG_CHECKING([for global _timezone variable])
1639        dnl FIXME: As above, don't want link check
1640        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1641          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1642             [Define if your platform has the global _timezone variable.])
1643           AC_MSG_RESULT(yes)],
1644           [AC_MSG_RESULT(no)])])])
1645
1646 AC_CHECK_PROGS(PERL, perl, false)
1647
1648 SYSDEP_SOURCES=
1649 SIGNAL_HANDLER_AUX=
1650
1651 case "${host}" in
1652  i?86-*-linux*)
1653     SIGNAL_HANDLER=include/i386-signal.h
1654     ;;
1655  sparc*-sun-solaris*)
1656     SIGNAL_HANDLER=include/sparc-signal.h
1657     ;;
1658 # ia64-*)
1659 #    SYSDEP_SOURCES=sysdep/ia64.c
1660 #    test -d sysdep || mkdir sysdep
1661 #    ;;
1662  hppa*-*-linux*)
1663     SIGNAL_HANDLER=include/pa-signal.h
1664     ;;
1665  hppa*-hp-hpux*)
1666     SIGNAL_HANDLER=include/hppa-signal.h
1667     ;;
1668  ia64-*-linux*)
1669     SIGNAL_HANDLER=include/dwarf2-signal.h
1670     ;;
1671  powerpc*-*-linux*)
1672     SIGNAL_HANDLER=include/powerpc-signal.h
1673     ;;
1674  alpha*-*-linux*)
1675     SIGNAL_HANDLER=include/dwarf2-signal.h
1676     ;;
1677  s390*-*-linux*)
1678     SIGNAL_HANDLER=include/s390-signal.h
1679     ;;
1680  x86_64*-*-linux*)
1681     SIGNAL_HANDLER=include/x86_64-signal.h
1682     SIGNAL_HANDLER_AUX=include/i386-signal.h
1683     ;;
1684  sparc*-*-linux*)
1685     SIGNAL_HANDLER=include/dwarf2-signal.h
1686     ;;
1687  sh*-*-linux*)
1688     SIGNAL_HANDLER=include/sh-signal.h
1689     ;;
1690  *mingw*)
1691     SIGNAL_HANDLER=include/win32-signal.h
1692     ;;
1693  mips*-*-linux*)
1694     SIGNAL_HANDLER=include/mips-signal.h
1695     ;;
1696  m68*-*-linux*)
1697     SIGNAL_HANDLER=include/dwarf2-signal.h
1698     ;;
1699  powerpc*-*-darwin* | i?86-*-darwin[[912]]* | x86_64-*-darwin[[912]]*)
1700     SIGNAL_HANDLER=include/darwin-signal.h
1701     ;;
1702  powerpc*-*-aix*)
1703     SIGNAL_HANDLER=include/aix-signal.h
1704     ;;
1705  *)
1706     SIGNAL_HANDLER=include/default-signal.h
1707     ;;
1708 esac
1709
1710 # If we're using sjlj exceptions, forget what we just learned.
1711 if test "$enable_sjlj_exceptions" = yes; then
1712    SIGNAL_HANDLER=include/default-signal.h
1713    SIGNAL_HANDLER_AUX=
1714 fi
1715
1716 AC_SUBST(SYSDEP_SOURCES)
1717
1718 if test -z "$SIGNAL_HANDLER_AUX"; then
1719   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1720 fi
1721
1722 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1723                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1724
1725 if test "${multilib}" = "yes"; then
1726   multilib_arg="--enable-multilib"
1727 else
1728   multilib_arg=
1729 fi
1730
1731 # See if we support thread-local storage.
1732 GCC_CHECK_TLS
1733
1734 # For _Unwind_GetIPInfo.
1735 GCC_CHECK_UNWIND_GETIPINFO
1736
1737 # See if linker supports anonymous version scripts.
1738 AC_CACHE_CHECK([whether ld supports anonymous version scripts],
1739   [libjava_cv_anon_version_script],
1740   [save_CFLAGS="$CFLAGS"; save_LDFLAGS="$LDFLAGS"
1741    libjava_cv_anon_version_script=no
1742    CFLAGS="$CFLAGS -fPIC"; LDFLAGS="$LDFLAGS -shared -Wl,--version-script,conftest.map"
1743    echo '{ global: globalsymb*; local: *; };' > conftest.map
1744    AC_TRY_LINK(void globalsymbol (void) {} void localsymbol (void) {},,
1745                [libjava_cv_anon_version_script=yes], [])
1746    CFLAGS="$save_CFLAGS"; LDFLAGS="$save_LDFLAGS"
1747   ])
1748 AM_CONDITIONAL(ANONVERSCRIPT, test "$libjava_cv_anon_version_script" = yes)
1749
1750 # Check if linker supports static linking on a per library basis
1751 LD_START_STATIC_SPEC=
1752 LD_FINISH_STATIC_SPEC=
1753 if $LD --help 2>&1 | grep -q -e -call_shared ; then
1754   if $LD --help 2>&1 | grep -q -e -non_shared ; then
1755     LD_START_STATIC_SPEC='%{static-libgcj:-non_shared}'
1756     LD_FINISH_STATIC_SPEC='%{static-libgcj:-call_shared}'
1757   fi
1758 fi
1759 AC_SUBST(LD_START_STATIC_SPEC)
1760 AC_SUBST(LD_FINISH_STATIC_SPEC)
1761
1762 here=`${PWDCMD-pwd}`
1763 AC_SUBST(here)
1764
1765 # We get this from the environment.
1766 AC_SUBST(GCJFLAGS)
1767
1768 AC_ARG_WITH([python-dir],
1769             AS_HELP_STRING([--with-python-dir],
1770                            [the location to install Python modules. This path should NOT include the prefix.]),
1771             [with_python_dir=$withval], [with_python_dir=""])
1772
1773 if test "x${with_python_dir}" = "x"
1774 then
1775   # Needed for installing Python modules during make install.
1776   python_mod_dir="\${prefix}/share/python"
1777   # Needed for substituting into aot-compile*
1778   python_mod_dir_expanded="${prefix}/share/python"
1779 else
1780   python_mod_dir="\${prefix}${with_python_dir}"
1781   python_mod_dir_expanded="${prefix}${with_python_dir}"
1782 fi
1783 AC_MSG_RESULT(Python modules dir: ${python_mod_dir_expanded});
1784 AC_SUBST(python_mod_dir)
1785 AC_SUBST(python_mod_dir_expanded)
1786
1787 # needed for aot-compile-rpm
1788 MAKE=`which make`
1789 AC_SUBST(MAKE)
1790
1791 AC_ARG_ENABLE([aot-compile-rpm],
1792   [AS_HELP_STRING([--enable-aot-compile-rpm],
1793                  [enable installation of aot-compile-rpm [default=no]])],
1794   [case "${enableval}" in
1795     yes) AOT_RPM_ENABLED=yes ;;
1796     no)  AOT_RPM_ENABLED=no ;;
1797     *)   AC_MSG_ERROR([Unknown argument to enable/disable aot-compile-rpm]) ;;
1798   esac],
1799   [AOT_RPM_ENABLED=no]
1800 )
1801 AM_CONDITIONAL(INSTALL_AOT_RPM, test "x${AOT_RPM_ENABLED}" = xyes)
1802
1803 AC_ARG_ENABLE([java-home],
1804   [AS_HELP_STRING([--enable-java-home],
1805                  [create a standard JDK-style directory layout in the install tree [default=no]])],
1806   [case "${enableval}" in
1807     yes) JAVA_HOME_ENABLED=yes ;;
1808     no)  JAVA_HOME_ENABLED=no ;;
1809     *)   AC_MSG_ERROR([Unknown argument to enable/disable java-home]) ;;
1810   esac],
1811   [JAVA_HOME_ENABLED=no]
1812 )
1813 AM_CONDITIONAL(CREATE_JAVA_HOME, test "x${JAVA_HOME_ENABLED}" = xyes)
1814
1815 # Only do these checks if java-home above is enabled.
1816 if test "x${JAVA_HOME_ENABLED}" = xyes
1817 then
1818
1819   AC_ARG_WITH([gcc-suffix],
1820               AS_HELP_STRING([--with-gcc-suffix],
1821                              [the GCC tool suffix (defaults to empty string)]),
1822               [gcc_suffix=$withval], [gcc_suffix=""])
1823   AC_MSG_RESULT(GCC suffix: ${gcc_suffix})
1824   AC_SUBST(gcc_suffix)
1825
1826   AC_ARG_WITH([arch-directory],
1827               AS_HELP_STRING([--with-arch-directory],
1828                              [the arch directory under jre/lib (defaults to auto-detect)]),
1829               [host_cpu=$withval], [host_cpu=""])
1830
1831   AC_ARG_WITH([os-directory],
1832               AS_HELP_STRING([--with-os-directory],
1833                              [the os directory under include (defaults to auto-detect)]),
1834               [host_os=$withval], [host_os=""])
1835
1836   AC_ARG_WITH([origin-name],
1837               AS_HELP_STRING([--with-origin-name],
1838                              [the JPackage origin name of this package (default is gcj${gcc_suffix}]),
1839               [origin_name=$withval], [origin_name=gcj${gcc_suffix}])
1840   AC_MSG_RESULT(JPackage origin name: ${origin_name})
1841
1842   AC_ARG_WITH([arch-suffix],
1843               AS_HELP_STRING([--with-arch-suffix],
1844                              [the arch directory suffix (default is the empty string]),
1845               [arch_suffix=$withval], [arch_suffix=""])
1846   AC_MSG_RESULT(arch suffix: ${arch_suffix})
1847
1848   AC_ARG_WITH([jvm-root-dir],
1849               AS_HELP_STRING([--with-jvm-root-dir],
1850                              [where to install SDK (default is ${prefix}/lib/jvm)]),
1851               [jvm_root_dir=$withval], [jvm_root_dir="\${prefix}/lib/jvm"])
1852   AC_MSG_RESULT(JVM root installation directory: ${jvm_root_dir})
1853
1854   AC_ARG_WITH([jvm-jar-dir],
1855               AS_HELP_STRING([--with-jvm-jar-dir],
1856                                          [where to install jars (default is ${prefix}/lib/jvm-exports)]),
1857               [jvm_jar_dir=$withval], [jvm_jar_dir=\${prefix}/lib/jvm-exports])
1858   AC_MSG_RESULT(JAR root installation directory: ${jvm_jar_dir})
1859
1860   JAVA_VERSION=1.5.0
1861   BUILD_VERSION=0
1862   AC_SUBST(JAVA_VERSION)
1863   AC_SUBST(BUILD_VERSION)
1864   AC_MSG_RESULT(Java version: ${JAVA_VERSION})
1865
1866   jre_dir=jre
1867   jre_lnk=jre-${JAVA_VERSION}-${origin_name}
1868   sdk_lnk=java-${JAVA_VERSION}-${origin_name}
1869
1870   JVM_ROOT_DIR=${jvm_root_dir}
1871   AC_SUBST(JVM_ROOT_DIR)
1872   AC_MSG_RESULT(JVM ROOT directory: ${JVM_ROOT_DIR})
1873
1874   JVM_JAR_ROOT_DIR=${jvm_jar_dir}
1875   AC_SUBST(JVM_JAR_ROOT_DIR)
1876   AC_MSG_RESULT(JVM JAR ROOT directory: ${JVM_JAR_ROOT_DIR})
1877
1878   JVM_JAR_DIR=${jvm_jar_dir}
1879   AC_SUBST(JVM_JAR_DIR)
1880   AC_MSG_RESULT(JVM JAR directory: ${JVM_JAR_DIR})
1881
1882   JRE_DIR=${jre_dir}
1883   AC_SUBST(JRE_DIR)
1884
1885   JRE_LNK=${jre_lnk}
1886   AC_SUBST(JRE_LNK)
1887
1888   SDK_LNK=${sdk_lnk}
1889   AC_SUBST(SDK_LNK)
1890
1891   SDK_BIN_DIR=${jvm_root_dir}/bin
1892   AC_SUBST(SDK_BIN_DIR)
1893   AC_MSG_RESULT(SDK tools directory: ${SDK_BIN_DIR})
1894
1895   SDK_LIB_DIR=${jvm_root_dir}/lib
1896   AC_SUBST(SDK_LIB_DIR)
1897   AC_MSG_RESULT(SDK jar directory: ${SDK_LIB_DIR})
1898
1899   SDK_INCLUDE_DIR=${jvm_root_dir}/include
1900   AC_SUBST(SDK_INCLUDE_DIR)
1901   AC_MSG_RESULT(SDK include directory: ${SDK_INCLUDE_DIR})
1902
1903   JRE_BIN_DIR=${jvm_root_dir}/${jre_dir}/bin
1904   AC_SUBST(JRE_BIN_DIR)
1905   AC_MSG_RESULT(JRE tools directory: ${JRE_BIN_DIR})
1906
1907   JRE_LIB_DIR=${jvm_root_dir}/${jre_dir}/lib
1908   AC_SUBST(JRE_LIB_DIR)
1909   AC_MSG_RESULT(JRE lib directory: ${JRE_LIB_DIR})
1910
1911   # Find gcj prefix using gcj found in PATH.
1912   gcj_prefix=`which gcj${gcc_suffix} | sed "s%/bin/gcj${gcc_suffix}%%"`
1913
1914   # Where do the gcj binaries live?
1915   # For jhbuild based builds, they all live in a sibling of bin called
1916   # gcj-bin.  Check for gcj-bin first, and use bin otherwise.
1917   GCJ_BIN_DIR=`if test -d ${gcj_prefix}/gcj-bin; then echo ${gcj_prefix}/gcj-bin; else echo ${gcj_prefix}/bin; fi`
1918   AC_SUBST(GCJ_BIN_DIR)
1919   AC_MSG_RESULT(GCJ tools directory: ${GCJ_BIN_DIR})
1920
1921   AC_MSG_RESULT(host is ${host})
1922   if test "x${host_cpu}" = "x"
1923   then
1924     case ${host} in
1925       *-mingw* | *-cygwin*)
1926         host_cpu=x86;;
1927       i486-* | i586-* | i686-*)
1928         host_cpu=i386;;
1929       x86_64-*)
1930         host_cpu=amd64;;
1931       *)
1932         host_cpu=${host_cpu};;
1933     esac
1934   fi
1935   AC_MSG_RESULT(arch directory: ${host_cpu})
1936   CPU=${host_cpu}
1937   AC_SUBST(CPU)
1938
1939   if test "x${host_os}" = "x"
1940   then
1941     case ${host} in
1942       *-mingw* | *-cygwin*)
1943         host_os=win32;;
1944       *-linux*)
1945         host_os=linux;;
1946       *)
1947         host_os=${host_os};;
1948     esac
1949   fi
1950   echo os directory: ${host_os}
1951   OS=${host_os}
1952   AC_SUBST(OS)
1953
1954   # make an expanded $libdir, for substituting into
1955   # scripts (and other non-Makefile things).
1956   LIBDIR=$libdir
1957   if test "x${exec_prefix}" = "xNONE"
1958   then
1959       lib_exec_prefix=$prefix
1960   else
1961       lib_exec_prefix=$exec_prefix
1962   fi
1963   LIBDIR=`echo $libdir | sed "s:\\\${exec_prefix}:$lib_exec_prefix:g"`
1964   AC_SUBST(LIBDIR)
1965 fi
1966
1967 AC_CONFIG_FILES([
1968 Makefile
1969 libgcj.pc
1970 libgcj.spec
1971 libgcj-test.spec
1972 gcj/Makefile
1973 include/Makefile
1974 testsuite/Makefile
1975 contrib/aotcompile.py
1976 contrib/aot-compile
1977 contrib/aot-compile-rpm
1978 contrib/generate-cacerts.pl
1979 contrib/rebuild-gcj-db
1980 ])
1981
1982 if test ${multilib} = yes; then
1983   multilib_arg="--enable-multilib"
1984 else
1985   multilib_arg=
1986 fi
1987
1988 AC_CONFIG_FILES([scripts/jar], [chmod +x scripts/jar])
1989 AC_OUTPUT