libbacktrace/configure.ac

   1 # configure.ac -- Backtrace configure script.
   2 # Copyright (C) 2012-2017 Free Software Foundation, Inc.
   3
   4 # Redistribution and use in source and binary forms, with or without
   5 # modification, are permitted provided that the following conditions are
   6 # met:
   7
   8 #     (1) Redistributions of source code must retain the above copyright
   9 #     notice, this list of conditions and the following disclaimer.
  10
  11 #     (2) Redistributions in binary form must reproduce the above copyright
  12 #     notice, this list of conditions and the following disclaimer in
  13 #     the documentation and/or other materials provided with the
  14 #     distribution.
  15
  16 #     (3) The name of the author may not be used to
  17 #     endorse or promote products derived from this software without
  18 #     specific prior written permission.
  19
  20 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  21 # IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  22 # WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE
  23 # DISCLAIMED. IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT,
  24 # INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES
  25 # (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR
  26 # SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27 # HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
  28 # STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING
  29 # IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  30 # POSSIBILITY OF SUCH DAMAGE.
  31
  32 AC_PREREQ(2.64)
  33 AC_INIT(package-unused, version-unused,, libbacktrace)
  34 AC_CONFIG_SRCDIR(backtrace.h)
  35 AC_CONFIG_HEADER(config.h)
  36
  37 if test -n "${with_target_subdir}"; then
  38   AM_ENABLE_MULTILIB(, ..)
  39 fi
  40
  41 AC_CANONICAL_SYSTEM
  42 target_alias=${target_alias-$host_alias}
  43
  44 AC_USE_SYSTEM_EXTENSIONS
  45
  46 libtool_VERSION=1:0:0
  47 AC_SUBST(libtool_VERSION)
  48
  49 # 1.11.1: Require that version of automake.
  50 # foreign: Don't require README, INSTALL, NEWS, etc.
  51 # no-define: Don't define PACKAGE and VERSION.
  52 # no-dependencies: Don't generate automatic dependencies.
  53 #    (because it breaks when using bootstrap-lean, since some of the
  54 #    headers are gone at "make install" time).
  55 # -Wall: Issue all automake warnings.
  56 # -Wno-portability: Don't warn about constructs supported by GNU make.
  57 #    (because GCC requires GNU make anyhow).
  58 AM_INIT_AUTOMAKE([1.11.1 foreign no-dist no-define no-dependencies -Wall -Wno-portability])
  59
  60 AM_MAINTAINER_MODE
  61
  62 AC_ARG_WITH(target-subdir,
  63 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  64
  65 # We must force CC to /not/ be precious variables; otherwise
  66 # the wrong, non-multilib-adjusted value will be used in multilibs.
  67 # As a side effect, we have to subst CFLAGS ourselves.
  68 m4_rename([_AC_ARG_VAR_PRECIOUS],[backtrace_PRECIOUS])
  69 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  70 AC_PROG_CC
  71 m4_rename_force([backtrace_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  72
  73 AC_SUBST(CFLAGS)
  74
  75 AC_PROG_RANLIB
  76
  77 AC_PROG_AWK
  78 case "$AWK" in
  79 "") AC_MSG_ERROR([can't build without awk]) ;;
  80 esac
  81
  82 LT_INIT
  83 AM_PROG_LIBTOOL
  84
  85 AC_SYS_LARGEFILE
  86
  87 backtrace_supported=yes
  88
  89 if test -n "${with_target_subdir}"; then
  90   # We are compiling a GCC library.  We can assume that the unwind
  91   # library exists.
  92   BACKTRACE_FILE="backtrace.lo simple.lo"
  93 else
  94   AC_CHECK_HEADER([unwind.h],
  95     [AC_CHECK_FUNC([_Unwind_Backtrace],
  96                    [BACKTRACE_FILE="backtrace.lo simple.lo"],
  97                    [BACKTRACE_FILE="nounwind.lo"
  98                     backtrace_supported=no])],
  99     [BACKTRACE_FILE="nounwind.lo"
 100      backtrace_supported=no])
 101 fi
 102 AC_SUBST(BACKTRACE_FILE)
 103
 104 EXTRA_FLAGS=
 105 if test -n "${with_target_subdir}"; then
 106   EXTRA_FLAGS="-funwind-tables -frandom-seed=\$@"
 107 else
 108   AC_CACHE_CHECK([for -funwind-tables option],
 109     [libbacktrace_cv_c_unwind_tables],
 110     [CFLAGS_hold="$CFLAGS"
 111      CFLAGS="$CFLAGS -funwind-tables"
 112      AC_COMPILE_IFELSE(
 113        [AC_LANG_PROGRAM([static int f() { return 0; }], [return f();])],
 114        [libbacktrace_cv_c_unwind_tables=yes],
 115        [libbacktrace_cv_c_unwind_tables=no])
 116      CFLAGS="$CFLAGS_hold"])
 117   if test "$libbacktrace_cv_c_unwind_tables" = "yes"; then
 118     EXTRA_FLAGS=-funwind-tables
 119   fi
 120   AC_CACHE_CHECK([for -frandom-seed=string option],
 121     [libbacktrace_cv_c_random_seed_string],
 122     [CFLAGS_hold="$CFLAGS"
 123      CFLAGS="$CFLAGS -frandom-seed=conftest.lo"
 124      AC_COMPILE_IFELSE(
 125        [AC_LANG_PROGRAM([], [return 0;])],
 126        [libbacktrace_cv_c_random_seed_string=yes],
 127        [libbacktrace_cv_c_random_seed_string=no])
 128      CFLAGS="$CFLAGS_hold"])
 129   if test "$libbacktrace_cv_c_random_seed_string" = "yes"; then
 130     EXTRA_FLAGS="$EXTRA_FLAGS -frandom-seed=\$@"
 131   fi
 132 fi
 133 AC_SUBST(EXTRA_FLAGS)
 134
 135 ACX_PROG_CC_WARNING_OPTS([-W -Wall -Wwrite-strings -Wstrict-prototypes \
 136                           -Wmissing-prototypes -Wold-style-definition \
 137                           -Wmissing-format-attribute -Wcast-qual],
 138                           [WARN_FLAGS])
 139
 140 if test -n "${with_target_subdir}"; then
 141   WARN_FLAGS="$WARN_FLAGS -Werror"
 142 fi
 143
 144 AC_SUBST(WARN_FLAGS)
 145
 146 if test -n "${with_target_subdir}"; then
 147   GCC_CHECK_UNWIND_GETIPINFO
 148 else
 149   ac_save_CFFLAGS="$CFLAGS"
 150   CFLAGS="$CFLAGS -Werror-implicit-function-declaration"
 151   AC_MSG_CHECKING([for _Unwind_GetIPInfo])
 152   AC_LINK_IFELSE(
 153     [AC_LANG_PROGRAM(
 154        [#include "unwind.h"
 155         struct _Unwind_Context *context;
 156         int ip_before_insn = 0;],
 157         [return _Unwind_GetIPInfo (context, &ip_before_insn);])],
 158         [have_unwind_getipinfo=yes], [have_unwind_getipinfo=no])
 159   CFLAGS="$ac_save_CFLAGS"
 160   AC_MSG_RESULT([$have_unwind_getipinfo])
 161   if test "$have_unwind_getipinfo" = "yes"; then
 162     AC_DEFINE(HAVE_GETIPINFO, 1, [Define if _Unwind_GetIPInfo is available.])
 163   fi
 164 fi
 165
 166 # Enable --enable-host-shared.
 167 AC_ARG_ENABLE(host-shared,
 168 [AS_HELP_STRING([--enable-host-shared],
 169                 [build host code as shared libraries])],
 170 [PIC_FLAG=-fPIC], [PIC_FLAG=])
 171 AC_SUBST(PIC_FLAG)
 172
 173 # Test for __sync support.
 174 AC_CACHE_CHECK([__sync extensions],
 175 [libbacktrace_cv_sys_sync],
 176 [if test -n "${with_target_subdir}"; then
 177    case "${host}" in
 178    hppa*-*-hpux*) libbacktrace_cv_sys_sync=no ;;
 179    *) libbacktrace_cv_sys_sync=yes ;;
 180    esac
 181  else
 182    AC_LINK_IFELSE(
 183      [AC_LANG_PROGRAM([int i;],
 184                       [__sync_bool_compare_and_swap (&i, i, i);
 185                        __sync_lock_test_and_set (&i, 1);
 186                        __sync_lock_release (&i);])],
 187      [libbacktrace_cv_sys_sync=yes],
 188      [libbacktrace_cv_sys_sync=no])
 189  fi])
 190 BACKTRACE_SUPPORTS_THREADS=0
 191 if test "$libbacktrace_cv_sys_sync" = "yes"; then
 192   BACKTRACE_SUPPORTS_THREADS=1
 193   AC_DEFINE([HAVE_SYNC_FUNCTIONS], 1,
 194             [Define to 1 if you have the __sync functions])
 195 fi
 196 AC_SUBST(BACKTRACE_SUPPORTS_THREADS)
 197
 198 # Test for __atomic support.
 199 AC_CACHE_CHECK([__atomic extensions],
 200 [libbacktrace_cv_sys_atomic],
 201 [if test -n "${with_target_subdir}"; then
 202    libbacktrace_cv_sys_atomic=yes
 203  else
 204    AC_LINK_IFELSE(
 205      [AC_LANG_PROGRAM([int i;],
 206                       [__atomic_load_n (&i, __ATOMIC_ACQUIRE);
 207                        __atomic_store_n (&i, 1, __ATOMIC_RELEASE);])],
 208      [libbacktrace_cv_sys_atomic=yes],
 209      [libbacktrace_cv_sys_atomic=no])
 210  fi])
 211 if test "$libbacktrace_cv_sys_atomic" = "yes"; then
 212   AC_DEFINE([HAVE_ATOMIC_FUNCTIONS], 1,
 213             [Define to 1 if you have the __atomic functions])
 214 fi
 215
 216 # The library needs to be able to read the executable itself.  Compile
 217 # a file to determine the executable format.  The awk script
 218 # filetype.awk prints out the file type.
 219 AC_CACHE_CHECK([output filetype],
 220 [libbacktrace_cv_sys_filetype],
 221 [filetype=
 222 AC_COMPILE_IFELSE(
 223   [AC_LANG_PROGRAM([int i;], [int j;])],
 224   [filetype=`${AWK} -f $srcdir/filetype.awk conftest.$ac_objext`],
 225   [AC_MSG_FAILURE([compiler failed])])
 226 libbacktrace_cv_sys_filetype=$filetype])
 227
 228 # Match the file type to decide what files to compile.
 229 FORMAT_FILE=
 230 backtrace_supports_data=yes
 231 case "$libbacktrace_cv_sys_filetype" in
 232 elf*) FORMAT_FILE="elf.lo" ;;
 233 pecoff) FORMAT_FILE="pecoff.lo"
 234         backtrace_supports_data=no
 235         ;;
 236 xcoff*) FORMAT_FILE="xcoff.lo"
 237         backtrace_supports_data=no
 238         ;;
 239 *) AC_MSG_WARN([could not determine output file type])
 240    FORMAT_FILE="unknown.lo"
 241    backtrace_supported=no
 242    ;;
 243 esac
 244 AC_SUBST(FORMAT_FILE)
 245
 246 # ELF defines.
 247 elfsize=
 248 case "$libbacktrace_cv_sys_filetype" in
 249 elf32) elfsize=32 ;;
 250 elf64) elfsize=64 ;;
 251 *)     elfsize=unused
 252 esac
 253 AC_DEFINE_UNQUOTED([BACKTRACE_ELF_SIZE], [$elfsize], [ELF size: 32 or 64])
 254
 255 # XCOFF defines.
 256 xcoffsize=
 257 case "$libbacktrace_cv_sys_filetype" in
 258 xcoff32) xcoffsize=32 ;;
 259 xcoff64) xcoffsize=64 ;;
 260 *)       xcoffsize=unused
 261 esac
 262 AC_DEFINE_UNQUOTED([BACKTRACE_XCOFF_SIZE], [$xcoffsize], [XCOFF size: 32 or 64])
 263
 264 BACKTRACE_SUPPORTED=0
 265 if test "$backtrace_supported" = "yes"; then
 266   BACKTRACE_SUPPORTED=1
 267 fi
 268 AC_SUBST(BACKTRACE_SUPPORTED)
 269
 270 BACKTRACE_SUPPORTS_DATA=0
 271 if test "$backtrace_supports_data" = "yes"; then
 272   BACKTRACE_SUPPORTS_DATA=1
 273 fi
 274 AC_SUBST(BACKTRACE_SUPPORTS_DATA)
 275
 276 GCC_HEADER_STDINT(gstdint.h)
 277
 278 AC_CHECK_HEADERS(sys/mman.h)
 279 if test "$ac_cv_header_sys_mman_h" = "no"; then
 280   have_mmap=no
 281 else
 282   if test -n "${with_target_subdir}"; then
 283     # When built as a GCC target library, we can't do a link test.  We
 284     # simply assume that if we have mman.h, we have mmap.
 285     have_mmap=yes
 286     case "${host}" in
 287     spu-*-*|*-*-msdosdjgpp)
 288         # The SPU does not have mmap, but it has a sys/mman.h header file
 289         # containing "mmap_eaddr" and the mmap flags, confusing the test.
 290         # DJGPP also has sys/man.h, but no mmap
 291         have_mmap=no ;;
 292     esac
 293   else
 294     AC_CHECK_FUNC(mmap, [have_mmap=yes], [have_mmap=no])
 295   fi
 296 fi
 297 if test "$have_mmap" = "no"; then
 298   VIEW_FILE=read.lo
 299   ALLOC_FILE=alloc.lo
 300 else
 301   VIEW_FILE=mmapio.lo
 302   AC_PREPROC_IFELSE([
 303 #include <sys/mman.h>
 304 #if !defined(MAP_ANONYMOUS) && !defined(MAP_ANON)
 305   #error no MAP_ANONYMOUS
 306 #endif
 307 ], [ALLOC_FILE=mmap.lo], [ALLOC_FILE=alloc.lo])
 308 fi
 309 AC_SUBST(VIEW_FILE)
 310 AC_SUBST(ALLOC_FILE)
 311
 312 BACKTRACE_USES_MALLOC=0
 313 if test "$ALLOC_FILE" = "alloc.lo"; then
 314   BACKTRACE_USES_MALLOC=1
 315 fi
 316 AC_SUBST(BACKTRACE_USES_MALLOC)
 317
 318 # Check for dl_iterate_phdr.
 319 AC_CHECK_HEADERS(link.h)
 320 if test "$ac_cv_header_link_h" = "no"; then
 321   have_dl_iterate_phdr=no
 322 else
 323   if test -n "${with_target_subdir}"; then
 324     # When built as a GCC target library, we can't do a link test.
 325     AC_EGREP_HEADER([dl_iterate_phdr], [link.h], [have_dl_iterate_phdr=yes],
 326                     [have_dl_iterate_phdr=no])
 327     case "${host}" in
 328     *-*-solaris2.10*)
 329         # Avoid dl_iterate_phdr on Solaris 10, where it is in the
 330         # header file but is only in -ldl.
 331         have_dl_iterate_phdr=no ;;
 332     esac
 333   else
 334     AC_CHECK_FUNC([dl_iterate_phdr], [have_dl_iterate_phdr=yes],
 335                   [have_dl_iterate_phdr=no])
 336   fi
 337 fi
 338 if test "$have_dl_iterate_phdr" = "yes"; then
 339   AC_DEFINE(HAVE_DL_ITERATE_PHDR, 1, [Define if dl_iterate_phdr is available.])
 340 fi
 341
 342 # Check for loadquery.
 343 AC_CHECK_HEADERS(sys/ldr.h)
 344 if test "$ac_cv_header_sys_ldr_h" = "no"; then
 345   have_loadquery=no
 346 else
 347   if test -n "${with_target_subdir}"; then
 348     # When built as a GCC target library, we can't do a link test.
 349     AC_EGREP_HEADER([loadquery], [sys/ldr.h], [have_loadquery=yes],
 350                     [have_loadquery=no])
 351   else
 352     AC_CHECK_FUNC([loadquery], [have_loadquery=yes],
 353                   [have_loadquery=no])
 354   fi
 355 fi
 356 if test "$have_loadquery" = "yes"; then
 357   AC_DEFINE(HAVE_LOADQUERY, 1, [Define if AIX loadquery is available.])
 358 fi
 359
 360 # Check for the fcntl function.
 361 if test -n "${with_target_subdir}"; then
 362    case "${host}" in
 363    *-*-mingw*) have_fcntl=no ;;
 364    spu-*-*) have_fcntl=no ;;
 365    *) have_fcntl=yes ;;
 366    esac
 367 else
 368   AC_CHECK_FUNC(fcntl, [have_fcntl=yes], [have_fcntl=no])
 369 fi
 370 if test "$have_fcntl" = "yes"; then
 371   AC_DEFINE([HAVE_FCNTL], 1,
 372             [Define to 1 if you have the fcntl function])
 373 fi
 374
 375 AC_CHECK_DECLS(strnlen)
 376
 377 # Check for getexecname function.
 378 if test -n "${with_target_subdir}"; then
 379    case "${host}" in
 380    *-*-solaris2*) have_getexecname=yes ;;
 381    *) have_getexecname=no ;;
 382    esac
 383 else
 384   AC_CHECK_FUNC(getexecname, [have_getexecname=yes], [have_getexecname=no])
 385 fi
 386 if test "$have_getexecname" = "yes"; then
 387   AC_DEFINE(HAVE_GETEXECNAME, 1, [Define if getexecname is available.])
 388 fi
 389
 390 dnl Test whether the compiler supports the -pthread option.
 391 AC_CACHE_CHECK([whether -pthread is supported],
 392 [libgo_cv_lib_pthread],
 393 [CFLAGS_hold=$CFLAGS
 394 CFLAGS="$CFLAGS -pthread"
 395 AC_COMPILE_IFELSE([[int i;]],
 396 [libgo_cv_lib_pthread=yes],
 397 [libgo_cv_lib_pthread=no])
 398 CFLAGS=$CFLAGS_hold])
 399 PTHREAD_CFLAGS=
 400 if test "$libgo_cv_lib_pthread" = yes; then
 401   PTHREAD_CFLAGS=-pthread
 402 fi
 403 AC_SUBST(PTHREAD_CFLAGS)
 404
 405 AM_CONDITIONAL(HAVE_PTHREAD, test "$libgo_cv_lib_pthread" = yes)
 406
 407 AC_CACHE_CHECK([whether tests can run],
 408   [libbacktrace_cv_sys_native],
 409   [AC_RUN_IFELSE([AC_LANG_PROGRAM([], [return 0;])],
 410      [libbacktrace_cv_sys_native=yes],
 411      [libbacktrace_cv_sys_native=no],
 412      [libbacktrace_cv_sys_native=no])])
 413 AM_CONDITIONAL(NATIVE, test "$libbacktrace_cv_sys_native" = "yes")
 414
 415 if test "${multilib}" = "yes"; then
 416   multilib_arg="--enable-multilib"
 417 else
 418   multilib_arg=
 419 fi
 420
 421 AC_CONFIG_FILES(Makefile backtrace-supported.h)
 422
 423 # We need multilib support, but only if configuring for the target.
 424 AC_CONFIG_COMMANDS([default],
 425 [if test -n "$CONFIG_FILES"; then
 426    if test -n "${with_target_subdir}"; then
 427      # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 428      # that multilib installs will end up installed in the correct place.
 429      # The testsuite needs it for multilib-aware ABI baseline files.
 430      # To work around this not being passed down from config-ml.in ->
 431      # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 432      # append it here.  Only modify Makefiles that have just been created.
 433      #
 434      # Also, get rid of this simulated-VPATH thing that automake does.
 435      cat > vpsed << \_EOF
 436   s!`test -f '$<' || echo '$(srcdir)/'`!!
 437 _EOF
 438      for i in $SUBDIRS; do
 439       case $CONFIG_FILES in
 440        *${i}/Makefile*)
 441          #echo "Adding MULTISUBDIR to $i/Makefile"
 442          sed -f vpsed $i/Makefile > tmp
 443          grep '^MULTISUBDIR =' Makefile >> tmp
 444          mv tmp $i/Makefile
 445          ;;
 446       esac
 447      done
 448      rm vpsed
 449    fi
 450  fi
 451 ],
 452 [
 453 # Variables needed in config.status (file generation) which aren't already
 454 # passed by autoconf.
 455 SUBDIRS="$SUBDIRS"
 456 ])
 457
 458 AC_OUTPUT