gcc/ada/sem_warn.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                             S E M _ W A R N                              --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1999-2010, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT; see file COPYING3.  If not, go to --
  19 -- http://www.gnu.org/licenses for a complete copy of the license.          --
  20 --                                                                          --
  21 -- GNAT was originally developed  by the GNAT team at  New York University. --
  22 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  23 --                                                                          --
  24 ------------------------------------------------------------------------------
  25
  26 --  This package contains the routines used to deal with issuing warnings
  27 --  about uses of uninitialized variables and unused with's. It also has
  28 --  some unrelated routines related to the generation of warnings.
  29
  30 with Alloc; use Alloc;
  31 with Table;
  32 with Types; use Types;
  33
  34 package Sem_Warn is
  35
  36    -------------------
  37    -- Warning Flags --
  38    -------------------
  39
  40    --  These flags are activated or deactivated by -gnatw switches and control
  41    --  whether warnings of a given class will be generated or not.
  42
  43    --  Note: most of these flags are still in opt, but the plan is to move them
  44    --  here as time goes by.
  45
  46    Warn_On_Record_Holes : Boolean := False;
  47    --  Warn when explicit record component clauses leave uncovered holes (gaps)
  48    --  in a record layout. Off by default, set by -gnatw.h (but not -gnatwa).
  49
  50    Warn_On_Overridden_Size : Boolean := False;
  51    --  Warn when explicit record component clause or array component_size
  52    --  clause specifies a size that overrides a size for the typen which was
  53    --  set with an explicit size clause. Off by default, set by -gnatw.sn (but
  54    --  not -gnatwa).
  55
  56    ------------------------
  57    -- Warnings Off Table --
  58    ------------------------
  59
  60    type Warnings_Off_Entry is record
  61       N : Node_Id;
  62       --  A pragma Warnings (Off, ent) node
  63
  64       E : Entity_Id;
  65       --  The entity involved
  66    end record;
  67
  68    --  An entry is made in the following table for any valid Pragma Warnings
  69    --  (Off, entity) encountered while Opt.Warn_On_Warnings_Off is True. It
  70    --  is used to generate warnings on any of these pragmas that turn out not
  71    --  to be needed, or that could be replaced by Unmodified/Unreferenced.
  72
  73    package Warnings_Off_Pragmas is new Table.Table (
  74      Table_Component_Type => Warnings_Off_Entry,
  75      Table_Index_Type     => Int,
  76      Table_Low_Bound      => 0,
  77      Table_Initial        => Alloc.Warnings_Off_Pragmas_Initial,
  78      Table_Increment      => Alloc.Warnings_Off_Pragmas_Increment,
  79      Table_Name           => "Name_Warnings_Off_Pragmas");
  80
  81    --------------------
  82    -- Initialization --
  83    --------------------
  84
  85    procedure Initialize;
  86    --  Initialize this package for new compilation
  87
  88    function Set_Warning_Switch (C : Character) return Boolean;
  89    --  This function sets the warning switch or switches corresponding to the
  90    --  given character. It is used to process a -gnatw switch on the command
  91    --  line, or a character in a string literal in pragma Warnings. Returns
  92    --  True for valid warning character C, False for invalid character.
  93
  94    function Set_Dot_Warning_Switch (C : Character) return Boolean;
  95    --  This function sets the warning switch or switches corresponding to the
  96    --  given character preceded by a dot. Used to process a -gnatw. switch on
  97    --  the command line or .C in a string literal in pragma Warnings. Returns
  98    --  True for valid warning character C, False for invalid character.
  99
 100    procedure Set_GNAT_Mode_Warnings;
 101    --  This is called in -gnatg mode to set the warnings for gnat mode. It is
 102    --  also used to set the proper warning statuses for -gnatw.g.
 103
 104    ------------------------------------------
 105    -- Routines to Handle Unused References --
 106    ------------------------------------------
 107
 108    procedure Check_References (E : Entity_Id; Anod : Node_Id := Empty);
 109    --  Called at the end of processing a declarative region. The entity E
 110    --  is the entity for the scope. All entities declared in the region,
 111    --  as indicated by First_Entity and the entity chain, are checked to
 112    --  see if they are variables for which warnings need to be posted for
 113    --  either no assignments, or a use before an assignment or no references
 114    --  at all. The Anod node is present for the case of an accept statement,
 115    --  and references the accept statement. This is used to place the warning
 116    --  messages in the right place.
 117
 118    procedure Check_Unset_Reference (N : Node_Id);
 119    --  N is the node for an expression which occurs in a reference position,
 120    --  e.g. as the right side of an assignment. This procedure checks to see
 121    --  if the node is a reference to a variable entity where the entity has
 122    --  Not_Assigned set. If so, the Unset_Reference field is set if it is not
 123    --  the first occurrence. No warning is posted, instead warnings will be
 124    --  posted later by Check_References. The reason we do things that
 125    --  way is that if there are no assignments anywhere, we prefer to flag
 126    --  the entity, rather than a reference to it. Note that for the purposes
 127    --  of this routine, a type conversion or qualified expression whose
 128    --  expression is an entity is also processed. The reason that we do not
 129    --  process these at the point of occurrence is that both these constructs
 130    --  can occur in non-reference positions (e.g. as out parameters).
 131
 132    procedure Check_Unused_Withs (Spec_Unit : Unit_Number_Type := No_Unit);
 133    --  This routine performs two kinds of checks. It checks that all with'ed
 134    --  units are referenced, and that at least one entity of each with'ed
 135    --  unit is referenced (the latter check catches units that are only
 136    --  referenced in a use or package renaming statement). Appropriate
 137    --  warning messages are generated if either of these situations is
 138    --  detected.
 139    --
 140    --  A special case arises when a package body or a subprogram body with
 141    --  a separate spec is being compiled. In this case, a with may appear
 142    --  on the spec, but be needed only by the body. This still generates
 143    --  a warning, but the text is different (the with is not redundant,
 144    --  it is misplaced).
 145    --
 146    --  This special case is implemented by making an initial call to this
 147    --  procedure with Spec_Unit set to the unit number of the separate spec.
 148    --  This call does not generate any warning messages, but instead may
 149    --  result in flags being set in the N_With_Clause node that record that
 150    --  there was no use in the spec.
 151    --
 152    --  The main call (made after all units have been analyzed, with Spec_Unit
 153    --  set to the default value of No_Unit) generates the required warnings
 154    --  using the flags set by the initial call where appropriate to specialize
 155    --  the text of the warning messages.
 156
 157    ---------------------
 158    -- Output Routines --
 159    ---------------------
 160
 161    procedure Output_Non_Modified_In_Out_Warnings;
 162    --  Warnings about IN OUT parameters that could be IN are collected till
 163    --  the end of the compilation process (see body of this routine for a
 164    --  discussion of why this is done). This procedure outputs the warnings.
 165    --  Note: this should be called before Output_Unreferenced_Messages, since
 166    --  if we have an IN OUT warning, that's the one we want to see!
 167
 168    procedure Output_Obsolescent_Entity_Warnings (N : Node_Id; E : Entity_Id);
 169    --  N is a reference to obsolescent entity E, for which appropriate warning
 170    --  messages are to be generated (caller has already checked that warnings
 171    --  are active and appropriate for this entity).
 172
 173    procedure Output_Unreferenced_Messages;
 174    --  Warnings about unreferenced entities are collected till the end of
 175    --  the compilation process (see Check_Unset_Reference for further
 176    --  details). This procedure outputs waiting warnings, if any.
 177
 178    procedure Output_Unused_Warnings_Off_Warnings;
 179    --  Warnings about pragma Warnings (Off, ent) statements that are unused,
 180    --  or could be replaced by Unmodified/Unreferenced pragmas, are collected
 181    --  till the end of the compilation process. This procedure outputs waiting
 182    --  warnings if any.
 183
 184    ----------------------------
 185    -- Other Warning Routines --
 186    ----------------------------
 187
 188    procedure Check_Code_Statement (N : Node_Id);
 189    --  Perform warning checks on a code statement node
 190
 191    procedure Check_Infinite_Loop_Warning (Loop_Statement : Node_Id);
 192    --  N is the node for a loop statement. This procedure checks if a warning
 193    --  for a possible infinite loop should be given for a suspicious WHILE or
 194    --  EXIT WHEN condition.
 195
 196    procedure Check_Low_Bound_Tested (Expr : Node_Id);
 197    --  Expr is the node for a comparison operation. This procedure checks if
 198    --  the comparison is a source comparison of P'First with some other value
 199    --  and if so, sets the Low_Bound_Tested flag on entity P to suppress
 200    --  warnings about improper low bound assumptions (we assume that if the
 201    --  code has a test that explicitly checks P'First, then it is not operating
 202    --  in blind assumption mode).
 203
 204    procedure Warn_On_Known_Condition (C : Node_Id);
 205    --  C is a node for a boolean expression resulting from a relational
 206    --  or membership operation. If the expression has a compile time known
 207    --  value, then a warning is output if all the following conditions hold:
 208    --
 209    --    1. Original expression comes from source. We don't want to generate
 210    --       warnings for internally generated conditionals.
 211    --
 212    --    2. As noted above, the expression is a relational or membership
 213    --       test, we don't want to generate warnings for boolean variables
 214    --       since this is typical of conditional compilation in Ada.
 215    --
 216    --    3. The expression appears in a statement, rather than a declaration.
 217    --       In practice, most occurrences in declarations are legitimate
 218    --       conditionalizations, but occurrences in statements are often
 219    --       errors for which the warning is useful.
 220    --
 221    --    4. The expression does not occur within an instantiation. A non-
 222    --       static expression in a generic may become constant because of
 223    --       the attributes of the actuals, and we do not want to warn on
 224    --       these legitimate constant foldings.
 225    --
 226    --  If all these conditions are met, the warning is issued noting that
 227    --  the result of the test is always false or always true as appropriate.
 228
 229    function Warn_On_Modified_As_Out_Parameter (E : Entity_Id) return Boolean;
 230    --  Returns True if we should activate warnings for entity E being modified
 231    --  as an out parameter. True if either Warn_On_Modified_Unread is set for
 232    --  an only OUT parameter, or if Warn_On_All_Unread_Out_Parameters is set.
 233
 234    procedure Warn_On_Overlapping_Actuals (Subp : Entity_Id; N : Node_Id);
 235    --  Called on a subprogram call. Checks whether an IN OUT actual that is
 236    --  not by-copy may overlap with another actual, thus leading to aliasing
 237    --  in the body of the called subprogram.
 238
 239    procedure Warn_On_Suspicious_Index (Name : Entity_Id; X : Node_Id);
 240    --  This is called after resolving an indexed component or a slice. Name
 241    --  is the entity for the name of the indexed array, and X is the subscript
 242    --  for the indexed component case, or one of the bounds in the slice case.
 243    --  If Name is an unconstrained parameter of a standard string type, and
 244    --  the index is of the form of a literal or Name'Length [- literal], then
 245    --  a warning is generated that the subscripting operation is possibly
 246    --  incorrectly assuming a lower bound of 1.
 247
 248    procedure Warn_On_Unassigned_Out_Parameter
 249      (Return_Node : Node_Id;
 250       Scope_Id    : Entity_Id);
 251    --  Called when processing a return statement given by Return_Node. Scope_Id
 252    --  is the Entity_Id for the procedure in which the return statement lives.
 253    --  A check is made for the case of a procedure with out parameters that
 254    --  have not yet been assigned, and appropriate warnings are given.
 255
 256    procedure Warn_On_Useless_Assignment
 257      (Ent : Entity_Id;
 258       N   : Node_Id := Empty);
 259    --  Called to check if we have a case of a useless assignment to the given
 260    --  entity Ent, as indicated by a non-empty Last_Assignment field. This call
 261    --  should only be made if at least one of the flags Warn_On_Modified_Unread
 262    --  or Warn_On_All_Unread_Out_Parameters is True, and if Ent is in the
 263    --  extended main source unit. N is Empty for the end of block call
 264    --  (warning message says value unreferenced), or the it is the node for
 265    --  an overwriting assignment (warning message points to this assignment).
 266
 267    procedure Warn_On_Useless_Assignments (E : Entity_Id);
 268    pragma Inline (Warn_On_Useless_Assignments);
 269    --  Called at the end of a block or subprogram. Scans the entities of the
 270    --  block or subprogram to see if there are any variables for which useless
 271    --  assignments were made (assignments whose values were never read).
 272
 273 end Sem_Warn;