libjava/configure.in

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 AC_INIT(java/lang/System.java)
   4
   5 # We use these options to decide which functions to include.
   6 AC_ARG_WITH(target-subdir,
   7   AS_HELP_STRING([--with-target-subdir=SUBDIR],
   8                  [configure in a subdirectory]))
   9
  10 # We may get other options which we don't document:
  11 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  12
  13 # When building with srcdir == objdir, links to the source files will
  14 # be created in directories within the target_subdir.  We have to
  15 # adjust toplevel_srcdir accordingly, so that configure finds
  16 # install-sh and other auxiliary files that live in the top-level
  17 # source directory.
  18 if test "${srcdir}" = "."; then
  19   if test -z "${with_target_subdir}"; then
  20     toprel=".."
  21   else
  22     if test "${with_target_subdir}" != "."; then
  23       toprel="${with_multisrctop}../.."
  24     else
  25       toprel="${with_multisrctop}.."
  26     fi
  27   fi
  28 else
  29   toprel=".."
  30 fi
  31
  32 libgcj_basedir=$srcdir/$toprel/./libjava
  33 AC_SUBST(libgcj_basedir)
  34
  35 AC_CONFIG_AUX_DIR(${srcdir}/$toprel)
  36 if :; then :; else
  37   # This overrides the previous occurrence for automake, but not for
  38   # autoconf, which is exactly what we want.
  39   AC_CONFIG_AUX_DIR(..)
  40 fi
  41
  42 AC_CANONICAL_SYSTEM
  43 _GCC_TOPLEV_NONCANONICAL_BUILD
  44 _GCC_TOPLEV_NONCANONICAL_TARGET
  45
  46 AC_SUBST(target_noncanonical)
  47
  48 # This works around the fact that libtool configuration may change LD
  49 # for this particular configuration, but some shells, instead of
  50 # keeping the changes in LD private, export them just because LD is
  51 # exported.
  52 ORIGINAL_LD_FOR_MULTILIBS=$LD
  53
  54 AC_PROG_LN_S
  55
  56 # This works around an automake problem.
  57 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  58 AC_SUBST(mkinstalldirs)
  59
  60 AC_ARG_WITH(cross-host,
  61   AS_HELP_STRING([--with-cross-host=HOST],
  62                  [configure with a cross compiler from HOST]))
  63
  64 AC_ARG_WITH(newlib,
  65   AS_HELP_STRING([--with-newlib],
  66                  [configure with newlib]))
  67
  68 AC_ARG_ENABLE(version-specific-runtime-libs,
  69   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  70                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  71     [case "$enableval" in
  72       yes) version_specific_libs=yes ;;
  73       no)  version_specific_libs=no ;;
  74       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  75      esac],
  76     [version_specific_libs=no]
  77 )
  78
  79 # Default to --enable-multilib
  80 AC_ARG_ENABLE(multilib,
  81   AS_HELP_STRING([--enable-multilib],
  82                  [build many library versions (default)]),
  83 [case "${enableval}" in
  84   yes) multilib=yes ;;
  85   no)  multilib=no ;;
  86   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  87  esac], [multilib=yes])dnl
  88
  89 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  90 GCC_NO_EXECUTABLES
  91
  92 # (1) We use an abnormal CXX (without library references), so we
  93 # must cache it under a different name.
  94 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  95 # the non-multilib-adjusted value will be used in multilibs.
  96 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  97 # (4) As another side effect, automake doesn't automatically include them
  98 # in Makefile.in.
  99 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
 100 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
 101 # used in later tests.  This may not be necessary in libjava; I don't know.
 102 m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 103 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 104 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 105 save_CXXFLAGS="$CXXFLAGS"
 106 CXXFLAGS="$CXXFLAGS -fno-builtin"
 107 AC_PROG_CC
 108 AC_PROG_CXX
 109 CXXFLAGS="$save_CXXFLAGS"
 110 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 111 AC_SUBST(CFLAGS)
 112 AC_SUBST(CXXFLAGS)
 113 AC_SUBST(LDFLAGS)
 114
 115 # version is pulled out to make it a bit easier to change using sed.
 116 version=0.0.7
 117 # Still use "libjava" here to placate dejagnu.
 118 AM_INIT_AUTOMAKE(libjava, $version)
 119
 120 AC_CHECK_TOOL(AS, as)
 121 AC_CHECK_TOOL(AR, ar)
 122 AC_CHECK_TOOL(RANLIB, ranlib, :)
 123
 124 AC_PROG_INSTALL
 125
 126 AM_MAINTAINER_MODE
 127
 128 AC_EXEEXT
 129
 130 # configure.host sets the following important variables
 131 #       libgcj_cflags    - host specific C compiler flags
 132 #       libgcj_cxxflags  - host specific C++ compiler flags
 133 #       libgcj_javaflags - host specific Java compiler flags
 134
 135 libgcj_cflags=
 136 libgcj_cxxflags=
 137 libgcj_javaflags=
 138
 139 . ${srcdir}/configure.host
 140
 141 LIBGCJ_CFLAGS="${libgcj_cflags}"
 142 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 143 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 144 AC_SUBST(LIBGCJ_CFLAGS)
 145 AC_SUBST(LIBGCJ_CXXFLAGS)
 146 AC_SUBST(LIBGCJ_JAVAFLAGS)
 147
 148 AM_CONFIG_HEADER(include/config.h gcj/libgcj-config.h)
 149
 150 # Only use libltdl for non-newlib builds.
 151 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 152    AC_LIBLTDL_CONVENIENCE
 153    AC_LIBTOOL_DLOPEN
 154    DIRLTDL=libltdl
 155    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 156    # Sigh.  Libtool's macro doesn't do the right thing.
 157    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 158    # FIXME: this is a hack.
 159    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 160    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 161 fi
 162 AC_SUBST(INCLTDL)
 163 AC_SUBST(LIBLTDL)
 164 AC_SUBST(DIRLTDL)
 165 AM_PROG_LIBTOOL
 166 AC_CONFIG_SUBDIRS($DIRLTDL)
 167
 168 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
 169    COMPPATH=.
 170 else
 171    COMPPATH=..
 172 fi
 173 AC_SUBST(COMPPATH)
 174
 175 # The -no-testsuite modules omit the test subdir.
 176 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 177
 178 # Should the runtime set system properties by examining the
 179 # environment variable GCJ_PROPERTIES?
 180 AC_ARG_ENABLE(getenv-properties,
 181   AS_HELP_STRING([--disable-getenv-properties],
 182                  [don't set system properties from GCJ_PROPERTIES]))
 183
 184 # Whether GCJ_PROPERTIES is used depends on the target.
 185 if test -z "$enable_getenv_properties"; then
 186    enable_getenv_properties=${enable_getenv_properties_default-yes}
 187 fi
 188 if test "$enable_getenv_properties" = no; then
 189    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 190      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 191 fi
 192
 193 # Whether we should use arguments to main()
 194 if test -z "$enable_main_args"; then
 195    enable_main_args=${enable_main_args_default-yes}
 196 fi
 197 if test "$enable_main_args" = no; then
 198    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 199 fi
 200
 201
 202 # Should we use hashtable-based synchronization?
 203 # Currently works only for Linux X86/ia64
 204 # Typically faster and more space-efficient
 205 AC_ARG_ENABLE(hash-synchronization,
 206   AS_HELP_STRING([--enable-hash-synchronization],
 207                  [use global hash table for monitor locks]))
 208
 209 if test -z "$enable_hash_synchronization"; then
 210    enable_hash_synchronization=$enable_hash_synchronization_default
 211 fi
 212
 213 # Do we allow intermodule optimizations (i.e. compiling many files at once)?
 214 AC_ARG_ENABLE(libgcj-multifile,
 215   AS_HELP_STRING([--enable-libgcj-multifile]
 216                  [allow compilation of several files at once]),
 217 [case "${enableval}" in
 218   yes) enable_libgcj_multifile=yes ;;
 219   no)  enable_libgcj_multifile=no ;;
 220   *) AC_MSG_ERROR(bad value ${enableval} for --enable-libgcj-multifile) ;;
 221 esac],[enable_libgcj_multifile=no])
 222 AM_CONDITIONAL(ONESTEP, test "$enable_libgcj_multifile" = yes)
 223
 224 # What is the native OS API for MinGW?
 225 AC_ARG_WITH(win32-nlsapi,
 226   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 227                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 228 [case "${withval}" in
 229   ansi) with_win32_nlsapi=ansi ;;
 230   unicows) with_win32_nlsapi=unicows ;;
 231   unicode) with_win32_nlsapi=unicode ;;
 232   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 233 esac],[with_win32_nlsapi=ansi])
 234
 235 case "${with_win32_nlsapi}" in
 236   unicows | unicode)
 237     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 238       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 239     ;;
 240 esac
 241
 242 # configure.host sets slow_pthread_self if the synchronization code should
 243 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 244 if test "${slow_pthread_self}" = "yes"; then
 245   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 246     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 247 fi
 248
 249
 250 # See if the user has requested runtime debugging.
 251 LIBGCJDEBUG="false"
 252 AC_SUBST(LIBGCJDEBUG)
 253 AC_ARG_ENABLE(libgcj-debug,
 254   AS_HELP_STRING([--enable-libgcj-debug],
 255                  [enable runtime debugging code]),
 256   [if test "$enable_libgcj_debug" = yes; then
 257     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 258     LIBGCJDEBUG="true"
 259   fi])
 260
 261 # See if the user has the interpreter included.
 262 AC_ARG_ENABLE(interpreter,
 263   AS_HELP_STRING([--enable-interpreter],
 264                  [enable interpreter]),
 265   [if test "$enable_interpreter" = yes; then
 266     # This can also be set in configure.host.
 267     libgcj_interpreter=yes
 268   elif test "$enable_interpreter" = no; then
 269     libgcj_interpreter=no
 270   fi])
 271
 272 if test "$libgcj_interpreter" = yes; then
 273    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 274 fi
 275 INTERPRETER="$libgcj_interpreter"
 276 AC_SUBST(INTERPRETER)
 277
 278 AC_MSG_CHECKING([for exception model to use])
 279 AC_LANG_SAVE
 280 AC_LANG_CPLUSPLUS
 281 AC_ARG_ENABLE(sjlj-exceptions,
 282   AS_HELP_STRING([--enable-sjlj-exceptions],
 283                  [force use of builtin_setjmp for exceptions]),
 284 [:],
 285 [dnl Botheration.  Now we've got to detect the exception model.
 286 dnl Link tests against libgcc.a are problematic since -- at least
 287 dnl as of this writing -- we've not been given proper -L bits for
 288 dnl single-tree newlib and libgloss.
 289 dnl
 290 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 291 dnl conftest files before we got a change to grep them first.
 292 cat > conftest.$ac_ext << EOF
 293 [#]line __oline__ "configure"
 294 struct S { ~S(); };
 295 void bar();
 296 void foo()
 297 {
 298   S s;
 299   bar();
 300 }
 301 EOF
 302 old_CXXFLAGS="$CXXFLAGS"
 303 CXXFLAGS=-S
 304 if AC_TRY_EVAL(ac_compile); then
 305   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 306     enable_sjlj_exceptions=yes
 307   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 308     enable_sjlj_exceptions=no
 309   fi
 310 fi
 311 CXXFLAGS="$old_CXXFLAGS"
 312 rm -f conftest*])
 313 if test x$enable_sjlj_exceptions = xyes; then
 314   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 315         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 316   ac_exception_model_name=sjlj
 317 elif test x$enable_sjlj_exceptions = xno; then
 318   ac_exception_model_name="call frame"
 319 else
 320   AC_MSG_ERROR([unable to detect exception model])
 321 fi
 322 AC_LANG_RESTORE
 323 AC_MSG_RESULT($ac_exception_model_name)
 324
 325 # If we are non using SJLJ exceptions, and this host does not have support
 326 # for unwinding from a signal handler, enable checked dereferences and divides.
 327 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 328   CHECKREFSPEC=-fcheck-references
 329   DIVIDESPEC=-fuse-divide-subroutine
 330   EXCEPTIONSPEC=
 331 fi
 332
 333 # See if the user wants to disable java.net.  This is the mildly
 334 # ugly way that we admit that target-side configuration sucks.
 335 AC_ARG_ENABLE(java-net,
 336   AS_HELP_STRING([--disable-java-net],
 337                  [disable java.net]))
 338
 339 # Whether java.net is built by default can depend on the target.
 340 if test -z "$enable_java_net"; then
 341    enable_java_net=${enable_java_net_default-yes}
 342 fi
 343 if test "$enable_java_net" = no; then
 344    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 345 fi
 346
 347 # See if the user wants to configure without libffi.  Some
 348 # architectures don't support it, and default values are set in
 349 # configure.host.
 350 AC_ARG_WITH(libffi,
 351   AS_HELP_STRING([--without-libffi],
 352                  [don't use libffi]),
 353   [:],
 354   [with_libffi=${with_libffi_default-yes}])
 355
 356 LIBFFI=
 357 LIBFFIINCS=
 358 if test "$with_libffi" != no; then
 359    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 360    LIBFFI=../libffi/libffi_convenience.la
 361    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 362 fi
 363 AC_SUBST(LIBFFI)
 364 AC_SUBST(LIBFFIINCS)
 365
 366 # See if the user wants to disable JVMPI support.
 367 AC_ARG_ENABLE(jvmpi,
 368   AS_HELP_STRING([--disable-jvmpi],
 369                  [disable JVMPI support]))
 370
 371 if test "$enable_jvmpi" != no; then
 372     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 373 fi
 374
 375 # If the target is an eCos system, use the appropriate eCos
 376 # I/O routines.
 377 # FIXME: this should not be a local option but a global target
 378 # system; at present there is no eCos target.
 379 TARGET_ECOS=${PROCESS-"no"}
 380 AC_ARG_WITH(ecos,
 381 [  --with-ecos             enable runtime eCos target support],
 382 TARGET_ECOS="$with_ecos"
 383 )
 384
 385 EXTRA_CC_FILES=
 386 AC_SUBST(EXTRA_CC_FILES)
 387
 388 PLATFORMOBJS=
 389 PLATFORM_INNER_NAT_HDRS=
 390 case "$TARGET_ECOS" in
 391    no) case "$host" in
 392       *mingw*)
 393             PLATFORM=Win32
 394             PLATFORMNET=Win32
 395             PLATFORMOBJS=win32.lo
 396             PLATFORMH=win32.h
 397         CHECK_FOR_BROKEN_MINGW_LD
 398       ;;
 399       *)
 400             PLATFORM=Posix
 401             PLATFORMNET=Posix
 402             PLATFORMOBJS=posix.lo
 403             PLATFORMH=posix.h
 404             PLATFORM_INNER_NAT_HDRS='java/lang/ConcreteProcess$$ProcessManager.h'
 405       ;;
 406       esac
 407       ;;
 408    *)
 409       PLATFORM=Ecos
 410       PLATFORMNET=NoNet
 411       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 412       PLATFORMOBJS=posix.lo
 413       PLATFORMH=posix.h
 414       ;;
 415 esac
 416 AC_SUBST(PLATFORMOBJS)
 417 AC_SUBST(PLATFORM_INNER_NAT_HDRS)
 418 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 419
 420 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 421                                       [Define if you have int32_t and uint32_t.]))
 422 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 423                                         [Define if you have int32_t and uint32_t.]))
 424 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 425                                           [Define if you have u_int32_t]))
 426 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 427                                            [Define if you have u_int32_t]))
 428
 429
 430 # These may not be defined in a non-ANS conformant embedded system.
 431 # FIXME: Should these case a runtime exception in that case?
 432 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 433                                   [Define is you have 'mktime' in <time.h>]))
 434 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 435                                   [Define is you have 'localtime' in <time.h>]))
 436
 437 # Create the subdirectory for natFile.cc, or the attempt
 438 # to create the link will fail.
 439 test -d java || mkdir java
 440 test -d java/io || mkdir java/io
 441 test -d gnu || mkdir gnu
 442 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 443
 444 # Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 445 test -d java/lang || mkdir java/lang
 446 AC_CONFIG_LINKS(java/lang/ConcreteProcess.java:java/lang/${PLATFORM}Process.java)
 447 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 448
 449 # Likewise for natInetAddress.cc and natNetworkInterface.cc.
 450 test -d java/net || mkdir java/net
 451 AC_CONFIG_LINKS(java/net/natInetAddress.cc:java/net/natInetAddress${PLATFORMNET}.cc)
 452 AC_CONFIG_LINKS(java/net/natNetworkInterface.cc:java/net/natNetworkInterface${PLATFORMNET}.cc)
 453
 454 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 455 test -d gnu/java || mkdir gnu/java
 456 test -d gnu/java/net || mkdir gnu/java/net
 457 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 458 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 459
 460 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 461 test -d gnu/java/nio || mkdir gnu/java/nio
 462 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 463 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 464 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 465 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 466
 467 case "${host}" in
 468     *mingw*)
 469       SYSTEMSPEC="-lgdi32 -lws2_32"
 470       if test "${with_win32_nlsapi}" = "unicows"; then
 471         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 472       fi
 473     ;;
 474     *)
 475       SYSTEMSPEC=
 476     ;;
 477 esac
 478 AC_SUBST(SYSTEMSPEC)
 479
 480 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 481 AC_SUBST(LIBGCJTESTSPEC)
 482
 483 AC_ARG_WITH(system-zlib,
 484   AS_HELP_STRING([--with-system-zlib],
 485                  [use installed libz]))
 486 ZLIBSPEC=
 487 AC_SUBST(ZLIBSPEC)
 488 ZLIBTESTSPEC=
 489 AC_SUBST(ZLIBTESTSPEC)
 490
 491 AC_PATH_XTRA
 492
 493 # Determine which AWT peer libraries to build
 494 AC_ARG_ENABLE(java-awt,
 495   AS_HELP_STRING([--enable-java-awt],
 496                  [list of AWT peer implementations to be built]))
 497
 498 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 499 use_xlib_awt=""
 500 use_gtk_awt=""
 501 # The default toolkit to use is the first one specified.
 502 TOOLKIT=
 503 AC_SUBST(TOOLKIT)
 504
 505 for peer in $peerlibs ; do
 506   case $peer in
 507     xlib)
 508       if test "$no_x" = yes; then
 509         echo "*** xlib peers requested but no X library available" 1>&2
 510         exit 1
 511       else
 512         use_xlib_awt="yes"
 513         if test -z "$TOOLKIT"; then
 514            TOOLKIT=gnu.awt.xlib.XToolkit
 515         fi
 516       fi
 517       ;;
 518     gtk)
 519       if test "$no_x" = yes; then
 520          echo "*** xlib peers requested but no X library available" 1>&2
 521          exit 1
 522       else
 523          use_gtk_awt=yes
 524          if test -z "$TOOLKIT"; then
 525             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 526          fi
 527          test -d jniinclude || mkdir jniinclude
 528       fi
 529       ;;
 530     no)
 531       use_xlib_awt=
 532       use_gtk_awt=
 533       break
 534       ;;
 535     *)
 536       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 537       exit 1
 538   esac
 539 done
 540
 541 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 542 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 543
 544 # determine whether to enable the cairo GTK Graphics2D backend
 545 AC_ARG_ENABLE(gtk-cairo,
 546   AS_HELP_STRING([--enable-gtk-cairo],
 547                  [build the cairo Graphics2D implementation on GTK]))
 548 AM_CONDITIONAL(GTK_CAIRO, test "x${enable_gtk_cairo}" = xyes)
 549 if test "x${enable_gtk_cairo}" = xyes
 550 then
 551         PKG_CHECK_MODULES(CAIRO, cairo)
 552         PKG_CHECK_MODULES(PANGOFT2, pangoft2)
 553 fi
 554 AC_SUBST(CAIRO_LIBS)
 555 AC_SUBST(CAIRO_CFLAGS)
 556 AC_SUBST(PANGOFT2_LIBS)
 557 AC_SUBST(PANGOFT2_CFLAGS)
 558
 559 # FIXME: this should be _libs on some hosts.
 560 libsubdir=.libs
 561
 562 # Allow the GC to be disabled.  Can be useful when debugging.
 563 AC_MSG_CHECKING([for garbage collector to use])
 564 AC_ARG_ENABLE(java-gc,
 565   AS_HELP_STRING([--enable-java-gc=TYPE],
 566                  [choose garbage collector (default is boehm)]),
 567   [GC=$enableval],
 568   [GC=boehm])
 569 GCLIBS=
 570 GCINCS=
 571 GCDEPS=
 572 GCOBJS=
 573 GCSPEC=
 574 JC1GCSPEC=
 575 GCTESTSPEC=
 576 case "$GC" in
 577  boehm)
 578     AC_MSG_RESULT(boehm)
 579     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 580     JC1GCSPEC='-fuse-boehm-gc'
 581     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 582
 583     # We also want to pick up some cpp flags required when including
 584     # boehm-config.h.  Yuck.
 585     GCINCS="`cat ../boehm-gc/boehm-cflags`"
 586     GCOBJS=boehm.lo
 587     GCHDR=boehm-gc.h
 588     # The POSIX thread support needs to know this.
 589     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 590     ;;
 591  no)
 592     AC_MSG_RESULT(none)
 593     GCOBJS=nogc.lo
 594     GCHDR=no-gc.h
 595     ;;
 596  *)
 597     AC_MSG_ERROR(unrecognized collector \"$GC\")
 598     ;;
 599 esac
 600 AC_SUBST(GCLIBS)
 601 AC_SUBST(GCINCS)
 602 AC_SUBST(GCDEPS)
 603 AC_SUBST(GCOBJS)
 604 AC_SUBST(GCSPEC)
 605 AC_SUBST(JC1GCSPEC)
 606 AC_SUBST(GCTESTSPEC)
 607 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 608
 609
 610 AC_MSG_CHECKING([for thread model used by GCC])
 611 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 612 AC_MSG_RESULT([$THREADS])
 613
 614 case "$THREADS" in
 615  no | none | single)
 616     THREADS=none
 617     ;;
 618  posix | pthreads)
 619     THREADS=posix
 620     case "$host" in
 621      *-*-linux*)
 622         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 623         ;;
 624     esac
 625     ;;
 626  win32)
 627     ;;
 628  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 629     AC_MSG_ERROR(thread package $THREADS not yet supported)
 630     ;;
 631  *)
 632     AC_MSG_ERROR($THREADS is an unknown thread package)
 633     ;;
 634 esac
 635
 636 THREADCXXFLAGS=
 637 THREADLDFLAGS=
 638 THREADLIBS=
 639 THREADINCS=
 640 THREADDEPS=
 641 THREADOBJS=
 642 THREADH=
 643 THREADSPEC=
 644 case "$THREADS" in
 645  posix)
 646     case "$host" in
 647      *-*-cygwin*)
 648         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 649         ;;
 650      *-*-freebsd[[1234]]*)
 651         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 652         # merely adds pthread_* functions) but it does have a -pthread switch
 653         # which is required at link-time to select -lc_r *instead* of -lc.
 654         THREADLDFLAGS=-pthread
 655         # Don't set THREADSPEC here as might be expected since -pthread is
 656         # not processed when found within a spec file, it must come from
 657         # the command line.  For now, the user must provide the -pthread
 658         # switch to link code compiled with gcj.  In future, consider adding
 659         # support for weak references to pthread_* functions ala gthr.h API.
 660         THREADSPEC='%{!pthread: %eUnder this configuration, the user must provide -pthread when linking.}'
 661         ;;
 662      *-*-freebsd*)
 663         # FreeBSD 5 implements a model much closer to other modern UNIX
 664         # which support threads.  However, it still does not support
 665         # -lpthread.
 666         THREADLDFLAGS=-pthread
 667         THREADSPEC=-lc_r
 668         ;;
 669      alpha*-dec-osf*)
 670         THREADCXXFLAGS=-pthread
 671         # boehm-gc needs some functions from librt, so link that too.
 672         THREADLIBS='-lpthread -lrt'
 673         THREADSPEC='-lpthread -lrt'
 674         ;;
 675      *)
 676         THREADLIBS=-lpthread
 677         THREADSPEC=-lpthread
 678         ;;
 679     esac
 680     THREADOBJS=posix-threads.lo
 681     THREADH=posix-threads.h
 682     # MIT pthreads doesn't seem to have the mutexattr functions.
 683     # But for now we don't check for it.  We just assume you aren't
 684     # using MIT pthreads.
 685     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 686
 687     # If we're using the Boehm GC, then we happen to know that it
 688     # defines _REENTRANT, so we don't bother.  Eww.
 689     if test "$GC" != boehm; then
 690        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 691     fi
 692     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 693     ;;
 694
 695  win32)
 696     THREADOBJS=win32-threads.lo
 697     THREADH=win32-threads.h
 698     ;;
 699
 700  none)
 701     THREADOBJS=no-threads.lo
 702     THREADH=no-threads.h
 703     ;;
 704 esac
 705 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 706 AC_SUBST(THREADLIBS)
 707 AC_SUBST(THREADINCS)
 708 AC_SUBST(THREADDEPS)
 709 AC_SUBST(THREADOBJS)
 710 AC_SUBST(THREADSPEC)
 711 AC_SUBST(THREADLDFLAGS)
 712 AC_SUBST(THREADCXXFLAGS)
 713
 714 if test -d sysdep; then true; else mkdir sysdep; fi
 715 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 716
 717 HASH_SYNC_SPEC=
 718 # Hash synchronization is only useful with posix threads right now.
 719 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 720    HASH_SYNC_SPEC=-fhash-synchronization
 721    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 722 fi
 723 AC_SUBST(HASH_SYNC_SPEC)
 724
 725
 726 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 727
 728 # We're in the tree with gcc, and need to include some of its headers.
 729 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 730
 731 # Figure out where generated headers like libgcj-config.h get installed.
 732 gcc_version_trigger=${libgcj_basedir}/../gcc/version.c
 733 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([[^\"]]*\)\".*/\1/'`
 734 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([[^ ]]*\) .*/\1/'`
 735 tool_include_dir='$(libdir)/gcc/$(target_noncanonical)/'${gcc_version}/include
 736 AC_SUBST(tool_include_dir)
 737 AC_SUBST(gcc_version)
 738
 739 if test "x${with_newlib}" = "xyes"; then
 740    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 741    # may not work correctly, because the compiler may not be able to
 742    # link executables.
 743
 744    # We assume newlib.  This lets us hard-code the functions we know
 745    # we'll have.
 746    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 747    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 748    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 749    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 750    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 751    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 752    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 753    # This is only for POSIX threads.
 754    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 755    # We also assume we are using gcc, which provides alloca.
 756    AC_DEFINE(HAVE_ALLOCA)
 757
 758    # Assume we do not have getuid and friends.
 759    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
 760    PLATFORMNET=NoNet
 761 else
 762    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep opendir)
 763    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r getcwd)
 764    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath utime chmod)
 765    AC_CHECK_FUNCS(nl_langinfo setlocale)
 766    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 767    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 768    AC_CHECK_FUNCS(fork execvp pipe sigaction ftruncate)
 769    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 770    AC_CHECK_FUNC(backtrace, [
 771      case "$host" in
 772        ia64-*-linux*)
 773          # Has broken backtrace()
 774          ;;
 775        mips*-*-linux*)
 776          # Has broken backtrace(), but we supply our own.
 777          if test -d sysdep; then true; else mkdir -p sysdep; fi
 778          EXTRA_CC_FILES="${EXTRA_CC_FILES} sysdep/dwarf2-backtrace.cc"
 779          AC_DEFINE(HAVE_BACKTRACE, 1,
 780            [Define if your platform has a working backtrace() function.])
 781          ;;
 782        *)
 783          AC_DEFINE(HAVE_BACKTRACE, 1,
 784            [Define if your platform has a working backtrace() function.])
 785          ;;
 786      esac
 787    ], [
 788      case "$host" in
 789        *mingw*)
 790          # Has backtrace() defined in libgcj itself
 791          AC_DEFINE(HAVE_BACKTRACE, 1,
 792            [Define if your platform has a working backtrace() function.])
 793          ;;
 794      esac
 795    ])
 796
 797    AC_CHECK_LIB(dl, dladdr, [
 798      if test "x${disable_dladdr}" = "xyes"; then
 799        #Broken dladdr().
 800        true
 801      else
 802        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])
 803      fi
 804    ])
 805    if test x"$build" = x"$host"; then
 806      AC_CHECK_FILES(/proc/self/exe, [
 807        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
 808    else
 809      case $host in
 810      *-linux*)
 811        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
 812        ;;
 813      esac
 814    fi
 815
 816    AM_ICONV
 817    AM_LC_MESSAGES
 818    AC_STRUCT_TIMEZONE
 819
 820    AC_CHECK_FUNCS(gethostbyname_r, [
 821      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
 822        [Define if you have the 'gethostbyname_r' function.])
 823      # There are two different kinds of gethostbyname_r.
 824      # We look for the one that returns `int'.
 825      # Hopefully this check is robust enough.
 826      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 827        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
 828
 829      case " $GCINCS " in
 830      *" -D_REENTRANT "*) ;;
 831      *)
 832         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 833         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 834         [libjava_cv_gethostbyname_r_needs_reentrant],
 835         [ AC_LANG_SAVE
 836           AC_LANG_CPLUSPLUS
 837           AC_TRY_COMPILE([#include <netdb.h>],
 838             [gethostbyname_r("", 0, 0);],
 839             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 840                 CPPFLAGS_SAVE="$CPPFLAGS"
 841                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 842                 AC_TRY_COMPILE([#include <netdb.h>], [gethostbyname_r("", 0, 0);],
 843                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 844                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 845                 CPPFLAGS="$CPPFLAGS_SAVE"
 846           ])
 847           AC_LANG_RESTORE
 848         ])
 849         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 850           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 851         fi
 852      ;;
 853      esac
 854
 855      AC_CACHE_CHECK([for struct hostent_data],
 856         [libjava_cv_struct_hostent_data], [dnl
 857         AC_TRY_COMPILE([
 858 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 859 # define _REENTRANT 1
 860 #endif
 861 #include <netdb.h>], [struct hostent_data data;],
 862           [libjava_cv_struct_hostent_data=yes],
 863           [libjava_cv_struct_hostent_data=no])])
 864      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 865        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 866          [Define if struct hostent_data is defined in netdb.h])
 867      fi
 868    ])
 869
 870    # FIXME: libjava source code expects to find a prototype for
 871    # gethostbyaddr_r in netdb.h.  The outer check ensures that
 872    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
 873    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
 874    # linkage check is enough, yet C++ code requires proper prototypes.)
 875    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
 876    AC_CHECK_FUNCS(gethostbyaddr_r, [
 877      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
 878        [Define if you have the 'gethostbyaddr_r' function.])
 879      # There are two different kinds of gethostbyaddr_r.
 880      # We look for the one that returns `int'.
 881      # Hopefully this check is robust enough.
 882      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 883        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
 884          [Define if gethostbyaddr_r returns 'int'.])])])])
 885
 886    AC_CHECK_FUNCS(gethostname, [
 887      AC_DEFINE(HAVE_GETHOSTNAME, 1,
 888        [Define if you have the 'gethostname' function.])
 889      AC_EGREP_HEADER(gethostname, unistd.h, [
 890        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
 891          [Define if gethostname is declared in <unistd.h>.])])])
 892
 893    AC_CHECK_FUNCS(usleep, [
 894      AC_EGREP_HEADER(usleep, unistd.h, [
 895        AC_DEFINE(HAVE_USLEEP_DECL, 1,
 896           [Define if usleep is declared in <unistd.h>.])])])
 897
 898    # Look for these functions in the thread library, but only bother
 899    # if using POSIX threads.
 900    if test "$THREADS" = posix; then
 901       save_LIBS="$LIBS"
 902       LIBS="$LIBS $THREADLIBS"
 903       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 904       # E.g., Solaris.
 905       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 906
 907       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 908       # Solaris 7 the name librt is preferred.
 909       AC_CHECK_FUNCS(sched_yield, , [
 910         AC_CHECK_LIB(rt, sched_yield, [
 911           AC_DEFINE(HAVE_SCHED_YIELD)
 912           THREADLIBS="$THREADLIBS -lrt"
 913           THREADSPEC="$THREADSPEC -lrt"], [
 914           AC_CHECK_LIB(posix4, sched_yield, [
 915             AC_DEFINE(HAVE_SCHED_YIELD)
 916             THREADLIBS="$THREADLIBS -lposix4"
 917             THREADSPEC="$THREADSPEC -lposix4"])])])
 918       LIBS="$save_LIBS"
 919
 920       # We can save a little space at runtime if the mutex has m_count
 921       # or __m_count.  This is a nice hack for Linux.
 922       AC_TRY_COMPILE([#include <pthread.h>], [
 923           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 924         ], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
 925              [Define if pthread_mutex_t has m_count member.]), [
 926         AC_TRY_COMPILE([#include <pthread.h>], [
 927             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 928           ], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
 929             [Define if pthread_mutex_t has __m_count member.]))])
 930    fi
 931
 932    # We require a way to get the time.
 933    time_found=no
 934    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 935    if test "$time_found" = no; then
 936       AC_MSG_ERROR([no function found to get the time])
 937    fi
 938
 939    AC_CHECK_FUNCS(memmove)
 940
 941    # We require memcpy.
 942    memcpy_found=no
 943    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 944    if test "$memcpy_found" = no; then
 945       AC_MSG_ERROR([memcpy is required])
 946    fi
 947
 948    AC_CHECK_LIB(dl, dlopen, [
 949        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])
 950
 951    # Some library-finding code we stole from Tcl.
 952    #--------------------------------------------------------------------
 953    #    Check for the existence of the -lsocket and -lnsl libraries.
 954    #    The order here is important, so that they end up in the right
 955    #    order in the command line generated by make.  Here are some
 956    #    special considerations:
 957    #    1. Use "connect" and "accept" to check for -lsocket, and
 958    #       "gethostbyname" to check for -lnsl.
 959    #    2. Use each function name only once:  can't redo a check because
 960    #       autoconf caches the results of the last check and won't redo it.
 961    #    3. Use -lnsl and -lsocket only if they supply procedures that
 962    #       aren't already present in the normal libraries.  This is because
 963    #       IRIX 5.2 has libraries, but they aren't needed and they're
 964    #       bogus:  they goof up name resolution if used.
 965    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 966    #       To get around this problem, check for both libraries together
 967    #       if -lsocket doesn't work by itself.
 968    #--------------------------------------------------------------------
 969
 970    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 971     [gcj_cv_lib_sockets=
 972      gcj_checkBoth=0
 973      unset ac_cv_func_connect
 974      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 975      if test "$gcj_checkSocket" = 1; then
 976          unset ac_cv_func_connect
 977          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 978                       gcj_checkBoth=1)
 979      fi
 980      if test "$gcj_checkBoth" = 1; then
 981          gcj_oldLibs=$LIBS
 982          LIBS="$LIBS -lsocket -lnsl"
 983          unset ac_cv_func_accept
 984          AC_CHECK_FUNC(accept,
 985                        [gcj_checkNsl=0
 986                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 987          unset ac_cv_func_accept
 988          LIBS=$gcj_oldLibs
 989      fi
 990      unset ac_cv_func_gethostbyname
 991      gcj_oldLibs=$LIBS
 992      LIBS="$LIBS $gcj_cv_lib_sockets"
 993      AC_CHECK_FUNC(gethostbyname, ,
 994                    [AC_CHECK_LIB(nsl, main,
 995                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 996      unset ac_cv_func_gethostbyname
 997      LIBS=$gcj_oldLIBS
 998    ])
 999    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
1000
1001    if test "$with_system_zlib" = yes; then
1002       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
1003    fi
1004
1005    # Test for Gtk stuff, if asked for.
1006    if test "$use_gtk_awt" = yes; then
1007       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
1008       AC_SUBST(GTK_CFLAGS)
1009       AC_SUBST(GTK_LIBS)
1010
1011       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1012       AC_SUBST(GLIB_CFLAGS)
1013       AC_SUBST(GLIB_LIBS)
1014
1015       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1016       AC_SUBST(LIBART_CFLAGS)
1017       AC_SUBST(LIBART_LIBS)
1018    fi
1019
1020    # On Solaris, and maybe other architectures, the Boehm collector
1021    # requires -ldl.
1022    if test "$GC" = boehm; then
1023       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1024    fi
1025 fi
1026
1027 if test -z "${with_multisubdir}"; then
1028    builddotdot=.
1029 else
1030    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
1031 fi
1032
1033 NATIVE=yes
1034
1035 # Which gcj do we use?
1036 which_gcj=default
1037 built_gcc_dir="`cd ${builddotdot}/../../gcc && ${PWDCMD-pwd}`"
1038 if test -n "${with_cross_host}"; then
1039   # We are being configured with a cross compiler. We can't
1040   # use ac_exeext, because that is for the target platform.
1041   NATIVE=no
1042   cross_host_exeext=
1043   case "${with_cross_host}" in
1044      *mingw* | *cygwin*)
1045          cross_host_exeext=.exe
1046      ;;
1047   esac
1048   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
1049      if test x"$build_noncanonical" = x"$with_cross_host"; then
1050         # Ordinary cross (host!=target and host=build)
1051         which_gcj=built
1052      else
1053         # Canadian cross (host!=target and host!=build)
1054         which_gcj=cross
1055      fi
1056   else
1057      which_gcj=cross
1058   fi
1059 else
1060   # We are being configured with a native or crossed-native compiler
1061   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
1062      if test x"$build" = x"$host"; then
1063         # True native build (host=target and host=build)
1064         which_gcj=built
1065      else
1066         # Crossed-native build (host=target and host!=build)
1067         which_gcj=cross
1068      fi
1069   else
1070      which_gcj=path
1071   fi
1072 fi
1073 case "${which_gcj}" in
1074    built)
1075       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
1076       GCJH='$(MULTIBUILDTOP)../$(COMPPATH)/gcc/gcjh'
1077       ZIP='$(MULTIBUILDTOP)../$(COMPPATH)/fastjar/fastjar'
1078    ;;
1079    cross)
1080       if test "x${with_newlib}" = "xyes"; then
1081          # FIXME (comment): Why is this needed?
1082          GCC_UNWIND_INCLUDE=
1083          GCJ="${target_noncanonical}-gcj"
1084       else
1085          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
1086       fi
1087       ZIP=jar
1088       GCJH='$(target_noncanonical)-gcjh'
1089    ;;
1090    path)
1091       GCJ="gcj -B`${PWDCMD-pwd}`/"
1092       ## In this case, gcj is found outside the build tree.  However, zip is
1093       ## found in the build tree.
1094       ZIP='$(MULTIBUILDTOP)../$(COMPPATH)/fastjar/fastjar'
1095       GCJH=gcjh
1096    ;;
1097 esac
1098
1099 AC_SUBST(GCJH)
1100 AC_SUBST(ZIP)
1101
1102 # Create it, so that compile/link tests don't fail
1103 test -f libgcj.spec || touch libgcj.spec
1104
1105 # We must search the source tree for java.lang, since we still don't
1106 # have libgcj.jar nor java/lang/*.class
1107 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1108 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1109
1110 # Since some classes depend on this one, we need its source available
1111 # before we can do any GCJ compilation test :-(
1112 if test ! -f gnu/classpath/Configuration.java; then
1113   test -d gnu || mkdir gnu
1114   test -d gnu/classpath || mkdir gnu/classpath
1115   sed -e 's,@LIBGCJDEBUG@,$LIBGCJDEBUG,' \
1116       -e 's,@TOOLKIT@,$TOOLKIT,' \
1117         < $srcdir/gnu/classpath/Configuration.java.in \
1118         > gnu/classpath/Configuration.java
1119   # We do not want to redirect the output of the grep below to /dev/null,
1120   # but we add /dev/null to the input list so that grep will print the
1121   # filename of Configuration.java in case it finds any matches.
1122   if grep @ gnu/classpath/Configuration.java /dev/null; then
1123     AC_MSG_ERROR([configure.in is missing the substitutions above])
1124   fi
1125 fi
1126
1127 LT_AC_PROG_GCJ
1128
1129 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1130
1131 AC_COMPILE_CHECK_SIZEOF(void *)
1132
1133 ZLIBS=
1134 SYS_ZLIBS=
1135 ZINCS=
1136
1137 if test -z "$ZLIBSPEC"; then
1138    # Use zlib from the GCC tree.
1139    ZINCS='-I$(top_srcdir)/../zlib'
1140    ZLIBS=../zlib/libzgcj_convenience.la
1141 else
1142    # System's zlib.
1143    SYS_ZLIBS="$ZLIBSPEC"
1144 fi
1145 AC_SUBST(ZLIBS)
1146 AC_SUBST(SYS_ZLIBS)
1147 AC_SUBST(ZINCS)
1148 AC_SUBST(DIVIDESPEC)
1149 AC_SUBST(CHECKREFSPEC)
1150 AC_SUBST(EXCEPTIONSPEC)
1151 AC_SUBST(IEEESPEC)
1152
1153 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1154 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1155 AC_SUBST(GCC_UNWIND_INCLUDE)
1156
1157 # Process the option "--enable-version-specific-runtime-libs"
1158 # Calculate toolexeclibdir
1159 case ${version_specific_libs} in
1160   yes)
1161     # Need the gcc compiler version to know where to install libraries
1162     # and header files if --enable-version-specific-runtime-libs option
1163     # is selected.
1164     includedir='${libdir}/gcc/${target_noncanonical}/'$gcc_version/include/
1165     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1166     toolexecmainlibdir='$(toolexecdir)/'${gcc_version}'$(MULTISUBDIR)'
1167     toolexeclibdir=$toolexecmainlibdir
1168     ;;
1169   no)
1170     if test -n "$with_cross_host" &&
1171        test x"$with_cross_host" != x"no"; then
1172       # Install a library built with a cross compiler in tooldir, not libdir.
1173       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1174       toolexecmainlibdir='$(toolexecdir)/lib'
1175     else
1176       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1177       toolexecmainlibdir='$(libdir)'
1178     fi
1179     multi_os_directory=`$CC -print-multi-os-directory`
1180     case $multi_os_directory in
1181       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1182       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1183     esac
1184     ;;
1185 esac
1186 AC_SUBST(toolexecdir)
1187 AC_SUBST(toolexecmainlibdir)
1188 AC_SUBST(toolexeclibdir)
1189
1190 # Determine gcj version number.
1191 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1192 GCJVERSION=$gcjversion
1193 AC_SUBST(GCJVERSION)
1194 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1195
1196 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1197 # On that system, sys/ioctl.h will not include sys/filio.h unless
1198 # BSD_COMP is defined; just including sys/filio.h is simpler.
1199 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h pwd.h sys/config.h stdint.h langinfo.h locale.h)
1200 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1201 # for now.  If you change this, you also must update natFile.cc.
1202 AC_CHECK_HEADERS(dirent.h)
1203 AC_CHECK_HEADERS(inttypes.h, [
1204     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1205     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1206 ])
1207 AC_HEADER_SYS_WAIT
1208
1209 AC_CHECK_TYPE([ssize_t], [int])
1210
1211 AC_MSG_CHECKING([for in_addr_t])
1212 AC_TRY_COMPILE([#include <sys/types.h>
1213 #if STDC_HEADERS
1214 #include <stdlib.h>
1215 #include <stddef.h>
1216 #endif
1217 #if HAVE_NETINET_IN_H
1218 #include <netinet/in.h>
1219 #endif], [in_addr_t foo;],
1220   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1221      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1222    AC_MSG_RESULT(yes)],
1223   [AC_MSG_RESULT(no)])
1224
1225 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1226 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ip_mreq mreq;],
1227   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1228      [Define if struct ip_mreq is defined in netinet/in.h.])
1229    AC_MSG_RESULT(yes)],
1230   [AC_MSG_RESULT(no)])
1231
1232 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1233 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ipv6_mreq mreq6;],
1234   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1235      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1236    AC_MSG_RESULT(yes)],
1237   [AC_MSG_RESULT(no)])
1238
1239 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1240 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
1241   [AC_DEFINE(HAVE_INET6, 1,
1242      [Define if inet6 structures are defined in netinet/in.h.])
1243    AC_MSG_RESULT(yes)],
1244   [AC_MSG_RESULT(no)])
1245
1246 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1247 AC_TRY_COMPILE([#define _POSIX_PII_SOCKET
1248 #include <sys/types.h>
1249 #include <sys/socket.h>], [socklen_t x = 5;],
1250   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1251    AC_MSG_RESULT(yes)],
1252   [AC_MSG_RESULT(no)])
1253
1254 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1255 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
1256   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1257    AC_MSG_RESULT(yes)],
1258   [AC_MSG_RESULT(no)
1259    AC_MSG_CHECKING([for global timezone variable])
1260    dnl FIXME: we don't want a link check here because that won't work
1261    dnl when cross-compiling.  So instead we make an assumption that
1262    dnl the header file will mention timezone if it exists.
1263    dnl Don't find the win32 function timezone
1264    AC_TRY_COMPILE([#include <time.h>], [void i(){long z2 = 2*timezone;}],
1265      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1266       AC_MSG_RESULT(yes)],
1267      [AC_MSG_RESULT(no)
1268        AC_MSG_CHECKING([for global _timezone variable])
1269        dnl FIXME: As above, don't want link check
1270        AC_TRY_COMPILE([#include <time.h>], [long z2 = _timezone;],
1271          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1272             [Define if your platform has the global _timezone variable.])
1273           AC_MSG_RESULT(yes)],
1274           [AC_MSG_RESULT(no)])])])
1275
1276 AC_FUNC_ALLOCA
1277 AC_FUNC_MMAP
1278
1279 AC_CHECK_PROGS(PERL, perl, false)
1280
1281 SYSDEP_SOURCES=
1282 SIGNAL_HANDLER_AUX=
1283
1284 case "${host}" in
1285  i?86-*-linux*)
1286     SIGNAL_HANDLER=include/i386-signal.h
1287     ;;
1288  sparc*-sun-solaris*)
1289     SIGNAL_HANDLER=include/sparc-signal.h
1290     ;;
1291 # ia64-*)
1292 #    SYSDEP_SOURCES=sysdep/ia64.c
1293 #    test -d sysdep || mkdir sysdep
1294 #    ;;
1295  hppa*-*-linux*)
1296     SIGNAL_HANDLER=include/pa-signal.h
1297     ;;
1298  ia64-*-linux*)
1299     SIGNAL_HANDLER=include/dwarf2-signal.h
1300     ;;
1301  powerpc*-*-linux*)
1302     SIGNAL_HANDLER=include/powerpc-signal.h
1303     ;;
1304  alpha*-*-linux*)
1305     SIGNAL_HANDLER=include/dwarf2-signal.h
1306     ;;
1307  s390*-*-linux*)
1308     SIGNAL_HANDLER=include/s390-signal.h
1309     ;;
1310  x86_64*-*-linux*)
1311     SIGNAL_HANDLER=include/x86_64-signal.h
1312     SIGNAL_HANDLER_AUX=include/i386-signal.h
1313     ;;
1314  sparc*-*-linux*)
1315     SIGNAL_HANDLER=include/dwarf2-signal.h
1316     ;;
1317  sh-*-linux* | sh[[34]]*-*-linux*)
1318     SIGNAL_HANDLER=include/dwarf2-signal.h
1319     ;;
1320  *mingw*)
1321     SIGNAL_HANDLER=include/win32-signal.h
1322     ;;
1323  mips*-*-linux*)
1324     SIGNAL_HANDLER=include/mips-signal.h
1325     ;;
1326  *-*-darwin*)
1327     SIGNAL_HANDLER=include/darwin-signal.h
1328     ;;
1329  *)
1330     SIGNAL_HANDLER=include/default-signal.h
1331     ;;
1332 esac
1333
1334 # If we're using sjlj exceptions, forget what we just learned.
1335 if test "$enable_sjlj_exceptions" = yes; then
1336    SIGNAL_HANDLER=include/default-signal.h
1337    SIGNAL_HANDLER_AUX=
1338 fi
1339
1340 # Define here any compiler flags that you need in order to make backtrace() work.
1341 BACKTRACESPEC=
1342 case "${host}" in
1343  x86_64*-*-linux*|i?86-*)
1344     BACKTRACESPEC=-fno-omit-frame-pointer
1345     ;;
1346 esac
1347 AC_SUBST(BACKTRACESPEC)
1348
1349 AC_SUBST(SYSDEP_SOURCES)
1350
1351 if test -z "$SIGNAL_HANDLER_AUX"; then
1352   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1353 fi
1354
1355 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1356                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1357
1358 if test "${multilib}" = "yes"; then
1359   multilib_arg="--enable-multilib"
1360 else
1361   multilib_arg=
1362 fi
1363
1364
1365
1366 here=`${PWDCMD-pwd}`
1367 AC_SUBST(here)
1368
1369 # We get this from the environment.
1370 AC_SUBST(GCJFLAGS)
1371
1372 AC_OUTPUT(Makefile libgcj.pc libgcj.spec libgcj-test.spec gnu/classpath/Configuration.java gcj/Makefile include/Makefile testsuite/Makefile,
1373 [# Only add multilib support code if we just rebuilt top-level Makefile.
1374 case " $CONFIG_FILES " in
1375  *" Makefile "*)
1376    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1377    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
1378    ;;
1379 esac
1380
1381 # Make subdirectories and `.d' files.  Look in both srcdir and
1382 # builddir for the .java files.
1383 h=`${PWDCMD-pwd}`
1384 : > deps.mk
1385 ( (cd $srcdir && find . \( -name '*.java' -o -name '*.cc' -o -name '*.c' \) -print) ;
1386   find . \( -name '*.java' -o -name '*.cc' -o -name '*.c' \) -print) | \
1387    fgrep -v testsuite | \
1388    sed -e 's/\.java/.d/'\;'s/\.cc/.d/'\;'s/\.c/.d/' | \
1389    while read f; do
1390       echo "include $f" >> deps.mk
1391       test -f $f || {
1392          d=`echo $f | sed -e 's,/[[^/]]*$,,'`
1393          if test ! -d $d; then
1394            $libgcj_basedir/../mkinstalldirs $d
1395          fi;
1396          echo > $f
1397       }
1398    done
1399 ],
1400 srcdir=${srcdir}
1401 host=${host}
1402 target=${target}
1403 with_multisubdir=${with_multisubdir}
1404 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1405 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1406 libgcj_basedir=${libgcj_basedir}
1407 CC="${CC}"
1408 CXX="${CXX}"
1409 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1410 )