gcc/ada/a-cforma.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --   A D A . C O N T A I N E R S . F O R M A L _ O R D E R E D _ M A P S    --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2004-2013, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  21 --                                                                          --
  22 -- As a special exception under Section 7 of GPL version 3, you are granted --
  23 -- additional permissions described in the GCC Runtime Library Exception,   --
  24 -- version 3.1, as published by the Free Software Foundation.               --
  25 --                                                                          --
  26 -- You should have received a copy of the GNU General Public License and    --
  27 -- a copy of the GCC Runtime Library Exception along with this program;     --
  28 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  29 -- <http://www.gnu.org/licenses/>.                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  This spec is derived from package Ada.Containers.Bounded_Ordered_Maps in
  33 --  the Ada 2012 RM. The modifications are to facilitate formal proofs by
  34 --  making it easier to express properties.
  35
  36 --  The modifications are:
  37
  38 --    A parameter for the container is added to every function reading the
  39 --    content of a container: Key, Element, Next, Query_Element, Previous,
  40 --    Has_Element, Iterate, Reverse_Iterate. This change is motivated by the
  41 --    need to have cursors which are valid on different containers (typically a
  42 --    container C and its previous version C'Old) for expressing properties,
  43 --    which is not possible if cursors encapsulate an access to the underlying
  44 --    container. The operators "<" and ">" that could not be modified that way
  45 --    have been removed.
  46
  47 --    There are four new functions:
  48
  49 --      function Strict_Equal (Left, Right : Map) return Boolean;
  50 --      function Overlap (Left, Right : Map) return Boolean;
  51 --      function Left  (Container : Map; Position : Cursor) return Map;
  52 --      function Right (Container : Map; Position : Cursor) return Map;
  53
  54 --    See detailed specifications for these subprograms
  55
  56 private with Ada.Containers.Red_Black_Trees;
  57
  58 generic
  59    type Key_Type is private;
  60    type Element_Type is private;
  61
  62    with function "<" (Left, Right : Key_Type) return Boolean is <>;
  63    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  64
  65 package Ada.Containers.Formal_Ordered_Maps is
  66    pragma Pure;
  67
  68    function Equivalent_Keys (Left, Right : Key_Type) return Boolean;
  69
  70    type Map (Capacity : Count_Type) is tagged private;
  71    pragma Preelaborable_Initialization (Map);
  72
  73    type Cursor is private;
  74    pragma Preelaborable_Initialization (Cursor);
  75
  76    Empty_Map : constant Map;
  77
  78    No_Element : constant Cursor;
  79
  80    function "=" (Left, Right : Map) return Boolean;
  81
  82    function Length (Container : Map) return Count_Type;
  83
  84    function Is_Empty (Container : Map) return Boolean;
  85
  86    procedure Clear (Container : in out Map);
  87
  88    procedure Assign (Target : in out Map; Source : Map);
  89
  90    function Copy (Source : Map; Capacity : Count_Type := 0) return Map;
  91
  92    function Key (Container : Map; Position : Cursor) return Key_Type;
  93
  94    function Element (Container : Map; Position : Cursor) return Element_Type;
  95
  96    procedure Replace_Element
  97      (Container : in out Map;
  98       Position  : Cursor;
  99       New_Item  : Element_Type);
 100
 101    procedure Move (Target : in out Map; Source : in out Map);
 102
 103    procedure Insert
 104      (Container : in out Map;
 105       Key       : Key_Type;
 106       New_Item  : Element_Type;
 107       Position  : out Cursor;
 108       Inserted  : out Boolean);
 109
 110    procedure Insert
 111      (Container : in out Map;
 112       Key       : Key_Type;
 113       New_Item  : Element_Type);
 114
 115    procedure Include
 116      (Container : in out Map;
 117       Key       : Key_Type;
 118       New_Item  : Element_Type);
 119
 120    procedure Replace
 121      (Container : in out Map;
 122       Key       : Key_Type;
 123       New_Item  : Element_Type);
 124
 125    procedure Exclude (Container : in out Map; Key : Key_Type);
 126
 127    procedure Delete (Container : in out Map; Key : Key_Type);
 128
 129    procedure Delete (Container : in out Map; Position : in out Cursor);
 130
 131    procedure Delete_First (Container : in out Map);
 132
 133    procedure Delete_Last (Container : in out Map);
 134
 135    function First (Container : Map) return Cursor;
 136
 137    function First_Element (Container : Map) return Element_Type;
 138
 139    function First_Key (Container : Map) return Key_Type;
 140
 141    function Last (Container : Map) return Cursor;
 142
 143    function Last_Element (Container : Map) return Element_Type;
 144
 145    function Last_Key (Container : Map) return Key_Type;
 146
 147    function Next (Container : Map; Position : Cursor) return Cursor;
 148
 149    procedure Next (Container : Map; Position : in out Cursor);
 150
 151    function Previous (Container : Map; Position : Cursor) return Cursor;
 152
 153    procedure Previous (Container : Map; Position : in out Cursor);
 154
 155    function Find (Container : Map; Key : Key_Type) return Cursor;
 156
 157    function Element (Container : Map; Key : Key_Type) return Element_Type;
 158
 159    function Floor (Container : Map; Key : Key_Type) return Cursor;
 160
 161    function Ceiling (Container : Map; Key : Key_Type) return Cursor;
 162
 163    function Contains (Container : Map; Key : Key_Type) return Boolean;
 164
 165    function Has_Element (Container : Map; Position : Cursor) return Boolean;
 166
 167    function Strict_Equal (Left, Right : Map) return Boolean;
 168    --  Strict_Equal returns True if the containers are physically equal, i.e.
 169    --  they are structurally equal (function "=" returns True) and that they
 170    --  have the same set of cursors.
 171
 172    function Left  (Container : Map; Position : Cursor) return Map;
 173    function Right (Container : Map; Position : Cursor) return Map;
 174    --  Left returns a container containing all elements preceding Position
 175    --  (excluded) in Container. Right returns a container containing all
 176    --  elements following Position (included) in Container. These two new
 177    --  functions can be used to express invariant properties in loops which
 178    --  iterate over containers. Left returns the part of the container already
 179    --  scanned and Right the part not scanned yet.
 180
 181    function Overlap (Left, Right : Map) return Boolean;
 182    --  Overlap returns True if the containers have common keys
 183 private
 184
 185    pragma Inline (Next);
 186    pragma Inline (Previous);
 187
 188    subtype Node_Access is Count_Type;
 189
 190    use Red_Black_Trees;
 191
 192    type Node_Type is record
 193       Has_Element : Boolean := False;
 194       Parent  : Node_Access := 0;
 195       Left    : Node_Access := 0;
 196       Right   : Node_Access := 0;
 197       Color   : Red_Black_Trees.Color_Type := Red;
 198       Key     : Key_Type;
 199       Element : Element_Type;
 200    end record;
 201
 202    package Tree_Types is
 203      new Ada.Containers.Red_Black_Trees.Generic_Bounded_Tree_Types (Node_Type);
 204
 205    type Map (Capacity : Count_Type) is
 206       new Tree_Types.Tree_Type (Capacity) with null record;
 207
 208    type Cursor is record
 209       Node : Node_Access;
 210    end record;
 211
 212    Empty_Map : constant Map := (Capacity => 0, others => <>);
 213
 214    No_Element : constant Cursor := (Node => 0);
 215
 216 end Ada.Containers.Formal_Ordered_Maps;