libgomp/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal -I ../config && autoconf && autoheader && automake
   3
   4 AC_PREREQ(2.59)
   5 AC_INIT([GNU OpenMP Runtime Library], 1.0,,[libgomp])
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # -------
   9 # Options
  10 # -------
  11
  12 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  13 LIBGOMP_ENABLE(version-specific-runtime-libs, no, ,
  14    [Specify that runtime libraries should be installed in a compiler-specific directory],
  15    permit yes|no)
  16 AC_MSG_RESULT($enable_version_specific_runtime_libs)
  17
  18 AC_MSG_CHECKING([for --enable-linux-futex])
  19 LIBGOMP_ENABLE(linux-futex, default, ,
  20   [Use the Linux futex system call],
  21   permit yes|no|default)
  22 AC_MSG_RESULT($enable_linux_futex)
  23
  24 # -------
  25 # -------
  26
  27 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  28 #
  29 # You will slowly go insane if you do not grok the following fact:  when
  30 # building this library, the top-level /target/ becomes the library's /host/.
  31 #
  32 # configure then causes --target to default to --host, exactly like any
  33 # other package using autoconf.  Therefore, 'target' and 'host' will
  34 # always be the same.  This makes sense both for native and cross compilers
  35 # just think about it for a little while.  :-)
  36 #
  37 # Also, if this library is being configured as part of a cross compiler, the
  38 # top-level configure script will pass the "real" host as $with_cross_host.
  39 #
  40 # Do not delete or change the following two lines.  For why, see
  41 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  42 AC_CANONICAL_SYSTEM
  43 target_alias=${target_alias-$host_alias}
  44
  45 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  46 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  47 #  1.9.0:  minimum required version
  48 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  49 #              of other PACKAGE_* variables will, however, and there's nothing
  50 #              we can do about that; they come from AC_INIT).
  51 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  52 #            file in the top srcdir, etc, etc), so stop complaining.
  53 #  no-dependencies:  turns off auto dependency generation (just for now)
  54 #  -Wall:  turns on all automake warnings...
  55 #  -Wno-portability:  ...except this one, since GNU make is required.
  56 #  -Wno-override: ... and this one, since we do want this in testsuite.
  57 AM_INIT_AUTOMAKE([1.9.0 foreign -Wall -Wno-portability -Wno-override])
  58 AM_ENABLE_MULTILIB(, ..)
  59
  60 # Calculate toolexeclibdir
  61 # Also toolexecdir, though it's only used in toolexeclibdir
  62 case ${enable_version_specific_runtime_libs} in
  63   yes)
  64     # Need the gcc compiler version to know where to install libraries
  65     # and header files if --enable-version-specific-runtime-libs option
  66     # is selected.
  67     toolexecdir='$(libdir)/gcc/$(target_alias)'
  68     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  69     ;;
  70   no)
  71     if test -n "$with_cross_host" &&
  72        test x"$with_cross_host" != x"no"; then
  73       # Install a library built with a cross compiler in tooldir, not libdir.
  74       toolexecdir='$(exec_prefix)/$(target_alias)'
  75       toolexeclibdir='$(toolexecdir)/lib'
  76     else
  77       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
  78       toolexeclibdir='$(libdir)'
  79     fi
  80     multi_os_directory=`$CC -print-multi-os-directory`
  81     case $multi_os_directory in
  82       .) ;; # Avoid trailing /.
  83       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
  84     esac
  85     ;;
  86 esac
  87 AC_SUBST(toolexecdir)
  88 AC_SUBST(toolexeclibdir)
  89
  90 # Check the compiler.
  91 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  92 # We must force CC to /not/ be precious variables; otherwise
  93 # the wrong, non-multilib-adjusted value will be used in multilibs.
  94 # As a side effect, we have to subst CFLAGS ourselves.
  95
  96 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  97 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  98 AC_PROG_CC
  99 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 100
 101 AC_SUBST(CFLAGS)
 102
 103 # In order to override CFLAGS_FOR_TARGET, all of our special flags go
 104 # in XCFLAGS.  But we need them in CFLAGS during configury.  So put them
 105 # in both places for now and restore CFLAGS at the end of config.
 106 save_CFLAGS="$CFLAGS"
 107
 108 # Add -Wall -Werror if we are using GCC.
 109 if test "x$GCC" = "xyes"; then
 110   XCFLAGS="$XCFLAGS -Wall -Werror"
 111 fi
 112
 113 # Find other programs we need.
 114 AC_CHECK_TOOL(AR, ar)
 115 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 116 AC_PATH_PROG(PERL, perl, perl-not-found-in-path-error)
 117 AC_PROG_MAKE_SET
 118 AC_PROG_INSTALL
 119
 120 # Configure libtool
 121 AM_PROG_LIBTOOL
 122 AC_SUBST(enable_shared)
 123 AC_SUBST(enable_static)
 124
 125 AM_MAINTAINER_MODE
 126
 127 # We need gfortran to compile parts of the library
 128 # We can't use AC_PROG_FC because it expects a fully working gfortran.
 129 #AC_PROG_FC(gfortran)
 130 FC="$GFORTRAN"
 131 AC_PROG_FC(gfortran)
 132 FCFLAGS="$FCFLAGS -Wall"
 133
 134 # For libtool versioning info, format is CURRENT:REVISION:AGE
 135 libtool_VERSION=1:0:0
 136 AC_SUBST(libtool_VERSION)
 137
 138 # Check header files.
 139 AC_STDC_HEADERS
 140 AC_HEADER_TIME
 141 AC_CHECK_HEADERS(unistd.h semaphore.h sys/loadavg.h sys/time.h)
 142
 143 GCC_HEADER_STDINT(gstdint.h)
 144
 145 # Check to see if -pthread or -lpthread is needed.  Prefer the former.
 146 # In case the pthread.h system header is not found, this test will fail.
 147 XPCFLAGS=""
 148
 149 # Darwin doesn't need the -pthread option since threads are in libSystem
 150 AC_LINK_IFELSE(
 151  [AC_LANG_PROGRAM(
 152   [#include <pthread.h>
 153    void *g(void *d) { return NULL; }],
 154   [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 155  [case $host in
 156    *-darwin*)
 157      ;;
 158    default)
 159      XPCFLAGS=" -Wc,-pthread"
 160      ;;
 161      esac],
 162  [CFLAGS="$save_CFLAGS" LIBS="-lpthread $LIBS"
 163   AC_LINK_IFELSE(
 164    [AC_LANG_PROGRAM(
 165     [#include <pthread.h>
 166      void *g(void *d) { return NULL; }],
 167     [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 168    [],
 169    [AC_MSG_ERROR([Pthreads are required to build libgomp])])])
 170
 171 # Check for functions needed.
 172 AC_CHECK_FUNCS(getloadavg clock_gettime)
 173
 174 # Check for broken semaphore implementation on darwin.
 175 # sem_init returns: sem_init error: Function not implemented.
 176 case "$host" in
 177   *-darwin*)
 178     AC_DEFINE(HAVE_BROKEN_POSIX_SEMAPHORES, 1,
 179         Define if the POSIX Semaphores do not work on your system.)
 180     ;;
 181   *-linux*)
 182     case "$enable_linux_futex" in
 183       default)
 184         # If headers don't have gettid/futex syscalls definition, then
 185         # default to no, otherwise there will be compile time failures.
 186         # Otherwise, default to yes.  If we don't detect we are
 187         # compiled/linked against NPTL and not cross-compiling, check
 188         # if programs are run by default against NPTL and if not, issue
 189         # a warning.
 190         enable_linux_futex=no
 191         AC_LINK_IFELSE(
 192          [AC_LANG_PROGRAM(
 193           [#include <sys/syscall.h>
 194            int lk;],
 195           [syscall (SYS_gettid); syscall (SYS_futex, &lk, 0, 0, 0);])],
 196           [AC_LINK_IFELSE(
 197            [AC_LANG_PROGRAM(
 198             [#ifndef _GNU_SOURCE
 199              #define _GNU_SOURCE 1
 200              #endif
 201              #include <pthread.h>
 202              pthread_t th; void *status;],
 203             [pthread_tryjoin_np (th, &status);])],[enable_linux_futex=yes],
 204             [if test x$cross_compiling = xno; then
 205                if getconf GNU_LIBPTHREAD_VERSION 2>/dev/null \
 206                   | LC_ALL=C grep -i NPTL > /dev/null 2>/dev/null; then
 207                  AC_MSG_WARN([The kernel might not support futex or gettid syscalls.
 208 If so, please configure with --disable-linux-futex])
 209                fi
 210              fi
 211              enable_linux_futex=yes])])
 212         ;;
 213       yes)
 214         AC_LINK_IFELSE(
 215          [AC_LANG_PROGRAM(
 216           [#include <sys/syscall.h>
 217            int lk;],
 218           [syscall (SYS_gettid); syscall (SYS_futex, &lk, 0, 0, 0);])],[],
 219           [AC_MSG_ERROR([SYS_gettid and SYS_futex required for --enable-linux-futex])])
 220         ;;
 221     esac
 222     ;;
 223 esac
 224
 225 # At least for glibc, clock_gettime is in librt.  But don't pull that
 226 # in if it still doesn't give us the function we want.
 227 if test $ac_cv_func_clock_gettime = no; then
 228   AC_CHECK_LIB(rt, clock_gettime,
 229     [LIBS="-lrt $LIBS"
 230      AC_DEFINE(HAVE_CLOCK_GETTIME,
 231                [Define to 1 if you have the `clock_gettime' function.])])
 232 fi
 233
 234 # See if we support thread-local storage.
 235 GCC_CHECK_TLS
 236
 237 # See what sort of export controls are availible.
 238 LIBGOMP_CHECK_ATTRIBUTE_VISIBILITY
 239 LIBGOMP_CHECK_ATTRIBUTE_DLLEXPORT
 240 LIBGOMP_CHECK_ATTRIBUTE_ALIAS
 241 LIBGOMP_ENABLE_SYMVERS
 242
 243 # Get target configury.
 244 . ${srcdir}/configure.tgt
 245 CFLAGS="$save_CFLAGS $XCFLAGS"
 246
 247 # Check for __sync_val_compare_and_swap, but only after the target has
 248 # had a chance to set XCFLAGS.
 249 LIBGOMP_CHECK_SYNC_BUILTINS
 250
 251 XCFLAGS="$XCFLAGS$XPCFLAGS"
 252
 253 AC_SUBST(config_path)
 254 AC_SUBST(XCFLAGS)
 255 AC_SUBST(XLDFLAGS)
 256
 257 # Cleanup and exit.
 258 CFLAGS="$save_CFLAGS"
 259 AC_CACHE_SAVE
 260
 261 if test ${multilib} = yes; then
 262   multilib_arg="--enable-multilib"
 263 else
 264   multilib_arg=
 265 fi
 266
 267 # Set up the set of libraries that we need to link against for libgomp.
 268 # Note that the GOMP_SELF_SPEC in gcc.c will force -pthread for -fopenmp,
 269 # which will force linkage against -lpthread (or equivalent for the system).
 270 # That's not 100% ideal, but about the best we can do easily.
 271 if test $enable_shared = yes; then
 272   link_gomp="-lgomp %{static: $LIBS}"
 273 else
 274   link_gomp="-lgomp $LIBS"
 275 fi
 276 AC_SUBST(link_gomp)
 277
 278 AM_CONDITIONAL([USE_FORTRAN], [test "$ac_cv_fc_compiler_gnu" = yes])
 279
 280 # ??? 2006-01-24: Paulo committed to asking autoconf folk to document
 281 # and export AC_COMPUTE_INT.  If that happens, then we'll need to remove
 282 # the underscore here and update the PREREQ.  If it doesn't, then we'll
 283 # need to copy this macro to our acinclude.m4.
 284 save_CFLAGS="$CFLAGS"
 285 for i in $config_path; do
 286   if test -f $srcdir/config/$i/omp-lock.h; then
 287     CFLAGS="$CFLAGS -include $srcdir/config/$i/omp-lock.h"
 288     break
 289   fi
 290 done
 291
 292 _AC_COMPUTE_INT([sizeof (omp_lock_t)], [OMP_LOCK_SIZE],,
 293   [AC_MSG_ERROR([unsupported system, cannot find sizeof (omp_lock_t)])])
 294 _AC_COMPUTE_INT([__alignof (omp_lock_t)], [OMP_LOCK_ALIGN])
 295 _AC_COMPUTE_INT([sizeof (omp_nest_lock_t)], [OMP_NEST_LOCK_SIZE])
 296 _AC_COMPUTE_INT([__alignof (omp_nest_lock_t)], [OMP_NEST_LOCK_ALIGN])
 297
 298 # If the lock fits in an integer, then arrange for Fortran to use that
 299 # integer.  If it doesn't, then arrange for Fortran to use a pointer.
 300 # Except that we don't have a way at present to multi-lib the installed
 301 # Fortran modules, so we assume 8 bytes for pointers, regardless of the
 302 # actual target.
 303 OMP_LOCK_KIND=$OMP_LOCK_SIZE
 304 OMP_NEST_LOCK_KIND=$OMP_NEST_LOCK_SIZE
 305 if test $OMP_LOCK_SIZE -gt 8 || test $OMP_LOCK_ALIGN -gt $OMP_LOCK_SIZE; then
 306   OMP_LOCK_KIND=8
 307 fi
 308 if test $OMP_NEST_LOCK_SIZE -gt 8 || test $OMP_NEST_LOCK_ALIGN -gt $OMP_NEST_LOCK_SIZE; then
 309   OMP_NEST_LOCK_KIND=8
 310 fi
 311
 312 AC_SUBST(OMP_LOCK_SIZE)
 313 AC_SUBST(OMP_LOCK_ALIGN)
 314 AC_SUBST(OMP_NEST_LOCK_SIZE)
 315 AC_SUBST(OMP_NEST_LOCK_ALIGN)
 316 AC_SUBST(OMP_LOCK_KIND)
 317 AC_SUBST(OMP_NEST_LOCK_KIND)
 318 CFLAGS="$save_CFLAGS"
 319
 320 AC_CONFIG_FILES(omp.h omp_lib.h omp_lib.f90 libgomp_f.h)
 321 AC_CONFIG_FILES(Makefile testsuite/Makefile libgomp.spec)
 322 AC_OUTPUT