libgcc/configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2
   3 sinclude(../config/enable.m4)
   4 sinclude(../config/tls.m4)
   5 sinclude(../config/acx.m4)
   6 sinclude(../config/no-executables.m4)
   7 sinclude(../config/lib-ld.m4)
   8 sinclude(../config/override.m4)
   9 sinclude(../config/picflag.m4)
  10 sinclude(../config/dfp.m4)
  11 sinclude(../config/unwind_ipinfo.m4)
  12 sinclude(../config/gthr.m4)
  13 sinclude(../config/sjlj.m4)
  14 sinclude(../config/cet.m4)
  15
  16 AC_PREREQ(2.64)
  17 AC_INIT([GNU C Runtime Library], 1.0,,[libgcc])
  18 AC_CONFIG_SRCDIR([static-object.mk])
  19
  20 # The libgcc should not depend on any header files
  21 AC_DEFUN([_AC_INCLUDES_DEFAULT_REQUIREMENTS],
  22   [m4_divert_text([DEFAULTS],
  23     [ac_includes_default='/* none */'])])
  24
  25 AC_ARG_WITH(target-subdir,
  26 [  --with-target-subdir=SUBDIR      Configuring in a subdirectory for target])
  27 AC_ARG_WITH(cross-host,
  28 [  --with-cross-host=HOST           Configuring with a cross compiler])
  29 AC_ARG_WITH(ld,
  30 [  --with-ld               arrange to use the specified ld (full pathname)])
  31
  32 if test "${srcdir}" = "."; then
  33   if test -n "${with_build_subdir}"; then
  34     libgcc_topdir="${srcdir}/../.."
  35     with_target_subdir=
  36   elif test -z "${with_target_subdir}"; then
  37     libgcc_topdir="${srcdir}/.."
  38   else
  39     if test "${with_target_subdir}" != "."; then
  40       libgcc_topdir="${srcdir}/${with_multisrctop}../.."
  41     else
  42       libgcc_topdir="${srcdir}/${with_multisrctop}.."
  43     fi
  44   fi
  45 else
  46   libgcc_topdir="${srcdir}/.."
  47 fi
  48 AC_SUBST(libgcc_topdir)
  49 AC_CONFIG_AUX_DIR($libgcc_topdir)
  50 AC_CONFIG_HEADER(auto-target.h:config.in)
  51
  52 AC_ARG_ENABLE(shared,
  53 [  --disable-shared        don't provide a shared libgcc],
  54 [
  55   case $enable_shared in
  56   yes | no) ;;
  57   *)
  58     enable_shared=no
  59     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
  60     for pkg in $enableval; do
  61       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
  62         enable_shared=yes
  63       fi
  64     done
  65     IFS="$ac_save_ifs"
  66     ;;
  67   esac
  68 ], [enable_shared=yes])
  69 AC_SUBST(enable_shared)
  70
  71 AC_ARG_ENABLE(vtable-verify,
  72 [  --enable-vtable-verify    Enable vtable verification feature ],
  73 [case "$enableval" in
  74  yes) enable_vtable_verify=yes ;;
  75  no)  enable_vtable_verify=no ;;
  76  *)   enable_vtable_verify=no;;
  77  esac],
  78 [enable_vtable_verify=no])
  79 AC_SUBST(enable_vtable_verify)
  80
  81 AC_ARG_WITH(aix-soname,
  82 [AS_HELP_STRING([--with-aix-soname=aix|svr4|both],
  83     [shared library versioning (aka "SONAME") variant to provide on AIX])],
  84 [case "${host}:${enable_shared}" in
  85  power*-*-aix[[5-9]]*:yes)
  86    AC_MSG_CHECKING([which variant of shared library versioning to provide for shared libgcc])
  87    case ${withval} in
  88      aix|svr4|both) ;;
  89      *) AC_MSG_ERROR([Unknown argument to --with-aix-soname]);;
  90    esac
  91    AC_MSG_RESULT($withval)
  92    ;;
  93  *) with_aix_soname=aix ;;
  94  esac
  95 ], [with_aix_soname=aix])
  96 AC_SUBST(with_aix_soname)
  97
  98 GCC_PICFLAG
  99 AC_SUBST(PICFLAG)
 100
 101 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 102 AC_ARG_ENABLE(version-specific-runtime-libs,
 103 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
 104 [case "$enableval" in
 105  yes) version_specific_libs=yes ;;
 106  no)  version_specific_libs=no ;;
 107  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 108  esac],
 109 [version_specific_libs=no])
 110 AC_MSG_RESULT($version_specific_libs)
 111
 112 AC_ARG_WITH(slibdir,
 113 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
 114 slibdir="$with_slibdir",
 115 if test "${version_specific_libs}" = yes; then
 116   slibdir='$(libsubdir)'
 117 elif test -n "$with_cross_host" && test x"$with_cross_host" != x"no"; then
 118   slibdir='$(exec_prefix)/$(host_noncanonical)/lib'
 119 else
 120   slibdir='$(libdir)'
 121 fi)
 122 AC_SUBST(slibdir)
 123
 124 # Command-line options.
 125 # Very limited version of AC_MAINTAINER_MODE.
 126 AC_ARG_ENABLE([maintainer-mode],
 127   [AC_HELP_STRING([--enable-maintainer-mode],
 128                  [enable make rules and dependencies not useful (and
 129                   sometimes confusing) to the casual installer])],
 130   [case ${enable_maintainer_mode} in
 131      yes) MAINT='' ;;
 132      no) MAINT='#' ;;
 133      *) AC_MSG_ERROR([--enable-maintainer-mode must be yes or no]) ;;
 134    esac
 135    maintainer_mode=${enableval}],
 136   [MAINT='#'])
 137 AC_SUBST([MAINT])dnl
 138
 139 AC_PROG_INSTALL
 140
 141 AC_PROG_AWK
 142 # We need awk; bail out if it's missing.
 143 case ${AWK} in
 144   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 145 esac
 146
 147 AC_CANONICAL_HOST
 148 ACX_NONCANONICAL_HOST
 149 ACX_NONCANONICAL_TARGET
 150 GCC_TOPLEV_SUBDIRS
 151
 152 # Calculate toolexeclibdir
 153 # Also toolexecdir, though it's only used in toolexeclibdir
 154 case ${version_specific_libs} in
 155   yes)
 156     # Need the gcc compiler version to know where to install libraries
 157     # and header files if --enable-version-specific-runtime-libs option
 158     # is selected.
 159     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
 160     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 161     ;;
 162   no)
 163     if test -n "$with_cross_host" &&
 164        test x"$with_cross_host" != x"no"; then
 165       # Install a library built with a cross compiler in tooldir, not libdir.
 166       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 167       toolexeclibdir='$(toolexecdir)/lib'
 168     else
 169       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 170       toolexeclibdir='$(libdir)'
 171     fi
 172     multi_os_directory=`$CC -print-multi-os-directory`
 173     case $multi_os_directory in
 174       .) ;; # Avoid trailing /.
 175       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 176     esac
 177     ;;
 178 esac
 179 AC_SUBST(toolexecdir)
 180 AC_SUBST(toolexeclibdir)
 181
 182 dnl These must be called before AM_PROG_LIBTOOL, because it may want
 183 dnl to call AC_CHECK_PROG.
 184 AC_CHECK_TOOL(AR, ar)
 185 AC_CHECK_TOOL(LIPO, lipo, :)
 186 AC_CHECK_TOOL(NM, nm)
 187 AC_CHECK_TOOL(RANLIB, ranlib, :)
 188 AC_CHECK_TOOL(STRIP, strip, :)
 189 AC_PROG_LN_S
 190
 191 GCC_NO_EXECUTABLES
 192 AC_PROG_CC
 193 AC_PROG_CPP_WERROR
 194
 195 AC_SYS_LARGEFILE
 196
 197 AC_CHECK_SIZEOF([double])
 198 AC_CHECK_SIZEOF([long double])
 199 AS_VAR_ARITH([double_type_size], [$ac_cv_sizeof_double \* 8])
 200 AS_VAR_ARITH([long_double_type_size], [$ac_cv_sizeof_long_double \* 8])
 201 AC_SUBST(double_type_size)
 202 AC_SUBST(long_double_type_size)
 203
 204 AC_CHECK_HEADERS(inttypes.h stdint.h stdlib.h ftw.h \
 205         unistd.h sys/stat.h sys/types.h \
 206         string.h strings.h memory.h)
 207 AC_HEADER_STDC
 208
 209 # Check for decimal float support.
 210 AC_CACHE_CHECK([whether decimal floating point is supported], [libgcc_cv_dfp],
 211                [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 212 #include <fenv.h>
 213 ]], [[
 214 _Decimal32 x;
 215 int fe_except =
 216   FE_INVALID|FE_DIVBYZERO|FE_OVERFLOW|FE_UNDERFLOW|FE_INEXACT;
 217 ]])],
 218                                   [libgcc_cv_dfp=yes],
 219                                   [libgcc_cv_dfp=no])])
 220 decimal_float=$libgcc_cv_dfp
 221 AC_SUBST(decimal_float)
 222
 223 GCC_AC_ENABLE_DECIMAL_FLOAT([$host])
 224
 225 # Check for fixed-point support.
 226 AC_CACHE_CHECK([whether fixed-point is supported], [libgcc_cv_fixed_point],
 227                [AC_COMPILE_IFELSE([_Sat _Fract x;], [libgcc_cv_fixed_point=yes],
 228                                   [libgcc_cv_fixed_point=no])])
 229 fixed_point=$libgcc_cv_fixed_point
 230 AC_SUBST(fixed_point)
 231
 232 # For platforms with the unwind ABI which includes an unwind library,
 233 # libunwind, we can choose to use the system libunwind.
 234 # config.gcc also contains tests of with_system_libunwind.
 235 GCC_CHECK_UNWIND_GETIPINFO
 236
 237 # Check if the compiler is configured for setjmp/longjmp exceptions.
 238 GCC_CHECK_SJLJ_EXCEPTIONS
 239
 240 GCC_CET_FLAGS(CET_FLAGS)
 241 AC_SUBST(CET_FLAGS)
 242
 243 AC_ARG_ENABLE([explicit-exception-frame-registration],
 244   [AC_HELP_STRING([--enable-explicit-exception-frame-registration],
 245      [register exception tables explicitly at module start, for use
 246       e.g. for compatibility with installations without PT_GNU_EH_FRAME support])],
 247 [
 248 force_explicit_eh_registry=
 249 if test "$enable_explicit_exception_frame_registration" = yes; then
 250   if test $ac_cv_sjlj_exceptions = yes; then
 251     AC_MSG_ERROR([Can't --enable-explicit-exception-frame-registration
 252                   with setjmp/longjmp exceptions])
 253   fi
 254   force_explicit_eh_registry=-DUSE_EH_FRAME_REGISTRY_ALWAYS
 255 fi
 256 ])
 257 AC_SUBST([force_explicit_eh_registry])
 258
 259 AC_LIB_PROG_LD_GNU
 260
 261 AC_MSG_CHECKING([for thread model used by GCC])
 262 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 263 AC_MSG_RESULT([$target_thread_file])
 264
 265 # Check for assembler CFI support.
 266 AC_CACHE_CHECK([whether assembler supports CFI directives], [libgcc_cv_cfi],
 267                [AC_COMPILE_IFELSE(
 268 [asm("\n\
 269         .text\n\
 270         .cfi_startproc\n\
 271         .cfi_personality 0, symbol\n\
 272         .cfi_endproc");],
 273   [libgcc_cv_cfi=yes],
 274   [libgcc_cv_cfi=no])])
 275
 276 # Check 32bit or 64bit.  In the case of MIPS, this really determines the
 277 # word size rather than the address size.
 278 cat > conftest.c <<EOF
 279 #if defined(__x86_64__) || (!defined(__i386__) && defined(__LP64__)) \
 280     || defined(__mips64)
 281 host_address=64
 282 #else
 283 host_address=32
 284 #endif
 285 EOF
 286 eval `${CC-cc} -E conftest.c | grep host_address=`
 287 rm -f conftest.c
 288
 289 case ${host} in
 290 mips*-*-*)
 291   AC_CACHE_CHECK([whether the target is hard-float],
 292                  [libgcc_cv_mips_hard_float],
 293                  [AC_COMPILE_IFELSE(
 294     [#ifndef __mips_hard_float
 295      #error FOO
 296      #endif],
 297     [libgcc_cv_mips_hard_float=yes],
 298     [libgcc_cv_mips_hard_float=no])])
 299 esac
 300
 301 case ${host} in
 302 *-*-solaris2*)
 303   # Check for system-provided CRTs on Solaris 11.4.
 304   AC_CACHE_CHECK([system-provided CRTs on Solaris],
 305                  [libgcc_cv_solaris_crts],
 306     [libgcc_cv_solaris_crts=no
 307      libgcc_sysroot="`${CC} -print-sysroot`"
 308      libgcc_libdir="$libgcc_sysroot/usr/lib"
 309      # At the time they were added, gcrt1.o became a symlink for backwards
 310      # compatibility on x86, while crt1.o was added on sparc, so check for that.
 311      case ${host} in
 312        i?86-*-solaris2* | x86_64-*-solaris2*)
 313          if test -h "$libgcc_libdir/gcrt1.o"; then libgcc_cv_solaris_crts=yes; fi
 314          ;;
 315        sparc*-*-solaris2*)
 316          if test -f "$libgcc_libdir/crt1.o"; then libgcc_cv_solaris_crts=yes; fi
 317          ;;
 318      esac])
 319   if test $libgcc_cv_solaris_crts = yes; then
 320     AC_DEFINE(HAVE_SOLARIS_CRTS, 1,
 321       [Define if the system-provided CRTs are present on Solaris.])
 322   fi
 323   ;;
 324 esac
 325
 326 # Determine the version of glibc, if any, used on the target.
 327 AC_MSG_CHECKING([for target glibc version])
 328 AC_ARG_WITH([glibc-version],
 329   [AS_HELP_STRING([--with-glibc-version=M.N],
 330     [assume GCC used with glibc version M.N or later])], [
 331 if [echo "$with_glibc_version" | grep '^[0-9][0-9]*\.[0-9][0-9]*$']; then
 332   glibc_version_major=`echo "$with_glibc_version" | sed -e 's/\..*//'`
 333   glibc_version_minor=`echo "$with_glibc_version" | sed -e 's/.*\.//'`
 334 else
 335   AC_MSG_ERROR([option --with-glibc-version requires a version number M.N])
 336 fi], [
 337 AC_COMPUTE_INT([glibc_version_major], [__GLIBC__],
 338                                       [#include <features.h>],
 339                                       [glibc_version_major=0])
 340 AC_COMPUTE_INT([glibc_version_minor], [__GLIBC_MINOR__],
 341                                       [#include <features.h>],
 342                                       [glibc_version_minor=0])])
 343 AC_MSG_RESULT([$glibc_version_major.$glibc_version_minor])
 344
 345 # Determine floating-point type for powerpc*-*-linux*.
 346 # Single-precision-only FPRs are not a supported configuration for
 347 # this target, so are not allowed for in this test.
 348 case ${host} in
 349 powerpc*-*-linux*)
 350   cat > conftest.c <<EOF
 351 #ifdef __powerpc64__
 352 ppc_fp_type=64
 353 #elif defined _SOFT_FLOAT
 354 ppc_fp_type=soft
 355 #elif defined _SOFT_DOUBLE
 356 ppc_fp_type=e500v1
 357 #elif defined __NO_FPRS__
 358 ppc_fp_type=e500v2
 359 #else
 360 ppc_fp_type=hard
 361 #endif
 362 EOF
 363 eval `${CC-cc} -E conftest.c | grep ppc_fp_type=`
 364 rm -f conftest.c
 365 # glibc 2.19 and later provide all the soft-fp functions, with proper
 366 # interactions with <fenv.h> exception and rounding mode handling, so
 367 # make libgcc's versions into compat symbols if a recent enough glibc
 368 # version is being used.
 369 ppc_fp_compat=
 370 case ${ppc_fp_type} in
 371 soft|e500v1|e500v2)
 372   if test $glibc_version_major -gt 2 \
 373     || ( test $glibc_version_major -eq 2 \
 374         && test $glibc_version_minor -ge 19 ); then
 375     ppc_fp_compat="t-softfp-compat"
 376   fi
 377   ;;
 378 esac
 379 ;;
 380 esac
 381
 382 case ${host} in
 383 # At present, we cannot turn -mfloat128 on via #pragma GCC target, so just
 384 # check if we have VSX (ISA 2.06) support to build the software libraries, and
 385 # whether the assembler can handle xsaddqp for hardware support.  Also check if
 386 # a new glibc is being used so that __builtin_cpu_supports can be used.
 387 powerpc*-*-linux*)
 388   saved_CFLAGS="$CFLAGS"
 389   CFLAGS="$CFLAGS -mabi=altivec -mvsx -mfloat128"
 390   AC_CACHE_CHECK([for PowerPC ISA 2.06 to build __float128 libraries],
 391                  [libgcc_cv_powerpc_float128],
 392                  [AC_COMPILE_IFELSE(
 393     [vector double dadd (vector double a, vector double b) { return a + b; }],
 394     [libgcc_cv_powerpc_float128=yes],
 395     [libgcc_cv_powerpc_float128=no])])
 396
 397   CFLAGS="$CFLAGS -mpower9-vector -mfloat128-hardware"
 398   AC_CACHE_CHECK([for PowerPC ISA 3.0 to build hardware __float128 libraries],
 399                  [libgcc_cv_powerpc_float128_hw],
 400                  [AC_COMPILE_IFELSE(
 401     [#include <sys/auxv.h>
 402      #ifndef AT_PLATFORM
 403      #error "AT_PLATFORM is not defined"
 404      #endif
 405      #ifndef __BUILTIN_CPU_SUPPORTS__
 406      #error "__builtin_cpu_supports is not available"
 407      #endif
 408      vector unsigned char add (vector unsigned char a, vector unsigned char b)
 409      {
 410        vector unsigned char ret;
 411        __asm__ ("xsaddqp %0,%1,%2" : "=v" (ret) : "v" (a), "v" (b));
 412        return ret;
 413      }
 414      void *add_resolver (void) { return (void *) add; }
 415      __float128 add_ifunc (__float128, __float128)
 416         __attribute__ ((__ifunc__ ("add_resolver")));],
 417     [libgcc_cv_powerpc_float128_hw=yes],
 418     [libgcc_cv_powerpc_float128_hw=no])])
 419   CFLAGS="$saved_CFLAGS"
 420 esac
 421
 422 # Collect host-machine-specific information.
 423 . ${srcdir}/config.host
 424
 425 # Used for constructing correct paths for offload compilers.
 426 accel_dir_suffix=
 427 real_host_noncanonical=${host_noncanonical}
 428 if test x"$enable_as_accelerator_for" != x; then
 429   accel_dir_suffix=/accel/${target_noncanonical}
 430   real_host_noncanonical=${enable_as_accelerator_for}
 431 fi
 432 AC_SUBST(accel_dir_suffix)
 433 AC_SUBST(real_host_noncanonical)
 434
 435 if test x"$enable_offload_targets" != x; then
 436   extra_parts="${extra_parts} crtoffloadbegin.o crtoffloadend.o crtoffloadtable.o"
 437 fi
 438
 439 # Check if Solaris/x86 linker supports ZERO terminator unwind entries.
 440 # This is after config.host so we can augment tmake_file.
 441 # Link with -nostartfiles -nodefaultlibs since neither are present while
 442 # building libgcc.
 443 case ${host} in
 444 i?86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
 445   cat > conftest.s <<EOF
 446         .section        .eh_frame,"a",@unwind
 447         .zero   4
 448         .section        .jcr,"aw",@progbits
 449         .zero   8
 450 EOF
 451   if AC_TRY_COMMAND(${CC-cc} -shared -nostartfiles -nodefaultlibs -o conftest.so conftest.s 1>&AS_MESSAGE_LOG_FD); then
 452       tmake_file="${tmake_file} i386/t-crtstuff"
 453   fi
 454   ;;
 455 esac
 456
 457 # Check if xtensa target is configured for windowed ABI and thus needs to use
 458 # custom unwind code.
 459 # This is after config.host so we can augment tmake_file.
 460 case ${host} in
 461 xtensa*-*)
 462   cat > conftest.c <<EOF
 463         #ifdef __XTENSA_CALL0_ABI__
 464         #error
 465         #endif
 466 EOF
 467   if AC_TRY_COMMAND(${CC-cc} -E -o conftest.i conftest.c 1>&AS_MESSAGE_LOG_FD); then
 468       tmake_file="${tmake_file} xtensa/t-windowed"
 469   fi
 470   ;;
 471 esac
 472
 473 # Check for visibility support.  This is after config.host so that
 474 # we can check for asm_hidden_op.
 475 AC_CACHE_CHECK([for __attribute__((visibility("hidden")))],
 476     libgcc_cv_hidden_visibility_attribute, [
 477         echo 'int __attribute__ ((visibility ("hidden"))) foo (void) { return 1; }' > conftest.c
 478         libgcc_cv_hidden_visibility_attribute=no
 479         if AC_TRY_COMMAND(${CC-cc} -Werror -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 480             if grep "\\$asm_hidden_op.*foo" conftest.s >/dev/null; then
 481                 libgcc_cv_hidden_visibility_attribute=yes
 482             fi
 483         fi
 484         rm -f conftest.*
 485     ])
 486
 487 if test $libgcc_cv_hidden_visibility_attribute = yes; then
 488     vis_hide='-fvisibility=hidden -DHIDE_EXPORTS'
 489     AC_DEFINE_UNQUOTED(AS_HIDDEN_DIRECTIVE, $asm_hidden_op, [Define to the .hidden-like directive if it exists.])
 490 else
 491     vis_hide=
 492 fi
 493 AC_SUBST(vis_hide)
 494
 495 # Check for .cfi_sections .debug_frame support.
 496 AC_CACHE_CHECK([for .cfi_sections .debug_frame],
 497     libgcc_cv_cfi_sections_directive, [
 498         echo 'int foo (int, char *);' > conftest.c
 499         echo 'int bar (int x) { char *y = __builtin_alloca (x); return foo (x + 1, y) + 1; }' >> conftest.c
 500         libgcc_cv_cfi_sections_directive=no
 501         if AC_TRY_COMMAND(${CC-cc} -Werror -g -fno-asynchronous-unwind-tables -fno-unwind-tables -fno-exceptions -S conftest.c -o conftest.s 1>&AS_MESSAGE_LOG_FD); then
 502             if grep "\\.cfi_sections.*\\.debug_frame" conftest.s >/dev/null; then
 503                 libgcc_cv_cfi_sections_directive=yes
 504             fi
 505         fi
 506         rm -f conftest.*
 507     ])
 508 if test $libgcc_cv_cfi_sections_directive = yes; then
 509     AC_DEFINE(HAVE_AS_CFI_SECTIONS, 1, [Define to 1 if the assembler supports .cfi_sections .debug_frame directive.])
 510 fi
 511
 512 # See if we have thread-local storage.  We can only test assembler
 513 # since link-time and run-time tests require the newly built
 514 # gcc, which can't be used to build executable due to that libgcc
 515 # is yet to be built here.
 516 GCC_CHECK_CC_TLS
 517 set_have_cc_tls=
 518 if test "$enable_tls $gcc_cv_have_cc_tls" = "yes yes"; then
 519   set_have_cc_tls="-DHAVE_CC_TLS"
 520 fi
 521 AC_SUBST(set_have_cc_tls)
 522
 523 # See if we have emulated thread-local storage.
 524 GCC_CHECK_EMUTLS
 525 set_use_emutls=
 526 if test "$enable_tls $gcc_cv_use_emutls" = "yes yes"; then
 527   set_use_emutls="-DUSE_EMUTLS"
 528 fi
 529 AC_SUBST(set_use_emutls)
 530
 531 dnl Check if as supports AVX instructions.
 532 AC_DEFUN([LIBGCC_CHECK_AS_AVX], [
 533 case "${target}" in
 534 i[[34567]]86-*-* | x86_64-*-*)
 535   AC_CACHE_CHECK([if the assembler supports AVX], libgcc_cv_as_avx, [
 536     AC_TRY_COMPILE([], [asm("vzeroupper");],
 537                    [libgcc_cv_as_avx=yes], [libgcc_cv_as_avx=no])
 538   ])
 539   if test x$libgcc_cv_as_avx = xyes; then
 540     AC_DEFINE(HAVE_AS_AVX, 1, [Define to 1 if the assembler supports AVX.])
 541   fi
 542   ;;
 543 esac])
 544 LIBGCC_CHECK_AS_AVX
 545
 546 dnl Check if as supports RTM instructions.
 547 AC_CACHE_CHECK(for init priority support, libgcc_cv_init_priority, [
 548 AC_COMPILE_IFELSE([AC_LANG_PROGRAM(,
 549   [[void ip (void) __attribute__ ((constructor (1)));]])],
 550   [libgcc_cv_init_priority=yes],[libgcc_cv_init_priority=no])])
 551 if test $libgcc_cv_init_priority = yes; then
 552   AC_DEFINE(HAVE_INIT_PRIORITY, 1,
 553   [Define if the compiler supports init priority.])
 554 fi
 555
 556 # Conditionalize the sfp-machine.h header for this target machine.
 557 if test -z "${sfp_machine_header}"; then
 558         sfp_machine_header=$cpu_type/sfp-machine.h
 559         if test -f ${srcdir}/config/${sfp_machine_header}; then
 560                 :
 561         else
 562                 sfp_machine_header=no-sfp-machine.h
 563         fi
 564 fi
 565 AC_SUBST(sfp_machine_header)
 566
 567 # Conditionalize the makefile for this target machine.
 568 tmake_file_=
 569 for f in ${tmake_file}
 570 do
 571         if test -f ${srcdir}/config/$f
 572         then
 573                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 574         fi
 575 done
 576 tmake_file="${tmake_file_}"
 577 AC_SUBST(tmake_file)
 578
 579 # Likewise export definitions for libgcc_tm.h
 580 tm_file_=
 581 for f in ${tm_file}
 582 do
 583         tm_file_="${tm_file_} \$(srcdir)/config/$f"
 584 done
 585 tm_file="${tm_file_}"
 586 AC_SUBST(tm_file)
 587 AC_SUBST(tm_defines)
 588
 589 # Map from thread model to thread header.
 590 GCC_AC_THREAD_HEADER([$target_thread_file])
 591
 592 # Determine what GCC version number to use in filesystem paths.
 593 GCC_BASE_VER
 594
 595 # Substitute configuration variables
 596 AC_SUBST(cpu_type)
 597 AC_SUBST(extra_parts)
 598 AC_SUBST(asm_hidden_op)
 599 AC_SUBST(enable_execute_stack)
 600 AC_SUBST(unwind_header)
 601 AC_SUBST(md_unwind_header)
 602 AC_SUBST(sfp_machine_header)
 603 AC_SUBST(thread_header)
 604
 605 # We need multilib support.
 606 AC_CONFIG_FILES([Makefile])
 607 AC_CONFIG_COMMANDS([default],
 608   [[test -z "$CONFIG_HEADERS" || echo timestamp > stamp-h
 609 if test -n "$CONFIG_FILES"; then
 610   # FIXME: We shouldn't need to set ac_file
 611   ac_file=Makefile
 612   . ${libgcc_topdir}/config-ml.in
 613 fi]],
 614 [[srcdir=${srcdir}
 615 host=${host}
 616 with_target_subdir=${with_target_subdir}
 617 with_multisubdir=${with_multisubdir}
 618 ac_configure_args="--enable-multilib ${ac_configure_args}"
 619 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 620 libgcc_topdir=${libgcc_topdir}
 621 CC="${CC}"
 622 ]])
 623 AC_OUTPUT