libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_PREREQ(2.64)
  10 AC_INIT(package-unused, version-unused,, libgo)
  11 AC_CONFIG_SRCDIR(Makefile.am)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 libtool_VERSION=3:1:0
  15 AC_SUBST(libtool_VERSION)
  16
  17 AM_ENABLE_MULTILIB(, ..)
  18
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$host_alias}
  21
  22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dist -Wall -Wno-portability])
  23 AH_TEMPLATE(PACKAGE, [Name of package])
  24 AH_TEMPLATE(VERSION, [Version number of package])
  25
  26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  28 AC_PROG_CC
  29 AC_PROG_GO
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 AM_MAINTAINER_MODE
  35
  36 AC_PROG_LD
  37 AC_PROG_RANLIB
  38 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  39
  40 AC_LIBTOOL_DLOPEN
  41 AM_PROG_LIBTOOL
  42 AC_SUBST(enable_shared)
  43 AC_SUBST(enable_static)
  44
  45 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  46 AC_SUBST(CC_FOR_BUILD)
  47
  48 AC_PROG_AWK
  49
  50 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  51 AC_SUBST(WARN_FLAGS)
  52
  53 AC_ARG_ENABLE(werror, [AS_HELP_STRING([--enable-werror],
  54                                       [turns on -Werror @<:@default=yes@:>@])])
  55 if test "x$enable_werror" != "xno"; then
  56   WERROR="-Werror"
  57 fi
  58 AC_SUBST(WERROR)
  59
  60 glibgo_toolexecdir=no
  61 glibgo_toolexeclibdir=no
  62
  63 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  64 AC_ARG_ENABLE([version-specific-runtime-libs],
  65   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  66                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  67   [case "$enableval" in
  68     yes) version_specific_libs=yes ;;
  69     no)  version_specific_libs=no ;;
  70     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  71    esac],
  72   [version_specific_libs=no])
  73 AC_MSG_RESULT($version_specific_libs)
  74
  75 # Version-specific runtime libs processing.
  76 if test $version_specific_libs = yes; then
  77   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  78   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  79 fi
  80
  81 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  82 # Install a library built with a cross compiler in tooldir, not libdir.
  83 if test -n "$with_cross_host" &&
  84    test x"$with_cross_host" != x"no"; then
  85   nover_glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  86   nover_glibgo_toolexeclibdir='${toolexecdir}/lib'
  87 else
  88   nover_glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  89   nover_glibgo_toolexeclibdir='${libdir}'
  90 fi
  91 multi_os_directory=`$CC -print-multi-os-directory`
  92 case $multi_os_directory in
  93   .) ;; # Avoid trailing /.
  94   *) nover_glibgo_toolexeclibdir=${nover_glibgo_toolexeclibdir}/${multi_os_directory} ;;
  95 esac
  96
  97 if test x"$glibgo_toolexecdir" = x"no"; then
  98   glibgo_toolexecdir="${nover_glibgo_toolexecdir}"
  99   glibgo_toolexeclibdir="${nover_glibgo_toolexeclibdir}"
 100 fi
 101
 102 AC_SUBST(glibgo_toolexecdir)
 103 AC_SUBST(glibgo_toolexeclibdir)
 104 AC_SUBST(nover_glibgo_toolexeclibdir)
 105
 106 # See if the user wants to configure without libffi.  Some
 107 # architectures don't support it.  FIXME: We should set a default
 108 # based on the host.
 109 AC_ARG_WITH(libffi,
 110   AS_HELP_STRING([--without-libffi],
 111                  [don't use libffi]),
 112   [:],
 113   [with_libffi=${with_libffi_default-yes}])
 114
 115 LIBFFI=
 116 LIBFFIINCS=
 117 if test "$with_libffi" != no; then
 118    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 119    LIBFFI=../libffi/libffi_convenience.la
 120    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 121 fi
 122 AC_SUBST(LIBFFI)
 123 AC_SUBST(LIBFFIINCS)
 124
 125 # Used to tell GNU make to include a file without telling automake to
 126 # include it.
 127 go_include="-include"
 128 AC_SUBST(go_include)
 129
 130 is_darwin=no
 131 is_freebsd=no
 132 is_irix=no
 133 is_linux=no
 134 is_netbsd=no
 135 is_openbsd=no
 136 is_rtems=no
 137 is_solaris=no
 138 GOOS=unknown
 139 case ${host} in
 140   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 141   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 142   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 143   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 144   *-*-netbsd*)   is_netbsd=yes;  GOOS=netbsd ;;
 145   *-*-openbsd*)  is_openbsd=yes; GOOS=openbsd ;;
 146   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 147   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 148 esac
 149 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 150 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 151 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 152 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 153 AM_CONDITIONAL(LIBGO_IS_NETBSD, test $is_netbsd = yes)
 154 AM_CONDITIONAL(LIBGO_IS_OPENBSD, test $is_openbsd = yes)
 155 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 156 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 157 AC_SUBST(GOOS)
 158
 159 dnl N.B. Keep in sync with gcc/testsuite/go.test/go-test.exp (go-set-goarch).
 160 is_386=no
 161 is_alpha=no
 162 is_arm=no
 163 is_m68k=no
 164 mips_abi=unknown
 165 is_ppc=no
 166 is_ppc64=no
 167 is_sparc=no
 168 is_sparc64=no
 169 is_x86_64=no
 170 GOARCH=unknown
 171 case ${host} in
 172   alpha*-*-*)
 173     is_alpha=yes
 174     GOARCH=alpha
 175     ;;
 176   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 177     is_arm=yes
 178     GOARCH=arm
 179     ;;
 180 changequote(,)dnl
 181   i[34567]86-*-* | x86_64-*-*)
 182 changequote([,])dnl
 183     AC_COMPILE_IFELSE([
 184 #ifdef __x86_64__
 185 #error 64-bit
 186 #endif],
 187 [is_386=yes], [is_x86_64=yes])
 188     if test "$is_386" = "yes"; then
 189       GOARCH=386
 190     else
 191       GOARCH=amd64
 192     fi
 193     ;;
 194   m68k*-*-*)
 195     is_m68k=yes
 196     GOARCH=m68k
 197     ;;
 198   mips*-*-*)
 199     AC_COMPILE_IFELSE([
 200 #if _MIPS_SIM != _ABIO32
 201 #error not o32
 202 #endif],
 203 [mips_abi="o32"],
 204         [AC_COMPILE_IFELSE([
 205 #if _MIPS_SIM != _ABIN32
 206 #error not n32
 207 #endif],
 208 [mips_abi="n32"],
 209         [AC_COMPILE_IFELSE([
 210 #if _MIPS_SIM != _ABI64
 211 #error not n64
 212 #endif],
 213 [mips_abi="n64"],
 214         [AC_COMPILE_IFELSE([
 215 #if _MIPS_SIM != _ABIO64
 216 #error not o64
 217 #endif],
 218 [mips_abi="o64"],
 219         [AC_MSG_ERROR([unknown MIPS ABI])
 220 [mips_abi="n32"]])])])])
 221     case "$mips_abi" in
 222     "o32") GOARCH=mipso32 ;;
 223     "n32") GOARCH=mipsn32 ;;
 224     "n64") GOARCH=mipsn64 ;;
 225     "o64") GOARCH=mipso64 ;;
 226     esac
 227     ;;
 228   rs6000*-*-* | powerpc*-*-*)
 229     AC_COMPILE_IFELSE([
 230 #ifdef _ARCH_PPC64
 231 #error 64-bit
 232 #endif],
 233 [is_ppc=yes], [is_ppc64=yes])
 234     if test "$is_ppc" = "yes"; then
 235       GOARCH=ppc
 236     else
 237       GOARCH=ppc64
 238     fi
 239     ;;
 240   sparc*-*-*)
 241     AC_COMPILE_IFELSE([
 242 #if defined(__sparcv9) || defined(__arch64__)
 243 #error 64-bit
 244 #endif],
 245 [is_sparc=yes], [is_sparc64=yes])
 246     if test "$is_sparc" = "yes"; then
 247       GOARCH=sparc
 248     else
 249       GOARCH=sparc64
 250     fi
 251     ;;
 252 esac
 253 AM_CONDITIONAL(LIBGO_IS_386, test $is_386 = yes)
 254 AM_CONDITIONAL(LIBGO_IS_ALPHA, test $is_alpha = yes)
 255 AM_CONDITIONAL(LIBGO_IS_ARM, test $is_arm = yes)
 256 AM_CONDITIONAL(LIBGO_IS_M68K, test $is_m68k = yes)
 257 AM_CONDITIONAL(LIBGO_IS_MIPS, test $mips_abi != unknown)
 258 AM_CONDITIONAL(LIBGO_IS_MIPSO32, test $mips_abi = o32)
 259 AM_CONDITIONAL(LIBGO_IS_MIPSN32, test $mips_abi = n32)
 260 AM_CONDITIONAL(LIBGO_IS_MIPSN64, test $mips_abi = n64)
 261 AM_CONDITIONAL(LIBGO_IS_MIPSO64, test $mips_abi = o64)
 262 AM_CONDITIONAL(LIBGO_IS_PPC, test $is_ppc = yes)
 263 AM_CONDITIONAL(LIBGO_IS_PPC64, test $is_ppc64 = yes)
 264 AM_CONDITIONAL(LIBGO_IS_SPARC, test $is_sparc = yes)
 265 AM_CONDITIONAL(LIBGO_IS_SPARC64, test $is_sparc64 = yes)
 266 AM_CONDITIONAL(LIBGO_IS_X86_64, test $is_x86_64 = yes)
 267 AC_SUBST(GOARCH)
 268
 269 dnl Some files are only present when needed for specific architectures.
 270 GO_LIBCALL_OS_FILE=
 271 GO_LIBCALL_OS_ARCH_FILE=
 272 GO_SYSCALL_OS_FILE=
 273 GO_SYSCALL_OS_ARCH_FILE=
 274 if test -f ${srcdir}/go/syscall/libcall_${GOOS}.go; then
 275   GO_LIBCALL_OS_FILE=go/syscall/libcall_${GOOS}.go
 276 fi
 277 if test -f ${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go; then
 278   GO_LIBCALL_OS_ARCH_FILE=go/syscall/libcall_${GOOS}_${GOARCH}.go
 279 fi
 280 if test -f ${srcdir}/go/syscall/syscall_${GOOS}.go; then
 281   GO_SYSCALL_OS_FILE=go/syscall/syscall_${GOOS}.go
 282 fi
 283 if test -f ${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go; then
 284   GO_SYSCALL_OS_ARCH_FILE=go/syscall/syscall_${GOOS}_${GOARCH}.go
 285 fi
 286 AC_SUBST(GO_LIBCALL_OS_FILE)
 287 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 288 AC_SUBST(GO_SYSCALL_OS_FILE)
 289 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 290
 291 dnl Special flags used to generate sysinfo.go.
 292 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 293 case "$target" in
 294     mips-sgi-irix6.5*)
 295         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 296         # msghdr in <sys/socket.h>.
 297         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 298         ;;
 299     *-*-solaris2.[[89]])
 300         # Solaris 8/9 need this so struct msghdr gets the msg_control
 301         # etc. fields in <sys/socket.h> (_XPG4_2).
 302         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500 -D_XOPEN_SOURCE_EXTENDED -D__EXTENSIONS__"
 303         ;;
 304     *-*-solaris2.1[[01]])
 305         # Solaris 10+ needs this so struct msghdr gets the msg_control
 306         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 307         # above doesn't work with C99.
 308         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 309         ;;
 310 esac
 311 AC_SUBST(OSCFLAGS)
 312
 313 dnl Use -fsplit-stack when compiling C code if available.
 314 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 315 [libgo_cv_c_split_stack_supported],
 316 [CFLAGS_hold=$CFLAGS
 317 CFLAGS="$CFLAGS -fsplit-stack"
 318 AC_COMPILE_IFELSE([[int i;]],
 319 [libgo_cv_c_split_stack_supported=yes],
 320 [libgo_cv_c_split_stack_supported=no])
 321 CFLAGS=$CFLAGS_hold])
 322 if test "$libgo_cv_c_split_stack_supported" = yes; then
 323   SPLIT_STACK=-fsplit-stack
 324   AC_DEFINE(USING_SPLIT_STACK, 1,
 325                 [Define if the compiler supports -fsplit-stack])
 326 else
 327   SPLIT_STACK=
 328 fi
 329 AC_SUBST(SPLIT_STACK)
 330 AM_CONDITIONAL(USING_SPLIT_STACK,
 331         test "$libgo_cv_c_split_stack_supported" = yes)
 332
 333 dnl Check whether the linker does stack munging when calling from
 334 dnl split-stack into non-split-stack code.  We check this by looking
 335 dnl at the --help output.  FIXME: This is only half right: it's
 336 dnl possible for the linker to support this for some targets but not
 337 dnl others.
 338 AC_CACHE_CHECK([whether linker supports split stack],
 339 [libgo_cv_c_linker_supports_split_stack],
 340 libgo_cv_c_linker_supports_split_stack=no
 341 if $LD --help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 342   libgo_cv_c_linker_supports_split_stack=yes
 343 fi)
 344 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 345   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 346             [Define if the linker support split stack adjustments])
 347 fi
 348
 349 dnl Test for the -lm library.
 350 MATH_LIBS=
 351 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 352 AC_SUBST(MATH_LIBS)
 353
 354 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 355 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 356   [libgo_cv_lib_sockets=
 357    libgo_check_both=no
 358    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 359    if test "$libgo_check_socket" = "yes"; then
 360      unset ac_cv_func_connect
 361      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 362                   libgo_check_both=yes)
 363    fi
 364    if test "$libgo_check_both" = "yes"; then
 365      libgo_old_libs=$LIBS
 366      LIBS="$LIBS -lsocket -lnsl"
 367      unset ac_cv_func_accept
 368      AC_CHECK_FUNC(accept,
 369                    [libgo_check_nsl=no
 370                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 371      unset ac_cv_func_accept
 372      LIBS=$libgo_old_libs
 373    fi
 374    unset ac_cv_func_gethostbyname
 375    libgo_old_libs="$LIBS"
 376    AC_CHECK_FUNC(gethostbyname, ,
 377                  [AC_CHECK_LIB(nsl, main,
 378                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 379    unset ac_cv_func_gethostbyname
 380    LIBS=$libgo_old_libs
 381 ])
 382 NET_LIBS="$libgo_cv_lib_sockets"
 383 AC_SUBST(NET_LIBS)
 384
 385 dnl Test whether the compiler supports the -pthread option.
 386 AC_CACHE_CHECK([whether -pthread is supported],
 387 [libgo_cv_lib_pthread],
 388 [CFLAGS_hold=$CFLAGS
 389 CFLAGS="$CFLAGS -pthread"
 390 AC_COMPILE_IFELSE([[int i;]],
 391 [libgo_cv_lib_pthread=yes],
 392 [libgo_cv_lib_pthread=no])
 393 CFLAGS=$CFLAGS_hold])
 394 PTHREAD_CFLAGS=
 395 if test "$libgo_cv_lib_pthread" = yes; then
 396   PTHREAD_CFLAGS=-pthread
 397 fi
 398 AC_SUBST(PTHREAD_CFLAGS)
 399
 400 dnl Test for the -lpthread library.
 401 PTHREAD_LIBS=
 402 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 403 AC_SUBST(PTHREAD_LIBS)
 404
 405 dnl Test if -lrt is required for sched_yield.
 406 AC_SEARCH_LIBS([sched_yield], [rt])
 407
 408 AC_C_BIGENDIAN
 409
 410 GCC_CHECK_UNWIND_GETIPINFO
 411
 412 AC_ARG_ENABLE(sjlj-exceptions,
 413   AC_HELP_STRING([--enable-sjlj-exceptions],
 414                  [force use of builtin_setjmp for exceptions]),
 415   [case "$enableval" in
 416    yes|no|auto) ;;
 417    *) AC_MSG_ERROR([unknown argument to --enable-sjlj-exceptions]) ;;
 418    esac],
 419   [enable_sjlj_exceptions=auto])
 420
 421 AC_CACHE_CHECK([whether to use setjmp/longjmp exceptions],
 422 [libgo_cv_lib_sjlj_exceptions],
 423 [AC_LANG_CONFTEST(
 424   [AC_LANG_SOURCE([
 425 void bar ();
 426 void clean (int *);
 427 void foo ()
 428 {
 429   int i __attribute__ ((cleanup (clean)));
 430   bar();
 431 }
 432 ])])
 433 CFLAGS_hold=$CFLAGS
 434 CFLAGS="--save-temps -fexceptions"
 435 libgo_cv_lib_sjlj_exceptions=unknown
 436 AS_IF([ac_fn_c_try_compile],
 437   [if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1; then
 438     libgo_cv_lib_sjlj_exceptions=yes
 439   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1; then
 440     libgo_cv_lib_sjlj_exceptions=no
 441   fi])
 442 CFLAGS=$CFLAGS_hold
 443 rm -f conftest*
 444 ])
 445
 446 if test "$enable_sjlj_exceptions" = "auto"; then
 447   enable_sjlj_exceptions=$libgo_cv_lib_sjlj_exceptions
 448 fi
 449
 450 case $enable_sjlj_exceptions in
 451 yes)
 452   AC_DEFINE(LIBGO_SJLJ_EXCEPTIONS, 1,
 453         [Define if the C++ compiler is configured for setjmp/longjmp exceptions.])
 454   ;;
 455 no)
 456   ;;
 457 *)
 458   AC_MSG_ERROR([unable to detect exception model])
 459   ;;
 460 esac
 461
 462 AC_CHECK_HEADERS(sys/file.h sys/mman.h syscall.h sys/epoll.h sys/inotify.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h net/if_arp.h net/route.h netpacket/packet.h sys/prctl.h sys/mount.h sys/vfs.h sys/statfs.h sys/timex.h sys/sysinfo.h utime.h linux/ether.h linux/fs.h linux/reboot.h netinet/in_syst.h netinet/ip.h netinet/ip_mroute.h netinet/if_ether.h)
 463
 464 AC_CHECK_HEADERS([linux/filter.h linux/if_addr.h linux/if_ether.h linux/if_tun.h linux/netlink.h linux/rtnetlink.h], [], [],
 465 [#ifdef HAVE_SYS_SOCKET_H
 466 #include <sys/socket.h>
 467 #endif
 468 ])
 469
 470 AC_CACHE_CHECK([whether <ustat.h> can be used],
 471 [libgo_cv_c_ustat_h],
 472 [CFLAGS_hold=$CFLAGS
 473 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE $OSCFLAGS"
 474 AC_COMPILE_IFELSE(
 475 [AC_LANG_SOURCE([
 476 #include <sys/types.h>
 477 #ifdef HAVE_LINUX_FILTER_H
 478 #include <linux/filter.h>
 479 #endif
 480 #include <ustat.h>
 481 ])], [libgo_cv_c_ustat_h=yes], [libgo_cv_c_ustat_h=no])
 482 CFLAGS=$CFLAGS_hold])
 483 if test $libgo_cv_c_ustat_h = yes; then
 484   AC_DEFINE(HAVE_USTAT_H, 1,
 485     [Define to 1 if you have the <ustat.h> header file and it works.])
 486 fi
 487
 488 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 489
 490 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv dl_iterate_phdr)
 491 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 492 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 493
 494 AC_CHECK_FUNCS(epoll_create1 faccessat fallocate fchmodat fchownat futimesat inotify_add_watch inotify_init inotify_init1 inotify_rm_watch mkdirat mknodat openat renameat sync_file_range splice tee unlinkat unshare)
 495 AC_TYPE_OFF_T
 496 AC_CHECK_TYPES([loff_t])
 497
 498 LIBS_hold="$LIBS"
 499 LIBS="$LIBS -lm"
 500 AC_CHECK_FUNCS(cosl expl logl sinl tanl acosl asinl atanl atan2l expm1l ldexpl log10l log1pl)
 501 LIBS="$LIBS_hold"
 502
 503 CFLAGS_hold="$CFLAGS"
 504 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 505 LIBS_hold="$LIBS"
 506 LIBS="$LIBS $PTHREAD_LIBS"
 507 AC_CHECK_FUNCS(sem_timedwait)
 508 CFLAGS="$CFLAGS_hold"
 509 LIBS="$LIBS_hold"
 510
 511 LIBS_hold="$LIBS"
 512 LIBS="$LIBS $MATH_LIBS"
 513 AC_CHECK_FUNCS(matherr)
 514 LIBS="$LIBS_hold"
 515
 516 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_4],
 517 [libgo_cv_func___sync_bool_compare_and_swap_4],
 518 [AC_LINK_IFELSE([
 519 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 520 uint32 i;
 521 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 522 ],
 523 [libgo_cv_func___sync_bool_compare_and_swap_4=yes],
 524 [libgo_cv_func___sync_bool_compare_and_swap_4=no])])
 525 if test "$libgo_cv_func___sync_bool_compare_and_swap_4" = "yes"; then
 526   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_4, 1,
 527     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint32])
 528 fi
 529
 530 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_8],
 531 [libgo_cv_func___sync_bool_compare_and_swap_8],
 532 [AC_LINK_IFELSE([
 533 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 534 uint64 i;
 535 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 536 ],
 537 [libgo_cv_func___sync_bool_compare_and_swap_8=yes],
 538 [libgo_cv_func___sync_bool_compare_and_swap_8=no])])
 539 if test "$libgo_cv_func___sync_bool_compare_and_swap_8" = "yes"; then
 540   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_8, 1,
 541     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint64])
 542 fi
 543
 544 AC_CACHE_CHECK([for __sync_fetch_and_add_4],
 545 [libgo_cv_func___sync_fetch_and_add_4],
 546 [AC_LINK_IFELSE([
 547 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 548 uint32 i;
 549 int main() { return __sync_fetch_and_add (&i, 1); }
 550 ],
 551 [libgo_cv_func___sync_fetch_and_add_4=yes],
 552 [libgo_cv_func___sync_fetch_and_add_4=no])])
 553 if test "$libgo_cv_func___sync_fetch_and_add_4" = "yes"; then
 554   AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD_4, 1,
 555     [Define to 1 if the compiler provides the __sync_fetch_and_add function for uint32])
 556 fi
 557
 558 AC_CACHE_CHECK([for __sync_add_and_fetch_8],
 559 [libgo_cv_func___sync_add_and_fetch_8],
 560 [AC_LINK_IFELSE([
 561 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 562 uint64 i;
 563 int main() { return __sync_add_and_fetch (&i, 1); }
 564 ],
 565 [libgo_cv_func___sync_add_and_fetch_8=yes],
 566 [libgo_cv_func___sync_add_and_fetch_8=no])])
 567 if test "$libgo_cv_func___sync_add_and_fetch_8" = "yes"; then
 568   AC_DEFINE(HAVE_SYNC_ADD_AND_FETCH_8, 1,
 569     [Define to 1 if the compiler provides the __sync_add_and_fetch function for uint64])
 570 fi
 571
 572 dnl For x86 we want to use the -minline-all-stringops option to avoid
 573 dnl forcing a stack split when calling memcpy and friends.
 574 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 575 [libgo_cv_c_stringops],
 576 [CFLAGS_hold=$CFLAGS
 577 CFLAGS="$CFLAGS -minline-all-stringops"
 578 AC_COMPILE_IFELSE([int i;],
 579 [libgo_cv_c_stringops=yes],
 580 [libgo_cv_c_stringops=no])
 581 CFLAGS=$CFLAGS_hold])
 582 STRINGOPS_FLAG=
 583 if test "$libgo_cv_c_stringops" = yes; then
 584   STRINGOPS_FLAG=-minline-all-stringops
 585 fi
 586 AC_SUBST(STRINGOPS_FLAG)
 587
 588 dnl For x86 we want to compile the math library with -mfancy-math-387
 589 dnl -funsafe-math-optimizations so that we can use the builtin
 590 dnl instructions directly.
 591 AC_CACHE_CHECK([whether compiler supports -mfancy-math-387],
 592 [libgo_cv_c_fancymath],
 593 [CFLAGS_hold=$CFLAGS
 594 CFLAGS="$CFLAGS -mfancy-math-387"
 595 AC_COMPILE_IFELSE([int i;],
 596 [libgo_cv_c_fancymath=yes],
 597 [libgo_cv_c_fancymath=no])
 598 CFLAGS=$CFLAGS_hold])
 599 MATH_FLAG=
 600 if test "$libgo_cv_c_fancymath" = yes; then
 601   MATH_FLAG="-mfancy-math-387 -funsafe-math-optimizations"
 602 fi
 603 AC_SUBST(MATH_FLAG)
 604
 605 CFLAGS_hold=$CFLAGS
 606 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 607 AC_CHECK_TYPES([off64_t])
 608 CFLAGS=$CFLAGS_hold
 609
 610 dnl Work out the size of the epoll_events struct on GNU/Linux.
 611 AC_CACHE_CHECK([epoll_event size],
 612 [libgo_cv_c_epoll_event_size],
 613 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 614 [sizeof (struct epoll_event)],
 615 [#include <sys/epoll.h>],
 616 [libgo_cv_c_epoll_event_size=0])])
 617 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 618 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 619
 620 dnl Work out the offset of the fd field in the epoll_events struct on
 621 dnl GNU/Linux.
 622 AC_CACHE_CHECK([epoll_event data.fd offset],
 623 [libgo_cv_c_epoll_event_fd_offset],
 624 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 625 [offsetof (struct epoll_event, data.fd)],
 626 [#include <stddef.h>
 627 #include <sys/epoll.h>],
 628 [libgo_cv_c_epoll_event_fd_offset=0])])
 629 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 630 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 631
 632 dnl See if struct exception is defined in <math.h>.
 633 AC_CHECK_TYPE([struct exception],
 634 [libgo_has_struct_exception=yes],
 635 [libgo_has_struct_exception=no],
 636 [#include <math.h>])
 637 if test "$libgo_has_struct_exception" = "yes"; then
 638   AC_DEFINE(HAVE_STRUCT_EXCEPTION, 1,
 639             [Define to 1 if <math.h> defines struct exception])
 640 fi
 641
 642 dnl Check if makecontext expects the uc_stack member of ucontext to point
 643 dnl to the top of the stack.
 644 case "$target" in
 645   sparc*-*-solaris2.[[89]]*)
 646     libgo_cv_lib_makecontext_stack_top=yes
 647     ;;
 648   *)
 649     libgo_cv_lib_makecontext_stack_top=no
 650     ;;
 651 esac
 652 if test "$libgo_cv_lib_makecontext_stack_top" = "yes"; then
 653   AC_DEFINE(MAKECONTEXT_STACK_TOP, 1,
 654             [Define if makecontext expects top of stack in uc_stack.])
 655 fi
 656
 657 dnl See whether setcontext changes the value of TLS variables.
 658 AC_CACHE_CHECK([whether setcontext clobbers TLS variables],
 659 [libgo_cv_lib_setcontext_clobbers_tls],
 660 [CFLAGS_hold="$CFLAGS"
 661 CFLAGS="$PTHREAD_CFLAGS"
 662 LIBS_hold="$LIBS"
 663 LIBS="$LIBS $PTHREAD_LIBS"
 664 AC_CHECK_SIZEOF([void *])
 665 AS_VAR_ARITH([ptr_type_size], [$ac_cv_sizeof_void_p \* 8])
 666 AC_RUN_IFELSE(
 667   [AC_LANG_SOURCE([
 668 #include <pthread.h>
 669 #include <stdlib.h>
 670 #include <ucontext.h>
 671 #include <unistd.h>
 672
 673 __thread int tls;
 674
 675 static char stack[[10 * 1024 * 1024]];
 676 static ucontext_t c;
 677
 678 /* Called via makecontext/setcontext.  */
 679
 680 static void
 681 cfn (void)
 682 {
 683   exit (tls);
 684 }
 685
 686 /* Called via pthread_create.  */
 687
 688 static void *
 689 tfn (void *dummy)
 690 {
 691   /* The thread should still see this value after calling
 692      setcontext.  */
 693   tls = 0;
 694
 695   setcontext (&c);
 696
 697   /* The call to setcontext should not return.  */
 698   abort ();
 699 }
 700
 701 int
 702 main ()
 703 {
 704   pthread_t tid;
 705
 706   /* The thread should not see this value.  */
 707   tls = 1;
 708
 709   if (getcontext (&c) < 0)
 710     abort ();
 711
 712   c.uc_stack.ss_sp = stack;
 713 #ifdef MAKECONTEXT_STACK_TOP
 714   c.uc_stack.ss_sp += sizeof stack;
 715 #endif
 716   c.uc_stack.ss_flags = 0;
 717   c.uc_stack.ss_size = sizeof stack;
 718   c.uc_link = NULL;
 719   makecontext (&c, cfn, 0);
 720
 721   if (pthread_create (&tid, NULL, tfn, NULL) != 0)
 722     abort ();
 723
 724   if (pthread_join (tid, NULL) != 0)
 725     abort ();
 726
 727   /* The thread should have called exit.  */
 728   abort ();
 729 }
 730 ])],
 731 [libgo_cv_lib_setcontext_clobbers_tls=no],
 732 [libgo_cv_lib_setcontext_clobbers_tls=yes],
 733 [case "$target:$ptr_type_size" in
 734   i?86-*-solaris2.1[[01]]:64 | x86_64*-*-solaris2.1[[01]]:64)
 735     libgo_cv_lib_setcontext_clobbers_tls=yes ;;
 736   *)
 737     libgo_cv_lib_setcontext_clobbers_tls=no ;;
 738  esac
 739 ])
 740 CFLAGS="$CFLAGS_hold"
 741 LIBS="$LIBS_hold"
 742 ])
 743 if test "$libgo_cv_lib_setcontext_clobbers_tls" = "yes"; then
 744   AC_DEFINE(SETCONTEXT_CLOBBERS_TLS, 1,
 745             [Define if setcontext clobbers TLS variables])
 746 fi
 747
 748 AC_CACHE_SAVE
 749
 750 if test ${multilib} = yes; then
 751   multilib_arg="--enable-multilib"
 752 else
 753   multilib_arg=
 754 fi
 755
 756 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 757
 758 AC_CONFIG_COMMANDS([default],
 759 [if test -n "$CONFIG_FILES"; then
 760    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 761    # that multilib installs will end up installed in the correct place.
 762    # The testsuite needs it for multilib-aware ABI baseline files.
 763    # To work around this not being passed down from config-ml.in ->
 764    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 765    # append it here.  Only modify Makefiles that have just been created.
 766    #
 767    # Also, get rid of this simulated-VPATH thing that automake does.
 768    cat > vpsed << \_EOF
 769 s!`test -f '$<' || echo '$(srcdir)/'`!!
 770 _EOF
 771    for i in $SUBDIRS; do
 772     case $CONFIG_FILES in
 773      *${i}/Makefile*)
 774        #echo "Adding MULTISUBDIR to $i/Makefile"
 775        sed -f vpsed $i/Makefile > tmp
 776        grep '^MULTISUBDIR =' Makefile >> tmp
 777        mv tmp $i/Makefile
 778        ;;
 779     esac
 780    done
 781    rm vpsed
 782  fi
 783 ],
 784 [
 785 # Variables needed in config.status (file generation) which aren't already
 786 # passed by autoconf.
 787 SUBDIRS="$SUBDIRS"
 788 ])
 789
 790 AC_OUTPUT