gcc/ada/a-cfhase.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --    A D A . C O N T A I N E R S . F O R M A L _ H A S H E D _ S E T S     --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2004-2014, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  21 --                                                                          --
  22 -- As a special exception under Section 7 of GPL version 3, you are granted --
  23 -- additional permissions described in the GCC Runtime Library Exception,   --
  24 -- version 3.1, as published by the Free Software Foundation.               --
  25 --                                                                          --
  26 -- You should have received a copy of the GNU General Public License and    --
  27 -- a copy of the GCC Runtime Library Exception along with this program;     --
  28 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  29 -- <http://www.gnu.org/licenses/>.                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  This spec is derived from package Ada.Containers.Bounded_Hashed_Sets in the
  33 --  Ada 2012 RM. The modifications are meant to facilitate formal proofs by
  34 --  making it easier to express properties, and by making the specification of
  35 --  this unit compatible with SPARK 2014. Note that the API of this unit may be
  36 --  subject to incompatible changes as SPARK 2014 evolves.
  37
  38 --  The modifications are:
  39
  40 --    A parameter for the container is added to every function reading the
  41 --    content of a container: Element, Next, Query_Element, Has_Element, Key,
  42 --    Iterate, Equivalent_Elements. This change is motivated by the need to
  43 --    have cursors which are valid on different containers (typically a
  44 --    container C and its previous version C'Old) for expressing properties,
  45 --    which is not possible if cursors encapsulate an access to the underlying
  46 --    container.
  47
  48 --    There are three new functions:
  49
  50 --      function Strict_Equal (Left, Right : Set) return Boolean;
  51 --      function First_To_Previous  (Container : Set; Current : Cursor)
  52 --         return Set;
  53 --      function Current_To_Last (Container : Set; Current : Cursor)
  54 --         return Set;
  55
  56 --    See detailed specifications for these subprograms
  57
  58 private with Ada.Containers.Hash_Tables;
  59
  60 generic
  61    type Element_Type is private;
  62
  63    with function Hash (Element : Element_Type) return Hash_Type;
  64
  65    with function Equivalent_Elements (Left, Right : Element_Type)
  66                                       return Boolean;
  67
  68    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  69
  70 package Ada.Containers.Formal_Hashed_Sets is
  71    pragma Annotate (GNATprove, External_Axiomatization);
  72    pragma Pure;
  73    pragma SPARK_Mode (On);
  74
  75    type Set (Capacity : Count_Type; Modulus : Hash_Type) is private with
  76      Iterable => (First       => First,
  77                   Next        => Next,
  78                   Has_Element => Has_Element,
  79                   Element     => Element),
  80      Default_Initial_Condition;
  81    pragma Preelaborable_Initialization (Set);
  82
  83    type Cursor is private;
  84    pragma Preelaborable_Initialization (Cursor);
  85
  86    Empty_Set : constant Set;
  87
  88    No_Element : constant Cursor;
  89
  90    function "=" (Left, Right : Set) return Boolean with
  91      Global => null;
  92
  93    function Equivalent_Sets (Left, Right : Set) return Boolean with
  94      Global => null;
  95
  96    function To_Set (New_Item : Element_Type) return Set with
  97      Global => null;
  98
  99    function Capacity (Container : Set) return Count_Type with
 100      Global => null;
 101
 102    procedure Reserve_Capacity
 103      (Container : in out Set;
 104       Capacity  : Count_Type)
 105    with
 106      Global => null,
 107      Pre    => Capacity <= Container.Capacity;
 108
 109    function Length (Container : Set) return Count_Type with
 110      Global => null;
 111
 112    function Is_Empty (Container : Set) return Boolean with
 113      Global => null;
 114
 115    procedure Clear (Container : in out Set) with
 116      Global => null;
 117
 118    procedure Assign (Target : in out Set; Source : Set) with
 119      Global => null,
 120      Pre    => Target.Capacity >= Length (Source);
 121
 122    function Copy
 123      (Source   : Set;
 124       Capacity : Count_Type := 0) return Set
 125    with
 126      Global => null,
 127      Pre    => Capacity = 0 or else Capacity >= Source.Capacity;
 128
 129    function Element
 130      (Container : Set;
 131       Position  : Cursor) return Element_Type
 132    with
 133      Global => null,
 134      Pre    => Has_Element (Container, Position);
 135
 136    procedure Replace_Element
 137      (Container : in out Set;
 138       Position  : Cursor;
 139       New_Item  : Element_Type)
 140    with
 141      Global => null,
 142      Pre    => Has_Element (Container, Position);
 143
 144    procedure Move (Target : in out Set; Source : in out Set) with
 145      Global => null,
 146      Pre    => Target.Capacity >= Length (Source);
 147
 148    procedure Insert
 149      (Container : in out Set;
 150       New_Item  : Element_Type;
 151       Position  : out Cursor;
 152       Inserted  : out Boolean)
 153    with
 154      Global => null,
 155      Pre    => Length (Container) < Container.Capacity;
 156
 157    procedure Insert  (Container : in out Set; New_Item : Element_Type) with
 158      Global => null,
 159      Pre    => Length (Container) < Container.Capacity
 160                  and then (not Contains (Container, New_Item));
 161
 162    procedure Include (Container : in out Set; New_Item : Element_Type) with
 163      Global => null,
 164      Pre    => Length (Container) < Container.Capacity;
 165
 166    procedure Replace (Container : in out Set; New_Item : Element_Type) with
 167      Global => null,
 168      Pre    => Contains (Container, New_Item);
 169
 170    procedure Exclude (Container : in out Set; Item     : Element_Type) with
 171      Global => null;
 172
 173    procedure Delete  (Container : in out Set; Item     : Element_Type) with
 174      Global => null,
 175      Pre    => Contains (Container, Item);
 176
 177    procedure Delete (Container : in out Set; Position  : in out Cursor) with
 178      Global => null,
 179      Pre    => Has_Element (Container, Position);
 180
 181    procedure Union (Target : in out Set; Source : Set) with
 182      Global => null,
 183      Pre    => Length (Target) + Length (Source) -
 184                  Length (Intersection (Target, Source)) <= Target.Capacity;
 185
 186    function Union (Left, Right : Set) return Set with
 187      Global => null,
 188      Pre    => Length (Left) + Length (Right) -
 189                  Length (Intersection (Left, Right)) <= Count_Type'Last;
 190
 191    function "or" (Left, Right : Set) return Set renames Union;
 192
 193    procedure Intersection (Target : in out Set; Source : Set) with
 194      Global => null;
 195
 196    function Intersection (Left, Right : Set) return Set with
 197      Global => null;
 198
 199    function "and" (Left, Right : Set) return Set renames Intersection;
 200
 201    procedure Difference (Target : in out Set; Source : Set) with
 202      Global => null;
 203
 204    function Difference (Left, Right : Set) return Set with
 205      Global => null;
 206
 207    function "-" (Left, Right : Set) return Set renames Difference;
 208
 209    procedure Symmetric_Difference (Target : in out Set; Source : Set) with
 210      Global => null,
 211      Pre    => Length (Target) + Length (Source) -
 212                  2 * Length (Intersection (Target, Source)) <= Target.Capacity;
 213
 214    function Symmetric_Difference (Left, Right : Set) return Set with
 215      Global => null,
 216      Pre    => Length (Left) + Length (Right) -
 217                  2 * Length (Intersection (Left, Right)) <= Count_Type'Last;
 218
 219    function "xor" (Left, Right : Set) return Set
 220      renames Symmetric_Difference;
 221
 222    function Overlap (Left, Right : Set) return Boolean with
 223      Global => null;
 224
 225    function Is_Subset (Subset : Set; Of_Set : Set) return Boolean with
 226      Global => null;
 227
 228    function First (Container : Set) return Cursor with
 229      Global => null;
 230
 231    function Next (Container : Set; Position : Cursor) return Cursor with
 232      Global => null,
 233      Pre    => Has_Element (Container, Position) or else Position = No_Element;
 234
 235    procedure Next (Container : Set; Position : in out Cursor) with
 236      Global => null,
 237      Pre    => Has_Element (Container, Position) or else Position = No_Element;
 238
 239    function Find
 240      (Container : Set;
 241       Item      : Element_Type) return Cursor
 242    with
 243      Global => null;
 244
 245    function Contains (Container : Set; Item : Element_Type) return Boolean with
 246      Global => null;
 247
 248    function Has_Element (Container : Set; Position : Cursor) return Boolean
 249    with
 250      Global => null;
 251
 252    function Equivalent_Elements (Left  : Set; CLeft : Cursor;
 253                                  Right : Set; CRight : Cursor) return Boolean
 254    with
 255      Global => null;
 256
 257    function Equivalent_Elements
 258      (Left  : Set; CLeft : Cursor;
 259       Right : Element_Type) return Boolean
 260    with
 261      Global => null;
 262
 263    function Equivalent_Elements
 264      (Left  : Element_Type;
 265       Right : Set; CRight : Cursor) return Boolean
 266    with
 267      Global => null;
 268
 269    function Default_Modulus (Capacity : Count_Type) return Hash_Type with
 270      Global => null;
 271
 272    generic
 273       type Key_Type (<>) is private;
 274
 275       with function Key (Element : Element_Type) return Key_Type;
 276
 277       with function Hash (Key : Key_Type) return Hash_Type;
 278
 279       with function Equivalent_Keys (Left, Right : Key_Type) return Boolean;
 280
 281    package Generic_Keys is
 282
 283       function Key (Container : Set; Position : Cursor) return Key_Type with
 284         Global => null;
 285
 286       function Element (Container : Set; Key : Key_Type) return Element_Type
 287       with
 288           Global => null;
 289
 290       procedure Replace
 291         (Container : in out Set;
 292          Key       : Key_Type;
 293          New_Item  : Element_Type)
 294       with
 295           Global => null;
 296
 297       procedure Exclude (Container : in out Set; Key : Key_Type) with
 298         Global => null;
 299
 300       procedure Delete (Container : in out Set; Key : Key_Type) with
 301         Global => null;
 302
 303       function Find (Container : Set; Key : Key_Type) return Cursor with
 304         Global => null;
 305
 306       function Contains (Container : Set; Key : Key_Type) return Boolean with
 307         Global => null;
 308
 309    end Generic_Keys;
 310
 311    function Strict_Equal (Left, Right : Set) return Boolean with
 312      Ghost,
 313      Global => null;
 314    --  Strict_Equal returns True if the containers are physically equal, i.e.
 315    --  they are structurally equal (function "=" returns True) and that they
 316    --  have the same set of cursors.
 317
 318    function First_To_Previous  (Container : Set; Current : Cursor) return Set
 319    with
 320      Ghost,
 321      Global => null,
 322      Pre    => Has_Element (Container, Current) or else Current = No_Element;
 323
 324    function Current_To_Last (Container : Set; Current : Cursor) return Set
 325    with
 326      Ghost,
 327      Global => null,
 328      Pre    => Has_Element (Container, Current) or else Current = No_Element;
 329    --  First_To_Previous returns a container containing all elements preceding
 330    --  Current (excluded) in Container. Current_To_Last returns a container
 331    --  containing all elements following Current (included) in Container.
 332    --  These two new functions can be used to express invariant properties in
 333    --  loops which iterate over containers. First_To_Previous returns the part
 334    --  of the container already scanned and Current_To_Last the part not
 335    --  scanned yet.
 336
 337 private
 338    pragma Inline (Next);
 339    pragma SPARK_Mode (Off);
 340
 341    type Node_Type is
 342       record
 343          Element     : Element_Type;
 344          Next        : Count_Type;
 345          Has_Element : Boolean := False;
 346       end record;
 347
 348    package HT_Types is new
 349      Ada.Containers.Hash_Tables.Generic_Bounded_Hash_Table_Types (Node_Type);
 350
 351    type Set (Capacity : Count_Type; Modulus : Hash_Type) is
 352      new HT_Types.Hash_Table_Type (Capacity, Modulus) with null record;
 353
 354    use HT_Types;
 355
 356    type Cursor is record
 357       Node : Count_Type;
 358    end record;
 359
 360    No_Element : constant Cursor := (Node => 0);
 361
 362    Empty_Set : constant Set := (Capacity => 0, Modulus => 0, others => <>);
 363
 364 end Ada.Containers.Formal_Hashed_Sets;