gcc/opt-functions.awk

   1 #  Copyright (C) 2003, 2004, 2007, 2008, 2009, 2010
   2 #  Free Software Foundation, Inc.
   3 #  Contributed by Kelley Cook, June 2004.
   4 #  Original code from Neil Booth, May 2003.
   5 #
   6 # This program is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by the
   8 # Free Software Foundation; either version 3, or (at your option) any
   9 # later version.
  10 #
  11 # This program is distributed in the hope that it will be useful,
  12 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with this program; see the file COPYING3.  If not see
  18 # <http://www.gnu.org/licenses/>.
  19
  20 # Some common subroutines for use by opt[ch]-gen.awk.
  21
  22 # Define some helpful character classes, for portability.
  23 BEGIN {
  24         lower = "abcdefghijklmnopqrstuvwxyz"
  25         upper = "ABCDEFGHIJKLMNOPQRSTUVWXYZ"
  26         digit = "0123456789"
  27         alnum = lower "" upper "" digit
  28 }
  29
  30 # Return nonzero if FLAGS contains a flag matching REGEX.
  31 function flag_set_p(regex, flags)
  32 {
  33         return (" " flags " ") ~ (" " regex " ")
  34 }
  35
  36 # Return STRING if FLAGS contains a flag matching regexp REGEX,
  37 # otherwise return the empty string.
  38 function test_flag(regex, flags, string)
  39 {
  40         if (flag_set_p(regex, flags))
  41                 return string
  42         return ""
  43 }
  44
  45 # If FLAGS contains a "NAME(...argument...)" flag, return the value
  46 # of the argument.  Return the empty string otherwise.
  47 function opt_args(name, flags)
  48 {
  49         flags = " " flags
  50         if (flags !~ " " name "\\(")
  51                 return ""
  52         sub(".* " name "\\(", "", flags)
  53         if (flags ~ "^{")
  54         {
  55                 sub ("^{", "", flags)
  56                 sub("}\\).*", "", flags)
  57         }
  58         else
  59                 sub("\\).*", "", flags)
  60
  61         return flags
  62 }
  63
  64 # Return the Nth comma-separated element of S.  Return the empty string
  65 # if S does not contain N elements.
  66 function nth_arg(n, s)
  67 {
  68         while (n-- > 0) {
  69                 if (s !~ ",")
  70                         return ""
  71                 sub("[^,]*, *", "", s)
  72         }
  73         sub(",.*", "", s)
  74         return s
  75 }
  76
  77 # Return a bitmask of CL_* values for option flags FLAGS.
  78 function switch_flags (flags)
  79 {
  80         result = "0"
  81         for (j = 0; j < n_langs; j++) {
  82                 regex = langs[j]
  83                 gsub ( "\\+", "\\+", regex )
  84                 result = result test_flag(regex, flags, " | " macros[j])
  85         }
  86         result = result \
  87           test_flag("Common", flags, " | CL_COMMON") \
  88           test_flag("Target", flags, " | CL_TARGET") \
  89           test_flag("Driver", flags, " | CL_DRIVER") \
  90           test_flag("RejectDriver", flags, " | CL_REJECT_DRIVER") \
  91           test_flag("NoDriverArg", flags, " | CL_NO_DRIVER_ARG") \
  92           test_flag("SeparateAlias", flags, " | CL_SEPARATE_ALIAS") \
  93           test_flag("Save", flags, " | CL_SAVE") \
  94           test_flag("Joined", flags, " | CL_JOINED") \
  95           test_flag("JoinedOrMissing", flags, " | CL_JOINED | CL_MISSING_OK") \
  96           test_flag("Separate", flags, " | CL_SEPARATE") \
  97           test_flag("RejectNegative", flags, " | CL_REJECT_NEGATIVE") \
  98           test_flag("UInteger", flags, " | CL_UINTEGER") \
  99           test_flag("Undocumented", flags,  " | CL_UNDOCUMENTED") \
 100           test_flag("Warning", flags,  " | CL_WARNING") \
 101           test_flag("Optimization", flags,  " | CL_OPTIMIZATION") \
 102           test_flag("Report", flags, " | CL_REPORT")
 103         sep_args = opt_args("Args", flags)
 104         if (sep_args != "") {
 105                 sep_args--
 106                 result = result " | (" sep_args \
 107                     " << CL_SEPARATE_NARGS_SHIFT)"
 108         }
 109         sub( "^0 \\| ", "", result )
 110         return result
 111 }
 112
 113 # If FLAGS includes a Var flag, return the name of the variable it specifies.
 114 # Return the empty string otherwise.
 115 function var_name(flags)
 116 {
 117         return nth_arg(0, opt_args("Var", flags))
 118 }
 119
 120 # Return true if the option described by FLAGS has a globally-visible state.
 121 function global_state_p(flags)
 122 {
 123         return (var_name(flags) != "" \
 124                 || opt_args("Mask", flags) != "" \
 125                 || opt_args("InverseMask", flags) != "")
 126 }
 127
 128 # Return true if the option described by FLAGS must have some state
 129 # associated with it.
 130 function needs_state_p(flags)
 131 {
 132         return (flag_set_p("Target", flags) \
 133                 && !flag_set_p("Alias.*", flags) \
 134                 && !flag_set_p("Ignore", flags))
 135 }
 136
 137 # If FLAGS describes an option that needs state without a public
 138 # variable name, return the name of that field, minus the initial
 139 # "x_", otherwise return "".  NAME is the name of the option.
 140 function static_var(name, flags)
 141 {
 142         if (global_state_p(flags) || !needs_state_p(flags))
 143                 return ""
 144         gsub ("[^" alnum "]", "_", name)
 145         return "VAR_" name
 146 }
 147
 148 # Return the type of variable that should be associated with the given flags.
 149 function var_type(flags)
 150 {
 151         if (flag_set_p("Defer", flags))
 152                 return "void *"
 153         else if (flag_set_p("Enum.*", flags)) {
 154                 en = opt_args("Enum", flags);
 155                 return enum_type[en] " "
 156         }
 157         else if (!flag_set_p("Joined.*", flags) && !flag_set_p("Separate", flags))
 158                 return "int "
 159         else if (flag_set_p("UInteger", flags))
 160                 return "int "
 161         else
 162                 return "const char *"
 163 }
 164
 165 # Return the type of variable that should be associated with the given flags
 166 # for use within a structure.  Simple variables are changed to signed char
 167 # type instead of int to save space.
 168 function var_type_struct(flags)
 169 {
 170         if (flag_set_p("UInteger", flags))
 171                 return "int "
 172         else if (!flag_set_p("Joined.*", flags) && !flag_set_p("Separate", flags)) {
 173                 if (flag_set_p(".*Mask.*", flags))
 174                         return "int "
 175                 else
 176                         return "signed char "
 177         }
 178         else
 179                 return "const char *"
 180 }
 181
 182 # Given that an option has flags FLAGS, return an initializer for the
 183 # "var_enum", "var_type" and "var_value" fields of its cl_options[] entry.
 184 function var_set(flags)
 185 {
 186         if (flag_set_p("Defer", flags))
 187                 return "0, CLVC_DEFER, 0"
 188         s = nth_arg(1, opt_args("Var", flags))
 189         if (s != "")
 190                 return "0, CLVC_EQUAL, " s
 191         s = opt_args("Mask", flags);
 192         if (s != "") {
 193                 vn = var_name(flags);
 194                 if (vn)
 195                         return "0, CLVC_BIT_SET, OPTION_MASK_" s
 196                 else
 197                         return "0, CLVC_BIT_SET, MASK_" s
 198         }
 199         s = nth_arg(0, opt_args("InverseMask", flags));
 200         if (s != "") {
 201                 vn = var_name(flags);
 202                 if (vn)
 203                         return "0, CLVC_BIT_CLEAR, OPTION_MASK_" s
 204                 else
 205                         return "0, CLVC_BIT_CLEAR, MASK_" s
 206         }
 207         if (flag_set_p("Enum.*", flags)) {
 208                 en = opt_args("Enum", flags);
 209                 return enum_index[en] ", CLVC_ENUM, 0"
 210         }
 211         if (var_type(flags) == "const char *")
 212                 return "0, CLVC_STRING, 0"
 213         return "0, CLVC_BOOLEAN, 0"
 214 }
 215
 216 # Given that an option called NAME has flags FLAGS, return an initializer
 217 # for the "flag_var" field of its cl_options[] entry.
 218 function var_ref(name, flags)
 219 {
 220         name = var_name(flags) static_var(name, flags)
 221         if (name != "")
 222                 return "offsetof (struct gcc_options, x_" name ")"
 223         if (opt_args("Mask", flags) != "")
 224                 return "offsetof (struct gcc_options, x_target_flags)"
 225         if (opt_args("InverseMask", flags) != "")
 226                 return "offsetof (struct gcc_options, x_target_flags)"
 227         return "-1"
 228 }
 229
 230 # Given the option called NAME return a sanitized version of its name.
 231 function opt_sanitized_name(name)
 232 {
 233         gsub ("[^" alnum "]", "_", name)
 234         return name
 235 }
 236
 237 # Given the option called NAME return the appropriate enum for it.
 238 function opt_enum(name)
 239 {
 240         return "OPT_" opt_sanitized_name(name)
 241 }