zlib/configure.ac

   1 dnl Process this with autoconf to create configure
   2
   3 AC_PREREQ(2.64)
   4 AC_INIT
   5 AC_CONFIG_SRCDIR([zlib.h])
   6
   7 AM_ENABLE_MULTILIB(, ..)
   8
   9 AC_CANONICAL_SYSTEM
  10
  11 # This works around an automake problem.
  12 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  13 AC_SUBST(mkinstalldirs)
  14
  15 AM_INIT_AUTOMAKE(zlib, 1.1.4)
  16
  17 AM_MAINTAINER_MODE
  18
  19 dnl We use these options to decide which functions to include.
  20 AC_ARG_WITH(target-subdir,
  21 [  --with-target-subdir=SUBDIR
  22                           configuring in a subdirectory])
  23
  24 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  25    COMPPATH=.
  26 else
  27    COMPPATH=..
  28 fi
  29 AC_SUBST(COMPPATH)
  30
  31 AC_ARG_WITH(cross-host,
  32 [  --with-cross-host=HOST  configuring with a cross compiler])
  33
  34 dnl Default to --enable-multilib
  35 AC_ARG_ENABLE(multilib,
  36 [  --enable-multilib       build many library versions (default)],
  37 [case "${enableval}" in
  38   yes) multilib=yes ;;
  39   no)  multilib=no ;;
  40   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  41  esac], [test -z "$with_target_subdir" && multilib=no || multilib=yes])dnl
  42
  43 AC_ARG_WITH(system-zlib,
  44 [  --with-system-zlib      use installed libz])
  45
  46 # Make sure we don't test executables when making cross-tools.
  47 GCC_NO_EXECUTABLES
  48
  49 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
  50 # We must force CC to /not/ be precious variables; otherwise
  51 # the wrong, non-multilib-adjusted value will be used in multilibs.
  52 # As a side effect, we have to subst CFLAGS ourselves.
  53
  54 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
  55 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  56 AC_PROG_CC
  57 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  58
  59 AC_SUBST(CFLAGS)
  60
  61 AC_PROG_LIBTOOL
  62
  63 # Find CPP now so that any conditional tests below won't do it and
  64 # thereby make the resulting definitions conditional.
  65 AC_PROG_CPP
  66
  67 if test -n "$with_cross_host"; then
  68    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
  69    # may not work correctly, because the compiler may not be able to
  70    # link executables.
  71
  72    # We assume newlib.  This lets us hard-code the functions we know
  73    # we'll have.
  74    AC_DEFINE(HAVE_MEMCPY)
  75    AC_DEFINE(HAVE_STRERROR)
  76
  77    # We ignore --with-system-zlib in this case.
  78    target_all=libzgcj.la
  79 else
  80    AC_FUNC_MMAP
  81    AC_CHECK_FUNCS(memcpy strerror)
  82
  83    if test "$with_system_zlib" = yes; then
  84       AC_CHECK_LIB(z, deflate, target_all=, target_all=libzgcj.la)
  85    else
  86       target_all=libzgcj.la
  87    fi
  88 fi
  89
  90 AC_SUBST(target_all)
  91
  92 AC_CHECK_HEADERS(unistd.h)
  93
  94 if test -n "$with_cross_host" &&
  95    test x"$with_cross_host" != x"no"; then
  96   toolexecdir='$(exec_prefix)/$(target_alias)'
  97   toolexeclibdir='$(toolexecdir)/lib'
  98 else
  99   toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 100   toolexeclibdir='$(libdir)'
 101 fi
 102 if test "$GCC" = yes && $CC -print-multi-os-directory > /dev/null 2>&1; then
 103   multiosdir=/`$CC -print-multi-os-directory`
 104   case $multiosdir in
 105     /.) multiosdir= ;; # Avoid trailing /.
 106   esac
 107 else
 108   multiosdir=
 109 fi
 110 toolexeclibdir=${toolexeclibdir}${multiosdir}
 111 AC_SUBST(toolexecdir)
 112 AC_SUBST(toolexeclibdir)
 113
 114 AM_CONDITIONAL(TARGET_LIBRARY, test -n "$with_target_subdir")
 115
 116 if test "${multilib}" = "yes"; then
 117   multilib_arg="--enable-multilib"
 118 else
 119   multilib_arg=
 120 fi
 121
 122 AC_ARG_ENABLE(host-shared,
 123 [AS_HELP_STRING([--enable-host-shared],
 124                 [build host code as shared libraries])],
 125 [PICFLAG=-fPIC], [PICFLAG=])
 126 AC_SUBST(PICFLAG)
 127
 128 AC_CONFIG_FILES([Makefile])
 129 AC_OUTPUT