gcc/ada/table.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                                T A B L E                                 --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2008, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This package provides an implementation of dynamically resizable one
  35 --  dimensional arrays. The idea is to mimic the normal Ada semantics for
  36 --  arrays as closely as possible with the one additional capability of
  37 --  dynamically modifying the value of the Last attribute.
  38
  39 --  Note that this interface should remain synchronized with those in
  40 --  GNAT.Table and GNAT.Dynamic_Tables to keep coherency between these
  41 --  three related units.
  42
  43 with Types; use Types;
  44
  45 package Table is
  46    pragma Elaborate_Body;
  47
  48    generic
  49       type Table_Component_Type is private;
  50       type Table_Index_Type     is range <>;
  51
  52       Table_Low_Bound  : Table_Index_Type;
  53       Table_Initial    : Pos;
  54       Table_Increment  : Nat;
  55       Table_Name       : String;
  56
  57    package Table is
  58
  59       --  Table_Component_Type and Table_Index_Type specify the type of the
  60       --  array, Table_Low_Bound is the lower bound. Index_type must be an
  61       --  integer type. The effect is roughly to declare:
  62
  63       --    Table : array (Table_Index_Type range Table_Low_Bound .. <>)
  64       --                       of Table_Component_Type;
  65
  66       --    Note: since the upper bound can be one less than the lower
  67       --    bound for an empty array, the table index type must be able
  68       --    to cover this range, e.g. if the lower bound is 1, then the
  69       --    Table_Index_Type should be Natural rather than Positive.
  70
  71       --  Table_Component_Type may be any Ada type, except that controlled
  72       --  types are not supported. Note however that default initialization
  73       --  will NOT occur for array components.
  74
  75       --  The Table_Initial values controls the allocation of the table when
  76       --  it is first allocated, either by default, or by an explicit Init
  77       --  call. The value used is Opt.Table_Factor * Table_Initial.
  78
  79       --  The Table_Increment value controls the amount of increase, if the
  80       --  table has to be increased in size. The value given is a percentage
  81       --  value (e.g. 100 = increase table size by 100%, i.e. double it).
  82
  83       --  The Table_Name parameter is simply use in debug output messages it
  84       --  has no other usage, and is not referenced in non-debugging mode.
  85
  86       --  The Last and Set_Last subprograms provide control over the current
  87       --  logical allocation. They are quite efficient, so they can be used
  88       --  freely (expensive reallocation occurs only at major granularity
  89       --  chunks controlled by the allocation parameters).
  90
  91       --  Note: We do not make the table components aliased, since this would
  92       --  restrict the use of table for discriminated types. If it is necessary
  93       --  to take the access of a table element, use Unrestricted_Access.
  94
  95       --  WARNING: On HPPA, the virtual addressing approach used in this unit
  96       --  is incompatible with the indexing instructions on the HPPA. So when
  97       --  using this unit, compile your application with -mdisable-indexing.
  98
  99       --  WARNING: If the table is reallocated, then the address of all its
 100       --  components will change. So do not capture the address of an element
 101       --  and then use the address later after the table may be reallocated.
 102       --  One tricky case of this is passing an element of the table to a
 103       --  subprogram by reference where the table gets reallocated during
 104       --  the execution of the subprogram. The best rule to follow is never
 105       --  to pass a table element as a parameter except for the case of IN
 106       --  mode parameters with scalar values.
 107
 108       type Table_Type is
 109         array (Table_Index_Type range <>) of Table_Component_Type;
 110
 111       subtype Big_Table_Type is
 112         Table_Type (Table_Low_Bound .. Table_Index_Type'Last);
 113       --  We work with pointers to a bogus array type that is constrained
 114       --  with the maximum possible range bound. This means that the pointer
 115       --  is a thin pointer, which is more efficient. Since subscript checks
 116       --  in any case must be on the logical, rather than physical bounds,
 117       --  safety is not compromised by this approach.
 118
 119       type Table_Ptr is access all Big_Table_Type;
 120       for Table_Ptr'Storage_Size use 0;
 121       --  The table is actually represented as a pointer to allow reallocation
 122
 123       Table : aliased Table_Ptr := null;
 124       --  The table itself. The lower bound is the value of Low_Bound.
 125       --  Logically the upper bound is the current value of Last (although
 126       --  the actual size of the allocated table may be larger than this).
 127       --  The program may only access and modify Table entries in the range
 128       --  First .. Last.
 129
 130       Locked : Boolean := False;
 131       --  Table expansion is permitted only if this switch is set to False. A
 132       --  client may set Locked to True, in which case any attempt to expand
 133       --  the table will cause an assertion failure. Note that while a table
 134       --  is locked, its address in memory remains fixed and unchanging. This
 135       --  feature is used to control table expansion during Gigi processing.
 136       --  Gigi assumes that tables other than the Uint and Ureal tables do
 137       --  not move during processing, which means that they cannot be expanded.
 138       --  The Locked flag is used to enforce this restriction.
 139
 140       procedure Init;
 141       --  This procedure allocates a new table of size Initial (freeing any
 142       --  previously allocated larger table). It is not necessary to call
 143       --  Init when a table is first instantiated (since the instantiation does
 144       --  the same initialization steps). However, it is harmless to do so, and
 145       --  Init is convenient in reestablishing a table for new use.
 146
 147       function Last return Table_Index_Type;
 148       pragma Inline (Last);
 149       --  Returns the current value of the last used entry in the table, which
 150       --  can then be used as a subscript for Table. Note that the only way to
 151       --  modify Last is to call the Set_Last procedure. Last must always be
 152       --  used to determine the logically last entry.
 153
 154       procedure Release;
 155       --  Storage is allocated in chunks according to the values given in the
 156       --  Initial and Increment parameters. A call to Release releases all
 157       --  storage that is allocated, but is not logically part of the current
 158       --  array value. Current array values are not affected by this call.
 159
 160       procedure Free;
 161       --  Free all allocated memory for the table. A call to init is required
 162       --  before any use of this table after calling Free.
 163
 164       First : constant Table_Index_Type := Table_Low_Bound;
 165       --  Export First as synonym for Low_Bound (parallel with use of Last)
 166
 167       procedure Set_Last (New_Val : Table_Index_Type);
 168       pragma Inline (Set_Last);
 169       --  This procedure sets Last to the indicated value. If necessary the
 170       --  table is reallocated to accommodate the new value (i.e. on return
 171       --  the allocated table has an upper bound of at least Last). If Set_Last
 172       --  reduces the size of the table, then logically entries are removed
 173       --  from the table. If Set_Last increases the size of the table, then
 174       --  new entries are logically added to the table.
 175
 176       procedure Increment_Last;
 177       pragma Inline (Increment_Last);
 178       --  Adds 1 to Last (same as Set_Last (Last + 1)
 179
 180       procedure Decrement_Last;
 181       pragma Inline (Decrement_Last);
 182       --  Subtracts 1 from Last (same as Set_Last (Last - 1)
 183
 184       procedure Append (New_Val : Table_Component_Type);
 185       pragma Inline (Append);
 186       --  Equivalent to:
 187       --    x.Increment_Last;
 188       --    x.Table (x.Last) := New_Val;
 189       --  i.e. the table size is increased by one, and the given new item
 190       --  stored in the newly created table element.
 191
 192       procedure Set_Item
 193         (Index : Table_Index_Type;
 194          Item  : Table_Component_Type);
 195       pragma Inline (Set_Item);
 196       --  Put Item in the table at position Index. The table is expanded if
 197       --  current table length is less than Index and in that case Last is set
 198       --  to Index. Item will replace any value already present in the table
 199       --  at this position.
 200
 201       type Saved_Table is private;
 202       --  Type used for Save/Restore subprograms
 203
 204       function Save return Saved_Table;
 205       --  Resets table to empty, but saves old contents of table in returned
 206       --  value, for possible later restoration by a call to Restore.
 207
 208       procedure Restore (T : Saved_Table);
 209       --  Given a Saved_Table value returned by a prior call to Save, restores
 210       --  the table to the state it was in at the time of the Save call.
 211
 212       procedure Tree_Write;
 213       --  Writes out contents of table using Tree_IO
 214
 215       procedure Tree_Read;
 216       --  Initializes table by reading contents previously written
 217       --  with the Tree_Write call (also using Tree_IO)
 218
 219    private
 220
 221       Last_Val : Int;
 222       --  Current value of Last. Note that we declare this in the private part
 223       --  because we don't want the client to modify Last except through one of
 224       --  the official interfaces (since a modification to Last may require a
 225       --  reallocation of the table).
 226
 227       Max : Int;
 228       --  Subscript of the maximum entry in the currently allocated table
 229
 230       type Saved_Table is record
 231          Last_Val : Int;
 232          Max      : Int;
 233          Table    : Table_Ptr;
 234       end record;
 235
 236    end Table;
 237 end Table;