gcc/ada/s-interr.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                 GNAT RUN-TIME LIBRARY (GNARL) COMPONENTS                 --
   4 --                                                                          --
   5 --                     S Y S T E M . I N T E R R U P T S                    --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --         Copyright (C) 1992-2007, Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  19 -- to  the  Free Software Foundation,  51  Franklin  Street,  Fifth  Floor, --
  20 -- Boston, MA 02110-1301, USA.                                              --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNARL was developed by the GNARL team at Florida State University.       --
  30 -- Extensive contributions were provided by Ada Core Technologies, Inc.     --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  Invariants:
  35
  36 --  All user-handleable interrupts are masked at all times in all
  37 --  tasks/threads except possibly for the Interrupt_Manager task.
  38
  39 --  When a user task wants to have the effect of masking/unmasking an
  40 --  interrupt, it must call Block_Interrupt/Unblock_Interrupt, which
  41 --  will have the effect of unmasking/masking the interrupt in the
  42 --  Interrupt_Manager task.
  43
  44 --  Note : Direct calls to sigaction, sigprocmask, pthread_sigsetmask or any
  45 --  other low-level interface that changes the interrupt action or
  46 --  interrupt mask needs a careful thought.
  47 --  One may acheive the effect of system calls first masking RTS blocked
  48 --  (by calling Block_Interrupt) for the interrupt under consideration.
  49 --  This will make all the tasks in RTS blocked for the Interrupt.
  50
  51 --  Once we associate a Server_Task with an interrupt, the task never
  52 --  goes away, and we never remove the association.
  53
  54 --  There is no more than one interrupt per Server_Task and no more than
  55 --  one Server_Task per interrupt.
  56
  57 with Ada.Task_Identification;
  58 --  used for Task_Id type
  59
  60 with Ada.Exceptions;
  61 --  used for Raise_Exception
  62
  63 with System.Task_Primitives;
  64 --  used for RTS_Lock
  65 --           Self
  66
  67 with System.Interrupt_Management;
  68 --  used for Reserve
  69 --           Interrupt_ID
  70 --           Interrupt_Mask
  71 --           Abort_Task_Interrupt
  72
  73 with System.Interrupt_Management.Operations;
  74 --  used for Thread_Block_Interrupt
  75 --           Thread_Unblock_Interrupt
  76 --           Install_Default_Action
  77 --           Install_Ignore_Action
  78 --           Copy_Interrupt_Mask
  79 --           Set_Interrupt_Mask
  80 --           Empty_Interrupt_Mask
  81 --           Fill_Interrupt_Mask
  82 --           Add_To_Interrupt_Mask
  83 --           Delete_From_Interrupt_Mask
  84 --           Interrupt_Wait
  85 --           Interrupt_Self_Process
  86 --           Get_Interrupt_Mask
  87 --           Set_Interrupt_Mask
  88 --           IS_Member
  89 --           Environment_Mask
  90 --           All_Tasks_Mask
  91 pragma Elaborate_All (System.Interrupt_Management.Operations);
  92
  93 with System.Task_Primitives.Operations;
  94 --  used for Write_Lock
  95 --           Unlock
  96 --           Abort
  97 --           Wakeup_Task
  98 --           Sleep
  99 --           Initialize_Lock
 100
 101 with System.Task_Primitives.Interrupt_Operations;
 102 --  used for Set_Interrupt_ID
 103
 104 with System.Storage_Elements;
 105 --  used for To_Address
 106 --           To_Integer
 107 --           Integer_Address
 108
 109 with System.Tasking.Utilities;
 110 --  used for Make_Independent
 111
 112 with System.Tasking.Rendezvous;
 113 --  used for Call_Simple
 114 pragma Elaborate_All (System.Tasking.Rendezvous);
 115
 116 with System.Tasking.Initialization;
 117 --  used for Defer_Abort
 118 --           Undefer_Abort
 119
 120 with System.Parameters;
 121 --  used for Single_Lock
 122
 123 with Ada.Unchecked_Conversion;
 124
 125 package body System.Interrupts is
 126
 127    use Parameters;
 128    use Tasking;
 129    use Ada.Exceptions;
 130
 131    package POP renames System.Task_Primitives.Operations;
 132    package PIO renames System.Task_Primitives.Interrupt_Operations;
 133    package IMNG renames System.Interrupt_Management;
 134    package IMOP renames System.Interrupt_Management.Operations;
 135
 136    function To_System is new Ada.Unchecked_Conversion
 137      (Ada.Task_Identification.Task_Id, Task_Id);
 138
 139    -----------------
 140    -- Local Tasks --
 141    -----------------
 142
 143    --  WARNING: System.Tasking.Stages performs calls to this task with
 144    --  low-level constructs. Do not change this spec without synchronizing it.
 145
 146    task Interrupt_Manager is
 147       entry Detach_Interrupt_Entries (T : Task_Id);
 148
 149       entry Initialize (Mask : IMNG.Interrupt_Mask);
 150
 151       entry Attach_Handler
 152         (New_Handler : Parameterless_Handler;
 153          Interrupt   : Interrupt_ID;
 154          Static      : Boolean;
 155          Restoration : Boolean := False);
 156
 157       entry Exchange_Handler
 158         (Old_Handler : out Parameterless_Handler;
 159          New_Handler : Parameterless_Handler;
 160          Interrupt   : Interrupt_ID;
 161          Static      : Boolean);
 162
 163       entry Detach_Handler
 164         (Interrupt   : Interrupt_ID;
 165          Static      : Boolean);
 166
 167       entry Bind_Interrupt_To_Entry
 168         (T         : Task_Id;
 169          E         : Task_Entry_Index;
 170          Interrupt : Interrupt_ID);
 171
 172       entry Block_Interrupt (Interrupt : Interrupt_ID);
 173
 174       entry Unblock_Interrupt (Interrupt : Interrupt_ID);
 175
 176       entry Ignore_Interrupt (Interrupt : Interrupt_ID);
 177
 178       entry Unignore_Interrupt (Interrupt : Interrupt_ID);
 179
 180       pragma Interrupt_Priority (System.Interrupt_Priority'Last);
 181    end Interrupt_Manager;
 182
 183    task type Server_Task (Interrupt : Interrupt_ID) is
 184       pragma Priority (System.Interrupt_Priority'Last);
 185       --  Note: the above pragma Priority is strictly speaking improper since
 186       --  it is outside the range of allowed priorities, but the compiler
 187       --  treats system units specially and does not apply this range checking
 188       --  rule to system units.
 189
 190    end Server_Task;
 191
 192    type Server_Task_Access is access Server_Task;
 193
 194    -------------------------------
 195    -- Local Types and Variables --
 196    -------------------------------
 197
 198    type Entry_Assoc is record
 199       T : Task_Id;
 200       E : Task_Entry_Index;
 201    end record;
 202
 203    type Handler_Assoc is record
 204       H      : Parameterless_Handler;
 205       Static : Boolean;   --  Indicates static binding;
 206    end record;
 207
 208    User_Handler : array (Interrupt_ID'Range) of Handler_Assoc :=
 209                     (others => (null, Static => False));
 210    pragma Volatile_Components (User_Handler);
 211    --  Holds the protected procedure handler (if any) and its Static
 212    --  information for each interrupt. A handler is a Static one if it is
 213    --  specified through the pragma Attach_Handler. Attach_Handler. Otherwise,
 214    --  not static)
 215
 216    User_Entry : array (Interrupt_ID'Range) of Entry_Assoc :=
 217                   (others => (T => Null_Task, E => Null_Task_Entry));
 218    pragma Volatile_Components (User_Entry);
 219    --  Holds the task and entry index (if any) for each interrupt
 220
 221    Blocked : array (Interrupt_ID'Range) of Boolean := (others => False);
 222    pragma Atomic_Components (Blocked);
 223    --  True iff the corresponding interrupt is blocked in the process level
 224
 225    Ignored : array (Interrupt_ID'Range) of Boolean := (others => False);
 226    pragma Atomic_Components (Ignored);
 227    --  True iff the corresponding interrupt is blocked in the process level
 228
 229    Last_Unblocker :
 230      array (Interrupt_ID'Range) of Task_Id := (others => Null_Task);
 231    pragma Atomic_Components (Last_Unblocker);
 232    --  Holds the ID of the last Task which Unblocked this Interrupt. It
 233    --  contains Null_Task if no tasks have ever requested the Unblocking
 234    --  operation or the Interrupt is currently Blocked.
 235
 236    Server_ID : array (Interrupt_ID'Range) of Task_Id :=
 237                  (others => Null_Task);
 238    pragma Atomic_Components (Server_ID);
 239    --  Holds the Task_Id of the Server_Task for each interrupt. Task_Id is
 240    --  needed to accomplish locking per Interrupt base. Also is needed to
 241    --  decide whether to create a new Server_Task.
 242
 243    --  Type and Head, Tail of the list containing Registered Interrupt
 244    --  Handlers. These definitions are used to register the handlers
 245    --  specified by the pragma Interrupt_Handler.
 246
 247    type Registered_Handler;
 248    type R_Link is access all Registered_Handler;
 249
 250    type Registered_Handler is record
 251       H    : System.Address := System.Null_Address;
 252       Next : R_Link := null;
 253    end record;
 254
 255    Registered_Handler_Head : R_Link := null;
 256    Registered_Handler_Tail : R_Link := null;
 257
 258    Access_Hold : Server_Task_Access;
 259    --  Variable used to allocate Server_Task using "new"
 260
 261    -----------------------
 262    -- Local Subprograms --
 263    -----------------------
 264
 265    function Is_Registered (Handler : Parameterless_Handler) return Boolean;
 266    --  See if the Handler has been "pragma"ed using Interrupt_Handler. Always
 267    --  consider a null handler as registered.
 268
 269    --------------------
 270    -- Attach_Handler --
 271    --------------------
 272
 273    --  Calling this procedure with New_Handler = null and Static = True means
 274    --  we want to detach the current handler regardless of the previous
 275    --  handler's binding status (ie. do not care if it is a dynamic or static
 276    --  handler).
 277
 278    --  This option is needed so that during the finalization of a PO, we can
 279    --  detach handlers attached through pragma Attach_Handler.
 280
 281    procedure Attach_Handler
 282      (New_Handler : Parameterless_Handler;
 283       Interrupt   : Interrupt_ID;
 284       Static      : Boolean := False)
 285    is
 286    begin
 287       if Is_Reserved (Interrupt) then
 288          Raise_Exception (Program_Error'Identity, "Interrupt" &
 289            Interrupt_ID'Image (Interrupt) & " is reserved");
 290       end if;
 291
 292       Interrupt_Manager.Attach_Handler (New_Handler, Interrupt, Static);
 293
 294    end Attach_Handler;
 295
 296    -----------------------------
 297    -- Bind_Interrupt_To_Entry --
 298    -----------------------------
 299
 300    --  This procedure raises a Program_Error if it tries to bind an interrupt
 301    --  to which an Entry or a Procedure is already bound.
 302
 303    procedure Bind_Interrupt_To_Entry
 304      (T       : Task_Id;
 305       E       : Task_Entry_Index;
 306       Int_Ref : System.Address)
 307    is
 308       Interrupt   : constant Interrupt_ID :=
 309                       Interrupt_ID (Storage_Elements.To_Integer (Int_Ref));
 310
 311    begin
 312       if Is_Reserved (Interrupt) then
 313          Raise_Exception (Program_Error'Identity, "Interrupt" &
 314            Interrupt_ID'Image (Interrupt) & " is reserved");
 315       end if;
 316
 317       Interrupt_Manager.Bind_Interrupt_To_Entry (T, E, Interrupt);
 318    end Bind_Interrupt_To_Entry;
 319
 320    ---------------------
 321    -- Block_Interrupt --
 322    ---------------------
 323
 324    procedure Block_Interrupt (Interrupt : Interrupt_ID) is
 325    begin
 326       if Is_Reserved (Interrupt) then
 327          Raise_Exception (Program_Error'Identity, "Interrupt" &
 328            Interrupt_ID'Image (Interrupt) & " is reserved");
 329       end if;
 330
 331       Interrupt_Manager.Block_Interrupt (Interrupt);
 332    end Block_Interrupt;
 333
 334    ---------------------
 335    -- Current_Handler --
 336    ---------------------
 337
 338    function Current_Handler
 339      (Interrupt : Interrupt_ID) return Parameterless_Handler
 340    is
 341    begin
 342       if Is_Reserved (Interrupt) then
 343          Raise_Exception (Program_Error'Identity, "Interrupt" &
 344            Interrupt_ID'Image (Interrupt) & " is reserved");
 345       end if;
 346
 347       --  ??? Since Parameterless_Handler is not Atomic, the current
 348       --  implementation is wrong. We need a new service in Interrupt_Manager
 349       --  to ensure atomicity.
 350
 351       return User_Handler (Interrupt).H;
 352    end Current_Handler;
 353
 354    --------------------
 355    -- Detach_Handler --
 356    --------------------
 357
 358    --  Calling this procedure with Static = True means we want to Detach the
 359    --  current handler regardless of the previous handler's binding status
 360    --  (i.e. do not care if it is a dynamic or static handler).
 361
 362    --  This option is needed so that during the finalization of a PO, we can
 363    --  detach handlers attached through pragma Attach_Handler.
 364
 365    procedure Detach_Handler
 366      (Interrupt : Interrupt_ID;
 367       Static    : Boolean := False)
 368    is
 369    begin
 370       if Is_Reserved (Interrupt) then
 371          Raise_Exception (Program_Error'Identity, "Interrupt" &
 372            Interrupt_ID'Image (Interrupt) & " is reserved");
 373       end if;
 374
 375       Interrupt_Manager.Detach_Handler (Interrupt, Static);
 376    end Detach_Handler;
 377
 378    ------------------------------
 379    -- Detach_Interrupt_Entries --
 380    ------------------------------
 381
 382    procedure Detach_Interrupt_Entries (T : Task_Id) is
 383    begin
 384       Interrupt_Manager.Detach_Interrupt_Entries (T);
 385    end Detach_Interrupt_Entries;
 386
 387    ----------------------
 388    -- Exchange_Handler --
 389    ----------------------
 390
 391    --  Calling this procedure with New_Handler = null and Static = True means
 392    --  we want to detach the current handler regardless of the previous
 393    --  handler's binding status (ie. do not care if it is a dynamic or static
 394    --  handler).
 395
 396    --  This option is needed so that during the finalization of a PO, we can
 397    --  detach handlers attached through pragma Attach_Handler.
 398
 399    procedure Exchange_Handler
 400      (Old_Handler : out Parameterless_Handler;
 401       New_Handler : Parameterless_Handler;
 402       Interrupt   : Interrupt_ID;
 403       Static      : Boolean := False)
 404    is
 405    begin
 406       if Is_Reserved (Interrupt) then
 407          Raise_Exception (Program_Error'Identity, "Interrupt" &
 408            Interrupt_ID'Image (Interrupt) & " is reserved");
 409       end if;
 410
 411       Interrupt_Manager.Exchange_Handler
 412         (Old_Handler, New_Handler, Interrupt, Static);
 413    end Exchange_Handler;
 414
 415    --------------
 416    -- Finalize --
 417    --------------
 418
 419    procedure Finalize (Object : in out Static_Interrupt_Protection) is
 420    begin
 421       --  ??? loop to be executed only when we're not doing library level
 422       --  finalization, since in this case all interrupt tasks are gone.
 423
 424       if not Interrupt_Manager'Terminated then
 425          for N in reverse Object.Previous_Handlers'Range loop
 426             Interrupt_Manager.Attach_Handler
 427               (New_Handler => Object.Previous_Handlers (N).Handler,
 428                Interrupt   => Object.Previous_Handlers (N).Interrupt,
 429                Static      => Object.Previous_Handlers (N).Static,
 430                Restoration => True);
 431          end loop;
 432       end if;
 433
 434       Tasking.Protected_Objects.Entries.Finalize
 435         (Tasking.Protected_Objects.Entries.Protection_Entries (Object));
 436    end Finalize;
 437
 438    -------------------------------------
 439    -- Has_Interrupt_Or_Attach_Handler --
 440    -------------------------------------
 441
 442    --  Need comments as to why these always return True ???
 443
 444    function Has_Interrupt_Or_Attach_Handler
 445      (Object : access Dynamic_Interrupt_Protection) return Boolean
 446    is
 447       pragma Unreferenced (Object);
 448    begin
 449       return True;
 450    end Has_Interrupt_Or_Attach_Handler;
 451
 452    function Has_Interrupt_Or_Attach_Handler
 453      (Object : access Static_Interrupt_Protection) return Boolean
 454    is
 455       pragma Unreferenced (Object);
 456    begin
 457       return True;
 458    end Has_Interrupt_Or_Attach_Handler;
 459
 460    ----------------------
 461    -- Ignore_Interrupt --
 462    ----------------------
 463
 464    procedure Ignore_Interrupt (Interrupt : Interrupt_ID) is
 465    begin
 466       if Is_Reserved (Interrupt) then
 467          Raise_Exception (Program_Error'Identity, "Interrupt" &
 468            Interrupt_ID'Image (Interrupt) & " is reserved");
 469       end if;
 470
 471       Interrupt_Manager.Ignore_Interrupt (Interrupt);
 472    end Ignore_Interrupt;
 473
 474    ----------------------
 475    -- Install_Handlers --
 476    ----------------------
 477
 478    procedure Install_Handlers
 479      (Object       : access Static_Interrupt_Protection;
 480       New_Handlers : New_Handler_Array)
 481    is
 482    begin
 483       for N in New_Handlers'Range loop
 484
 485          --  We need a lock around this ???
 486
 487          Object.Previous_Handlers (N).Interrupt := New_Handlers (N).Interrupt;
 488          Object.Previous_Handlers (N).Static    := User_Handler
 489            (New_Handlers (N).Interrupt).Static;
 490
 491          --  We call Exchange_Handler and not directly Interrupt_Manager.
 492          --  Exchange_Handler so we get the Is_Reserved check.
 493
 494          Exchange_Handler
 495            (Old_Handler => Object.Previous_Handlers (N).Handler,
 496             New_Handler => New_Handlers (N).Handler,
 497             Interrupt   => New_Handlers (N).Interrupt,
 498             Static      => True);
 499       end loop;
 500    end Install_Handlers;
 501
 502    ----------------
 503    -- Is_Blocked --
 504    ----------------
 505
 506    function Is_Blocked (Interrupt : Interrupt_ID) return Boolean is
 507    begin
 508       if Is_Reserved (Interrupt) then
 509          Raise_Exception (Program_Error'Identity, "Interrupt" &
 510            Interrupt_ID'Image (Interrupt) & " is reserved");
 511       end if;
 512
 513       return Blocked (Interrupt);
 514    end Is_Blocked;
 515
 516    -----------------------
 517    -- Is_Entry_Attached --
 518    -----------------------
 519
 520    function Is_Entry_Attached (Interrupt : Interrupt_ID) return Boolean is
 521    begin
 522       if Is_Reserved (Interrupt) then
 523          Raise_Exception (Program_Error'Identity, "Interrupt" &
 524            Interrupt_ID'Image (Interrupt) & " is reserved");
 525       end if;
 526
 527       return User_Entry (Interrupt).T /= Null_Task;
 528    end Is_Entry_Attached;
 529
 530    -------------------------
 531    -- Is_Handler_Attached --
 532    -------------------------
 533
 534    function Is_Handler_Attached (Interrupt : Interrupt_ID) return Boolean is
 535    begin
 536       if Is_Reserved (Interrupt) then
 537          Raise_Exception (Program_Error'Identity, "Interrupt" &
 538            Interrupt_ID'Image (Interrupt) & " is reserved");
 539       end if;
 540
 541       return User_Handler (Interrupt).H /= null;
 542    end Is_Handler_Attached;
 543
 544    ----------------
 545    -- Is_Ignored --
 546    ----------------
 547
 548    function Is_Ignored (Interrupt : Interrupt_ID) return Boolean is
 549    begin
 550       if Is_Reserved (Interrupt) then
 551          Raise_Exception (Program_Error'Identity, "Interrupt" &
 552            Interrupt_ID'Image (Interrupt) & " is reserved");
 553       end if;
 554
 555       return Ignored (Interrupt);
 556    end Is_Ignored;
 557
 558    -------------------
 559    -- Is_Registered --
 560    -------------------
 561
 562    function Is_Registered (Handler : Parameterless_Handler) return Boolean is
 563
 564       type Fat_Ptr is record
 565          Object_Addr  : System.Address;
 566          Handler_Addr : System.Address;
 567       end record;
 568
 569       function To_Fat_Ptr is new Ada.Unchecked_Conversion
 570         (Parameterless_Handler, Fat_Ptr);
 571
 572       Ptr : R_Link;
 573       Fat : Fat_Ptr;
 574
 575    begin
 576       if Handler = null then
 577          return True;
 578       end if;
 579
 580       Fat := To_Fat_Ptr (Handler);
 581
 582       Ptr := Registered_Handler_Head;
 583
 584       while Ptr /= null loop
 585          if Ptr.H = Fat.Handler_Addr then
 586             return True;
 587          end if;
 588
 589          Ptr := Ptr.Next;
 590       end loop;
 591
 592       return False;
 593    end Is_Registered;
 594
 595    -----------------
 596    -- Is_Reserved --
 597    -----------------
 598
 599    function Is_Reserved (Interrupt : Interrupt_ID) return Boolean is
 600    begin
 601       return IMNG.Reserve (IMNG.Interrupt_ID (Interrupt));
 602    end Is_Reserved;
 603
 604    ---------------
 605    -- Reference --
 606    ---------------
 607
 608    function Reference (Interrupt : Interrupt_ID) return System.Address is
 609    begin
 610       if Is_Reserved (Interrupt) then
 611          Raise_Exception (Program_Error'Identity, "Interrupt" &
 612            Interrupt_ID'Image (Interrupt) & " is reserved");
 613       end if;
 614
 615       return Storage_Elements.To_Address
 616         (Storage_Elements.Integer_Address (Interrupt));
 617    end Reference;
 618
 619    ---------------------------------
 620    -- Register_Interrupt_Handler  --
 621    ---------------------------------
 622
 623    procedure Register_Interrupt_Handler (Handler_Addr : System.Address) is
 624       New_Node_Ptr : R_Link;
 625
 626    begin
 627       --  This routine registers the Handler as usable for Dynamic Interrupt
 628       --  Handler. Routines attaching and detaching Handler dynamically should
 629       --  first consult if the Handler is registered. A Program Error should
 630       --  be raised if it is not registered.
 631
 632       --  The pragma Interrupt_Handler can only appear in the library level PO
 633       --  definition and instantiation. Therefore, we do not need to implement
 634       --  Unregistering operation. Neither we need to protect the queue
 635       --  structure using a Lock.
 636
 637       pragma Assert (Handler_Addr /= System.Null_Address);
 638
 639       New_Node_Ptr := new Registered_Handler;
 640       New_Node_Ptr.H := Handler_Addr;
 641
 642       if Registered_Handler_Head = null then
 643          Registered_Handler_Head := New_Node_Ptr;
 644          Registered_Handler_Tail := New_Node_Ptr;
 645
 646       else
 647          Registered_Handler_Tail.Next := New_Node_Ptr;
 648          Registered_Handler_Tail := New_Node_Ptr;
 649       end if;
 650    end Register_Interrupt_Handler;
 651
 652    -----------------------
 653    -- Unblock_Interrupt --
 654    -----------------------
 655
 656    procedure Unblock_Interrupt (Interrupt : Interrupt_ID) is
 657    begin
 658       if Is_Reserved (Interrupt) then
 659          Raise_Exception (Program_Error'Identity, "Interrupt" &
 660            Interrupt_ID'Image (Interrupt) & " is reserved");
 661       end if;
 662
 663       Interrupt_Manager.Unblock_Interrupt (Interrupt);
 664    end Unblock_Interrupt;
 665
 666    ------------------
 667    -- Unblocked_By --
 668    ------------------
 669
 670    function Unblocked_By
 671      (Interrupt : Interrupt_ID) return System.Tasking.Task_Id
 672    is
 673    begin
 674       if Is_Reserved (Interrupt) then
 675          Raise_Exception (Program_Error'Identity, "Interrupt" &
 676            Interrupt_ID'Image (Interrupt) & " is reserved");
 677       end if;
 678
 679       return Last_Unblocker (Interrupt);
 680    end Unblocked_By;
 681
 682    ------------------------
 683    -- Unignore_Interrupt --
 684    ------------------------
 685
 686    procedure Unignore_Interrupt (Interrupt : Interrupt_ID) is
 687    begin
 688       if Is_Reserved (Interrupt) then
 689          Raise_Exception (Program_Error'Identity, "Interrupt" &
 690            Interrupt_ID'Image (Interrupt) & " is reserved");
 691       end if;
 692
 693       Interrupt_Manager.Unignore_Interrupt (Interrupt);
 694    end Unignore_Interrupt;
 695
 696    -----------------------
 697    -- Interrupt_Manager --
 698    -----------------------
 699
 700    task body Interrupt_Manager is
 701
 702       ---------------------
 703       -- Local Variables --
 704       ---------------------
 705
 706       Intwait_Mask  : aliased IMNG.Interrupt_Mask;
 707       Ret_Interrupt : Interrupt_ID;
 708       Old_Mask      : aliased IMNG.Interrupt_Mask;
 709       Old_Handler   : Parameterless_Handler;
 710
 711       --------------------
 712       -- Local Routines --
 713       --------------------
 714
 715       procedure Bind_Handler (Interrupt : Interrupt_ID);
 716       --  This procedure does not do anything if the Interrupt is blocked.
 717       --  Otherwise, we have to interrupt Server_Task for status change through
 718       --  Wakeup interrupt.
 719
 720       procedure Unbind_Handler (Interrupt : Interrupt_ID);
 721       --  This procedure does not do anything if the Interrupt is blocked.
 722       --  Otherwise, we have to interrupt Server_Task for status change
 723       --  through abort interrupt.
 724
 725       procedure Unprotected_Exchange_Handler
 726         (Old_Handler : out Parameterless_Handler;
 727          New_Handler : Parameterless_Handler;
 728          Interrupt   : Interrupt_ID;
 729          Static      : Boolean;
 730          Restoration : Boolean := False);
 731
 732       procedure Unprotected_Detach_Handler
 733         (Interrupt   : Interrupt_ID;
 734          Static      : Boolean);
 735
 736       ------------------
 737       -- Bind_Handler --
 738       ------------------
 739
 740       procedure Bind_Handler (Interrupt : Interrupt_ID) is
 741       begin
 742          if not Blocked (Interrupt) then
 743
 744             --  Mask this task for the given Interrupt so that all tasks
 745             --  are masked for the Interrupt and the actuall delivery of the
 746             --  Interrupt will be caught using "sigwait" by the
 747             --  corresponding Server_Task.
 748
 749             IMOP.Thread_Block_Interrupt (IMNG.Interrupt_ID (Interrupt));
 750
 751             --  We have installed a Handler or an Entry before we called
 752             --  this procedure. If the Handler Task is waiting to be awakened,
 753             --  do it here. Otherwise, the interrupt will be discarded.
 754
 755             POP.Wakeup (Server_ID (Interrupt), Interrupt_Server_Idle_Sleep);
 756          end if;
 757       end Bind_Handler;
 758
 759       --------------------
 760       -- Unbind_Handler --
 761       --------------------
 762
 763       procedure Unbind_Handler (Interrupt : Interrupt_ID) is
 764          Server : System.Tasking.Task_Id;
 765       begin
 766          if not Blocked (Interrupt) then
 767             --  Currently, there is a Handler or an Entry attached and
 768             --  corresponding Server_Task is waiting on "sigwait."
 769             --  We have to wake up the Server_Task and make it
 770             --  wait on condition variable by sending an
 771             --  Abort_Task_Interrupt
 772
 773             Server := Server_ID (Interrupt);
 774
 775             case Server.Common.State is
 776                when Interrupt_Server_Idle_Sleep |
 777                     Interrupt_Server_Blocked_Interrupt_Sleep
 778                =>
 779                   POP.Wakeup (Server, Server.Common.State);
 780
 781                when Interrupt_Server_Blocked_On_Event_Flag =>
 782                   POP.Abort_Task (Server);
 783
 784                   --  Make sure corresponding Server_Task is out of its
 785                   --  own sigwait state.
 786
 787                   Ret_Interrupt :=
 788                     Interrupt_ID (IMOP.Interrupt_Wait (Intwait_Mask'Access));
 789                   pragma Assert
 790                     (Ret_Interrupt = Interrupt_ID (IMNG.Abort_Task_Interrupt));
 791
 792                when Runnable =>
 793                   null;
 794
 795                when others =>
 796                   pragma Assert (False);
 797                   null;
 798             end case;
 799
 800             IMOP.Install_Default_Action (IMNG.Interrupt_ID (Interrupt));
 801
 802             --  Unmake the Interrupt for this task in order to allow default
 803             --  action again.
 804
 805             IMOP.Thread_Unblock_Interrupt (IMNG.Interrupt_ID (Interrupt));
 806
 807          else
 808             IMOP.Install_Default_Action (IMNG.Interrupt_ID (Interrupt));
 809          end if;
 810       end Unbind_Handler;
 811
 812       --------------------------------
 813       -- Unprotected_Detach_Handler --
 814       --------------------------------
 815
 816       procedure Unprotected_Detach_Handler
 817         (Interrupt   : Interrupt_ID;
 818          Static      : Boolean)
 819       is
 820          Old_Handler : Parameterless_Handler;
 821
 822       begin
 823          if User_Entry (Interrupt).T /= Null_Task then
 824
 825             --  In case we have an Interrupt Entry installed.
 826             --  raise a program error. (propagate it to the caller).
 827
 828             Raise_Exception (Program_Error'Identity,
 829               "An interrupt entry is already installed");
 830          end if;
 831
 832          --  Note : Static = True will pass the following check. That is the
 833          --  case when we want to detach a handler regardless of the static
 834          --  status of the current_Handler.
 835
 836          if not Static and then User_Handler (Interrupt).Static then
 837
 838             --  Tries to detach a static Interrupt Handler.
 839             --  raise a program error.
 840
 841             Raise_Exception (Program_Error'Identity,
 842               "Trying to detach a static Interrupt Handler");
 843          end if;
 844
 845          --  The interrupt should no longer be ignored if
 846          --  it was ever ignored.
 847
 848          Ignored (Interrupt) := False;
 849
 850          Old_Handler := User_Handler (Interrupt).H;
 851
 852          --  The new handler
 853
 854          User_Handler (Interrupt).H := null;
 855          User_Handler (Interrupt).Static := False;
 856
 857          if Old_Handler /= null then
 858             Unbind_Handler (Interrupt);
 859          end if;
 860       end Unprotected_Detach_Handler;
 861
 862       ----------------------------------
 863       -- Unprotected_Exchange_Handler --
 864       ----------------------------------
 865
 866       procedure Unprotected_Exchange_Handler
 867         (Old_Handler : out Parameterless_Handler;
 868          New_Handler : Parameterless_Handler;
 869          Interrupt   : Interrupt_ID;
 870          Static      : Boolean;
 871          Restoration : Boolean := False)
 872       is
 873       begin
 874          if User_Entry (Interrupt).T /= Null_Task then
 875
 876             --  In case we have an Interrupt Entry already installed.
 877             --  raise a program error. (propagate it to the caller).
 878
 879             Raise_Exception (Program_Error'Identity,
 880               "An interrupt is already installed");
 881          end if;
 882
 883          --  Note : A null handler with Static = True will pass the
 884          --  following check. That is the case when we want to Detach a
 885          --  handler regardless of the Static status of the current_Handler.
 886
 887          --  We don't check anything if Restoration is True, since we
 888          --  may be detaching a static handler to restore a dynamic one.
 889
 890          if not Restoration and then not Static
 891
 892             --  Tries to overwrite a static Interrupt Handler with a
 893             --  dynamic Handler
 894
 895            and then (User_Handler (Interrupt).Static
 896
 897                         --  The new handler is not specified as an
 898                         --  Interrupt Handler by a pragma.
 899
 900                         or else not Is_Registered (New_Handler))
 901          then
 902             Raise_Exception (Program_Error'Identity,
 903               "Trying to overwrite a static Interrupt Handler with a " &
 904               "dynamic Handler");
 905          end if;
 906
 907          --  The interrupt should no longer be ingnored if
 908          --  it was ever ignored.
 909
 910          Ignored (Interrupt) := False;
 911
 912          --  Save the old handler
 913
 914          Old_Handler := User_Handler (Interrupt).H;
 915
 916          --  The new handler
 917
 918          User_Handler (Interrupt).H := New_Handler;
 919
 920          if New_Handler = null then
 921
 922             --  The null handler means we are detaching the handler
 923
 924             User_Handler (Interrupt).Static := False;
 925
 926          else
 927             User_Handler (Interrupt).Static := Static;
 928          end if;
 929
 930          --  Invoke a corresponding Server_Task if not yet created.
 931          --  Place Task_Id info in Server_ID array.
 932
 933          if Server_ID (Interrupt) = Null_Task then
 934
 935             --  When a new Server_Task is created, it should have its
 936             --  signal mask set to the All_Tasks_Mask.
 937
 938             IMOP.Set_Interrupt_Mask
 939               (IMOP.All_Tasks_Mask'Access, Old_Mask'Access);
 940             Access_Hold := new Server_Task (Interrupt);
 941             IMOP.Set_Interrupt_Mask (Old_Mask'Access);
 942
 943             Server_ID (Interrupt) := To_System (Access_Hold.all'Identity);
 944          end if;
 945
 946          if New_Handler = null then
 947             if Old_Handler /= null then
 948                Unbind_Handler (Interrupt);
 949             end if;
 950
 951             return;
 952          end if;
 953
 954          if Old_Handler = null then
 955             Bind_Handler (Interrupt);
 956          end if;
 957       end Unprotected_Exchange_Handler;
 958
 959    --  Start of processing for Interrupt_Manager
 960
 961    begin
 962       --  By making this task independent of master, when the process
 963       --  goes away, the Interrupt_Manager will terminate gracefully.
 964
 965       System.Tasking.Utilities.Make_Independent;
 966
 967       --  Environment task gets its own interrupt mask, saves it,
 968       --  and then masks all interrupts except the Keep_Unmasked set.
 969
 970       --  During rendezvous, the Interrupt_Manager receives the old
 971       --  interrupt mask of the environment task, and sets its own
 972       --  interrupt mask to that value.
 973
 974       --  The environment task will call the entry of Interrupt_Manager some
 975       --  during elaboration of the body of this package.
 976
 977       accept Initialize (Mask : IMNG.Interrupt_Mask) do
 978          declare
 979             The_Mask : aliased IMNG.Interrupt_Mask;
 980
 981          begin
 982             IMOP.Copy_Interrupt_Mask (The_Mask, Mask);
 983             IMOP.Set_Interrupt_Mask (The_Mask'Access);
 984          end;
 985       end Initialize;
 986
 987       --  Note: All tasks in RTS will have all the Reserve Interrupts
 988       --  being masked (except the Interrupt_Manager) and Keep_Unmasked
 989       --  unmasked when created.
 990
 991       --  Abort_Task_Interrupt is one of the Interrupt unmasked
 992       --  in all tasks. We mask the Interrupt in this particular task
 993       --  so that "sigwait" is possible to catch an explicitely sent
 994       --  Abort_Task_Interrupt from the Server_Tasks.
 995
 996       --  This sigwaiting is needed so that we make sure a Server_Task is
 997       --  out of its own sigwait state. This extra synchronization is
 998       --  necessary to prevent following senarios.
 999
1000       --   1) Interrupt_Manager sends an Abort_Task_Interrupt to the
1001       --      Server_Task then changes its own interrupt mask (OS level).
1002       --      If an interrupt (corresponding to the Server_Task) arrives
1003       --      in the nean time we have the Interrupt_Manager umnasked and
1004       --      the Server_Task waiting on sigwait.
1005
1006       --   2) For unbinding handler, we install a default action in the
1007       --      Interrupt_Manager. POSIX.1c states that the result of using
1008       --      "sigwait" and "sigaction" simaltaneously on the same interrupt
1009       --      is undefined. Therefore, we need to be informed from the
1010       --      Server_Task of the fact that the Server_Task is out of its
1011       --      sigwait stage.
1012
1013       IMOP.Empty_Interrupt_Mask (Intwait_Mask'Access);
1014       IMOP.Add_To_Interrupt_Mask
1015         (Intwait_Mask'Access, IMNG.Abort_Task_Interrupt);
1016       IMOP.Thread_Block_Interrupt
1017         (IMNG.Abort_Task_Interrupt);
1018
1019       loop
1020          --  A block is needed to absorb Program_Error exception
1021
1022          begin
1023             select
1024                accept Attach_Handler
1025                   (New_Handler : Parameterless_Handler;
1026                    Interrupt   : Interrupt_ID;
1027                    Static      : Boolean;
1028                    Restoration : Boolean := False)
1029                do
1030                   Unprotected_Exchange_Handler
1031                     (Old_Handler, New_Handler, Interrupt, Static, Restoration);
1032                end Attach_Handler;
1033
1034             or
1035                accept Exchange_Handler
1036                   (Old_Handler : out Parameterless_Handler;
1037                    New_Handler : Parameterless_Handler;
1038                    Interrupt   : Interrupt_ID;
1039                    Static      : Boolean)
1040                do
1041                   Unprotected_Exchange_Handler
1042                     (Old_Handler, New_Handler, Interrupt, Static);
1043                end Exchange_Handler;
1044
1045             or
1046                accept Detach_Handler
1047                  (Interrupt   : Interrupt_ID;
1048                   Static      : Boolean)
1049                do
1050                   Unprotected_Detach_Handler (Interrupt, Static);
1051                end Detach_Handler;
1052
1053             or
1054                accept Bind_Interrupt_To_Entry
1055                  (T       : Task_Id;
1056                   E       : Task_Entry_Index;
1057                   Interrupt : Interrupt_ID)
1058                do
1059                   --  if there is a binding already (either a procedure or an
1060                   --  entry), raise Program_Error (propagate it to the caller).
1061
1062                   if User_Handler (Interrupt).H /= null
1063                     or else User_Entry (Interrupt).T /= Null_Task
1064                   then
1065                      Raise_Exception (Program_Error'Identity,
1066                        "A binding for this interrupt is already present");
1067                   end if;
1068
1069                   --  The interrupt should no longer be ingnored if
1070                   --  it was ever ignored.
1071
1072                   Ignored (Interrupt) := False;
1073                   User_Entry (Interrupt) := Entry_Assoc'(T => T, E => E);
1074
1075                   --  Indicate the attachment of Interrupt Entry in ATCB.
1076                   --  This is need so that when an Interrupt Entry task
1077                   --  terminates the binding can be cleaned. The call to
1078                   --  unbinding must be made by the task before it terminates.
1079
1080                   T.Interrupt_Entry := True;
1081
1082                   --  Invoke a corresponding Server_Task if not yet created.
1083                   --  Place Task_Id info in Server_ID array.
1084
1085                   if Server_ID (Interrupt) = Null_Task then
1086
1087                      --  When a new Server_Task is created, it should have its
1088                      --  signal mask set to the All_Tasks_Mask.
1089
1090                      IMOP.Set_Interrupt_Mask
1091                        (IMOP.All_Tasks_Mask'Access, Old_Mask'Access);
1092                      Access_Hold := new Server_Task (Interrupt);
1093                      IMOP.Set_Interrupt_Mask (Old_Mask'Access);
1094                      Server_ID (Interrupt) :=
1095                        To_System (Access_Hold.all'Identity);
1096                   end if;
1097
1098                   Bind_Handler (Interrupt);
1099                end Bind_Interrupt_To_Entry;
1100
1101             or
1102                accept Detach_Interrupt_Entries (T : Task_Id) do
1103                   for J in Interrupt_ID'Range loop
1104                      if not Is_Reserved (J) then
1105                         if User_Entry (J).T = T then
1106
1107                            --  The interrupt should no longer be ingnored if
1108                            --  it was ever ignored.
1109
1110                            Ignored (J) := False;
1111                            User_Entry (J) := Entry_Assoc'
1112                              (T => Null_Task, E => Null_Task_Entry);
1113                            Unbind_Handler (J);
1114                         end if;
1115                      end if;
1116                   end loop;
1117
1118                   --  Indicate in ATCB that no Interrupt Entries are attached
1119
1120                   T.Interrupt_Entry := False;
1121                end Detach_Interrupt_Entries;
1122
1123             or
1124                accept Block_Interrupt (Interrupt : Interrupt_ID) do
1125                   if Blocked (Interrupt) then
1126                      return;
1127                   end if;
1128
1129                   Blocked (Interrupt) := True;
1130                   Last_Unblocker (Interrupt) := Null_Task;
1131
1132                   --  Mask this task for the given Interrupt so that all tasks
1133                   --  are masked for the Interrupt.
1134
1135                   IMOP.Thread_Block_Interrupt (IMNG.Interrupt_ID (Interrupt));
1136
1137                   if User_Handler (Interrupt).H /= null
1138                     or else User_Entry (Interrupt).T /= Null_Task
1139                   then
1140                      --  This is the case where the Server_Task is waiting
1141                      --  on "sigwait." Wake it up by sending an
1142                      --  Abort_Task_Interrupt so that the Server_Task
1143                      --  waits on Cond.
1144
1145                      POP.Abort_Task (Server_ID (Interrupt));
1146
1147                      --  Make sure corresponding Server_Task is out of its own
1148                      --  sigwait state.
1149
1150                      Ret_Interrupt := Interrupt_ID
1151                        (IMOP.Interrupt_Wait (Intwait_Mask'Access));
1152                      pragma Assert
1153                        (Ret_Interrupt =
1154                         Interrupt_ID (IMNG.Abort_Task_Interrupt));
1155                   end if;
1156                end Block_Interrupt;
1157
1158             or
1159                accept Unblock_Interrupt (Interrupt : Interrupt_ID) do
1160                   if not Blocked (Interrupt) then
1161                      return;
1162                   end if;
1163
1164                   Blocked (Interrupt) := False;
1165                   Last_Unblocker (Interrupt) :=
1166                     To_System (Unblock_Interrupt'Caller);
1167
1168                   if User_Handler (Interrupt).H = null
1169                     and then User_Entry (Interrupt).T = Null_Task
1170                   then
1171                      --  No handler is attached. Unmask the Interrupt so that
1172                      --  the default action can be carried out.
1173
1174                      IMOP.Thread_Unblock_Interrupt
1175                        (IMNG.Interrupt_ID (Interrupt));
1176
1177                   else
1178                      --  The Server_Task must be waiting on the Cond variable
1179                      --  since it was being blocked and an Interrupt Hander or
1180                      --  an Entry was there. Wake it up and let it change
1181                      --  it place of waiting according to its new state.
1182
1183                      POP.Wakeup (Server_ID (Interrupt),
1184                        Interrupt_Server_Blocked_Interrupt_Sleep);
1185                   end if;
1186                end Unblock_Interrupt;
1187
1188             or
1189                accept Ignore_Interrupt (Interrupt : Interrupt_ID) do
1190                   if Ignored (Interrupt) then
1191                      return;
1192                   end if;
1193
1194                   Ignored (Interrupt) := True;
1195
1196                   --  If there is a handler associated with the Interrupt,
1197                   --  detach it first. In this way we make sure that the
1198                   --  Server_Task is not on sigwait. This is legal since
1199                   --  Unignore_Interrupt is to install the default action.
1200
1201                   if User_Handler (Interrupt).H /= null then
1202                      Unprotected_Detach_Handler
1203                        (Interrupt => Interrupt, Static => True);
1204
1205                   elsif User_Entry (Interrupt).T /= Null_Task then
1206                      User_Entry (Interrupt) := Entry_Assoc'
1207                        (T => Null_Task, E => Null_Task_Entry);
1208                      Unbind_Handler (Interrupt);
1209                   end if;
1210
1211                   IMOP.Install_Ignore_Action (IMNG.Interrupt_ID (Interrupt));
1212                end Ignore_Interrupt;
1213
1214             or
1215                accept Unignore_Interrupt (Interrupt : Interrupt_ID) do
1216                   Ignored (Interrupt) := False;
1217
1218                   --  If there is a handler associated with the Interrupt,
1219                   --  detach it first. In this way we make sure that the
1220                   --  Server_Task is not on sigwait. This is legal since
1221                   --  Unignore_Interrupt is to install the default action.
1222
1223                   if User_Handler (Interrupt).H /= null then
1224                      Unprotected_Detach_Handler
1225                        (Interrupt => Interrupt, Static => True);
1226
1227                   elsif User_Entry (Interrupt).T /= Null_Task then
1228                      User_Entry (Interrupt) := Entry_Assoc'
1229                        (T => Null_Task, E => Null_Task_Entry);
1230                      Unbind_Handler (Interrupt);
1231                   end if;
1232
1233                   IMOP.Install_Default_Action (IMNG.Interrupt_ID (Interrupt));
1234                end Unignore_Interrupt;
1235             end select;
1236
1237          exception
1238             --  If there is a program error we just want to propagate it to
1239             --  the caller and do not want to stop this task.
1240
1241             when Program_Error =>
1242                null;
1243
1244             when others =>
1245                pragma Assert (False);
1246                null;
1247          end;
1248       end loop;
1249    end Interrupt_Manager;
1250
1251    -----------------
1252    -- Server_Task --
1253    -----------------
1254
1255    task body Server_Task is
1256       Intwait_Mask    : aliased IMNG.Interrupt_Mask;
1257       Ret_Interrupt   : Interrupt_ID;
1258       Self_ID         : constant Task_Id := Self;
1259       Tmp_Handler     : Parameterless_Handler;
1260       Tmp_ID          : Task_Id;
1261       Tmp_Entry_Index : Task_Entry_Index;
1262
1263    begin
1264       --  By making this task independent of master, when the process
1265       --  goes away, the Server_Task will terminate gracefully.
1266
1267       System.Tasking.Utilities.Make_Independent;
1268
1269       --  Install default action in system level
1270
1271       IMOP.Install_Default_Action (IMNG.Interrupt_ID (Interrupt));
1272
1273       --  Note: All tasks in RTS will have all the Reserve Interrupts being
1274       --  masked (except the Interrupt_Manager) and Keep_Unmasked unmasked when
1275       --  created.
1276
1277       --  Abort_Task_Interrupt is one of the Interrupt unmasked in all tasks.
1278       --  We mask the Interrupt in this particular task so that "sigwait" is
1279       --  possible to catch an explicitely sent Abort_Task_Interrupt from the
1280       --  Interrupt_Manager.
1281
1282       --  There are two Interrupt interrupts that this task catch through
1283       --  "sigwait." One is the Interrupt this task is designated to catch
1284       --  in order to execure user handler or entry. The other one is the
1285       --  Abort_Task_Interrupt. This interrupt is being sent from the
1286       --  Interrupt_Manager to inform status changes (e.g: become Blocked,
1287       --  Handler or Entry is to be detached).
1288
1289       --  Prepare a mask to used for sigwait
1290
1291       IMOP.Empty_Interrupt_Mask (Intwait_Mask'Access);
1292
1293       IMOP.Add_To_Interrupt_Mask
1294         (Intwait_Mask'Access, IMNG.Interrupt_ID (Interrupt));
1295
1296       IMOP.Add_To_Interrupt_Mask
1297         (Intwait_Mask'Access, IMNG.Abort_Task_Interrupt);
1298
1299       IMOP.Thread_Block_Interrupt
1300         (IMNG.Abort_Task_Interrupt);
1301
1302       PIO.Set_Interrupt_ID (IMNG.Interrupt_ID (Interrupt), Self_ID);
1303
1304       loop
1305          System.Tasking.Initialization.Defer_Abort (Self_ID);
1306
1307          if Single_Lock then
1308             POP.Lock_RTS;
1309          end if;
1310
1311          POP.Write_Lock (Self_ID);
1312
1313          if User_Handler (Interrupt).H = null
1314            and then User_Entry (Interrupt).T = Null_Task
1315          then
1316             --  No Interrupt binding. If there is an interrupt,
1317             --  Interrupt_Manager will take default action.
1318
1319             Self_ID.Common.State := Interrupt_Server_Blocked_Interrupt_Sleep;
1320             POP.Sleep (Self_ID, Interrupt_Server_Idle_Sleep);
1321             Self_ID.Common.State := Runnable;
1322
1323          elsif Blocked (Interrupt) then
1324
1325             --  Interrupt is blocked. Stay here, so we won't catch
1326             --  the Interrupt.
1327
1328             Self_ID.Common.State := Interrupt_Server_Blocked_Interrupt_Sleep;
1329             POP.Sleep (Self_ID, Interrupt_Server_Blocked_Interrupt_Sleep);
1330             Self_ID.Common.State := Runnable;
1331
1332          else
1333             --  A Handler or an Entry is installed. At this point all tasks
1334             --  mask for the Interrupt is masked. Catch the Interrupt using
1335             --  sigwait.
1336
1337             --  This task may wake up from sigwait by receiving an interrupt
1338             --  (Abort_Task_Interrupt) from the Interrupt_Manager for unbinding
1339             --  a Procedure Handler or an Entry. Or it could be a wake up
1340             --  from status change (Unblocked -> Blocked). If that is not
1341             --  the case, we should exceute the attached Procedure or Entry.
1342
1343             Self_ID.Common.State := Interrupt_Server_Blocked_On_Event_Flag;
1344             POP.Unlock (Self_ID);
1345
1346             if Single_Lock then
1347                POP.Unlock_RTS;
1348             end if;
1349
1350             --  Avoid race condition when terminating application and
1351             --  System.Parameters.No_Abort is True.
1352
1353             if Parameters.No_Abort and then Self_ID.Pending_Action then
1354                Initialization.Do_Pending_Action (Self_ID);
1355             end if;
1356
1357             Ret_Interrupt :=
1358               Interrupt_ID (IMOP.Interrupt_Wait (Intwait_Mask'Access));
1359             Self_ID.Common.State := Runnable;
1360
1361             if Ret_Interrupt = Interrupt_ID (IMNG.Abort_Task_Interrupt) then
1362
1363                --  Inform the Interrupt_Manager of wakeup from above sigwait
1364
1365                POP.Abort_Task (Interrupt_Manager_ID);
1366
1367                if Single_Lock then
1368                   POP.Lock_RTS;
1369                end if;
1370
1371                POP.Write_Lock (Self_ID);
1372
1373             else
1374                if Single_Lock then
1375                   POP.Lock_RTS;
1376                end if;
1377
1378                POP.Write_Lock (Self_ID);
1379
1380                if Ret_Interrupt /= Interrupt then
1381
1382                   --  On some systems (e.g. recent linux kernels), sigwait
1383                   --  may return unexpectedly (with errno set to EINTR).
1384
1385                   null;
1386
1387                else
1388                   --  Even though we have received an Interrupt the status may
1389                   --  have changed already before we got the Self_ID lock above
1390                   --  Therefore we make sure a Handler or an Entry is still
1391                   --  there and make appropriate call.
1392
1393                   --  If there is no calls to make we need to regenerate the
1394                   --  Interrupt in order not to lose it.
1395
1396                   if User_Handler (Interrupt).H /= null then
1397                      Tmp_Handler := User_Handler (Interrupt).H;
1398
1399                      --  RTS calls should not be made with self being locked
1400
1401                      POP.Unlock (Self_ID);
1402
1403                      if Single_Lock then
1404                         POP.Unlock_RTS;
1405                      end if;
1406
1407                      Tmp_Handler.all;
1408
1409                      if Single_Lock then
1410                         POP.Lock_RTS;
1411                      end if;
1412
1413                      POP.Write_Lock (Self_ID);
1414
1415                   elsif User_Entry (Interrupt).T /= Null_Task then
1416                      Tmp_ID := User_Entry (Interrupt).T;
1417                      Tmp_Entry_Index := User_Entry (Interrupt).E;
1418
1419                      --  RTS calls should not be made with self being locked
1420
1421                      if Single_Lock then
1422                         POP.Unlock_RTS;
1423                      end if;
1424
1425                      POP.Unlock (Self_ID);
1426
1427                      System.Tasking.Rendezvous.Call_Simple
1428                        (Tmp_ID, Tmp_Entry_Index, System.Null_Address);
1429
1430                      POP.Write_Lock (Self_ID);
1431
1432                      if Single_Lock then
1433                         POP.Lock_RTS;
1434                      end if;
1435
1436                   else
1437                      --  This is a situation that this task wakes up receiving
1438                      --  an Interrupt and before it gets the lock the Interrupt
1439                      --  is blocked. We do not want to lose the interrupt in
1440                      --  this case so we regenerate the Interrupt to process
1441                      --  level.
1442
1443                      IMOP.Interrupt_Self_Process
1444                        (IMNG.Interrupt_ID (Interrupt));
1445                   end if;
1446                end if;
1447             end if;
1448          end if;
1449
1450          POP.Unlock (Self_ID);
1451
1452          if Single_Lock then
1453             POP.Unlock_RTS;
1454          end if;
1455
1456          System.Tasking.Initialization.Undefer_Abort (Self_ID);
1457
1458          if Self_ID.Pending_Action then
1459             Initialization.Do_Pending_Action (Self_ID);
1460          end if;
1461
1462          --  Undefer abort here to allow a window for this task to be aborted
1463          --  at the time of system shutdown. We also explicitely test for
1464          --  Pending_Action in case System.Parameters.No_Abort is True.
1465
1466       end loop;
1467    end Server_Task;
1468
1469 --  Elaboration code for package System.Interrupts
1470
1471 begin
1472    --  Get Interrupt_Manager's ID so that Abort_Interrupt can be sent
1473
1474    Interrupt_Manager_ID := To_System (Interrupt_Manager'Identity);
1475
1476    --  During the elaboration of this package body we want the RTS
1477    --  to inherit the interrupt mask from the Environment Task.
1478
1479    IMOP.Setup_Interrupt_Mask;
1480
1481    --  The environment task should have gotten its mask from the enclosing
1482    --  process during the RTS start up. (See processing in s-inmaop.adb). Pass
1483    --  the Interrupt_Mask of the environment task to the Interrupt_Manager.
1484
1485    --  Note: At this point we know that all tasks are masked for non-reserved
1486    --  signals. Only the Interrupt_Manager will have masks set up differently
1487    --  inheriting the original environment task's mask.
1488
1489    Interrupt_Manager.Initialize (IMOP.Environment_Mask);
1490 end System.Interrupts;