libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.59)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/ios.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # For libtool versioning info, format is CURRENT:REVISION:AGE
  15 libtool_VERSION=6:9:0
  16 AC_SUBST(libtool_VERSION)
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  22 #
  23 # You will slowly go insane if you do not grok the following fact:  when
  24 # building v3 as part of the compiler, the top-level /target/ becomes the
  25 # library's /host/.  configure then causes --target to default to --host,
  26 # exactly like any other package using autoconf.  Therefore, 'target' and
  27 # 'host' will always be the same.  This makes sense both for native and
  28 # cross compilers, just think about it for a little while.  :-)
  29 #
  30 # Also, if v3 is being configured as part of a cross compiler, the top-level
  31 # configure script will pass the "real" host as $with_cross_host.
  32 #
  33 # Do not delete or change the following two lines.  For why, see
  34 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  35 AC_CANONICAL_SYSTEM
  36 target_alias=${target_alias-$host_alias}
  37
  38 # Handy for debugging:
  39 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  40
  41 if test "$build" != "$host"; then
  42   # We are being configured with some form of cross compiler.
  43   GLIBCXX_IS_NATIVE=false
  44   case "$host","$target" in
  45     # Darwin crosses can use the host system's libraries and headers,
  46     # because of the fat library support.  Of course, it must be the
  47     # same version of Darwin on both sides.  Allow the user to
  48     # just say --target=foo-darwin without a version number to mean
  49     # "the version on this system".
  50       *-*-darwin*,*-*-darwin*)
  51         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  52         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  53         if test $hostos = $targetos -o $targetos = darwin ; then
  54           GLIBCXX_IS_NATIVE=true
  55         fi
  56         ;;
  57
  58       *)
  59         GCC_NO_EXECUTABLES
  60         ;;
  61   esac
  62 else
  63   GLIBCXX_IS_NATIVE=true
  64 fi
  65
  66 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  67 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  68 #  1.x:  minimum required version
  69 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  70 #              of other PACKAGE_* variables will, however, and there's nothing
  71 #              we can do about that; they come from AC_INIT).
  72 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  73 #            file in the top srcdir, etc, etc), so stop complaining.
  74 #  no-dependencies:  turns off auto dependency generation (just for now)
  75 #  -Wall:  turns on all automake warnings...
  76 #  -Wno-portability:  ...except this one, since GNU make is now required.
  77 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies -Wall -Wno-portability -Wno-override])
  78 AH_TEMPLATE(PACKAGE, [Name of package])
  79 AH_TEMPLATE(VERSION, [Version number of package])
  80
  81 # Runs configure.host, finds CC, CXX, and assorted other critical bits.  Sets
  82 # up critical shell variables.
  83 GLIBCXX_CONFIGURE
  84
  85 AC_LIBTOOL_DLOPEN
  86 AM_PROG_LIBTOOL
  87 AC_SUBST(enable_shared)
  88 AC_SUBST(enable_static)
  89
  90 # Possibly disable most of the library.
  91 ## TODO: Consider skipping unncessary tests altogether in this case, rather
  92 ## than just ignoring the results.  Faster /and/ more correct, win win.
  93 GLIBCXX_ENABLE_HOSTED
  94
  95 # Check for compiler support that doesn't require linking.
  96 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
  97 GLIBCXX_ENABLE_PCH($is_hosted)
  98
  99 # Enable all the variable C++ runtime options.
 100 GLIBCXX_ENABLE_CSTDIO
 101 GLIBCXX_ENABLE_CLOCALE
 102 GLIBCXX_ENABLE_ALLOCATOR
 103 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 104 GLIBCXX_ENABLE_LONG_LONG([yes])
 105 GLIBCXX_ENABLE_WCHAR_T([yes])
 106 GLIBCXX_ENABLE_C99([yes])
 107 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 108 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
 109 GLIBCXX_ENABLE_DEBUG([no])
 110 GLIBCXX_ENABLE_CXX_FLAGS
 111 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 112
 113 # No surprises, no surprises...
 114 GLIBCXX_ENABLE_THREADS
 115 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 116 if test $atomicity_dir = cpu/generic/atomic_mutex ; then
 117   AC_MSG_WARN([No native atomic operations are provided for this platform.])
 118   if test $target_thread_file = single; then
 119     AC_MSG_WARN([They cannot be faked when thread support is disabled.])
 120     AC_MSG_WARN([Thread-safety of certain classes is not guaranteed.])
 121   else
 122     AC_MSG_WARN([They will be faked using a mutex.])
 123     AC_MSG_WARN([Performance of certain classes will degrade as a result.])
 124   fi
 125 fi
 126
 127 GLIBCXX_CHECK_COMPILER_FEATURES
 128
 129 if $GLIBCXX_IS_NATIVE; then
 130
 131   # We can do more elaborate tests that assume a working linker.
 132   CANADIAN=no
 133
 134   # Check for available headers.
 135   AC_CHECK_HEADERS([nan.h ieeefp.h endian.h sys/isa_defs.h machine/endian.h \
 136   machine/param.h sys/machine.h fp.h locale.h float.h inttypes.h gconv.h \
 137   sys/types.h sys/ipc.h sys/sem.h])
 138
 139   GLIBCXX_CHECK_LINKER_FEATURES
 140   GLIBCXX_CHECK_MATH_SUPPORT
 141   GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 142   GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT
 143   GLIBCXX_CHECK_ICONV_SUPPORT
 144   GLIBCXX_CHECK_STDLIB_SUPPORT
 145
 146   # For showmanyc_helper().
 147   AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 148   GLIBCXX_CHECK_POLL
 149   GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 150
 151   # For xsputn_2().
 152   AC_CHECK_HEADERS(sys/uio.h)
 153   GLIBCXX_CHECK_WRITEV
 154
 155   # For the __streamoff_base_type typedef.
 156   GLIBCXX_CHECK_INT64_T
 157
 158   # For LFS support.
 159   GLIBCXX_CHECK_LFS
 160
 161   # For C99 support to TR1.
 162   GLIBCXX_CHECK_C99_TR1
 163
 164   # For dev/random and dev/urandom for TR1.
 165   GLIBCXX_CHECK_RANDOM_TR1
 166
 167   # For TLS support.
 168   GCC_CHECK_TLS
 169
 170   # For _Unwind_GetIPInfo.
 171   GCC_CHECK_UNWIND_GETIPINFO
 172
 173   AC_LC_MESSAGES
 174
 175   AC_TRY_COMPILE(
 176     [#include <setjmp.h>],
 177     [sigjmp_buf env;
 178      while (! sigsetjmp (env, 1))
 179        siglongjmp (env, 1);
 180     ],
 181     [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available.])])
 182
 183   AC_FUNC_MMAP
 184
 185 else
 186
 187   # This lets us hard-code the functionality we know we'll have in the cross
 188   # target environment.  "Let" is a sugar-coated word placed on an especially
 189   # dull and tedious hack, actually.
 190   #
 191   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 192   # that involve linking, can't be used:
 193   #    "cannot open sim-crt0.o"
 194   #    "cannot open crt0.o"
 195   # etc.  All this is because there currently exists no unified, consistent
 196   # way for top level CC information to be passed down to target directories:
 197   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 198   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 199   # crosses can be removed.
 200
 201   # If Canadian cross, then don't pick up tools from the build directory.
 202   # Used only in GLIBCXX_EXPORT_INCLUDES.
 203   if test -n "$with_cross_host" &&
 204      test x"$build_alias" != x"$with_cross_host" &&
 205      test x"$build" != x"$target";
 206   then
 207     CANADIAN=yes
 208   else
 209     CANADIAN=no
 210   fi
 211
 212   # Construct crosses by hand, eliminating bits that need ld...
 213   # GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 214   # GLIBCXX_CHECK_MATH_SUPPORT
 215
 216   # First, test for "known" system libraries.  We may be using newlib even
 217   # on a hosted environment.
 218   if test "x${with_newlib}" = "xyes"; then
 219     os_include_dir="os/newlib"
 220     AC_DEFINE(HAVE_HYPOT)
 221
 222     # GLIBCXX_CHECK_STDLIB_SUPPORT
 223     AC_DEFINE(HAVE_STRTOF)
 224     # AC_FUNC_MMAP
 225     AC_DEFINE(HAVE_MMAP)
 226
 227     AC_DEFINE(HAVE_ACOSF)
 228     AC_DEFINE(HAVE_ASINF)
 229     AC_DEFINE(HAVE_ATAN2F)
 230     AC_DEFINE(HAVE_ATANF)
 231     AC_DEFINE(HAVE_CEILF)
 232     AC_DEFINE(HAVE_COPYSIGN)
 233     AC_DEFINE(HAVE_COPYSIGNF)
 234     AC_DEFINE(HAVE_COSF)
 235     AC_DEFINE(HAVE_COSHF)
 236     AC_DEFINE(HAVE_EXPF)
 237     AC_DEFINE(HAVE_FABSF)
 238     AC_DEFINE(HAVE_FLOORF)
 239     AC_DEFINE(HAVE_FMODF)
 240     AC_DEFINE(HAVE_FREXPF)
 241     AC_DEFINE(HAVE_LDEXPF)
 242     AC_DEFINE(HAVE_LOG10F)
 243     AC_DEFINE(HAVE_LOGF)
 244     AC_DEFINE(HAVE_MODFF)
 245     AC_DEFINE(HAVE_POWF)
 246     AC_DEFINE(HAVE_SINF)
 247     AC_DEFINE(HAVE_SINHF)
 248     AC_DEFINE(HAVE_SQRTF)
 249     AC_DEFINE(HAVE_TANF)
 250     AC_DEFINE(HAVE_TANHF)
 251
 252     AC_DEFINE(HAVE_S_ISREG)
 253     AC_DEFINE(HAVE_S_IFREG)
 254   else
 255     GLIBCXX_CROSSCONFIG
 256   fi
 257
 258   # At some point, we should differentiate between architectures
 259   # like x86, which have long double versions, and alpha/powerpc/etc.,
 260   # which don't. For the time being, punt.
 261   if test x"long_double_math_on_this_cpu" = x"yes"; then
 262     AC_DEFINE(HAVE_ACOSL)
 263     AC_DEFINE(HAVE_ASINL)
 264     AC_DEFINE(HAVE_ATAN2L)
 265     AC_DEFINE(HAVE_ATANL)
 266     AC_DEFINE(HAVE_CEILL)
 267     AC_DEFINE(HAVE_COPYSIGNL)
 268     AC_DEFINE(HAVE_COSL)
 269     AC_DEFINE(HAVE_COSHL)
 270     AC_DEFINE(HAVE_EXPL)
 271     AC_DEFINE(HAVE_FABSL)
 272     AC_DEFINE(HAVE_FLOORL)
 273     AC_DEFINE(HAVE_FMODL)
 274     AC_DEFINE(HAVE_FREXPL)
 275     AC_DEFINE(HAVE_LDEXPL)
 276     AC_DEFINE(HAVE_LOG10L)
 277     AC_DEFINE(HAVE_LOGL)
 278     AC_DEFINE(HAVE_MODFL)
 279     AC_DEFINE(HAVE_POWL)
 280     AC_DEFINE(HAVE_SINCOSL)
 281     AC_DEFINE(HAVE_SINL)
 282     AC_DEFINE(HAVE_SINHL)
 283     AC_DEFINE(HAVE_SQRTL)
 284     AC_DEFINE(HAVE_TANL)
 285     AC_DEFINE(HAVE_TANHL)
 286   fi
 287
 288   # Assume we have _Unwind_GetIPInfo for cross-compiles.
 289   AC_DEFINE(HAVE_GETIPINFO)
 290
 291 fi
 292
 293 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
 294 GLIBCXX_ENABLE_SYMVERS([yes])
 295 GLIBCXX_ENABLE_VISIBILITY([yes])
 296
 297 ac_ldbl_compat=no
 298 case "$target" in
 299   powerpc*-*-*gnu* | \
 300   sparc*-*-linux* | \
 301   s390*-*-linux* | \
 302   alpha*-*-linux*)
 303   AC_TRY_COMPILE(, [
 304 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 305 #error no need for long double compatibility
 306 #endif
 307   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 308   if test "$ac_ldbl_compat" = yes; then
 309     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 310               [Define if compatibility should be provided for -mlong-double-64.])
 311     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 312   fi
 313 esac
 314 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 315
 316 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 317 GLIBCXX_CONFIGURE_TESTSUITE
 318
 319 # Propagate the target-specific source directories through the build chain.
 320 ATOMICITY_SRCDIR=config/${atomicity_dir}
 321 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 322 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 323 OS_INC_SRCDIR=config/${os_include_dir}
 324 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 325 AC_SUBST(ATOMICITY_SRCDIR)
 326 AC_SUBST(ATOMIC_WORD_SRCDIR)
 327 AC_SUBST(CPU_DEFINES_SRCDIR)
 328 AC_SUBST(ABI_TWEAKS_SRCDIR)
 329 AC_SUBST(OS_INC_SRCDIR)
 330
 331
 332 # Determine cross-compile flags and AM_CONDITIONALs.
 333 #AC_SUBST(GLIBCXX_IS_NATIVE)
 334 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 335 # from GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT:
 336 #AM_CONDITIONAL(GLIBCXX_BUILD_LIBMATH,  test $need_libmath = yes)
 337 GLIBCXX_EVALUATE_CONDITIONALS
 338
 339 AC_CACHE_SAVE
 340
 341 if test ${multilib} = yes; then
 342   multilib_arg="--enable-multilib"
 343 else
 344   multilib_arg=
 345 fi
 346
 347 # Export all the install information.
 348 GLIBCXX_EXPORT_INSTALL_INFO
 349
 350 # Export all the include and flag information to Makefiles.
 351 GLIBCXX_EXPORT_INCLUDES
 352 GLIBCXX_EXPORT_FLAGS
 353
 354 if ${CONFIG_SHELL-/bin/sh} ./libtool --tag CXX --features |
 355    grep "enable shared" > /dev/null;
 356 then
 357   LIBSUPCXX_PICFLAGS=-prefer-pic
 358 else
 359   LIBSUPCXX_PICFLAGS=
 360 fi
 361 AC_SUBST(LIBSUPCXX_PICFLAGS)
 362
 363 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 364 dnl which can all be called multiple times as needed, plus one (different)
 365 dnl AC_OUTPUT macro.  This one lists the files to be created:
 366 AC_CONFIG_FILES( \
 367   Makefile \
 368   AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ])
 369   )
 370 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 371
 372 dnl These commands are run at the end of config.status:
 373 AC_CONFIG_COMMANDS([default],
 374 [if test -n "$CONFIG_FILES"; then
 375    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 376    # that multilib installs will end up installed in the correct place.
 377    # The testsuite needs it for multilib-aware ABI baseline files.
 378    # To work around this not being passed down from config-ml.in ->
 379    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 380    # append it here.  Only modify Makefiles that have just been created.
 381    #
 382    # Also, get rid of this simulated-VPATH thing that automake does.
 383    cat > vpsed << \_EOF
 384 s!`test -f '$<' || echo '$(srcdir)/'`!!
 385 _EOF
 386    for i in $SUBDIRS; do
 387     case $CONFIG_FILES in
 388      *${i}/Makefile*)
 389        #echo "Adding MULTISUBDIR to $i/Makefile"
 390        sed -f vpsed $i/Makefile > tmp
 391        grep '^MULTISUBDIR =' Makefile >> tmp
 392        mv tmp $i/Makefile
 393        ;;
 394     esac
 395    done
 396    rm vpsed
 397  fi
 398  (cd include && ${MAKE-make})
 399 ],
 400 [
 401 # Variables needed in config.status (file generation) which aren't already
 402 # passed by autoconf.
 403 SUBDIRS="$SUBDIRS"
 404 ])
 405
 406 dnl And this actually makes things happen:
 407 AC_OUTPUT