libstdc++-v3/aclocal.m4

   1 dnl aclocal.m4 generated automatically by aclocal 1.4
   2
   3 dnl Copyright (C) 1994, 1995-8, 1999 Free Software Foundation, Inc.
   4 dnl This file is free software; the Free Software Foundation
   5 dnl gives unlimited permission to copy and/or distribute it,
   6 dnl with or without modifications, as long as this notice is preserved.
   7
   8 dnl This program is distributed in the hope that it will be useful,
   9 dnl but WITHOUT ANY WARRANTY, to the extent permitted by law; without
  10 dnl even the implied warranty of MERCHANTABILITY or FITNESS FOR A
  11 dnl PARTICULAR PURPOSE.
  12
  13 dnl
  14 dnl Initialize configure bits.
  15 dnl
  16 dnl Define OPTLEVEL='-O2' if new inlining code present.
  17 dnl
  18 dnl GLIBCPP_CONFIGURE
  19 AC_DEFUN(GLIBCPP_CONFIGURE, [
  20   dnl Default to --enable-multilib
  21   AC_ARG_ENABLE(multilib,
  22   [  --enable-multilib       build hella library versions (default)],
  23   [case "${enableval}" in
  24     yes) multilib=yes ;;
  25     no)  multilib=no ;;
  26     *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  27    esac], [multilib=yes])dnl
  28
  29   glibcpp_basedir=$auxdir/$1/libstdc++-v3
  30   AC_SUBST(glibcpp_basedir)
  31
  32   AM_INIT_AUTOMAKE(libstdc++, 2.92)
  33
  34   # Never versions of autoconf add an underscore to these functions.
  35   # Prevent future problems ...
  36   ifdef([AC_PROG_CC_G],[],[define([AC_PROG_CC_G],defn([_AC_PROG_CC_G]))])
  37   ifdef([AC_PROG_CC_GNU],[],[define([AC_PROG_CC_GNU],defn([_AC_PROG_CC_GNU]))])
  38   ifdef([AC_PROG_CXX_G],[],[define([AC_PROG_CXX_G],defn([_AC_PROG_CXX_G]))])
  39   ifdef([AC_PROG_CXX_GNU],[],[define([AC_PROG_CXX_GNU],defn([_AC_PROG_CXX_GNU]))])
  40
  41 #  AC_PROG_CC
  42
  43 # FIXME: We temporarily define our own version of AC_PROG_CC.  This is
  44 # copied from autoconf 2.12, but does not call AC_PROG_CC_WORKS.  We
  45 # are probably using a cross compiler, which will not be able to fully
  46 # link an executable.  This should really be fixed in autoconf
  47 # itself.
  48
  49 AC_DEFUN(LIB_AC_PROG_CC,
  50 [AC_BEFORE([$0], [AC_PROG_CPP])dnl
  51 dnl Fool anybody using AC_PROG_CC.
  52 AC_PROVIDE([AC_PROG_CC])
  53 AC_CHECK_PROG(CC, gcc, gcc)
  54 if test -z "$CC"; then
  55   AC_CHECK_PROG(CC, cc, cc, , , /usr/ucb/cc)
  56   test -z "$CC" && AC_MSG_ERROR([no acceptable cc found in \$PATH])
  57 fi
  58
  59 AC_PROG_CC_GNU
  60
  61 if test $ac_cv_prog_gcc = yes; then
  62   GCC=yes
  63 dnl Check whether -g works, even if CFLAGS is set, in case the package
  64 dnl plays around with CFLAGS (such as to build both debugging and
  65 dnl normal versions of a library), tasteless as that idea is.
  66   ac_test_CFLAGS="${CFLAGS+set}"
  67   ac_save_CFLAGS="$CFLAGS"
  68   CFLAGS=
  69   AC_PROG_CC_G
  70   if test "$ac_test_CFLAGS" = set; then
  71     CFLAGS="$ac_save_CFLAGS"
  72   elif test $ac_cv_prog_cc_g = yes; then
  73     CFLAGS="-g -O2"
  74   else
  75     CFLAGS="-O2"
  76   fi
  77 else
  78   GCC=
  79   test "${CFLAGS+set}" = set || CFLAGS="-g"
  80 fi
  81 ])
  82
  83 LIB_AC_PROG_CC
  84
  85 # Can't just call these here as g++ requires libstc++ to be built....
  86 #  AC_PROG_CXX
  87
  88 # Likewise for AC_PROG_CXX.
  89 AC_DEFUN(LIB_AC_PROG_CXX,
  90 [AC_BEFORE([$0], [AC_PROG_CXXCPP])dnl
  91 dnl Fool anybody using AC_PROG_CXX.
  92 AC_PROVIDE([AC_PROG_CXX])
  93 # Use glibcpp_CXX so that we do not cause CXX to be cached with the
  94 # flags that come in CXX while configuring libstdc++.  They're different
  95 # from those used for all other target libraries.  If CXX is set in
  96 # the environment, respect that here.
  97 glibcpp_CXX=$CXX
  98 AC_CHECK_PROGS(glibcpp_CXX, $CCC c++ g++ gcc CC cxx cc++, gcc)
  99 AC_SUBST(glibcpp_CXX)
 100 CXX=$glibcpp_CXX
 101 test -z "$glibcpp_CXX" && AC_MSG_ERROR([no acceptable c++ found in \$PATH])
 102
 103 AC_PROG_CXX_GNU
 104
 105 if test $ac_cv_prog_gxx = yes; then
 106   GXX=yes
 107 dnl Check whether -g works, even if CXXFLAGS is set, in case the package
 108 dnl plays around with CXXFLAGS (such as to build both debugging and
 109 dnl normal versions of a library), tasteless as that idea is.
 110   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 111   ac_save_CXXFLAGS="$CXXFLAGS"
 112   CXXFLAGS=
 113   AC_PROG_CXX_G
 114   if test "$ac_test_CXXFLAGS" = set; then
 115     CXXFLAGS="$ac_save_CXXFLAGS"
 116   elif test $ac_cv_prog_cxx_g = yes; then
 117     CXXFLAGS="-g -O2"
 118   else
 119     CXXFLAGS="-O2"
 120   fi
 121 else
 122   GXX=
 123   test "${CXXFLAGS+set}" = set || CXXFLAGS="-g"
 124 fi
 125 ])
 126
 127 LIB_AC_PROG_CXX
 128
 129   AC_CHECK_TOOL(AS, as)
 130   AC_CHECK_TOOL(AR, ar)
 131   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 132   AC_PROG_INSTALL
 133
 134   AM_MAINTAINER_MODE
 135
 136   # We need AC_EXEEXT to keep automake happy in cygnus mode.  However,
 137   # at least currently, we never actually build a program, so we never
 138   # need to use $(EXEEXT).  Moreover, the test for EXEEXT normally
 139   # fails, because we are probably configuring with a cross compiler
 140   # which cant create executables.  So we include AC_EXEEXT to keep
 141   # automake happy, but we dont execute it, since we dont care about
 142   # the result.
 143   if false; then
 144     AC_EXEEXT
 145   fi
 146
 147   . [$]{glibcpp_basedir}/configure.host
 148
 149   case [$]{glibcpp_basedir} in
 150     /* | [A-Za-z]:[\\/]*) libgcj_flagbasedir=[$]{glibcpp_basedir} ;;
 151     *) glibcpp_flagbasedir='[$](top_builddir)/'[$]{glibcpp_basedir} ;;
 152   esac
 153
 154   # This does for the target what configure.host does for the host.  In
 155   # addition to possibly modifying the same flags, it also sets up symlinks.
 156   GLIBCPP_CHECK_TARGET
 157 ])
 158
 159
 160 dnl
 161 dnl Check to see if g++ can compile this library, and if so, if any version-
 162 dnl specific precautions need to be taken.
 163 dnl
 164 dnl GLIBCPP_CHECK_COMPILER_VERSION
 165 AC_DEFUN(GLIBCPP_CHECK_COMPILER_VERSION, [
 166 if test ! -f stamp-sanity-compiler; then
 167   AC_MSG_CHECKING([for g++ that will successfully compile libstdc++-v3])
 168   AC_LANG_SAVE
 169   AC_LANG_CPLUSPLUS
 170   AC_EGREP_CPP(ok, [
 171   #if __GNUC__ >= 3
 172     ok
 173   #endif
 174   ], gpp_satisfactory=yes, AC_MSG_ERROR([please upgrade to GCC 3.0 or above]))
 175   AC_LANG_RESTORE
 176   AC_MSG_RESULT($gpp_satisfactory)
 177   touch stamp-sanity-compiler
 178 fi
 179 ])
 180
 181
 182 dnl
 183 dnl Test for newer compiler features, or features that are present in newer
 184 dnl compiler version but not older compiler versions should be placed
 185 dnl here.
 186 dnl
 187 dnl Define WERROR='-Werror' if requested and possible; g++'s that lack the
 188 dnl new inlining code or the new system_header pragma will die on -Werror.
 189 dnl Leave it out by default and use maint-mode to use it.
 190 dnl
 191 dnl Define SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 192 dnl compiler supports it and the user has not requested debug mode.
 193 dnl
 194 dnl GLIBCPP_CHECK_COMPILER_FEATURES
 195 AC_DEFUN(GLIBCPP_CHECK_COMPILER_FEATURES, [
 196   # All these tests are for C++; save the language and the compiler flags.
 197   # The CXXFLAGS thing is suspicious, but based on similar bits
 198   # found in GLIBCPP_CONFIGURE.
 199   AC_LANG_SAVE
 200   AC_LANG_CPLUSPLUS
 201   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 202   ac_save_CXXFLAGS="$CXXFLAGS"
 203
 204   # Check for maintainer-mode bits.
 205   if test x"$USE_MAINTAINER_MODE" = xno; then
 206     WERROR=''
 207   else
 208     WERROR='-Werror'
 209   fi
 210
 211   # Check for -ffunction-sections -fdata-sections
 212   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 213   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 214   AC_TRY_COMPILE(, [int foo;
 215   ], [ac_fdsections=yes], [ac_fdsections=no])
 216   if test "$ac_test_CXXFLAGS" = set; then
 217     CXXFLAGS="$ac_save_CXXFLAGS"
 218   else
 219     # this is the suspicious part
 220     CXXFLAGS=''
 221   fi
 222   if test x"$ac_fdsections" = x"yes" && test x"$enable_debug" = x"no"; then
 223     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 224   fi
 225   AC_MSG_RESULT($ac_fdsections)
 226
 227   AC_LANG_RESTORE
 228   AC_SUBST(WERROR)
 229   AC_SUBST(SECTION_FLAGS)
 230 ])
 231
 232
 233 dnl
 234 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 235 dnl the native linker is in use, all variables will be defined to something
 236 dnl safe (like an empty string).
 237 dnl
 238 dnl Define SECTION_LDFLAGS='-Wl,--gc-sections' if possible.
 239 dnl Define OPT_LDFLAGS='-Wl,-O1' if possible.
 240 dnl
 241 dnl GLIBCPP_CHECK_LINKER_FEATURES
 242 AC_DEFUN(GLIBCPP_CHECK_LINKER_FEATURES, [
 243   # If we're not using GNU ld, then there's no point in even trying these
 244   # tests.  Check for that first.  We should have already tested for gld
 245   # by now (in libtool), but require it now just to be safe...
 246   SECTION_LDFLAGS=''
 247   OPT_LDFLAGS=''
 248   AC_REQUIRE([AC_PROG_LD])
 249
 250   # Set --gc-sections.
 251   if test "$ac_cv_prog_gnu_ld" = "notbroken"; then
 252     # GNU ld it is!  Joy and bunny rabbits!
 253
 254     # All these tests are for C++; save the language and the compiler flags.
 255     # Need to do this so that g++ won't try to link in libstdc++
 256     ac_test_CFLAGS="${CFLAGS+set}"
 257     ac_save_CFLAGS="$CFLAGS"
 258     CFLAGS='-x c++  -Wl,--gc-sections'
 259
 260     # Check for -Wl,--gc-sections
 261     # XXX This test is broken at the moment, as symbols required for
 262     # linking are now in libsupc++ (not built yet.....). In addition,
 263     # this test has cored on solaris in the past. In addition,
 264     # --gc-sections doesn't really work at the moment (keeps on discarding
 265     # used sections, first .eh_frame and now some of the glibc sections for
 266     # iconv). Bzzzzt. Thanks for playing, maybe next time.
 267     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 268     AC_TRY_RUN([
 269      int main(void)
 270      {
 271        try { throw 1; }
 272        catch (...) { };
 273        return 0;
 274      }
 275     ], [ac_sectionLDflags=yes],[ac_sectionLFflags=no], [ac_sectionLDflags=yes])
 276     if test "$ac_test_CFLAGS" = set; then
 277       CFLAGS="$ac_save_CFLAGS"
 278     else
 279       # this is the suspicious part
 280       CFLAGS=''
 281     fi
 282     if test "$ac_sectionLDflags" = "yes"; then
 283       SECTION_LDFLAGS='-Wl,--gc-sections'
 284     fi
 285     AC_MSG_RESULT($ac_sectionLDflags)
 286   fi
 287
 288   # Set linker optimization flags.
 289   if test x"$ac_cv_prog_gnu_ld" = x"yes" && test x"$enable_debug" = x"no"; then
 290     OPT_LDFLAGS='-Wl,-O1'
 291   fi
 292
 293   AC_SUBST(SECTION_LDFLAGS)
 294   AC_SUBST(OPT_LDFLAGS)
 295 ])
 296
 297
 298 dnl
 299 dnl Check to see if the (math function) argument passed is
 300 dnl declared when using the c++ compiler
 301 dnl ASSUMES argument is a math function with ONE parameter
 302 dnl
 303 dnl GLIBCPP_CHECK_MATH_DECL_1
 304 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_1, [
 305   AC_MSG_CHECKING([for $1 declaration])
 306   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 307     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 308       AC_LANG_SAVE
 309       AC_LANG_CPLUSPLUS
 310       AC_TRY_COMPILE([#include <math.h>
 311                       #ifdef HAVE_IEEEFP_H
 312                       #include <ieeefp.h>
 313                       #endif
 314                      ],
 315                      [ $1(0);],
 316                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 317       AC_LANG_RESTORE
 318     ])
 319   fi
 320   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 321 ])
 322
 323 dnl
 324 dnl Check to see if the (math function) argument passed is
 325 dnl 1) declared when using the c++ compiler
 326 dnl 2) has "C" linkage
 327 dnl 3) if not, see if 1) and 2) for argument prepended with '_'
 328 dnl
 329 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 330 dnl
 331 dnl argument 1 is name of function to check
 332 dnl
 333 dnl ASSUMES argument is a math function with ONE parameter
 334 dnl
 335 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1
 336 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1, [
 337   GLIBCPP_CHECK_MATH_DECL_1($1)
 338   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 339     AC_CHECK_FUNCS($1)
 340   else
 341     GLIBCPP_CHECK_MATH_DECL_1(_$1)
 342     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 343       AC_CHECK_FUNCS(_$1)
 344     fi
 345   fi
 346 ])
 347
 348
 349 dnl
 350 dnl Like GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1, but does a bunch of
 351 dnl of functions at once.  It's an all-or-nothing check -- either
 352 dnl HAVE_XYZ is defined for each of the functions, or for none of them.
 353 dnl Doing it this way saves significant configure time.
 354 AC_DEFUN(GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1, [
 355   AC_MSG_CHECKING([for $1 functions])
 356   AC_CACHE_VAL(glibcpp_cv_func_$2_use, [
 357     AC_LANG_SAVE
 358     AC_LANG_CPLUSPLUS
 359     AC_TRY_COMPILE([#include <math.h>],
 360                    [ `for x in $3; do echo "$x (0);"; done` ],
 361                    [glibcpp_cv_func_$2_use=yes],
 362                    [glibcpp_cv_func_$2_use=no])
 363     AC_LANG_RESTORE])
 364   AC_MSG_RESULT($glibcpp_cv_func_$2_use)
 365   if test x$glibcpp_cv_func_$2_use = x"yes"; then
 366     AC_CHECK_FUNCS($3)
 367   fi
 368 ])
 369
 370 dnl
 371 dnl Check to see if the (math function) argument passed is
 372 dnl declared when using the c++ compiler
 373 dnl ASSUMES argument is a math function with ONE parameter
 374 dnl
 375 dnl GLIBCPP_CHECK_MATH_DECL_2
 376 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_2, [
 377   AC_MSG_CHECKING([for $1 declaration])
 378   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 379     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 380       AC_LANG_SAVE
 381       AC_LANG_CPLUSPLUS
 382       AC_TRY_COMPILE([#include <math.h>],
 383                      [ $1(0, 0);],
 384                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 385       AC_LANG_RESTORE
 386     ])
 387   fi
 388   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 389 ])
 390
 391 dnl
 392 dnl Check to see if the (math function) argument passed is
 393 dnl 1) declared when using the c++ compiler
 394 dnl 2) has "C" linkage
 395 dnl
 396 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 397 dnl
 398 dnl argument 1 is name of function to check
 399 dnl
 400 dnl ASSUMES argument is a math function with TWO parameters
 401 dnl
 402 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2
 403 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2, [
 404   GLIBCPP_CHECK_MATH_DECL_2($1)
 405   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 406     AC_CHECK_FUNCS($1)
 407   else
 408     GLIBCPP_CHECK_MATH_DECL_2(_$1)
 409     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 410       AC_CHECK_FUNCS(_$1)
 411     fi
 412   fi
 413 ])
 414
 415
 416 dnl
 417 dnl Check to see if the (math function) argument passed is
 418 dnl declared when using the c++ compiler
 419 dnl ASSUMES argument is a math function with ONE parameter
 420 dnl
 421 dnl GLIBCPP_CHECK_MATH_DECL_3
 422 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_3, [
 423   AC_MSG_CHECKING([for $1 declaration])
 424   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 425     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 426       AC_LANG_SAVE
 427       AC_LANG_CPLUSPLUS
 428       AC_TRY_COMPILE([#include <math.h>],
 429                      [ $1(0, 0, 0);],
 430                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 431       AC_LANG_RESTORE
 432     ])
 433   fi
 434   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 435 ])
 436
 437 dnl
 438 dnl Check to see if the (math function) argument passed is
 439 dnl 1) declared when using the c++ compiler
 440 dnl 2) has "C" linkage
 441 dnl
 442 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 443 dnl
 444 dnl argument 1 is name of function to check
 445 dnl
 446 dnl ASSUMES argument is a math function with THREE parameters
 447 dnl
 448 dnl GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3
 449 AC_DEFUN(GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3, [
 450   GLIBCPP_CHECK_MATH_DECL_3($1)
 451   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 452     AC_CHECK_FUNCS($1)
 453   else
 454     GLIBCPP_CHECK_MATH_DECL_3(_$1)
 455     if test x$glibcpp_cv_func__$1_use = x"yes"; then
 456       AC_CHECK_FUNCS(_$1)
 457     fi
 458   fi
 459 ])
 460
 461
 462 dnl
 463 dnl Check to see if the (stdlib function) argument passed is
 464 dnl 1) declared when using the c++ compiler
 465 dnl 2) has "C" linkage
 466 dnl
 467 dnl argument 1 is name of function to check
 468 dnl
 469 dnl ASSUMES argument is a math function with TWO parameters
 470 dnl
 471 dnl GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2
 472 AC_DEFUN(GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2, [
 473   AC_MSG_CHECKING([for $1 declaration])
 474   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 475     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 476       AC_LANG_SAVE
 477       AC_LANG_CPLUSPLUS
 478       AC_TRY_COMPILE([#include <stdlib.h>],
 479                      [ $1(0, 0);],
 480                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 481       AC_LANG_RESTORE
 482     ])
 483   fi
 484   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 485   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 486     AC_CHECK_FUNCS($1)
 487   fi
 488 ])
 489
 490
 491 dnl
 492 dnl Because the builtins are picky picky picky about the arguments they take,
 493 dnl do an explict linkage tests here.
 494 dnl Check to see if the (math function) argument passed is
 495 dnl 1) declared when using the c++ compiler
 496 dnl 2) has "C" linkage
 497 dnl
 498 dnl Define HAVE_CARGF etc if "cargf" is declared and links
 499 dnl
 500 dnl argument 1 is name of function to check
 501 dnl
 502 dnl ASSUMES argument is a math function with ONE parameter
 503 dnl
 504 dnl GLIBCPP_CHECK_BUILTIN_MATH_DECL_LINKAGE_1
 505 AC_DEFUN(GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1, [
 506   AC_MSG_CHECKING([for $1 declaration])
 507   if test x${glibcpp_cv_func_$1_use+set} != xset; then
 508     AC_CACHE_VAL(glibcpp_cv_func_$1_use, [
 509       AC_LANG_SAVE
 510       AC_LANG_CPLUSPLUS
 511       AC_TRY_COMPILE([#include <math.h>],
 512                      [ $1(0);],
 513                      [glibcpp_cv_func_$1_use=yes], [glibcpp_cv_func_$1_use=no])
 514       AC_LANG_RESTORE
 515     ])
 516   fi
 517   AC_MSG_RESULT($glibcpp_cv_func_$1_use)
 518   if test x$glibcpp_cv_func_$1_use = x"yes"; then
 519     AC_MSG_CHECKING([for $1 linkage])
 520     if test x${glibcpp_cv_func_$1_link+set} != xset; then
 521       AC_CACHE_VAL(glibcpp_cv_func_$1_link, [
 522         AC_TRY_LINK([#include <math.h>],
 523                     [ $1(0);],
 524                     [glibcpp_cv_func_$1_link=yes], [glibcpp_cv_func_$1_link=no])
 525       ])
 526     fi
 527     AC_MSG_RESULT($glibcpp_cv_func_$1_link)
 528     if test x$glibcpp_cv_func_$1_link = x"yes"; then
 529       ac_tr_func=HAVE_`echo $1 | tr 'abcdefghijklmnopqrstuvwxyz' 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'`
 530       AC_DEFINE_UNQUOTED(${ac_tr_func})
 531     fi
 532   fi
 533 ])
 534
 535
 536 dnl
 537 dnl Check to see what builtin math functions are supported
 538 dnl
 539 dnl check for __builtin_abs
 540 dnl check for __builtin_fabsf
 541 dnl check for __builtin_fabs
 542 dnl check for __builtin_fabl
 543 dnl check for __builtin_labs
 544 dnl check for __builtin_sqrtf
 545 dnl check for __builtin_sqrtl
 546 dnl check for __builtin_fsqrt
 547 dnl check for __builtin_sinf
 548 dnl check for __builtin_sin
 549 dnl check for __builtin_sinl
 550 dnl check for __builtin_cosf
 551 dnl check for __builtin_cos
 552 dnl check for __builtin_cosl
 553 dnl
 554 dnl GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT
 555 AC_DEFUN(GLIBCPP_CHECK_BUILTIN_MATH_SUPPORT, [
 556   dnl Test for builtin math functions.
 557   dnl These are made in gcc/c-common.c
 558   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_abs)
 559   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabsf)
 560   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabs)
 561   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fabsl)
 562   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_labs)
 563
 564   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrtf)
 565   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_fsqrt)
 566   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sqrtl)
 567
 568   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sinf)
 569   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sin)
 570   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_sinl)
 571
 572   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cosf)
 573   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cos)
 574   GLIBCPP_CHECK_BUILTIN_MATH_DECL_AND_LINKAGE_1(__builtin_cosl)
 575
 576   dnl There is, without a doubt, a more elegant way to have these
 577   dnl names exported so that they won't be stripped out of acconfig.h by
 578   dnl autoheader. I leave this as an exercise to somebody less frustrated
 579   dnl than I.... please email the libstdc++ list if you can figure out a
 580   dnl more elegant approach (see autoconf/acgen.m4 and specifically
 581   dnl AC_CHECK_FUNC for things to steal.)
 582   dummyvar=no
 583   if test x$dummyvar = x"yes"; then
 584     AC_DEFINE(HAVE___BUILTIN_ABS)
 585     AC_DEFINE(HAVE___BUILTIN_LABS)
 586     AC_DEFINE(HAVE___BUILTIN_COS)
 587     AC_DEFINE(HAVE___BUILTIN_COSF)
 588     AC_DEFINE(HAVE___BUILTIN_COSL)
 589     AC_DEFINE(HAVE___BUILTIN_FABS)
 590     AC_DEFINE(HAVE___BUILTIN_FABSF)
 591     AC_DEFINE(HAVE___BUILTIN_FABSL)
 592     AC_DEFINE(HAVE___BUILTIN_SIN)
 593     AC_DEFINE(HAVE___BUILTIN_SINF)
 594     AC_DEFINE(HAVE___BUILTIN_SINL)
 595     AC_DEFINE(HAVE___BUILTIN_FSQRT)
 596     AC_DEFINE(HAVE___BUILTIN_SQRTF)
 597     AC_DEFINE(HAVE___BUILTIN_SQRTL)
 598   fi
 599 ])
 600
 601
 602 dnl
 603 dnl Check to see what the underlying c library
 604 dnl These checks need to do two things:
 605 dnl 1) make sure the name is declared when using the c++ compiler
 606 dnl 2) make sure the name has "C" linkage
 607 dnl This might seem like overkill but experience has shown that it's not...
 608 dnl
 609 dnl Define HAVE_STRTOLD if "strtold" is declared and links
 610 dnl Define HAVE_STRTOF if "strtof" is declared and links
 611 dnl Define HAVE_DRAND48 if "drand48" is declared and links
 612 dnl
 613 dnl GLIBCPP_CHECK_STDLIB_SUPPORT
 614 AC_DEFUN(GLIBCPP_CHECK_STDLIB_SUPPORT, [
 615   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 616   ac_save_CXXFLAGS="$CXXFLAGS"
 617   CXXFLAGS='-fno-builtins -D_GNU_SOURCE'
 618
 619   AC_CHECK_FUNCS(strtof)
 620   GLIBCPP_CHECK_STDLIB_DECL_AND_LINKAGE_2(strtold)
 621   AC_CHECK_FUNCS(drand48)
 622
 623   CXXFLAGS="$ac_save_CXXFLAGS"
 624 ])
 625
 626
 627 dnl
 628 dnl Check to see what the underlying c library or math library is like.
 629 dnl These checks need to do two things:
 630 dnl 1) make sure the name is declared when using the c++ compiler
 631 dnl 2) make sure the name has "C" linkage
 632 dnl This might seem like overkill but experience has shown that it's not...
 633 dnl
 634 dnl Define HAVE_CARGF etc if "cargf" is found.
 635 dnl
 636 dnl GLIBCPP_CHECK_MATH_SUPPORT
 637 AC_DEFUN(GLIBCPP_CHECK_MATH_SUPPORT, [
 638   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 639   ac_save_CXXFLAGS="$CXXFLAGS"
 640   CXXFLAGS='-fno-builtins -D_GNU_SOURCE'
 641
 642   dnl Check libm
 643   AC_CHECK_LIB(m, sin, libm="-lm")
 644   ac_save_LIBS="$LIBS"
 645   LIBS="$LIBS $libm"
 646
 647   dnl Check to see if certain C math functions exist.
 648   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinf)
 649   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnan)
 650   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finite)
 651   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysign)
 652   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincos)
 653   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fpclass)
 654   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(qfpclass)
 655
 656   dnl Check to see if basic C math functions have float versions.
 657   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(float trig,
 658                                           float_trig,
 659                                           acosf asinf atanf \
 660                                           cosf sinf tanf \
 661                                           coshf sinhf tanhf)
 662   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(float round,
 663                                           float_round,
 664                                           ceilf floorf)
 665   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnanf)
 666   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinff)
 667   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fabsf)
 668   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(fmodf)
 669   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(frexpf)
 670   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(ldexpf)
 671   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(logf)
 672   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(log10f)
 673   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(modff)
 674   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(powf)
 675   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sqrtf)
 676   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincosf)
 677   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finitef)
 678
 679   dnl Check to see if basic C math functions have long double versions.
 680   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(long double trig,
 681                                           long_double_trig,
 682                                           acosl asinl atanl \
 683                                           cosl sinl tanl \
 684                                           coshl sinhl tanhl)
 685   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(long double round,
 686                                           long_double_round,
 687                                           ceill floorl)
 688   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isnanl)
 689   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(isinfl)
 690   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(copysignl)
 691   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(atan2l)
 692   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(expl)
 693   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(fabsl)
 694   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(fmodl)
 695   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(frexpl)
 696   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(ldexpl)
 697   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(logl)
 698   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(log10l)
 699   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(modfl)
 700   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_2(powl)
 701   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(sqrtl)
 702   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_3(sincosl)
 703   GLIBCPP_CHECK_MATH_DECL_AND_LINKAGE_1(finitel)
 704
 705   dnl Some runtimes have these functions with a preceding underscore. Please
 706   dnl keep this sync'd with the one above. And if you add any new symbol,
 707   dnl please add the corresponding block in the @BOTTOM@ section of acconfig.h.
 708   dnl Check to see if certain C math functions exist.
 709
 710   dnl Check to see if basic C math functions have float versions.
 711   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_float trig,
 712                                           _float_trig,
 713                                           _acosf _asinf _atanf \
 714                                           _cosf _sinf _tanf \
 715                                           _coshf _sinhf _tanhf)
 716   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_float round,
 717                                           _float_round,
 718                                           _ceilf _floorf)
 719
 720   dnl Check to see if basic C math functions have long double versions.
 721   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_long double trig,
 722                                           _long_double_trig,
 723                                           _acosl _asinl _atanl \
 724                                           _cosl _sinl _tanl \
 725                                           _coshl _sinhl _tanhl)
 726   GLIBCPP_CHECK_MATH_DECLS_AND_LINKAGES_1(_long double round,
 727                                           _long_double_round,
 728                                           _ceill _floorl)
 729
 730   LIBS="$ac_save_LIBS"
 731   CXXFLAGS="$ac_save_CXXFLAGS"
 732 ])
 733
 734
 735 dnl
 736 dnl Check to see if there is native support for complex
 737 dnl
 738 dnl Don't compile bits in math/* if native support exits.
 739 dnl
 740 dnl Define USE_COMPLEX_LONG_DOUBLE etc if "atan2l/copysignl" is found.
 741 dnl
 742 dnl GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT
 743 AC_DEFUN(GLIBCPP_CHECK_COMPLEX_MATH_SUPPORT, [
 744   dnl Check for complex versions of math functions of platform.
 745   AC_CHECK_LIB(m, main)
 746   AC_REPLACE_MATHFUNCS(nan hypot hypotf atan2f expf copysignf)
 747
 748   dnl Compile the long double complex functions only if the function
 749   dnl provides the non-complex long double functions that are needed.
 750   dnl Currently this includes copysignl and atan2l, which should be
 751   dnl cached from the GLIBCPP_CHECK_MATH_SUPPORT macro, above.
 752   USE_COMPLEX_LONG_DOUBLE=no
 753   if test x$ac_cv_func_atan2l = x"yes" \
 754      && test x$ac_cv_func_copysignl = x"yes"; then
 755     USE_COMPLEX_LONG_DOUBLE=yes
 756     AC_REPLACE_MATHFUNCS(hypotl signbitl)
 757   fi
 758
 759   AC_SUBST(USE_COMPLEX_LONG_DOUBLE)
 760 ])
 761
 762
 763 dnl Check to see what architecture and operating system we are compiling
 764 dnl for.  Also, if architecture- or OS-specific flags are required for
 765 dnl compilation, pick them up here.
 766 dnl
 767 dnl GLIBCPP_CHECK_TARGET
 768 AC_DEFUN(GLIBCPP_CHECK_TARGET, [
 769     . [$]{glibcpp_basedir}/configure.target
 770     AC_MSG_RESULT(CPU config directory is $cpu_include_dir)
 771     AC_MSG_RESULT(OS config directory is $os_include_dir)
 772     AC_LINK_FILES($os_include_dir/bits/os_defines.h, include/bits/os_defines.h)
 773 ])
 774
 775
 776 dnl
 777 dnl Check to see if this target can enable the wchar_t parts of libstdc++.
 778 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 779 dnl must have been previously checked.)
 780 dnl
 781 dnl Define _GLIBCPP_USE_WCHAR_T if all the bits are found
 782 dnl Define HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 783 dnl
 784 dnl GLIBCPP_CHECK_WCHAR_T_SUPPORT
 785 AC_DEFUN(GLIBCPP_CHECK_WCHAR_T_SUPPORT, [
 786
 787   dnl Test wchar.h for mbstate_t, which is needed for char_traits and
 788   dnl others even if wchar_t support is not on.
 789   AC_MSG_CHECKING([for mbstate_t])
 790   AC_TRY_COMPILE([#include <wchar.h>],
 791   [mbstate_t teststate;],
 792   have_mbstate_t=yes, have_mbstate_t=no)
 793   AC_MSG_RESULT($have_mbstate_t)
 794   if test x"$have_mbstate_t" = xyes; then
 795     AC_DEFINE(HAVE_MBSTATE_T)
 796   fi
 797
 798   dnl Sanity check for existence of ISO C99 headers for extended encoding.
 799   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 800   AC_CHECK_HEADER(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 801
 802   dnl Only continue checking if the ISO C99 headers exist and support is on.
 803   if test x"$ac_has_wchar_h" = xyes && test x"$ac_has_wctype_h" = xyes \
 804      && test x"$enable_c_mbchar" != xno; then
 805
 806     dnl Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 807     dnl numeric_limits can instantiate type_traits<wchar_t>
 808     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 809     AC_TRY_COMPILE([#include <wchar.h>],
 810     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 811     has_wchar_minmax=yes, has_wchar_minmax=no)
 812     AC_MSG_RESULT($has_wchar_minmax)
 813
 814     dnl Test wchar.h for WEOF, which is what we use to determine whether
 815     dnl to specialize for char_traits<wchar_t> or not.
 816     AC_MSG_CHECKING([for WEOF])
 817     AC_TRY_COMPILE([
 818       #include <wchar.h>
 819       #include <stddef.h>],
 820     [wint_t i = WEOF;],
 821     has_weof=yes, has_weof=no)
 822     AC_MSG_RESULT($has_weof)
 823
 824     dnl Tests for wide character functions used in char_traits<wchar_t>.
 825     AC_CHECK_FUNCS(wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset \
 826     wcsrtombs mbsrtowcs, ac_wfuncs=yes, ac_wfuncs=no)
 827
 828     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 829     if test x"$has_weof" = xyes && test x"$has_wchar_minmax" = xyes \
 830        && test x"$ac_wfuncs" = xyes; then
 831       ac_isoC99_wchar_t=yes
 832     else
 833       ac_isoC99_wchar_t=no
 834     fi
 835     AC_MSG_RESULT($ac_isoC99_wchar_t)
 836
 837     dnl Use iconv for wchar_t to char conversions. As such, check for
 838     dnl X/Open Portability Guide, version 2 features (XPG2).
 839     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 840     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 841
 842     dnl Check for existence of libiconv.a providing XPG2 wchar_t support.
 843     AC_CHECK_LIB(iconv, iconv, libiconv="-liconv")
 844     ac_save_LIBS="$LIBS"
 845     LIBS="$LIBS $libiconv"
 846
 847     AC_CHECK_FUNCS(iconv_open iconv_close iconv nl_langinfo, \
 848     ac_XPG2funcs=yes, ac_XPG2funcs=no)
 849
 850     LIBS="$ac_save_LIBS"
 851
 852     AC_MSG_CHECKING([for XPG2 wchar_t support])
 853     if test x"$ac_has_iconv_h" = xyes && test x"$ac_has_langinfo_h" = xyes \
 854        && test x"$ac_XPG2funcs" = xyes; then
 855       ac_XPG2_wchar_t=yes
 856     else
 857       ac_XPG2_wchar_t=no
 858     fi
 859     AC_MSG_RESULT($ac_XPG2_wchar_t)
 860
 861     dnl At the moment, only enable wchar_t specializations if all the
 862     dnl above support is present.
 863     AC_MSG_CHECKING([for enabled wchar_t specializations])
 864     if test x"$ac_isoC99_wchar_t" = xyes \
 865        && test x"$ac_XPG2_wchar_t" = xyes; then
 866       AC_DEFINE(_GLIBCPP_USE_WCHAR_T)
 867       AC_MSG_RESULT("yes")
 868     else
 869       AC_MSG_RESULT("no")
 870     fi
 871   else
 872     dnl Wide characters disabled by the user.
 873     AC_MSG_WARN([wchar_t support disabled.])
 874   fi
 875 ])
 876
 877
 878 dnl
 879 dnl Check for special debugging mode; not for production use.
 880 dnl
 881 dnl GLIBCPP_ENABLE_DEBUG
 882 dnl --enable-debug sets '-ggdb3 -O0'.
 883 dnl --disable-debug sets '-g' and whatever optimization options the
 884 dnl     compiler can handle.
 885 dnl  +  --enable-maintainer-mode automatically defaults this to on.
 886 dnl  +  Perhaps -D/-U of NDEBUG, DEBUG, DEBUG_ASSERT, ...?
 887 dnl  +  Usage:  GLIBCPP_ENABLE_DEBUG[(DEFAULT)]
 888 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
 889 dnl       defaults to `no'.
 890 AC_DEFUN(GLIBCPP_ENABLE_DEBUG, [dnl
 891 define([GLIBCPP_ENABLE_DEBUG_DEFAULT], ifelse($1, yes, yes, no))dnl
 892 AC_ARG_ENABLE(debug,
 893 changequote(<<, >>)dnl
 894 <<  --enable-debug          extra debugging, turn off optimization [default=>>GLIBCPP_ENABLE_DEBUG_DEFAULT],
 895 changequote([, ])dnl
 896 [case "${enableval}" in
 897  yes) enable_debug=yes ;;
 898  no)  enable_debug=no ;;
 899  *)   AC_MSG_ERROR([Unknown argument to enable/disable extra debugging]) ;;
 900  esac],
 901 enable_debug=GLIBCPP_ENABLE_DEBUG_DEFAULT)dnl
 902
 903 dnl Option parsed, now set things appropriately
 904 case "${enable_debug}" in
 905     yes)
 906         DEBUG_FLAGS='-O0 -ggdb3'
 907         ;;
 908     no)
 909         DEBUG_FLAGS='-g'
 910         ;;
 911 esac
 912 AC_SUBST(DEBUG_FLAGS)
 913 ])
 914
 915
 916 dnl
 917 dnl Check for "unusual" flags to pass to the compiler while building.
 918 dnl
 919 dnl GLIBCPP_ENABLE_CXX_FLAGS
 920 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
 921 dnl     experimental flags such as -fhonor-std, -fsquangle, -Dfloat=char, etc.
 922 dnl     Somehow this same set of flags must be passed when [re]building
 923 dnl     libgcc.
 924 dnl --disable-cxx-flags passes nothing.
 925 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
 926 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
 927 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
 928 dnl  +  Usage:  GLIBCPP_ENABLE_CXX_FLAGS(default flags)
 929 dnl       If "default flags" is an empty string (or "none"), the effect is
 930 dnl       the same as --disable or --enable=no.
 931 AC_DEFUN(GLIBCPP_ENABLE_CXX_FLAGS, [dnl
 932 define([GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT], ifelse($1,,, $1))dnl
 933 AC_ARG_ENABLE(cxx-flags,
 934 changequote(<<, >>)dnl
 935 <<  --enable-cxx-flags=FLAGS      pass compiler FLAGS when building library;
 936                                 [default=>>GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT],
 937 changequote([, ])dnl
 938 [case "x$enableval" in
 939  xyes)
 940         AC_MSG_ERROR([--enable-cxx-flags needs compiler flags as arguments]) ;;
 941  xno|x)
 942         enable_cxx_flags='' ;;
 943  *)
 944         enable_cxx_flags="$enableval" ;;
 945  esac],
 946 enable_cxx_flags='GLIBCPP_ENABLE_CXX_FLAGS_DEFAULT')
 947
 948 dnl Thinko on my part during design.  This kludge is the workaround.
 949 if test "$enable_cxx_flags" = "none"; then
 950   enable_cxx_flags='';
 951 fi
 952
 953 dnl Run through flags (either default or command-line) and set anything
 954 dnl extra (e.g., #defines) that must accompany particular g++ options.
 955 if test -n "$enable_cxx_flags"; then
 956     for f in $enable_cxx_flags; do
 957         case "$f" in
 958             -fhonor-std)  ;;
 959             -*)  ;;
 960             *)   # and we're trying to pass /what/ exactly?
 961                  AC_MSG_ERROR([compiler flags start with a -]) ;;
 962         esac
 963     done
 964 fi
 965 EXTRA_CXX_FLAGS="$enable_cxx_flags"
 966 AC_SUBST(EXTRA_CXX_FLAGS)
 967 ])
 968
 969
 970 dnl
 971 dnl Check for which locale library to use:  gnu or generic.
 972 dnl
 973 dnl GLIBCPP_ENABLE_CLOCALE
 974 dnl --enable-clocale=gnu sets config/c_locale_gnu.cc and friends
 975 dnl --enable-clocale=generic sets config/c_locale_generic.cc and friends
 976 dnl
 977 dnl default is generic
 978 dnl
 979 AC_DEFUN(GLIBCPP_ENABLE_CLOCALE, [
 980   AC_MSG_CHECKING([for clocale to use])
 981   AC_ARG_ENABLE(clocale,
 982   [  --enable-clocale        enable model for target locale package.
 983   --enable-clocale=MODEL  use MODEL target-speific locale package. [default=generic]
 984   ],
 985   if test x$enable_clocale = xno; then
 986      enable_clocale=generic
 987   fi,
 988      enable_clocale=generic)
 989
 990   enable_clocale_flag=$enable_clocale
 991
 992   dnl Check if a valid locale package
 993   case x${enable_clocale_flag} in
 994     xgnu)
 995       CLOCALE_H=config/c_locale_gnu.h
 996       CLOCALE_CC=config/c_locale_gnu.cc
 997       AC_MSG_RESULT(gnu)
 998       ;;
 999     xgeneric)
1000       CLOCALE_H=config/c_locale_generic.h
1001       CLOCALE_CC=config/c_locale_generic.cc
1002       AC_MSG_RESULT(generic)
1003       ;;
1004     *)
1005       echo "$enable_clocale is an unknown locale package" 1>&2
1006       exit 1
1007       ;;
1008   esac
1009
1010   AC_LINK_FILES($CLOCALE_H, include/bits/c++locale.h)
1011   AC_LINK_FILES($CLOCALE_CC, src/c++locale.cc)
1012 ])
1013
1014
1015 dnl
1016 dnl Check for which I/O library to use:  libio, or something specific.
1017 dnl
1018 dnl GLIBCPP_ENABLE_CSTDIO
1019 dnl --enable-cstdio=libio sets config/c_io_libio.h and friends
1020 dnl
1021 dnl default is stdio
1022 dnl
1023 AC_DEFUN(GLIBCPP_ENABLE_CSTDIO, [
1024   AC_MSG_CHECKING([for cstdio to use])
1025   AC_ARG_ENABLE(cstdio,
1026   [  --enable-cstdio         enable stdio for target io package.
1027   --enable-cstdio=LIB     use LIB target-speific io package. [default=stdio]
1028   ],
1029   if test x$enable_cstdio = xno; then
1030      enable_cstdio=stdio
1031   fi,
1032      enable_cstdio=stdio)
1033
1034   enable_cstdio_flag=$enable_cstdio
1035
1036   dnl Check if a valid I/O package
1037   case x${enable_cstdio_flag} in
1038     xlibio)
1039       CSTDIO_H=config/c_io_libio.h
1040       BASIC_FILE_H=config/basic_file_libio.h
1041       BASIC_FILE_CC=config/basic_file_libio.cc
1042       AC_MSG_RESULT(libio)
1043
1044       # see if we are on a system with libio native (ie, linux)
1045       AC_CHECK_HEADER(libio.h,  has_libio=yes, has_libio=no)
1046
1047       # Need to check and see what version of glibc is being used. If
1048       # it's not glibc-2.2 or higher, then we'll need to go ahead and
1049       # compile most of libio for linux systems.
1050       if test x$has_libio = x"yes"; then
1051         case "$target" in
1052           *-*-linux*)
1053               AC_MSG_CHECKING([for glibc version >= 2.2])
1054               AC_EGREP_CPP([ok], [
1055             #include <features.h>
1056               #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
1057                     ok
1058               #endif
1059               ], glibc_satisfactory=yes, glibc_satisfactory=no)
1060               AC_MSG_RESULT($glibc_satisfactory)
1061             ;;
1062         esac
1063
1064         # XXX at the moment, admit defeat and force the recompilation
1065         # XXX of glibc even on glibc-2.2 systems, because libio is not synched.
1066         glibc_satisfactory=no
1067
1068         if test x$glibc_satisfactory = x"yes"; then
1069            need_libio=no
1070            need_wlibio=no
1071         else
1072            need_libio=yes
1073            # bkoz XXX need to add checks to enable this
1074            # pme XXX here's a first pass at such a check
1075            if test x$enable_c_mbchar != xno; then
1076               need_wlibio=yes
1077            else
1078               need_wlibio=no
1079            fi
1080         fi
1081
1082       else
1083          # Using libio, but <libio.h> doesn't exist on the target system. . .
1084          need_libio=yes
1085          # bkoz XXX need to add checks to enable this
1086          # pme XXX here's a first pass at such a check
1087          if test x$enable_c_mbchar != xno; then
1088              need_wlibio=yes
1089          else
1090              need_wlibio=no
1091          fi
1092       fi
1093       ;;
1094     xstdio | x | xno | xnone | xyes)
1095       # default
1096       CSTDIO_H=config/c_io_stdio.h
1097       BASIC_FILE_H=config/basic_file_stdio.h
1098       BASIC_FILE_CC=config/basic_file_stdio.cc
1099       AC_MSG_RESULT(stdio)
1100
1101       # We're not using stdio.
1102       need_libio=no
1103       need_wlibio=no
1104       ;;
1105     *)
1106       echo "$enable_cstdio is an unknown io package" 1>&2
1107       exit 1
1108       ;;
1109   esac
1110   AC_LINK_FILES($CSTDIO_H, include/bits/c++io.h)
1111   AC_LINK_FILES($BASIC_FILE_H, include/bits/basic_file_model.h)
1112   AC_LINK_FILES($BASIC_FILE_CC, src/basic_file.cc)
1113
1114   # 2000-08-04 bkoz hack
1115   CCODECVT_C=config/c_io_libio_codecvt.c
1116   AC_LINK_FILES($CCODECVT_C, libio/c_codecvt.c)
1117   # 2000-08-04 bkoz hack
1118
1119   AM_CONDITIONAL(GLIBCPP_BUILD_LIBIO,
1120                  test "$need_libio" = yes || test "$need_wlibio" = yes)
1121   AM_CONDITIONAL(GLIBCPP_NEED_LIBIO, test "$need_libio" = yes)
1122   AM_CONDITIONAL(GLIBCPP_NEED_WLIBIO, test "$need_wlibio" = yes)
1123   if test "$need_libio" = yes || test "$need_wlibio" = yes; then
1124     libio_la=../libio/libio.la
1125   else
1126     libio_la=
1127   fi
1128   AC_SUBST(libio_la)
1129 ])
1130
1131
1132 dnl
1133 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1134 dnl We must stage the required headers so that they will be installed
1135 dnl with the library (unlike libgcc, the STL implementation is provided
1136 dnl solely within headers).  Since we must not inject random user-space
1137 dnl macro names into user-provided C++ code, we first stage into <file>-in
1138 dnl and process to <file> with an output command.  The reason for a two-
1139 dnl stage process here is to correctly handle $srcdir!=$objdir without
1140 dnl having to write complex code (the sed commands to clean the macro
1141 dnl namespace are complex and fragile enough as it is).
1142 dnl
1143 AC_DEFUN(GLIBCPP_ENABLE_THREADS, [
1144   AC_MSG_CHECKING([for thread model used by GCC])
1145   target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
1146   AC_MSG_RESULT([$target_thread_file])
1147
1148   AC_LINK_FILES(../gcc/gthr.h, include/bits/gthr.h-in)
1149   AC_LINK_FILES(../gcc/gthr-single.h, include/bits/gthr-single.h-in)
1150   AC_LINK_FILES(../gcc/gthr-$target_thread_file.h,
1151                 include/bits/gthr-default.h-in)
1152   if test $target_thread_file != single; then
1153     AC_DEFINE(HAVE_GTHR_DEFAULT)
1154     AC_DEFINE(_GLIBCPP_SUPPORTS_WEAK, __GXX_WEAK__)
1155   fi
1156   AC_OUTPUT_COMMANDS([d=include/bits
1157     rm -f $d/gthr.h $d/gthr-single.h $d/gthr-default.h
1158     sed '/^#/s/\([A-Z_][A-Z_]*\)/_GLIBCPP_\1/g' <$d/gthr.h-in >$d/gthr.h
1159     sed 's/\(UNUSED\)/_GLIBCPP_\1/g' <$d/gthr-single.h-in \
1160       | sed 's/\(GCC[A-Z_]*_H\)/_GLIBCPP_\1/g' >$d/gthr-single.h
1161     sed 's/\(UNUSED\)/_GLIBCPP_\1/g' <$d/gthr-default.h-in \
1162       | sed 's/\(GCC[A-Z_]*_H\)/_GLIBCPP_\1/g' \
1163       | sed 's/\([A-Z_]*WEAK\)/_GLIBCPP_\1/g' >$d/gthr-default.h])
1164 ])
1165
1166
1167 dnl
1168 dnl Check for exception handling support.  If an explicit enable/disable
1169 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1170 dnl target may or may not support call frame exceptions.
1171 dnl
1172 dnl GLIBCPP_ENABLE_SJLJ_EXCEPTIONS
1173 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1174 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1175 dnl
1176 dnl Define _GLIBCPP_SJLJ_EXCEPTIONS if the compiler is configured for it.
1177 dnl
1178 AC_DEFUN(GLIBCPP_ENABLE_SJLJ_EXCEPTIONS, [
1179   AC_MSG_CHECKING([for exception model to use])
1180   AC_LANG_SAVE
1181   AC_LANG_CPLUSPLUS
1182   AC_ARG_ENABLE(sjlj-exceptions,
1183   [  --enable-sjlj-exceptions  force use of builtin_setjmp for exceptions],
1184   [:],
1185   [dnl Botheration.  Now we've got to detect the exception model.
1186    dnl Link tests against libgcc.a are problematic since -- at least
1187    dnl as of this writing -- we've not been given proper -L bits for
1188    dnl single-tree newlib and libgloss.
1189    dnl
1190    dnl This is what AC_TRY_COMPILE would do if it didn't delete the
1191    dnl conftest files before we got a change to grep them first.
1192    cat > conftest.$ac_ext << EOF
1193 [#]line __oline__ "configure"
1194 struct S { ~S(); };
1195 void bar();
1196 void foo()
1197 {
1198   S s;
1199   bar();
1200 }
1201 EOF
1202    old_CXXFLAGS="$CXXFLAGS"
1203    CXXFLAGS=-S
1204    if AC_TRY_EVAL(ac_compile); then
1205      if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1206        enable_sjlj_exceptions=yes
1207      elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1208        enable_sjlj_exceptions=no
1209      fi
1210    fi
1211    CXXFLAGS="$old_CXXFLAGS"
1212    rm -f conftest*])
1213    if test x$enable_sjlj_exceptions = xyes; then
1214      AC_DEFINE(_GLIBCPP_SJLJ_EXCEPTIONS, 1,
1215         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1216      ac_exception_model_name=sjlj
1217    elif test x$enable_sjlj_exceptions = xno; then
1218      ac_exception_model_name="call frame"
1219    else
1220      AC_MSG_ERROR([unable to detect exception model])
1221    fi
1222    AC_LANG_RESTORE
1223    AC_MSG_RESULT($ac_exception_model_name)
1224 ])
1225
1226
1227 dnl
1228 dnl Check for ISO/IEC 9899:1999 "C99" support.
1229 dnl
1230 dnl GLIBCPP_ENABLE_C99
1231 dnl --enable-c99 defines _GLIBCPP_USE_C99
1232 dnl --disable-c99 leaves _GLIBCPP_USE_C99 undefined
1233 dnl  +  Usage:  GLIBCPP_ENABLE_C99[(DEFAULT)]
1234 dnl       Where DEFAULT is either `yes' or `no'.  If omitted, it
1235 dnl       defaults to `no'.
1236 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
1237 dnl
1238 dnl GLIBCPP_ENABLE_C99
1239 AC_DEFUN(GLIBCPP_ENABLE_C99, [dnl
1240   define([GLIBCPP_ENABLE_C99_DEFAULT], ifelse($1, yes, yes, no))dnl
1241
1242   AC_ARG_ENABLE(c99,
1243   changequote(<<, >>)dnl
1244   <<--enable-c99      turns on 'ISO/IEC 9899:1999 support' [default=>>GLIBCPP_ENABLE_C99_DEFAULT],
1245   changequote([, ])dnl
1246   [case "$enableval" in
1247    yes) enable_c99=yes ;;
1248    no)  enable_c99=no ;;
1249    *)   AC_MSG_ERROR([Unknown argument to enable/disable C99]) ;;
1250    esac],
1251   enable_c99=GLIBCPP_ENABLE_C99_DEFAULT)dnl
1252
1253   AC_LANG_SAVE
1254   AC_LANG_CPLUSPLUS
1255
1256   # Check for the existence of <math.h> functions used if C99 is enabled.
1257   ac_c99_math=yes;
1258   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
1259   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
1260   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
1261   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
1262   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
1263   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
1264   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
1265   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
1266   AC_TRY_COMPILE([#include <math.h>],
1267                  [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
1268   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
1269   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
1270   AC_TRY_COMPILE([#include <math.h>],
1271                  [islessgreater(0.0,0.0);],, [ac_c99_math=no])
1272   AC_TRY_COMPILE([#include <math.h>],
1273                  [isunordered(0.0,0.0);],, [ac_c99_math=no])
1274   AC_MSG_RESULT($ac_c99_math)
1275
1276   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
1277   ac_c99_stdlib=yes;
1278   AC_MSG_CHECKING([for lldiv_t declaration])
1279   AC_CACHE_VAL(ac_c99_lldiv_t, [
1280   AC_TRY_COMPILE([#include <stdlib.h>],
1281                    [ lldiv_t mydivt;],
1282                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
1283   ])
1284   AC_MSG_RESULT($ac_c99_lldiv_t)
1285
1286   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
1287   AC_TRY_COMPILE([#include <stdlib.h>],
1288                  [char* tmp; strtoll("gnu", &tmp, 10);],, [ac_c99_stdlib=no])
1289   AC_TRY_COMPILE([#include <stdlib.h>],
1290                  [char* tmp; strtoull("gnu", &tmp, 10);],, [ac_c99_stdlib=no])
1291   AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
1292   AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
1293   AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
1294   if test x"$ac_c99_lldiv_t" = x"no"; then
1295     ac_c99_stdlib=no;
1296   fi;
1297   AC_MSG_RESULT($ac_c99_stdlib)
1298
1299   # Check for the existence of <wchar.h> functions used if C99 is enabled.
1300   ac_c99_wchar=yes;
1301   AC_MSG_CHECKING([for ISO C99 support in <wchar.h>])
1302   AC_TRY_COMPILE([#include <wchar.h>],
1303                  [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
1304   AC_TRY_COMPILE([#include <wchar.h>],
1305                  [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
1306   AC_TRY_COMPILE([#include <wchar.h>],
1307                  [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
1308   AC_MSG_RESULT($ac_c99_wchar)
1309
1310   AC_MSG_CHECKING([for enabled ISO C99 support])
1311   if test x"$ac_c99_math" = x"no" || test x"$ac_c99_wchar" = x"no" \
1312         || test x"$ac_c99_stdlib" = x"no"; then
1313     enable_c99=no;
1314   fi;
1315   AC_MSG_RESULT($enable_c99)
1316
1317   # Option parsed, now set things appropriately
1318   if test x"$enable_c99" = x"yes"; then
1319     AC_DEFINE(_GLIBCPP_USE_C99)
1320   fi
1321
1322   AC_LANG_RESTORE
1323 ])
1324
1325
1326 dnl
1327 dnl Check for template specializations for the 'long long' type extension.
1328 dnl NB: Must check for C99 support before calling _GLIBCPP_ENABLE_LONG_LONG
1329 dnl
1330 dnl GLIBCPP_ENABLE_LONG_LONG
1331 dnl --enable-long-long defines _GLIBCPP_USE_LONG_LONG
1332 dnl --disable-long-long leaves _GLIBCPP_USE_LONG_LONG undefined
1333 dnl  +  Usage:  GLIBCPP_ENABLE_LONG_LONG[(DEFAULT)]
1334 dnl       Where DEFAULT is either `yes' or `no'.  If omitted, it
1335 dnl       defaults to `no'.
1336 dnl  +  If 'long long' stuff is not available, ignores DEFAULT and sets `no'.
1337 dnl
1338 dnl GLIBCPP_ENABLE_LONG_LONG
1339 AC_DEFUN(GLIBCPP_ENABLE_LONG_LONG, [dnl
1340   define([GLIBCPP_ENABLE_LONG_LONG_DEFAULT], ifelse($1, yes, yes, no))dnl
1341
1342   AC_ARG_ENABLE(long-long,
1343   changequote(<<, >>)dnl
1344   <<--enable-long-long      turns on 'long long' [default=>>GLIBCPP_ENABLE_LONG_LONG_DEFAULT],
1345   changequote([, ])dnl
1346   [case "$enableval" in
1347    yes) enable_long_long=yes ;;
1348    no)  enable_long_long=no ;;
1349    *)   AC_MSG_ERROR([Unknown argument to enable/disable long long]) ;;
1350    esac],
1351   enable_long_long=GLIBCPP_ENABLE_LONG_LONG_DEFAULT)dnl
1352
1353   # iostreams require strtoll, strtoull to compile. If the
1354   # GLIBCPP_ENABLE_C99 tests found these, and if C99 support is enabled,
1355   # go ahead and allow long long to be used.
1356   if test x"$enable_c99" = x"no"; then
1357     enable_long_long=no;
1358   fi
1359
1360   # Option parsed, now set things appropriately
1361   AC_MSG_CHECKING([for enabled long long support])
1362   if test x"$enable_long_long" = xyes; then
1363     AC_DEFINE(_GLIBCPP_USE_LONG_LONG)
1364   fi
1365   AC_MSG_RESULT($enable_long_long)
1366 ])
1367
1368
1369 dnl
1370 dnl Check for what kind of C headers to use.
1371 dnl
1372 dnl GLIBCPP_ENABLE_CHEADERS
1373 dnl --enable-cheaders= [does stuff].
1374 dnl --disable-cheaders [does not do anything, really].
1375 dnl  +  This will eventually need to be 'c_shadow' by default.
1376 dnl  +  Usage:  GLIBCPP_ENABLE_CHEADERS[(DEFAULT)]
1377 dnl       Where DEFAULT is either `c' or `c_std' or 'c_shadow'.
1378 dnl       If ommitted, it defaults to `c_std'.
1379 AC_DEFUN(GLIBCPP_ENABLE_CHEADERS, [dnl
1380 define([GLIBCPP_ENABLE_CHEADERS_DEFAULT], ifelse($1, c_std, c_std, c_std))dnl
1381 AC_MSG_CHECKING([for c header strategy to use])
1382 AC_ARG_ENABLE(cheaders,
1383 changequote(<<, >>)dnl
1384 <<  --enable-cheaders       construct "C" header files for g++ [default=>>GLIBCPP_ENABLE_CHEADERS_DEFAULT],
1385 changequote([, ])
1386   [case "$enableval" in
1387    c)
1388         enable_cheaders=c
1389         ;;
1390    c_std)
1391         enable_cheaders=c_std
1392         ;;
1393    c_shadow)
1394         enable_cheaders=c_shadow
1395         ;;
1396    *)   AC_MSG_ERROR([Unknown argument to enable/disable "C" headers])
1397         ;;
1398   esac],
1399   enable_cheaders=GLIBCPP_ENABLE_CHEADERS_DEFAULT)
1400   AC_MSG_RESULT($enable_cheaders)
1401
1402   dnl Option parsed, now set things appropriately
1403   case "$enable_cheaders" in
1404     c_shadow)
1405         CSHADOW_FLAGS="-fno-builtin"
1406         C_INCLUDE_DIR='${top_srcdir}/include/c_shadow'
1407         AC_DEFINE(_GLIBCPP_USE_SHADOW_HEADERS)
1408         ;;
1409     c_std)
1410         CSHADOW_FLAGS=""
1411         C_INCLUDE_DIR='${top_srcdir}/include/c_std'
1412         ;;
1413     c)
1414         CSHADOW_FLAGS=""
1415         C_INCLUDE_DIR='${top_srcdir}/include/c'
1416         ;;
1417   esac
1418
1419   AC_SUBST(CSHADOW_FLAGS)
1420   AC_SUBST(C_INCLUDE_DIR)
1421   AM_CONDITIONAL(GLIBCPP_USE_CSHADOW, test "$enable_cheaders" = c_shadow)
1422 ])
1423
1424
1425 dnl
1426 dnl Check for wide character support.  Has the same effect as the option
1427 dnl in gcc's configure, but in a form that autoconf can mess with.
1428 dnl
1429 dnl GLIBCPP_ENABLE_C_MBCHAR
1430 dnl --enable-c-mbchar requests all the wchar_t stuff.
1431 dnl --disable-c-mbchar doesn't.
1432 dnl  +  Usage:  GLIBCPP_ENABLE_C_MBCHAR[(DEFAULT)]
1433 dnl       Where DEFAULT is either `yes' or `no'.  If ommitted, it
1434 dnl       defaults to `no'.
1435 AC_DEFUN(GLIBCPP_ENABLE_C_MBCHAR, [dnl
1436 define([GLIBCPP_ENABLE_C_MBCHAR_DEFAULT], ifelse($1, yes, yes, no))dnl
1437 AC_ARG_ENABLE(c-mbchar,
1438 changequote(<<, >>)dnl
1439 <<  --enable-c-mbchar       enable multibyte (wide) characters [default=>>GLIBCPP_ENABLE_C_MBCHAR_DEFAULT],
1440 changequote([, ])dnl
1441 [case "$enableval" in
1442  yes) enable_c_mbchar=yes ;;
1443  no)  enable_c_mbchar=no ;;
1444  *)   AC_MSG_ERROR([Unknown argument to enable/disable c-mbchar]) ;;
1445  esac],
1446 enable_c_mbchar=GLIBCPP_ENABLE_C_MBCHAR_DEFAULT)dnl
1447 dnl Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1448 ])
1449
1450
1451 dnl
1452 dnl Set up *_INCLUDES and *_INCLUDE_DIR variables for all sundry Makefile.am's.
1453 dnl
1454 dnl GLIBCPP_INCLUDE_DIR
1455 dnl C_INCLUDE_DIR
1456 dnl TOPLEVEL_INCLUDES
1457 dnl LIBMATH_INCLUDES
1458 dnl LIBSUPCXX_INCLUDES
1459 dnl LIBIO_INCLUDES
1460 dnl CSHADOW_INCLUDES
1461 dnl
1462 dnl GLIBCPP_EXPORT_INCLUDE
1463 AC_DEFUN(GLIBCPP_EXPORT_INCLUDES, [
1464   # Root level of the include sources.
1465   GLIBCPP_INCLUDE_DIR='$(top_srcdir)/include'
1466
1467   # Can either use include/c or include/c_std to grab "C" headers. This
1468   # variable is set to the include directory currently in use.
1469   # set with C_INCLUDE_DIR in GLIBCPP_ENABLE_CHEADERS
1470
1471   # Passed down for canadian crosses.
1472   if  test x"$CANADIAN" = xyes; then
1473     TOPLEVEL_INCLUDES='-I$(includedir)'
1474   fi
1475
1476   LIBMATH_INCLUDES='-I$(top_srcdir)/libmath'
1477
1478   LIBSUPCXX_INCLUDES='-I$(top_srcdir)/libsupc++'
1479
1480   #if GLIBCPP_NEED_LIBIO
1481   LIBIO_INCLUDES='-I$(top_builddir)/libio -I$(top_srcdir)/libio'
1482   #else
1483   #LIBIO_INCLUDES='-I$(top_srcdir)/libio'
1484   #endif
1485
1486   #if GLIBCPP_USE_CSHADOW
1487   #  CSHADOW_INCLUDES='-I$(GLIBCPP_INCLUDE_DIR)/std -I$(C_INCLUDE_DIR) \
1488   #                   -I$(top_blddir)/cshadow'
1489   #else
1490   CSTD_INCLUDES='-I$(GLIBCPP_INCLUDE_DIR)/std -I$(C_INCLUDE_DIR)'
1491   #endif
1492
1493   # Now, export this to all the little Makefiles....
1494   AC_SUBST(GLIBCPP_INCLUDE_DIR)
1495   AC_SUBST(TOPLEVEL_INCLUDES)
1496   AC_SUBST(LIBMATH_INCLUDES)
1497   AC_SUBST(LIBSUPCXX_INCLUDES)
1498   AC_SUBST(LIBIO_INCLUDES)
1499   AC_SUBST(CSTD_INCLUDES)
1500 ])
1501
1502
1503 dnl
1504 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
1505 dnl
1506 AC_DEFUN(GLIBCPP_EXPORT_FLAGS, [
1507   # Optimization flags that are probably a good idea for thrill-seekers. Just
1508   # uncomment the lines below and make, everything else is ready to go...
1509   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
1510   OPTIMIZE_CXXFLAGS=
1511   AC_SUBST(OPTIMIZE_CXXFLAGS)
1512
1513   WARN_FLAGS='-Wall -Wno-format -W -Wwrite-strings -Winline'
1514   AC_SUBST(WARN_FLAGS)
1515 ])
1516
1517 dnl
1518 dnl  GLIBCPP_EXPORT_INSTALL_INFO
1519 dnl  calculates gxx_install_dir
1520 dnl  exports glibcpp_toolexecdir
1521 dnl  exports glibcpp_toolexeclibdir
1522 dnl  exports glibcpp_builddir
1523 dnl  exports glibcpp_srcdir
1524 dnl  exports glibcpp_prefixdir
1525 dnl
1526 dnl Assumes cross_compiling bits already done, and with_cross_host in
1527 dnl particular
1528 dnl
1529 dnl GLIBCPP_EXPORT_INSTALL_INFO
1530 AC_DEFUN(GLIBCPP_EXPORT_INSTALL_INFO, [
1531
1532 glibcpp_toolexecdir=no
1533 glibcpp_toolexeclibdir=no
1534
1535 # Export build and source directories.
1536 # These need to be absolute paths, yet at the same time need to
1537 # canonicalize only relative paths, because then amd will not unmount
1538 # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
1539 glibcpp_builddir=`pwd`
1540 case $srcdir in
1541 [\\/$]* | ?:[\\/]*) glibcpp_srcdir=${srcdir} ;;
1542 *) glibcpp_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
1543 esac
1544 glibcpp_prefixdir=${prefix}
1545
1546 AC_MSG_CHECKING([for interface version number])
1547 libstdcxx_interface=$INTERFACE
1548 AC_MSG_RESULT($libstdcxx_interface)
1549
1550 # Process the option --with-gxx-include-dir=<path to include-files directory>
1551 AC_MSG_CHECKING([for --with-gxx-include-dir])
1552 AC_ARG_WITH(gxx-include-dir,
1553 [  --with-gxx-include-dir  the installation directory for include files],
1554 [case "${withval}" in
1555   yes)
1556     AC_MSG_ERROR(Missing directory for --with-gxx-include-dir)
1557     gxx_include_dir=no
1558     ;;
1559   no)
1560     gxx_include_dir=no
1561     ;;
1562   *)
1563     gxx_include_dir=${withval}
1564     ;;
1565 esac], [gxx_include_dir=no])
1566 AC_MSG_RESULT($gxx_include_dir)
1567
1568 # Process the option "--enable-version-specific-runtime-libs"
1569 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
1570 AC_ARG_ENABLE(version-specific-runtime-libs,
1571 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
1572 [  version_specific_libs=yes
1573 # Need the gcc compiler version to know where to install libraries
1574 # and header files if --enable-version-specific-runtime-libs option
1575 # is selected.
1576 changequote(,)dnl
1577 gcc_version_trigger=${srcdir}/../gcc/version.c
1578 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([^\"]*\)\".*/\1/'`
1579 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([^ ]*\) .*/\1/'`
1580 gxx_include_dir='$(libdir)/gcc-lib/$(target_alias)/'${gcc_version}/include/g++
1581 glibcpp_toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
1582 glibcpp_toolexeclibdir='$(toolexecdir)/'${gcc_version}
1583 changequote([,])dnl
1584 ],version_specific_libs=no)
1585 AC_MSG_RESULT($version_specific_libs)
1586
1587 # Default case for install directory for include files.
1588 if test x"$version_specific_libs" = x"no" \
1589    && test x"$gxx_include_dir" = x"no"; then
1590   gxx_include_dir='$(prefix)'/include/g++-${libstdcxx_interface}
1591 fi
1592
1593 # Calculate glibcpp_toolexecdir, glibcpp_toolexeclibdir
1594 # Install a library built with a cross compiler in tooldir, not libdir.
1595 if test x"$glibcpp_toolexecdir" = x"no"; then
1596   if test -n "$with_cross_host" && test x"$with_cross_host" != x"no"; then
1597     glibcpp_toolexecdir='$(exec_prefix)/$(target_alias)'
1598     glibcpp_toolexeclibdir='$(toolexecdir)/lib$(MULTISUBDIR)'
1599   else
1600     glibcpp_toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
1601     glibcpp_toolexeclibdir='$(libdir)$(MULTISUBDIR)'
1602   fi
1603 fi
1604
1605 AC_MSG_CHECKING([for install location])
1606 AC_MSG_RESULT($gxx_include_dir)
1607
1608 AC_SUBST(glibcpp_builddir)
1609 AC_SUBST(glibcpp_srcdir)
1610 AC_SUBST(glibcpp_prefixdir)
1611 AC_SUBST(gxx_include_dir)
1612 AC_SUBST(glibcpp_toolexecdir)
1613 AC_SUBST(glibcpp_toolexeclibdir)
1614 ])
1615
1616
1617 # Check whether LC_MESSAGES is available in <locale.h>.
1618 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1619 #
1620 # This file file be copied and used freely without restrictions.  It can
1621 # be used in projects which are not available under the GNU Public License
1622 # but which still want to provide support for the GNU gettext functionality.
1623 # Please note that the actual code is *not* freely available.
1624
1625 # serial 1
1626
1627 AC_DEFUN(AC_LC_MESSAGES, [
1628   AC_CHECK_HEADER(locale.h, [
1629     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1630       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1631        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1632     if test $ac_cv_val_LC_MESSAGES = yes; then
1633       AC_DEFINE(HAVE_LC_MESSAGES)
1634     fi
1635   ])
1636 ])
1637
1638
1639 # Check for functions in math library.
1640 # Ulrich Drepper <drepper@cygnus.com>, 1998.
1641 #
1642 # This file can be copied and used freely without restrictions.  It can
1643 # be used in projects which are not available under the GNU Public License
1644 # but which still want to provide support for the GNU gettext functionality.
1645 # Please note that the actual code is *not* freely available.
1646
1647 # serial 1
1648
1649 dnl AC_REPLACE_MATHFUNCS(FUNCTION...)
1650 AC_DEFUN(AC_REPLACE_MATHFUNCS,
1651 [AC_CHECK_FUNCS([$1], , [LIBMATHOBJS="$LIBMATHOBJS ${ac_func}.lo"])
1652 AC_SUBST(LIBMATHOBJS)dnl
1653 ])
1654
1655
1656 # Check for string functions.
1657 # Ulrich Drepper <drepper@cygnus.com>, 1998.
1658 #
1659 # This file can be copied and used freely without restrictions.  It can
1660 # be used in projects which are not available under the GNU Public License
1661 # but which still want to provide support for the GNU gettext functionality.
1662 # Please note that the actual code is *not* freely available.
1663
1664 # serial 1
1665
1666 dnl AC_REPLACE_STRINGFUNCS(FUNCTION...)
1667 AC_DEFUN(AC_REPLACE_STRINGFUNCS,
1668 [AC_CHECK_FUNCS([$1], , [LIBSTRINGOBJS="$LIBSTRINGOBJS ${ac_func}.lo"])
1669 AC_SUBST(LIBSTRINGOBJS)dnl
1670 ])
1671
1672
1673 dnl This macro searches for a GNU version of make.  If a match is found, the
1674 dnl makefile variable `ifGNUmake' is set to the empty string, otherwise it is
1675 dnl set to "#". This is useful for  including a special features in a Makefile,
1676 dnl which cannot be handled by other versions of make.  The variable
1677 dnl _cv_gnu_make_command is set to the command to invoke GNU make if it exists,
1678 dnl the empty string otherwise.
1679 dnl
1680 dnl Here is an example of its use:
1681 dnl
1682 dnl Makefile.in might contain:
1683 dnl
1684 dnl     # A failsafe way of putting a dependency rule into a makefile
1685 dnl     $(DEPEND):
1686 dnl             $(CC) -MM $(srcdir)/*.c > $(DEPEND)
1687 dnl
1688 dnl     @ifGNUmake@ ifeq ($(DEPEND),$(wildcard $(DEPEND)))
1689 dnl     @ifGNUmake@ include $(DEPEND)
1690 dnl     @ifGNUmake@ endif
1691 dnl
1692 dnl Then configure.in would normally contain:
1693 dnl
1694 dnl     CHECK_GNU_MAKE()
1695 dnl     AC_OUTPUT(Makefile)
1696 dnl
1697 dnl Then perhaps to cause gnu make to override any other make, we could do
1698 dnl something like this (note that GNU make always looks for GNUmakefile first):
1699 dnl
1700 dnl     if  ! test x$_cv_gnu_make_command = x ; then
1701 dnl             mv Makefile GNUmakefile
1702 dnl             echo .DEFAULT: > Makefile ;
1703 dnl             echo \  $_cv_gnu_make_command \$@ >> Makefile;
1704 dnl     fi
1705 dnl
1706 dnl Then, if any (well almost any) other make is called, and GNU make also
1707 dnl exists, then the other make wraps the GNU make.
1708 dnl
1709 dnl @author John Darrington <j.darrington@elvis.murdoch.edu.au>
1710 dnl @version 1.1 #### replaced Id string now that Id is for lib-v3; pme
1711 dnl
1712 dnl #### Changes for libstdc++-v3:  reformatting and linewrapping; prepending
1713 dnl #### GLIBCPP_ to the macro name; adding the :-make fallback in the
1714 dnl #### conditional's subshell (" --version" is not a command), using a
1715 dnl #### different option to grep(1).
1716 dnl #### -pme
1717 dnl #### Fixed Bourne shell portability bug (use ${MAKE-make}, not
1718 dnl #### ${MAKE:-make}).
1719 dnl #### -msokolov
1720 AC_DEFUN(
1721   GLIBCPP_CHECK_GNU_MAKE, [AC_CACHE_CHECK( for GNU make,_cv_gnu_make_command,
1722           _cv_gnu_make_command='' ;
1723 dnl Search all the common names for GNU make
1724           for a in "${MAKE-make}" make gmake gnumake ; do
1725                   if ( $a --version 2> /dev/null | grep -c GNU > /dev/null )
1726                   then
1727                           _cv_gnu_make_command=$a ;
1728                           break;
1729                   fi
1730           done ;
1731   ) ;
1732 dnl If there was a GNU version, then set @ifGNUmake@ to the empty
1733 dnl string, '#' otherwise
1734   if test  "x$_cv_gnu_make_command" != "x"  ; then
1735           ifGNUmake='' ;
1736   else
1737           ifGNUmake='#' ;
1738   fi
1739   AC_SUBST(ifGNUmake)
1740 ])
1741
1742 sinclude(../libtool.m4)
1743 dnl The lines below arrange for aclocal not to bring an installed
1744 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
1745 dnl add a definition of LIBTOOL to Makefile.in.
1746 ifelse(,,,[AC_SUBST(LIBTOOL)
1747 AC_DEFUN([AM_PROG_LIBTOOL])
1748 AC_DEFUN([AC_LIBTOOL_DLOPEN])
1749 AC_DEFUN([AC_PROG_LD])
1750 ])
1751
1752
1753
1754 # Do all the work for Automake.  This macro actually does too much --
1755 # some checks are only needed if your package does certain things.
1756 # But this isn't really a big deal.
1757
1758 # serial 1
1759
1760 dnl Usage:
1761 dnl AM_INIT_AUTOMAKE(package,version, [no-define])
1762
1763 AC_DEFUN(AM_INIT_AUTOMAKE,
1764 [AC_REQUIRE([AC_PROG_INSTALL])
1765 PACKAGE=[$1]
1766 AC_SUBST(PACKAGE)
1767 VERSION=[$2]
1768 AC_SUBST(VERSION)
1769 dnl test to see if srcdir already configured
1770 if test "`cd $srcdir && pwd`" != "`pwd`" && test -f $srcdir/config.status; then
1771   AC_MSG_ERROR([source directory already configured; run "make distclean" there first])
1772 fi
1773 ifelse([$3],,
1774 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of package])
1775 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version number of package]))
1776 AC_REQUIRE([AM_SANITY_CHECK])
1777 AC_REQUIRE([AC_ARG_PROGRAM])
1778 dnl FIXME This is truly gross.
1779 missing_dir=`cd $ac_aux_dir && pwd`
1780 AM_MISSING_PROG(ACLOCAL, aclocal, $missing_dir)
1781 AM_MISSING_PROG(AUTOCONF, autoconf, $missing_dir)
1782 AM_MISSING_PROG(AUTOMAKE, automake, $missing_dir)
1783 AM_MISSING_PROG(AUTOHEADER, autoheader, $missing_dir)
1784 AM_MISSING_PROG(MAKEINFO, makeinfo, $missing_dir)
1785 AC_REQUIRE([AC_PROG_MAKE_SET])])
1786
1787 #
1788 # Check to make sure that the build environment is sane.
1789 #
1790
1791 AC_DEFUN(AM_SANITY_CHECK,
1792 [AC_MSG_CHECKING([whether build environment is sane])
1793 # Just in case
1794 sleep 1
1795 echo timestamp > conftestfile
1796 # Do `set' in a subshell so we don't clobber the current shell's
1797 # arguments.  Must try -L first in case configure is actually a
1798 # symlink; some systems play weird games with the mod time of symlinks
1799 # (eg FreeBSD returns the mod time of the symlink's containing
1800 # directory).
1801 if (
1802    set X `ls -Lt $srcdir/configure conftestfile 2> /dev/null`
1803    if test "[$]*" = "X"; then
1804       # -L didn't work.
1805       set X `ls -t $srcdir/configure conftestfile`
1806    fi
1807    if test "[$]*" != "X $srcdir/configure conftestfile" \
1808       && test "[$]*" != "X conftestfile $srcdir/configure"; then
1809
1810       # If neither matched, then we have a broken ls.  This can happen
1811       # if, for instance, CONFIG_SHELL is bash and it inherits a
1812       # broken ls alias from the environment.  This has actually
1813       # happened.  Such a system could not be considered "sane".
1814       AC_MSG_ERROR([ls -t appears to fail.  Make sure there is not a broken
1815 alias in your environment])
1816    fi
1817
1818    test "[$]2" = conftestfile
1819    )
1820 then
1821    # Ok.
1822    :
1823 else
1824    AC_MSG_ERROR([newly created file is older than distributed files!
1825 Check your system clock])
1826 fi
1827 rm -f conftest*
1828 AC_MSG_RESULT(yes)])
1829
1830 dnl AM_MISSING_PROG(NAME, PROGRAM, DIRECTORY)
1831 dnl The program must properly implement --version.
1832 AC_DEFUN(AM_MISSING_PROG,
1833 [AC_MSG_CHECKING(for working $2)
1834 # Run test in a subshell; some versions of sh will print an error if
1835 # an executable is not found, even if stderr is redirected.
1836 # Redirect stdin to placate older versions of autoconf.  Sigh.
1837 if ($2 --version) < /dev/null > /dev/null 2>&1; then
1838    $1=$2
1839    AC_MSG_RESULT(found)
1840 else
1841    $1="$3/missing $2"
1842    AC_MSG_RESULT(missing)
1843 fi
1844 AC_SUBST($1)])
1845
1846 # Add --enable-maintainer-mode option to configure.
1847 # From Jim Meyering
1848
1849 # serial 1
1850
1851 AC_DEFUN(AM_MAINTAINER_MODE,
1852 [AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
1853   dnl maintainer-mode is disabled by default
1854   AC_ARG_ENABLE(maintainer-mode,
1855 [  --enable-maintainer-mode enable make rules and dependencies not useful
1856                           (and sometimes confusing) to the casual installer],
1857       USE_MAINTAINER_MODE=$enableval,
1858       USE_MAINTAINER_MODE=no)
1859   AC_MSG_RESULT($USE_MAINTAINER_MODE)
1860   AM_CONDITIONAL(MAINTAINER_MODE, test $USE_MAINTAINER_MODE = yes)
1861   MAINT=$MAINTAINER_MODE_TRUE
1862   AC_SUBST(MAINT)dnl
1863 ]
1864 )
1865
1866 # Define a conditional.
1867
1868 AC_DEFUN(AM_CONDITIONAL,
1869 [AC_SUBST($1_TRUE)
1870 AC_SUBST($1_FALSE)
1871 if $2; then
1872   $1_TRUE=
1873   $1_FALSE='#'
1874 else
1875   $1_TRUE='#'
1876   $1_FALSE=
1877 fi])
1878
1879 # Like AC_CONFIG_HEADER, but automatically create stamp file.
1880
1881 AC_DEFUN(AM_CONFIG_HEADER,
1882 [AC_PREREQ([2.12])
1883 AC_CONFIG_HEADER([$1])
1884 dnl When config.status generates a header, we must update the stamp-h file.
1885 dnl This file resides in the same directory as the config header
1886 dnl that is generated.  We must strip everything past the first ":",
1887 dnl and everything past the last "/".
1888 AC_OUTPUT_COMMANDS(changequote(<<,>>)dnl
1889 ifelse(patsubst(<<$1>>, <<[^ ]>>, <<>>), <<>>,
1890 <<test -z "<<$>>CONFIG_HEADERS" || echo timestamp > patsubst(<<$1>>, <<^\([^:]*/\)?.*>>, <<\1>>)stamp-h<<>>dnl>>,
1891 <<am_indx=1
1892 for am_file in <<$1>>; do
1893   case " <<$>>CONFIG_HEADERS " in
1894   *" <<$>>am_file "*<<)>>
1895     echo timestamp > `echo <<$>>am_file | sed -e 's%:.*%%' -e 's%[^/]*$%%'`stamp-h$am_indx
1896     ;;
1897   esac
1898   am_indx=`expr "<<$>>am_indx" + 1`
1899 done<<>>dnl>>)
1900 changequote([,]))])
1901