libstdc++-v3/acinclude.m4

   1
   2 dnl
   3 dnl GLIBCXX_CONDITIONAL (NAME, SHELL-TEST)
   4 dnl
   5 dnl Exactly like AM_CONDITIONAL, but delays evaluation of the test until the
   6 dnl end of configure.  This lets tested variables be reassigned, and the
   7 dnl conditional will depend on the final state of the variable.  For a simple
   8 dnl example of why this is needed, see GLIBCXX_ENABLE_HOSTED.
   9 dnl
  10 m4_define([_m4_divert(glibcxx_diversion)], 8000)dnl
  11 AC_DEFUN(GLIBCXX_CONDITIONAL, [dnl
  12   m4_divert_text([glibcxx_diversion],dnl
  13    AM_CONDITIONAL([$1],[$2])
  14   )dnl
  15 ])dnl
  16 AC_DEFUN(GLIBCXX_EVALUATE_CONDITIONALS, [m4_undivert([glibcxx_diversion])])dnl
  17
  18
  19 dnl
  20 dnl Check to see what architecture and operating system we are compiling
  21 dnl for.  Also, if architecture- or OS-specific flags are required for
  22 dnl compilation, pick them up here.
  23 dnl
  24 AC_DEFUN(GLIBCXX_CHECK_HOST, [
  25   . $glibcxx_srcdir/configure.host
  26   AC_MSG_NOTICE(CPU config directory is $cpu_include_dir)
  27   AC_MSG_NOTICE(OS config directory is $os_include_dir)
  28 ])
  29
  30
  31 dnl
  32 dnl Initialize basic configure bits.
  33 dnl
  34 dnl Substs:
  35 dnl  multi_basedir
  36 dnl
  37 AC_DEFUN(GLIBCXX_TOPREL_CONFIGURE, [
  38   # Sets up multi_basedir, which is srcdir/.. plus the usual
  39   # "multi_source_toprel_bottom_adjust" lunacy as needed.
  40   AM_ENABLE_MULTILIB(, ..)
  41
  42   # The generated code is exactly the same, except that automake's looks in
  43   # ".. $srcdir/.." and autoconf's looks in multi_basedir.  Apparently other
  44   # things are triggered on the presence of the two ...AUX_DIR[S], but I don't
  45   # know what they are or what the other differences might be (and they keep
  46   # changing anyhow).
  47   #
  48   # Looking in multi_basedir seems smarter, so actually execute that branch.
  49   if false; then
  50     # this is for automake
  51     AC_CONFIG_AUX_DIR(..)
  52   else
  53     # this is for autoconf
  54     AC_CONFIG_AUX_DIRS(${multi_basedir})
  55   fi
  56
  57   dnl XXX Turn this on.
  58   dnl AC_LANG_CPLUSPLUS
  59 ])
  60
  61
  62 dnl
  63 dnl Initialize the rest of the library configury.  At this point we have
  64 dnl variables like $host.
  65 dnl
  66 dnl Sets:
  67 dnl  gcc_version          (x.y.z format)
  68 dnl  SUBDIRS
  69 dnl Substs:
  70 dnl  glibcxx_builddir     (absolute path)
  71 dnl  glibcxx_srcdir       (absolute path)
  72 dnl  toplevel_srcdir      (absolute path)
  73 dnl  with_cross_host
  74 dnl  with_newlib
  75 dnl  with_target_subdir
  76 dnl plus
  77 dnl  - the variables in GLIBCXX_CHECK_HOST / configure.host
  78 dnl  - default settings for all AM_CONFITIONAL test variables
  79 dnl  - lots of tools, like CC and CXX
  80 dnl
  81 AC_DEFUN(GLIBCXX_CONFIGURE, [
  82   # Keep these sync'd with the list in Makefile.am.  The first provides an
  83   # expandable list at autoconf time; the second provides an expandable list
  84   # (i.e., shell variable) at configure time.
  85   m4_define([glibcxx_SUBDIRS],[include libmath libsupc++ src po testsuite])
  86   SUBDIRS='glibcxx_SUBDIRS'
  87
  88   # These need to be absolute paths, yet at the same time need to
  89   # canonicalize only relative paths, because then amd will not unmount
  90   # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
  91   glibcxx_builddir=`${PWDCMD-pwd}`
  92   case $srcdir in
  93     [\\/$]* | ?:[\\/]*) glibcxx_srcdir=${srcdir} ;;
  94     *) glibcxx_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
  95   esac
  96   toplevel_srcdir=${glibcxx_srcdir}/..
  97   AC_SUBST(glibcxx_builddir)
  98   AC_SUBST(glibcxx_srcdir)
  99   AC_SUBST(toplevel_srcdir)
 100
 101   # We use these options to decide which functions to include.  They are
 102   # set from the top level.
 103   AC_ARG_WITH([target-subdir],
 104     AC_HELP_STRING([--with-target-subdir=SUBDIR],
 105                    [configuring in a subdirectory]))
 106
 107   AC_ARG_WITH([cross-host],
 108     AC_HELP_STRING([--with-cross-host=HOST],
 109                    [configuring with a cross compiler]))
 110
 111   AC_ARG_WITH([newlib],
 112     AC_HELP_STRING([--with-newlib],
 113                    [assume newlib as a system C library]))
 114
 115   # We're almost certainly being configured before anything else which uses
 116   # C++, so all of our AC_PROG_* discoveries will be cached.  It's vital that
 117   # we not cache the value of CXX that we "discover" here, because it's set
 118   # to something unique for us and libjava.  Other target libraries need to
 119   # find CXX for themselves.  We yank the rug out from under the normal AC_*
 120   # process by sneakily renaming the cache variable.  This also lets us debug
 121   # the value of "our" CXX in postmortems.
 122   #
 123   # We must also force CXX to /not/ be a precious variable, otherwise the
 124   # wrong (non-multilib-adjusted) value will be used in multilibs.  This
 125   # little trick also affects CPPFLAGS, CXXFLAGS, and LDFLAGS.  And as a side
 126   # effect, CXXFLAGS is no longer automagically subst'd, so we have to do
 127   # that ourselves.  Un-preciousing AC_PROG_CC also affects CC and CFLAGS.
 128   #
 129   # -fno-builtin must be present here so that a non-conflicting form of
 130   # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
 131
 132   m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
 133   m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 134   m4_define([_AC_ARG_VAR_PRECIOUS],[])
 135   save_CXXFLAGS="$CXXFLAGS"
 136   CXXFLAGS="$CXXFLAGS -fno-builtin"
 137   AC_PROG_CC
 138   AC_PROG_CXX
 139   CXXFLAGS="$save_CXXFLAGS"
 140   m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 141   AC_SUBST(CFLAGS)
 142   AC_SUBST(CXXFLAGS)
 143
 144   # For directory versioning (e.g., headers) and other variables.
 145   AC_MSG_CHECKING([for GCC version number])
 146   gcc_version=`$CXX -dumpversion`
 147   AC_MSG_RESULT($gcc_version)
 148
 149   # Will set LN_S to either 'ln -s', 'ln', or 'cp -p' (if linking isn't
 150   # available).  Uncomment the next line to force a particular method.
 151   AC_PROG_LN_S
 152   #LN_S='cp -p'
 153
 154   AC_CHECK_TOOL(AS, as)
 155   AC_CHECK_TOOL(AR, ar)
 156   AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 157
 158   AM_MAINTAINER_MODE
 159
 160   # Set up safe default values for all subsequent AM_CONDITIONAL tests
 161   # which are themselves conditionally expanded.
 162   ## (Right now, this only matters for enable_wchar_t, but nothing prevents
 163   ## other macros from doing the same.  This should be automated.)  -pme
 164   need_libmath=no
 165   enable_wchar_t=no
 166   #enable_libstdcxx_debug=no
 167   #enable_libstdcxx_pch=no
 168   #enable_cheaders=c
 169   #c_compatibility=no
 170   #enable_abi_check=no
 171   #enable_symvers=no
 172   #enable_hosted_libstdcxx=yes
 173
 174   # Find platform-specific directories containing configuration info.
 175   # Also possibly modify flags used elsewhere, as needed by the platform.
 176   GLIBCXX_CHECK_HOST
 177 ])
 178
 179
 180 m4_include([linkage.m4])
 181 m4_include([../config/no-executables.m4])
 182
 183
 184 dnl
 185 dnl Tests for newer compiler features, or features that are present in newer
 186 dnl compiler versions but not older compiler versions still in use, should
 187 dnl be placed here.
 188 dnl
 189 dnl Defines:
 190 dnl  WERROR='-Werror' if requested and possible; g++'s that lack the
 191 dnl   new inlining code or the new system_header pragma will die on -Werror.
 192 dnl   Leave it out by default and use maint-mode to use it.
 193 dnl  SECTION_FLAGS='-ffunction-sections -fdata-sections' if
 194 dnl   compiler supports it and the user has not requested debug mode.
 195 dnl
 196 AC_DEFUN(GLIBCXX_CHECK_COMPILER_FEATURES, [
 197   # All these tests are for C++; save the language and the compiler flags.
 198   # The CXXFLAGS thing is suspicious, but based on similar bits previously
 199   # found in GLIBCXX_CONFIGURE.
 200   AC_LANG_SAVE
 201   AC_LANG_CPLUSPLUS
 202   ac_test_CXXFLAGS="${CXXFLAGS+set}"
 203   ac_save_CXXFLAGS="$CXXFLAGS"
 204
 205   # Check for maintainer-mode bits.
 206   if test x"$USE_MAINTAINER_MODE" = xno; then
 207     WERROR=''
 208   else
 209     WERROR='-Werror'
 210   fi
 211
 212   # Check for -ffunction-sections -fdata-sections
 213   AC_MSG_CHECKING([for g++ that supports -ffunction-sections -fdata-sections])
 214   CXXFLAGS='-Werror -ffunction-sections -fdata-sections'
 215   AC_TRY_COMPILE(, [int foo;], [ac_fdsections=yes], [ac_fdsections=no])
 216   if test "$ac_test_CXXFLAGS" = set; then
 217     CXXFLAGS="$ac_save_CXXFLAGS"
 218   else
 219     # this is the suspicious part
 220     CXXFLAGS=''
 221   fi
 222   if test x"$ac_fdsections" = x"yes"; then
 223     SECTION_FLAGS='-ffunction-sections -fdata-sections'
 224   fi
 225   AC_MSG_RESULT($ac_fdsections)
 226
 227   AC_LANG_RESTORE
 228   AC_SUBST(WERROR)
 229   AC_SUBST(SECTION_FLAGS)
 230 ])
 231
 232
 233 dnl
 234 dnl If GNU ld is in use, check to see if tricky linker opts can be used.  If
 235 dnl the native linker is in use, all variables will be defined to something
 236 dnl safe (like an empty string).
 237 dnl
 238 dnl Defines:
 239 dnl  SECTION_LDFLAGS='-Wl,--gc-sections' if possible
 240 dnl  OPT_LDFLAGS='-Wl,-O1' if possible
 241 dnl  LD (as a side effect of testing)
 242 dnl Sets:
 243 dnl  with_gnu_ld
 244 dnl  glibcxx_gnu_ld_version (possibly)
 245 dnl
 246 dnl The last will be a single integer, e.g., version 1.23.45.0.67.89 will
 247 dnl set glibcxx_gnu_ld_version to 12345.  Zeros cause problems.
 248 dnl
 249 AC_DEFUN(GLIBCXX_CHECK_LINKER_FEATURES, [
 250   # If we're not using GNU ld, then there's no point in even trying these
 251   # tests.  Check for that first.  We should have already tested for gld
 252   # by now (in libtool), but require it now just to be safe...
 253   test -z "$SECTION_LDFLAGS" && SECTION_LDFLAGS=''
 254   test -z "$OPT_LDFLAGS" && OPT_LDFLAGS=''
 255   AC_REQUIRE([AC_PROG_LD])
 256   AC_REQUIRE([AC_PROG_AWK])
 257
 258   # The name set by libtool depends on the version of libtool.  Shame on us
 259   # for depending on an impl detail, but c'est la vie.  Older versions used
 260   # ac_cv_prog_gnu_ld, but now it's lt_cv_prog_gnu_ld, and is copied back on
 261   # top of with_gnu_ld (which is also set by --with-gnu-ld, so that actually
 262   # makes sense).  We'll test with_gnu_ld everywhere else, so if that isn't
 263   # set (hence we're using an older libtool), then set it.
 264   if test x${with_gnu_ld+set} != xset; then
 265     if test x${ac_cv_prog_gnu_ld+set} != xset; then
 266       # We got through "ac_require(ac_prog_ld)" and still not set?  Huh?
 267       with_gnu_ld=no
 268     else
 269       with_gnu_ld=$ac_cv_prog_gnu_ld
 270     fi
 271   fi
 272
 273   # Start by getting the version number.  I think the libtool test already
 274   # does some of this, but throws away the result.
 275   changequote(,)
 276   ldver=`$LD --version 2>/dev/null | head -1 | \
 277          sed -e 's/GNU ld version \([0-9.][0-9.]*\).*/\1/'`
 278   changequote([,])
 279   glibcxx_gnu_ld_version=`echo $ldver | \
 280          $AWK -F. '{ if (NF<3) [$]3=0; print ([$]1*100+[$]2)*100+[$]3 }'`
 281
 282   # Set --gc-sections.
 283   if test "$with_gnu_ld" = "notbroken"; then
 284     # GNU ld it is!  Joy and bunny rabbits!
 285
 286     # All these tests are for C++; save the language and the compiler flags.
 287     # Need to do this so that g++ won't try to link in libstdc++
 288     ac_test_CFLAGS="${CFLAGS+set}"
 289     ac_save_CFLAGS="$CFLAGS"
 290     CFLAGS='-x c++  -Wl,--gc-sections'
 291
 292     # Check for -Wl,--gc-sections
 293     # XXX This test is broken at the moment, as symbols required for linking
 294     # are now in libsupc++ (not built yet).  In addition, this test has
 295     # cored on solaris in the past.  In addition, --gc-sections doesn't
 296     # really work at the moment (keeps on discarding used sections, first
 297     # .eh_frame and now some of the glibc sections for iconv).
 298     # Bzzzzt.  Thanks for playing, maybe next time.
 299     AC_MSG_CHECKING([for ld that supports -Wl,--gc-sections])
 300     AC_TRY_RUN([
 301      int main(void)
 302      {
 303        try { throw 1; }
 304        catch (...) { };
 305        return 0;
 306      }
 307     ], [ac_sectionLDflags=yes],[ac_sectionLDflags=no], [ac_sectionLDflags=yes])
 308     if test "$ac_test_CFLAGS" = set; then
 309       CFLAGS="$ac_save_CFLAGS"
 310     else
 311       # this is the suspicious part
 312       CFLAGS=''
 313     fi
 314     if test "$ac_sectionLDflags" = "yes"; then
 315       SECTION_LDFLAGS="-Wl,--gc-sections $SECTION_LDFLAGS"
 316     fi
 317     AC_MSG_RESULT($ac_sectionLDflags)
 318   fi
 319
 320   # Set linker optimization flags.
 321   if test x"$with_gnu_ld" = x"yes"; then
 322     OPT_LDFLAGS="-Wl,-O1 $OPT_LDFLAGS"
 323   fi
 324
 325   AC_SUBST(SECTION_LDFLAGS)
 326   AC_SUBST(OPT_LDFLAGS)
 327 ])
 328
 329
 330 dnl
 331 dnl Check to see if this target can enable the wchar_t parts.
 332 dnl If --disable-c-mbchar was given, no wchar_t stuff is enabled.  (This
 333 dnl must have been previously checked.)  By default, wide characters are
 334 dnl disabled.
 335 dnl
 336 dnl Defines:
 337 dnl  HAVE_MBSTATE_T if mbstate_t is not in wchar.h
 338 dnl  _GLIBCXX_USE_WCHAR_T if all the bits are found.
 339 dnl
 340 AC_DEFUN(GLIBCXX_CHECK_WCHAR_T_SUPPORT, [
 341   # Test wchar.h for mbstate_t, which is needed for char_traits and
 342   # others even if wchar_t support is not on.
 343   AC_MSG_CHECKING([for mbstate_t])
 344   AC_TRY_COMPILE([#include <wchar.h>],
 345   [mbstate_t teststate;],
 346   have_mbstate_t=yes, have_mbstate_t=no)
 347   AC_MSG_RESULT($have_mbstate_t)
 348   if test x"$have_mbstate_t" = xyes; then
 349     AC_DEFINE(HAVE_MBSTATE_T)
 350   fi
 351
 352   # Sanity check for existence of ISO C99 headers for extended encoding.
 353   AC_CHECK_HEADERS(wchar.h, ac_has_wchar_h=yes, ac_has_wchar_h=no)
 354   AC_CHECK_HEADERS(wctype.h, ac_has_wctype_h=yes, ac_has_wctype_h=no)
 355
 356   # Only continue checking if the ISO C99 headers exist and support is on.
 357   if test x"$ac_has_wchar_h" = xyes &&
 358      test x"$ac_has_wctype_h" = xyes &&
 359      test x"$enable_c_mbchar" != xno; then
 360
 361     # Test wchar.h for WCHAR_MIN, WCHAR_MAX, which is needed before
 362     # numeric_limits can instantiate type_traits<wchar_t>
 363     AC_MSG_CHECKING([for WCHAR_MIN and WCHAR_MAX])
 364     AC_TRY_COMPILE([#include <wchar.h>],
 365     [int i = WCHAR_MIN; int j = WCHAR_MAX;],
 366     has_wchar_minmax=yes, has_wchar_minmax=no)
 367     AC_MSG_RESULT($has_wchar_minmax)
 368
 369     # Test wchar.h for WEOF, which is what we use to determine whether
 370     # to specialize for char_traits<wchar_t> or not.
 371     AC_MSG_CHECKING([for WEOF])
 372     AC_TRY_COMPILE([
 373       #include <wchar.h>
 374       #include <stddef.h>],
 375     [wint_t i = WEOF;],
 376     has_weof=yes, has_weof=no)
 377     AC_MSG_RESULT($has_weof)
 378
 379     # Tests for wide character functions used in char_traits<wchar_t>.
 380     ac_wfuncs=yes
 381     AC_CHECK_FUNCS([wcslen wmemchr wmemcmp wmemcpy wmemmove wmemset],
 382     [],[ac_wfuncs=no])
 383
 384     # Checks for names injected into std:: by the c_std headers.
 385     AC_CHECK_FUNCS([btowc wctob fgetwc fgetws fputwc fputws fwide \
 386     fwprintf fwscanf swprintf swscanf vfwprintf vswprintf \
 387     vwprintf wprintf wscanf getwc getwchar mbsinit mbrlen mbrtowc \
 388     mbsrtowcs wcsrtombs putwc putwchar ungetwc wcrtomb wcstod wcstol \
 389     wcstoul wcscpy wcsncpy wcscat wcsncat wcscmp wcscoll wcsncmp wcsxfrm \
 390     wcscspn wcsspn wcstok wcsftime wcschr wcspbrk wcsrchr wcsstr],
 391     [],[ac_wfuncs=no])
 392
 393     # Checks for wide character functions that are not required
 394     # for basic wchar_t support.  Don't disable support if they are missing.
 395     # Injection of these is wrapped with guard macros.
 396     AC_CHECK_FUNCS([vfwscanf vswscanf vwscanf wcstof iswblank],[],[])
 397
 398     AC_MSG_CHECKING([for ISO C99 wchar_t support])
 399     if test x"$has_weof" = xyes &&
 400        test x"$has_wchar_minmax" = xyes &&
 401        test x"$ac_wfuncs" = xyes;
 402     then
 403       ac_isoC99_wchar_t=yes
 404     else
 405       ac_isoC99_wchar_t=no
 406     fi
 407     AC_MSG_RESULT($ac_isoC99_wchar_t)
 408
 409     # Use iconv for wchar_t to char conversions. As such, check for
 410     # X/Open Portability Guide, version 2 features (XPG2).
 411     AC_CHECK_HEADER(iconv.h, ac_has_iconv_h=yes, ac_has_iconv_h=no)
 412     AC_CHECK_HEADER(langinfo.h, ac_has_langinfo_h=yes, ac_has_langinfo_h=no)
 413
 414     # Check for existence of libiconv.a providing XPG2 wchar_t support.
 415     AC_CHECK_LIB(iconv, iconv, libiconv="-liconv")
 416     ac_save_LIBS="$LIBS"
 417     LIBS="$LIBS $libiconv"
 418
 419     AC_CHECK_FUNCS([iconv_open iconv_close iconv nl_langinfo],
 420     [ac_XPG2funcs=yes], [ac_XPG2funcs=no])
 421
 422     LIBS="$ac_save_LIBS"
 423
 424     AC_MSG_CHECKING([for XPG2 wchar_t support])
 425     if test x"$ac_has_iconv_h" = xyes &&
 426        test x"$ac_has_langinfo_h" = xyes &&
 427        test x"$ac_XPG2funcs" = xyes;
 428     then
 429       ac_XPG2_wchar_t=yes
 430     else
 431       ac_XPG2_wchar_t=no
 432     fi
 433     AC_MSG_RESULT($ac_XPG2_wchar_t)
 434
 435     # At the moment, only enable wchar_t specializations if all the
 436     # above support is present.
 437     if test x"$ac_isoC99_wchar_t" = xyes &&
 438        test x"$ac_XPG2_wchar_t" = xyes;
 439     then
 440       AC_DEFINE(_GLIBCXX_USE_WCHAR_T)
 441       enable_wchar_t=yes
 442     fi
 443   fi
 444   AC_MSG_CHECKING([for enabled wchar_t specializations])
 445   AC_MSG_RESULT($enable_wchar_t)
 446 ])
 447
 448
 449 dnl
 450 dnl Check for headers for, and arguments to, the setrlimit() function.
 451 dnl Used only in testsuite_hooks.h.  Called from GLIBCXX_CONFIGURE_TESTSUITE.
 452 dnl
 453 dnl Defines:
 454 dnl  _GLIBCXX_MEM_LIMITS if we can set artificial limits on memory
 455 dnl  various HAVE_MEMLIMIT_* for individual limit names
 456 dnl
 457 AC_DEFUN(GLIBCXX_CHECK_SETRLIMIT_ancilliary, [
 458   AC_TRY_COMPILE(
 459     [#include <unistd.h>
 460      #include <sys/time.h>
 461      #include <sys/resource.h>
 462     ],
 463     [ int f = RLIMIT_$1 ; ],
 464     [glibcxx_mresult=1], [glibcxx_mresult=0])
 465   AC_DEFINE_UNQUOTED(HAVE_MEMLIMIT_$1, $glibcxx_mresult,
 466                      [Only used in build directory testsuite_hooks.h.])
 467 ])
 468
 469 AC_DEFUN(GLIBCXX_CHECK_SETRLIMIT, [
 470   setrlimit_have_headers=yes
 471   AC_CHECK_HEADERS(unistd.h sys/time.h sys/resource.h,
 472                    [],
 473                    [setrlimit_have_headers=no])
 474   # If don't have the headers, then we can't run the tests now, and we
 475   # won't be seeing any of these during testsuite compilation.
 476   if test $setrlimit_have_headers = yes; then
 477     # Can't do these in a loop, else the resulting syntax is wrong.
 478     GLIBCXX_CHECK_SETRLIMIT_ancilliary(DATA)
 479     GLIBCXX_CHECK_SETRLIMIT_ancilliary(RSS)
 480     GLIBCXX_CHECK_SETRLIMIT_ancilliary(VMEM)
 481     GLIBCXX_CHECK_SETRLIMIT_ancilliary(AS)
 482
 483     # Check for rlimit, setrlimit.
 484     AC_CACHE_VAL(ac_setrlimit, [
 485       AC_TRY_COMPILE(
 486         [#include <unistd.h>
 487          #include <sys/time.h>
 488          #include <sys/resource.h>
 489         ],
 490         [struct rlimit r;
 491          setrlimit(0, &r);],
 492         [ac_setrlimit=yes], [ac_setrlimit=no])
 493     ])
 494   fi
 495
 496   AC_MSG_CHECKING([for testsuite memory limit support])
 497   if test $setrlimit_have_headers = yes && test $ac_setrlimit = yes; then
 498     ac_mem_limits=yes
 499     AC_DEFINE(_GLIBCXX_MEM_LIMITS)
 500   else
 501     ac_mem_limits=no
 502   fi
 503   AC_MSG_RESULT($ac_mem_limits)
 504 ])
 505
 506
 507 dnl
 508 dnl Check whether S_ISREG (Posix) or S_IFREG is available in <sys/stat.h>.
 509 dnl Define HAVE_S_ISREG / HAVE_S_IFREG appropriately.
 510 dnl
 511 AC_DEFUN(GLIBCXX_CHECK_S_ISREG_OR_S_IFREG, [
 512   AC_CACHE_VAL(glibcxx_cv_S_ISREG, [
 513     AC_TRY_LINK(
 514       [#include <sys/stat.h>],
 515       [struct stat buffer;
 516        fstat(0, &buffer);
 517        S_ISREG(buffer.st_mode);],
 518       [glibcxx_cv_S_ISREG=yes],
 519       [glibcxx_cv_S_ISREG=no])
 520   ])
 521   AC_CACHE_VAL(glibcxx_cv_S_IFREG, [
 522     AC_TRY_LINK(
 523       [#include <sys/stat.h>],
 524       [struct stat buffer;
 525        fstat(0, &buffer);
 526        S_IFREG & buffer.st_mode;],
 527       [glibcxx_cv_S_IFREG=yes],
 528       [glibcxx_cv_S_IFREG=no])
 529   ])
 530   if test $glibcxx_cv_S_ISREG = yes; then
 531     AC_DEFINE(HAVE_S_ISREG)
 532   elif test $glibcxx_cv_S_IFREG = yes; then
 533     AC_DEFINE(HAVE_S_IFREG)
 534   fi
 535 ])
 536
 537
 538 dnl
 539 dnl Check whether poll is available in <poll.h>, and define HAVE_POLL.
 540 dnl
 541 AC_DEFUN(GLIBCXX_CHECK_POLL, [
 542   AC_CACHE_VAL(glibcxx_cv_POLL, [
 543     AC_TRY_COMPILE(
 544       [#include <poll.h>],
 545       [struct pollfd pfd[1];
 546        pfd[0].events = POLLIN;
 547        poll(pfd, 1, 0);],
 548       [glibcxx_cv_POLL=yes],
 549       [glibcxx_cv_POLL=no])
 550   ])
 551   if test $glibcxx_cv_POLL = yes; then
 552     AC_DEFINE(HAVE_POLL)
 553   fi
 554 ])
 555
 556
 557 dnl
 558 dnl Check whether writev is available in <sys/uio.h>, and define HAVE_WRITEV.
 559 dnl
 560 AC_DEFUN(GLIBCXX_CHECK_WRITEV, [
 561   AC_CACHE_VAL(glibcxx_cv_WRITEV, [
 562     AC_TRY_COMPILE(
 563       [#include <sys/uio.h>],
 564       [struct iovec iov[2];
 565        writev(0, iov, 0);],
 566       [glibcxx_cv_WRITEV=yes],
 567       [glibcxx_cv_WRITEV=no])
 568   ])
 569   if test $glibcxx_cv_WRITEV = yes; then
 570     AC_DEFINE(HAVE_WRITEV)
 571   fi
 572 ])
 573
 574
 575 dnl
 576 dnl Does any necessary configuration of the testsuite directory.  Generates
 577 dnl the testsuite_hooks.h header.
 578 dnl
 579 dnl GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE must be done before this.
 580 dnl
 581 dnl Sets:
 582 dnl  enable_abi_check / GLIBCXX_TEST_ABI
 583 dnl Substs:
 584 dnl  baseline_dir
 585 dnl
 586 AC_DEFUN(GLIBCXX_CONFIGURE_TESTSUITE, [
 587   if $GLIBCXX_IS_NATIVE && test $is_hosted = yes; then
 588     # Do checks for memory limit functions.
 589     GLIBCXX_CHECK_SETRLIMIT
 590
 591     # Look for setenv, so that extended locale tests can be performed.
 592     GLIBCXX_CHECK_STDLIB_DECL_AND_LINKAGE_3(setenv)
 593
 594     if test $enable_symvers = no; then
 595       enable_abi_check=no
 596     else
 597       case "$host" in
 598         *-*-cygwin*)
 599           enable_abi_check=no ;;
 600         *)
 601           enable_abi_check=yes ;;
 602       esac
 603     fi
 604   else
 605     # Only build this as native, since automake does not understand
 606     # CXX_FOR_BUILD.
 607     enable_abi_check=no
 608   fi
 609
 610   # Export file names for ABI checking.
 611   baseline_dir="$glibcxx_srcdir/config/abi/${abi_baseline_pair}\$(MULTISUBDIR)"
 612   AC_SUBST(baseline_dir)
 613
 614   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_WCHAR_T, test $enable_wchar_t = yes)
 615   GLIBCXX_CONDITIONAL(GLIBCXX_TEST_ABI, test $enable_abi_check = yes)
 616 ])
 617
 618
 619 dnl
 620 dnl Set up *_INCLUDES variables for all sundry Makefile.am's.
 621 dnl
 622 dnl Substs:
 623 dnl  GLIBCXX_INCLUDES
 624 dnl  TOPLEVEL_INCLUDES
 625 dnl
 626 AC_DEFUN(GLIBCXX_EXPORT_INCLUDES, [
 627   # Used for every C++ compile we perform.
 628   GLIBCXX_INCLUDES="\
 629 -I$glibcxx_builddir/include/$host_alias \
 630 -I$glibcxx_builddir/include \
 631 -I$glibcxx_srcdir/libsupc++"
 632
 633   # For Canadian crosses, pick this up too.
 634   if test $CANADIAN = yes; then
 635     GLIBCXX_INCLUDES="$GLIBCXX_INCLUDES -I\${includedir}"
 636   fi
 637
 638   # Stuff in the actual top level.  Currently only used by libsupc++ to
 639   # get unwind* headers from the gcc dir.
 640   #TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc -I$(toplevel_srcdir)/include'
 641   TOPLEVEL_INCLUDES='-I$(toplevel_srcdir)/gcc'
 642
 643   # Now, export this to all the little Makefiles....
 644   AC_SUBST(GLIBCXX_INCLUDES)
 645   AC_SUBST(TOPLEVEL_INCLUDES)
 646 ])
 647
 648
 649 dnl
 650 dnl Set up *_FLAGS and *FLAGS variables for all sundry Makefile.am's.
 651 dnl (SECTION_FLAGS is done under CHECK_COMPILER_FEATURES.)
 652 dnl
 653 dnl Substs:
 654 dnl  OPTIMIZE_CXXFLAGS
 655 dnl  WARN_FLAGS
 656 dnl
 657 AC_DEFUN(GLIBCXX_EXPORT_FLAGS, [
 658   # Optimization flags that are probably a good idea for thrill-seekers. Just
 659   # uncomment the lines below and make, everything else is ready to go...
 660   # OPTIMIZE_CXXFLAGS = -O3 -fstrict-aliasing -fvtable-gc
 661   OPTIMIZE_CXXFLAGS=
 662   AC_SUBST(OPTIMIZE_CXXFLAGS)
 663
 664   WARN_FLAGS='-Wall -W -Wwrite-strings -Wcast-qual'
 665   AC_SUBST(WARN_FLAGS)
 666 ])
 667
 668
 669 dnl
 670 dnl All installation directory information is determined here.
 671 dnl
 672 dnl Substs:
 673 dnl  gxx_install_dir
 674 dnl  glibcxx_prefixdir
 675 dnl  glibcxx_toolexecdir
 676 dnl  glibcxx_toolexeclibdir
 677 dnl
 678 dnl Assumes cross_compiling bits already done, and with_cross_host in
 679 dnl particular.
 680 dnl
 681 AC_DEFUN(GLIBCXX_EXPORT_INSTALL_INFO, [
 682   glibcxx_toolexecdir=no
 683   glibcxx_toolexeclibdir=no
 684   glibcxx_prefixdir=$prefix
 685
 686   AC_MSG_CHECKING([for gxx-include-dir])
 687   AC_ARG_WITH([gxx-include-dir],
 688     AC_HELP_STRING([--with-gxx-include-dir=DIR],
 689                    [installation directory for include files]),
 690     [case "$withval" in
 691       yes) AC_MSG_ERROR([Missing directory for --with-gxx-include-dir]) ;;
 692       no)  gxx_include_dir=no ;;
 693       *)   gxx_include_dir=$withval ;;
 694      esac],
 695     [gxx_include_dir=no])
 696   AC_MSG_RESULT($gxx_include_dir)
 697
 698   AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
 699   AC_ARG_ENABLE([version-specific-runtime-libs],
 700     AC_HELP_STRING([--enable-version-specific-runtime-libs],
 701                    [Specify that runtime libraries should be installed in a compiler-specific directory]),
 702     [case "$enableval" in
 703       yes) version_specific_libs=yes ;;
 704       no)  version_specific_libs=no ;;
 705       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
 706      esac],
 707     [version_specific_libs=no])
 708   AC_MSG_RESULT($version_specific_libs)
 709
 710   # Default case for install directory for include files.
 711   if test $version_specific_libs = no && test $gxx_include_dir = no; then
 712     gxx_include_dir='${prefix}'/include/c++/${gcc_version}
 713   fi
 714
 715   # Version-specific runtime libs processing.
 716   if test $version_specific_libs = yes; then
 717     # Need the gcc compiler version to know where to install libraries
 718     # and header files if --enable-version-specific-runtime-libs option
 719     # is selected.
 720     if test x"$gxx_include_dir" = x"no"; then
 721       gxx_include_dir='${libdir}/gcc-lib/${host_alias}/'$gcc_version/include/c++
 722     fi
 723     glibcxx_toolexecdir='${libdir}/gcc-lib/${host_alias}'
 724     glibcxx_toolexeclibdir='${toolexecdir}/'$gcc_version'$(MULTISUBDIR)'
 725   fi
 726
 727   # Calculate glibcxx_toolexecdir, glibcxx_toolexeclibdir
 728   # Install a library built with a cross compiler in tooldir, not libdir.
 729   if test x"$glibcxx_toolexecdir" = x"no"; then
 730     if test -n "$with_cross_host" &&
 731        test x"$with_cross_host" != x"no"; then
 732       glibcxx_toolexecdir='${exec_prefix}/${host_alias}'
 733       glibcxx_toolexeclibdir='${toolexecdir}/lib'
 734     else
 735       glibcxx_toolexecdir='${libdir}/gcc-lib/${host_alias}'
 736       glibcxx_toolexeclibdir='${libdir}'
 737     fi
 738     multi_os_directory=`$CXX -print-multi-os-directory`
 739     case $multi_os_directory in
 740       .) ;; # Avoid trailing /.
 741       *) glibcxx_toolexeclibdir=$glibcxx_toolexeclibdir/$multi_os_directory ;;
 742     esac
 743   fi
 744
 745   AC_MSG_CHECKING([for install location])
 746   AC_MSG_RESULT($gxx_include_dir)
 747
 748   AC_SUBST(glibcxx_prefixdir)
 749   AC_SUBST(gxx_include_dir)
 750   AC_SUBST(glibcxx_toolexecdir)
 751   AC_SUBST(glibcxx_toolexeclibdir)
 752 ])
 753
 754
 755 dnl
 756 dnl GLIBCXX_ENABLE
 757 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING)
 758 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, permit a|b|c)
 759 dnl    (FEATURE, DEFAULT, HELP-ARG, HELP-STRING, SHELL-CODE-HANDLER)
 760 dnl
 761 dnl See docs/html/17_intro/configury.html#enable for documentation.
 762 dnl
 763 m4_define([GLIBCXX_ENABLE],[dnl
 764 m4_define([_g_switch],[--enable-$1])dnl
 765 m4_define([_g_help],[AC_HELP_STRING(_g_switch$3,[$4 @<:@default=$2@:>@])])dnl
 766  AC_ARG_ENABLE($1,_g_help,
 767   m4_bmatch([$5],
 768    [^permit ],
 769      [[
 770       case "$enableval" in
 771        m4_bpatsubst([$5],[permit ])) ;;
 772        *) AC_MSG_ERROR(Unknown argument to enable/disable $1) ;;
 773           dnl Idea for future:  generate a URL pointing to
 774           dnl "onlinedocs/configopts.html#whatever"
 775       esac
 776      ]],
 777    [^$],
 778      [[
 779       case "$enableval" in
 780        yes|no) ;;
 781        *) AC_MSG_ERROR(Argument to enable/disable $1 must be yes or no) ;;
 782       esac
 783      ]],
 784    [[$5]]),
 785   [enable_]m4_bpatsubst([$1],-,_)[=][$2])
 786 m4_undefine([_g_switch])dnl
 787 m4_undefine([_g_help])dnl
 788 ])
 789
 790
 791 dnl
 792 dnl Check for ISO/IEC 9899:1999 "C99" support.
 793 dnl
 794 dnl --enable-c99 defines _GLIBCXX_USE_C99
 795 dnl --disable-c99 leaves _GLIBCXX_USE_C99 undefined
 796 dnl  +  Usage:  GLIBCXX_ENABLE_C99[(DEFAULT)]
 797 dnl       Where DEFAULT is either `yes' or `no'.
 798 dnl  +  If 'C99' stuff is not available, ignores DEFAULT and sets `no'.
 799 dnl
 800 AC_DEFUN(GLIBCXX_ENABLE_C99, [
 801   GLIBCXX_ENABLE(c99,$1,,[turns on ISO/IEC 9899:1999 support])
 802
 803   AC_LANG_SAVE
 804   AC_LANG_CPLUSPLUS
 805
 806   # Check for the existence of <math.h> functions used if C99 is enabled.
 807   ac_c99_math=yes;
 808   AC_MSG_CHECKING([for ISO C99 support in <math.h>])
 809   AC_TRY_COMPILE([#include <math.h>],[fpclassify(0.0);],, [ac_c99_math=no])
 810   AC_TRY_COMPILE([#include <math.h>],[isfinite(0.0);],, [ac_c99_math=no])
 811   AC_TRY_COMPILE([#include <math.h>],[isinf(0.0);],, [ac_c99_math=no])
 812   AC_TRY_COMPILE([#include <math.h>],[isnan(0.0);],, [ac_c99_math=no])
 813   AC_TRY_COMPILE([#include <math.h>],[isnormal(0.0);],, [ac_c99_math=no])
 814   AC_TRY_COMPILE([#include <math.h>],[signbit(0.0);],, [ac_c99_math=no])
 815   AC_TRY_COMPILE([#include <math.h>],[isgreater(0.0,0.0);],, [ac_c99_math=no])
 816   AC_TRY_COMPILE([#include <math.h>],
 817                  [isgreaterequal(0.0,0.0);],, [ac_c99_math=no])
 818   AC_TRY_COMPILE([#include <math.h>],[isless(0.0,0.0);],, [ac_c99_math=no])
 819   AC_TRY_COMPILE([#include <math.h>],[islessequal(0.0,0.0);],,[ac_c99_math=no])
 820   AC_TRY_COMPILE([#include <math.h>],
 821                  [islessgreater(0.0,0.0);],, [ac_c99_math=no])
 822   AC_TRY_COMPILE([#include <math.h>],
 823                  [isunordered(0.0,0.0);],, [ac_c99_math=no])
 824   AC_MSG_RESULT($ac_c99_math)
 825
 826   # Check for the existence in <stdio.h> of vscanf, et. al.
 827   ac_c99_stdio=yes;
 828   AC_MSG_CHECKING([for ISO C99 support in <stdio.h>])
 829   AC_TRY_COMPILE([#include <stdio.h>],
 830                  [snprintf("12", 0, "%i");],, [ac_c99_stdio=no])
 831   AC_TRY_COMPILE([#include <stdio.h>
 832                   #include <stdarg.h>
 833                   void foo(char* fmt, ...)
 834                   {va_list args; va_start(args, fmt);
 835                   vfscanf(stderr, "%i", args);}],
 836                   [],, [ac_c99_stdio=no])
 837   AC_TRY_COMPILE([#include <stdio.h>
 838                   #include <stdarg.h>
 839                   void foo(char* fmt, ...)
 840                   {va_list args; va_start(args, fmt);
 841                   vscanf("%i", args);}],
 842                   [],, [ac_c99_stdio=no])
 843   AC_TRY_COMPILE([#include <stdio.h>
 844                   #include <stdarg.h>
 845                   void foo(char* fmt, ...)
 846                   {va_list args; va_start(args, fmt);
 847                   vsnprintf(fmt, 0, "%i", args);}],
 848                   [],, [ac_c99_stdio=no])
 849   AC_TRY_COMPILE([#include <stdio.h>
 850                   #include <stdarg.h>
 851                   void foo(char* fmt, ...)
 852                   {va_list args; va_start(args, fmt);
 853                   vsscanf(fmt, "%i", args);}],
 854                   [],, [ac_c99_stdio=no])
 855   AC_MSG_RESULT($ac_c99_stdio)
 856
 857   # Check for the existence in <stdlib.h> of lldiv_t, et. al.
 858   ac_c99_stdlib=yes;
 859   AC_MSG_CHECKING([for lldiv_t declaration])
 860   AC_CACHE_VAL(ac_c99_lldiv_t, [
 861   AC_TRY_COMPILE([#include <stdlib.h>],
 862                    [ lldiv_t mydivt;],
 863                    [ac_c99_lldiv_t=yes], [ac_c99_lldiv_t=no])
 864   ])
 865   AC_MSG_RESULT($ac_c99_lldiv_t)
 866
 867   AC_MSG_CHECKING([for ISO C99 support in <stdlib.h>])
 868   AC_TRY_COMPILE([#include <stdlib.h>],
 869                  [char* tmp; strtof("gnu", &tmp);],, [ac_c99_stdlib=no])
 870   AC_TRY_COMPILE([#include <stdlib.h>],
 871                  [char* tmp; strtold("gnu", &tmp);],, [ac_c99_stdlib=no])
 872   AC_TRY_COMPILE([#include <stdlib.h>], [llabs(10);],, [ac_c99_stdlib=no])
 873   AC_TRY_COMPILE([#include <stdlib.h>], [lldiv(10,1);],, [ac_c99_stdlib=no])
 874   AC_TRY_COMPILE([#include <stdlib.h>], [atoll("10");],, [ac_c99_stdlib=no])
 875   AC_TRY_COMPILE([#include <stdlib.h>], [_Exit(0);],, [ac_c99_stdlib=no])
 876   if test x"$ac_c99_lldiv_t" = x"no"; then
 877     ac_c99_stdlib=no;
 878   fi;
 879   AC_MSG_RESULT($ac_c99_stdlib)
 880
 881   # Check for the existence of <wchar.h> functions used if C99 is enabled.
 882   # XXX the wchar.h checks should be rolled into the general C99 bits.
 883   ac_c99_wchar=yes;
 884   AC_MSG_CHECKING([for additional ISO C99 support in <wchar.h>])
 885   AC_TRY_COMPILE([#include <wchar.h>],
 886                  [wcstold(L"10.0", NULL);],, [ac_c99_wchar=no])
 887   AC_TRY_COMPILE([#include <wchar.h>],
 888                  [wcstoll(L"10", NULL, 10);],, [ac_c99_wchar=no])
 889   AC_TRY_COMPILE([#include <wchar.h>],
 890                  [wcstoull(L"10", NULL, 10);],, [ac_c99_wchar=no])
 891   AC_MSG_RESULT($ac_c99_wchar)
 892
 893   AC_MSG_CHECKING([for enabled ISO C99 support])
 894   if test x"$ac_c99_math" = x"no" ||
 895      test x"$ac_c99_stdio" = x"no" ||
 896      test x"$ac_c99_stdlib" = x"no" ||
 897      test x"$ac_c99_wchar" = x"no"; then
 898     enable_c99=no;
 899   fi;
 900   AC_MSG_RESULT($enable_c99)
 901
 902   # Option parsed, now set things appropriately
 903   if test x"$enable_c99" = x"yes"; then
 904     AC_DEFINE(_GLIBCXX_USE_C99)
 905   fi
 906
 907   AC_LANG_RESTORE
 908 ])
 909
 910
 911 dnl
 912 dnl Check for what type of C headers to use.
 913 dnl
 914 dnl --enable-cheaders= [does stuff].
 915 dnl --disable-cheaders [does not do anything, really].
 916 dnl  +  Usage:  GLIBCXX_ENABLE_CHEADERS[(DEFAULT)]
 917 dnl       Where DEFAULT is either `c' or `c_std'.
 918 dnl
 919 AC_DEFUN(GLIBCXX_ENABLE_CHEADERS, [
 920   GLIBCXX_ENABLE(cheaders,$1,[=KIND],
 921     [construct "C" headers for g++], [permit c|c_std])
 922   AC_MSG_NOTICE("C" header strategy set to $enable_cheaders)
 923
 924   C_INCLUDE_DIR='${glibcxx_srcdir}/include/'$enable_cheaders
 925
 926   AC_SUBST(C_INCLUDE_DIR)
 927   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C, test $enable_cheaders = c)
 928   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_C_STD, test $enable_cheaders = c_std)
 929   GLIBCXX_CONDITIONAL(GLIBCXX_C_HEADERS_COMPATIBILITY, test $c_compatibility = yes)
 930 ])
 931
 932
 933 dnl
 934 dnl Check for which locale library to use.  The choice is mapped to
 935 dnl a subdirectory of config/locale.
 936 dnl
 937 dnl Default is generic.
 938 dnl
 939 AC_DEFUN(GLIBCXX_ENABLE_CLOCALE, [
 940   AC_MSG_CHECKING([for C locale to use])
 941   GLIBCXX_ENABLE(clocale,auto,[@<:@=MODEL@:>@],
 942     [use MODEL for target locale package],
 943     [permit generic|gnu|ieee_1003.1-2001|yes|no|auto])
 944
 945   # If they didn't use this option switch, or if they specified --enable
 946   # with no specific model, we'll have to look for one.  If they
 947   # specified --disable (???), do likewise.
 948   if test $enable_clocale = no || test $enable_clocale = yes; then
 949      enable_clocale=auto
 950   fi
 951
 952   # Either a known package, or "auto"
 953   enable_clocale_flag=$enable_clocale
 954
 955   # Probe for locale support if no specific model is specified.
 956   # Default to "generic".
 957   if test $enable_clocale_flag = auto; then
 958     case x${target_os} in
 959       xlinux* | xgnu*)
 960         AC_EGREP_CPP([_GLIBCXX_ok], [
 961         #include <features.h>
 962         #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2)
 963           _GLIBCXX_ok
 964         #endif
 965         ], enable_clocale_flag=gnu, enable_clocale_flag=generic)
 966
 967         # Test for bugs early in glibc-2.2.x series
 968           if test x$enable_clocale_flag = xgnu; then
 969           AC_TRY_RUN([
 970           #define _GNU_SOURCE 1
 971           #include <locale.h>
 972           #include <string.h>
 973           #if __GLIBC__ > 2 || (__GLIBC__ == 2 && __GLIBC_MINOR__ > 2)
 974           extern __typeof(newlocale) __newlocale;
 975           extern __typeof(duplocale) __duplocale;
 976           extern __typeof(strcoll_l) __strcoll_l;
 977           #endif
 978           int main()
 979           {
 980               const char __one[] = "Äuglein Augmen";
 981               const char __two[] = "Äuglein";
 982               int i;
 983               int j;
 984               __locale_t        loc;
 985                __locale_t        loc_dup;
 986               loc = __newlocale(1 << LC_ALL, "de_DE", 0);
 987               loc_dup = __duplocale(loc);
 988               i = __strcoll_l(__one, __two, loc);
 989               j = __strcoll_l(__one, __two, loc_dup);
 990               return 0;
 991           }
 992           ],
 993           [enable_clocale_flag=gnu],[enable_clocale_flag=generic],
 994           [enable_clocale_flag=generic])
 995           fi
 996
 997         # ... at some point put __strxfrm_l tests in as well.
 998         ;;
 999       *)
1000         enable_clocale_flag=generic
1001         ;;
1002     esac
1003   fi
1004
1005   # Deal with gettext issues.  Default to not using it (=no) until we detect
1006   # support for it later.  Let the user turn it off via --e/d, but let that
1007   # default to on for easier handling.
1008   USE_NLS=no
1009   AC_ARG_ENABLE(nls,
1010     AC_HELP_STRING([--enable-nls],[use Native Language Support (default)]),
1011     [],
1012     [enable_nls=yes])
1013
1014   # Set configure bits for specified locale package
1015   case ${enable_clocale_flag} in
1016     generic)
1017       AC_MSG_RESULT(generic)
1018
1019       CLOCALE_H=config/locale/generic/c_locale.h
1020       CLOCALE_CC=config/locale/generic/c_locale.cc
1021       CCODECVT_H=config/locale/generic/codecvt_specializations.h
1022       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1023       CCOLLATE_CC=config/locale/generic/collate_members.cc
1024       CCTYPE_CC=config/locale/generic/ctype_members.cc
1025       CMESSAGES_H=config/locale/generic/messages_members.h
1026       CMESSAGES_CC=config/locale/generic/messages_members.cc
1027       CMONEY_CC=config/locale/generic/monetary_members.cc
1028       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1029       CTIME_H=config/locale/generic/time_members.h
1030       CTIME_CC=config/locale/generic/time_members.cc
1031       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1032       ;;
1033     gnu)
1034       AC_MSG_RESULT(gnu)
1035
1036       # Declare intention to use gettext, and add support for specific
1037       # languages.
1038       # For some reason, ALL_LINGUAS has to be before AM-GNU-GETTEXT
1039       ALL_LINGUAS="de fr"
1040
1041       # Don't call AM-GNU-GETTEXT here. Instead, assume glibc.
1042       AC_CHECK_PROG(check_msgfmt, msgfmt, yes, no)
1043       if test x"$check_msgfmt" = x"yes" && test x"$enable_nls" = x"yes"; then
1044         USE_NLS=yes
1045       fi
1046       # Export the build objects.
1047       for ling in $ALL_LINGUAS; do \
1048         glibcxx_MOFILES="$glibcxx_MOFILES $ling.mo"; \
1049         glibcxx_POFILES="$glibcxx_POFILES $ling.po"; \
1050       done
1051       AC_SUBST(glibcxx_MOFILES)
1052       AC_SUBST(glibcxx_POFILES)
1053
1054       CLOCALE_H=config/locale/gnu/c_locale.h
1055       CLOCALE_CC=config/locale/gnu/c_locale.cc
1056       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1057       CCODECVT_CC=config/locale/gnu/codecvt_members.cc
1058       CCOLLATE_CC=config/locale/gnu/collate_members.cc
1059       CCTYPE_CC=config/locale/gnu/ctype_members.cc
1060       CMESSAGES_H=config/locale/gnu/messages_members.h
1061       CMESSAGES_CC=config/locale/gnu/messages_members.cc
1062       CMONEY_CC=config/locale/gnu/monetary_members.cc
1063       CNUMERIC_CC=config/locale/gnu/numeric_members.cc
1064       CTIME_H=config/locale/gnu/time_members.h
1065       CTIME_CC=config/locale/gnu/time_members.cc
1066       CLOCALE_INTERNAL_H=config/locale/gnu/c++locale_internal.h
1067       ;;
1068     ieee_1003.1-2001)
1069       AC_MSG_RESULT(IEEE 1003.1)
1070
1071       CLOCALE_H=config/locale/ieee_1003.1-2001/c_locale.h
1072       CLOCALE_CC=config/locale/ieee_1003.1-2001/c_locale.cc
1073       CCODECVT_H=config/locale/ieee_1003.1-2001/codecvt_specializations.h
1074       CCODECVT_CC=config/locale/generic/codecvt_members.cc
1075       CCOLLATE_CC=config/locale/generic/collate_members.cc
1076       CCTYPE_CC=config/locale/generic/ctype_members.cc
1077       CMESSAGES_H=config/locale/ieee_1003.1-2001/messages_members.h
1078       CMESSAGES_CC=config/locale/ieee_1003.1-2001/messages_members.cc
1079       CMONEY_CC=config/locale/generic/monetary_members.cc
1080       CNUMERIC_CC=config/locale/generic/numeric_members.cc
1081       CTIME_H=config/locale/generic/time_members.h
1082       CTIME_CC=config/locale/generic/time_members.cc
1083       CLOCALE_INTERNAL_H=config/locale/generic/c++locale_internal.h
1084       ;;
1085   esac
1086
1087   # This is where the testsuite looks for locale catalogs, using the
1088   # -DLOCALEDIR define during testsuite compilation.
1089   glibcxx_localedir=${glibcxx_builddir}/po/share/locale
1090   AC_SUBST(glibcxx_localedir)
1091
1092   # A standalone libintl (e.g., GNU libintl) may be in use.
1093   if test $USE_NLS = yes; then
1094     AC_CHECK_HEADERS([libintl.h], [], USE_NLS=no)
1095     AC_SEARCH_LIBS(gettext, intl, [], USE_NLS=no)
1096   fi
1097   if test $USE_NLS = yes; then
1098     AC_DEFINE(_GLIBCXX_USE_NLS)
1099   fi
1100
1101   AC_SUBST(USE_NLS)
1102   AC_SUBST(CLOCALE_H)
1103   AC_SUBST(CCODECVT_H)
1104   AC_SUBST(CMESSAGES_H)
1105   AC_SUBST(CCODECVT_CC)
1106   AC_SUBST(CCOLLATE_CC)
1107   AC_SUBST(CCTYPE_CC)
1108   AC_SUBST(CMESSAGES_CC)
1109   AC_SUBST(CMONEY_CC)
1110   AC_SUBST(CNUMERIC_CC)
1111   AC_SUBST(CTIME_H)
1112   AC_SUBST(CTIME_CC)
1113   AC_SUBST(CLOCALE_CC)
1114   AC_SUBST(CLOCALE_INTERNAL_H)
1115 ])
1116
1117
1118 dnl
1119 dnl Check for whether the Boost-derived checks should be turned on.
1120 dnl
1121 dnl --enable-concept-checks turns them on.
1122 dnl --disable-concept-checks leaves them off.
1123 dnl  +  Usage:  GLIBCXX_ENABLE_CONCEPT_CHECKS[(DEFAULT)]
1124 dnl       Where DEFAULT is either `yes' or `no'.
1125 dnl
1126 AC_DEFUN(GLIBCXX_ENABLE_CONCEPT_CHECKS, [
1127   GLIBCXX_ENABLE(concept-checks,$1,,[use Boost-derived template checks])
1128   if test $enable_concept_checks = yes; then
1129     AC_DEFINE(_GLIBCXX_CONCEPT_CHECKS)
1130   fi
1131 ])
1132
1133
1134 dnl
1135 dnl Check for which I/O library to use:  stdio, or something specific.
1136 dnl
1137 dnl Default is stdio.
1138 dnl
1139 AC_DEFUN(GLIBCXX_ENABLE_CSTDIO, [
1140   AC_MSG_CHECKING([for underlying I/O to use])
1141   GLIBCXX_ENABLE(cstdio,stdio,[=PACKAGE],
1142     [use target-specific I/O package], [permit stdio])
1143
1144   # Now that libio has been removed, you can have any color you want as long
1145   # as it's black.  This is one big no-op until other packages are added, but
1146   # showing the framework never hurts.
1147   case ${enable_cstdio} in
1148     stdio)
1149       CSTDIO_H=config/io/c_io_stdio.h
1150       BASIC_FILE_H=config/io/basic_file_stdio.h
1151       BASIC_FILE_CC=config/io/basic_file_stdio.cc
1152       AC_MSG_RESULT(stdio)
1153       ;;
1154   esac
1155
1156   dnl Set directory for fpos.h
1157   FPOS_H=$fpos_include_dir
1158
1159   AC_SUBST(CSTDIO_H)
1160   AC_SUBST(FPOS_H)
1161   AC_SUBST(BASIC_FILE_H)
1162   AC_SUBST(BASIC_FILE_CC)
1163 ])
1164
1165
1166 dnl
1167 dnl Check for "unusual" flags to pass to the compiler while building.
1168 dnl
1169 dnl --enable-cxx-flags='-foo -bar -baz' is a general method for passing
1170 dnl     experimental flags such as -fpch, -fIMI, -Dfloat=char, etc.
1171 dnl --disable-cxx-flags passes nothing.
1172 dnl  +  See http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00131.html
1173 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q2/msg00284.html
1174 dnl         http://gcc.gnu.org/ml/libstdc++/2000-q1/msg00035.html
1175 dnl  +  Usage:  GLIBCXX_ENABLE_CXX_FLAGS(default flags)
1176 dnl       If "default flags" is an empty string, the effect is the same
1177 dnl       as --disable or --enable=no.
1178 dnl
1179 AC_DEFUN(GLIBCXX_ENABLE_CXX_FLAGS, [dnl
1180   AC_MSG_CHECKING([for extra compiler flags for building])
1181   GLIBCXX_ENABLE(cxx-flags,$1,[=FLAGS],
1182     [pass compiler FLAGS when building library],
1183     [case "x$enable_cxx_flags" in
1184       xno | x)   enable_cxx_flags= ;;
1185       x-*)       ;;
1186       *)         AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1187      esac])
1188
1189   # Run through flags (either default or command-line) and set anything
1190   # extra (e.g., #defines) that must accompany particular g++ options.
1191   if test -n "$enable_cxx_flags"; then
1192     for f in $enable_cxx_flags; do
1193       case "$f" in
1194         -fhonor-std)  ;;
1195         -*)  ;;
1196         *)   # and we're trying to pass /what/ exactly?
1197              AC_MSG_ERROR([compiler flags start with a -]) ;;
1198       esac
1199     done
1200   fi
1201
1202   EXTRA_CXX_FLAGS="$enable_cxx_flags"
1203   AC_MSG_RESULT($EXTRA_CXX_FLAGS)
1204   AC_SUBST(EXTRA_CXX_FLAGS)
1205 ])
1206
1207
1208 dnl
1209 dnl Check for wide character support.  Has the same effect as the option
1210 dnl in gcc's configure, but in a form that autoconf can mess with.
1211 dnl
1212 dnl --enable-c-mbchar requests all the wchar_t stuff.
1213 dnl --disable-c-mbchar doesn't.
1214 dnl  +  Usage:  GLIBCXX_ENABLE_C_MBCHAR[(DEFAULT)]
1215 dnl       Where DEFAULT is either `yes' or `no'.
1216 dnl
1217 AC_DEFUN(GLIBCXX_ENABLE_C_MBCHAR, [
1218   GLIBCXX_ENABLE(c-mbchar,$1,,[enable multibyte (wide) characters])
1219   # Option parsed, now other scripts can test enable_c_mbchar for yes/no.
1220 ])
1221
1222
1223 dnl
1224 dnl Check to see if debugging libraries are to be built.
1225 dnl
1226 dnl --enable-libstdcxx-debug
1227 dnl builds a separate set of debugging libraries in addition to the
1228 dnl normal (shared, static) libstdc++ binaries.
1229 dnl
1230 dnl --disable-libstdcxx-debug
1231 dnl builds only one (non-debug) version of libstdc++.
1232 dnl
1233 dnl --enable-libstdcxx-debug-flags=FLAGS
1234 dnl iff --enable-debug == yes, then use FLAGS to build the debug library.
1235 dnl
1236 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG[(DEFAULT)]
1237 dnl       Where DEFAULT is either `yes' or `no'.
1238 dnl
1239 AC_DEFUN(GLIBCXX_ENABLE_DEBUG, [
1240   AC_MSG_CHECKING([for additional debug build])
1241   GLIBCXX_ENABLE(libstdcxx-debug,$1,,[build extra debug library])
1242   AC_MSG_RESULT($enable_libstdcxx_debug)
1243   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_DEBUG, test $enable_libstdcxx_debug = yes)
1244 ])
1245
1246
1247 dnl
1248 dnl Check for explicit debug flags.
1249 dnl
1250 dnl --enable-libstdcxx-debug-flags='-O1'
1251 dnl is a general method for passing flags to be used when
1252 dnl building debug libraries with --enable-debug.
1253 dnl
1254 dnl --disable-libstdcxx-debug-flags does nothing.
1255 dnl  +  Usage:  GLIBCXX_ENABLE_DEBUG_FLAGS(default flags)
1256 dnl       If "default flags" is an empty string, the effect is the same
1257 dnl       as --disable or --enable=no.
1258 dnl
1259 AC_DEFUN(GLIBCXX_ENABLE_DEBUG_FLAGS, [
1260   GLIBCXX_ENABLE(libstdcxx-debug-flags,[$1],[=FLAGS],
1261     [pass compiler FLAGS when building debug library],
1262     [case "x$enable_libstdcxx_debug_flags" in
1263       xno | x)    enable_libstdcxx_debug_flags= ;;
1264       x-*)        ;;
1265       *)          AC_MSG_ERROR(_g_switch needs compiler flags as arguments) ;;
1266      esac])
1267
1268   # Option parsed, now set things appropriately
1269   DEBUG_FLAGS="$enable_libstdcxx_debug_flags"
1270   AC_SUBST(DEBUG_FLAGS)
1271
1272   AC_MSG_NOTICE([Debug build flags set to $DEBUG_FLAGS])
1273 ])
1274
1275
1276 dnl
1277 dnl Check if the user only wants a freestanding library implementation.
1278 dnl
1279 dnl --disable-hosted-libstdcxx will turn off most of the library build,
1280 dnl installing only the headers required by [17.4.1.3] and the language
1281 dnl support library.  More than that will be built (to keep the Makefiles
1282 dnl conveniently clean), but not installed.
1283 dnl
1284 dnl Sets:
1285 dnl  is_hosted  (yes/no)
1286 dnl
1287 dnl Defines:
1288 dnl  _GLIBCXX_HOSTED   (always defined, either to 1 or 0)
1289 dnl
1290 AC_DEFUN(GLIBCXX_ENABLE_HOSTED, [
1291   AC_ARG_ENABLE([hosted-libstdcxx],
1292     AC_HELP_STRING([--disable-hosted-libstdcxx],
1293                    [only build freestanding C++ runtime support]),,
1294     [enable_hosted_libstdcxx=yes])
1295   if test "$enable_hosted_libstdcxx" = no; then
1296     AC_MSG_NOTICE([Only freestanding libraries will be built])
1297     is_hosted=no
1298     hosted_define=0
1299     enable_abi_check=no
1300     enable_libstdcxx_pch=no
1301   else
1302     is_hosted=yes
1303     hosted_define=1
1304   fi
1305   GLIBCXX_CONDITIONAL(GLIBCXX_HOSTED, test $is_hosted = yes)
1306   AC_DEFINE_UNQUOTED(_GLIBCXX_HOSTED, $hosted_define,
1307     [Define to 1 if a full hosted library is built, or 0 if freestanding.])
1308 ])
1309
1310
1311 dnl
1312 dnl Check for libunwind exception handling support.  If enabled, then
1313 dnl we assume that the _Unwind_* functions that make up the Unwind ABI
1314 dnl (_Unwind_RaiseException, _Unwind_Resume, etc.) are defined by
1315 dnl libunwind instead of libgcc, and that libstdc++ has a dependency
1316 dnl on libunwind as well as libgcc.
1317 dnl
1318 dnl --enable-libunwind-exceptions forces the use of libunwind.
1319 dnl --disable-libunwind-exceptions assumes there is no libunwind.
1320 dnl
1321 dnl Substs:
1322 dnl  LIBUNWIND_FLAG
1323 dnl
1324 AC_DEFUN(GLIBCXX_ENABLE_LIBUNWIND_EXCEPTIONS, [
1325   AC_MSG_CHECKING([for use of libunwind])
1326   GLIBCXX_ENABLE(libunwind-exceptions,no,,
1327     [force use of libunwind for exceptions])
1328   AC_MSG_RESULT($use_libunwind_exceptions)
1329   if test $enable_libunwind_exceptions = yes; then
1330     LIBUNWIND_FLAG="-lunwind"
1331   else
1332     LIBUNWIND_FLAG=""
1333   fi
1334   AC_SUBST(LIBUNWIND_FLAG)
1335 ])
1336
1337
1338 dnl
1339 dnl Check for template specializations for the 'long long' type extension.
1340 dnl The result determines only whether 'long long' I/O is enabled; things
1341 dnl like numeric_limits<> specializations are always available.
1342 dnl
1343 dnl --enable-long-long defines _GLIBCXX_USE_LONG_LONG
1344 dnl --disable-long-long leaves _GLIBCXX_USE_LONG_LONG undefined
1345 dnl  +  Usage:  GLIBCXX_ENABLE_LONG_LONG[(DEFAULT)]
1346 dnl       Where DEFAULT is either `yes' or `no'.
1347 dnl  +  If 'long long' stuff is not available, ignores DEFAULT and sets `no'.
1348 dnl
1349 AC_DEFUN(GLIBCXX_ENABLE_LONG_LONG, [
1350   GLIBCXX_ENABLE(long-long,$1,,[enables I/O support for 'long long'])
1351
1352   AC_LANG_SAVE
1353   AC_LANG_CPLUSPLUS
1354
1355   AC_MSG_CHECKING([for enabled long long I/O support])
1356   # iostreams require strtoll, strtoull to compile
1357   AC_TRY_COMPILE([#include <stdlib.h>],
1358                  [char* tmp; strtoll("gnu", &tmp, 10);],,[enable_long_long=no])
1359   AC_TRY_COMPILE([#include <stdlib.h>],
1360                  [char* tmp; strtoull("gnu", &tmp, 10);],,[enable_long_long=no])
1361
1362   # Option parsed, now set things appropriately
1363   if test $enable_long_long = yes; then
1364     AC_DEFINE(_GLIBCXX_USE_LONG_LONG)
1365   fi
1366   AC_MSG_RESULT($enable_long_long)
1367
1368   AC_LANG_RESTORE
1369 ])
1370
1371
1372 dnl
1373 dnl Check to see if building and using a C++ precompiled header can be done.
1374 dnl
1375 dnl --enable-libstdcxx-pch=yes
1376 dnl default, this shows intent to use stdc++.h.gch If it looks like it
1377 dnl may work, after some light-hearted attempts to puzzle out compiler
1378 dnl support, flip bits on in include/Makefile.am
1379 dnl
1380 dnl --disable-libstdcxx-pch
1381 dnl turns off attempts to use or build stdc++.h.gch.
1382 dnl
1383 dnl Substs:
1384 dnl  glibcxx_PCHFLAGS
1385 dnl
1386 AC_DEFUN(GLIBCXX_ENABLE_PCH, [
1387   AC_MSG_CHECKING([for enabled PCH])
1388   GLIBCXX_ENABLE(libstdcxx-pch,$1,,[build pre-compiled libstdc++ headers])
1389   AC_MSG_RESULT([$enable_libstdcxx_pch])
1390
1391   if test $enable_libstdcxx_pch = yes; then
1392     AC_CACHE_CHECK([for compiler with PCH support],
1393       [glibcxx_cv_prog_CXX_pch],
1394       [ac_save_CXXFLAGS="$CXXFLAGS"
1395        CXXFLAGS="$CXXFLAGS -Werror -Winvalid-pch -Wno-deprecated"
1396        AC_LANG_SAVE
1397        AC_LANG_CPLUSPLUS
1398        echo '#include <math.h>' > conftest.h
1399        if $CXX $CXXFLAGS $CPPFLAGS -x c++-header conftest.h \
1400                           -o conftest.h.gch 1>&5 2>&1 &&
1401                 echo '#error "pch failed"' > conftest.h &&
1402           echo '#include "conftest.h"' > conftest.cc &&
1403                $CXX -c $CXXFLAGS $CPPFLAGS conftest.cc 1>&5 2>&1 ;
1404        then
1405          glibcxx_cv_prog_CXX_pch=yes
1406        else
1407          glibcxx_cv_prog_CXX_pch=no
1408        fi
1409        rm -f conftest*
1410        CXXFLAGS=$ac_save_CXXFLAGS
1411        AC_LANG_RESTORE
1412       ])
1413     enable_libstdcxx_pch=$glibcxx_cv_prog_CXX_pch
1414   fi
1415
1416   GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_PCH, test $enable_libstdcxx_pch = yes)
1417   if test $enable_libstdcxx_pch = yes; then
1418     glibcxx_PCHFLAGS="-include bits/stdc++.h"
1419   else
1420     glibcxx_PCHFLAGS=""
1421   fi
1422   AC_SUBST(glibcxx_PCHFLAGS)
1423 ])
1424
1425
1426 dnl
1427 dnl Check for exception handling support.  If an explicit enable/disable
1428 dnl sjlj exceptions is given, we don't have to detect.  Otherwise the
1429 dnl target may or may not support call frame exceptions.
1430 dnl
1431 dnl --enable-sjlj-exceptions forces the use of builtin setjmp.
1432 dnl --disable-sjlj-exceptions forces the use of call frame unwinding.
1433 dnl Neither one forces an attempt at detection.
1434 dnl
1435 dnl Defines:
1436 dnl  _GLIBCXX_SJLJ_EXCEPTIONS if the compiler is configured for it
1437 dnl
1438 AC_DEFUN(GLIBCXX_ENABLE_SJLJ_EXCEPTIONS, [
1439   AC_MSG_CHECKING([for exception model to use])
1440   AC_LANG_SAVE
1441   AC_LANG_CPLUSPLUS
1442   GLIBCXX_ENABLE(sjlj-exceptions,auto,,
1443     [force use of builtin_setjmp for exceptions],
1444     [permit yes|no|auto])
1445
1446   if test $enable_sjlj_exceptions = auto; then
1447     # Botheration.  Now we've got to detect the exception model.  Link tests
1448     # against libgcc.a are problematic since we've not been given proper -L
1449     # bits for single-tree newlib and libgloss.
1450     #
1451     # Fake what AC_TRY_COMPILE does.  XXX Look at redoing this new-style.
1452     cat > conftest.$ac_ext << EOF
1453 [#]line __oline__ "configure"
1454 struct S { ~S(); };
1455 void bar();
1456 void foo()
1457 {
1458   S s;
1459   bar();
1460 }
1461 EOF
1462     old_CXXFLAGS="$CXXFLAGS"
1463     CXXFLAGS=-S
1464     if AC_TRY_EVAL(ac_compile); then
1465       if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
1466         enable_sjlj_exceptions=yes
1467       elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
1468         enable_sjlj_exceptions=no
1469       fi
1470     fi
1471     CXXFLAGS="$old_CXXFLAGS"
1472     rm -f conftest*
1473   fi
1474
1475   # This is a tad weird, for hysterical raisins.  We have to map enable/disable
1476   # to two different models.
1477   case $enable_sjlj_exceptions in
1478     yes)
1479       AC_DEFINE(_GLIBCXX_SJLJ_EXCEPTIONS, 1,
1480         [Define if the compiler is configured for setjmp/longjmp exceptions.])
1481       ac_exception_model_name=sjlj
1482       ;;
1483     no)
1484       ac_exception_model_name="call frame"
1485       ;;
1486     *)
1487       AC_MSG_ERROR([unable to detect exception model])
1488       ;;
1489   esac
1490  AC_LANG_RESTORE
1491  AC_MSG_RESULT($ac_exception_model_name)
1492 ])
1493
1494
1495 dnl
1496 dnl Add version tags to symbols in shared library (or not), additionally
1497 dnl marking other symbols as private/local (or not).
1498 dnl
1499 dnl --enable-symvers=style adds a version script to the linker call when
1500 dnl       creating the shared library.  The choice of version script is
1501 dnl       controlled by 'style'.
1502 dnl --disable-symvers does not.
1503 dnl  +  Usage:  GLIBCXX_ENABLE_SYMVERS[(DEFAULT)]
1504 dnl       Where DEFAULT is either 'yes' or 'no'.  Passing `yes' tries to
1505 dnl       choose a default style based on linker characteristics.  Passing
1506 dnl       'no' disables versioning.
1507 dnl
1508 AC_DEFUN(GLIBCXX_ENABLE_SYMVERS, [
1509
1510 GLIBCXX_ENABLE(symvers,$1,[=STYLE],
1511   [enables symbol versioning of the shared library],
1512   [permit yes|no|gnu])
1513
1514 # If we never went through the GLIBCXX_CHECK_LINKER_FEATURES macro, then we
1515 # don't know enough about $LD to do tricks...
1516 AC_REQUIRE([GLIBCXX_CHECK_LINKER_FEATURES])
1517 # FIXME  The following test is too strict, in theory.
1518 if test $enable_shared = no ||
1519         test "x$LD" = x ||
1520         test x$glibcxx_gnu_ld_version = x; then
1521   enable_symvers=no
1522 fi
1523
1524 # Check to see if libgcc_s exists, indicating that shared libgcc is possible.
1525 if test $enable_symvers != no; then
1526   AC_MSG_CHECKING([for shared libgcc])
1527   ac_save_CFLAGS="$CFLAGS"
1528   CFLAGS=' -lgcc_s'
1529   AC_TRY_LINK(, [return 0;], glibcxx_shared_libgcc=yes, glibcxx_shared_libgcc=no)
1530   CFLAGS="$ac_save_CFLAGS"
1531   AC_MSG_RESULT($glibcxx_shared_libgcc)
1532 fi
1533
1534 # For GNU ld, we need at least this version.  The format is described in
1535 # GLIBCXX_CHECK_LINKER_FEATURES above.
1536 glibcxx_min_gnu_ld_version=21400
1537 # XXXXXXXXXXX glibcxx_gnu_ld_version=21390
1538
1539 # Check to see if unspecified "yes" value can win, given results above.
1540 # Change "yes" into either "no" or a style name.
1541 if test $enable_symvers = yes; then
1542   if test $with_gnu_ld = yes &&
1543      test $glibcxx_shared_libgcc = yes;
1544   then
1545     if test $glibcxx_gnu_ld_version -ge $glibcxx_min_gnu_ld_version ; then
1546       enable_symvers=gnu
1547     else
1548       # The right tools, the right setup, but too old.  Fallbacks?
1549       AC_MSG_WARN(=== Linker version $glibcxx_gnu_ld_version is too old for)
1550       AC_MSG_WARN(=== full symbol versioning support in this release of GCC.)
1551       AC_MSG_WARN(=== You would need to upgrade your binutils to version)
1552       AC_MSG_WARN(=== $glibcxx_min_gnu_ld_version or later and rebuild GCC.)
1553       if test $glibcxx_gnu_ld_version -ge 21200 ; then
1554         # Globbing fix is present, proper block support is not.
1555         dnl AC_MSG_WARN([=== Dude, you are soooo close.  Maybe we can fake it.])
1556         dnl enable_symvers=???
1557         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1558         enable_symvers=no
1559       else
1560         # 2.11 or older.
1561         AC_MSG_WARN([=== Symbol versioning will be disabled.])
1562         enable_symvers=no
1563       fi
1564     fi
1565   else
1566     # just fail for now
1567     AC_MSG_WARN([=== You have requested some kind of symbol versioning, but])
1568     AC_MSG_WARN([=== either you are not using a supported linker, or you are])
1569     AC_MSG_WARN([=== not building a shared libgcc_s (which is required).])
1570     AC_MSG_WARN([=== Symbol versioning will be disabled.])
1571     enable_symvers=no
1572   fi
1573 fi
1574
1575 # Everything parsed; figure out what file to use.
1576 case $enable_symvers in
1577   no)
1578     SYMVER_MAP=config/linker-map.dummy
1579     ;;
1580   gnu)
1581     SYMVER_MAP=config/linker-map.gnu
1582     AC_DEFINE(_GLIBCXX_SYMVER)
1583     ;;
1584 esac
1585
1586 AC_SUBST(SYMVER_MAP)
1587 AC_SUBST(port_specific_symbol_files)
1588 GLIBCXX_CONDITIONAL(GLIBCXX_BUILD_VERSIONED_SHLIB, test $enable_symvers != no)
1589 AC_MSG_NOTICE(versioning on shared library symbols is $enable_symvers)
1590 ])
1591
1592
1593 dnl
1594 dnl Setup to use the gcc gthr.h thread-specific memory and mutex model.
1595 dnl We must stage the required headers so that they will be installed
1596 dnl with the library (unlike libgcc, the STL implementation is provided
1597 dnl solely within headers).  Since we must not inject random user-space
1598 dnl macro names into user-provided C++ code, we first stage into <file>-in
1599 dnl and process to <file> with an output command.  The reason for a two-
1600 dnl stage process here is to correctly handle $srcdir!=$objdir without
1601 dnl having to write complex code (the sed commands to clean the macro
1602 dnl namespace are complex and fragile enough as it is).  We must also
1603 dnl add a relative path so that -I- is supported properly.
1604 dnl
1605 dnl Substs:
1606 dnl  glibcxx_thread_h
1607 dnl
1608 dnl Defines:
1609 dnl  HAVE_GTHR_DEFAULT
1610 dnl  _GLIBCXX_SUPPORTS_WEAK
1611 dnl
1612 AC_DEFUN(GLIBCXX_ENABLE_THREADS, [
1613   AC_MSG_CHECKING([for thread model used by GCC])
1614   target_thread_file=`$CXX -v 2>&1 | sed -n 's/^Thread model: //p'`
1615   AC_MSG_RESULT([$target_thread_file])
1616
1617   if test $target_thread_file != single; then
1618     AC_DEFINE(HAVE_GTHR_DEFAULT)
1619     AC_DEFINE(_GLIBCXX_SUPPORTS_WEAK, __GXX_WEAK__)
1620   fi
1621
1622   glibcxx_thread_h=gthr-$target_thread_file.h
1623   AC_SUBST(glibcxx_thread_h)
1624 ])
1625
1626
1627 # Check whether LC_MESSAGES is available in <locale.h>.
1628 # Ulrich Drepper <drepper@cygnus.com>, 1995.
1629 #
1630 # This file file be copied and used freely without restrictions.  It can
1631 # be used in projects which are not available under the GNU Public License
1632 # but which still want to provide support for the GNU gettext functionality.
1633 # Please note that the actual code is *not* freely available.
1634
1635 # serial 1
1636 AC_DEFUN(AC_LC_MESSAGES, [
1637   AC_CHECK_HEADER(locale.h, [
1638     AC_CACHE_CHECK([for LC_MESSAGES], ac_cv_val_LC_MESSAGES,
1639       [AC_TRY_LINK([#include <locale.h>], [return LC_MESSAGES],
1640        ac_cv_val_LC_MESSAGES=yes, ac_cv_val_LC_MESSAGES=no)])
1641     if test $ac_cv_val_LC_MESSAGES = yes; then
1642       AC_DEFINE(HAVE_LC_MESSAGES)
1643     fi
1644   ])
1645 ])
1646
1647
1648 sinclude([../libtool.m4])
1649 dnl The lines below arrange for aclocal not to bring an installed
1650 dnl libtool.m4 into aclocal.m4, while still arranging for automake to
1651 dnl add a definition of LIBTOOL to Makefile.in.
1652 ifelse(,,,[AC_SUBST(LIBTOOL)
1653 AC_DEFUN([AM_PROG_LIBTOOL])
1654 AC_DEFUN([AC_LIBTOOL_DLOPEN])
1655 AC_DEFUN([AC_PROG_LD])
1656 ])
1657
1658 dnl vim:et:ts=2:sw=2