libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_PREREQ(2.64)
  10 AC_INIT(package-unused, version-unused,, libgo)
  11 AC_CONFIG_SRCDIR(Makefile.am)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 libtool_VERSION=11:0:0
  15 AC_SUBST(libtool_VERSION)
  16
  17 AM_ENABLE_MULTILIB(, ..)
  18
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$host_alias}
  21
  22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dist -Wall -Wno-portability])
  23 AH_TEMPLATE(PACKAGE, [Name of package])
  24 AH_TEMPLATE(VERSION, [Version number of package])
  25
  26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  28 AC_PROG_CC
  29 AC_PROG_GO
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 AM_MAINTAINER_MODE
  35
  36 AC_PROG_LD
  37 AC_PROG_RANLIB
  38 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  39
  40 AC_LIBTOOL_DLOPEN
  41 AM_PROG_LIBTOOL
  42 AC_SUBST(enable_shared)
  43 AC_SUBST(enable_static)
  44
  45 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  46 AC_SUBST(CC_FOR_BUILD)
  47
  48 AC_PROG_AWK
  49
  50 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  51 AC_SUBST(WARN_FLAGS)
  52
  53 AC_ARG_ENABLE(werror, [AS_HELP_STRING([--enable-werror],
  54                                       [turns on -Werror @<:@default=yes@:>@])])
  55 if test "x$enable_werror" != "xno"; then
  56   WERROR="-Werror"
  57 fi
  58 AC_SUBST(WERROR)
  59
  60 glibgo_toolexecdir=no
  61 glibgo_toolexeclibdir=no
  62
  63 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  64 AC_ARG_ENABLE([version-specific-runtime-libs],
  65   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  66                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  67   [case "$enableval" in
  68     yes) version_specific_libs=yes ;;
  69     no)  version_specific_libs=no ;;
  70     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  71    esac],
  72   [version_specific_libs=no])
  73 AC_MSG_RESULT($version_specific_libs)
  74
  75 # Version-specific runtime libs processing.
  76 if test $version_specific_libs = yes; then
  77   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  78   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  79 fi
  80
  81 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  82 # Install a library built with a cross compiler in tooldir, not libdir.
  83 if test -n "$with_cross_host" &&
  84    test x"$with_cross_host" != x"no"; then
  85   nover_glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  86   nover_glibgo_toolexeclibdir='${toolexecdir}/lib'
  87 else
  88   nover_glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  89   nover_glibgo_toolexeclibdir='${libdir}'
  90 fi
  91 multi_os_directory=`$GOC -print-multi-os-directory`
  92 case $multi_os_directory in
  93   .) ;; # Avoid trailing /.
  94   *) nover_glibgo_toolexeclibdir=${nover_glibgo_toolexeclibdir}/${multi_os_directory} ;;
  95 esac
  96
  97 if test x"$glibgo_toolexecdir" = x"no"; then
  98   glibgo_toolexecdir="${nover_glibgo_toolexecdir}"
  99   glibgo_toolexeclibdir="${nover_glibgo_toolexeclibdir}"
 100 fi
 101
 102 AC_SUBST(glibgo_toolexecdir)
 103 AC_SUBST(glibgo_toolexeclibdir)
 104 AC_SUBST(nover_glibgo_toolexeclibdir)
 105
 106 # See if the user wants to configure without libffi.  Some
 107 # architectures don't support it.  FIXME: We should set a default
 108 # based on the host.
 109 AC_ARG_WITH(libffi,
 110   AS_HELP_STRING([--without-libffi],
 111                  [don't use libffi]),
 112   [:],
 113   [with_libffi=${with_libffi_default-yes}])
 114
 115 LIBFFI=
 116 LIBFFIINCS=
 117 if test "$with_libffi" != no; then
 118    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 119    LIBFFI=../libffi/libffi_convenience.la
 120    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 121 fi
 122 AC_SUBST(LIBFFI)
 123 AC_SUBST(LIBFFIINCS)
 124 AM_CONDITIONAL(USE_LIBFFI, test "$with_liffi" != "no")
 125
 126 # See if the user wants to configure without libatomic. This is useful if we are
 127 # on an architecture for which libgo does not need an atomic support library and
 128 # libatomic does not support our C compiler.
 129 AC_ARG_WITH(libatomic,
 130   AS_HELP_STRING([--without-libatomic],
 131                  [don't use libatomic]),
 132   [:],
 133   [with_libatomic=${with_libatomic_default-yes}])
 134
 135 LIBATOMIC=
 136 if test "$with_libatomic" != no; then
 137    LIBATOMIC=../libatomic/libatomic_convenience.la
 138 fi
 139 AC_SUBST(LIBATOMIC)
 140
 141 # Used to tell GNU make to include a file without telling automake to
 142 # include it.
 143 go_include="-include"
 144 AC_SUBST(go_include)
 145
 146 # All known GOOS values.  This is the union of all operating systems
 147 # supported by the gofrontend and all operating systems supported by
 148 # the gc toolchain.
 149 ALLGOOS="android darwin dragonfly freebsd irix linux netbsd openbsd plan9 rtems solaris windows"
 150
 151 is_darwin=no
 152 is_freebsd=no
 153 is_irix=no
 154 is_linux=no
 155 is_netbsd=no
 156 is_openbsd=no
 157 is_dragonfly=no
 158 is_rtems=no
 159 is_solaris=no
 160 GOOS=unknown
 161 case ${host} in
 162   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 163   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 164   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 165   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 166   *-*-netbsd*)   is_netbsd=yes;  GOOS=netbsd ;;
 167   *-*-openbsd*)  is_openbsd=yes; GOOS=openbsd ;;
 168   *-*-dragonfly*) is_dragonfly=yes; GOOS=dragonfly ;;
 169   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 170   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 171 esac
 172 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 173 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 174 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 175 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 176 AM_CONDITIONAL(LIBGO_IS_NETBSD, test $is_netbsd = yes)
 177 AM_CONDITIONAL(LIBGO_IS_OPENBSD, test $is_openbsd = yes)
 178 AM_CONDITIONAL(LIBGO_IS_DRAGONFLY, test $is_dragonfly = yes)
 179 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 180 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 181 AM_CONDITIONAL(LIBGO_IS_BSD, test $is_darwin = yes -o $is_dragonfly = yes -o $is_freebsd = yes -o $is_netbsd = yes -o $is_openbsd = yes)
 182 AC_SUBST(GOOS)
 183 AC_SUBST(ALLGOOS)
 184
 185 dnl Test whether we need to use DejaGNU or whether we can use the
 186 dnl simpler gotest approach.  We can only use gotest for a native
 187 dnl build.
 188 USE_DEJAGNU=no
 189 case ${host} in
 190   *-*-rtems*) USE_DEJAGNU=yes ;;
 191   ${build}) ;;
 192   *) USE_DEJAGNU=yes ;;
 193 esac
 194 AC_SUBST(USE_DEJAGNU)
 195
 196 # All known GOARCH values.  This is the union of all architectures
 197 # supported by the gofrontend and all architectures supported by the
 198 # gc toolchain.
 199 # N.B. Keep in sync with gcc/testsuite/go.test/go-test.exp (go-set-goarch).
 200 ALLGOARCH="386 alpha amd64 amd64p32 arm armbe arm64 arm64be ia64 m68k mipso32 mipsn32 mipso64 mipsn64 mips mipsle mips64 mips64le mips64p32 mips64p32le ppc ppc64 ppc64le s390 s390x sparc sparc64"
 201
 202 # All known GOARCH_FAMILY values.
 203 ALLGOARCHFAMILY="I386 ALPHA AMD64 ARM ARM64 IA64 M68K MIPS MIPS64 PPC PPC64 S390 S390X SPARC SPARC64"
 204
 205 GOARCH=unknown
 206 GOARCH_FAMILY=unknown
 207 GOARCH_BIGENDIAN=0
 208 GOARCH_CACHELINESIZE=64
 209 GOARCH_PHYSPAGESIZE=4096
 210 GOARCH_PCQUANTUM=1
 211 GOARCH_INT64ALIGN=8
 212 GOARCH_HUGEPAGESIZE=0
 213 GOARCH_MINFRAMESIZE=0
 214 case ${host} in
 215   alpha*-*-*)
 216     GOARCH=alpha
 217     GOARCH_FAMILY=ALPHA
 218     GOARCH_PHYSPAGESIZE=8192
 219     GOARCH_PCQUANTUM=4
 220     ;;
 221   aarch64-*-*)
 222     GOARCH=arm64
 223     GOARCH_FAMILY=ARM64
 224     GOARCH_CACHELINESIZE=32
 225     GOARCH_PHYSPAGESIZE=65536
 226     GOARCH_PCQUANTUM=4
 227     GOARCH_MINFRAMESIZE=8
 228     ;;
 229   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 230     GOARCH=arm
 231     GOARCH_FAMILY=ARM
 232     GOARCH_CACHELINESIZE=32
 233     GOARCH_PCQUANTUM=4
 234     GOARCH_MINFRAMESIZE=4
 235     ;;
 236 changequote(,)dnl
 237   i[34567]86-*-* | x86_64-*-*)
 238 changequote([,])dnl
 239     AC_COMPILE_IFELSE([
 240 #ifdef __x86_64__
 241 #error 64-bit
 242 #endif],
 243 [GOARCH=386
 244 GOARCH_FAMILY=I386
 245 GOARCH_INT64ALIGN=4
 246 GOARCH_HUGEPAGESIZE="1 << 21"
 247 ],
 248 [GOARCH=amd64
 249 GOARCH_FAMILY=AMD64
 250 GOARCH_HUGEPAGESIZE="1 << 21"
 251 ])
 252     ;;
 253   ia64-*-*)
 254     GOARCH=ia64
 255     GOARCH_FAMILY=IA64
 256     GOARCH_CACHELINESIZE=16384
 257     GOARCH_PHYSPAGESIZE=65536
 258     ;;
 259   m68k*-*-*)
 260     GOARCH=m68k
 261     GOARCH_FAMILY=M68K
 262     GOARCH_BIGENDIAN=1
 263     GOARCH_CACHELINESIZE=16
 264     GOARCH_PCQUANTUM=4
 265     GOARCH_INT64ALIGN=2
 266     ;;
 267   mips*-*-*)
 268     AC_COMPILE_IFELSE([
 269 #if _MIPS_SIM != _ABIO32
 270 #error not o32
 271 #endif],
 272 [mips_abi="o32"],
 273         [AC_COMPILE_IFELSE([
 274 #if _MIPS_SIM != _ABIN32
 275 #error not n32
 276 #endif],
 277 [mips_abi="n32"],
 278         [AC_COMPILE_IFELSE([
 279 #if _MIPS_SIM != _ABI64
 280 #error not n64
 281 #endif],
 282 [mips_abi="n64"],
 283         [AC_COMPILE_IFELSE([
 284 #if _MIPS_SIM != _ABIO64
 285 #error not o64
 286 #endif],
 287 [mips_abi="o64"],
 288         [AC_MSG_ERROR([unknown MIPS ABI])
 289 [mips_abi="n32"]])])])])
 290     case "$mips_abi" in
 291     "o32") GOARCH=mipso32 ;;
 292     "n32") GOARCH=mipsn32 ;;
 293     "n64") GOARCH=mipsn64 ;;
 294     "o64") GOARCH=mipso64 ;;
 295     esac
 296     case "$mips_abi" in
 297     "o32" | "n32")
 298         GOARCH_FAMILY=MIPS
 299         GOARCH_MINFRAMESIZE=4
 300         ;;
 301     "n64" | "o64")
 302         GOARCH_FAMILY=MIPS64
 303         GOARCH_MINFRAMESIZE=8
 304         ;;
 305     esac
 306     case "${host}" in
 307     mips*el)
 308         ;;
 309     *)
 310         GOARCH_BIGENDIAN=1
 311         ;;
 312     esac
 313     GOARCH_CACHELINESIZE=32
 314     GOARCH_PHYSPAGESIZE=16384
 315     GOARCH_PCQUANTUM=4
 316     ;;
 317   rs6000*-*-* | powerpc*-*-*)
 318     AC_COMPILE_IFELSE([
 319 #ifdef _ARCH_PPC64
 320 #error 64-bit
 321 #endif],
 322 [GOARCH=ppc
 323 GOARCH_FAMILY=PPC
 324 GOARCH_BIGENDIAN=1
 325 ],
 326     [
 327 GOARCH_FAMILY=PPC64
 328 AC_COMPILE_IFELSE([
 329 #if defined(_BIG_ENDIAN) || defined(__BIG_ENDIAN__)
 330 #error 64be
 331 #endif],
 332 [GOARCH=ppc64le
 333 ],
 334 [GOARCH=ppc64
 335 GOARCH_BIGENDIAN=1
 336 ])])
 337     GOARCH_PHYSPAGESIZE=65536
 338     GOARCH_PCQUANTUM=4
 339     GOARCH_MINFRAMESIZE=32
 340     ;;
 341   s390*-*-*)
 342     AC_COMPILE_IFELSE([
 343 #if defined(__s390x__)
 344 #error 64-bit
 345 #endif],
 346 [GOARCH=s390
 347 GOARCH_FAMILY=S390
 348 GOARCH_MINFRAMESIZE=4
 349 ], [GOARCH=s390x
 350 GOARCH_FAMILY=S390X
 351 GOARCH_MINFRAMESIZE=8
 352 ])
 353     GOARCH_BIGENDIAN=1
 354     GOARCH_CACHELINESIZE=256
 355     GOARCH_PCQUANTUM=2
 356     ;;
 357   sparc*-*-*)
 358     AC_COMPILE_IFELSE([
 359 #if defined(__sparcv9) || defined(__arch64__)
 360 #error 64-bit
 361 #endif],
 362 [GOARCH=sparc
 363 GOARCH_FAMILY=SPARC
 364 ],
 365 [GOARCH=sparc64
 366 GOARCH_FAMILY=SPARC64
 367 ])
 368     GOARCH_BIGENDIAN=1
 369     GOARCH_PHYSPAGESIZE=8192
 370     GOARCH_PCQUANTUM=4
 371     ;;
 372 esac
 373 AC_SUBST(GOARCH)
 374 AC_SUBST(GOARCH_FAMILY)
 375 AC_SUBST(GOARCH_BIGENDIAN)
 376 AC_SUBST(GOARCH_CACHELINESIZE)
 377 AC_SUBST(GOARCH_PHYSPAGESIZE)
 378 AC_SUBST(GOARCH_PCQUANTUM)
 379 AC_SUBST(GOARCH_INT64ALIGN)
 380 AC_SUBST(GOARCH_HUGEPAGESIZE)
 381 AC_SUBST(GOARCH_MINFRAMESIZE)
 382 AC_SUBST(ALLGOARCH)
 383 AC_SUBST(ALLGOARCHFAMILY)
 384
 385 dnl Some files are only present when needed for specific architectures.
 386 GO_LIBCALL_OS_FILE=
 387 GO_LIBCALL_OS_ARCH_FILE=
 388 GO_SYSCALL_OS_FILE=
 389 GO_SYSCALL_OS_ARCH_FILE=
 390 if test -f "${srcdir}/go/syscall/libcall_${GOOS}.go"; then
 391   GO_LIBCALL_OS_FILE="go/syscall/libcall_${GOOS}.go"
 392 fi
 393 if test -f "${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go"; then
 394   GO_LIBCALL_OS_ARCH_FILE="go/syscall/libcall_${GOOS}_${GOARCH}.go"
 395 fi
 396 if test -f "${srcdir}/go/syscall/syscall_${GOOS}.go"; then
 397   GO_SYSCALL_OS_FILE="go/syscall/syscall_${GOOS}.go"
 398 fi
 399 if test -f "${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go"; then
 400   GO_SYSCALL_OS_ARCH_FILE="go/syscall/syscall_${GOOS}_${GOARCH}.go"
 401 fi
 402 AC_SUBST(GO_LIBCALL_OS_FILE)
 403 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 404 AC_SUBST(GO_SYSCALL_OS_FILE)
 405 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 406
 407 dnl Special flags used to generate sysinfo.go.
 408 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 409 case "$target" in
 410     mips-sgi-irix6.5*)
 411         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 412         # msghdr in <sys/socket.h>.
 413         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 414         ;;
 415     *-*-solaris2.1[[01]])
 416         # Solaris 10+ needs this so struct msghdr gets the msg_control
 417         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 418         # above doesn't work with C99.
 419         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 420         ;;
 421 esac
 422 AC_SUBST(OSCFLAGS)
 423
 424 dnl Check if assembler supports disabling hardware capability support.
 425 GCC_CHECK_ASSEMBLER_HWCAP
 426
 427 dnl Use -fsplit-stack when compiling C code if available.
 428 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 429 [libgo_cv_c_split_stack_supported],
 430 [CFLAGS_hold=$CFLAGS
 431 CFLAGS="$CFLAGS -fsplit-stack"
 432 AC_COMPILE_IFELSE([[int i;]],
 433 [libgo_cv_c_split_stack_supported=yes],
 434 [libgo_cv_c_split_stack_supported=no])
 435 CFLAGS=$CFLAGS_hold])
 436
 437 dnl Make sure the linker permits -fsplit-stack.  Old versions of gold will
 438 dnl reject split-stack code calling non-split-stack code on targets
 439 dnl they don't support.
 440 AC_CACHE_CHECK([whether linker supports split/non-split linked together],
 441 [libgo_cv_c_linker_split_non_split],
 442 [cat > conftest1.c << EOF
 443 extern void f();
 444 int main() { f(); return 0; }
 445 EOF
 446 cat > conftest2.c << EOF
 447 void f() {}
 448 EOF
 449 $CC -c -fsplit-stack $CFLAGS $CPPFLAGS conftest1.c >/dev/null 2>&1
 450 $CC -c $CFLAGS $CPPFLAGS conftest2.c > /dev/null 2>&1
 451 if $CC -o conftest conftest1.$ac_objext conftest2.$ac_objext > /dev/null 2>&1; then
 452   libgo_cv_c_linker_split_non_split=yes
 453 else
 454   libgo_cv_c_linker_split_non_split=no
 455 fi
 456 rm -f conftest1.* conftest2.* conftest])
 457
 458 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes; then
 459   SPLIT_STACK=-fsplit-stack
 460   AC_DEFINE(USING_SPLIT_STACK, 1,
 461                 [Define if the compiler supports -fsplit-stack])
 462 else
 463   SPLIT_STACK=
 464 fi
 465 AC_SUBST(SPLIT_STACK)
 466 AM_CONDITIONAL(USING_SPLIT_STACK,
 467         test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes)
 468
 469 dnl If the compiler supports split-stack but the linker does not, then
 470 dnl we need to explicitly disable split-stack for Go.
 471 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = no; then
 472   GO_SPLIT_STACK=-fno-split-stack
 473 else
 474   GO_SPLIT_STACK=
 475 fi
 476 AC_SUBST(GO_SPLIT_STACK)
 477
 478 dnl Check whether the linker does stack munging when calling from
 479 dnl split-stack into non-split-stack code.  We check this by looking
 480 dnl at the --help output.  FIXME: This is only half right: it's
 481 dnl possible for the linker to support this for some targets but not
 482 dnl others.
 483 dnl This is slightly different from the above check, which is whether
 484 dnl the linker permits the call at all.
 485 AC_CACHE_CHECK([whether linker supports split stack],
 486 [libgo_cv_c_linker_supports_split_stack],
 487 [libgo_cv_c_linker_supports_split_stack=no
 488 if $GOC -Wl,--help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 489   libgo_cv_c_linker_supports_split_stack=yes
 490 fi])
 491 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 492   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 493             [Define if the linker support split stack adjustments])
 494 fi
 495
 496 AC_CACHE_CHECK([whether compiler is llgo],
 497 [libgo_cv_c_goc_is_llgo],
 498 [libgo_cv_c_goc_is_llgo=no
 499 if $GOC -dumpversion 2>/dev/null | grep llgo >/dev/null 2>&1; then
 500   libgo_cv_c_goc_is_llgo=yes
 501 fi])
 502 AM_CONDITIONAL(GOC_IS_LLGO, test "$libgo_cv_c_goc_is_llgo" = yes)
 503
 504 dnl Test for the -lm library.
 505 MATH_LIBS=
 506 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 507 AC_SUBST(MATH_LIBS)
 508
 509 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 510 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 511   [libgo_cv_lib_sockets=
 512    libgo_check_both=no
 513    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 514    if test "$libgo_check_socket" = "yes"; then
 515      unset ac_cv_func_connect
 516      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 517                   libgo_check_both=yes)
 518    fi
 519    if test "$libgo_check_both" = "yes"; then
 520      libgo_old_libs=$LIBS
 521      LIBS="$LIBS -lsocket -lnsl"
 522      unset ac_cv_func_accept
 523      AC_CHECK_FUNC(accept,
 524                    [libgo_check_nsl=no
 525                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 526      unset ac_cv_func_accept
 527      LIBS=$libgo_old_libs
 528    fi
 529    unset ac_cv_func_gethostbyname
 530    libgo_old_libs="$LIBS"
 531    AC_CHECK_FUNC(gethostbyname, ,
 532                  [AC_CHECK_LIB(nsl, main,
 533                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 534    unset ac_cv_func_gethostbyname
 535    AC_CHECK_FUNC(sendfile, ,
 536                  [AC_CHECK_LIB(sendfile, main,
 537                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lsendfile"])])
 538    LIBS=$libgo_old_libs
 539 ])
 540 NET_LIBS="$libgo_cv_lib_sockets"
 541 AC_SUBST(NET_LIBS)
 542
 543 dnl Test whether the compiler supports the -pthread option.
 544 AC_CACHE_CHECK([whether -pthread is supported],
 545 [libgo_cv_lib_pthread],
 546 [CFLAGS_hold=$CFLAGS
 547 CFLAGS="$CFLAGS -pthread"
 548 AC_COMPILE_IFELSE([[int i;]],
 549 [libgo_cv_lib_pthread=yes],
 550 [libgo_cv_lib_pthread=no])
 551 CFLAGS=$CFLAGS_hold])
 552 PTHREAD_CFLAGS=
 553 if test "$libgo_cv_lib_pthread" = yes; then
 554   PTHREAD_CFLAGS=-pthread
 555 fi
 556 AC_SUBST(PTHREAD_CFLAGS)
 557
 558 dnl Test for the -lpthread library.
 559 PTHREAD_LIBS=
 560 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 561 AC_SUBST(PTHREAD_LIBS)
 562
 563 dnl Test if -lrt is required for sched_yield or nanosleep or clock_gettime.
 564 AC_SEARCH_LIBS([sched_yield], [rt])
 565 AC_SEARCH_LIBS([nanosleep], [rt])
 566 AC_SEARCH_LIBS([clock_gettime], [rt])
 567
 568 AC_C_BIGENDIAN
 569
 570 GCC_CHECK_UNWIND_GETIPINFO
 571
 572 AC_CHECK_HEADERS(port.h sched.h semaphore.h sys/file.h sys/mman.h syscall.h sys/epoll.h sys/event.h sys/inotify.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h net/if_arp.h net/route.h netpacket/packet.h sys/prctl.h sys/mount.h sys/vfs.h sys/statfs.h sys/timex.h sys/sysinfo.h utime.h linux/ether.h linux/fs.h linux/reboot.h netinet/icmp6.h netinet/in_syst.h netinet/ip.h netinet/ip_mroute.h netinet/if_ether.h)
 573
 574 AC_CHECK_HEADERS([linux/filter.h linux/if_addr.h linux/if_ether.h linux/if_tun.h linux/netlink.h linux/rtnetlink.h], [], [],
 575 [#ifdef HAVE_SYS_SOCKET_H
 576 #include <sys/socket.h>
 577 #endif
 578 ])
 579
 580 AC_CACHE_CHECK([whether <ustat.h> can be used],
 581 [libgo_cv_c_ustat_h],
 582 [CFLAGS_hold=$CFLAGS
 583 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE $OSCFLAGS"
 584 AC_COMPILE_IFELSE(
 585 [AC_LANG_SOURCE([
 586 #include <sys/types.h>
 587 #ifdef HAVE_LINUX_FILTER_H
 588 #include <linux/filter.h>
 589 #endif
 590 #include <ustat.h>
 591 ])], [libgo_cv_c_ustat_h=yes], [libgo_cv_c_ustat_h=no])
 592 CFLAGS=$CFLAGS_hold])
 593 if test $libgo_cv_c_ustat_h = yes; then
 594   AC_DEFINE(HAVE_USTAT_H, 1,
 595     [Define to 1 if you have the <ustat.h> header file and it works.])
 596 fi
 597
 598 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 599
 600 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv unsetenv dl_iterate_phdr)
 601 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 602 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 603
 604 AC_CHECK_FUNCS(accept4 dup3 epoll_create1 faccessat fallocate fchmodat fchownat futimesat getxattr inotify_add_watch inotify_init inotify_init1 inotify_rm_watch listxattr mkdirat mknodat open64 openat pipe2 removexattr renameat setxattr sync_file_range splice tee unlinkat unshare utimensat)
 605 AC_TYPE_OFF_T
 606 AC_CHECK_TYPES([loff_t])
 607
 608 LIBS_hold="$LIBS"
 609 LIBS="$LIBS -lm"
 610 AC_CHECK_FUNCS(cosl expl logl sinl tanl acosl asinl atanl atan2l expm1l ldexpl log10l log1pl)
 611 LIBS="$LIBS_hold"
 612
 613 CFLAGS_hold="$CFLAGS"
 614 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 615 LIBS_hold="$LIBS"
 616 LIBS="$LIBS $PTHREAD_LIBS"
 617 AC_CHECK_FUNCS(sem_timedwait)
 618 CFLAGS="$CFLAGS_hold"
 619 LIBS="$LIBS_hold"
 620
 621 LIBS_hold="$LIBS"
 622 LIBS="$LIBS $MATH_LIBS"
 623 AC_CHECK_FUNCS(matherr)
 624 LIBS="$LIBS_hold"
 625
 626 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_4],
 627 [libgo_cv_func___sync_bool_compare_and_swap_4],
 628 [AC_LINK_IFELSE([
 629 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 630 uint32 i;
 631 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 632 ],
 633 [libgo_cv_func___sync_bool_compare_and_swap_4=yes],
 634 [libgo_cv_func___sync_bool_compare_and_swap_4=no])])
 635 if test "$libgo_cv_func___sync_bool_compare_and_swap_4" = "yes"; then
 636   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_4, 1,
 637     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint32])
 638 fi
 639
 640 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_8],
 641 [libgo_cv_func___sync_bool_compare_and_swap_8],
 642 [AC_LINK_IFELSE([
 643 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 644 uint64 i;
 645 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 646 ],
 647 [libgo_cv_func___sync_bool_compare_and_swap_8=yes],
 648 [libgo_cv_func___sync_bool_compare_and_swap_8=no])])
 649 if test "$libgo_cv_func___sync_bool_compare_and_swap_8" = "yes"; then
 650   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_8, 1,
 651     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint64])
 652 fi
 653
 654 AC_CACHE_CHECK([for __sync_fetch_and_add_4],
 655 [libgo_cv_func___sync_fetch_and_add_4],
 656 [AC_LINK_IFELSE([
 657 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 658 uint32 i;
 659 int main() { return __sync_fetch_and_add (&i, 1); }
 660 ],
 661 [libgo_cv_func___sync_fetch_and_add_4=yes],
 662 [libgo_cv_func___sync_fetch_and_add_4=no])])
 663 if test "$libgo_cv_func___sync_fetch_and_add_4" = "yes"; then
 664   AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD_4, 1,
 665     [Define to 1 if the compiler provides the __sync_fetch_and_add function for uint32])
 666 fi
 667
 668 AC_CACHE_CHECK([for __sync_add_and_fetch_8],
 669 [libgo_cv_func___sync_add_and_fetch_8],
 670 [AC_LINK_IFELSE([
 671 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 672 uint64 i;
 673 int main() { return __sync_add_and_fetch (&i, 1); }
 674 ],
 675 [libgo_cv_func___sync_add_and_fetch_8=yes],
 676 [libgo_cv_func___sync_add_and_fetch_8=no])])
 677 if test "$libgo_cv_func___sync_add_and_fetch_8" = "yes"; then
 678   AC_DEFINE(HAVE_SYNC_ADD_AND_FETCH_8, 1,
 679     [Define to 1 if the compiler provides the __sync_add_and_fetch function for uint64])
 680 fi
 681
 682 dnl For x86 we want to use the -minline-all-stringops option to avoid
 683 dnl forcing a stack split when calling memcpy and friends.
 684 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 685 [libgo_cv_c_stringops],
 686 [CFLAGS_hold=$CFLAGS
 687 CFLAGS="$CFLAGS -minline-all-stringops"
 688 AC_COMPILE_IFELSE([int i;],
 689 [libgo_cv_c_stringops=yes],
 690 [libgo_cv_c_stringops=no])
 691 CFLAGS=$CFLAGS_hold])
 692 STRINGOPS_FLAG=
 693 if test "$libgo_cv_c_stringops" = yes; then
 694   STRINGOPS_FLAG=-minline-all-stringops
 695 fi
 696 AC_SUBST(STRINGOPS_FLAG)
 697
 698 dnl For x86 we want to compile the math library with -mfancy-math-387
 699 dnl -funsafe-math-optimizations so that we can use the builtin
 700 dnl instructions directly.
 701 AC_CACHE_CHECK([whether compiler supports -mfancy-math-387],
 702 [libgo_cv_c_fancymath],
 703 [CFLAGS_hold=$CFLAGS
 704 CFLAGS="$CFLAGS -mfancy-math-387"
 705 AC_COMPILE_IFELSE([int i;],
 706 [libgo_cv_c_fancymath=yes],
 707 [libgo_cv_c_fancymath=no])
 708 CFLAGS=$CFLAGS_hold])
 709 MATH_FLAG=
 710 if test "$libgo_cv_c_fancymath" = yes; then
 711   MATH_FLAG="-mfancy-math-387 -funsafe-math-optimizations"
 712 else
 713   MATH_FLAG="-ffp-contract=off"
 714 fi
 715 AC_SUBST(MATH_FLAG)
 716
 717 CFLAGS_hold=$CFLAGS
 718 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 719 AC_CHECK_TYPES([off64_t])
 720 CFLAGS=$CFLAGS_hold
 721
 722 dnl Work out the size of the epoll_events struct on GNU/Linux.
 723 AC_CACHE_CHECK([epoll_event size],
 724 [libgo_cv_c_epoll_event_size],
 725 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 726 [sizeof (struct epoll_event)],
 727 [#include <sys/epoll.h>],
 728 [libgo_cv_c_epoll_event_size=0])])
 729 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 730 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 731
 732 dnl Work out the offset of the fd field in the epoll_events struct on
 733 dnl GNU/Linux.
 734 AC_CACHE_CHECK([epoll_event data.fd offset],
 735 [libgo_cv_c_epoll_event_fd_offset],
 736 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 737 [offsetof (struct epoll_event, data.fd)],
 738 [#include <stddef.h>
 739 #include <sys/epoll.h>],
 740 [libgo_cv_c_epoll_event_fd_offset=0])])
 741 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 742 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 743
 744 dnl Check if <sys/stat.h> uses timespec_t for st_?tim members.  Introduced
 745 dnl in Solaris 12 for XPG7 compatibility.
 746 AC_EGREP_HEADER([timespec_t.*st_atim], [sys/stat.h],
 747                 [have_stat_timespec=yes], [have_stat_timespec=no])
 748 AM_CONDITIONAL(HAVE_STAT_TIMESPEC, test $have_stat_timespec = yes)
 749
 750 dnl See if struct exception is defined in <math.h>.
 751 AC_CHECK_TYPE([struct exception],
 752 [libgo_has_struct_exception=yes],
 753 [libgo_has_struct_exception=no],
 754 [#include <math.h>])
 755 if test "$libgo_has_struct_exception" = "yes"; then
 756   AC_DEFINE(HAVE_STRUCT_EXCEPTION, 1,
 757             [Define to 1 if <math.h> defines struct exception])
 758 fi
 759
 760 dnl See whether setcontext changes the value of TLS variables.
 761 AC_CACHE_CHECK([whether setcontext clobbers TLS variables],
 762 [libgo_cv_lib_setcontext_clobbers_tls],
 763 [CFLAGS_hold="$CFLAGS"
 764 CFLAGS="$PTHREAD_CFLAGS"
 765 LIBS_hold="$LIBS"
 766 LIBS="$LIBS $PTHREAD_LIBS"
 767 AC_CHECK_SIZEOF([void *])
 768 AS_VAR_ARITH([ptr_type_size], [$ac_cv_sizeof_void_p \* 8])
 769 AC_RUN_IFELSE(
 770   [AC_LANG_SOURCE([
 771 #include <pthread.h>
 772 #include <stdlib.h>
 773 #include <ucontext.h>
 774 #include <unistd.h>
 775
 776 __thread int tls;
 777
 778 static char stack[[10 * 1024 * 1024]];
 779 static ucontext_t c;
 780
 781 /* Called via makecontext/setcontext.  */
 782
 783 static void
 784 cfn (void)
 785 {
 786   exit (tls);
 787 }
 788
 789 /* Called via pthread_create.  */
 790
 791 static void *
 792 tfn (void *dummy)
 793 {
 794   /* The thread should still see this value after calling
 795      setcontext.  */
 796   tls = 0;
 797
 798   setcontext (&c);
 799
 800   /* The call to setcontext should not return.  */
 801   abort ();
 802 }
 803
 804 int
 805 main ()
 806 {
 807   pthread_t tid;
 808
 809   /* The thread should not see this value.  */
 810   tls = 1;
 811
 812   if (getcontext (&c) < 0)
 813     abort ();
 814
 815   c.uc_stack.ss_sp = stack;
 816 #ifdef MAKECONTEXT_STACK_TOP
 817   c.uc_stack.ss_sp += sizeof stack;
 818 #endif
 819   c.uc_stack.ss_flags = 0;
 820   c.uc_stack.ss_size = sizeof stack;
 821   c.uc_link = NULL;
 822   makecontext (&c, cfn, 0);
 823
 824   if (pthread_create (&tid, NULL, tfn, NULL) != 0)
 825     abort ();
 826
 827   if (pthread_join (tid, NULL) != 0)
 828     abort ();
 829
 830   /* The thread should have called exit.  */
 831   abort ();
 832 }
 833 ])],
 834 [libgo_cv_lib_setcontext_clobbers_tls=no],
 835 [libgo_cv_lib_setcontext_clobbers_tls=yes],
 836 [case "$target:$ptr_type_size" in
 837   i?86-*-solaris2.1[[01]]:64 | x86_64*-*-solaris2.1[[01]]:64)
 838     libgo_cv_lib_setcontext_clobbers_tls=yes ;;
 839   *)
 840     libgo_cv_lib_setcontext_clobbers_tls=no ;;
 841  esac
 842 ])
 843 CFLAGS="$CFLAGS_hold"
 844 LIBS="$LIBS_hold"
 845 ])
 846 if test "$libgo_cv_lib_setcontext_clobbers_tls" = "yes"; then
 847   AC_DEFINE(SETCONTEXT_CLOBBERS_TLS, 1,
 848             [Define if setcontext clobbers TLS variables])
 849 fi
 850
 851 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 852 libgo_cv_ro_eh_frame, [
 853 libgo_cv_ro_eh_frame=no
 854 echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 855 if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 856   if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 857     libgo_cv_ro_eh_frame=yes
 858   elif grep '.section.*eh_frame.*#alloc' conftest.c \
 859        | grep -v '#write' > /dev/null; then
 860     libgo_cv_ro_eh_frame=yes
 861   fi
 862 fi
 863 rm -f conftest.*
 864 ])
 865 if test "x$libgo_cv_ro_eh_frame" = xyes; then
 866   AC_DEFINE(EH_FRAME_FLAGS, "a",
 867             [Define to the flags needed for the .section .eh_frame directive.])
 868 else
 869   AC_DEFINE(EH_FRAME_FLAGS, "aw",
 870             [Define to the flags needed for the .section .eh_frame directive.])
 871 fi
 872
 873 AC_CACHE_CHECK([if compiler supports -Qunused-arguments],
 874 [libgo_cv_c_unused_arguments],
 875 [CFLAGS_hold=$CFLAGS
 876 CFLAGS="$CFLAGS -Qunused-arguments"
 877 AC_COMPILE_IFELSE([[int i;]],
 878 [libgo_cv_c_unused_arguments=yes],
 879 [libgo_cv_c_unused_arguments=no])
 880 CFLAGS=$CFLAGS_hold])
 881
 882 AC_CACHE_CHECK([if assembler supports GNU comdat group syntax],
 883 libgo_cv_as_comdat_gnu, [
 884 echo '.section .text,"axG",@progbits,.foo,comdat' > conftest.s
 885 CFLAGS_hold=$CFLAGS
 886 if test "$libgo_cv_c_unused_arguments" = yes; then
 887   CFLAGS="$CFLAGS -Qunused-arguments"
 888 fi
 889 if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
 890   libgo_cv_as_comdat_gnu=yes
 891 else
 892   libgo_cv_as_comdat_gnu=no
 893 fi
 894 CFLAGS=$CFLAGS_hold
 895 ])
 896 if test "x$libgo_cv_as_comdat_gnu" = xyes; then
 897   AC_DEFINE(HAVE_AS_COMDAT_GAS, 1,
 898             [Define if your assembler supports GNU comdat group syntax.])
 899 fi
 900
 901 AC_CACHE_CHECK([assembler supports pc related relocs],
 902 libgo_cv_as_x86_pcrel, [
 903 libgo_cv_as_x86_pcrel=yes
 904 echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 905 CFLAGS_hold=$CFLAGS
 906 if test "$libgo_cv_c_unused_arguments" = yes; then
 907   CFLAGS="$CFLAGS -Qunused-arguments"
 908 fi
 909 if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 910     libgo_cv_as_x86_pcrel=no
 911 fi
 912 CFLAGS=$CFLAGS_hold
 913 ])
 914 if test "x$libgo_cv_as_x86_pcrel" = xyes; then
 915   AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 916             [Define if your assembler supports PC relative relocs.])
 917 fi
 918
 919 AC_CACHE_CHECK([assembler supports unwind section type],
 920 libgo_cv_as_x86_64_unwind_section_type, [
 921 libgo_cv_as_x86_64_unwind_section_type=yes
 922 echo '.section .eh_frame,"a",@unwind' > conftest.s
 923 CFLAGS_hold=$CFLAGS
 924 if test "$libgo_cv_c_unused_arguments" = yes; then
 925   CFLAGS="$CFLAGS -Qunused-arguments"
 926 fi
 927 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 928     libgo_cv_as_x86_64_unwind_section_type=no
 929 fi
 930 CFLAGS=$CFLAGS_hold
 931 ])
 932 if test "x$libgo_cv_as_x86_64_unwind_section_type" = xyes; then
 933   AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 934             [Define if your assembler supports unwind section type.])
 935 fi
 936
 937 AC_CACHE_CHECK([assembler supports AES instructions],
 938 libgo_cv_as_x86_aes, [
 939 libgo_cv_as_x86_aes=yes
 940 echo 'aesenc %xmm0, %xmm1' > conftest.s
 941 CFLAGS_hold=$CFLAGS
 942 if test "$libgo_cv_c_unused_arguments" = yes; then
 943   CFLAGS="$CFLAGS -Qunused-arguments"
 944 fi
 945 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i error > /dev/null; then
 946     libgo_cv_as_x86_aes=no
 947 fi
 948 CFLAGS=$CFLAGS_hold
 949 ])
 950 if test "x$libgo_cv_as_x86_aes" = xyes; then
 951   AC_DEFINE(HAVE_AS_X86_AES, 1,
 952             [Define if your assembler supports AES instructions.])
 953 fi
 954
 955 AC_CACHE_SAVE
 956
 957 if test ${multilib} = yes; then
 958   multilib_arg="--enable-multilib"
 959 else
 960   multilib_arg=
 961 fi
 962
 963 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 964
 965 AC_CONFIG_COMMANDS([default],
 966 [if test -n "$CONFIG_FILES"; then
 967    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 968    # that multilib installs will end up installed in the correct place.
 969    # The testsuite needs it for multilib-aware ABI baseline files.
 970    # To work around this not being passed down from config-ml.in ->
 971    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 972    # append it here.  Only modify Makefiles that have just been created.
 973    #
 974    # Also, get rid of this simulated-VPATH thing that automake does.
 975    cat > vpsed << \_EOF
 976 s!`test -f '$<' || echo '$(srcdir)/'`!!
 977 _EOF
 978    for i in $SUBDIRS; do
 979     case $CONFIG_FILES in
 980      *${i}/Makefile*)
 981        #echo "Adding MULTISUBDIR to $i/Makefile"
 982        sed -f vpsed $i/Makefile > tmp
 983        grep '^MULTISUBDIR =' Makefile >> tmp
 984        mv tmp $i/Makefile
 985        ;;
 986     esac
 987    done
 988    rm vpsed
 989  fi
 990 ],
 991 [
 992 # Variables needed in config.status (file generation) which aren't already
 993 # passed by autoconf.
 994 SUBDIRS="$SUBDIRS"
 995 ])
 996
 997 AC_OUTPUT