libatomic/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2 #  Copyright (C) 2012-2023 Free Software Foundation, Inc.
   3 #
   4 #  This file is part of the GNU Atomic Library (libatomic).
   5 #
   6 #  Libatomic is free software; you can redistribute it and/or modify it
   7 #  under the terms of the GNU General Public License as published by
   8 #  the Free Software Foundation; either version 3 of the License, or
   9 #  (at your option) any later version.
  10 #
  11 #  Libatomic is distributed in the hope that it will be useful, but WITHOUT ANY
  12 #  WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  13 #  FOR A PARTICULAR PURPOSE.  See the GNU General Public License for
  14 #  more details.
  15 #
  16 #  Under Section 7 of GPL version 3, you are granted additional
  17 #  permissions described in the GCC Runtime Library Exception, version
  18 #  3.1, as published by the Free Software Foundation.
  19 #
  20 #  You should have received a copy of the GNU General Public License and
  21 #  a copy of the GCC Runtime Library Exception along with this program;
  22 #  see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see
  23 #  <http://www.gnu.org/licenses/>.
  24
  25 AC_INIT([GNU Atomic Library], 1.0,,[libatomic])
  26 AC_CONFIG_HEADER(auto-config.h)
  27
  28 # -------
  29 # Options
  30 # -------
  31
  32 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  33 LIBAT_ENABLE(version-specific-runtime-libs, no, ,
  34    [Specify that runtime libraries should be installed in a compiler-specific directory],
  35    permit yes|no)
  36 AC_MSG_RESULT($enable_version_specific_runtime_libs)
  37
  38 # We would like our source tree to be readonly. However when releases or
  39 # pre-releases are generated, the flex/bison generated files as well as the
  40 # various formats of manuals need to be included along with the rest of the
  41 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
  42 # just that.
  43 AC_MSG_CHECKING([for --enable-generated-files-in-srcdir])
  44 LIBAT_ENABLE(generated-files-in-srcdir, no, ,
  45    [put copies of generated files in source dir intended for creating source
  46     tarballs for users without texinfo bison or flex.],
  47    permit yes|no)
  48 AC_MSG_RESULT($enable_generated_files_in_srcdir)
  49 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
  50
  51
  52 # -------
  53
  54 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  55 #
  56 # You will slowly go insane if you do not grok the following fact:  when
  57 # building this library, the top-level /target/ becomes the library's /host/.
  58 #
  59 # configure then causes --target to default to --host, exactly like any
  60 # other package using autoconf.  Therefore, 'target' and 'host' will
  61 # always be the same.  This makes sense both for native and cross compilers
  62 # just think about it for a little while.  :-)
  63 #
  64 # Also, if this library is being configured as part of a cross compiler, the
  65 # top-level configure script will pass the "real" host as $with_cross_host.
  66 #
  67 # Do not delete or change the following two lines.  For why, see
  68 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  69 AC_CANONICAL_SYSTEM
  70 target_alias=${target_alias-$host_alias}
  71
  72 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  73 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  74 #  1.9.0:  minimum required version
  75 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  76 #              of other PACKAGE_* variables will, however, and there's nothing
  77 #              we can do about that; they come from AC_INIT).
  78 #  no-dist:  we don't want 'dist' and related rules.
  79 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  80 #            file in the top srcdir, etc, etc), so stop complaining.
  81 #  -Wall:  turns on all automake warnings...
  82 #  -Wno-portability:  ...except this one, since GNU make is required.
  83 #  -Wno-override: ... and this one, since we do want this in testsuite.
  84 AM_INIT_AUTOMAKE([1.9.0 foreign no-dist -Wall -Wno-portability -Wno-override])
  85 AM_ENABLE_MULTILIB(, ..)
  86
  87 GCC_WITH_TOOLEXECLIBDIR
  88
  89 # Calculate toolexeclibdir
  90 # Also toolexecdir, though it's only used in toolexeclibdir
  91 case ${enable_version_specific_runtime_libs} in
  92   yes)
  93     # Need the gcc compiler version to know where to install libraries
  94     # and header files if --enable-version-specific-runtime-libs option
  95     # is selected.
  96     toolexecdir='$(libdir)/gcc/$(target_alias)'
  97     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  98     ;;
  99   no)
 100     if test -n "$with_cross_host" &&
 101        test x"$with_cross_host" != x"no"; then
 102       # Install a library built with a cross compiler in tooldir, not libdir.
 103       toolexecdir='$(exec_prefix)/$(target_alias)'
 104       case ${with_toolexeclibdir} in
 105         no)
 106           toolexeclibdir='$(toolexecdir)/lib'
 107           ;;
 108         *)
 109           toolexeclibdir=${with_toolexeclibdir}
 110           ;;
 111       esac
 112     else
 113       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 114       toolexeclibdir='$(libdir)'
 115     fi
 116     multi_os_directory=`$CC -print-multi-os-directory`
 117     case $multi_os_directory in
 118       .) ;; # Avoid trailing /.
 119       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 120     esac
 121     ;;
 122 esac
 123 AC_SUBST(toolexecdir)
 124 AC_SUBST(toolexeclibdir)
 125
 126 # Check the compiler.
 127 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
 128 # We must force CC to /not/ be precious variables; otherwise
 129 # the wrong, non-multilib-adjusted value will be used in multilibs.
 130 # As a side effect, we have to subst CFLAGS ourselves.
 131
 132 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 133 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 134 AC_PROG_CC
 135 AM_PROG_AS
 136 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 137
 138 AC_SUBST(CFLAGS)
 139
 140 # In order to override CFLAGS_FOR_TARGET, all of our special flags go
 141 # in XCFLAGS.  But we need them in CFLAGS during configury.  So put them
 142 # in both places for now and restore CFLAGS at the end of config.
 143 save_CFLAGS="$CFLAGS"
 144
 145 # Find other programs we need.
 146 AC_CHECK_TOOL(AR, ar)
 147 AC_CHECK_TOOL(NM, nm)
 148 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 149 AC_PROG_INSTALL
 150
 151 # Configure libtool
 152 AM_PROG_LIBTOOL
 153 ACX_LT_HOST_FLAGS
 154 AC_SUBST(enable_shared)
 155 AC_SUBST(enable_static)
 156 AM_MAINTAINER_MODE
 157
 158 AM_CONDITIONAL([ENABLE_DARWIN_AT_RPATH], [test x$enable_darwin_at_rpath = xyes])
 159
 160 # For libtool versioning info, format is CURRENT:REVISION:AGE
 161 libtool_VERSION=3:0:2
 162 AC_SUBST(libtool_VERSION)
 163
 164 # Check for used threading-model
 165 AC_MSG_CHECKING([for thread model used by GCC])
 166 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 167 AC_MSG_RESULT([$target_thread_file])
 168
 169 case "$target" in
 170  *aarch64*)
 171     ACX_PROG_CC_WARNING_OPTS([-march=armv8-a+lse],[enable_aarch64_lse])
 172     ;;
 173 esac
 174
 175 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
 176
 177 # Get target configury.
 178 . ${srcdir}/configure.tgt
 179 if test -n "$UNSUPPORTED"; then
 180   AC_MSG_ERROR([Configuration ${target} is unsupported.])
 181 fi
 182
 183 # Write out the ifunc resolver arg type.
 184 AC_DEFINE_UNQUOTED(IFUNC_RESOLVER_ARGS, $IFUNC_RESOLVER_ARGS,
 185         [Define ifunc resolver function argument.])
 186
 187 # Disable fallbacks to __sync routines from libgcc.  Otherwise we'll
 188 # make silly decisions about what the cpu can do.
 189 CFLAGS="$save_CFLAGS -fno-sync-libcalls $XCFLAGS"
 190
 191 # Check header files.
 192 AC_STDC_HEADERS
 193 ACX_HEADER_STRING
 194 GCC_HEADER_STDINT(gstdint.h)
 195 AC_CHECK_HEADERS([fenv.h])
 196
 197 # Check for common type sizes
 198 LIBAT_FORALL_MODES([LIBAT_HAVE_INT_MODE])
 199
 200 # Check for compiler builtins of atomic operations.
 201 LIBAT_TEST_ATOMIC_INIT
 202 LIBAT_FORALL_MODES([LIBAT_HAVE_ATOMIC_LOADSTORE])
 203 LIBAT_FORALL_MODES([LIBAT_HAVE_ATOMIC_TAS])
 204 LIBAT_FORALL_MODES([LIBAT_HAVE_ATOMIC_EXCHANGE])
 205 LIBAT_FORALL_MODES([LIBAT_HAVE_ATOMIC_CAS])
 206 LIBAT_FORALL_MODES([LIBAT_HAVE_ATOMIC_FETCH_ADD])
 207 LIBAT_FORALL_MODES([LIBAT_HAVE_ATOMIC_FETCH_OP])
 208
 209 AC_C_BIGENDIAN
 210 # I don't like the default behaviour of WORDS_BIGENDIAN undefined for LE.
 211 AH_BOTTOM(
 212 [#ifndef WORDS_BIGENDIAN
 213 #define WORDS_BIGENDIAN 0
 214 #endif])
 215
 216 LIBAT_WORDSIZE
 217
 218 # Check to see if -pthread or -lpthread is needed.  Prefer the former.
 219 # In case the pthread.h system header is not found, this test will fail.
 220 case " $config_path " in
 221  *" posix "*)
 222   XPCFLAGS=""
 223   CFLAGS="$CFLAGS -pthread"
 224   AC_LINK_IFELSE(
 225     [AC_LANG_PROGRAM(
 226      [#include <pthread.h>
 227       void *g(void *d) { return NULL; }],
 228      [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 229     [XPCFLAGS=" -pthread"],
 230     [CFLAGS="$save_CFLAGS $XCFLAGS" LIBS="-lpthread $LIBS"
 231      AC_LINK_IFELSE(
 232       [AC_LANG_PROGRAM(
 233        [#include <pthread.h>
 234         void *g(void *d) { return NULL; }],
 235        [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 236       [],
 237       [AC_MSG_ERROR([Pthreads are required to build libatomic])])])
 238   CFLAGS="$save_CFLAGS $XPCFLAGS"
 239   ;;
 240 esac
 241
 242 # See what sort of export controls are available.
 243 LIBAT_CHECK_ATTRIBUTE_VISIBILITY
 244 LIBAT_CHECK_ATTRIBUTE_DLLEXPORT
 245 LIBAT_CHECK_ATTRIBUTE_ALIAS
 246 if test x$try_ifunc = xyes; then
 247   LIBAT_CHECK_IFUNC
 248 fi
 249
 250 # Check linker support.
 251 LIBAT_ENABLE_SYMVERS
 252
 253 # Cleanup and exit.
 254 CFLAGS="$save_CFLAGS"
 255 AC_CACHE_SAVE
 256
 257 AC_ARG_ENABLE([werror],
 258   [AS_HELP_STRING([--disable-werror], [disable building with -Werror])])
 259 # Add -Wall -Werror if we are using GCC.
 260 AS_IF([test "x$GCC" = "xyes"],
 261   [XCFLAGS="$XCFLAGS -Wall"])
 262 AS_IF([test "x$enable_werror" != "xno" && test "x$GCC" = "xyes"],
 263   [XCFLAGS="$XCFLAGS -Werror"])
 264
 265 # Add CET specific flags if CET is enabled
 266 GCC_CET_FLAGS(CET_FLAGS)
 267 XCFLAGS="$XCFLAGS $CET_FLAGS"
 268
 269 XCFLAGS="$XCFLAGS $XPCFLAGS"
 270
 271 AC_SUBST(config_path)
 272 AC_SUBST(XCFLAGS)
 273 AC_SUBST(XLDFLAGS)
 274 AC_SUBST(LIBS)
 275 AC_SUBST(SIZES)
 276
 277 # Conditionalize the makefile for this target machine.
 278 tmake_file_=
 279 for f in ${tmake_file}
 280 do
 281         if test -f ${srcdir}/config/$f
 282         then
 283                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
 284         fi
 285 done
 286 tmake_file="${tmake_file_}"
 287 AC_SUBST(tmake_file)
 288
 289
 290 AM_CONDITIONAL(HAVE_IFUNC, test x$libat_cv_have_ifunc = xyes)
 291 AM_CONDITIONAL(ARCH_AARCH64_LINUX,
 292                [expr "$config_path" : ".* linux/aarch64 .*" > /dev/null])
 293 AM_CONDITIONAL(ARCH_ARM_LINUX,
 294                [expr "$config_path" : ".* linux/arm .*" > /dev/null])
 295 AM_CONDITIONAL(ARCH_I386,
 296                [test "$ARCH" = x86 && test x$libat_cv_wordsize = x4])
 297 AM_CONDITIONAL(ARCH_X86_64,
 298                [test "$ARCH" = x86 && test x$libat_cv_wordsize = x8])
 299
 300 # Determine what GCC version number to use in filesystem paths.
 301 GCC_BASE_VER
 302
 303 if test ${multilib} = yes; then
 304   multilib_arg="--enable-multilib"
 305 else
 306   multilib_arg=
 307 fi
 308
 309 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 310 AC_CONFIG_FILES(testsuite/libatomic-site-extra.exp)
 311 AC_OUTPUT