libgcc/config/rs6000/tramp.S

   1 /*  Special support for trampolines
   2  *
   3  *   Copyright (C) 1996-2018 Free Software Foundation, Inc.
   4  *   Written By Michael Meissner
   5  *
   6  * This file is free software; you can redistribute it and/or modify it
   7  * under the terms of the GNU General Public License as published by the
   8  * Free Software Foundation; either version 3, or (at your option) any
   9  * later version.
  10  *
  11  * This file is distributed in the hope that it will be useful, but
  12  * WITHOUT ANY WARRANTY; without even the implied warranty of
  13  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14  * General Public License for more details.
  15  *
  16  * Under Section 7 of GPL version 3, you are granted additional
  17  * permissions described in the GCC Runtime Library Exception, version
  18  * 3.1, as published by the Free Software Foundation.
  19  *
  20  * You should have received a copy of the GNU General Public License and
  21  * a copy of the GCC Runtime Library Exception along with this program;
  22  * see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see
  23  * <http://www.gnu.org/licenses/>.
  24  */
  25
  26 /* Set up trampolines.  */
  27
  28         .section ".text"
  29 #include "ppc-asm.h"
  30 #include "config.h"
  31
  32 #ifndef __powerpc64__
  33         .type   trampoline_initial,@object
  34         .align  2
  35 trampoline_initial:
  36         mflr    r0
  37         bcl     20,31,1f
  38 .Lfunc = .-trampoline_initial
  39         .long   0                       /* will be replaced with function address */
  40 .Lchain = .-trampoline_initial
  41         .long   0                       /* will be replaced with static chain */
  42 1:      mflr    r11
  43         mtlr    r0
  44         lwz     r0,0(r11)               /* function address */
  45         lwz     r11,4(r11)              /* static chain */
  46         mtctr   r0
  47         bctr
  48
  49 trampoline_size = .-trampoline_initial
  50         .size   trampoline_initial,trampoline_size
  51
  52
  53 /* R3 = stack address to store trampoline */
  54 /* R4 = length of trampoline area */
  55 /* R5 = function address */
  56 /* R6 = static chain */
  57
  58 FUNC_START(__trampoline_setup)
  59         .cfi_startproc
  60         mflr    r0              /* save return address */
  61         bcl     20,31,.LCF0     /* load up __trampoline_initial into r7 */
  62         .cfi_register lr,r0
  63 .LCF0:
  64         mflr    r11
  65         addi    r7,r11,trampoline_initial-4-.LCF0 /* trampoline address -4 */
  66
  67         li      r8,trampoline_size      /* verify that the trampoline is big enough */
  68         cmpw    cr1,r8,r4
  69         srwi    r4,r4,2         /* # words to move */
  70         addi    r9,r3,-4        /* adjust pointer for lwzu */
  71         mtctr   r4
  72         blt     cr1,.Labort
  73
  74         mtlr    r0
  75
  76         /* Copy the instructions to the stack */
  77 .Lmove:
  78         lwzu    r10,4(r7)
  79         stwu    r10,4(r9)
  80         bdnz    .Lmove
  81
  82         /* Store correct function and static chain */
  83         stw     r5,.Lfunc(r3)
  84         stw     r6,.Lchain(r3)
  85
  86         /* Now flush both caches */
  87         mtctr   r4
  88 .Lcache:
  89         icbi    0,r3
  90         dcbf    0,r3
  91         addi    r3,r3,4
  92         bdnz    .Lcache
  93
  94         /* Finally synchronize things & return */
  95         sync
  96         isync
  97         blr
  98
  99 .Labort:
 100 /* Use a longcall sequence in the non PIC case on VxWorks, to prevent
 101    possible relocation errors if this is module-loaded very far away from
 102    the 'abort' entry point.  */
 103 #if defined (__VXWORKS__) && ! (defined __PIC__ || defined __pic__)
 104         lis   r11,JUMP_TARGET(abort)@ha
 105         addic r11,r11,JUMP_TARGET(abort)@l
 106         mtlr  r11
 107         blrl
 108 #else
 109
 110 #if (defined __PIC__ || defined __pic__) && defined HAVE_AS_REL16
 111         bcl     20,31,1f
 112 1:      mflr    r30
 113         addis   r30,r30,_GLOBAL_OFFSET_TABLE_-1b@ha
 114         addi    r30,r30,_GLOBAL_OFFSET_TABLE_-1b@l
 115 #endif
 116         bl      JUMP_TARGET(abort)
 117         .cfi_endproc
 118 FUNC_END(__trampoline_setup)
 119
 120 #endif
 121
 122 #elif _CALL_ELF == 2
 123         .type   trampoline_initial,@object
 124         .align  3
 125 trampoline_initial:
 126         ld      r11,.Lchain(r12)
 127         ld      r12,.Lfunc(r12)
 128         mtctr   r12
 129         bctr
 130 .Lfunc = .-trampoline_initial
 131         .quad   0                       /* will be replaced with function address */
 132 .Lchain = .-trampoline_initial
 133         .quad   0                       /* will be replaced with static chain */
 134
 135 trampoline_size = .-trampoline_initial
 136         .size   trampoline_initial,trampoline_size
 137
 138
 139 /* R3 = stack address to store trampoline */
 140 /* R4 = length of trampoline area */
 141 /* R5 = function address */
 142 /* R6 = static chain */
 143
 144         .pushsection ".toc","aw"
 145 .LC0:
 146         .quad   trampoline_initial-8
 147         .popsection
 148
 149 FUNC_START(__trampoline_setup)
 150         .cfi_startproc
 151         addis 7,2,.LC0@toc@ha
 152         ld 7,.LC0@toc@l(7)      /* trampoline address -8 */
 153
 154         li      r8,trampoline_size      /* verify that the trampoline is big enough */
 155         cmpw    cr1,r8,r4
 156         srwi    r4,r4,3         /* # doublewords to move */
 157         addi    r9,r3,-8        /* adjust pointer for stdu */
 158         mtctr   r4
 159         blt     cr1,.Labort
 160
 161         /* Copy the instructions to the stack */
 162 .Lmove:
 163         ldu     r10,8(r7)
 164         stdu    r10,8(r9)
 165         bdnz    .Lmove
 166
 167         /* Store correct function and static chain */
 168         std     r5,.Lfunc(r3)
 169         std     r6,.Lchain(r3)
 170
 171         /* Now flush both caches */
 172         mtctr   r4
 173 .Lcache:
 174         icbi    0,r3
 175         dcbf    0,r3
 176         addi    r3,r3,8
 177         bdnz    .Lcache
 178
 179         /* Finally synchronize things & return */
 180         sync
 181         isync
 182         blr
 183
 184 .Labort:
 185         bl      JUMP_TARGET(abort)
 186         nop
 187         .cfi_endproc
 188 FUNC_END(__trampoline_setup)
 189
 190 #endif