libjava/configure.ac

   1 dnl # Process this with autoconf to create configure
   2 AC_PREREQ(2.59)
   3 # Still use "libjava" here to placate dejagnu.
   4 AC_INIT([libjava], [version-unused],, [libjava])
   5
   6 AC_CONFIG_SRCDIR(java/lang/System.java)
   7
   8 # We use these options to decide which functions to include.
   9 AC_ARG_WITH(target-subdir,
  10   AS_HELP_STRING([--with-target-subdir=SUBDIR],
  11                  [configure in a subdirectory]))
  12
  13 # We may get other options which we don't document:
  14 # --with-target-subdir, --with-multisrctop, --with-multisubdir
  15
  16 # When building with srcdir == objdir, links to the source files will
  17 # be created in directories within the target_subdir.  We have to
  18 # adjust toplevel_srcdir accordingly, so that configure finds
  19 # install-sh and other auxiliary files that live in the top-level
  20 # source directory.
  21 if test "${srcdir}" = "."; then
  22   if test -z "${with_target_subdir}"; then
  23     toprel=".."
  24   else
  25     if test "${with_target_subdir}" != "."; then
  26       toprel="${with_multisrctop}../.."
  27     else
  28       toprel="${with_multisrctop}.."
  29     fi
  30   fi
  31 else
  32   toprel=".."
  33 fi
  34
  35 libgcj_basedir=$srcdir/$toprel/./libjava
  36 AC_SUBST(libgcj_basedir)
  37
  38 AC_CANONICAL_SYSTEM
  39 _GCC_TOPLEV_NONCANONICAL_BUILD
  40 _GCC_TOPLEV_NONCANONICAL_TARGET
  41
  42 AC_SUBST(target_noncanonical)
  43
  44 # This works around the fact that libtool configuration may change LD
  45 # for this particular configuration, but some shells, instead of
  46 # keeping the changes in LD private, export them just because LD is
  47 # exported.
  48 ORIGINAL_LD_FOR_MULTILIBS=$LD
  49
  50 AC_PROG_LN_S
  51
  52 # This works around an automake problem.
  53 mkinstalldirs="`cd $ac_aux_dir && ${PWDCMD-pwd}`/mkinstalldirs"
  54 AC_SUBST(mkinstalldirs)
  55
  56 AC_ARG_WITH(cross-host,
  57   AS_HELP_STRING([--with-cross-host=HOST],
  58                  [configure with a cross compiler from HOST]))
  59
  60 AC_ARG_WITH(newlib,
  61   AS_HELP_STRING([--with-newlib],
  62                  [configure with newlib]))
  63
  64 AC_ARG_ENABLE(version-specific-runtime-libs,
  65   AS_HELP_STRING([--enable-version-specific-runtime-libs],
  66                  [specify that runtime libraries should be installed in a compiler-specific directory]),
  67     [case "$enableval" in
  68       yes) version_specific_libs=yes ;;
  69       no)  version_specific_libs=no ;;
  70       *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  71      esac],
  72     [version_specific_libs=no]
  73 )
  74
  75 # Default to --enable-multilib
  76 AC_ARG_ENABLE(multilib,
  77   AS_HELP_STRING([--enable-multilib],
  78                  [build many library versions (default)]),
  79 [case "${enableval}" in
  80   yes) multilib=yes ;;
  81   no)  multilib=no ;;
  82   *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  83  esac], [multilib=yes])dnl
  84
  85 # It may not be safe to run linking tests in AC_PROG_CC/AC_PROG_CXX.
  86 GCC_NO_EXECUTABLES
  87
  88 # (1) We use an abnormal CXX (without library references), so we
  89 # must cache it under a different name.
  90 # (2) CC, CFLAGS, CXX, CXXFLAGS, LDFLAGS must not be 'precious', or
  91 # the non-multilib-adjusted value will be used in multilibs.
  92 # (3) As a side effect, we must SUBST CXXFLAGS, CFLAGS, and LDFLAGS ourselves.
  93 # (4) As another side effect, automake doesn't automatically include them
  94 # in Makefile.in.
  95 # (5) For libstdc++-v3, -fno-builtin must be present here so that a
  96 # non-conflicting form of std::exit can be guessed by AC_PROG_CXX, and
  97 # used in later tests.  This may not be necessary in libjava; I don't know.
  98 m4_define([ac_cv_prog_CXX],[glibcxx_cv_prog_CXX])
  99 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibcxx_PRECIOUS])
 100 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 101 save_CXXFLAGS="$CXXFLAGS"
 102 CXXFLAGS="$CXXFLAGS -fno-builtin"
 103 AC_PROG_CC
 104 AC_PROG_CXX
 105 CXXFLAGS="$save_CXXFLAGS"
 106 m4_rename([glibcxx_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 107 AC_SUBST(CFLAGS)
 108 AC_SUBST(CXXFLAGS)
 109 AC_SUBST(LDFLAGS)
 110
 111 AM_INIT_AUTOMAKE([1.9.0])
 112
 113 AC_CHECK_TOOL(AS, as)
 114 AC_CHECK_TOOL(AR, ar)
 115 AC_CHECK_TOOL(RANLIB, ranlib, :)
 116
 117 AC_PROG_INSTALL
 118
 119 AM_MAINTAINER_MODE
 120
 121 AC_EXEEXT
 122
 123 # configure.host sets the following important variables
 124 #       libgcj_cflags    - host specific C compiler flags
 125 #       libgcj_cxxflags  - host specific C++ compiler flags
 126 #       libgcj_javaflags - host specific Java compiler flags
 127
 128 libgcj_cflags=
 129 libgcj_cxxflags=
 130 libgcj_javaflags=
 131
 132 . ${srcdir}/configure.host
 133
 134 LIBGCJ_CFLAGS="${libgcj_cflags}"
 135 LIBGCJ_CXXFLAGS="${libgcj_cxxflags}"
 136 LIBGCJ_JAVAFLAGS="${libgcj_javaflags}"
 137 AC_SUBST(LIBGCJ_CFLAGS)
 138 AC_SUBST(LIBGCJ_CXXFLAGS)
 139 AC_SUBST(LIBGCJ_JAVAFLAGS)
 140
 141 AC_CONFIG_HEADERS([include/config.h gcj/libgcj-config.h])
 142
 143 # Only use libltdl for non-newlib builds.
 144 if test "x${with_newlib}" = "x" || test "x${with_newlib}" = "xno"; then
 145    AC_LIBLTDL_CONVENIENCE
 146    AC_LIBTOOL_DLOPEN
 147    DIRLTDL=libltdl
 148    AC_DEFINE(USE_LTDL, 1, [Define if libltdl is in use.])
 149    # Sigh.  Libtool's macro doesn't do the right thing.
 150    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
 151    # FIXME: this is a hack.
 152    sub_auxdir="`cd $ac_aux_dir && ${PWDCMD-pwd}`"
 153    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
 154 fi
 155 AC_SUBST(INCLTDL)
 156 AC_SUBST(LIBLTDL)
 157 AC_SUBST(DIRLTDL)
 158 AC_PROG_LIBTOOL
 159 AM_PROG_GCJ
 160 AM_PROG_CC_C_O
 161 AC_CONFIG_SUBDIRS(libltdl)
 162
 163 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
 164    COMPPATH=.
 165 else
 166    COMPPATH=..
 167 fi
 168 AC_SUBST(COMPPATH)
 169
 170 # The -no-testsuite modules omit the test subdir.
 171 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
 172
 173 # Should the runtime set system properties by examining the
 174 # environment variable GCJ_PROPERTIES?
 175 AC_ARG_ENABLE(getenv-properties,
 176   AS_HELP_STRING([--disable-getenv-properties],
 177                  [don't set system properties from GCJ_PROPERTIES]))
 178
 179 # Whether GCJ_PROPERTIES is used depends on the target.
 180 if test -z "$enable_getenv_properties"; then
 181    enable_getenv_properties=${enable_getenv_properties_default-yes}
 182 fi
 183 if test "$enable_getenv_properties" = no; then
 184    AC_DEFINE(DISABLE_GETENV_PROPERTIES, 1,
 185      [Define if system properties shouldn't be read from getenv("GCJ_PROPERTIES").])
 186 fi
 187
 188 # Whether we should use arguments to main()
 189 if test -z "$enable_main_args"; then
 190    enable_main_args=${enable_main_args_default-yes}
 191 fi
 192 if test "$enable_main_args" = no; then
 193    AC_DEFINE(DISABLE_MAIN_ARGS, 1, [Define if we should ignore arguments to main().])
 194 fi
 195
 196
 197 # Should we use hashtable-based synchronization?
 198 # Currently works only for Linux X86/ia64
 199 # Typically faster and more space-efficient
 200 AC_ARG_ENABLE(hash-synchronization,
 201   AS_HELP_STRING([--enable-hash-synchronization],
 202                  [use global hash table for monitor locks]))
 203
 204 if test -z "$enable_hash_synchronization"; then
 205    enable_hash_synchronization=$enable_hash_synchronization_default
 206 fi
 207
 208 # Do we allow intermodule optimizations (i.e. compiling many files at once)?
 209 AC_ARG_ENABLE(libgcj-multifile,
 210   AS_HELP_STRING([--enable-libgcj-multifile]
 211                  [allow compilation of several files at once]),
 212 [case "${enableval}" in
 213   yes) enable_libgcj_multifile=yes ;;
 214   no)  enable_libgcj_multifile=no ;;
 215   *) AC_MSG_ERROR(bad value ${enableval} for --enable-libgcj-multifile) ;;
 216 esac],[enable_libgcj_multifile=no])
 217 AM_CONDITIONAL(ONESTEP, test "$enable_libgcj_multifile" = yes)
 218
 219 # What is the native OS API for MinGW?
 220 AC_ARG_WITH(win32-nlsapi,
 221   AS_HELP_STRING([--with-win32-nlsapi=ansi or unicows or unicode],
 222                  [native MinGW libgcj Win32 OS API (default is ansi)]),
 223 [case "${withval}" in
 224   ansi) with_win32_nlsapi=ansi ;;
 225   unicows) with_win32_nlsapi=unicows ;;
 226   unicode) with_win32_nlsapi=unicode ;;
 227   *) AC_MSG_ERROR(Bad value ${withval} for --with-win32-nlsapi.) ;;
 228 esac],[with_win32_nlsapi=ansi])
 229
 230 case "${with_win32_nlsapi}" in
 231   unicows | unicode)
 232     AC_DEFINE(MINGW_LIBGCJ_UNICODE, 1,
 233       [Define if MinGW libgcj uses the Windows UNICODE OS API.])
 234     ;;
 235 esac
 236
 237 # configure.host sets slow_pthread_self if the synchronization code should
 238 # try to avoid pthread_self calls by caching thread IDs in a hashtable.
 239 if test "${slow_pthread_self}" = "yes"; then
 240   AC_DEFINE(SLOW_PTHREAD_SELF, 1,
 241     [Define if if the synchronization code should try to avoid pthread_self calls by caching thread IDs in a hashtable.])
 242 fi
 243
 244
 245 # See if the user has requested runtime debugging.
 246 LIBGCJDEBUG="false"
 247 AC_SUBST(LIBGCJDEBUG)
 248 AC_ARG_ENABLE(libgcj-debug,
 249   AS_HELP_STRING([--enable-libgcj-debug],
 250                  [enable runtime debugging code]),
 251   [if test "$enable_libgcj_debug" = yes; then
 252     AC_DEFINE(DEBUG, 1, [Define this if you want runtime debugging enabled.])
 253     LIBGCJDEBUG="true"
 254   fi])
 255
 256 # Check for gc debugging.  This option is handled both here and in the GC.
 257 AC_ARG_ENABLE(gc-debug,
 258 [  --enable-gc-debug    include full support for pointer backtracing etc.],
 259 [ if test "$enable_gc_debug" = "yes"; then
 260     AC_DEFINE(LIBGCJ_GC_DEBUG)
 261   fi])
 262
 263 # See if the user has the interpreter included.
 264 AC_ARG_ENABLE(interpreter,
 265   AS_HELP_STRING([--enable-interpreter],
 266                  [enable interpreter]),
 267   [if test "$enable_interpreter" = yes; then
 268     # This can also be set in configure.host.
 269     libgcj_interpreter=yes
 270   elif test "$enable_interpreter" = no; then
 271     libgcj_interpreter=no
 272   fi])
 273
 274 if test "$libgcj_interpreter" = yes; then
 275    AC_DEFINE(INTERPRETER, 1, [Define if you want a bytecode interpreter.])
 276 fi
 277 INTERPRETER="$libgcj_interpreter"
 278 AC_SUBST(INTERPRETER)
 279
 280 AC_MSG_CHECKING([for exception model to use])
 281 AC_LANG_PUSH(C++)
 282 AC_ARG_ENABLE(sjlj-exceptions,
 283   AS_HELP_STRING([--enable-sjlj-exceptions],
 284                  [force use of builtin_setjmp for exceptions]),
 285 [:],
 286 [dnl Botheration.  Now we've got to detect the exception model.
 287 dnl Link tests against libgcc.a are problematic since -- at least
 288 dnl as of this writing -- we've not been given proper -L bits for
 289 dnl single-tree newlib and libgloss.
 290 dnl
 291 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 292 dnl conftest files before we got a change to grep them first.
 293 cat > conftest.$ac_ext << EOF
 294 [#]line __oline__ "configure"
 295 struct S { ~S(); };
 296 void bar();
 297 void foo()
 298 {
 299   S s;
 300   bar();
 301 }
 302 EOF
 303 old_CXXFLAGS="$CXXFLAGS"
 304 CXXFLAGS=-S
 305 if AC_TRY_EVAL(ac_compile); then
 306   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 307     enable_sjlj_exceptions=yes
 308   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 309     enable_sjlj_exceptions=no
 310   fi
 311 fi
 312 CXXFLAGS="$old_CXXFLAGS"
 313 rm -f conftest*])
 314 if test x$enable_sjlj_exceptions = xyes; then
 315   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 316         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 317   ac_exception_model_name=sjlj
 318 elif test x$enable_sjlj_exceptions = xno; then
 319   ac_exception_model_name="call frame"
 320 else
 321   AC_MSG_ERROR([unable to detect exception model])
 322 fi
 323 AC_LANG_POP(C++)
 324 AC_MSG_RESULT($ac_exception_model_name)
 325
 326 # If we are non using SJLJ exceptions, and this host does not have support
 327 # for unwinding from a signal handler, enable checked dereferences and divides.
 328 if test $can_unwind_signal = no && test $enable_sjlj_exceptions = no; then
 329   CHECKREFSPEC=-fcheck-references
 330   DIVIDESPEC=-fuse-divide-subroutine
 331   EXCEPTIONSPEC=
 332 fi
 333
 334 # See if the user wants to disable java.net.  This is the mildly
 335 # ugly way that we admit that target-side configuration sucks.
 336 AC_ARG_ENABLE(java-net,
 337   AS_HELP_STRING([--disable-java-net],
 338                  [disable java.net]))
 339
 340 # Whether java.net is built by default can depend on the target.
 341 if test -z "$enable_java_net"; then
 342    enable_java_net=${enable_java_net_default-yes}
 343 fi
 344 if test "$enable_java_net" = no; then
 345    AC_DEFINE(DISABLE_JAVA_NET, 1, [Define if java.net native functions should be stubbed out.])
 346 fi
 347
 348 # See if the user wants to configure without libffi.  Some
 349 # architectures don't support it, and default values are set in
 350 # configure.host.
 351 AC_ARG_WITH(libffi,
 352   AS_HELP_STRING([--without-libffi],
 353                  [don't use libffi]),
 354   [:],
 355   [with_libffi=${with_libffi_default-yes}])
 356
 357 LIBFFI=
 358 LIBFFIINCS=
 359 if test "$with_libffi" != no; then
 360    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 361    LIBFFI=../libffi/libffi_convenience.la
 362    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 363 fi
 364 AC_SUBST(LIBFFI)
 365 AC_SUBST(LIBFFIINCS)
 366
 367 # See if the user wants to disable JVMPI support.
 368 AC_ARG_ENABLE(jvmpi,
 369   AS_HELP_STRING([--disable-jvmpi],
 370                  [disable JVMPI support]))
 371
 372 if test "$enable_jvmpi" != no; then
 373     AC_DEFINE(ENABLE_JVMPI, 1, [Define if you are using JVMPI.])
 374 fi
 375
 376 # If the target is an eCos system, use the appropriate eCos
 377 # I/O routines.
 378 # FIXME: this should not be a local option but a global target
 379 # system; at present there is no eCos target.
 380 TARGET_ECOS=${PROCESS-"no"}
 381 AC_ARG_WITH(ecos,
 382 [  --with-ecos             enable runtime eCos target support],
 383 TARGET_ECOS="$with_ecos"
 384 )
 385
 386 supply_backtrace=no
 387
 388 PLATFORM_INNER_NAT_HDRS=
 389 case "$TARGET_ECOS" in
 390    no) case "$host" in
 391       *mingw*)
 392             PLATFORM=Win32
 393             PLATFORMNET=Win32
 394             PLATFORMH=win32.h
 395         CHECK_FOR_BROKEN_MINGW_LD
 396       ;;
 397       *)
 398             PLATFORM=Posix
 399             PLATFORMNET=Posix
 400             PLATFORMH=posix.h
 401             PLATFORM_INNER_NAT_HDRS='java/lang/ConcreteProcess$$ProcessManager.h'
 402       ;;
 403       esac
 404       ;;
 405    *)
 406       PLATFORM=Ecos
 407       PLATFORMNET=NoNet
 408       AC_DEFINE(ECOS, 1, [Define if you're running eCos.])
 409       PLATFORMH=posix.h
 410       ;;
 411 esac
 412 AC_SUBST(PLATFORM_INNER_NAT_HDRS)
 413 AC_CONFIG_LINKS(include/platform.h:include/$PLATFORMH)
 414
 415 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 416                                       [Define if you have int32_t and uint32_t.]))
 417 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED, 1,
 418                                         [Define if you have int32_t and uint32_t.]))
 419 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 420                                           [Define if you have u_int32_t]))
 421 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED, 1,
 422                                            [Define if you have u_int32_t]))
 423
 424 AM_CONDITIONAL(USING_WIN32_PLATFORM, test "$PLATFORM" = Win32)
 425 AM_CONDITIONAL(USING_POSIX_PLATFORM, test "$PLATFORM" = Posix)
 426 AM_CONDITIONAL(USING_ECOS_PLATFORM, test "$PLATFORM" = Ecos)
 427
 428 # These may not be defined in a non-ANS conformant embedded system.
 429 # FIXME: Should these case a runtime exception in that case?
 430 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME, 1,
 431                                   [Define is you have 'mktime' in <time.h>]))
 432 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME, 1,
 433                                   [Define is you have 'localtime' in <time.h>]))
 434
 435 # Create the subdirectory for natFile.cc, or the attempt
 436 # to create the link will fail.
 437 test -d java || mkdir java
 438 test -d java/io || mkdir java/io
 439 test -d gnu || mkdir gnu
 440 AC_CONFIG_LINKS(java/io/natFile.cc:java/io/natFile${FILE-${PLATFORM}}.cc)
 441
 442 # Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 443 test -d java/lang || mkdir java/lang
 444 AC_CONFIG_LINKS(java/lang/ConcreteProcess.java:java/lang/${PLATFORM}Process.java)
 445 AC_CONFIG_LINKS(java/lang/natConcreteProcess.cc:java/lang/nat${PLATFORM}Process.cc)
 446
 447 # Likewise for natInetAddress.cc and natNetworkInterface.cc.
 448 test -d java/net || mkdir java/net
 449 AC_CONFIG_LINKS(java/net/natInetAddress.cc:java/net/natInetAddress${PLATFORMNET}.cc)
 450 AC_CONFIG_LINKS(java/net/natNetworkInterface.cc:java/net/natNetworkInterface${PLATFORMNET}.cc)
 451
 452 # Likewise for natPlainSocketImpl.cc and natPlainDatagramSocketImpl.cc.
 453 test -d gnu/java || mkdir gnu/java
 454 test -d gnu/java/net || mkdir gnu/java/net
 455 AC_CONFIG_LINKS(gnu/java/net/natPlainSocketImpl.cc:gnu/java/net/natPlainSocketImpl${PLATFORMNET}.cc)
 456 AC_CONFIG_LINKS(gnu/java/net/natPlainDatagramSocketImpl.cc:gnu/java/net/natPlainDatagramSocketImpl${PLATFORMNET}.cc)
 457
 458 # Likewise for natPipeImpl.cc and natSelectorImpl.cc.
 459 test -d gnu/java/nio || mkdir gnu/java/nio
 460 AC_CONFIG_LINKS(gnu/java/nio/natPipeImpl.cc:gnu/java/nio/natPipeImpl${PLATFORM}.cc)
 461 AC_CONFIG_LINKS(gnu/java/nio/natSelectorImpl.cc:gnu/java/nio/natSelectorImpl${PLATFORM}.cc)
 462 test -d gnu/java/nio/channels || mkdir gnu/java/nio/channels
 463 AC_CONFIG_LINKS(gnu/java/nio/channels/natFileChannelImpl.cc:gnu/java/nio/channels/natFileChannel${FILE-${PLATFORM}}.cc)
 464
 465 case "${host}" in
 466     *mingw*)
 467       SYSTEMSPEC="-lgdi32 -lws2_32"
 468       if test "${with_win32_nlsapi}" = "unicows"; then
 469         SYSTEMSPEC="-lunicows $SYSTEMSPEC"
 470       fi
 471     ;;
 472     *)
 473       SYSTEMSPEC=
 474     ;;
 475 esac
 476 AC_SUBST(SYSTEMSPEC)
 477
 478 LIBGCJTESTSPEC="-L`${PWDCMD-pwd}`/.libs -rpath `${PWDCMD-pwd}`/.libs"
 479 AC_SUBST(LIBGCJTESTSPEC)
 480
 481 AC_ARG_WITH(system-zlib,
 482   AS_HELP_STRING([--with-system-zlib],
 483                  [use installed libz]))
 484 ZLIBSPEC=
 485 AC_SUBST(ZLIBSPEC)
 486 ZLIBTESTSPEC=
 487 AC_SUBST(ZLIBTESTSPEC)
 488
 489 AC_PATH_XTRA
 490
 491 # Determine which AWT peer libraries to build
 492 AC_ARG_ENABLE(java-awt,
 493   AS_HELP_STRING([--enable-java-awt],
 494                  [list of AWT peer implementations to be built]))
 495
 496 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 497 use_xlib_awt=""
 498 use_gtk_awt=""
 499 # The default toolkit to use is the first one specified.
 500 TOOLKIT=
 501 AC_SUBST(TOOLKIT)
 502
 503 for peer in $peerlibs ; do
 504   case $peer in
 505     xlib)
 506       if test "$no_x" = yes; then
 507         echo "*** xlib peers requested but no X library available" 1>&2
 508         exit 1
 509       else
 510         use_xlib_awt="yes"
 511         if test -z "$TOOLKIT"; then
 512            TOOLKIT=gnu.awt.xlib.XToolkit
 513         fi
 514       fi
 515       ;;
 516     gtk)
 517       if test "$no_x" = yes; then
 518          echo "*** xlib peers requested but no X library available" 1>&2
 519          exit 1
 520       else
 521          use_gtk_awt=yes
 522          if test -z "$TOOLKIT"; then
 523             TOOLKIT=gnu.java.awt.peer.gtk.GtkToolkit
 524          fi
 525          test -d jniinclude || mkdir jniinclude
 526       fi
 527       ;;
 528     no)
 529       use_xlib_awt=
 530       use_gtk_awt=
 531       break
 532       ;;
 533     *)
 534       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 535       exit 1
 536   esac
 537 done
 538
 539 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 540 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 541
 542 # determine whether to enable the cairo GTK Graphics2D backend
 543 AC_ARG_ENABLE(gtk-cairo,
 544   AS_HELP_STRING([--enable-gtk-cairo],
 545                  [build the cairo Graphics2D implementation on GTK]))
 546 AM_CONDITIONAL(GTK_CAIRO, test "x${enable_gtk_cairo}" = xyes)
 547 if test "x${enable_gtk_cairo}" = xyes
 548 then
 549         PKG_CHECK_MODULES(CAIRO, cairo)
 550         PKG_CHECK_MODULES(PANGOFT2, pangoft2)
 551 fi
 552 AC_SUBST(CAIRO_LIBS)
 553 AC_SUBST(CAIRO_CFLAGS)
 554 AC_SUBST(PANGOFT2_LIBS)
 555 AC_SUBST(PANGOFT2_CFLAGS)
 556
 557 # FIXME: this should be _libs on some hosts.
 558 libsubdir=.libs
 559
 560 # Allow the GC to be disabled.  Can be useful when debugging.
 561 AC_MSG_CHECKING([for garbage collector to use])
 562 AC_ARG_ENABLE(java-gc,
 563   AS_HELP_STRING([--enable-java-gc=TYPE],
 564                  [choose garbage collector (default is boehm)]),
 565   [GC=$enableval],
 566   [GC=boehm])
 567 GCLIBS=
 568 GCINCS=
 569 GCDEPS=
 570 GCSPEC=
 571 JC1GCSPEC=
 572 GCTESTSPEC=
 573 case "$GC" in
 574  boehm)
 575     AC_MSG_RESULT(boehm)
 576     GCLIBS=../boehm-gc/libgcjgc_convenience.la
 577     JC1GCSPEC='-fuse-boehm-gc'
 578     GCTESTSPEC="-L`${PWDCMD-pwd}`/../boehm-gc/.libs -rpath `${PWDCMD-pwd}`/../boehm-gc/.libs"
 579     GCINCS='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
 580     GCOBJS=boehm.lo
 581     GCHDR=boehm-gc.h
 582     # The POSIX thread support needs to know this.
 583     AC_DEFINE(HAVE_BOEHM_GC, 1, [Define if Boehm GC in use.])
 584     ;;
 585  no)
 586     AC_MSG_RESULT(none)
 587     GCHDR=no-gc.h
 588     ;;
 589  *)
 590     AC_MSG_ERROR([unrecognized collector "$GC"])
 591     ;;
 592 esac
 593 AC_SUBST(GCLIBS)
 594 AC_SUBST(GCINCS)
 595 AC_SUBST(GCDEPS)
 596 AC_SUBST(GCSPEC)
 597 AC_SUBST(JC1GCSPEC)
 598 AC_SUBST(GCTESTSPEC)
 599 AC_CONFIG_LINKS(include/java-gc.h:include/$GCHDR)
 600 AM_CONDITIONAL(USING_BOEHMGC, test "$GC" = boehm)
 601 AM_CONDITIONAL(USING_NOGC, test "$GC" = no)
 602
 603
 604 AC_MSG_CHECKING([for thread model used by GCC])
 605 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 606 AC_MSG_RESULT([$THREADS])
 607
 608 case "$THREADS" in
 609  no | none | single)
 610     THREADS=none
 611     ;;
 612  posix | pthreads)
 613     THREADS=posix
 614     case "$host" in
 615      *-*-linux*)
 616         AC_DEFINE(LINUX_THREADS, 1, [Define if using POSIX threads on Linux.])
 617         ;;
 618     esac
 619     ;;
 620  win32)
 621     ;;
 622  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 623     AC_MSG_ERROR(thread package $THREADS not yet supported)
 624     ;;
 625  *)
 626     AC_MSG_ERROR($THREADS is an unknown thread package)
 627     ;;
 628 esac
 629
 630 THREADCXXFLAGS=
 631 THREADLDFLAGS=
 632 THREADLIBS=
 633 THREADINCS=
 634 THREADDEPS=
 635 THREADH=
 636 THREADSPEC=
 637 case "$THREADS" in
 638  posix)
 639     case "$host" in
 640      *-*-cygwin*)
 641         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 642         ;;
 643      *-*-freebsd[[1234]]*)
 644         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 645         # merely adds pthread_* functions) but it does have a -pthread switch
 646         # which is required at link-time to select -lc_r *instead* of -lc.
 647         THREADLDFLAGS=-pthread
 648         # Don't set THREADSPEC here as might be expected since -pthread is
 649         # not processed when found within a spec file, it must come from
 650         # the command line.  For now, the user must provide the -pthread
 651         # switch to link code compiled with gcj.  In future, consider adding
 652         # support for weak references to pthread_* functions ala gthr.h API.
 653         THREADSPEC='%{!pthread: %eUnder this configuration, the user must provide -pthread when linking.}'
 654         ;;
 655      *-*-freebsd*)
 656         # FreeBSD 5 implements a model much closer to other modern UNIX
 657         # which support threads.  However, it still does not support
 658         # -lpthread.
 659         THREADLDFLAGS=-pthread
 660         THREADSPEC=-lc_r
 661         ;;
 662      alpha*-dec-osf*)
 663         THREADCXXFLAGS=-pthread
 664         # boehm-gc needs some functions from librt, so link that too.
 665         THREADLIBS='-lpthread -lrt'
 666         THREADSPEC='-lpthread -lrt'
 667         ;;
 668      *)
 669         THREADLIBS=-lpthread
 670         THREADSPEC=-lpthread
 671         ;;
 672     esac
 673     THREADH=posix-threads.h
 674     # MIT pthreads doesn't seem to have the mutexattr functions.
 675     # But for now we don't check for it.  We just assume you aren't
 676     # using MIT pthreads.
 677     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 678
 679     # If we're using the Boehm GC, then we happen to know that it
 680     # defines _REENTRANT, so we don't bother.  Eww.
 681     if test "$GC" != boehm; then
 682        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 683     fi
 684     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 685     ;;
 686
 687  win32)
 688     THREADH=win32-threads.h
 689     ;;
 690
 691  none)
 692     THREADH=no-threads.h
 693     ;;
 694 esac
 695 AC_CONFIG_LINKS(include/java-threads.h:include/$THREADH)
 696 AC_SUBST(THREADLIBS)
 697 AC_SUBST(THREADINCS)
 698 AC_SUBST(THREADDEPS)
 699 AC_SUBST(THREADSPEC)
 700 AC_SUBST(THREADLDFLAGS)
 701 AC_SUBST(THREADCXXFLAGS)
 702 AM_CONDITIONAL(USING_POSIX_THREADS, test "$THREADS" = posix)
 703 AM_CONDITIONAL(USING_WIN32_THREADS, test "$THREADS" = win32)
 704 AM_CONDITIONAL(USING_NO_THREADS, test "$THREADS" = none)
 705
 706 if test -d sysdep; then true; else mkdir sysdep; fi
 707 AC_CONFIG_LINKS(sysdep/locks.h:sysdep/$sysdeps_dir/locks.h)
 708
 709 HASH_SYNC_SPEC=
 710 # Hash synchronization is only useful with posix threads right now.
 711 if test "$enable_hash_synchronization" = yes && test "$THREADS" != "none"; then
 712    HASH_SYNC_SPEC=-fhash-synchronization
 713    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 714 fi
 715 AC_SUBST(HASH_SYNC_SPEC)
 716
 717
 718 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 719
 720 # We're in the tree with gcc, and need to include some of its headers.
 721 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 722
 723 # Figure out where generated headers like libgcj-config.h get installed.
 724 gcc_version_trigger=${libgcj_basedir}/../gcc/version.c
 725 gcc_version_full=`grep version_string ${gcc_version_trigger} | sed -e 's/.*\"\([[^\"]]*\)\".*/\1/'`
 726 gcc_version=`echo ${gcc_version_full} | sed -e 's/\([[^ ]]*\) .*/\1/'`
 727 tool_include_dir='$(libdir)/gcc/$(target_noncanonical)/'${gcc_version}/include
 728 AC_SUBST(tool_include_dir)
 729 AC_SUBST(gcc_version)
 730
 731 if test "x${with_newlib}" = "xyes"; then
 732    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 733    # may not work correctly, because the compiler may not be able to
 734    # link executables.
 735
 736    # We assume newlib.  This lets us hard-code the functions we know
 737    # we'll have.
 738    AC_DEFINE(HAVE_MEMMOVE, 1, [Define if you have memmove.])
 739    AC_DEFINE(HAVE_MEMCPY, 1, [Define if you have memcpy.])
 740    AC_DEFINE(HAVE_STRERROR, 1, [Define if you have strerror.])
 741    AC_DEFINE(HAVE_TIME, 1, [Define if you have time.])
 742    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have the 'gmtime_r' function])
 743    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have the 'localtime_r' function.])
 744    AC_DEFINE(HAVE_USLEEP_DECL, 1, [Define if usleep is declared in <unistd.h>.])
 745    # This is only for POSIX threads.
 746    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT, 1, [Define if using POSIX threads that have the mutexattr functions.])
 747    # We also assume we are using gcc, which provides alloca.
 748    AC_DEFINE(HAVE_ALLOCA)
 749
 750    # Assume we do not have getuid and friends.
 751    AC_DEFINE(NO_GETUID, 1, [Define if getuid() and friends are missing.])
 752    PLATFORMNET=NoNet
 753 else
 754    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep opendir)
 755    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r getcwd)
 756    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath utime chmod)
 757    AC_CHECK_FUNCS(nl_langinfo setlocale)
 758    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 759    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 760    AC_CHECK_FUNCS(fork execvp pipe sigaction ftruncate)
 761    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 762    AC_CHECK_FUNC(backtrace, [
 763      case "$host" in
 764        ia64-*-linux*)
 765          # Has broken backtrace()
 766          ;;
 767        mips*-*-linux*)
 768          # Has broken backtrace(), but we supply our own.
 769          if test -d sysdep; then true; else mkdir -p sysdep; fi
 770          supply_backtrace=yes
 771          AC_DEFINE(HAVE_BACKTRACE, 1,
 772            [Define if your platform has a working backtrace() function.])
 773          ;;
 774        *)
 775          AC_DEFINE(HAVE_BACKTRACE, 1,
 776            [Define if your platform has a working backtrace() function.])
 777          ;;
 778      esac
 779    ], [
 780      case "$host" in
 781        *mingw*)
 782          # Has backtrace() defined in libgcj itself
 783          AC_DEFINE(HAVE_BACKTRACE, 1,
 784            [Define if your platform has a working backtrace() function.])
 785          ;;
 786      esac
 787    ])
 788
 789    AC_CHECK_LIB(dl, dladdr, [
 790      if test "x${disable_dladdr}" = "xyes"; then
 791        #Broken dladdr().
 792        true
 793      else
 794        AC_DEFINE(HAVE_DLADDR, 1, [Define if you have dladdr()])
 795      fi
 796    ])
 797    if test x"$build" = x"$host"; then
 798      AC_CHECK_FILES(/proc/self/exe, [
 799        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])])
 800    else
 801      case $host in
 802      *-linux*)
 803        AC_DEFINE(HAVE_PROC_SELF_EXE, 1, [Define if you have /proc/self/exe])
 804        ;;
 805      esac
 806    fi
 807
 808    AM_ICONV
 809    AM_LC_MESSAGES
 810    AC_STRUCT_TIMEZONE
 811
 812    AC_CHECK_FUNCS(gethostbyname_r, [
 813      AC_DEFINE(HAVE_GETHOSTBYNAME_R, 1,
 814        [Define if you have the 'gethostbyname_r' function.])
 815      # There are two different kinds of gethostbyname_r.
 816      # We look for the one that returns `int'.
 817      # Hopefully this check is robust enough.
 818      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 819        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT, 1, [Define if gethostbyname_r returns 'int'.])])
 820
 821      case " $GCINCS " in
 822      *" -D_REENTRANT "*) ;;
 823      *)
 824         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 825         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 826         [libjava_cv_gethostbyname_r_needs_reentrant],
 827         [ AC_LANG_PUSH(C++)
 828           AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
 829             [[gethostbyname_r("", 0, 0);]])],
 830             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 831                 CPPFLAGS_SAVE="$CPPFLAGS"
 832                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 833                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]], [[gethostbyname_r("", 0, 0);]])],
 834                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 835                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 836                 CPPFLAGS="$CPPFLAGS_SAVE"
 837           ])
 838           AC_LANG_POP(C++)
 839         ])
 840         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 841           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 842         fi
 843      ;;
 844      esac
 845
 846      AC_CACHE_CHECK([for struct hostent_data],
 847         [libjava_cv_struct_hostent_data], [dnl
 848         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
 849 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 850 # define _REENTRANT 1
 851 #endif
 852 #include <netdb.h>]], [[struct hostent_data data;]])],
 853           [libjava_cv_struct_hostent_data=yes],
 854           [libjava_cv_struct_hostent_data=no])])
 855      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 856        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 857          [Define if struct hostent_data is defined in netdb.h])
 858      fi
 859    ])
 860
 861    # FIXME: libjava source code expects to find a prototype for
 862    # gethostbyaddr_r in netdb.h.  The outer check ensures that
 863    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
 864    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
 865    # linkage check is enough, yet C++ code requires proper prototypes.)
 866    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
 867    AC_CHECK_FUNCS(gethostbyaddr_r, [
 868      AC_DEFINE(HAVE_GETHOSTBYADDR_R, 1,
 869        [Define if you have the 'gethostbyaddr_r' function.])
 870      # There are two different kinds of gethostbyaddr_r.
 871      # We look for the one that returns `int'.
 872      # Hopefully this check is robust enough.
 873      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 874        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT, 1,
 875          [Define if gethostbyaddr_r returns 'int'.])])])])
 876
 877    AC_CHECK_FUNCS(gethostname, [
 878      AC_DEFINE(HAVE_GETHOSTNAME, 1,
 879        [Define if you have the 'gethostname' function.])
 880      AC_EGREP_HEADER(gethostname, unistd.h, [
 881        AC_DEFINE(HAVE_GETHOSTNAME_DECL, 1,
 882          [Define if gethostname is declared in <unistd.h>.])])])
 883
 884    AC_CHECK_FUNCS(usleep, [
 885      AC_EGREP_HEADER(usleep, unistd.h, [
 886        AC_DEFINE(HAVE_USLEEP_DECL, 1,
 887           [Define if usleep is declared in <unistd.h>.])])])
 888
 889    # Look for these functions in the thread library, but only bother
 890    # if using POSIX threads.
 891    if test "$THREADS" = posix; then
 892       save_LIBS="$LIBS"
 893       LIBS="$LIBS $THREADLIBS"
 894       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 895       # E.g., Solaris.
 896       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 897
 898       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 899       # Solaris 7 the name librt is preferred.
 900       AC_CHECK_FUNCS(sched_yield, , [
 901         AC_CHECK_LIB(rt, sched_yield, [
 902           AC_DEFINE(HAVE_SCHED_YIELD)
 903           THREADLIBS="$THREADLIBS -lrt"
 904           THREADSPEC="$THREADSPEC -lrt"], [
 905           AC_CHECK_LIB(posix4, sched_yield, [
 906             AC_DEFINE(HAVE_SCHED_YIELD)
 907             THREADLIBS="$THREADLIBS -lposix4"
 908             THREADSPEC="$THREADSPEC -lposix4"])])])
 909       LIBS="$save_LIBS"
 910
 911       # We can save a little space at runtime if the mutex has m_count
 912       # or __m_count.  This is a nice hack for Linux.
 913       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
 914           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 915         ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT, 1,
 916              [Define if pthread_mutex_t has m_count member.]), [
 917         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <pthread.h>]], [[
 918             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 919           ]])], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT, 1,
 920             [Define if pthread_mutex_t has __m_count member.]))])
 921    fi
 922
 923    # We require a way to get the time.
 924    time_found=no
 925    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 926    if test "$time_found" = no; then
 927       AC_MSG_ERROR([no function found to get the time])
 928    fi
 929
 930    AC_CHECK_FUNCS(memmove)
 931
 932    # We require memcpy.
 933    memcpy_found=no
 934    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 935    if test "$memcpy_found" = no; then
 936       AC_MSG_ERROR([memcpy is required])
 937    fi
 938
 939    AC_CHECK_LIB(dl, dlopen, [
 940        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])
 941
 942    # Some library-finding code we stole from Tcl.
 943    #--------------------------------------------------------------------
 944    #    Check for the existence of the -lsocket and -lnsl libraries.
 945    #    The order here is important, so that they end up in the right
 946    #    order in the command line generated by make.  Here are some
 947    #    special considerations:
 948    #    1. Use "connect" and "accept" to check for -lsocket, and
 949    #       "gethostbyname" to check for -lnsl.
 950    #    2. Use each function name only once:  can't redo a check because
 951    #       autoconf caches the results of the last check and won't redo it.
 952    #    3. Use -lnsl and -lsocket only if they supply procedures that
 953    #       aren't already present in the normal libraries.  This is because
 954    #       IRIX 5.2 has libraries, but they aren't needed and they're
 955    #       bogus:  they goof up name resolution if used.
 956    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 957    #       To get around this problem, check for both libraries together
 958    #       if -lsocket doesn't work by itself.
 959    #--------------------------------------------------------------------
 960
 961    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 962     [gcj_cv_lib_sockets=
 963      gcj_checkBoth=0
 964      unset ac_cv_func_connect
 965      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 966      if test "$gcj_checkSocket" = 1; then
 967          unset ac_cv_func_connect
 968          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 969                       gcj_checkBoth=1)
 970      fi
 971      if test "$gcj_checkBoth" = 1; then
 972          gcj_oldLibs=$LIBS
 973          LIBS="$LIBS -lsocket -lnsl"
 974          unset ac_cv_func_accept
 975          AC_CHECK_FUNC(accept,
 976                        [gcj_checkNsl=0
 977                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 978          unset ac_cv_func_accept
 979          LIBS=$gcj_oldLibs
 980      fi
 981      unset ac_cv_func_gethostbyname
 982      gcj_oldLibs=$LIBS
 983      LIBS="$LIBS $gcj_cv_lib_sockets"
 984      AC_CHECK_FUNC(gethostbyname, ,
 985                    [AC_CHECK_LIB(nsl, main,
 986                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 987      unset ac_cv_func_gethostbyname
 988      LIBS=$gcj_oldLIBS
 989    ])
 990    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 991
 992    if test "$with_system_zlib" = yes; then
 993       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=)
 994    fi
 995
 996    # Test for Gtk stuff, if asked for.
 997    if test "$use_gtk_awt" = yes; then
 998       PKG_CHECK_MODULES(GTK, gtk+-2.0 >= 2.4)
 999       AC_SUBST(GTK_CFLAGS)
1000       AC_SUBST(GTK_LIBS)
1001
1002       PKG_CHECK_MODULES(GLIB, glib-2.0 >= 2.4 gthread-2.0 >= 2.4)
1003       AC_SUBST(GLIB_CFLAGS)
1004       AC_SUBST(GLIB_LIBS)
1005
1006       PKG_CHECK_MODULES(LIBART, libart-2.0 >= 2.1)
1007       AC_SUBST(LIBART_CFLAGS)
1008       AC_SUBST(LIBART_LIBS)
1009    fi
1010
1011    # On Solaris, and maybe other architectures, the Boehm collector
1012    # requires -ldl.
1013    if test "$GC" = boehm; then
1014       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
1015    fi
1016 fi
1017 AM_CONDITIONAL(SUPPLY_BACKTRACE, test "$supply_backtrace" = yes)
1018
1019 if test -z "${with_multisubdir}"; then
1020    builddotdot=.
1021 else
1022    builddotdot=`echo ${with_multisubdir} | sed -e 's:[[^/]][[^/]]*:..:g'`
1023 fi
1024
1025 NATIVE=yes
1026
1027 # Which gcj do we use?
1028 which_gcj=default
1029 built_gcc_dir="`cd ${builddotdot}/../../gcc && ${PWDCMD-pwd}`"
1030 if test -n "${with_cross_host}"; then
1031   # We are being configured with a cross compiler. We can't
1032   # use ac_exeext, because that is for the target platform.
1033   NATIVE=no
1034   cross_host_exeext=
1035   case "${with_cross_host}" in
1036      *mingw* | *cygwin*)
1037          cross_host_exeext=.exe
1038      ;;
1039   esac
1040   if test -x "${built_gcc_dir}/gcj${cross_host_exeext}"; then
1041      if test x"$build_noncanonical" = x"$with_cross_host"; then
1042         # Ordinary cross (host!=target and host=build)
1043         which_gcj=built
1044      else
1045         # Canadian cross (host!=target and host!=build)
1046         which_gcj=cross
1047      fi
1048   else
1049      which_gcj=cross
1050   fi
1051 else
1052   # We are being configured with a native or crossed-native compiler
1053   if test -x "${built_gcc_dir}/gcj${ac_exeext}"; then
1054      if test x"$build" = x"$host"; then
1055         # True native build (host=target and host=build)
1056         which_gcj=built
1057      else
1058         # Crossed-native build (host=target and host!=build)
1059         which_gcj=cross
1060      fi
1061   else
1062      which_gcj=path
1063   fi
1064 fi
1065 case "${which_gcj}" in
1066    built)
1067       GCJ="$built_gcc_dir/gcj -B`${PWDCMD-pwd}`/ -B$built_gcc_dir/"
1068       GCJH='$(MULTIBUILDTOP)../$(COMPPATH)/gcc/gcjh'
1069       ZIP='$(MULTIBUILDTOP)../$(COMPPATH)/fastjar/fastjar'
1070    ;;
1071    cross)
1072       if test "x${with_newlib}" = "xyes"; then
1073          # FIXME (comment): Why is this needed?
1074          GCC_UNWIND_INCLUDE=
1075          GCJ="${target_noncanonical}-gcj"
1076       else
1077          GCJ="${target_noncanonical}-gcj -B`${PWDCMD-pwd}`/"
1078       fi
1079       ZIP=jar
1080       GCJH='$(target_noncanonical)-gcjh'
1081    ;;
1082    path)
1083       GCJ="gcj -B`${PWDCMD-pwd}`/"
1084       ## In this case, gcj is found outside the build tree.  However, zip is
1085       ## found in the build tree.
1086       ZIP='$(MULTIBUILDTOP)../$(COMPPATH)/fastjar/fastjar'
1087       GCJH=gcjh
1088    ;;
1089 esac
1090
1091 AC_SUBST(GCJH)
1092 AC_SUBST(ZIP)
1093
1094 # Create it, so that compile/link tests don't fail
1095 test -f libgcj.spec || touch libgcj.spec
1096
1097 # We must search the source tree for java.lang, since we still don't
1098 # have libgcj.jar nor java/lang/*.class
1099 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
1100 CPPFLAGS="$CPPFLAGS -I`${PWDCMD-pwd}` -I`cd $srcdir && ${PWDCMD-pwd}`"
1101
1102 # Since some classes depend on this one, we need its source available
1103 # before we can do any GCJ compilation test :-(
1104 if test ! -f gnu/classpath/Configuration.java; then
1105   test -d gnu || mkdir gnu
1106   test -d gnu/classpath || mkdir gnu/classpath
1107   sed -e 's,@LIBGCJDEBUG@,$LIBGCJDEBUG,' \
1108       -e 's,@TOOLKIT@,$TOOLKIT,' \
1109         < $srcdir/gnu/classpath/Configuration.java.in \
1110         > gnu/classpath/Configuration.java
1111   # We do not want to redirect the output of the grep below to /dev/null,
1112   # but we add /dev/null to the input list so that grep will print the
1113   # filename of Configuration.java in case it finds any matches.
1114   if grep @ gnu/classpath/Configuration.java /dev/null; then
1115     AC_MSG_ERROR([configure.ac is missing the substitutions above])
1116   fi
1117 fi
1118
1119 LT_AC_PROG_GCJ
1120
1121 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
1122
1123 AC_COMPILE_CHECK_SIZEOF(void *)
1124
1125 ZLIBS=
1126 SYS_ZLIBS=
1127 ZINCS=
1128
1129 if test -z "$ZLIBSPEC"; then
1130    # Use zlib from the GCC tree.
1131    ZINCS='-I$(top_srcdir)/../zlib'
1132    ZLIBS=../zlib/libzgcj_convenience.la
1133 else
1134    # System's zlib.
1135    SYS_ZLIBS="$ZLIBSPEC"
1136 fi
1137 AC_SUBST(ZLIBS)
1138 AC_SUBST(SYS_ZLIBS)
1139 AC_SUBST(ZINCS)
1140 AC_SUBST(DIVIDESPEC)
1141 AC_SUBST(CHECKREFSPEC)
1142 AC_SUBST(EXCEPTIONSPEC)
1143 AC_SUBST(IEEESPEC)
1144
1145 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes)
1146 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
1147 AC_SUBST(GCC_UNWIND_INCLUDE)
1148
1149 # Process the option "--enable-version-specific-runtime-libs"
1150 # Calculate toolexeclibdir
1151 case ${version_specific_libs} in
1152   yes)
1153     # Need the gcc compiler version to know where to install libraries
1154     # and header files if --enable-version-specific-runtime-libs option
1155     # is selected.
1156     includedir='${libdir}/gcc/${target_noncanonical}/'$gcc_version/include/
1157     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
1158     toolexecmainlibdir='$(toolexecdir)/'${gcc_version}'$(MULTISUBDIR)'
1159     toolexeclibdir=$toolexecmainlibdir
1160     ;;
1161   no)
1162     if test -n "$with_cross_host" &&
1163        test x"$with_cross_host" != x"no"; then
1164       # Install a library built with a cross compiler in tooldir, not libdir.
1165       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
1166       toolexecmainlibdir='$(toolexecdir)/lib'
1167     else
1168       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
1169       toolexecmainlibdir='$(libdir)'
1170     fi
1171     multi_os_directory=`$CC -print-multi-os-directory`
1172     case $multi_os_directory in
1173       .) toolexeclibdir=$toolexecmainlibdir ;; # Avoid trailing /.
1174       *) toolexeclibdir=$toolexecmainlibdir/$multi_os_directory ;;
1175     esac
1176     ;;
1177 esac
1178 AC_SUBST(toolexecdir)
1179 AC_SUBST(toolexecmainlibdir)
1180 AC_SUBST(toolexeclibdir)
1181
1182 # Determine gcj version number.
1183 gcjversion=`$GCJ -v 2>&1 | sed -n 's/^.*version \([[^ ]]*\).*$/\1/p'`
1184 GCJVERSION=$gcjversion
1185 AC_SUBST(GCJVERSION)
1186 AC_DEFINE_UNQUOTED(GCJVERSION, "$GCJVERSION", [Short GCJ version ID])
1187
1188 # We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
1189 # On that system, sys/ioctl.h will not include sys/filio.h unless
1190 # BSD_COMP is defined; just including sys/filio.h is simpler.
1191 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h net/if.h pwd.h sys/config.h stdint.h langinfo.h locale.h)
1192 # We avoid AC_HEADER_DIRENT since we really only care about dirent.h
1193 # for now.  If you change this, you also must update natFile.cc.
1194 AC_CHECK_HEADERS(dirent.h)
1195 AC_CHECK_HEADERS(inttypes.h, [
1196     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1197     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
1198 ])
1199 AC_HEADER_SYS_WAIT
1200
1201 AC_CHECK_TYPE([ssize_t], [int])
1202
1203 AC_MSG_CHECKING([for in_addr_t])
1204 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/types.h>
1205 #if STDC_HEADERS
1206 #include <stdlib.h>
1207 #include <stddef.h>
1208 #endif
1209 #if HAVE_NETINET_IN_H
1210 #include <netinet/in.h>
1211 #endif]], [[in_addr_t foo;]])],
1212   [AC_DEFINE(HAVE_IN_ADDR_T, 1,
1213      [Define to 1 if 'in_addr_t' is defined in sys/types.h or netinet/in.h.])
1214    AC_MSG_RESULT(yes)],
1215   [AC_MSG_RESULT(no)])
1216
1217 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
1218 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ip_mreq mreq;]])],
1219   [AC_DEFINE(HAVE_STRUCT_IP_MREQ, 1,
1220      [Define if struct ip_mreq is defined in netinet/in.h.])
1221    AC_MSG_RESULT(yes)],
1222   [AC_MSG_RESULT(no)])
1223
1224 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
1225 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct ipv6_mreq mreq6;]])],
1226   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ, 1,
1227      [Define if struct ipv6_mreq is defined in netinet/in.h.])
1228    AC_MSG_RESULT(yes)],
1229   [AC_MSG_RESULT(no)])
1230
1231 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
1232 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>]], [[struct sockaddr_in6 addr6;]])],
1233   [AC_DEFINE(HAVE_INET6, 1,
1234      [Define if inet6 structures are defined in netinet/in.h.])
1235    AC_MSG_RESULT(yes)],
1236   [AC_MSG_RESULT(no)])
1237
1238 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
1239 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#define _POSIX_PII_SOCKET
1240 #include <sys/types.h>
1241 #include <sys/socket.h>]], [[socklen_t x = 5;]])],
1242   [AC_DEFINE(HAVE_SOCKLEN_T, 1, [Define it socklen_t typedef is in sys/socket.h.])
1243    AC_MSG_RESULT(yes)],
1244   [AC_MSG_RESULT(no)])
1245
1246 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
1247 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[struct tm tim; tim.tm_gmtoff = 0;]])],
1248   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF, 1, [Define if struct tm has tm_gmtoff field.])
1249    AC_MSG_RESULT(yes)],
1250   [AC_MSG_RESULT(no)
1251    AC_MSG_CHECKING([for global timezone variable])
1252    dnl FIXME: we don't want a link check here because that won't work
1253    dnl when cross-compiling.  So instead we make an assumption that
1254    dnl the header file will mention timezone if it exists.
1255    dnl Don't find the win32 function timezone
1256    AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[void i(){long z2 = 2*timezone;}]])],
1257      [AC_DEFINE(HAVE_TIMEZONE, 1, [Define if global 'timezone' exists.])
1258       AC_MSG_RESULT(yes)],
1259      [AC_MSG_RESULT(no)
1260        AC_MSG_CHECKING([for global _timezone variable])
1261        dnl FIXME: As above, don't want link check
1262        AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[long z2 = _timezone;]])],
1263          [AC_DEFINE(HAVE_UNDERSCORE_TIMEZONE, 1,
1264             [Define if your platform has the global _timezone variable.])
1265           AC_MSG_RESULT(yes)],
1266           [AC_MSG_RESULT(no)])])])
1267
1268 AC_FUNC_ALLOCA
1269 AC_FUNC_MMAP
1270
1271 AC_CHECK_PROGS(PERL, perl, false)
1272
1273 SYSDEP_SOURCES=
1274 SIGNAL_HANDLER_AUX=
1275
1276 case "${host}" in
1277  i?86-*-linux*)
1278     SIGNAL_HANDLER=include/i386-signal.h
1279     ;;
1280  sparc*-sun-solaris*)
1281     SIGNAL_HANDLER=include/sparc-signal.h
1282     ;;
1283 # ia64-*)
1284 #    SYSDEP_SOURCES=sysdep/ia64.c
1285 #    test -d sysdep || mkdir sysdep
1286 #    ;;
1287  hppa*-*-linux*)
1288     SIGNAL_HANDLER=include/pa-signal.h
1289     ;;
1290  ia64-*-linux*)
1291     SIGNAL_HANDLER=include/dwarf2-signal.h
1292     ;;
1293  powerpc*-*-linux*)
1294     SIGNAL_HANDLER=include/powerpc-signal.h
1295     ;;
1296  alpha*-*-linux*)
1297     SIGNAL_HANDLER=include/dwarf2-signal.h
1298     ;;
1299  s390*-*-linux*)
1300     SIGNAL_HANDLER=include/s390-signal.h
1301     ;;
1302  x86_64*-*-linux*)
1303     SIGNAL_HANDLER=include/x86_64-signal.h
1304     SIGNAL_HANDLER_AUX=include/i386-signal.h
1305     ;;
1306  sparc*-*-linux*)
1307     SIGNAL_HANDLER=include/dwarf2-signal.h
1308     ;;
1309  sh-*-linux* | sh[[34]]*-*-linux*)
1310     SIGNAL_HANDLER=include/dwarf2-signal.h
1311     ;;
1312  *mingw*)
1313     SIGNAL_HANDLER=include/win32-signal.h
1314     ;;
1315  mips*-*-linux*)
1316     SIGNAL_HANDLER=include/mips-signal.h
1317     ;;
1318  *-*-darwin*)
1319     SIGNAL_HANDLER=include/darwin-signal.h
1320     ;;
1321  *)
1322     SIGNAL_HANDLER=include/default-signal.h
1323     ;;
1324 esac
1325
1326 # If we're using sjlj exceptions, forget what we just learned.
1327 if test "$enable_sjlj_exceptions" = yes; then
1328    SIGNAL_HANDLER=include/default-signal.h
1329    SIGNAL_HANDLER_AUX=
1330 fi
1331
1332 # Define here any compiler flags that you need in order to make backtrace() work.
1333 BACKTRACESPEC=
1334 case "${host}" in
1335  x86_64*-*-linux*|i?86-*)
1336     BACKTRACESPEC=-fno-omit-frame-pointer
1337     ;;
1338 esac
1339 AC_SUBST(BACKTRACESPEC)
1340
1341 AC_SUBST(SYSDEP_SOURCES)
1342
1343 if test -z "$SIGNAL_HANDLER_AUX"; then
1344   SIGNAL_HANDLER_AUX=$SIGNAL_HANDLER
1345 fi
1346
1347 AC_CONFIG_LINKS(include/java-signal.h:$SIGNAL_HANDLER
1348                 include/java-signal-aux.h:$SIGNAL_HANDLER_AUX)
1349
1350 if test "${multilib}" = "yes"; then
1351   multilib_arg="--enable-multilib"
1352 else
1353   multilib_arg=
1354 fi
1355
1356
1357
1358 here=`${PWDCMD-pwd}`
1359 AC_SUBST(here)
1360
1361 # We get this from the environment.
1362 AC_SUBST(GCJFLAGS)
1363
1364 AC_CONFIG_FILES([
1365 Makefile
1366 libgcj.pc
1367 libgcj.spec
1368 libgcj-test.spec
1369 gnu/classpath/Configuration.java
1370 gcj/Makefile
1371 include/Makefile
1372 testsuite/Makefile
1373 ])
1374
1375 AC_CONFIG_COMMANDS([default],
1376 [# Only add multilib support code if we just rebuilt top-level Makefile.
1377 case " $CONFIG_FILES " in
1378  *" Makefile "*)
1379    LD="${ORIGINAL_LD_FOR_MULTILIBS}"
1380    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
1381    ;;
1382 esac
1383
1384 # Make subdirectories and `.d' files.  Look in both srcdir and
1385 # builddir for the .java files.
1386 h=`${PWDCMD-pwd}`
1387 : > deps.mk
1388 ( (cd $srcdir && find . \( -name '*.java' -o -name '*.cc' -o -name '*.c' \) -print) ;
1389   find . \( -name '*.java' -o -name '*.cc' -o -name '*.c' \) -print) | \
1390    fgrep -v testsuite | \
1391    sed -e 's/\.java/.d/'\;'s/\.cc/.d/'\;'s/\.c/.d/' | \
1392    while read f; do
1393       echo "include $f" >> deps.mk
1394       test -f $f || {
1395          d=`echo $f | sed -e 's,/[[^/]]*$,,'`
1396          if test ! -d $d; then
1397            $libgcj_basedir/../mkinstalldirs $d
1398          fi;
1399          echo > $f
1400       }
1401    done
1402 ],
1403 srcdir=${srcdir}
1404 host=${host}
1405 target=${target}
1406 with_multisubdir=${with_multisubdir}
1407 ac_configure_args="${multilib_arg} ${ac_configure_args}"
1408 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
1409 libgcj_basedir=${libgcj_basedir}
1410 CC="${CC}"
1411 CXX="${CXX}"
1412 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
1413 )
1414
1415 AC_OUTPUT