gcc/configure.ac

   1 # configure.ac for GCC
   2 # Process this file with autoconf to generate a configuration script.
   3
   4 # Copyright 1997, 1998, 1999, 2000, 2001, 2002, 2003, 2004
   5 # Free Software Foundation, Inc.
   6
   7 #This file is part of GCC.
   8
   9 #GCC is free software; you can redistribute it and/or modify it under
  10 #the terms of the GNU General Public License as published by the Free
  11 #Software Foundation; either version 2, or (at your option) any later
  12 #version.
  13
  14 #GCC is distributed in the hope that it will be useful, but WITHOUT
  15 #ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  16 #FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  17 #for more details.
  18
  19 #You should have received a copy of the GNU General Public License
  20 #along with GCC; see the file COPYING.  If not, write to the Free
  21 #Software Foundation, 59 Temple Place - Suite 330, Boston, MA
  22 #02111-1307, USA.
  23
  24 # --------------------------------
  25 # Initialization and sanity checks
  26 # --------------------------------
  27
  28 AC_PREREQ(2.59)
  29 AC_INIT
  30 AC_CONFIG_SRCDIR(tree.c)
  31 AC_CONFIG_HEADER(auto-host.h:config.in)
  32
  33 # Determine the host, build, and target systems
  34 AC_CANONICAL_BUILD
  35 AC_CANONICAL_HOST
  36 AC_CANONICAL_TARGET
  37
  38 # Determine the noncanonical target name, for directory use.
  39 ACX_NONCANONICAL_TARGET
  40
  41 # Determine the target- and build-specific subdirectories
  42 GCC_TOPLEV_SUBDIRS
  43
  44 # Set program_transform_name
  45 AC_ARG_PROGRAM
  46
  47 # Check for bogus environment variables.
  48 # Test if LIBRARY_PATH contains the notation for the current directory
  49 # since this would lead to problems installing/building glibc.
  50 # LIBRARY_PATH contains the current directory if one of the following
  51 # is true:
  52 # - one of the terminals (":" and ";") is the first or last sign
  53 # - two terminals occur directly after each other
  54 # - the path contains an element with a dot in it
  55 AC_MSG_CHECKING(LIBRARY_PATH variable)
  56 changequote(,)dnl
  57 case ${LIBRARY_PATH} in
  58   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  59     library_path_setting="contains current directory"
  60     ;;
  61   *)
  62     library_path_setting="ok"
  63     ;;
  64 esac
  65 changequote([,])dnl
  66 AC_MSG_RESULT($library_path_setting)
  67 if test "$library_path_setting" != "ok"; then
  68 AC_MSG_ERROR([
  69 *** LIBRARY_PATH shouldn't contain the current directory when
  70 *** building gcc. Please change the environment variable
  71 *** and run configure again.])
  72 fi
  73
  74 # Test if GCC_EXEC_PREFIX contains the notation for the current directory
  75 # since this would lead to problems installing/building glibc.
  76 # GCC_EXEC_PREFIX contains the current directory if one of the following
  77 # is true:
  78 # - one of the terminals (":" and ";") is the first or last sign
  79 # - two terminals occur directly after each other
  80 # - the path contains an element with a dot in it
  81 AC_MSG_CHECKING(GCC_EXEC_PREFIX variable)
  82 changequote(,)dnl
  83 case ${GCC_EXEC_PREFIX} in
  84   [:\;]* | *[:\;] | *[:\;][:\;]* |  *[:\;]. | .[:\;]*| . | *[:\;].[:\;]* )
  85     gcc_exec_prefix_setting="contains current directory"
  86     ;;
  87   *)
  88     gcc_exec_prefix_setting="ok"
  89     ;;
  90 esac
  91 changequote([,])dnl
  92 AC_MSG_RESULT($gcc_exec_prefix_setting)
  93 if test "$gcc_exec_prefix_setting" != "ok"; then
  94 AC_MSG_ERROR([
  95 *** GCC_EXEC_PREFIX shouldn't contain the current directory when
  96 *** building gcc. Please change the environment variable
  97 *** and run configure again.])
  98 fi
  99
 100 # -----------
 101 # Directories
 102 # -----------
 103
 104 # Specify the local prefix
 105 local_prefix=
 106 AC_ARG_WITH(local-prefix,
 107 [  --with-local-prefix=DIR specifies directory to put local include],
 108 [case "${withval}" in
 109 yes)    AC_MSG_ERROR(bad value ${withval} given for local include directory prefix) ;;
 110 no)     ;;
 111 *)      local_prefix=$with_local_prefix ;;
 112 esac])
 113
 114 # Default local prefix if it is empty
 115 if test x$local_prefix = x; then
 116         local_prefix=/usr/local
 117 fi
 118
 119 # Don't set gcc_gxx_include_dir to gxx_include_dir since that's only
 120 # passed in by the toplevel make and thus we'd get different behavior
 121 # depending on where we built the sources.
 122 gcc_gxx_include_dir=
 123 # Specify the g++ header file directory
 124 AC_ARG_WITH(gxx-include-dir,
 125 [  --with-gxx-include-dir=DIR
 126                           specifies directory to put g++ header files],
 127 [case "${withval}" in
 128 yes)    AC_MSG_ERROR(bad value ${withval} given for g++ include directory) ;;
 129 no)     ;;
 130 *)      gcc_gxx_include_dir=$with_gxx_include_dir ;;
 131 esac])
 132
 133 if test x${gcc_gxx_include_dir} = x; then
 134   if test x${enable_version_specific_runtime_libs} = xyes; then
 135     gcc_gxx_include_dir='${libsubdir}/include/c++'
 136   else
 137     libstdcxx_incdir='c++/$(version)'
 138 changequote(<<, >>)dnl
 139     gcc_gxx_include_dir="\$(libsubdir)/\$(unlibsubdir)/..\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/[^/]*|/..|g'\`/include/"${libstdcxx_incdir}
 140 changequote([, ])dnl
 141   fi
 142 fi
 143
 144 AC_ARG_WITH(cpp_install_dir,
 145 [  --with-cpp-install-dir=DIR
 146                           install the user visible C preprocessor in DIR
 147                           (relative to PREFIX) as well as PREFIX/bin],
 148 [if test x$withval = xyes; then
 149   AC_MSG_ERROR([option --with-cpp-install-dir requires an argument])
 150 elif test x$withval != xno; then
 151   cpp_install_dir=$withval
 152 fi])
 153
 154 # We would like to our source tree to be readonly.  However when releases or
 155 # pre-releases are generated, the flex/bison generated files as well as the
 156 # various formats of manuals need to be included along with the rest of the
 157 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
 158 # just that.
 159
 160 AC_MSG_CHECKING([whether to place generated files in the source directory])
 161   dnl generated-files-in-srcdir is disabled by default
 162   AC_ARG_ENABLE(generated-files-in-srcdir,
 163 [  --enable-generated-files-in-srcdir
 164                           put copies of generated files in source dir
 165                           intended for creating source tarballs for users
 166                           without texinfo bison or flex.],
 167       generated_files_in_srcdir=$enableval,
 168       generated_files_in_srcdir=no)
 169
 170 AC_MSG_RESULT($generated_files_in_srcdir)
 171
 172 if test "$generated_files_in_srcdir" = "yes"; then
 173   GENINSRC=''
 174 else
 175   GENINSRC='#'
 176 fi
 177 AC_SUBST(GENINSRC)
 178
 179 # -------------------
 180 # Find default linker
 181 # -------------------
 182
 183 # With GNU ld
 184 AC_ARG_WITH(gnu-ld,
 185 [  --with-gnu-ld           arrange to work with GNU ld.],
 186 gnu_ld_flag="$with_gnu_ld",
 187 gnu_ld_flag=no)
 188
 189 # With pre-defined ld
 190 AC_ARG_WITH(ld,
 191 [  --with-ld               arrange to use the specified ld (full pathname)],
 192 DEFAULT_LINKER="$with_ld")
 193 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 194   if test ! -x "$DEFAULT_LINKER"; then
 195     AC_MSG_ERROR([cannot execute: $DEFAULT_LINKER: check --with-ld or env. var. DEFAULT_LINKER])
 196   elif $DEFAULT_LINKER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 197     gnu_ld_flag=yes
 198   fi
 199   AC_DEFINE_UNQUOTED(DEFAULT_LINKER,"$DEFAULT_LINKER",
 200         [Define to enable the use of a default linker.])
 201 fi
 202
 203 AC_MSG_CHECKING([whether a default linker was specified])
 204 if test x"${DEFAULT_LINKER+set}" = x"set"; then
 205   if test x"$gnu_ld_flag" = x"no"; then
 206     AC_MSG_RESULT([yes ($DEFAULT_LINKER)])
 207   else
 208     AC_MSG_RESULT([yes ($DEFAULT_LINKER - GNU ld)])
 209   fi
 210 else
 211   AC_MSG_RESULT(no)
 212 fi
 213
 214 # With demangler in GNU ld
 215 AC_ARG_WITH(demangler-in-ld,
 216 [  --with-demangler-in-ld  try to use demangler in GNU ld.],
 217 demangler_in_ld="$with_demangler_in_ld",
 218 demangler_in_ld=no)
 219
 220 # ----------------------
 221 # Find default assembler
 222 # ----------------------
 223
 224 # With GNU as
 225 AC_ARG_WITH(gnu-as,
 226 [  --with-gnu-as           arrange to work with GNU as],
 227 gas_flag="$with_gnu_as",
 228 gas_flag=no)
 229
 230 AC_ARG_WITH(as,
 231 [  --with-as               arrange to use the specified as (full pathname)],
 232 DEFAULT_ASSEMBLER="$with_as")
 233 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 234   if test ! -x "$DEFAULT_ASSEMBLER"; then
 235     AC_MSG_ERROR([cannot execute: $DEFAULT_ASSEMBLER: check --with-as or env. var. DEFAULT_ASSEMBLER])
 236   elif $DEFAULT_ASSEMBLER -v < /dev/null 2>&1 | grep GNU > /dev/null; then
 237     gas_flag=yes
 238   fi
 239   AC_DEFINE_UNQUOTED(DEFAULT_ASSEMBLER,"$DEFAULT_ASSEMBLER",
 240         [Define to enable the use of a default assembler.])
 241 fi
 242
 243 AC_MSG_CHECKING([whether a default assembler was specified])
 244 if test x"${DEFAULT_ASSEMBLER+set}" = x"set"; then
 245   if test x"$gas_flag" = x"no"; then
 246     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER)])
 247   else
 248     AC_MSG_RESULT([yes ($DEFAULT_ASSEMBLER - GNU as)])
 249   fi
 250 else
 251   AC_MSG_RESULT(no)
 252 fi
 253
 254 # ---------------
 255 # Find C compiler
 256 # ---------------
 257
 258 # If a non-executable a.out is present (e.g. created by GNU as above even if
 259 # invoked with -v only), the IRIX 6 native ld just overwrites the existing
 260 # file, even when creating an executable, so an execution test fails.
 261 # Remove possible default executable files to avoid this.
 262 #
 263 # FIXME: This really belongs into AC_PROG_CC and can be removed once
 264 # Autoconf includes it.
 265 rm -f a.out a.exe b.out
 266
 267 # Find the native compiler
 268 AC_PROG_CC
 269 AM_PROG_CC_C_O
 270 # autoconf is lame and doesn't give us any substitution variable for this.
 271 if eval "test \"`echo '$ac_cv_prog_cc_'${ac_cc}_c_o`\" = no"; then
 272   NO_MINUS_C_MINUS_O=yes
 273 else
 274   OUTPUT_OPTION='-o $@'
 275 fi
 276 AC_SUBST(NO_MINUS_C_MINUS_O)
 277 AC_SUBST(OUTPUT_OPTION)
 278
 279 # -------------------------
 280 # Check C compiler features
 281 # -------------------------
 282
 283 AC_PROG_CPP
 284 AC_C_INLINE
 285
 286 # sizeof(char) is 1 by definition.
 287 AC_CHECK_SIZEOF(void *)
 288 AC_CHECK_SIZEOF(short)
 289 AC_CHECK_SIZEOF(int)
 290 AC_CHECK_SIZEOF(long)
 291 AC_CHECK_TYPES([long long], [AC_CHECK_SIZEOF(long long)])
 292 AC_CHECK_TYPES([__int64], [AC_CHECK_SIZEOF(__int64)])
 293
 294 # ---------------------
 295 # Warnings and checking
 296 # ---------------------
 297
 298 # Check $CC warning features (if it's GCC).
 299 # We want to use -pedantic, but we don't want warnings about
 300 # * 'long long'
 301 # * variadic macros
 302 # So, we only use -pedantic if we can disable those warnings.
 303
 304 AC_CACHE_CHECK(
 305   [whether ${CC} accepts -Wno-long-long],
 306   [ac_cv_prog_cc_w_no_long_long],
 307   [save_CFLAGS="$CFLAGS"
 308   CFLAGS="-Wno-long-long"
 309   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 310                     [ac_cv_prog_cc_w_no_long_long=yes],
 311                     [ac_cv_prog_cc_w_no_long_long=no])
 312   CFLAGS="$save_CFLAGS"
 313   ])
 314
 315 AC_CACHE_CHECK(
 316   [whether ${CC} accepts -Wno-variadic-macros],
 317   [ac_cv_prog_cc_w_no_variadic_macros],
 318   [save_CFLAGS="$CFLAGS"
 319   CFLAGS="-Wno-variadic-macros"
 320   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 321                     [ac_cv_prog_cc_w_no_variadic_macros=yes],
 322                     [ac_cv_prog_cc_w_no_variadic_macros=no])
 323   CFLAGS="$save_CFLAGS"
 324   ])
 325
 326 strict1_warn=
 327 if test $ac_cv_prog_cc_w_no_long_long = yes \
 328    && test $ac_cv_prog_cc_w_no_variadic_macros = yes ; then
 329   strict1_warn="-pedantic -Wno-long-long -Wno-variadic-macros"
 330 fi
 331 AC_SUBST(strict1_warn)
 332
 333 # Add -Wold-style-definition if it's accepted
 334 AC_CACHE_CHECK(
 335   [whether ${CC} accepts -Wold-style-definition],
 336   [ac_cv_prog_cc_w_old_style_definition],
 337   [save_CFLAGS="$CFLAGS"
 338   CFLAGS="-Wold-style-definition"
 339   AC_COMPILE_IFELSE([AC_LANG_SOURCE([[]])],
 340                     [ac_cv_prog_cc_w_old_style_definition=yes],
 341                     [ac_cv_prog_cc_w_old_style_definition=no])
 342   CFLAGS="$save_CFLAGS"
 343   ])
 344 if test $ac_cv_prog_cc_w_old_style_definition = yes ; then
 345   strict1_warn="${strict1_warn} -Wold-style-definition"
 346 fi
 347
 348 # Enable -Werror, period.
 349 AC_ARG_ENABLE(werror_always,
 350 [  --enable-werror-always         enable -Werror always], [],
 351 [enable_werror_always=no])
 352 if test x${enable_werror_always} = xyes ; then
 353   strict1_warn="${strict1_warn} -Werror"
 354   WERROR=-Werror
 355 fi
 356
 357 # If the native compiler is GCC, we can enable warnings even in stage1.
 358 # That's useful for people building cross-compilers, or just running a
 359 # quick `make'.
 360 warn_cflags=
 361 if test "x$GCC" = "xyes"; then
 362   warn_cflags='$(GCC_WARN_CFLAGS)'
 363 fi
 364 AC_SUBST(warn_cflags)
 365
 366 # Enable -Werror in bootstrap stage2 and later.
 367 is_release=
 368 if test x"`cat $srcdir/DEV-PHASE`" != xexperimental; then
 369   is_release=yes
 370 fi
 371 AC_ARG_ENABLE(werror,
 372 [  --enable-werror         enable -Werror in bootstrap stage2 and later], [],
 373 [if test x$is_release = x ; then
 374   # Default to "yes" on development branches.
 375   enable_werror=yes
 376 else
 377   # Default to "no" on release branches.
 378   enable_werror=no
 379 fi])
 380 if test x$enable_werror = xyes ; then
 381   WERROR=-Werror
 382 fi
 383 AC_SUBST(WERROR)
 384
 385 # Enable expensive internal checks
 386 AC_ARG_ENABLE(checking,
 387 [  --enable-checking[=LIST]
 388                           enable expensive run-time checks.  With LIST,
 389                           enable only specific categories of checks.
 390                           Categories are: yes,no,all,none,release.
 391                           Flags are: assert,fold,gc,gcac,misc,
 392                           rtlflag,rtl,runtime,tree,valgrind.],
 393 [ac_checking_flags="${enableval}"],[
 394 # Determine the default checks.
 395 if test x$is_release = x ; then
 396   ac_checking_flags=yes
 397 else
 398   ac_checking_flags=release
 399 fi])
 400 ac_assert_checking=1
 401 ac_checking=
 402 ac_fold_checking=
 403 ac_gc_checking=
 404 ac_gc_always_collect=
 405 ac_rtl_checking=
 406 ac_rtlflag_checking=
 407 ac_runtime_checking=1
 408 ac_tree_checking=
 409 ac_valgrind_checking=
 410 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 411 for check in $ac_checking_flags
 412 do
 413         case $check in
 414         # these set all the flags to specific states
 415         yes)            ac_assert_checking=1 ; ac_checking=1 ;
 416                         ac_fold_checking= ; ac_gc_checking=1 ;
 417                         ac_gc_always_collect= ; ac_rtl_checking= ;
 418                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 419                         ac_tree_checking=1 ; ac_valgrind_checking= ;;
 420         no|none)        ac_assert_checking= ; ac_checking= ;
 421                         ac_fold_checking= ; ac_gc_checking= ;
 422                         ac_gc_always_collect= ; ac_rtl_checking= ;
 423                         ac_rtlflag_checking= ; ac_runtime_checking= ;
 424                         ac_tree_checking= ; ac_valgrind_checking= ;;
 425         all)            ac_assert_checking=1 ; ac_checking=1 ;
 426                         ac_fold_checking=1 ; ac_gc_checking=1 ;
 427                         ac_gc_always_collect=1 ; ac_rtl_checking=1 ;
 428                         ac_rtlflag_checking=1 ; ac_runtime_checking=1 ;
 429                         ac_tree_checking=1 ; ac_valgrind_checking= ;;
 430         release)        ac_assert_checking=1 ; ac_checking= ;
 431                         ac_fold_checking= ; ac_gc_checking= ;
 432                         ac_gc_always_collect= ; ac_rtl_checking= ;
 433                         ac_rtlflag_checking= ; ac_runtime_checking=1 ;
 434                         ac_tree_checking= ; ac_valgrind_checking= ;;
 435         # these enable particular checks
 436         assert)         ac_assert_checking=1 ;;
 437         fold)           ac_fold_checking=1 ;;
 438         gc)             ac_gc_checking=1 ;;
 439         gcac)           ac_gc_always_collect=1 ;;
 440         misc)           ac_checking=1 ;;
 441         rtl)            ac_rtl_checking=1 ;;
 442         rtlflag)        ac_rtlflag_checking=1 ;;
 443         runtime)        ac_runtime_checking=1 ;;
 444         tree)           ac_tree_checking=1 ;;
 445         valgrind)       ac_valgrind_checking=1 ;;
 446         *)      AC_MSG_ERROR(unknown check category $check) ;;
 447         esac
 448 done
 449 IFS="$ac_save_IFS"
 450
 451 nocommon_flag=""
 452 if test x$ac_checking != x ; then
 453   AC_DEFINE(ENABLE_CHECKING, 1,
 454 [Define if you want more run-time sanity checks.  This one gets a grab
 455    bag of miscellaneous but relatively cheap checks.])
 456   nocommon_flag=-fno-common
 457 fi
 458 AC_SUBST(nocommon_flag)
 459 if test x$ac_assert_checking != x ; then
 460   AC_DEFINE(ENABLE_ASSERT_CHECKING, 1,
 461 [Define if you want assertions enabled.  This is a cheap check.])
 462 fi
 463 GCC_TARGET_TEMPLATE(ENABLE_RUNTIME_CHECKING)
 464 if test x$ac_runtime_checking != x ; then
 465   AC_DEFINE(ENABLE_RUNTIME_CHECKING, 1,
 466 [Define if you want runtime assertions enabled.  This is a cheap check.])
 467 fi
 468 if test x$ac_tree_checking != x ; then
 469   AC_DEFINE(ENABLE_TREE_CHECKING, 1,
 470 [Define if you want all operations on trees (the basic data
 471    structure of the front ends) to be checked for dynamic type safety
 472    at runtime.  This is moderately expensive.  The tree browser debugging
 473    routines will also be enabled by this option.
 474    ])
 475   TREEBROWSER=tree-browser.o
 476 fi
 477 AC_SUBST(TREEBROWSER)
 478 if test x$ac_rtl_checking != x ; then
 479   AC_DEFINE(ENABLE_RTL_CHECKING, 1,
 480 [Define if you want all operations on RTL (the basic data structure
 481    of the optimizer and back end) to be checked for dynamic type safety
 482    at runtime.  This is quite expensive.])
 483 fi
 484 if test x$ac_rtlflag_checking != x ; then
 485   AC_DEFINE(ENABLE_RTL_FLAG_CHECKING, 1,
 486 [Define if you want RTL flag accesses to be checked against the RTL
 487    codes that are supported for each access macro.  This is relatively
 488    cheap.])
 489 fi
 490 if test x$ac_gc_checking != x ; then
 491   AC_DEFINE(ENABLE_GC_CHECKING, 1,
 492 [Define if you want the garbage collector to do object poisoning and
 493    other memory allocation checks.  This is quite expensive.])
 494 fi
 495 if test x$ac_gc_always_collect != x ; then
 496   AC_DEFINE(ENABLE_GC_ALWAYS_COLLECT, 1,
 497 [Define if you want the garbage collector to operate in maximally
 498    paranoid mode, validating the entire heap and collecting garbage at
 499    every opportunity.  This is extremely expensive.])
 500 fi
 501 if test x$ac_fold_checking != x ; then
 502   AC_DEFINE(ENABLE_FOLD_CHECKING, 1,
 503 [Define if you want fold checked that it never destructs its argument.
 504    This is quite expensive.])
 505 fi
 506 valgrind_path_defines=
 507 valgrind_command=
 508
 509 dnl # This check AC_REQUIREs various stuff, so it *must not* be inside
 510 dnl # an if statement.  This was the source of very frustrating bugs
 511 dnl # in converting to autoconf 2.5x!
 512 AC_CHECK_HEADER(valgrind.h, have_valgrind_h=yes, have_valgrind_h=no)
 513
 514 if test x$ac_valgrind_checking != x ; then
 515   # It is certainly possible that there's valgrind but no valgrind.h.
 516   # GCC relies on making annotations so we must have both.
 517   AC_MSG_CHECKING(for VALGRIND_DISCARD in <valgrind/memcheck.h>)
 518   AC_TRY_CPP(
 519     [#include <valgrind/memcheck.h>
 520 #ifndef VALGRIND_DISCARD
 521 #error VALGRIND_DISCARD not defined
 522 #endif],
 523   [gcc_cv_header_valgrind_memcheck_h=yes],
 524   [gcc_cv_header_valgrind_memcheck_h=no])
 525   AC_MSG_RESULT($gcc_cv_header_valgrind_memcheck_h)
 526   AC_MSG_CHECKING(for VALGRIND_DISCARD in <memcheck.h>)
 527   AC_TRY_CPP(
 528     [#include <memcheck.h>
 529 #ifndef VALGRIND_DISCARD
 530 #error VALGRIND_DISCARD not defined
 531 #endif],
 532   [gcc_cv_header_memcheck_h=yes],
 533   gcc_cv_header_memcheck_h=no)
 534   AC_MSG_RESULT($gcc_cv_header_memcheck_h)
 535   AM_PATH_PROG_WITH_TEST(valgrind_path, valgrind,
 536         [$ac_dir/$ac_word --version | grep valgrind- >/dev/null 2>&1])
 537   if test "x$valgrind_path" = "x" \
 538     || (test $have_valgrind_h = no \
 539         && test $gcc_cv_header_memcheck_h = no \
 540         && test $gcc_cv_header_valgrind_memcheck_h = no); then
 541         AC_MSG_ERROR([*** Can't find both valgrind and valgrind/memcheck.h, memcheck.h or valgrind.h])
 542   fi
 543   valgrind_path_defines=-DVALGRIND_PATH='\"'$valgrind_path'\"'
 544   valgrind_command="$valgrind_path -q"
 545   AC_DEFINE(ENABLE_VALGRIND_CHECKING, 1,
 546 [Define if you want to run subprograms and generated programs
 547    through valgrind (a memory checker).  This is extremely expensive.])
 548   if test $gcc_cv_header_valgrind_memcheck_h = yes; then
 549     AC_DEFINE(HAVE_VALGRIND_MEMCHECK_H, 1,
 550         [Define if valgrind's valgrind/memcheck.h header is installed.])
 551   fi
 552   if test $gcc_cv_header_memcheck_h = yes; then
 553     AC_DEFINE(HAVE_MEMCHECK_H, 1,
 554         [Define if valgrind's memcheck.h header is installed.])
 555   fi
 556 fi
 557 AC_SUBST(valgrind_path_defines)
 558 AC_SUBST(valgrind_command)
 559
 560 AC_ARG_ENABLE(mapped-location,
 561 [  --enable-mapped-location   location_t is fileline integer cookie],,
 562 enable_mapped_location=no)
 563
 564 if test "$enable_mapped_location" = yes ; then
 565   AC_DEFINE(USE_MAPPED_LOCATION, 1,
 566 [Define if location_t is fileline integer cookie.])
 567 fi
 568
 569 # Enable code coverage collection
 570 AC_ARG_ENABLE(coverage,
 571 [  --enable-coverage[=LEVEL]
 572                           enable compiler's code coverage collection.
 573                           Use to measure compiler performance and locate
 574                           unused parts of the compiler. With LEVEL, specify
 575                           optimization. Values are opt, noopt,
 576                           default is noopt],
 577 [case "${enableval}" in
 578   yes|noopt)
 579     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O0"
 580     ;;
 581   opt)
 582     coverage_flags="-fprofile-arcs -ftest-coverage -frandom-seed=\$@ -O2"
 583     ;;
 584   no)
 585     # a.k.a. --disable-coverage
 586     coverage_flags=""
 587     ;;
 588   *)
 589     AC_MSG_ERROR(unknown coverage setting $enableval)
 590     ;;
 591 esac],
 592 [coverage_flags=""])
 593 AC_SUBST(coverage_flags)
 594
 595 AC_ARG_ENABLE(gather-detailed-mem-stats,
 596 [  --enable-gather-detailed-mem-stats         enable detailed memory allocation stats gathering], [],
 597 [enable_gather_detailed_mem_stats=no])
 598 if test x$enable_gather_detailed_mem_stats = xyes ; then
 599   AC_DEFINE(GATHER_STATISTICS, 1,
 600         [Define to enable detailed memory allocation stats gathering.])
 601 fi
 602
 603 # -------------------------------
 604 # Miscenalleous configure options
 605 # -------------------------------
 606
 607 # With stabs
 608 AC_ARG_WITH(stabs,
 609 [  --with-stabs            arrange to use stabs instead of host debug format],
 610 stabs="$with_stabs",
 611 stabs=no)
 612
 613 # Determine whether or not multilibs are enabled.
 614 AC_ARG_ENABLE(multilib,
 615 [  --enable-multilib       enable library support for multiple ABIs],
 616 [], [enable_multilib=yes])
 617 AC_SUBST(enable_multilib)
 618
 619 # Enable __cxa_atexit for C++.
 620 AC_ARG_ENABLE(__cxa_atexit,
 621 [  --enable-__cxa_atexit   enable __cxa_atexit for C++],
 622 [], [])
 623
 624 # Enable threads
 625 # Pass with no value to take the default
 626 # Pass with a value to specify a thread package
 627 AC_ARG_ENABLE(threads,
 628 [  --enable-threads        enable thread usage for target GCC
 629   --enable-threads=LIB    use LIB thread package for target GCC],,
 630 [enable_threads=''])
 631
 632 AC_ARG_ENABLE(objc-gc,
 633 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
 634                           the GNU Objective-C runtime],
 635 if test x$enable_objc_gc = xno; then
 636         objc_boehm_gc=''
 637 else
 638         objc_boehm_gc=1
 639 fi,
 640 objc_boehm_gc='')
 641
 642 AC_ARG_WITH(dwarf2,
 643 [  --with-dwarf2           force the default debug format to be DWARF 2],
 644 dwarf2="$with_dwarf2",
 645 dwarf2=no)
 646
 647 AC_ARG_ENABLE(shared,
 648 [  --disable-shared        don't provide a shared libgcc],
 649 [
 650   case $enable_shared in
 651   yes | no) ;;
 652   *)
 653     enable_shared=no
 654     IFS="${IFS=         }"; ac_save_ifs="$IFS"; IFS="${IFS}:,"
 655     for pkg in $enableval; do
 656       if test "X$pkg" = "Xgcc" || test "X$pkg" = "Xlibgcc"; then
 657         enable_shared=yes
 658       fi
 659     done
 660     IFS="$ac_save_ifs"
 661     ;;
 662   esac
 663 ], [enable_shared=yes])
 664 AC_SUBST(enable_shared)
 665
 666 AC_ARG_WITH(sysroot,
 667 [  --with-sysroot[=DIR] Search for usr/lib, usr/include, et al, within DIR.],
 668 [
 669  case ${with_sysroot} in
 670  yes) TARGET_SYSTEM_ROOT='${exec_prefix}/${target_noncanonical}/sys-root' ;;
 671  *) TARGET_SYSTEM_ROOT=$with_sysroot ;;
 672  esac
 673
 674  TARGET_SYSTEM_ROOT_DEFINE='-DTARGET_SYSTEM_ROOT=\"$(TARGET_SYSTEM_ROOT)\"'
 675  CROSS_SYSTEM_HEADER_DIR='$(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)'
 676
 677  if test "x$exec_prefix" = xNONE; then
 678   if test "x$prefix" = xNONE; then
 679    test_prefix=/usr/local
 680   else
 681    test_prefix=$prefix
 682   fi
 683  else
 684   test_prefix=$exec_prefix
 685  fi
 686  case ${TARGET_SYSTEM_ROOT} in
 687  "${test_prefix}"|"${test_prefix}/"*|\
 688  '${exec_prefix}'|'${exec_prefix}/'*)
 689    t="$TARGET_SYSTEM_ROOT_DEFINE -DTARGET_SYSTEM_ROOT_RELOCATABLE"
 690    TARGET_SYSTEM_ROOT_DEFINE="$t"
 691    ;;
 692  esac
 693 ], [
 694  TARGET_SYSTEM_ROOT=
 695  TARGET_SYSTEM_ROOT_DEFINE=
 696  CROSS_SYSTEM_HEADER_DIR='$(gcc_tooldir)/sys-include'
 697 ])
 698 AC_SUBST(TARGET_SYSTEM_ROOT)
 699 AC_SUBST(TARGET_SYSTEM_ROOT_DEFINE)
 700 AC_SUBST(CROSS_SYSTEM_HEADER_DIR)
 701
 702 # Build with intermodule optimisations
 703 AC_ARG_ENABLE(intermodule,
 704 [  --enable-intermodule    build the compiler in one step],
 705 [case ${enable_intermodule} in
 706   yes) onestep="-onestep";;
 707   *) onestep="";;
 708 esac],
 709 [onestep=""])
 710 AC_SUBST(onestep)
 711
 712 # Sanity check enable_languages in case someone does not run the toplevel
 713 # configure # script.
 714 AC_ARG_ENABLE(languages,
 715 [  --enable-languages=LIST specify which front-ends to build],
 716 [case ,${enable_languages}, in
 717        ,,|,yes,)
 718                 # go safe -- we cannot be much sure without the toplevel
 719                 # configure's
 720                 # analysis of which target libs are present and usable
 721                 enable_languages=c
 722                 ;;
 723          *,all,*)
 724                 AC_MSG_ERROR([only the toplevel supports --enable-languages=all])
 725                 ;;
 726         *,c,*)
 727                 ;;
 728         *)
 729                 enable_languages=c,${enable_languages}
 730                 ;;
 731 esac],
 732 [enable_languages=c])
 733
 734 subdirs=
 735 for lang in ${srcdir}/*/config-lang.in
 736 do
 737         case $lang in
 738         # The odd quoting in the next line works around
 739         # an apparent bug in bash 1.12 on linux.
 740 changequote(,)dnl
 741         ${srcdir}/[*]/config-lang.in) ;;
 742         *)
 743           lang_alias=`sed -n -e 's,^language=['"'"'"'"]\(.*\)["'"'"'"'].*$,\1,p' -e 's,^language=\([^   ]*\).*$,\1,p' $lang`
 744           if test "x$lang_alias" = x
 745           then
 746                 echo "$lang doesn't set \$language." 1>&2
 747                 exit 1
 748           fi
 749           case ",$enable_languages," in
 750           *,$lang_alias,*)
 751             subdirs="$subdirs `echo $lang | sed -e 's,^.*/\([^/]*\)/config-lang.in$,\1,'`" ;;
 752           esac
 753           ;;
 754 changequote([,])dnl
 755         esac
 756 done
 757
 758
 759 # -------------------------
 760 # Checks for other programs
 761 # -------------------------
 762
 763 AC_PROG_MAKE_SET
 764
 765 # Find some useful tools
 766 AC_PROG_AWK
 767 # We need awk to create options.c and options.h.
 768 # Bail out if it's missing.
 769 case ${AWK} in
 770   "") AC_MSG_ERROR([can't build without awk, bailing out]) ;;
 771 esac
 772
 773 gcc_AC_PROG_LN_S
 774 ACX_PROG_LN($LN_S)
 775 AC_PROG_RANLIB
 776 case "${host}" in
 777 *-*-darwin*)
 778   # By default, the Darwin ranlib will not treat common symbols as
 779   # definitions when  building the archive table of contents.  Other
 780   # ranlibs do that; pass an option to the Darwin ranlib that makes
 781   # it behave similarly.
 782   ranlib_flags="-c"
 783   ;;
 784 *)
 785   ranlib_flags=""
 786 esac
 787 AC_SUBST(ranlib_flags)
 788
 789 gcc_AC_PROG_INSTALL
 790
 791 # See if cmp has --ignore-initial.
 792 gcc_AC_PROG_CMP_IGNORE_INITIAL
 793
 794 # See if we have the mktemp command.
 795 AC_CHECK_PROG(have_mktemp_command, mktemp, yes, no)
 796
 797 MISSING="${CONFIG_SHELL-/bin/sh} $srcdir/../missing"
 798
 799 # See if makeinfo has been installed and is modern enough
 800 # that we can use it.
 801 gcc_AC_CHECK_PROG_VER(MAKEINFO, makeinfo, --version,
 802   [GNU texinfo.* \([0-9][0-9.]*\)],
 803   [4.[2-9]*])
 804 if test $gcc_cv_prog_makeinfo_modern = no; then
 805   MAKEINFO="$MISSING makeinfo"
 806   AC_MSG_WARN([
 807 *** Makeinfo is missing or too old.
 808 *** Info documentation will not be built.])
 809   BUILD_INFO=
 810 else
 811   BUILD_INFO=info
 812 fi
 813 AC_SUBST(BUILD_INFO)
 814
 815 # Is pod2man recent enough to regenerate manpages?
 816 AC_MSG_CHECKING([for recent Pod::Man])
 817 if (perl -e 'use 1.10 Pod::Man') >/dev/null 2>&1; then
 818   AC_MSG_RESULT(yes)
 819   GENERATED_MANPAGES=generated-manpages
 820 else
 821   AC_MSG_RESULT(no)
 822   GENERATED_MANPAGES=
 823 fi
 824 AC_SUBST(GENERATED_MANPAGES)
 825
 826 # How about lex?
 827 dnl Don't use AC_PROG_LEX; we insist on flex.
 828 dnl LEXLIB is not useful in gcc.
 829 AC_CHECK_PROGS([FLEX], flex, [$MISSING flex])
 830
 831 # Bison?
 832 AC_CHECK_PROGS([BISON], bison, [$MISSING bison])
 833
 834 # Binutils are not build modules, unlike bison/flex/makeinfo.  So we
 835 # check for build == host before using them.
 836
 837 # NM
 838 if test x${build} = x${host} && test -f $srcdir/../binutils/nm.c \
 839   && test -d ../binutils ; then
 840   NM='$(objdir)/../binutils/nm-new'
 841 else
 842   AC_CHECK_PROG(NM, nm, nm, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing nm)
 843 fi
 844
 845 # AR
 846 if test x${build} = x${host} && test -f $srcdir/../binutils/ar.c \
 847   && test -d ../binutils ; then
 848   AR='$(objdir)/../binutils/ar'
 849 else
 850   AC_CHECK_PROG(AR, ar, ar, ${CONFIG_SHELL-/bin/sh} ${srcdir}/../missing ar)
 851 fi
 852
 853
 854 # --------------------
 855 # Checks for C headers
 856 # --------------------
 857
 858 AC_MSG_CHECKING(for GNU C library)
 859 AC_CACHE_VAL(gcc_cv_glibc,
 860 [AC_TRY_COMPILE(
 861   [#include <features.h>],[
 862 #if ! (defined __GLIBC__ || defined __GNU_LIBRARY__)
 863 #error Not a GNU C library system
 864 #endif],
 865   [gcc_cv_glibc=yes],
 866   gcc_cv_glibc=no)])
 867 AC_MSG_RESULT($gcc_cv_glibc)
 868 if test $gcc_cv_glibc = yes; then
 869   AC_DEFINE(_GNU_SOURCE, 1, [Always define this when using the GNU C Library])
 870 fi
 871
 872 # Need to reject headers which give warnings, so that the -Werror bootstrap
 873 # works later. *sigh*  This needs to come before all header checks.
 874 AC_PROG_CPP_WERROR
 875
 876 AC_HEADER_STDC
 877 AC_HEADER_TIME
 878 ACX_HEADER_STRING
 879 AC_HEADER_SYS_WAIT
 880 AC_CHECK_HEADERS(limits.h stddef.h string.h strings.h stdlib.h time.h iconv.h \
 881                  fcntl.h unistd.h sys/file.h sys/time.h sys/mman.h \
 882                  sys/resource.h sys/param.h sys/times.h sys/stat.h \
 883                  direct.h malloc.h langinfo.h ldfcn.h locale.h wchar.h)
 884
 885 # Check for thread headers.
 886 AC_CHECK_HEADER(thread.h, [have_thread_h=yes], [have_thread_h=])
 887 AC_CHECK_HEADER(pthread.h, [have_pthread_h=yes], [have_pthread_h=])
 888
 889 # These tests can't be done till we know if we have limits.h.
 890 gcc_AC_C_CHAR_BIT
 891 AC_C_BIGENDIAN
 892
 893 # --------
 894 # UNSORTED
 895 # --------
 896
 897 # Stage specific cflags for build.
 898 stage1_cflags=
 899 case $build in
 900 vax-*-*)
 901   if test x$GCC = xyes
 902   then
 903     stage1_cflags="-Wa,-J"
 904   else
 905     stage1_cflags="-J"
 906   fi
 907   ;;
 908 powerpc-*-darwin*)
 909   # The spiffy cpp-precomp chokes on some legitimate constructs in GCC
 910   # sources; use -no-cpp-precomp to get to GNU cpp.
 911   # Apple's GCC has bugs in designated initializer handling, so disable
 912   # that too.
 913   stage1_cflags="-no-cpp-precomp -DHAVE_DESIGNATED_INITIALIZERS=0"
 914   ;;
 915 esac
 916 AC_SUBST(stage1_cflags)
 917
 918 # These libraries may be used by collect2.
 919 # We may need a special search path to get them linked.
 920 AC_CACHE_CHECK(for collect2 libraries, gcc_cv_collect2_libs,
 921 [save_LIBS="$LIBS"
 922 for libs in '' -lld -lmld \
 923                 '-L/usr/lib/cmplrs/cc2.11 -lmld' \
 924                 '-L/usr/lib/cmplrs/cc3.11 -lmld'
 925 do
 926         LIBS="$libs"
 927         AC_TRY_LINK_FUNC(ldopen,
 928                 [gcc_cv_collect2_libs="$libs"; break])
 929 done
 930 LIBS="$save_LIBS"
 931 test -z "$gcc_cv_collect2_libs" && gcc_cv_collect2_libs='none required'])
 932 case $gcc_cv_collect2_libs in
 933         "none required")        ;;
 934         *)      COLLECT2_LIBS=$gcc_cv_collect2_libs ;;
 935 esac
 936 AC_SUBST(COLLECT2_LIBS)
 937
 938 # When building Ada code on Alpha, we need exc_resume which is usually in
 939 # -lexc.  So test for it.
 940 save_LIBS="$LIBS"
 941 LIBS=
 942 AC_SEARCH_LIBS(exc_resume, exc)
 943 GNAT_LIBEXC="$LIBS"
 944 LIBS="$save_LIBS"
 945 AC_SUBST(GNAT_LIBEXC)
 946
 947 # Some systems put ldexp and frexp in libm instead of libc; assume
 948 # they're both in the same place.  jcf-dump needs them.
 949 save_LIBS="$LIBS"
 950 LIBS=
 951 AC_SEARCH_LIBS(ldexp, m)
 952 LDEXP_LIB="$LIBS"
 953 LIBS="$save_LIBS"
 954 AC_SUBST(LDEXP_LIB)
 955
 956 # Use <inttypes.h> only if it exists,
 957 # doesn't clash with <sys/types.h>, and declares intmax_t.
 958 AC_MSG_CHECKING(for inttypes.h)
 959 AC_CACHE_VAL(gcc_cv_header_inttypes_h,
 960 [AC_TRY_COMPILE(
 961   [#include <sys/types.h>
 962 #include <inttypes.h>],
 963   [intmax_t i = -1;],
 964   [gcc_cv_header_inttypes_h=yes],
 965   gcc_cv_header_inttypes_h=no)])
 966 AC_MSG_RESULT($gcc_cv_header_inttypes_h)
 967 if test $gcc_cv_header_inttypes_h = yes; then
 968   AC_DEFINE(HAVE_INTTYPES_H, 1,
 969         [Define if you have a working <inttypes.h> header file.])
 970 fi
 971
 972 dnl Disabled until we have a complete test for buggy enum bitfields.
 973 dnl gcc_AC_C_ENUM_BF_UNSIGNED
 974
 975 define(gcc_UNLOCKED_FUNCS, clearerr_unlocked feof_unlocked dnl
 976   ferror_unlocked fflush_unlocked fgetc_unlocked fgets_unlocked dnl
 977   fileno_unlocked fprintf_unlocked fputc_unlocked fputs_unlocked dnl
 978   fread_unlocked fwrite_unlocked getchar_unlocked getc_unlocked dnl
 979   putchar_unlocked putc_unlocked)
 980 AC_CHECK_FUNCS(times clock dup2 kill getrlimit setrlimit atoll atoq \
 981         sysconf strsignal getrusage nl_langinfo scandir alphasort \
 982         gettimeofday mbstowcs wcswidth mmap mincore setlocale \
 983         gcc_UNLOCKED_FUNCS)
 984
 985 if test x$ac_cv_func_mbstowcs = xyes; then
 986   AC_CACHE_CHECK(whether mbstowcs works, gcc_cv_func_mbstowcs_works,
 987 [    AC_TRY_RUN([#include <stdlib.h>
 988 int main()
 989 {
 990   mbstowcs(0, "", 0);
 991   return 0;
 992 }],
 993     gcc_cv_func_mbstowcs_works=yes,
 994     gcc_cv_func_mbstowcs_works=no,
 995     gcc_cv_func_mbstowcs_works=yes)])
 996   if test x$gcc_cv_func_mbstowcs_works = xyes; then
 997     AC_DEFINE(HAVE_WORKING_MBSTOWCS, 1,
 998   [Define this macro if mbstowcs does not crash when its
 999    first argument is NULL.])
1000   fi
1001 fi
1002
1003 AC_CHECK_TYPE(ssize_t, int)
1004
1005 # Try to determine the array type of the second argument of getgroups
1006 # for the target system (int or gid_t).
1007 AC_TYPE_GETGROUPS
1008 if test "${target}" = "${build}"; then
1009   TARGET_GETGROUPS_T=$ac_cv_type_getgroups
1010 else
1011   case "${target}" in
1012         # This condition may need some tweaking.  It should include all
1013         # targets where the array type of the second argument of getgroups
1014         # is int and the type of gid_t is not equivalent to int.
1015         *-*-sunos* | *-*-ultrix*)
1016                 TARGET_GETGROUPS_T=int
1017                 ;;
1018         *)
1019                 TARGET_GETGROUPS_T=gid_t
1020                 ;;
1021   esac
1022 fi
1023 AC_SUBST(TARGET_GETGROUPS_T)
1024
1025 gcc_AC_FUNC_PRINTF_PTR
1026 gcc_AC_FUNC_MMAP_BLACKLIST
1027
1028 case "${host}" in
1029 *-*-*vms*)
1030   # Under VMS, vfork works very differently than on Unix. The standard test
1031   # won't work, and it isn't easily adaptable. It makes more sense to
1032   # just force it.
1033   ac_cv_func_vfork_works=yes
1034   ;;
1035 esac
1036 AC_FUNC_VFORK
1037
1038 AM_ICONV
1039 # Until we have in-tree GNU iconv:
1040 LIBICONV_DEP=
1041 AC_SUBST(LIBICONV_DEP)
1042
1043 AM_LC_MESSAGES
1044
1045 AM_LANGINFO_CODESET
1046
1047 # We will need to find libiberty.h and ansidecl.h
1048 saved_CFLAGS="$CFLAGS"
1049 CFLAGS="$CFLAGS -I${srcdir} -I${srcdir}/../include"
1050 gcc_AC_CHECK_DECLS(getenv atol sbrk abort atof getcwd getwd strsignal \
1051         strstr errno snprintf vsnprintf vasprintf malloc realloc calloc \
1052         free basename getopt clock getpagesize gcc_UNLOCKED_FUNCS, , ,[
1053 #include "ansidecl.h"
1054 #include "system.h"])
1055
1056 gcc_AC_CHECK_DECLS(getrlimit setrlimit getrusage, , ,[
1057 #include "ansidecl.h"
1058 #include "system.h"
1059 #ifdef HAVE_SYS_RESOURCE_H
1060 #include <sys/resource.h>
1061 #endif
1062 ])
1063
1064 AC_TRY_COMPILE([
1065 #include "ansidecl.h"
1066 #include "system.h"
1067 #ifdef HAVE_SYS_RESOURCE_H
1068 #include <sys/resource.h>
1069 #endif
1070 ],[rlim_t l = 0;],,[AC_DEFINE([rlim_t],[long],
1071 [Define to \`long' if <sys/resource.h> doesn't define.])])
1072
1073 # On AIX 5.2, <ldfcn.h> conflicts with <fcntl.h>, as both define incompatible
1074 # FREAD and FWRITE macros.  Fortunately, for GCC's single usage of ldgetname
1075 # in collect2.c, <fcntl.h> isn't visible, but the configure test below needs
1076 # to undef these macros to get the correct value for HAVE_DECL_LDGETNAME.
1077 gcc_AC_CHECK_DECLS(ldgetname, , ,[
1078 #include "ansidecl.h"
1079 #include "system.h"
1080 #ifdef HAVE_LDFCN_H
1081 #undef FREAD
1082 #undef FWRITE
1083 #include <ldfcn.h>
1084 #endif
1085 ])
1086
1087 gcc_AC_CHECK_DECLS(times, , ,[
1088 #include "ansidecl.h"
1089 #include "system.h"
1090 #ifdef HAVE_SYS_TIMES_H
1091 #include <sys/times.h>
1092 #endif
1093 ])
1094
1095 # More time-related stuff.
1096 AC_CACHE_CHECK(for struct tms, ac_cv_struct_tms, [
1097 AC_TRY_COMPILE([
1098 #include "ansidecl.h"
1099 #include "system.h"
1100 #ifdef HAVE_SYS_TIMES_H
1101 #include <sys/times.h>
1102 #endif
1103 ], [struct tms tms;], ac_cv_struct_tms=yes, ac_cv_struct_tms=no)])
1104 if test $ac_cv_struct_tms = yes; then
1105   AC_DEFINE(HAVE_STRUCT_TMS, 1,
1106   [Define if <sys/times.h> defines struct tms.])
1107 fi
1108
1109 # use gcc_cv_* here because this doesn't match the behavior of AC_CHECK_TYPE.
1110 # revisit after autoconf 2.50.
1111 AC_CACHE_CHECK(for clock_t, gcc_cv_type_clock_t, [
1112 AC_TRY_COMPILE([
1113 #include "ansidecl.h"
1114 #include "system.h"
1115 ], [clock_t x;], gcc_cv_type_clock_t=yes, gcc_cv_type_clock_t=no)])
1116 if test $gcc_cv_type_clock_t = yes; then
1117   AC_DEFINE(HAVE_CLOCK_T, 1,
1118   [Define if <time.h> defines clock_t.])
1119 fi
1120
1121 # Restore CFLAGS from before the gcc_AC_NEED_DECLARATIONS tests.
1122 CFLAGS="$saved_CFLAGS"
1123
1124 gcc_AC_INITFINI_ARRAY
1125
1126 # mkdir takes a single argument on some systems.
1127 gcc_AC_FUNC_MKDIR_TAKES_ONE_ARG
1128
1129 # File extensions
1130 manext='.1'
1131 objext='.o'
1132 AC_SUBST(manext)
1133 AC_SUBST(objext)
1134
1135 # With Setjmp/Longjmp based exception handling.
1136 AC_ARG_ENABLE(sjlj-exceptions,
1137 [  --enable-sjlj-exceptions
1138                           arrange to use setjmp/longjmp exception handling],
1139 [sjlj=`if test $enableval = yes; then echo 1; else echo 0; fi`
1140 AC_DEFINE_UNQUOTED(CONFIG_SJLJ_EXCEPTIONS, $sjlj,
1141   [Define 0/1 to force the choice for exception handling model.])])
1142
1143 # For platforms with the unwind ABI which includes an unwind library,
1144 # libunwind, we can choose to use the system libunwind.
1145 AC_ARG_WITH(system-libunwind,
1146 [  --with-system-libunwind use installed libunwind])
1147
1148 # --------------------------------------------------------
1149 # Build, host, and target specific configuration fragments
1150 # --------------------------------------------------------
1151
1152 # Collect build-machine-specific information.
1153 . ${srcdir}/config.build
1154
1155 # Collect host-machine-specific information.
1156 . ${srcdir}/config.host
1157
1158 target_gtfiles=
1159
1160 # Collect target-machine-specific information.
1161 . ${srcdir}/config.gcc
1162
1163 extra_objs="${host_extra_objs} ${extra_objs}"
1164 extra_gcc_objs="${host_extra_gcc_objs} ${extra_gcc_objs}"
1165
1166 # Default the target-machine variables that were not explicitly set.
1167 if test x"$tm_file" = x
1168 then tm_file=$cpu_type/$cpu_type.h; fi
1169
1170 if test x"$extra_headers" = x
1171 then extra_headers=; fi
1172
1173 if test x$md_file = x
1174 then md_file=$cpu_type/$cpu_type.md; fi
1175
1176 if test x$out_file = x
1177 then out_file=$cpu_type/$cpu_type.c; fi
1178
1179 if test x"$tmake_file" = x
1180 then tmake_file=$cpu_type/t-$cpu_type
1181 fi
1182
1183 if test x"$dwarf2" = xyes
1184 then tm_file="$tm_file tm-dwarf2.h"
1185 fi
1186
1187 # Say what files are being used for the output code and MD file.
1188 echo "Using \`$srcdir/config/$out_file' for machine-specific logic."
1189 echo "Using \`$srcdir/config/$md_file' as machine description file."
1190
1191 # If any of the xm_file variables contain nonexistent files, warn
1192 # about them and drop them.
1193
1194 bx=
1195 for x in $build_xm_file; do
1196   if    test -f $srcdir/config/$x
1197   then      bx="$bx $x"
1198   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1199   fi
1200 done
1201 build_xm_file="$bx"
1202
1203 hx=
1204 for x in $host_xm_file; do
1205   if    test -f $srcdir/config/$x
1206   then      hx="$hx $x"
1207   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1208   fi
1209 done
1210 host_xm_file="$hx"
1211
1212 tx=
1213 for x in $xm_file; do
1214   if    test -f $srcdir/config/$x
1215   then      tx="$tx $x"
1216   else      AC_MSG_WARN($srcdir/config/$x does not exist.)
1217   fi
1218 done
1219 xm_file="$tx"
1220
1221 count=a
1222 for f in $tm_file; do
1223         count=${count}x
1224 done
1225 if test $count = ax; then
1226         echo "Using \`$srcdir/config/$tm_file' as target machine macro file."
1227 else
1228         echo "Using the following target machine macro files:"
1229         for f in $tm_file; do
1230                 echo "  $srcdir/config/$f"
1231         done
1232 fi
1233
1234 if test x$need_64bit_hwint = xyes; then
1235         AC_DEFINE(NEED_64BIT_HOST_WIDE_INT, 1,
1236 [Define to 1 if HOST_WIDE_INT must be 64 bits wide (see hwint.h).])
1237 fi
1238
1239 if test x$use_long_long_for_widest_fast_int = xyes; then
1240         AC_DEFINE(USE_LONG_LONG_FOR_WIDEST_FAST_INT, 1,
1241 [Define to 1 if the 'long long' (or '__int64') is wider than 'long' but still
1242 efficiently supported by the host hardware.])
1243 fi
1244
1245 count=a
1246 for f in $host_xm_file; do
1247         count=${count}x
1248 done
1249 if test $count = a; then
1250         :
1251 elif test $count = ax; then
1252         echo "Using \`$srcdir/config/$host_xm_file' as host machine macro file."
1253 else
1254         echo "Using the following host machine macro files:"
1255         for f in $host_xm_file; do
1256                 echo "  $srcdir/config/$f"
1257         done
1258 fi
1259 echo "Using ${out_host_hook_obj} for host machine hooks."
1260
1261 if test "$host_xm_file" != "$build_xm_file"; then
1262         count=a
1263         for f in $build_xm_file; do
1264                 count=${count}x
1265         done
1266         if test $count = a; then
1267                 :
1268         elif test $count = ax; then
1269                 echo "Using \`$srcdir/config/$build_xm_file' as build machine macro file."
1270         else
1271                 echo "Using the following build machine macro files:"
1272                 for f in $build_xm_file; do
1273                         echo "  $srcdir/config/$f"
1274                 done
1275         fi
1276 fi
1277
1278 # ---------
1279 # Threading
1280 # ---------
1281
1282 # Check if a valid thread package
1283 case ${enable_threads} in
1284   "" | no)
1285     # No threads
1286     target_thread_file='single'
1287     ;;
1288   yes)
1289     # default
1290     target_thread_file='single'
1291     ;;
1292   aix | dce | gnat | irix | posix | posix95 | rtems | \
1293   single | solaris | vxworks | win32 )
1294     target_thread_file=${enable_threads}
1295     ;;
1296   *)
1297     echo "${enable_threads} is an unknown thread package" 1>&2
1298     exit 1
1299     ;;
1300 esac
1301
1302 if test x${thread_file} = x; then
1303   # No thread file set by target-specific clauses in config.gcc,
1304   # so use file chosen by default logic above
1305   thread_file=${target_thread_file}
1306 fi
1307
1308 # Make gthr-default.h if we have a thread file.
1309 gthread_flags=
1310 if test $thread_file != single; then
1311   rm -f gthr-default.h
1312   echo "#include \"gthr-${thread_file}.h\"" > gthr-default.h
1313   gthread_flags=-DHAVE_GTHR_DEFAULT
1314 fi
1315 AC_SUBST(gthread_flags)
1316
1317 # --------
1318 # UNSORTED
1319 # --------
1320
1321 use_cxa_atexit=no
1322 if test x$enable___cxa_atexit = xyes || \
1323    test x$enable___cxa_atexit = x -a x$default_use_cxa_atexit = xyes; then
1324   if test x$host = x$target; then
1325     AC_CHECK_FUNC(__cxa_atexit,[use_cxa_atexit=yes],
1326         [echo "__cxa_atexit can't be enabled on this target"])
1327   else
1328     # We can't check for __cxa_atexit when building a cross, so assume
1329     # it is available
1330     use_cxa_atexit=yes
1331   fi
1332   if test x$use_cxa_atexit = xyes; then
1333     AC_DEFINE(DEFAULT_USE_CXA_ATEXIT, 1,
1334       [Define if you want to use __cxa_atexit, rather than atexit, to
1335       register C++ destructors for local statics and global objects.
1336       This is essential for fully standards-compliant handling of
1337       destructors, but requires __cxa_atexit in libc.])
1338   fi
1339 fi
1340
1341 # Look for a file containing extra machine modes.
1342 if test -n "$extra_modes" && test -f $srcdir/config/$extra_modes; then
1343   extra_modes_file='$(srcdir)'/config/${extra_modes}
1344   AC_SUBST(extra_modes_file)
1345   AC_DEFINE_UNQUOTED(EXTRA_MODES_FILE, "config/$extra_modes",
1346   [Define to the name of a file containing a list of extra machine modes
1347    for this architecture.])
1348 fi
1349
1350 # Convert extra_options into a form suitable for Makefile use.
1351 extra_opt_files=
1352 for f in $extra_options; do
1353   extra_opt_files="$extra_opt_files \$(srcdir)/config/$f"
1354 done
1355 AC_SUBST(extra_opt_files)
1356
1357 # auto-host.h is the file containing items generated by autoconf and is
1358 # the first file included by config.h.
1359 # If host=build, it is correct to have bconfig include auto-host.h
1360 # as well.  If host!=build, we are in error and need to do more
1361 # work to find out the build config parameters.
1362 if test x$host = x$build
1363 then
1364         build_auto=auto-host.h
1365 else
1366         # We create a subdir, then run autoconf in the subdir.
1367         # To prevent recursion we set host and build for the new
1368         # invocation of configure to the build for this invocation
1369         # of configure.
1370         tempdir=build.$$
1371         rm -rf $tempdir
1372         mkdir $tempdir
1373         cd $tempdir
1374         case ${srcdir} in
1375         /* | [A-Za-z]:[\\/]* ) realsrcdir=${srcdir};;
1376         *) realsrcdir=../${srcdir};;
1377         esac
1378         saved_CFLAGS="${CFLAGS}"
1379         CC="${CC_FOR_BUILD}" CFLAGS="${CFLAGS_FOR_BUILD}" \
1380         ${realsrcdir}/configure \
1381                 --enable-languages=${enable_languages-all} \
1382                 --target=$target_alias --host=$build_alias --build=$build_alias
1383         CFLAGS="${saved_CFLAGS}"
1384
1385         # We just finished tests for the build machine, so rename
1386         # the file auto-build.h in the gcc directory.
1387         mv auto-host.h ../auto-build.h
1388         cd ..
1389         rm -rf $tempdir
1390         build_auto=auto-build.h
1391 fi
1392 AC_SUBST(build_subdir)
1393
1394 tm_file="${tm_file} defaults.h"
1395 tm_p_file="${tm_p_file} tm-preds.h"
1396 host_xm_file="auto-host.h ansidecl.h ${host_xm_file}"
1397 build_xm_file="${build_auto} ansidecl.h ${build_xm_file}"
1398 # We don't want ansidecl.h in target files, write code there in ISO/GNU C.
1399 # put this back in temporarily.
1400 xm_file="auto-host.h ansidecl.h ${xm_file}"
1401
1402 # --------
1403 # UNSORTED
1404 # --------
1405
1406 changequote(,)dnl
1407 # Compile in configure arguments.
1408 if test -f configargs.h ; then
1409         # Being re-configured.
1410         gcc_config_arguments=`grep configuration_arguments configargs.h | sed -e 's/.*"\([^"]*\)".*/\1/'`
1411         gcc_config_arguments="$gcc_config_arguments : (reconfigured) $TOPLEVEL_CONFIGURE_ARGUMENTS"
1412 else
1413         gcc_config_arguments="$TOPLEVEL_CONFIGURE_ARGUMENTS"
1414 fi
1415
1416 # Double all backslashes and backslash all quotes to turn
1417 # gcc_config_arguments into a C string.
1418 sed -e 's/\\/\\\\/g; s/"/\\"/g' <<EOF >conftest.out
1419 $gcc_config_arguments
1420 EOF
1421 gcc_config_arguments_str=`cat conftest.out`
1422 rm -f conftest.out
1423
1424 cat > configargs.h <<EOF
1425 /* Generated automatically. */
1426 static const char configuration_arguments[] = "$gcc_config_arguments_str";
1427 static const char thread_model[] = "$thread_file";
1428
1429 static const struct {
1430   const char *name, *value;
1431 } configure_default_options[] = $configure_default_options;
1432 EOF
1433 changequote([,])dnl
1434
1435 # Internationalization
1436 ZW_GNU_GETTEXT_SISTER_DIR
1437
1438 # If LIBINTL contains LIBICONV, then clear LIBICONV so we don't get
1439 # -liconv on the link line twice.
1440 case "$LIBINTL" in *$LIBICONV*)
1441         LIBICONV= ;;
1442 esac
1443
1444 # Windows32 Registry support for specifying GCC installation paths.
1445 AC_ARG_ENABLE(win32-registry,
1446 [  --disable-win32-registry
1447                           disable lookup of installation paths in the
1448                           Registry on Windows hosts
1449   --enable-win32-registry enable registry lookup (default)
1450   --enable-win32-registry=KEY
1451                           use KEY instead of GCC version as the last portion
1452                           of the registry key],,)
1453
1454 case $host_os in
1455   win32 | pe | cygwin* | mingw32* | uwin*)
1456     if test "x$enable_win32_registry" != xno; then
1457       AC_SEARCH_LIBS(RegOpenKeyExA, advapi32,, [enable_win32_registry=no])
1458     fi
1459
1460     if test "x$enable_win32_registry" != xno; then
1461       AC_DEFINE(ENABLE_WIN32_REGISTRY, 1,
1462   [Define to 1 if installation paths should be looked up in the Windows
1463    Registry. Ignored on non-Windows hosts.])
1464
1465       if test "x$enable_win32_registry" != xyes \
1466          && test "x$enable_win32_registry" != x; then
1467         AC_DEFINE_UNQUOTED(WIN32_REGISTRY_KEY, "$enable_win32_registry",
1468   [Define to be the last component of the Windows registry key under which
1469    to look for installation paths.  The full key used will be
1470    HKEY_LOCAL_MACHINE/SOFTWARE/Free Software Foundation/{WIN32_REGISTRY_KEY}.
1471    The default is the GCC version number.])
1472       fi
1473     fi
1474   ;;
1475 esac
1476
1477 # Get an absolute path to the GCC top-level source directory
1478 holddir=`${PWDCMD-pwd}`
1479 cd $srcdir
1480 topdir=`${PWDCMD-pwd}`
1481 cd $holddir
1482
1483 # Conditionalize the makefile for this host machine.
1484 xmake_file=
1485 for f in ${host_xmake_file}
1486 do
1487         if test -f ${srcdir}/config/$f
1488         then
1489                 xmake_file="${xmake_file} \$(srcdir)/config/$f"
1490         fi
1491 done
1492
1493 # Conditionalize the makefile for this target machine.
1494 tmake_file_=
1495 for f in ${tmake_file}
1496 do
1497         if test -f ${srcdir}/config/$f
1498         then
1499                 tmake_file_="${tmake_file_} \$(srcdir)/config/$f"
1500         fi
1501 done
1502 tmake_file="${tmake_file_}"
1503
1504 # If the host doesn't support symlinks, modify CC in
1505 # FLAGS_TO_PASS so CC="stage1/xgcc -Bstage1/" works.
1506 # Otherwise, we can use "CC=$(CC)".
1507 rm -f symtest.tem
1508 case "$LN_S" in
1509         *-s*)
1510                 cc_set_by_configure="\$(CC)"
1511                 quoted_cc_set_by_configure="\$(CC)"
1512                 stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1513                 quoted_stage_prefix_set_by_configure="\$(STAGE_PREFIX)"
1514                 ;;
1515         *)
1516                 cc_set_by_configure="\`case '\$(CC)' in stage*) echo '\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\$(CC)';; esac\`"
1517                 quoted_cc_set_by_configure="\\\`case '\\\$(CC)' in stage*) echo '\\\$(CC)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(CC)';; esac\\\`"
1518                 stage_prefix_set_by_configure="\`case '\$(STAGE_PREFIX)' in stage*) echo '\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\$(STAGE_PREFIX)';; esac\`"
1519                 quoted_stage_prefix_set_by_configure="\\\`case '\\\$(STAGE_PREFIX)' in stage*) echo '\\\$(STAGE_PREFIX)' | sed -e 's|stage|../stage|g';; *) echo '\\\$(STAGE_PREFIX)';; esac\\\`"
1520                 ;;
1521 esac
1522
1523 # This is a terrible hack which will go away some day.
1524 host_cc_for_libada=${CC}
1525 AC_SUBST(host_cc_for_libada)
1526
1527 out_object_file=`basename $out_file .c`.o
1528
1529 tm_file_list="options.h"
1530 tm_include_list="options.h"
1531 for f in $tm_file; do
1532   case $f in
1533     defaults.h )
1534        tm_file_list="${tm_file_list} \$(srcdir)/$f"
1535        tm_include_list="${tm_include_list} $f"
1536        ;;
1537     * )
1538        tm_file_list="${tm_file_list} \$(srcdir)/config/$f"
1539        tm_include_list="${tm_include_list} config/$f"
1540        ;;
1541   esac
1542 done
1543
1544 tm_p_file_list=
1545 tm_p_include_list=
1546 for f in $tm_p_file; do
1547   case $f in
1548     tm-preds.h )
1549        tm_p_file_list="${tm_p_file_list} $f"
1550        tm_p_include_list="${tm_p_include_list} $f"
1551        ;;
1552     * )
1553        tm_p_file_list="${tm_p_file_list} \$(srcdir)/config/$f"
1554        tm_p_include_list="${tm_p_include_list} config/$f"
1555   esac
1556 done
1557
1558 xm_file_list=
1559 xm_include_list=
1560 for f in $xm_file; do
1561   case $f in
1562     ansidecl.h )
1563        xm_file_list="${xm_file_list} \$(srcdir)/../include/$f"
1564        xm_include_list="${xm_include_list} $f"
1565        ;;
1566     auto-host.h )
1567        xm_file_list="${xm_file_list} $f"
1568        xm_include_list="${xm_include_list} $f"
1569        ;;
1570     * )
1571        xm_file_list="${xm_file_list} \$(srcdir)/config/$f"
1572        xm_include_list="${xm_include_list} config/$f"
1573        ;;
1574   esac
1575 done
1576
1577 host_xm_file_list=
1578 host_xm_include_list=
1579 for f in $host_xm_file; do
1580   case $f in
1581     ansidecl.h )
1582        host_xm_file_list="${host_xm_file_list} \$(srcdir)/../include/$f"
1583        host_xm_include_list="${host_xm_include_list} $f"
1584        ;;
1585     auto-host.h )
1586        host_xm_file_list="${host_xm_file_list} $f"
1587        host_xm_include_list="${host_xm_include_list} $f"
1588        ;;
1589     * )
1590        host_xm_file_list="${host_xm_file_list} \$(srcdir)/config/$f"
1591        host_xm_include_list="${host_xm_include_list} config/$f"
1592        ;;
1593   esac
1594 done
1595
1596 build_xm_file_list=
1597 for f in $build_xm_file; do
1598   case $f in
1599     ansidecl.h )
1600        build_xm_file_list="${build_xm_file_list} \$(srcdir)/../include/$f"
1601        build_xm_include_list="${build_xm_include_list} $f"
1602        ;;
1603     auto-build.h | auto-host.h )
1604        build_xm_file_list="${build_xm_file_list} $f"
1605        build_xm_include_list="${build_xm_include_list} $f"
1606        ;;
1607     * )
1608        build_xm_file_list="${build_xm_file_list} \$(srcdir)/config/$f"
1609        build_xm_include_list="${build_xm_include_list} config/$f"
1610        ;;
1611   esac
1612 done
1613
1614 # Define macro CROSS_COMPILE in compilation if this is a cross-compiler.
1615 # Also use all.cross instead of all.internal and adjust SYSTEM_HEADER_DIR.
1616 CROSS=                                          AC_SUBST(CROSS)
1617 ALL=all.internal                                AC_SUBST(ALL)
1618 SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)' AC_SUBST(SYSTEM_HEADER_DIR)
1619 if test x$host != x$target
1620 then
1621         CROSS="-DCROSS_COMPILE"
1622         ALL=all.cross
1623         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1624         case "$host","$target" in
1625         # Darwin crosses can use the host system's libraries and headers,
1626         # because of the fat library support.  Of course, it must be the
1627         # same version of Darwin on both sides.  Allow the user to
1628         # just say --target=foo-darwin without a version number to mean
1629         # "the version on this system".
1630             *-*-darwin*,*-*-darwin*)
1631                 hostos=`echo $host | sed 's/.*-darwin/darwin/'`
1632                 targetos=`echo $target | sed 's/.*-darwin/darwin/'`
1633                 if test $hostos = $targetos -o $targetos = darwin ; then
1634                     CROSS=
1635                     SYSTEM_HEADER_DIR='$(NATIVE_SYSTEM_HEADER_DIR)'
1636                     with_headers=yes
1637                 fi
1638                 ;;
1639
1640             i?86-*-*,x86_64-*-* \
1641             | powerpc*-*-*,powerpc64*-*-*)
1642                 CROSS="$CROSS -DNATIVE_CROSS" ;;
1643         esac
1644 elif test "x$TARGET_SYSTEM_ROOT" != x; then
1645         # This is just $(TARGET_SYSTEM_ROOT)$(NATIVE_SYSTEM_HEADER_DIR)
1646         SYSTEM_HEADER_DIR='$(CROSS_SYSTEM_HEADER_DIR)'
1647 fi
1648
1649 # If this is a cross-compiler that does not
1650 # have its own set of headers then define
1651 # inhibit_libc
1652
1653 # If this is using newlib, without having the headers available now,
1654 # then define inhibit_libc in LIBGCC2_CFLAGS.
1655 # This prevents libgcc2 from containing any code which requires libc
1656 # support.
1657 inhibit_libc=
1658 if { { test x$host != x$target && test "x$with_sysroot" = x ; } ||
1659        test x$with_newlib = xyes ; } &&
1660      { test "x$with_headers" = x || test "x$with_headers" = xno ; } ; then
1661        inhibit_libc=-Dinhibit_libc
1662 fi
1663 AC_SUBST(inhibit_libc)
1664
1665 # When building gcc with a cross-compiler, we need to adjust things so
1666 # that the generator programs are still built with the native compiler.
1667 # Also, we cannot run fixincludes or fix-header.
1668
1669 # These are the normal (build=host) settings:
1670 CC_FOR_BUILD='$(CC)'            AC_SUBST(CC_FOR_BUILD)
1671 BUILD_CFLAGS='$(ALL_CFLAGS)'    AC_SUBST(BUILD_CFLAGS)
1672 STMP_FIXINC=stmp-fixinc         AC_SUBST(STMP_FIXINC)
1673
1674 # Possibly disable fixproto, on a per-target basis.
1675 case ${use_fixproto} in
1676   no)
1677     STMP_FIXPROTO=
1678     ;;
1679   yes)
1680     STMP_FIXPROTO=stmp-fixproto
1681     ;;
1682 esac
1683 AC_SUBST(STMP_FIXPROTO)
1684
1685 # And these apply if build != host, or we are generating coverage data
1686 if test x$build != x$host || test "x$coverage_flags" != x
1687 then
1688     BUILD_CFLAGS='$(INTERNAL_CFLAGS) $(T_CFLAGS) $(CFLAGS_FOR_BUILD)'
1689
1690     if test "x$TARGET_SYSTEM_ROOT" = x; then
1691         if test "x$STMP_FIXPROTO" != x; then
1692           STMP_FIXPROTO=stmp-install-fixproto
1693         fi
1694     fi
1695 fi
1696
1697 # Expand extra_headers to include complete path.
1698 # This substitutes for lots of t-* files.
1699 extra_headers_list=
1700 # Prepend $(srcdir)/config/${cpu_type}/ to every entry in extra_headers.
1701 for file in ${extra_headers} ; do
1702   extra_headers_list="${extra_headers_list} \$(srcdir)/config/${cpu_type}/${file}"
1703 done
1704
1705 # Define collect2 in Makefile.
1706 case $host_can_use_collect2 in
1707   no) collect2= ;;
1708   *) collect2='collect2$(exeext)' ;;
1709 esac
1710 AC_SUBST([collect2])
1711
1712 # Add a definition of USE_COLLECT2 if system wants one.
1713 case $use_collect2 in
1714   no) use_collect2= ;;
1715   "") ;;
1716   *)
1717     host_xm_defines="${host_xm_defines} USE_COLLECT2"
1718     xm_defines="${xm_defines} USE_COLLECT2"
1719     case $host_can_use_collect2 in
1720       no)
1721         AC_MSG_ERROR([collect2 is required but cannot be built on this system])
1722         ;;
1723     esac
1724     ;;
1725 esac
1726
1727 # ---------------------------
1728 # Assembler & linker features
1729 # ---------------------------
1730
1731 # Identify the assembler which will work hand-in-glove with the newly
1732 # built GCC, so that we can examine its features.  This is the assembler
1733 # which will be driven by the driver program.
1734 #
1735 # If build != host, and we aren't building gas in-tree, we identify a
1736 # build->target assembler and hope that it will have the same features
1737 # as the host->target assembler we'll be using.
1738 AC_MSG_CHECKING(what assembler to use)
1739 in_tree_gas=no
1740 gcc_cv_as=
1741 gcc_cv_gas_major_version=
1742 gcc_cv_gas_minor_version=
1743 gcc_cv_as_gas_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/gas
1744 if test -x "$DEFAULT_ASSEMBLER"; then
1745         gcc_cv_as="$DEFAULT_ASSEMBLER"
1746 elif test -x as$build_exeext; then
1747         # Build using assembler in the current directory.
1748         gcc_cv_as=./as$build_exeext
1749 elif test -f $gcc_cv_as_gas_srcdir/configure.in \
1750      && test -f ../gas/Makefile \
1751      && test x$build = x$host; then
1752   # Single tree build which includes gas.  We want to prefer it
1753   # over whatever linker top-level may have detected, since
1754   # we'll use what we're building after installation anyway.
1755   in_tree_gas=yes
1756   _gcc_COMPUTE_GAS_VERSION
1757   rm -f as$build_exeext
1758   $LN_S ../gas/as-new$build_exeext as$build_exeext 2>/dev/null
1759   in_tree_gas_is_elf=no
1760   if grep 'obj_format = elf' ../gas/Makefile > /dev/null \
1761      || (grep 'obj_format = multi' ../gas/Makefile \
1762          && grep 'extra_objects =.* obj-elf' ../gas/Makefile) > /dev/null
1763   then
1764     in_tree_gas_is_elf=yes
1765   fi
1766 m4_pattern_allow([AS_FOR_TARGET])dnl
1767 elif test -x "$AS_FOR_TARGET"; then
1768         gcc_cv_as="$AS_FOR_TARGET"
1769 elif test -x "$AS" && test x$host = x$target; then
1770         gcc_cv_as="$AS"
1771 fi
1772
1773 gcc_version=`cat $srcdir/BASE-VER`
1774
1775 if test "x$gcc_cv_as" = x; then
1776         # Search the same directories that the installed compiler will
1777         # search.  Else we may find the wrong assembler and lose.  If we
1778         # do not find a suitable assembler binary, then try the user's
1779         # path.
1780         #
1781         # Also note we have to check MD_EXEC_PREFIX before checking the
1782         # user's path.  Unfortunately, there is no good way to get at the
1783         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1784         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1785         # to be fixed as part of the make/configure rewrite too.
1786
1787         if test "x$exec_prefix" = xNONE; then
1788                 if test "x$prefix" = xNONE; then
1789                         test_prefix=/usr/local
1790                 else
1791                         test_prefix=$prefix
1792                 fi
1793         else
1794                 test_prefix=$exec_prefix
1795         fi
1796
1797         # If the loop below does not find an assembler, then use whatever
1798         # one we can find in the users's path.  We are looking for a
1799         # ${build} -> ${target} assembler.
1800         if test "x$program_prefix" != xNONE; then
1801                 gcc_cv_as=${program_prefix}as$build_exeext
1802         elif test x$build != x$host && test x$build != x$target; then
1803                 gcc_cv_as=${target_noncanonical}-as$build_exeext
1804         else
1805                 gcc_cv_as=`echo as | sed "${program_transform_name}"`$build_exeext
1806         fi
1807
1808         if test x$host = x$build; then
1809             test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1810                        $test_prefix/libexec/gcc/$target_noncanonical \
1811                        /usr/lib/gcc/$target_noncanonical/$gcc_version \
1812                        /usr/lib/gcc/$target_noncanonical \
1813                        $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1814                        $test_prefix/$target_noncanonical/bin"
1815         else
1816             test_dirs=
1817         fi
1818
1819         if test x$build = x$target; then
1820             test_dirs="$test_dirs \
1821                    /usr/libexec \
1822                    /usr/ccs/gcc \
1823                    /usr/ccs/bin \
1824                    /udk/usr/ccs/bin \
1825                    /bsd43/usr/lib/cmplrs/cc \
1826                    /usr/cross64/usr/bin \
1827                    /usr/lib/cmplrs/cc \
1828                    /sysv/usr/lib/cmplrs/cc \
1829                    /svr4/usr/lib/cmplrs/cc \
1830                    /usr/bin"
1831         fi
1832
1833         for dir in $test_dirs; do
1834                 if test -x $dir/as$build_exeext; then
1835                         gcc_cv_as=$dir/as$build_exeext
1836                         break;
1837                 fi
1838         done
1839 fi
1840 case $in_tree_gas in
1841   yes)
1842     AC_MSG_RESULT("newly built gas")
1843     ;;
1844   no)
1845     AC_MSG_RESULT($gcc_cv_as)
1846     ;;
1847 esac
1848
1849 # Identify the linker which will work hand-in-glove with the newly
1850 # built GCC, so that we can examine its features.  This is the linker
1851 # which will be driven by the driver program.
1852 #
1853 # If build != host, and we aren't building gas in-tree, we identify a
1854 # build->target linker and hope that it will have the same features
1855 # as the host->target linker we'll be using.
1856 AC_MSG_CHECKING(what linker to use)
1857 in_tree_ld=no
1858 gcc_cv_ld=
1859 gcc_cv_gld_major_version=
1860 gcc_cv_gld_minor_version=
1861 gcc_cv_ld_gld_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/ld
1862 gcc_cv_ld_bfd_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/bfd
1863 if test -x "$DEFAULT_LINKER"; then
1864         gcc_cv_ld="$DEFAULT_LINKER"
1865 elif test -x collect-ld$build_exeext; then
1866         # Build using linker in the current directory.
1867         gcc_cv_ld=./collect-ld$build_exeext
1868 elif test -f $gcc_cv_ld_gld_srcdir/configure.in \
1869      && test -f ../ld/Makefile \
1870      && test x$build = x$host; then
1871         # Single tree build which includes ld.  We want to prefer it
1872         # over whatever linker top-level may have detected, since
1873         # we'll use what we're building after installation anyway.
1874         in_tree_ld=yes
1875         in_tree_ld_is_elf=no
1876         if (grep 'EMUL = .*elf' ../ld/Makefile \
1877             || grep 'EMUL = .*linux' ../ld/Makefile \
1878             || grep 'EMUL = .*lynx' ../ld/Makefile) > /dev/null; then
1879           in_tree_ld_is_elf=yes
1880         fi
1881         for f in $gcc_cv_ld_bfd_srcdir/configure $gcc_cv_ld_gld_srcdir/configure $gcc_cv_ld_gld_srcdir/configure.in $gcc_cv_ld_gld_srcdir/Makefile.in
1882         do
1883 changequote(,)dnl
1884                 gcc_cv_gld_version=`sed -n -e 's/^[     ]*\(VERSION=[0-9]*\.[0-9]*.*\)/\1/p' < $f`
1885 changequote([,])dnl
1886                 if test x$gcc_cv_gld_version != x; then
1887                         break
1888                 fi
1889         done
1890 changequote(,)dnl
1891         gcc_cv_gld_major_version=`expr "$gcc_cv_gld_version" : "VERSION=\([0-9]*\)"`
1892         gcc_cv_gld_minor_version=`expr "$gcc_cv_gld_version" : "VERSION=[0-9]*\.\([0-9]*\)"`
1893 changequote([,])dnl
1894         rm -f collect-ld$build_exeext
1895         $LN_S ../ld/ld-new$build_exeext collect-ld$build_exeext 2>/dev/null
1896 elif test -x "$LD_FOR_TARGET"; then
1897         gcc_cv_ld="$LD_FOR_TARGET"
1898 elif test -x "$LD" && test x$host = x$target; then
1899         gcc_cv_ld="$LD"
1900 fi
1901
1902 if test "x$gcc_cv_ld" = x; then
1903         # Search the same directories that the installed compiler will
1904         # search.  Else we may find the wrong linker and lose.  If we
1905         # do not find a suitable linker binary, then try the user's
1906         # path.
1907         #
1908         # Also note we have to check MD_EXEC_PREFIX before checking the
1909         # user's path.  Unfortunately, there is no good way to get at the
1910         # value of MD_EXEC_PREFIX here.  So we do a brute force search
1911         # through all the known MD_EXEC_PREFIX values.  Ugh.  This needs
1912         # to be fixed as part of the make/configure rewrite too.
1913
1914         if test "x$exec_prefix" = xNONE; then
1915                 if test "x$prefix" = xNONE; then
1916                         test_prefix=/usr/local
1917                 else
1918                         test_prefix=$prefix
1919                 fi
1920         else
1921                 test_prefix=$exec_prefix
1922         fi
1923
1924         # If the loop below does not find a linker, then use whatever
1925         # one we can find in the users's path.  We are looking for a
1926         # ${build} -> ${target} linker.
1927         if test "x$program_prefix" != xNONE; then
1928                 gcc_cv_ld=${program_prefix}ld$build_exeext
1929         elif test x$build != x$host && test x$build != x$target; then
1930                 gcc_cv_ld=${target_noncanonical}-ld$build_exeext
1931         else
1932                 gcc_cv_ld=`echo ld | sed "${program_transform_name}"`$build_exeext
1933         fi
1934
1935         if test x$host = x$build; then
1936             test_dirs="$test_prefix/libexec/gcc/$target_noncanonical/$gcc_version \
1937                        $test_prefix/libexec/gcc/$target_noncanonical \
1938                        /usr/lib/gcc/$target_noncanonical/$gcc_version \
1939                        /usr/lib/gcc/$target_noncanonical \
1940                        $test_prefix/$target_noncanonical/bin/$target_noncanonical/$gcc_version \
1941                        $test_prefix/$target_noncanonical/bin"
1942         else
1943             test_dirs=
1944         fi
1945
1946         if test x$build = x$target; then
1947             test_dirs="$test_dirs \
1948                    /usr/libexec \
1949                    /usr/ccs/gcc \
1950                    /usr/ccs/bin \
1951                    /udk/usr/ccs/bin \
1952                    /bsd43/usr/lib/cmplrs/cc \
1953                    /usr/cross64/usr/bin \
1954                    /usr/lib/cmplrs/cc \
1955                    /sysv/usr/lib/cmplrs/cc \
1956                    /svr4/usr/lib/cmplrs/cc \
1957                    /usr/bin"
1958         fi
1959
1960         for dir in $test_dirs; do
1961                 if test -x $dir/ld$build_exeext; then
1962                         gcc_cv_ld=$dir/ld$build_exeext
1963                         break;
1964                 fi
1965         done
1966 fi
1967 case $in_tree_ld in
1968   yes)
1969     AC_MSG_RESULT("newly built ld")
1970     ;;
1971   no)
1972     AC_MSG_RESULT($gcc_cv_ld)
1973     ;;
1974 esac
1975
1976 # Figure out what nm we will be using.
1977 gcc_cv_binutils_srcdir=`echo $srcdir | sed -e 's,/gcc$,,'`/binutils
1978 AC_MSG_CHECKING(what nm to use)
1979 in_tree_nm=no
1980 if test -x nm$build_exeext; then
1981         gcc_cv_nm=./nm$build_exeext
1982 elif test -f $gcc_cv_binutils_srcdir/configure.in \
1983      && test -f ../binutils/Makefile; then
1984         # Single tree build which includes binutils.
1985         in_tree_nm=yes
1986         gcc_cv_nm=./nm$build_exeext
1987         rm -f nm$build_exeext
1988         $LN_S ../binutils/nm-new$build_exeext nm$build_exeext 2>/dev/null
1989 elif test "x$program_prefix" != xNONE; then
1990         gcc_cv_nm=${program_prefix}nm$build_exeext
1991 elif test x$build != x$host && test x$build != x$target; then
1992         gcc_cv_nm=${target_noncanonical}-nm$build_exeext
1993 else
1994         gcc_cv_nm=`echo nm | sed "${program_transform_name}"`$build_exeext
1995 fi
1996 case $in_tree_nm in
1997   yes) AC_MSG_RESULT("newly built nm") ;;
1998   no)  AC_MSG_RESULT($gcc_cv_nm) ;;
1999 esac
2000
2001 # Figure out what objdump we will be using.
2002 AC_MSG_CHECKING(what objdump to use)
2003 in_tree_objdump=no
2004 if test -x objdump$build_exeext; then
2005         gcc_cv_objdump=./objdump$build_exeext
2006 elif test -f $gcc_cv_binutils_srcdir/configure.in \
2007      && test -f ../binutils/Makefile; then
2008         # Single tree build which includes binutils.
2009         in_tree_objdump=yes
2010         gcc_cv_objdump=./objdump$build_exeext
2011         rm -f objdump$build_exeext
2012         $LN_S ../binutils/objdump$build_exeext objdump$build_exeext 2>/dev/null
2013 elif test "x$program_prefix" != xNONE; then
2014         gcc_cv_objdump=${program_prefix}objdump$build_exeext
2015 elif test x$build != x$host && test x$build != x$target; then
2016         gcc_cv_objdump=${target_noncanonical}-objdump$build_exeext
2017 else
2018         gcc_cv_objdump=`echo objdump | \
2019                 sed "${program_transform_name}"`$build_exeext
2020 fi
2021 case $in_tree_objdump in
2022   yes) AC_MSG_RESULT("newly built objdump") ;;
2023   no)  AC_MSG_RESULT($gcc_cv_objdump) ;;
2024 esac
2025
2026 # Figure out what assembler alignment features are present.
2027 gcc_GAS_CHECK_FEATURE([.balign and .p2align], gcc_cv_as_balign_and_p2align,
2028  [2,6,0],,
2029 [.balign 4
2030 .p2align 2],,
2031 [AC_DEFINE(HAVE_GAS_BALIGN_AND_P2ALIGN, 1,
2032   [Define if your assembler supports .balign and .p2align.])])
2033
2034 gcc_GAS_CHECK_FEATURE([.p2align with maximum skip], gcc_cv_as_max_skip_p2align,
2035  [2,8,0],,
2036  [.p2align 4,,7],,
2037 [AC_DEFINE(HAVE_GAS_MAX_SKIP_P2ALIGN, 1,
2038   [Define if your assembler supports specifying the maximum number
2039    of bytes to skip when using the GAS .p2align command.])])
2040
2041 gcc_GAS_CHECK_FEATURE([working .subsection -1], gcc_cv_as_subsection_m1,
2042  [elf,2,9,0],,
2043  [conftest_label1: .word 0
2044 .subsection -1
2045 conftest_label2: .word 0
2046 .previous],
2047  [if test x$gcc_cv_nm != x; then
2048     $gcc_cv_nm conftest.o | grep conftest_label1 > conftest.nm1
2049     $gcc_cv_nm conftest.o | grep conftest_label2 | sed -e 's/label2/label1/' > conftest.nm2
2050     if cmp conftest.nm1 conftest.nm2 > /dev/null 2>&1
2051     then :
2052     else gcc_cv_as_subsection_m1=yes
2053     fi
2054     rm -f conftest.nm1 conftest.nm2
2055   fi],
2056  [AC_DEFINE(HAVE_GAS_SUBSECTION_ORDERING, 1,
2057   [Define if your assembler supports .subsection and .subsection -1 starts
2058    emitting at the beginning of your section.])])
2059
2060 gcc_GAS_CHECK_FEATURE([.weak], gcc_cv_as_weak,
2061  [2,2,0],,
2062  [      .weak foobar],,
2063 [AC_DEFINE(HAVE_GAS_WEAK, 1, [Define if your assembler supports .weak.])])
2064
2065 gcc_GAS_CHECK_FEATURE([.nsubspa comdat], gcc_cv_as_nsubspa_comdat,
2066  [2,15,91],,
2067  [      .SPACE $TEXT$
2068         .NSUBSPA $CODE$,COMDAT],,
2069 [AC_DEFINE(HAVE_GAS_NSUBSPA_COMDAT, 1, [Define if your assembler supports .nsubspa comdat option.])])
2070
2071 # .hidden needs to be supported in both the assembler and the linker,
2072 # because GNU LD versions before 2.12.1 have buggy support for STV_HIDDEN.
2073 # This is irritatingly difficult to feature test for; we have to check the
2074 # date string after the version number.  If we've got an in-tree
2075 # ld, we don't know its patchlevel version, so we set the baseline at 2.13
2076 # to be safe.
2077 # The gcc_GAS_CHECK_FEATURE call just sets a cache variable.
2078 gcc_GAS_CHECK_FEATURE([.hidden], gcc_cv_as_hidden,
2079  [elf,2,13,0],,
2080 [       .hidden foobar
2081 foobar:])
2082
2083 AC_CACHE_CHECK(linker for .hidden support, gcc_cv_ld_hidden,
2084 [if test $in_tree_ld = yes ; then
2085   gcc_cv_ld_hidden=no
2086   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 13 -o "$gcc_cv_gld_major_version" -gt 2 \
2087      && test $in_tree_ld_is_elf = yes; then
2088      gcc_cv_ld_hidden=yes
2089   fi
2090 else
2091   gcc_cv_ld_hidden=yes
2092   ld_ver=`$gcc_cv_ld --version 2>/dev/null | sed 1q`
2093   if echo "$ld_ver" | grep GNU > /dev/null; then
2094 changequote(,)dnl
2095     ld_vers=`echo $ld_ver | sed -n \
2096         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2097         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2098         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)$,\1,p' \
2099         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\)[  ].*$,\1,p' \
2100         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[     ].*$,\1,p' \
2101         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[       ].*$,\1,p' \
2102         -e 's,^.*[       ]\([0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\.[0-9][0-9]*\)[   ].*$,\1,p'`
2103     ld_date=`echo $ld_ver | sed -n 's,^.*\([2-9][0-9][0-9][0-9]\)[-]*\([01][0-9]\)[-]*\([0-3][0-9]\).*$,\1\2\3,p'`
2104     ld_vers_major=`expr "$ld_vers" : '\([0-9]*\)'`
2105     ld_vers_minor=`expr "$ld_vers" : '[0-9]*\.\([0-9]*\)'`
2106     ld_vers_patch=`expr "$ld_vers" : '[0-9]*\.[0-9]*\.\([0-9]*\)'`
2107     if test 0"$ld_date" -lt 20020404; then
2108       if test -n "$ld_date"; then
2109         # If there was date string, but was earlier than 2002-04-04, fail
2110         gcc_cv_ld_hidden=no
2111       elif test -z "$ld_vers"; then
2112         # If there was no date string nor ld version number, something is wrong
2113         gcc_cv_ld_hidden=no
2114       else
2115         test -z "$ld_vers_patch" && ld_vers_patch=0
2116         if test "$ld_vers_major" -lt 2; then
2117           gcc_cv_ld_hidden=no
2118         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 12; then
2119           gcc_cv_ld_hidden="no"
2120         elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -eq 12 -a "$ld_vers_patch" -eq 0; then
2121           gcc_cv_ld_hidden=no
2122         fi
2123       fi
2124 changequote([,])dnl
2125     fi
2126   else
2127     case "${target}" in
2128       hppa64*-*-hpux* | ia64*-*-hpux*)
2129         gcc_cv_ld_hidden=yes
2130         ;;
2131       *)
2132         gcc_cv_ld_hidden=no
2133         ;;
2134     esac
2135   fi
2136 fi])
2137 libgcc_visibility=no
2138 AC_SUBST(libgcc_visibility)
2139 GCC_TARGET_TEMPLATE([HAVE_GAS_HIDDEN])
2140 if test $gcc_cv_as_hidden = yes && test $gcc_cv_ld_hidden = yes; then
2141   libgcc_visibility=yes
2142   AC_DEFINE(HAVE_GAS_HIDDEN, 1,
2143   [Define if your assembler and linker support .hidden.])
2144 fi
2145
2146 # Check if we have .[us]leb128, and support symbol arithmetic with it.
2147 gcc_GAS_CHECK_FEATURE([.sleb128 and .uleb128], gcc_cv_as_leb128,
2148   [elf,2,11,0],,
2149 [       .data
2150         .uleb128 L2 - L1
2151 L1:
2152         .uleb128 1280
2153         .sleb128 -1010
2154 L2:],
2155  [# GAS versions before 2.11 do not support uleb128,
2156   # despite appearing to.
2157   # ??? There exists an elf-specific test that will crash
2158   # the assembler.  Perhaps it's better to figure out whether
2159   # arbitrary sections are supported and try the test.
2160   as_ver=`$gcc_cv_as --version 2>/dev/null | sed 1q`
2161   if echo "$as_ver" | grep GNU > /dev/null; then
2162 changequote(,)dnl
2163     as_ver=`echo $as_ver | sed -e 's/GNU assembler \([0-9.][0-9.]*\).*/\1/'`
2164     as_major=`echo $as_ver | sed 's/\..*//'`
2165     as_minor=`echo $as_ver | sed 's/[^.]*\.\([0-9]*\).*/\1/'`
2166 changequote([,])dnl
2167     if test $as_major -eq 2 && test $as_minor -lt 11
2168     then :
2169     else gcc_cv_as_leb128=yes
2170     fi
2171   fi],
2172   [AC_DEFINE(HAVE_AS_LEB128, 1,
2173     [Define if your assembler supports .sleb128 and .uleb128.])])
2174
2175 # GAS versions up to and including 2.11.0 may mis-optimize
2176 # .eh_frame data.
2177 gcc_GAS_CHECK_FEATURE(eh_frame optimization, gcc_cv_as_eh_frame,
2178   [elf,2,12,0],,
2179 [       .text
2180 .LFB1:
2181         .4byte  0
2182 .L1:
2183         .4byte  0
2184 .LFE1:
2185         .section        .eh_frame,"aw",@progbits
2186 __FRAME_BEGIN__:
2187         .4byte  .LECIE1-.LSCIE1
2188 .LSCIE1:
2189         .4byte  0x0
2190         .byte   0x1
2191         .ascii "z\0"
2192         .byte   0x1
2193         .byte   0x78
2194         .byte   0x1a
2195         .byte   0x0
2196         .byte   0x4
2197         .4byte  1
2198         .p2align 1
2199 .LECIE1:
2200 .LSFDE1:
2201         .4byte  .LEFDE1-.LASFDE1
2202 .LASFDE1:
2203         .4byte  .LASFDE1-__FRAME_BEGIN__
2204         .4byte  .LFB1
2205         .4byte  .LFE1-.LFB1
2206         .byte   0x4
2207         .4byte  .LFE1-.LFB1
2208         .byte   0x4
2209         .4byte  .L1-.LFB1
2210 .LEFDE1:],
2211 [  dnl # For autoconf 2.5x, must protect trailing spaces with @&t@.
2212 cat > conftest.lit <<EOF
2213  0000 10000000 00000000 017a0001 781a0004  .........z..x...
2214  0010 01000000 12000000 18000000 00000000  ................
2215  0020 08000000 04080000 0044               .........D      @&t@
2216 EOF
2217 cat > conftest.big <<EOF
2218  0000 00000010 00000000 017a0001 781a0004  .........z..x...
2219  0010 00000001 00000012 00000018 00000000  ................
2220  0020 00000008 04000000 0844               .........D      @&t@
2221 EOF
2222   # If the assembler didn't choke, and we can objdump,
2223   # and we got the correct data, then succeed.
2224   if test x$gcc_cv_objdump != x \
2225   && $gcc_cv_objdump -s -j .eh_frame conftest.o 2>/dev/null \
2226      | tail -3 > conftest.got \
2227   && { cmp conftest.lit conftest.got > /dev/null 2>&1 \
2228     || cmp conftest.big conftest.got > /dev/null 2>&1; }
2229   then
2230     gcc_cv_as_eh_frame=yes
2231   elif AC_TRY_COMMAND($gcc_cv_as -o conftest.o --traditional-format /dev/null); then
2232     gcc_cv_as_eh_frame=buggy
2233   else
2234     # Uh oh, what do we do now?
2235     gcc_cv_as_eh_frame=no
2236   fi])
2237
2238 if test $gcc_cv_as_eh_frame = buggy; then
2239   AC_DEFINE(USE_AS_TRADITIONAL_FORMAT, 1,
2240   [Define if your assembler mis-optimizes .eh_frame data.])
2241 fi
2242
2243 gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2244  [elf,2,12,0], [--fatal-warnings],
2245  [.section .rodata.str, "aMS", @progbits, 1])
2246 if test $gcc_cv_as_shf_merge = no; then
2247   gcc_GAS_CHECK_FEATURE(section merging support, gcc_cv_as_shf_merge,
2248     [elf,2,12,0], [--fatal-warnings],
2249     [.section .rodata.str, "aMS", %progbits, 1])
2250 fi
2251 AC_DEFINE_UNQUOTED(HAVE_GAS_SHF_MERGE,
2252   [`if test $gcc_cv_as_shf_merge = yes; then echo 1; else echo 0; fi`],
2253 [Define 0/1 if your assembler supports marking sections with SHF_MERGE flag.])
2254
2255 gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group,
2256  [elf,2,16,0], [--fatal-warnings],
2257  [.section .text,"axG",@progbits,.foo,comdat])
2258 if test $gcc_cv_as_comdat_group = yes; then
2259   gcc_cv_as_comdat_group_percent=no
2260 else
2261  gcc_GAS_CHECK_FEATURE(COMDAT group support, gcc_cv_as_comdat_group_percent,
2262    [elf,2,16,0], [--fatal-warnings],
2263    [.section .text,"axG",%progbits,.foo,comdat])
2264 fi
2265 if test $in_tree_ld != yes && test x"$ld_vers" != x; then
2266   comdat_group=yes
2267   if test 0"$ld_date" -lt 20050308; then
2268     if test -n "$ld_date"; then
2269       # If there was date string, but was earlier than 2005-03-08, fail
2270       comdat_group=no
2271     elif test "$ld_vers_major" -lt 2; then
2272       comdat_group=no
2273     elif test "$ld_vers_major" -eq 2 -a "$ld_vers_minor" -lt 16; then
2274       comdat_group=no
2275     fi
2276   fi
2277   if test $comdat_group = no; then
2278     gcc_cv_as_comdat_group=no
2279     gcc_cv_as_comdat_group_percent=no
2280   fi
2281 fi
2282 AC_DEFINE_UNQUOTED(HAVE_COMDAT_GROUP,
2283   [`if test $gcc_cv_as_comdat_group = yes || test $gcc_cv_as_comdat_group_percent = yes; then echo 1; else echo 0; fi`],
2284 [Define 0/1 if your assembler and linker support COMDAT groups.])
2285
2286 # Thread-local storage - the check is heavily parametrized.
2287 conftest_s=
2288 tls_first_major=
2289 tls_first_minor=
2290 tls_as_opt=
2291 case "$target" in
2292 changequote(,)dnl
2293   alpha*-*-*)
2294     conftest_s='
2295         .section ".tdata","awT",@progbits
2296 foo:    .long   25
2297         .text
2298         ldq     $27,__tls_get_addr($29)         !literal!1
2299         lda     $16,foo($29)                    !tlsgd!1
2300         jsr     $26,($27),__tls_get_addr        !lituse_tlsgd!1
2301         ldq     $27,__tls_get_addr($29)         !literal!2
2302         lda     $16,foo($29)                    !tlsldm!2
2303         jsr     $26,($27),__tls_get_addr        !lituse_tlsldm!2
2304         ldq     $1,foo($29)                     !gotdtprel
2305         ldah    $2,foo($29)                     !dtprelhi
2306         lda     $3,foo($2)                      !dtprello
2307         lda     $4,foo($29)                     !dtprel
2308         ldq     $1,foo($29)                     !gottprel
2309         ldah    $2,foo($29)                     !tprelhi
2310         lda     $3,foo($2)                      !tprello
2311         lda     $4,foo($29)                     !tprel'
2312         tls_first_major=2
2313         tls_first_minor=13
2314         tls_as_opt=--fatal-warnings
2315         ;;
2316   frv*-*-*)
2317     conftest_s='
2318         .section ".tdata","awT",@progbits
2319 x:      .long   25
2320         .text
2321         call    #gettlsoff(x)'
2322         tls_first_major=2
2323         tls_first_minor=14
2324         ;;
2325   i[34567]86-*-*)
2326     conftest_s='
2327         .section ".tdata","awT",@progbits
2328 foo:    .long   25
2329         .text
2330         movl    %gs:0, %eax
2331         leal    foo@TLSGD(,%ebx,1), %eax
2332         leal    foo@TLSLDM(%ebx), %eax
2333         leal    foo@DTPOFF(%eax), %edx
2334         movl    foo@GOTTPOFF(%ebx), %eax
2335         subl    foo@GOTTPOFF(%ebx), %eax
2336         addl    foo@GOTNTPOFF(%ebx), %eax
2337         movl    foo@INDNTPOFF, %eax
2338         movl    $foo@TPOFF, %eax
2339         subl    $foo@TPOFF, %eax
2340         leal    foo@NTPOFF(%ecx), %eax'
2341         tls_first_major=2
2342         tls_first_minor=14
2343         tls_as_opt=--fatal-warnings
2344         ;;
2345   x86_64-*-*)
2346     conftest_s='
2347         .section ".tdata","awT",@progbits
2348 foo:    .long   25
2349         .text
2350         movq    %fs:0, %rax
2351         leaq    foo@TLSGD(%rip), %rdi
2352         leaq    foo@TLSLD(%rip), %rdi
2353         leaq    foo@DTPOFF(%rax), %rdx
2354         movq    foo@GOTTPOFF(%rip), %rax
2355         movq    $foo@TPOFF, %rax'
2356         tls_first_major=2
2357         tls_first_minor=14
2358         tls_as_opt=--fatal-warnings
2359         ;;
2360   ia64-*-*)
2361     conftest_s='
2362         .section ".tdata","awT",@progbits
2363 foo:    data8   25
2364         .text
2365         addl    r16 = @ltoff(@dtpmod(foo#)), gp
2366         addl    r17 = @ltoff(@dtprel(foo#)), gp
2367         addl    r18 = @ltoff(@tprel(foo#)), gp
2368         addl    r19 = @dtprel(foo#), gp
2369         adds    r21 = @dtprel(foo#), r13
2370         movl    r23 = @dtprel(foo#)
2371         addl    r20 = @tprel(foo#), gp
2372         adds    r22 = @tprel(foo#), r13
2373         movl    r24 = @tprel(foo#)'
2374         tls_first_major=2
2375         tls_first_minor=13
2376         tls_as_opt=--fatal-warnings
2377         ;;
2378   mips*-*-*)
2379     conftest_s='
2380         .section .tdata,"awT",@progbits
2381 x:
2382         .word 2
2383         .text
2384         addiu $4, $28, %tlsgd(x)
2385         addiu $4, $28, %tlsldm(x)
2386         lui $4, %dtprel_hi(x)
2387         addiu $4, $4, %dtprel_lo(x)
2388         lw $4, %gottprel(x)($28)
2389         lui $4, %tprel_hi(x)
2390         addiu $4, $4, %tprel_lo(x)'
2391         tls_first_major=2
2392         tls_first_minor=16
2393         tls_as_opt='-32 --fatal-warnings'
2394         ;;
2395   powerpc-*-*)
2396     conftest_s='
2397         .section ".tdata","awT",@progbits
2398         .align 2
2399 ld0:    .space 4
2400 ld1:    .space 4
2401 x1:     .space 4
2402 x2:     .space 4
2403 x3:     .space 4
2404         .text
2405         addi 3,31,ld0@got@tlsgd
2406         bl __tls_get_addr
2407         addi 3,31,x1@got@tlsld
2408         bl __tls_get_addr
2409         addi 9,3,x1@dtprel
2410         addis 9,3,x2@dtprel@ha
2411         addi 9,9,x2@dtprel@l
2412         lwz 9,x3@got@tprel(31)
2413         add 9,9,x@tls
2414         addi 9,2,x1@tprel
2415         addis 9,2,x2@tprel@ha
2416         addi 9,9,x2@tprel@l'
2417         tls_first_major=2
2418         tls_first_minor=14
2419         tls_as_opt="-a32 --fatal-warnings"
2420         ;;
2421   powerpc64-*-*)
2422     conftest_s='
2423         .section ".tdata","awT",@progbits
2424         .align 3
2425 ld0:    .space 8
2426 ld1:    .space 8
2427 x1:     .space 8
2428 x2:     .space 8
2429 x3:     .space 8
2430         .text
2431         addi 3,2,ld0@got@tlsgd
2432         bl .__tls_get_addr
2433         nop
2434         addi 3,2,ld1@toc
2435         bl .__tls_get_addr
2436         nop
2437         addi 3,2,x1@got@tlsld
2438         bl .__tls_get_addr
2439         nop
2440         addi 9,3,x1@dtprel
2441         bl .__tls_get_addr
2442         nop
2443         addis 9,3,x2@dtprel@ha
2444         addi 9,9,x2@dtprel@l
2445         bl .__tls_get_addr
2446         nop
2447         ld 9,x3@got@dtprel(2)
2448         add 9,9,3
2449         bl .__tls_get_addr
2450         nop'
2451         tls_first_major=2
2452         tls_first_minor=14
2453         tls_as_opt="-a64 --fatal-warnings"
2454         ;;
2455   s390-*-*)
2456     conftest_s='
2457         .section ".tdata","awT",@progbits
2458 foo:    .long   25
2459         .text
2460         .long   foo@TLSGD
2461         .long   foo@TLSLDM
2462         .long   foo@DTPOFF
2463         .long   foo@NTPOFF
2464         .long   foo@GOTNTPOFF
2465         .long   foo@INDNTPOFF
2466         l       %r1,foo@GOTNTPOFF(%r12)
2467         l       %r1,0(%r1):tls_load:foo
2468         bas     %r14,0(%r1,%r13):tls_gdcall:foo
2469         bas     %r14,0(%r1,%r13):tls_ldcall:foo'
2470         tls_first_major=2
2471         tls_first_minor=14
2472         tls_as_opt="-m31 --fatal-warnings"
2473         ;;
2474   s390x-*-*)
2475     conftest_s='
2476         .section ".tdata","awT",@progbits
2477 foo:    .long   25
2478         .text
2479         .quad   foo@TLSGD
2480         .quad   foo@TLSLDM
2481         .quad   foo@DTPOFF
2482         .quad   foo@NTPOFF
2483         .quad   foo@GOTNTPOFF
2484         lg      %r1,foo@GOTNTPOFF(%r12)
2485         larl    %r1,foo@INDNTPOFF
2486         brasl   %r14,__tls_get_offset@PLT:tls_gdcall:foo
2487         brasl   %r14,__tls_get_offset@PLT:tls_ldcall:foo'
2488         tls_first_major=2
2489         tls_first_minor=14
2490         tls_as_opt="-m64 -Aesame --fatal-warnings"
2491         ;;
2492   sh-*-* | sh[34]-*-*)
2493     conftest_s='
2494         .section ".tdata","awT",@progbits
2495 foo:    .long   25
2496         .text
2497         .long   foo@TLSGD
2498         .long   foo@TLSLDM
2499         .long   foo@DTPOFF
2500         .long   foo@GOTTPOFF
2501         .long   foo@TPOFF'
2502         tls_first_major=2
2503         tls_first_minor=13
2504         tls_as_opt=--fatal-warnings
2505         ;;
2506   sparc*-*-*)
2507     case "$target" in
2508       sparc*-sun-solaris2.*)
2509         on_solaris=yes
2510         ;;
2511       *)
2512         on_solaris=no
2513         ;;
2514     esac
2515     if test x$on_solaris = xyes && test x$gas_flag = xno; then
2516       conftest_s='
2517         .section ".tdata",#alloc,#write,#tls
2518 foo:    .long   25
2519         .text
2520         sethi   %tgd_hi22(foo), %o0
2521         add     %o0, %tgd_lo10(foo), %o1
2522         add     %l7, %o1, %o0, %tgd_add(foo)
2523         call    __tls_get_addr, %tgd_call(foo)
2524         sethi   %tldm_hi22(foo), %l1
2525         add     %l1, %tldm_lo10(foo), %l2
2526         add     %l7, %l2, %o0, %tldm_add(foo)
2527         call    __tls_get_addr, %tldm_call(foo)
2528         sethi   %tldo_hix22(foo), %l3
2529         xor     %l3, %tldo_lox10(foo), %l4
2530         add     %o0, %l4, %l5, %tldo_add(foo)
2531         sethi   %tie_hi22(foo), %o3
2532         add     %o3, %tie_lo10(foo), %o3
2533         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2534         add     %g7, %o2, %o4, %tie_add(foo)
2535         sethi   %tle_hix22(foo), %l1
2536         xor     %l1, %tle_lox10(foo), %o5
2537         ld      [%g7 + %o5], %o1'
2538         tls_first_major=0
2539         tls_first_minor=0
2540     else
2541       conftest_s='
2542         .section ".tdata","awT",@progbits
2543 foo:    .long   25
2544         .text
2545         sethi   %tgd_hi22(foo), %o0
2546         add     %o0, %tgd_lo10(foo), %o1
2547         add     %l7, %o1, %o0, %tgd_add(foo)
2548         call    __tls_get_addr, %tgd_call(foo)
2549         sethi   %tldm_hi22(foo), %l1
2550         add     %l1, %tldm_lo10(foo), %l2
2551         add     %l7, %l2, %o0, %tldm_add(foo)
2552         call    __tls_get_addr, %tldm_call(foo)
2553         sethi   %tldo_hix22(foo), %l3
2554         xor     %l3, %tldo_lox10(foo), %l4
2555         add     %o0, %l4, %l5, %tldo_add(foo)
2556         sethi   %tie_hi22(foo), %o3
2557         add     %o3, %tie_lo10(foo), %o3
2558         ld      [%l7 + %o3], %o2, %tie_ld(foo)
2559         add     %g7, %o2, %o4, %tie_add(foo)
2560         sethi   %tle_hix22(foo), %l1
2561         xor     %l1, %tle_lox10(foo), %o5
2562         ld      [%g7 + %o5], %o1'
2563         tls_first_major=2
2564         tls_first_minor=14
2565         tls_as_opt="-32 --fatal-warnings"
2566       fi
2567         ;;
2568 changequote([,])dnl
2569 esac
2570 if test -z "$tls_first_major"; then
2571   : # If we don't have a check, assume no support.
2572 else
2573   gcc_GAS_CHECK_FEATURE(thread-local storage support, gcc_cv_as_tls,
2574   [$tls_first_major,$tls_first_minor,0], [$tls_as_opt], [$conftest_s],,
2575   [AC_DEFINE(HAVE_AS_TLS, 1,
2576             [Define if your assembler supports thread-local storage.])])
2577 fi
2578
2579 # Target-specific assembler checks.
2580
2581 AC_MSG_CHECKING(linker -Bstatic/-Bdynamic option)
2582 gcc_cv_ld_static_dynamic=no
2583 if test $in_tree_ld = yes ; then
2584   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10; then
2585     gcc_cv_ld_static_dynamic=yes
2586   fi
2587 elif test x$gcc_cv_ld != x; then
2588         # Check if linker supports -Bstatic/-Bdynamic option
2589         if $gcc_cv_ld --help 2>/dev/null | grep -- -Bstatic > /dev/null \
2590           && $gcc_cv_ld --help 2>/dev/null | grep -- -Bdynamic > /dev/null; then
2591                 gcc_cv_ld_static_dynamic=yes
2592         fi
2593 fi
2594 if test x"$gcc_cv_ld_static_dynamic" = xyes; then
2595         AC_DEFINE(HAVE_LD_STATIC_DYNAMIC, 1,
2596 [Define if your linker supports -Bstatic/-Bdynamic option.])
2597 fi
2598 AC_MSG_RESULT($gcc_cv_ld_static_dynamic)
2599
2600 if test x"$demangler_in_ld" = xyes; then
2601   AC_MSG_CHECKING(linker --demangle support)
2602   gcc_cv_ld_demangle=no
2603   if test $in_tree_ld = yes; then
2604     if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 14 -o "$gcc_cv_gld_major_version" -gt 2; then \
2605       gcc_cv_ld_demangle=yes
2606     fi
2607   elif test x$gcc_cv_ld != x -a x"$gnu_ld" = xyes; then
2608     # Check if the GNU linker supports --demangle option
2609     if $gcc_cv_ld --help 2>/dev/null | grep no-demangle > /dev/null; then
2610       gcc_cv_ld_demangle=yes
2611     fi
2612   fi
2613   if test x"$gcc_cv_ld_demangle" = xyes; then
2614     AC_DEFINE(HAVE_LD_DEMANGLE, 1,
2615 [Define if your linker supports --demangle option.])
2616   fi
2617   AC_MSG_RESULT($gcc_cv_ld_demangle)
2618 fi
2619
2620 case "$target" in
2621   # All TARGET_ABI_OSF targets.
2622   alpha*-*-osf* | alpha*-*-linux* | alpha*-*-*bsd*)
2623     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2624         gcc_cv_as_alpha_explicit_relocs, [2,12,0],,
2625 [       .set nomacro
2626         .text
2627         extbl   $3, $2, $3      !lituse_bytoff!1
2628         ldq     $2, a($29)      !literal!1
2629         ldq     $4, b($29)      !literal!2
2630         ldq_u   $3, 0($2)       !lituse_base!1
2631         ldq     $27, f($29)     !literal!5
2632         jsr     $26, ($27), f   !lituse_jsr!5
2633         ldah    $29, 0($26)     !gpdisp!3
2634         lda     $0, c($29)      !gprel
2635         ldah    $1, d($29)      !gprelhigh
2636         lda     $1, d($1)       !gprellow
2637         lda     $29, 0($29)     !gpdisp!3],,
2638     [AC_DEFINE(HAVE_AS_EXPLICIT_RELOCS, 1,
2639   [Define if your assembler supports explicit relocations.])])
2640     ;;
2641
2642   cris-*-*)
2643     gcc_GAS_CHECK_FEATURE([-no-mul-bug-abort option],
2644       gcc_cv_as_cris_no_mul_bug,[2,15,91],
2645       [-no-mul-bug-abort], [.text],,
2646       [AC_DEFINE(HAVE_AS_NO_MUL_BUG_ABORT_OPTION, 1,
2647                 [Define if your assembler supports the -no-mul-bug-abort option.])])
2648     ;;
2649
2650   sparc*-*-*)
2651     gcc_GAS_CHECK_FEATURE([.register], gcc_cv_as_sparc_register_op,,,
2652       [.register %g2, #scratch],,
2653       [AC_DEFINE(HAVE_AS_REGISTER_PSEUDO_OP, 1,
2654                 [Define if your assembler supports .register.])])
2655
2656     gcc_GAS_CHECK_FEATURE([-relax option], gcc_cv_as_sparc_relax,,
2657       [-relax], [.text],,
2658       [AC_DEFINE(HAVE_AS_RELAX_OPTION, 1,
2659                 [Define if your assembler supports -relax option.])])
2660
2661     gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs],
2662       gcc_cv_as_sparc_ua_pcrel,,
2663       [-K PIC],
2664 [.text
2665 foo:
2666         nop
2667 .data
2668 .align 4
2669 .byte 0
2670 .uaword %r_disp32(foo)],
2671       [if test x$gcc_cv_ld != x \
2672        && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1; then
2673          gcc_cv_as_sparc_ua_pcrel=yes
2674        fi
2675        rm -f conftest],
2676       [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL, 1,
2677                 [Define if your assembler and linker support unaligned PC relative relocs.])
2678
2679       gcc_GAS_CHECK_FEATURE([unaligned pcrel relocs against hidden symbols],
2680         gcc_cv_as_sparc_ua_pcrel_hidden,,
2681         [-K PIC],
2682 [.data
2683 .align 4
2684 .byte 0x31
2685 .uaword %r_disp32(foo)
2686 .byte 0x32, 0x33, 0x34
2687 .global foo
2688 .hidden foo
2689 foo:
2690 .skip 4],
2691         [if test x$gcc_cv_ld != x && test x$gcc_cv_objdump != x \
2692          && $gcc_cv_ld -o conftest conftest.o -G > /dev/null 2>&1 \
2693          && $gcc_cv_objdump -s -j .data conftest 2> /dev/null \
2694             | grep ' 31000000 07323334' > /dev/null 2>&1; then
2695             if $gcc_cv_objdump -R conftest 2> /dev/null \
2696                | grep 'DISP32' > /dev/null 2>&1; then
2697                 :
2698             else
2699                 gcc_cv_as_sparc_ua_pcrel_hidden=yes
2700             fi
2701          fi
2702          rm -f conftest],
2703          [AC_DEFINE(HAVE_AS_SPARC_UA_PCREL_HIDDEN, 1,
2704                    [Define if your assembler and linker support unaligned PC relative relocs against hidden symbols.])])
2705     ]) # unaligned pcrel relocs
2706
2707     gcc_GAS_CHECK_FEATURE([offsetable %lo()],
2708       gcc_cv_as_sparc_offsetable_lo10,,
2709       [-xarch=v9],
2710 [.text
2711         or %g1, %lo(ab) + 12, %g1
2712         or %g1, %lo(ab + 12), %g1],
2713       [if test x$gcc_cv_objdump != x \
2714        && $gcc_cv_objdump -s -j .text conftest.o 2> /dev/null \
2715           | grep ' 82106000 82106000' > /dev/null 2>&1; then
2716          gcc_cv_as_sparc_offsetable_lo10=yes
2717        fi],
2718        [AC_DEFINE(HAVE_AS_OFFSETABLE_LO10, 1,
2719                  [Define if your assembler supports offsetable %lo().])])
2720     ;;
2721
2722 changequote(,)dnl
2723   i[34567]86-*-* | x86_64-*-*)
2724 changequote([,])dnl
2725     case $target_os in
2726       cygwin* | pe | mingw32*)
2727         # Used for DWARF 2 in PE
2728         gcc_GAS_CHECK_FEATURE([.secrel32 relocs],
2729           gcc_cv_as_ix86_pe_secrel32,
2730           [2,15,91],,
2731 [.text
2732 foo:    nop
2733 .data
2734         .secrel32 foo],
2735           [if test x$gcc_cv_ld != x \
2736            && $gcc_cv_ld -o conftest conftest.o > /dev/null 2>&1; then
2737              gcc_cv_as_ix86_pe_secrel32=yes
2738            fi
2739            rm -f conftest],
2740           [AC_DEFINE(HAVE_GAS_PE_SECREL32_RELOC, 1,
2741             [Define if your assembler and linker support 32-bit section relative relocs via '.secrel32 label'.])])
2742         ;;
2743     esac
2744
2745     gcc_GAS_CHECK_FEATURE([filds and fists mnemonics],
2746        gcc_cv_as_ix86_filds_fists,
2747       [2,9,0],, [filds mem; fists mem],,
2748       [AC_DEFINE(HAVE_GAS_FILDS_FISTS, 1,
2749         [Define if your assembler uses the new HImode fild and fist notation.])])
2750
2751     gcc_GAS_CHECK_FEATURE([cmov syntax],
2752       gcc_cv_as_ix86_cmov_sun_syntax,,,
2753       [cmovl.l %edx, %eax],,
2754       [AC_DEFINE(HAVE_AS_IX86_CMOV_SUN_SYNTAX, 1,
2755         [Define if your assembler supports the Sun syntax for cmov.])])
2756
2757     # This one is used unconditionally by i386.[ch]; it is to be defined
2758     # to 1 if the feature is present, 0 otherwise.
2759     gcc_GAS_CHECK_FEATURE([GOTOFF in data],
2760         gcc_cv_as_ix86_gotoff_in_data, [2,11,0],,
2761 [       .text
2762 .L0:
2763         nop
2764         .data
2765         .long .L0@GOTOFF])
2766     AC_DEFINE_UNQUOTED(HAVE_AS_GOTOFF_IN_DATA,
2767       [`if test $gcc_cv_as_ix86_gotoff_in_data = yes; then echo 1; else echo 0; fi`],
2768       [Define true if the assembler supports '.long foo@GOTOFF'.])
2769     ;;
2770
2771   ia64*-*-*)
2772     gcc_GAS_CHECK_FEATURE([ltoffx and ldxmov relocs],
2773         gcc_cv_as_ia64_ltoffx_ldxmov_relocs, [2,14,0],,
2774 [       .text
2775         addl r15 = @ltoffx(x#), gp
2776         ;;
2777         ld8.mov r16 = [[r15]], x#],,
2778     [AC_DEFINE(HAVE_AS_LTOFFX_LDXMOV_RELOCS, 1,
2779           [Define if your assembler supports ltoffx and ldxmov relocations.])])
2780
2781     ;;
2782
2783   powerpc*-*-*)
2784     case $target in
2785       *-*-aix*) conftest_s='    .machine "pwr5"
2786         .csect .text[[PR]]
2787         mfcr 3,128';;
2788       *-*-darwin*)
2789         gcc_GAS_CHECK_FEATURE([.machine directive support],
2790           gcc_cv_as_machine_directive,,,
2791           [     .machine ppc7400])
2792         if test x$gcc_cv_as_machine_directive != xyes; then
2793           echo "*** This target requires an assembler supporting \".machine\"" >&2
2794           echo you can get it from: ftp://gcc.gnu.org/pub/gcc/infrastructure/cctools-528.5.dmg >&2
2795           test x$build = x$target && exit 1
2796         fi
2797         conftest_s='    .text
2798         mfcr r3,128';;
2799       *) conftest_s='   .machine power4
2800         .text
2801         mfcr 3,128';;
2802     esac
2803
2804     gcc_GAS_CHECK_FEATURE([mfcr field support],
2805       gcc_cv_as_powerpc_mfcrf, [2,14,0],,
2806       [$conftest_s],,
2807       [AC_DEFINE(HAVE_AS_MFCRF, 1,
2808           [Define if your assembler supports mfcr field.])])
2809
2810     case $target in
2811       *-*-aix*) conftest_s='    .machine "pwr5"
2812         .csect .text[[PR]]
2813         popcntb 3,3';;
2814       *) conftest_s='   .machine power5
2815         .text
2816         popcntb 3,3';;
2817     esac
2818
2819     gcc_GAS_CHECK_FEATURE([popcntb support],
2820       gcc_cv_as_powerpc_popcntb, [2,17,0],,
2821       [$conftest_s],,
2822       [AC_DEFINE(HAVE_AS_POPCNTB, 1,
2823           [Define if your assembler supports popcntb field.])])
2824
2825     ;;
2826
2827   mips*-*-*)
2828     gcc_GAS_CHECK_FEATURE([explicit relocation support],
2829       gcc_cv_as_mips_explicit_relocs, [2,14,0],,
2830 [       lw $4,%gp_rel(foo)($4)],,
2831       [if test x$target_cpu_default = x
2832        then target_cpu_default=MASK_EXPLICIT_RELOCS
2833        else target_cpu_default="($target_cpu_default)|MASK_EXPLICIT_RELOCS"
2834        fi])
2835
2836     if test x$gas_flag = xyes \
2837        || test x"$host" != x"$build" \
2838        || test ! -x "$gcc_cv_as" \
2839        || "$gcc_cv_as" -v < /dev/null 2>&1 | grep GNU > /dev/null; then
2840       :
2841     else
2842       echo "*** This configuration requires the GNU assembler" >&2
2843       exit 1
2844     fi
2845     ;;
2846 esac
2847 # ??? Not all targets support dwarf2 debug_line, even within a version
2848 # of gas.  Moreover, we need to emit a valid instruction to trigger any
2849 # info to the output file.  So, as supported targets are added to gas 2.11,
2850 # add some instruction here to (also) show we expect this might work.
2851 # ??? Once 2.11 is released, probably need to add first known working
2852 # version to the per-target configury.
2853 case "$target" in
2854   i?86*-*-* | mips*-*-* | alpha*-*-* | powerpc*-*-* | sparc*-*-* | m68*-*-* \
2855   | x86_64*-*-* | hppa*-*-* | arm*-*-* | strongarm*-*-* | xscale*-*-* \
2856   | xstormy16*-*-* | cris-*-* | xtensa-*-*)
2857     insn="nop"
2858     ;;
2859   ia64*-*-* | s390*-*-*)
2860     insn="nop 0"
2861     ;;
2862   mmix-*-*)
2863     insn="swym 0"
2864     ;;
2865 esac
2866 if test x"$insn" != x; then
2867  conftest_s="\
2868         .file 1 \"conftest.s\"
2869         .loc 1 3 0
2870         $insn"
2871  gcc_GAS_CHECK_FEATURE([dwarf2 debug_line support],
2872   gcc_cv_as_dwarf2_debug_line,
2873   [elf,2,11,0],, [$conftest_s],
2874   [if test x$gcc_cv_objdump != x \
2875    && $gcc_cv_objdump -h conftest.o 2> /dev/null \
2876       | grep debug_line > /dev/null 2>&1; then
2877      gcc_cv_as_dwarf2_debug_line=yes
2878    fi])
2879
2880 # The .debug_line file table must be in the exact order that
2881 # we specified the files, since these indices are also used
2882 # by DW_AT_decl_file.  Approximate this test by testing if
2883 # the assembler bitches if the same index is assigned twice.
2884  gcc_GAS_CHECK_FEATURE([buggy dwarf2 .file directive],
2885   gcc_cv_as_dwarf2_file_buggy,,,
2886 [       .file 1 "foo.s"
2887         .file 1 "bar.s"])
2888
2889  if test $gcc_cv_as_dwarf2_debug_line = yes \
2890  && test $gcc_cv_as_dwarf2_file_buggy = no; then
2891         AC_DEFINE(HAVE_AS_DWARF2_DEBUG_LINE, 1,
2892   [Define if your assembler supports dwarf2 .file/.loc directives,
2893    and preserves file table indices exactly as given.])
2894  fi
2895
2896  gcc_GAS_CHECK_FEATURE([--gdwarf2 option],
2897   gcc_cv_as_gdwarf2_flag,
2898   [elf,2,11,0], [--gdwarf2], [$insn],,
2899   [AC_DEFINE(HAVE_AS_GDWARF2_DEBUG_FLAG, 1,
2900 [Define if your assembler supports the --gdwarf2 option.])])
2901
2902  gcc_GAS_CHECK_FEATURE([--gstabs option],
2903   gcc_cv_as_gstabs_flag,
2904   [elf,2,11,0], [--gstabs], [$insn],
2905   [# The native Solaris 9/Intel assembler doesn't understand --gstabs
2906    # and warns about it, but still exits successfully.  So check for
2907    # this.
2908    if AC_TRY_COMMAND([$gcc_cv_as --gstabs -o conftest.o conftest.s 2>&1 | grep -i warning > /dev/null])
2909    then :
2910    else gcc_cv_as_gstabs_flag=yes
2911    fi],
2912   [AC_DEFINE(HAVE_AS_GSTABS_DEBUG_FLAG, 1,
2913 [Define if your assembler supports the --gstabs option.])])
2914 fi
2915
2916 AC_MSG_CHECKING(linker read-only and read-write section mixing)
2917 gcc_cv_ld_ro_rw_mix=unknown
2918 if test $in_tree_ld = yes ; then
2919   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 10 -o "$gcc_cv_gld_major_version" -gt 2 \
2920      && test $in_tree_ld_is_elf = yes; then
2921     gcc_cv_ld_ro_rw_mix=read-write
2922   fi
2923 elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x -a x$gcc_cv_objdump != x ; then
2924   echo '.section myfoosect, "a"' > conftest1.s
2925   echo '.section myfoosect, "aw"' > conftest2.s
2926   echo '.byte 1' >> conftest2.s
2927   echo '.section myfoosect, "a"' > conftest3.s
2928   echo '.byte 0' >> conftest3.s
2929   if $gcc_cv_as -o conftest1.o conftest1.s > /dev/null 2>&1 \
2930      && $gcc_cv_as -o conftest2.o conftest2.s > /dev/null 2>&1 \
2931      && $gcc_cv_as -o conftest3.o conftest3.s > /dev/null 2>&1 \
2932      && $gcc_cv_ld -shared -o conftest1.so conftest1.o \
2933         conftest2.o conftest3.o > /dev/null 2>&1; then
2934     gcc_cv_ld_ro_rw_mix=`$gcc_cv_objdump -h conftest1.so \
2935                          | sed -e '/myfoosect/!d' -e N`
2936     if echo "$gcc_cv_ld_ro_rw_mix" | grep CONTENTS > /dev/null; then
2937       if echo "$gcc_cv_ld_ro_rw_mix" | grep READONLY > /dev/null; then
2938         gcc_cv_ld_ro_rw_mix=read-only
2939       else
2940         gcc_cv_ld_ro_rw_mix=read-write
2941       fi
2942     fi
2943   fi
2944 changequote(,)dnl
2945   rm -f conftest.* conftest[123].*
2946 changequote([,])dnl
2947 fi
2948 if test x$gcc_cv_ld_ro_rw_mix = xread-write; then
2949         AC_DEFINE(HAVE_LD_RO_RW_SECTION_MIXING, 1,
2950   [Define if your linker links a mix of read-only
2951    and read-write sections into a read-write section.])
2952 fi
2953 AC_MSG_RESULT($gcc_cv_ld_ro_rw_mix)
2954
2955 AC_MSG_CHECKING(linker PT_GNU_EH_FRAME support)
2956 gcc_cv_ld_eh_frame_hdr=no
2957 if test $in_tree_ld = yes ; then
2958   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 12 -o "$gcc_cv_gld_major_version" -gt 2 \
2959      && test $in_tree_ld_is_elf = yes; then
2960     gcc_cv_ld_eh_frame_hdr=yes
2961   fi
2962 elif test x$gcc_cv_ld != x; then
2963         # Check if linker supports --eh-frame-hdr option
2964         if $gcc_cv_ld --help 2>/dev/null | grep eh-frame-hdr > /dev/null; then
2965                 gcc_cv_ld_eh_frame_hdr=yes
2966         fi
2967 fi
2968 GCC_TARGET_TEMPLATE([HAVE_LD_EH_FRAME_HDR])
2969 if test x"$gcc_cv_ld_eh_frame_hdr" = xyes; then
2970         AC_DEFINE(HAVE_LD_EH_FRAME_HDR, 1,
2971 [Define if your linker supports --eh-frame-hdr option.])
2972 fi
2973 AC_MSG_RESULT($gcc_cv_ld_eh_frame_hdr)
2974
2975 AC_MSG_CHECKING(linker position independent executable support)
2976 gcc_cv_ld_pie=no
2977 if test $in_tree_ld = yes ; then
2978   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 15 -o "$gcc_cv_gld_major_version" -gt 2 \
2979      && test $in_tree_ld_is_elf = yes; then
2980     gcc_cv_ld_pie=yes
2981   fi
2982 elif test x$gcc_cv_ld != x; then
2983         # Check if linker supports -pie option
2984         if $gcc_cv_ld --help 2>/dev/null | grep -- -pie > /dev/null; then
2985                 gcc_cv_ld_pie=yes
2986         fi
2987 fi
2988 if test x"$gcc_cv_ld_pie" = xyes; then
2989         AC_DEFINE(HAVE_LD_PIE, 1,
2990 [Define if your linker supports -pie option.])
2991 fi
2992 AC_MSG_RESULT($gcc_cv_ld_pie)
2993
2994 # --------
2995 # UNSORTED
2996 # --------
2997
2998 AC_CACHE_CHECK(linker --as-needed support,
2999 gcc_cv_ld_as_needed,
3000 [gcc_cv_ld_as_needed=no
3001 if test $in_tree_ld = yes ; then
3002   if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 \
3003      && test $in_tree_ld_is_elf = yes; then
3004     gcc_cv_ld_as_needed=yes
3005   fi
3006 elif test x$gcc_cv_ld != x; then
3007         # Check if linker supports --as-needed and --no-as-needed options
3008         if $gcc_cv_ld --help 2>/dev/null | grep as-needed > /dev/null; then
3009                 gcc_cv_ld_as_needed=yes
3010         fi
3011 fi
3012 ])
3013 if test x"$gcc_cv_ld_as_needed" = xyes; then
3014         AC_DEFINE(HAVE_LD_AS_NEEDED, 1,
3015 [Define if your linker supports --as-needed and --no-as-needed options.])
3016 fi
3017
3018 case "$target" in
3019   powerpc64*-*-linux*)
3020     AC_CACHE_CHECK(linker support for omitting dot symbols,
3021     gcc_cv_ld_no_dot_syms,
3022     [gcc_cv_ld_no_dot_syms=no
3023     if test $in_tree_ld = yes ; then
3024       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2; then
3025         gcc_cv_ld_no_dot_syms=yes
3026       fi
3027     elif test x$gcc_cv_as != x -a x$gcc_cv_ld != x ; then
3028       cat > conftest1.s <<EOF
3029         .text
3030         bl .foo
3031 EOF
3032       cat > conftest2.s <<EOF
3033         .section ".opd","aw"
3034         .align 3
3035         .globl foo
3036         .type foo,@function
3037 foo:
3038         .quad .LEfoo,.TOC.@tocbase,0
3039         .text
3040 .LEfoo:
3041         blr
3042         .size foo,.-.LEfoo
3043 EOF
3044       if $gcc_cv_as -a64 -o conftest1.o conftest1.s > /dev/null 2>&1 \
3045          && $gcc_cv_as -a64 -o conftest2.o conftest2.s > /dev/null 2>&1 \
3046          && $gcc_cv_ld -melf64ppc -o conftest conftest1.o conftest2.o > /dev/null 2>&1; then
3047         gcc_cv_ld_no_dot_syms=yes
3048       fi
3049       rm -f conftest conftest1.o conftest2.o conftest1.s conftest2.s
3050     fi
3051     ])
3052     if test x"$gcc_cv_ld_no_dot_syms" = xyes; then
3053       AC_DEFINE(HAVE_LD_NO_DOT_SYMS, 1,
3054     [Define if your PowerPC64 linker only needs function descriptor syms.])
3055     fi
3056     ;;
3057 esac
3058
3059 AC_CACHE_CHECK(linker --sysroot support,
3060   gcc_cv_ld_sysroot,
3061   [gcc_cv_ld_sysroot=no
3062   if test $in_tree_ld = yes ; then
3063       if test "$gcc_cv_gld_major_version" -eq 2 -a "$gcc_cv_gld_minor_version" -ge 16 -o "$gcc_cv_gld_major_version" -gt 2 ; then
3064         gcc_cv_ld_sysroot=yes
3065       fi
3066   elif test x$gcc_cv_ld != x; then
3067     if $gcc_cv_ld --help 2>/dev/null | grep sysroot > /dev/null; then
3068       gcc_cv_ld_sysroot=yes
3069     fi
3070   fi])
3071 if test x"$gcc_cv_ld_sysroot" = xyes; then
3072   AC_DEFINE(HAVE_LD_SYSROOT, 1,
3073   [Define if your linker supports --sysroot.])
3074 fi
3075
3076 if test x$with_sysroot = x && test x$host = x$target \
3077    && test "$prefix" != "/usr" && test "x$prefix" != "x$local_prefix" ; then
3078   AC_DEFINE_UNQUOTED(PREFIX_INCLUDE_DIR, "$prefix/include",
3079 [Define to PREFIX/include if cpp should also search that directory.])
3080 fi
3081
3082 # Find out what GC implementation we want, or may, use.
3083 AC_ARG_WITH(gc,
3084 [  --with-gc={page,zone}   choose the garbage collection mechanism to use
3085                           with the compiler],
3086 [case "$withval" in
3087   page)
3088     GGC=ggc-$withval
3089     ;;
3090   zone)
3091     GGC=ggc-$withval
3092     AC_DEFINE(GGC_ZONE, 1, [Define if the zone collector is in use])
3093     ;;
3094   *)
3095     AC_MSG_ERROR([$withval is an invalid option to --with-gc])
3096     ;;
3097 esac],
3098 [GGC=ggc-page])
3099 AC_SUBST(GGC)
3100 echo "Using $GGC for garbage collection."
3101
3102 # Use the system's zlib library.
3103 zlibdir=-L../zlib
3104 zlibinc="-I\$(srcdir)/../zlib"
3105 AC_ARG_WITH(system-zlib,
3106 [  --with-system-zlib      use installed libz],
3107 zlibdir=
3108 zlibinc=
3109 )
3110 AC_SUBST(zlibdir)
3111 AC_SUBST(zlibinc)
3112
3113 dnl Very limited version of automake's enable-maintainer-mode
3114
3115 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3116   dnl maintainer-mode is disabled by default
3117   AC_ARG_ENABLE(maintainer-mode,
3118 [  --enable-maintainer-mode
3119                           enable make rules and dependencies not useful
3120                           (and sometimes confusing) to the casual installer],
3121       maintainer_mode=$enableval,
3122       maintainer_mode=no)
3123
3124 AC_MSG_RESULT($maintainer_mode)
3125
3126 if test "$maintainer_mode" = "yes"; then
3127   MAINT=''
3128 else
3129   MAINT='#'
3130 fi
3131 AC_SUBST(MAINT)dnl
3132
3133 # --------------
3134 # Language hooks
3135 # --------------
3136
3137 # Make empty files to contain the specs and options for each language.
3138 # Then add #include lines to for a compiler that has specs and/or options.
3139
3140 lang_opt_files=
3141 lang_specs_files=
3142 lang_tree_files=
3143 for subdir in . $subdirs
3144 do
3145         if test -f $srcdir/$subdir/lang.opt; then
3146             lang_opt_files="$lang_opt_files $srcdir/$subdir/lang.opt"
3147         fi
3148         if test -f $srcdir/$subdir/lang-specs.h; then
3149             lang_specs_files="$lang_specs_files $srcdir/$subdir/lang-specs.h"
3150         fi
3151         if test -f $srcdir/$subdir/$subdir-tree.def; then
3152             lang_tree_files="$lang_tree_files $srcdir/$subdir/$subdir-tree.def"
3153         fi
3154 done
3155
3156 # These (without "all_") are set in each config-lang.in.
3157 # `language' must be a single word so is spelled singularly.
3158 all_languages=
3159 all_boot_languages=
3160 all_compilers=
3161 all_stagestuff=
3162 all_outputs='Makefile gccbug mklibgcc libada-mk'
3163 # List of language makefile fragments.
3164 all_lang_makefrags=
3165 # List of language subdirectory makefiles.  Deprecated.
3166 all_lang_makefiles=
3167 # Files for gengtype
3168 all_gtfiles="$target_gtfiles"
3169 # Files for gengtype with language
3170 all_gtfiles_files_langs=
3171 all_gtfiles_files_files=
3172
3173 # Add the language fragments.
3174 # Languages are added via two mechanisms.  Some information must be
3175 # recorded in makefile variables, these are defined in config-lang.in.
3176 # We accumulate them and plug them into the main Makefile.
3177 # The other mechanism is a set of hooks for each of the main targets
3178 # like `clean', `install', etc.
3179
3180 language_hooks="Make-hooks"
3181
3182 for s in $subdirs
3183 do
3184                 language=
3185                 boot_language=
3186                 compilers=
3187                 stagestuff=
3188                 outputs=
3189                 gtfiles=
3190                 . ${srcdir}/$s/config-lang.in
3191                 if test "x$language" = x
3192                 then
3193                         echo "${srcdir}/$s/config-lang.in doesn't set \$language." 1>&2
3194                         exit 1
3195                 fi
3196                 all_lang_makefrags="$all_lang_makefrags \$(srcdir)/$s/Make-lang.in"
3197                 if test -f ${srcdir}/$s/Makefile.in
3198                 then all_lang_makefiles="$s/Makefile"
3199                 fi
3200                 all_languages="$all_languages $language"
3201                 if test "x$boot_language" = xyes
3202                 then
3203                         all_boot_languages="$all_boot_languages $language"
3204                 fi
3205                 all_compilers="$all_compilers $compilers"
3206                 all_stagestuff="$all_stagestuff $stagestuff"
3207                 all_outputs="$all_outputs $outputs"
3208                 all_gtfiles="$all_gtfiles $gtfiles"
3209                 for f in $gtfiles
3210                 do
3211                          all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
3212                          all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3213                 done
3214 done
3215
3216 # Pick up gtfiles for c
3217 gtfiles=
3218 s="c"
3219 . ${srcdir}/c-config-lang.in
3220 all_gtfiles="$all_gtfiles $gtfiles"
3221 for f in $gtfiles
3222 do
3223         all_gtfiles_files_langs="$all_gtfiles_files_langs ${s} "
3224         all_gtfiles_files_files="$all_gtfiles_files_files ${f} "
3225 done
3226
3227 check_languages=
3228 for language in $all_languages
3229 do
3230                 check_languages="$check_languages check-$language"
3231 done
3232
3233 # We link each language in with a set of hooks, reached indirectly via
3234 # lang.${target}.
3235
3236 rm -f Make-hooks
3237 touch Make-hooks
3238 target_list="all.build all.cross start.encap rest.encap tags \
3239         install-normal install-common install-man \
3240         uninstall info man srcextra srcman srcinfo \
3241         mostlyclean clean distclean maintainer-clean \
3242         stage1 stage2 stage3 stage4 stageprofile stagefeedback"
3243 for t in $target_list
3244 do
3245         x=
3246         for lang in $all_languages
3247         do
3248                         x="$x $lang.$t"
3249         done
3250         echo "lang.$t: $x" >> Make-hooks
3251 done
3252
3253 # --------
3254 # UNSORTED
3255 # --------
3256
3257 # Create .gdbinit.
3258
3259 echo "dir ." > .gdbinit
3260 echo "dir ${srcdir}" >> .gdbinit
3261 if test x$gdb_needs_out_file_path = xyes
3262 then
3263         echo "dir ${srcdir}/config/"`dirname ${out_file}` >> .gdbinit
3264 fi
3265 if test "x$subdirs" != x; then
3266         for s in $subdirs
3267         do
3268                 echo "dir ${srcdir}/$s" >> .gdbinit
3269         done
3270 fi
3271 echo "source ${srcdir}/gdbinit.in" >> .gdbinit
3272
3273 # If $(exec_prefix) exists and is not the same as $(prefix), then compute an
3274 # absolute path for gcc_tooldir based on inserting the number of up-directory
3275 # movements required to get from $(exec_prefix) to $(prefix) into the basic
3276 # $(libsubdir)/@(unlibsubdir) based path.
3277 # Don't set gcc_tooldir to tooldir since that's only passed in by the toplevel
3278 # make and thus we'd get different behavior depending on where we built the
3279 # sources.
3280 if test x$exec_prefix = xNONE -o x$exec_prefix = x$prefix; then
3281     gcc_tooldir='$(libsubdir)/$(unlibsubdir)/../$(target_noncanonical)'
3282 else
3283 changequote(<<, >>)dnl
3284 # An explanation of the sed strings:
3285 #  -e 's|^\$(prefix)||'   matches and eliminates 'prefix' from 'exec_prefix'
3286 #  -e 's|/$||'            match a trailing forward slash and eliminates it
3287 #  -e 's|^[^/]|/|'        forces the string to start with a forward slash (*)
3288 #  -e 's|/[^/]*|../|g'    replaces each occurrence of /<directory> with ../
3289 #
3290 # (*) Note this pattern overwrites the first character of the string
3291 # with a forward slash if one is not already present.  This is not a
3292 # problem because the exact names of the sub-directories concerned is
3293 # unimportant, just the number of them matters.
3294 #
3295 # The practical upshot of these patterns is like this:
3296 #
3297 #  prefix     exec_prefix        result
3298 #  ------     -----------        ------
3299 #   /foo        /foo/bar          ../
3300 #   /foo/       /foo/bar          ../
3301 #   /foo        /foo/bar/         ../
3302 #   /foo/       /foo/bar/         ../
3303 #   /foo        /foo/bar/ugg      ../../
3304 #
3305     dollar='$$'
3306     gcc_tooldir="\$(libsubdir)/\$(unlibsubdir)/\`echo \$(exec_prefix) | sed -e 's|^\$(prefix)||' -e 's|/\$(dollar)||' -e 's|^[^/]|/|' -e 's|/[^/]*|../|g'\`\$(target_noncanonical)"
3307 changequote([, ])dnl
3308 fi
3309 AC_SUBST(gcc_tooldir)
3310 AC_SUBST(dollar)
3311
3312 # Find a directory in which to install a shared libgcc.
3313
3314 AC_ARG_ENABLE(version-specific-runtime-libs,
3315 [  --enable-version-specific-runtime-libs
3316                           specify that runtime libraries should be
3317                           installed in a compiler-specific directory])
3318
3319 AC_ARG_WITH(slibdir,
3320 [  --with-slibdir=DIR      shared libraries in DIR [LIBDIR]],
3321 slibdir="$with_slibdir",
3322 if test "${enable_version_specific_runtime_libs+set}" = set; then
3323   slibdir='$(libsubdir)'
3324 elif test "$host" != "$target"; then
3325   slibdir='$(build_tooldir)/lib'
3326 else
3327   slibdir='$(libdir)'
3328 fi)
3329 AC_SUBST(slibdir)
3330
3331 objdir=`${PWDCMD-pwd}`
3332 AC_SUBST(objdir)
3333
3334 # Substitute configuration variables
3335 AC_SUBST(subdirs)
3336 AC_SUBST(srcdir)
3337 AC_SUBST(all_boot_languages)
3338 AC_SUBST(all_compilers)
3339 AC_SUBST(all_gtfiles)
3340 AC_SUBST(all_gtfiles_files_langs)
3341 AC_SUBST(all_gtfiles_files_files)
3342 AC_SUBST(all_lang_makefrags)
3343 AC_SUBST(all_lang_makefiles)
3344 AC_SUBST(all_languages)
3345 AC_SUBST(all_stagestuff)
3346 AC_SUBST(build_exeext)
3347 AC_SUBST(build_install_headers_dir)
3348 AC_SUBST(build_xm_file_list)
3349 AC_SUBST(build_xm_include_list)
3350 AC_SUBST(build_xm_defines)
3351 AC_SUBST(check_languages)
3352 AC_SUBST(cc_set_by_configure)
3353 AC_SUBST(quoted_cc_set_by_configure)
3354 AC_SUBST(cpp_install_dir)
3355 AC_SUBST(xmake_file)
3356 AC_SUBST(tmake_file)
3357 AC_SUBST(extra_gcc_objs)
3358 AC_SUBST(extra_headers_list)
3359 AC_SUBST(extra_objs)
3360 AC_SUBST(extra_parts)
3361 AC_SUBST(extra_passes)
3362 AC_SUBST(extra_programs)
3363 AC_SUBST(float_h_file)
3364 AC_SUBST(gcc_config_arguments)
3365 AC_SUBST(gcc_gxx_include_dir)
3366 AC_SUBST(libstdcxx_incdir)
3367 AC_SUBST(host_exeext)
3368 AC_SUBST(host_xm_file_list)
3369 AC_SUBST(host_xm_include_list)
3370 AC_SUBST(host_xm_defines)
3371 AC_SUBST(out_host_hook_obj)
3372 AC_SUBST(install)
3373 AC_SUBST(lang_opt_files)
3374 AC_SUBST(lang_specs_files)
3375 AC_SUBST(lang_tree_files)
3376 AC_SUBST(local_prefix)
3377 AC_SUBST(md_file)
3378 AC_SUBST(objc_boehm_gc)
3379 AC_SUBST(out_file)
3380 AC_SUBST(out_object_file)
3381 AC_SUBST(stage_prefix_set_by_configure)
3382 AC_SUBST(quoted_stage_prefix_set_by_configure)
3383 AC_SUBST(thread_file)
3384 AC_SUBST(tm_file_list)
3385 AC_SUBST(tm_include_list)
3386 AC_SUBST(tm_defines)
3387 AC_SUBST(tm_p_file_list)
3388 AC_SUBST(tm_p_include_list)
3389 AC_SUBST(xm_file_list)
3390 AC_SUBST(xm_include_list)
3391 AC_SUBST(xm_defines)
3392 AC_SUBST(c_target_objs)
3393 AC_SUBST(cxx_target_objs)
3394 AC_SUBST(target_cpu_default)
3395
3396 AC_SUBST_FILE(language_hooks)
3397
3398 # Echo link setup.
3399 if test x${build} = x${host} ; then
3400   if test x${host} = x${target} ; then
3401     echo "Links are now set up to build a native compiler for ${target}." 1>&2
3402   else
3403     echo "Links are now set up to build a cross-compiler" 1>&2
3404     echo " from ${host} to ${target}." 1>&2
3405   fi
3406 else
3407   if test x${host} = x${target} ; then
3408     echo "Links are now set up to build (on ${build}) a native compiler" 1>&2
3409     echo " for ${target}." 1>&2
3410   else
3411     echo "Links are now set up to build (on ${build}) a cross-compiler" 1>&2
3412     echo " from ${host} to ${target}." 1>&2
3413   fi
3414 fi
3415
3416 AC_ARG_VAR(GMPLIBS,[How to link GMP])
3417 AC_ARG_VAR(GMPINC,[How to find GMP include files])
3418
3419 # Configure the subdirectories
3420 # AC_CONFIG_SUBDIRS($subdirs)
3421
3422 # Create the Makefile
3423 # and configure language subdirectories
3424 AC_CONFIG_FILES($all_outputs)
3425
3426 AC_CONFIG_COMMANDS([default],
3427 [
3428 case ${CONFIG_HEADERS} in
3429   *auto-host.h:config.in*)
3430   echo > cstamp-h ;;
3431 esac
3432 # Make sure all the subdirs exist.
3433 for d in $subdirs doc build
3434 do
3435     test -d $d || mkdir $d
3436 done
3437 # If the host supports symlinks, point stage[1234] at ../stage[1234] so
3438 # bootstrapping and the installation procedure can still use
3439 # CC="stage1/xgcc -Bstage1/".  If the host doesn't support symlinks,
3440 # FLAGS_TO_PASS has been modified to solve the problem there.
3441 # This is virtually a duplicate of what happens in configure.lang; we do
3442 # an extra check to make sure this only happens if ln -s can be used.
3443 case "$LN_S" in
3444   *-s*)
3445     for d in ${subdirs} ; do
3446         STARTDIR=`${PWDCMD-pwd}`
3447         cd $d
3448         for t in stage1 stage2 stage3 stage4 stageprofile stagefeedback include
3449         do
3450                 rm -f $t
3451                 $LN_S ../$t $t 2>/dev/null
3452         done
3453         cd $STARTDIR
3454     done
3455   ;;
3456 esac
3457 ],
3458 [subdirs='$subdirs'])
3459 AC_OUTPUT