libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.59)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/ios.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # For libtool versioning info, format is CURRENT:REVISION:AGE
  15 libtool_VERSION=6:7:0
  16 AC_SUBST(libtool_VERSION)
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  22 #
  23 # You will slowly go insane if you do not grok the following fact:  when
  24 # building v3 as part of the compiler, the top-level /target/ becomes the
  25 # library's /host/.  configure then causes --target to default to --host,
  26 # exactly like any other package using autoconf.  Therefore, 'target' and
  27 # 'host' will always be the same.  This makes sense both for native and
  28 # cross compilers, just think about it for a little while.  :-)
  29 #
  30 # Also, if v3 is being configured as part of a cross compiler, the top-level
  31 # configure script will pass the "real" host as $with_cross_host.
  32 #
  33 # Do not delete or change the following two lines.  For why, see
  34 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  35 AC_CANONICAL_SYSTEM
  36 target_alias=${target_alias-$host_alias}
  37
  38 # Handy for debugging:
  39 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  40
  41 if test "$build" != "$host"; then
  42   # We are being configured with some form of cross compiler.
  43   GLIBCXX_IS_NATIVE=false
  44   case "$host","$target" in
  45     # Darwin crosses can use the host system's libraries and headers,
  46     # because of the fat library support.  Of course, it must be the
  47     # same version of Darwin on both sides.  Allow the user to
  48     # just say --target=foo-darwin without a version number to mean
  49     # "the version on this system".
  50       *-*-darwin*,*-*-darwin*)
  51         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  52         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  53         if test $hostos = $targetos -o $targetos = darwin ; then
  54           GLIBCXX_IS_NATIVE=true
  55         fi
  56         ;;
  57
  58       *)
  59         GCC_NO_EXECUTABLES
  60         ;;
  61   esac
  62 else
  63   GLIBCXX_IS_NATIVE=true
  64 fi
  65
  66 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  67 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  68 #  1.x:  minimum required version
  69 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  70 #              of other PACKAGE_* variables will, however, and there's nothing
  71 #              we can do about that; they come from AC_INIT).
  72 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  73 #            file in the top srcdir, etc, etc), so stop complaining.
  74 #  no-dependencies:  turns off auto dependency generation (just for now)
  75 #  -Wall:  turns on all automake warnings...
  76 #  -Wno-portability:  ...except this one, since GNU make is now required.
  77 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies -Wall -Wno-portability -Wno-override])
  78 AH_TEMPLATE(PACKAGE, [Name of package])
  79 AH_TEMPLATE(VERSION, [Version number of package])
  80
  81 # Runs configure.host, finds CC, CXX, and assorted other critical bits.  Sets
  82 # up critical shell variables.
  83 GLIBCXX_CONFIGURE
  84
  85 AC_LIBTOOL_DLOPEN
  86 AM_PROG_LIBTOOL
  87 AC_SUBST(enable_shared)
  88 AC_SUBST(enable_static)
  89
  90 # Possibly disable most of the library.
  91 ## TODO: Consider skipping unncessary tests altogether in this case, rather
  92 ## than just ignoring the results.  Faster /and/ more correct, win win.
  93 GLIBCXX_ENABLE_HOSTED
  94
  95 # Check for compiler support that doesn't require linking.
  96 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
  97 GLIBCXX_ENABLE_PCH($is_hosted)
  98
  99 # Enable all the variable C++ runtime options.
 100 GLIBCXX_ENABLE_CSTDIO
 101 GLIBCXX_ENABLE_CLOCALE
 102 GLIBCXX_ENABLE_ALLOCATOR
 103 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 104 GLIBCXX_ENABLE_C99([yes])
 105 GLIBCXX_ENABLE_LONG_LONG([yes])
 106 GLIBCXX_ENABLE_WCHAR_T([yes])
 107 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 108 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
 109 GLIBCXX_ENABLE_DEBUG([no])
 110 GLIBCXX_ENABLE_CXX_FLAGS
 111 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 112
 113 # No surprises, no surprises...
 114 GLIBCXX_ENABLE_THREADS
 115 if test $atomicity_dir = cpu/generic ; then
 116   AC_MSG_WARN([No native atomic operations are provided for this platform.])
 117   if test $target_thread_file = single; then
 118     AC_MSG_WARN([They cannot be faked when thread support is disabled.])
 119     AC_MSG_WARN([Thread-safety of certain classes is not guaranteed.])
 120   else
 121     AC_MSG_WARN([They will be faked using a mutex.])
 122     AC_MSG_WARN([Performance of certain classes will degrade as a result.])
 123   fi
 124 fi
 125
 126
 127 if $GLIBCXX_IS_NATIVE; then
 128
 129   # We can do more elaborate tests that assume a working linker.
 130   CANADIAN=no
 131
 132   # Check for available headers.
 133   AC_CHECK_HEADERS([nan.h ieeefp.h endian.h sys/isa_defs.h machine/endian.h \
 134   machine/param.h sys/machine.h fp.h locale.h float.h inttypes.h gconv.h \
 135   sys/types.h sys/ipc.h sys/sem.h])
 136
 137   GLIBCXX_CHECK_COMPILER_FEATURES
 138   GLIBCXX_CHECK_LINKER_FEATURES
 139   GLIBCXX_CHECK_MATH_SUPPORT
 140   GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 141   GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT
 142   GLIBCXX_CHECK_ICONV_SUPPORT
 143   GLIBCXX_CHECK_STDLIB_SUPPORT
 144
 145   # For showmanyc_helper().
 146   AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 147   GLIBCXX_CHECK_POLL
 148   GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 149
 150   # For xsputn_2().
 151   AC_CHECK_HEADERS(sys/uio.h)
 152   GLIBCXX_CHECK_WRITEV
 153
 154   # For the __streamoff_base_type typedef.
 155   GLIBCXX_CHECK_INT64_T
 156
 157   # For LFS support.
 158   GLIBCXX_CHECK_LFS
 159
 160   # For TLS support.
 161   GCC_CHECK_TLS
 162
 163   AC_LC_MESSAGES
 164
 165   AC_TRY_COMPILE(
 166     [#include <setjmp.h>],
 167     [sigjmp_buf env;
 168      while (! sigsetjmp (env, 1))
 169        siglongjmp (env, 1);
 170     ],
 171     [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available.])])
 172
 173   AC_FUNC_MMAP
 174
 175 else
 176
 177   # This lets us hard-code the functionality we know we'll have in the cross
 178   # target environment.  "Let" is a sugar-coated word placed on an especially
 179   # dull and tedious hack, actually.
 180   #
 181   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 182   # that involve linking, can't be used:
 183   #    "cannot open sim-crt0.o"
 184   #    "cannot open crt0.o"
 185   # etc.  All this is because there currently exists no unified, consistent
 186   # way for top level CC information to be passed down to target directories:
 187   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 188   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 189   # crosses can be removed.
 190
 191   # If Canadian cross, then don't pick up tools from the build directory.
 192   # Used only in GLIBCXX_EXPORT_INCLUDES.
 193   if test -n "$with_cross_host" &&
 194      test x"$build_alias" != x"$with_cross_host" &&
 195      test x"$build" != x"$target";
 196   then
 197     CANADIAN=yes
 198   else
 199     CANADIAN=no
 200   fi
 201
 202   # Construct crosses by hand, eliminating bits that need ld...
 203   # GLIBCXX_CHECK_COMPILER_FEATURES
 204   # GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 205   # GLIBCXX_CHECK_MATH_SUPPORT
 206
 207   # First, test for "known" system libraries.  We may be using newlib even
 208   # on a hosted environment.
 209   if test "x${with_newlib}" = "xyes"; then
 210     os_include_dir="os/newlib"
 211     AC_DEFINE(HAVE_HYPOT)
 212
 213     # GLIBCXX_CHECK_STDLIB_SUPPORT
 214     AC_DEFINE(HAVE_STRTOF)
 215     # AC_FUNC_MMAP
 216     AC_DEFINE(HAVE_MMAP)
 217
 218     AC_DEFINE(HAVE_ACOSF)
 219     AC_DEFINE(HAVE_ASINF)
 220     AC_DEFINE(HAVE_ATAN2F)
 221     AC_DEFINE(HAVE_ATANF)
 222     AC_DEFINE(HAVE_CEILF)
 223     AC_DEFINE(HAVE_COPYSIGN)
 224     AC_DEFINE(HAVE_COPYSIGNF)
 225     AC_DEFINE(HAVE_COSF)
 226     AC_DEFINE(HAVE_COSHF)
 227     AC_DEFINE(HAVE_EXPF)
 228     AC_DEFINE(HAVE_FABSF)
 229     AC_DEFINE(HAVE_FLOORF)
 230     AC_DEFINE(HAVE_FMODF)
 231     AC_DEFINE(HAVE_FREXPF)
 232     AC_DEFINE(HAVE_LDEXPF)
 233     AC_DEFINE(HAVE_LOG10F)
 234     AC_DEFINE(HAVE_LOGF)
 235     AC_DEFINE(HAVE_MODFF)
 236     AC_DEFINE(HAVE_POWF)
 237     AC_DEFINE(HAVE_SINF)
 238     AC_DEFINE(HAVE_SINHF)
 239     AC_DEFINE(HAVE_SQRTF)
 240     AC_DEFINE(HAVE_TANF)
 241     AC_DEFINE(HAVE_TANHF)
 242
 243     AC_DEFINE(HAVE_S_ISREG)
 244     AC_DEFINE(HAVE_S_IFREG)
 245   else
 246     GLIBCXX_CROSSCONFIG
 247   fi
 248
 249   # At some point, we should differentiate between architectures
 250   # like x86, which have long double versions, and alpha/powerpc/etc.,
 251   # which don't. For the time being, punt.
 252   if test x"long_double_math_on_this_cpu" = x"yes"; then
 253     AC_DEFINE(HAVE_ACOSL)
 254     AC_DEFINE(HAVE_ASINL)
 255     AC_DEFINE(HAVE_ATAN2L)
 256     AC_DEFINE(HAVE_ATANL)
 257     AC_DEFINE(HAVE_CEILL)
 258     AC_DEFINE(HAVE_COPYSIGNL)
 259     AC_DEFINE(HAVE_COSL)
 260     AC_DEFINE(HAVE_COSHL)
 261     AC_DEFINE(HAVE_EXPL)
 262     AC_DEFINE(HAVE_FABSL)
 263     AC_DEFINE(HAVE_FLOORL)
 264     AC_DEFINE(HAVE_FMODL)
 265     AC_DEFINE(HAVE_FREXPL)
 266     AC_DEFINE(HAVE_LDEXPL)
 267     AC_DEFINE(HAVE_LOG10L)
 268     AC_DEFINE(HAVE_LOGL)
 269     AC_DEFINE(HAVE_MODFL)
 270     AC_DEFINE(HAVE_POWL)
 271     AC_DEFINE(HAVE_SINCOSL)
 272     AC_DEFINE(HAVE_SINL)
 273     AC_DEFINE(HAVE_SINHL)
 274     AC_DEFINE(HAVE_SQRTL)
 275     AC_DEFINE(HAVE_TANL)
 276     AC_DEFINE(HAVE_TANHL)
 277   fi
 278
 279 fi
 280
 281 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
 282 GLIBCXX_ENABLE_SYMVERS([yes])
 283
 284 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 285 GLIBCXX_CONFIGURE_TESTSUITE
 286
 287 # Propagate the target-specific source directories through the build chain.
 288 ATOMICITY_SRCDIR=config/${atomicity_dir}
 289 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 290 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 291 OS_INC_SRCDIR=config/${os_include_dir}
 292 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 293 AC_SUBST(ATOMICITY_SRCDIR)
 294 AC_SUBST(ATOMIC_WORD_SRCDIR)
 295 AC_SUBST(CPU_DEFINES_SRCDIR)
 296 AC_SUBST(ABI_TWEAKS_SRCDIR)
 297 AC_SUBST(OS_INC_SRCDIR)
 298
 299 # Determine cross-compile flags and AM_CONDITIONALs.
 300 #AC_SUBST(GLIBCXX_IS_NATIVE)
 301 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 302 # from GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT:
 303 #AM_CONDITIONAL(GLIBCXX_BUILD_LIBMATH,  test $need_libmath = yes)
 304 GLIBCXX_EVALUATE_CONDITIONALS
 305
 306 AC_CACHE_SAVE
 307
 308 if test ${multilib} = yes; then
 309   multilib_arg="--enable-multilib"
 310 else
 311   multilib_arg=
 312 fi
 313
 314 # Export all the install information.
 315 GLIBCXX_EXPORT_INSTALL_INFO
 316
 317 # Export all the include and flag information to Makefiles.
 318 GLIBCXX_EXPORT_INCLUDES
 319 GLIBCXX_EXPORT_FLAGS
 320
 321 if ${CONFIG_SHELL-/bin/sh} ./libtool --tag CXX --features |
 322    grep "enable shared" > /dev/null;
 323 then
 324   LIBSUPCXX_PICFLAGS=-prefer-pic
 325 else
 326   LIBSUPCXX_PICFLAGS=
 327 fi
 328 AC_SUBST(LIBSUPCXX_PICFLAGS)
 329
 330 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 331 dnl which can all be called multiple times as needed, plus one (different)
 332 dnl AC_OUTPUT macro.  This one lists the files to be created:
 333 AC_CONFIG_FILES( \
 334   Makefile \
 335   AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ])
 336   )
 337 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 338
 339 dnl These commands are run at the end of config.status:
 340 AC_CONFIG_COMMANDS([default],
 341 [if test -n "$CONFIG_FILES"; then
 342    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 343    # that multilib installs will end up installed in the correct place.
 344    # The testsuite needs it for multilib-aware ABI baseline files.
 345    # To work around this not being passed down from config-ml.in ->
 346    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 347    # append it here.  Only modify Makefiles that have just been created.
 348    #
 349    # Also, get rid of this simulated-VPATH thing that automake does.
 350    cat > vpsed << \_EOF
 351 s!`test -f '$<' || echo '$(srcdir)/'`!!
 352 _EOF
 353    for i in $SUBDIRS; do
 354     case $CONFIG_FILES in
 355      *${i}/Makefile*)
 356        #echo "Adding MULTISUBDIR to $i/Makefile"
 357        sed -f vpsed $i/Makefile > tmp
 358        grep '^MULTISUBDIR =' Makefile >> tmp
 359        mv tmp $i/Makefile
 360        ;;
 361     esac
 362    done
 363    rm vpsed
 364  fi
 365  (cd include && ${MAKE-make})
 366 ],
 367 [
 368 # Variables needed in config.status (file generation) which aren't already
 369 # passed by autoconf.
 370 SUBDIRS="$SUBDIRS"
 371 ])
 372
 373 dnl And this actually makes things happen:
 374 AC_OUTPUT