gcc/ada/a-cforma.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --   A D A . C O N T A I N E R S . F O R M A L _ O R D E R E D _ M A P S    --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2004-2014, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  21 --                                                                          --
  22 -- As a special exception under Section 7 of GPL version 3, you are granted --
  23 -- additional permissions described in the GCC Runtime Library Exception,   --
  24 -- version 3.1, as published by the Free Software Foundation.               --
  25 --                                                                          --
  26 -- You should have received a copy of the GNU General Public License and    --
  27 -- a copy of the GCC Runtime Library Exception along with this program;     --
  28 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  29 -- <http://www.gnu.org/licenses/>.                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  This spec is derived from package Ada.Containers.Bounded_Ordered_Maps in
  33 --  the Ada 2012 RM. The modifications are meant to facilitate formal proofs by
  34 --  making it easier to express properties, and by making the specification of
  35 --  this unit compatible with SPARK 2014. Note that the API of this unit may be
  36 --  subject to incompatible changes as SPARK 2014 evolves.
  37
  38 --  The modifications are:
  39
  40 --    A parameter for the container is added to every function reading the
  41 --    content of a container: Key, Element, Next, Query_Element, Previous,
  42 --    Has_Element, Iterate, Reverse_Iterate. This change is motivated by the
  43 --    need to have cursors which are valid on different containers (typically a
  44 --    container C and its previous version C'Old) for expressing properties,
  45 --    which is not possible if cursors encapsulate an access to the underlying
  46 --    container. The operators "<" and ">" that could not be modified that way
  47 --    have been removed.
  48
  49 --    There are four new functions:
  50
  51 --      function Strict_Equal (Left, Right : Map) return Boolean;
  52 --      function Overlap (Left, Right : Map) return Boolean;
  53 --      function First_To_Previous  (Container : Map; Current : Cursor)
  54 --         return Map;
  55 --      function Current_To_Last (Container : Map; Current : Cursor)
  56 --         return Map;
  57
  58 --    See detailed specifications for these subprograms
  59
  60 private with Ada.Containers.Red_Black_Trees;
  61
  62 generic
  63    type Key_Type is private;
  64    type Element_Type is private;
  65
  66    with function "<" (Left, Right : Key_Type) return Boolean is <>;
  67    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  68
  69 package Ada.Containers.Formal_Ordered_Maps is
  70    pragma Annotate (GNATprove, External_Axiomatization);
  71    pragma Pure;
  72    pragma SPARK_Mode (On);
  73
  74    function Equivalent_Keys (Left, Right : Key_Type) return Boolean with
  75      Global => null;
  76
  77    type Map (Capacity : Count_Type) is private with
  78      Iterable => (First       => First,
  79                   Next        => Next,
  80                   Has_Element => Has_Element,
  81                   Element     => Element);
  82    pragma Preelaborable_Initialization (Map);
  83
  84    type Cursor is private;
  85    pragma Preelaborable_Initialization (Cursor);
  86
  87    Empty_Map : constant Map;
  88
  89    No_Element : constant Cursor;
  90
  91    function "=" (Left, Right : Map) return Boolean with
  92      Global => null;
  93
  94    function Length (Container : Map) return Count_Type with
  95      Global => null;
  96
  97    function Is_Empty (Container : Map) return Boolean with
  98      Global => null;
  99
 100    procedure Clear (Container : in out Map) with
 101      Global => null;
 102
 103    procedure Assign (Target : in out Map; Source : Map) with
 104      Global => null,
 105      Pre    => Target.Capacity >= Length (Source);
 106
 107    function Copy (Source : Map; Capacity : Count_Type := 0) return Map with
 108      Global => null,
 109      Pre    => Capacity = 0 or else Capacity >= Source.Capacity;
 110
 111    function Key (Container : Map; Position : Cursor) return Key_Type with
 112      Global => null,
 113      Pre    => Has_Element (Container, Position);
 114
 115    function Element
 116      (Container : Map;
 117       Position  : Cursor) return Element_Type
 118    with
 119      Global => null,
 120      Pre    => Has_Element (Container, Position);
 121
 122    procedure Replace_Element
 123      (Container : in out Map;
 124       Position  : Cursor;
 125       New_Item  : Element_Type)
 126    with
 127      Global => null,
 128      Pre    => Has_Element (Container, Position);
 129
 130    procedure Move (Target : in out Map; Source : in out Map) with
 131      Global => null,
 132      Pre    => Target.Capacity >= Length (Source);
 133
 134    procedure Insert
 135      (Container : in out Map;
 136       Key       : Key_Type;
 137       New_Item  : Element_Type;
 138       Position  : out Cursor;
 139       Inserted  : out Boolean)
 140    with
 141      Global => null,
 142      Pre    => Length (Container) < Container.Capacity;
 143
 144    procedure Insert
 145      (Container : in out Map;
 146       Key       : Key_Type;
 147       New_Item  : Element_Type)
 148    with
 149      Global => null,
 150      Pre    => Length (Container) < Container.Capacity
 151                  and then (not Contains (Container, Key));
 152
 153    procedure Include
 154      (Container : in out Map;
 155       Key       : Key_Type;
 156       New_Item  : Element_Type)
 157    with
 158      Global => null,
 159      Pre    => Length (Container) < Container.Capacity;
 160
 161    procedure Replace
 162      (Container : in out Map;
 163       Key       : Key_Type;
 164       New_Item  : Element_Type)
 165    with
 166      Global => null,
 167      Pre    => Contains (Container, Key);
 168
 169    procedure Exclude (Container : in out Map; Key : Key_Type) with
 170      Global => null;
 171
 172    procedure Delete (Container : in out Map; Key : Key_Type) with
 173      Global => null,
 174      Pre    => Contains (Container, Key);
 175
 176    procedure Delete (Container : in out Map; Position : in out Cursor) with
 177      Global => null,
 178      Pre    => Has_Element (Container, Position);
 179
 180    procedure Delete_First (Container : in out Map) with
 181      Global => null;
 182
 183    procedure Delete_Last (Container : in out Map) with
 184      Global => null;
 185
 186    function First (Container : Map) return Cursor with
 187      Global => null;
 188
 189    function First_Element (Container : Map) return Element_Type with
 190      Global => null,
 191      Pre    => not Is_Empty (Container);
 192
 193    function First_Key (Container : Map) return Key_Type with
 194      Global => null,
 195      Pre    => not Is_Empty (Container);
 196
 197    function Last (Container : Map) return Cursor with
 198      Global => null;
 199
 200    function Last_Element (Container : Map) return Element_Type with
 201      Global => null,
 202      Pre    => not Is_Empty (Container);
 203
 204    function Last_Key (Container : Map) return Key_Type with
 205      Global => null,
 206      Pre    => not Is_Empty (Container);
 207
 208    function Next (Container : Map; Position : Cursor) return Cursor with
 209      Global => null,
 210      Pre    => Has_Element (Container, Position) or else Position = No_Element;
 211
 212    procedure Next (Container : Map; Position : in out Cursor) with
 213      Global => null,
 214      Pre    => Has_Element (Container, Position) or else Position = No_Element;
 215
 216    function Previous (Container : Map; Position : Cursor) return Cursor with
 217      Global => null,
 218      Pre    => Has_Element (Container, Position) or else Position = No_Element;
 219
 220    procedure Previous (Container : Map; Position : in out Cursor) with
 221      Global => null,
 222      Pre    => Has_Element (Container, Position) or else Position = No_Element;
 223
 224    function Find (Container : Map; Key : Key_Type) return Cursor with
 225      Global => null;
 226
 227    function Element (Container : Map; Key : Key_Type) return Element_Type with
 228      Global => null,
 229      Pre    => Contains (Container, Key);
 230
 231    function Floor (Container : Map; Key : Key_Type) return Cursor with
 232      Global => null;
 233
 234    function Ceiling (Container : Map; Key : Key_Type) return Cursor with
 235      Global => null;
 236
 237    function Contains (Container : Map; Key : Key_Type) return Boolean with
 238      Global => null;
 239
 240    function Has_Element (Container : Map; Position : Cursor) return Boolean
 241    with
 242      Global => null;
 243
 244    function Strict_Equal (Left, Right : Map) return Boolean with
 245      Global => null;
 246    --  Strict_Equal returns True if the containers are physically equal, i.e.
 247    --  they are structurally equal (function "=" returns True) and that they
 248    --  have the same set of cursors.
 249
 250    function First_To_Previous (Container : Map; Current : Cursor) return Map
 251    with
 252      Global => null,
 253      Pre    => Has_Element (Container, Current) or else Current = No_Element;
 254    function Current_To_Last (Container : Map; Current : Cursor) return Map
 255    with
 256      Global => null,
 257      Pre    => Has_Element (Container, Current) or else Current = No_Element;
 258    --  First_To_Previous returns a container containing all elements preceding
 259    --  Current (excluded) in Container. Current_To_Last returns a container
 260    --  containing all elements following Current (included) in Container.
 261    --  These two new functions can be used to express invariant properties in
 262    --  loops which iterate over containers. First_To_Previous returns the part
 263    --  of the container already scanned and Current_To_Last the part not
 264    --  scanned yet.
 265
 266    function Overlap (Left, Right : Map) return Boolean with
 267      Global => null;
 268    --  Overlap returns True if the containers have common keys
 269
 270 private
 271    pragma Inline (Next);
 272    pragma Inline (Previous);
 273    pragma SPARK_Mode (Off);
 274
 275    subtype Node_Access is Count_Type;
 276
 277    use Red_Black_Trees;
 278
 279    type Node_Type is record
 280       Has_Element : Boolean := False;
 281       Parent  : Node_Access := 0;
 282       Left    : Node_Access := 0;
 283       Right   : Node_Access := 0;
 284       Color   : Red_Black_Trees.Color_Type := Red;
 285       Key     : Key_Type;
 286       Element : Element_Type;
 287    end record;
 288
 289    package Tree_Types is
 290      new Ada.Containers.Red_Black_Trees.Generic_Bounded_Tree_Types (Node_Type);
 291
 292    type Map (Capacity : Count_Type) is
 293      new Tree_Types.Tree_Type (Capacity) with null record;
 294
 295    type Cursor is record
 296       Node : Node_Access;
 297    end record;
 298
 299    Empty_Map : constant Map := (Capacity => 0, others => <>);
 300
 301    No_Element : constant Cursor := (Node => 0);
 302
 303 end Ada.Containers.Formal_Ordered_Maps;