gcc/ada/a-cfhase.ads

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT LIBRARY COMPONENTS                          --
   4 --                                                                          --
   5 --    A D A . C O N T A I N E R S . F O R M A L _ H A S H E D _ S E T S     --
   6 --                                                                          --
   7 --                                 S p e c                                  --
   8 --                                                                          --
   9 --          Copyright (C) 2004-2014, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- This specification is derived from the Ada Reference Manual for use with --
  12 -- GNAT. The copyright notice above, and the license provisions that follow --
  13 -- apply solely to the  contents of the part following the private keyword. --
  14 --                                                                          --
  15 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  16 -- terms of the  GNU General Public License as published  by the Free Soft- --
  17 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  18 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  19 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  20 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  21 --                                                                          --
  22 -- As a special exception under Section 7 of GPL version 3, you are granted --
  23 -- additional permissions described in the GCC Runtime Library Exception,   --
  24 -- version 3.1, as published by the Free Software Foundation.               --
  25 --                                                                          --
  26 -- You should have received a copy of the GNU General Public License and    --
  27 -- a copy of the GCC Runtime Library Exception along with this program;     --
  28 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  29 -- <http://www.gnu.org/licenses/>.                                          --
  30 ------------------------------------------------------------------------------
  31
  32 --  This spec is derived from package Ada.Containers.Bounded_Hashed_Sets in the
  33 --  Ada 2012 RM. The modifications are meant to facilitate formal proofs by
  34 --  making it easier to express properties, and by making the specification of
  35 --  this unit compatible with SPARK 2014. Note that the API of this unit may be
  36 --  subject to incompatible changes as SPARK 2014 evolves.
  37
  38 --  The modifications are:
  39
  40 --    A parameter for the container is added to every function reading the
  41 --    content of a container: Element, Next, Query_Element, Has_Element, Key,
  42 --    Iterate, Equivalent_Elements. This change is motivated by the need to
  43 --    have cursors which are valid on different containers (typically a
  44 --    container C and its previous version C'Old) for expressing properties,
  45 --    which is not possible if cursors encapsulate an access to the underlying
  46 --    container.
  47
  48 --    There are three new functions:
  49
  50 --      function Strict_Equal (Left, Right : Set) return Boolean;
  51 --      function First_To_Previous  (Container : Set; Current : Cursor)
  52 --         return Set;
  53 --      function Current_To_Last (Container : Set; Current : Cursor)
  54 --         return Set;
  55
  56 --    See detailed specifications for these subprograms
  57
  58 private with Ada.Containers.Hash_Tables;
  59
  60 generic
  61    type Element_Type is private;
  62
  63    with function Hash (Element : Element_Type) return Hash_Type;
  64
  65    with function Equivalent_Elements (Left, Right : Element_Type)
  66                                       return Boolean;
  67
  68    with function "=" (Left, Right : Element_Type) return Boolean is <>;
  69
  70 package Ada.Containers.Formal_Hashed_Sets is
  71    pragma Annotate (GNATprove, External_Axiomatization);
  72    pragma Pure;
  73    pragma SPARK_Mode (On);
  74
  75    type Set (Capacity : Count_Type; Modulus : Hash_Type) is private with
  76      Iterable => (First       => First,
  77                   Next        => Next,
  78                   Has_Element => Has_Element,
  79                   Element     => Element);
  80    pragma Preelaborable_Initialization (Set);
  81
  82    type Cursor is private;
  83    pragma Preelaborable_Initialization (Cursor);
  84
  85    Empty_Set : constant Set;
  86
  87    No_Element : constant Cursor;
  88
  89    function "=" (Left, Right : Set) return Boolean with
  90      Global => null;
  91
  92    function Equivalent_Sets (Left, Right : Set) return Boolean with
  93      Global => null;
  94
  95    function To_Set (New_Item : Element_Type) return Set with
  96      Global => null;
  97
  98    function Capacity (Container : Set) return Count_Type with
  99      Global => null;
 100
 101    procedure Reserve_Capacity
 102      (Container : in out Set;
 103       Capacity  : Count_Type)
 104    with
 105      Global => null,
 106      Pre    => Capacity <= Container.Capacity;
 107
 108    function Length (Container : Set) return Count_Type with
 109      Global => null;
 110
 111    function Is_Empty (Container : Set) return Boolean with
 112      Global => null;
 113
 114    procedure Clear (Container : in out Set) with
 115      Global => null;
 116
 117    procedure Assign (Target : in out Set; Source : Set) with
 118      Global => null,
 119      Pre    => Target.Capacity >= Length (Source);
 120
 121    function Copy
 122      (Source   : Set;
 123       Capacity : Count_Type := 0) return Set
 124    with
 125      Global => null,
 126      Pre    => Capacity = 0 or else Capacity >= Source.Capacity;
 127
 128    function Element
 129      (Container : Set;
 130       Position  : Cursor) return Element_Type
 131    with
 132      Global => null,
 133      Pre    => Has_Element (Container, Position);
 134
 135    procedure Replace_Element
 136      (Container : in out Set;
 137       Position  : Cursor;
 138       New_Item  : Element_Type)
 139    with
 140      Global => null,
 141      Pre    => Has_Element (Container, Position);
 142
 143    procedure Move (Target : in out Set; Source : in out Set) with
 144      Global => null,
 145      Pre    => Target.Capacity >= Length (Source);
 146
 147    procedure Insert
 148      (Container : in out Set;
 149       New_Item  : Element_Type;
 150       Position  : out Cursor;
 151       Inserted  : out Boolean)
 152    with
 153      Global => null,
 154      Pre    => Length (Container) < Container.Capacity;
 155
 156    procedure Insert  (Container : in out Set; New_Item : Element_Type) with
 157      Global => null,
 158      Pre    => Length (Container) < Container.Capacity
 159                  and then (not Contains (Container, New_Item));
 160
 161    procedure Include (Container : in out Set; New_Item : Element_Type) with
 162      Global => null,
 163      Pre    => Length (Container) < Container.Capacity;
 164
 165    procedure Replace (Container : in out Set; New_Item : Element_Type) with
 166      Global => null,
 167      Pre    => Contains (Container, New_Item);
 168
 169    procedure Exclude (Container : in out Set; Item     : Element_Type) with
 170      Global => null;
 171
 172    procedure Delete  (Container : in out Set; Item     : Element_Type) with
 173      Global => null,
 174      Pre    => Contains (Container, Item);
 175
 176    procedure Delete (Container : in out Set; Position  : in out Cursor) with
 177      Global => null,
 178      Pre    => Has_Element (Container, Position);
 179
 180    procedure Union (Target : in out Set; Source : Set) with
 181      Global => null,
 182      Pre    => Length (Target) + Length (Source) -
 183                  Length (Intersection (Target, Source)) <= Target.Capacity;
 184
 185    function Union (Left, Right : Set) return Set with
 186      Global => null,
 187      Pre    => Length (Left) + Length (Right) -
 188                  Length (Intersection (Left, Right)) <= Count_Type'Last;
 189
 190    function "or" (Left, Right : Set) return Set renames Union;
 191
 192    procedure Intersection (Target : in out Set; Source : Set) with
 193      Global => null;
 194
 195    function Intersection (Left, Right : Set) return Set with
 196      Global => null;
 197
 198    function "and" (Left, Right : Set) return Set renames Intersection;
 199
 200    procedure Difference (Target : in out Set; Source : Set) with
 201      Global => null;
 202
 203    function Difference (Left, Right : Set) return Set with
 204      Global => null;
 205
 206    function "-" (Left, Right : Set) return Set renames Difference;
 207
 208    procedure Symmetric_Difference (Target : in out Set; Source : Set) with
 209      Global => null,
 210      Pre    => Length (Target) + Length (Source) -
 211                  2 * Length (Intersection (Target, Source)) <= Target.Capacity;
 212
 213    function Symmetric_Difference (Left, Right : Set) return Set with
 214      Global => null,
 215      Pre    => Length (Left) + Length (Right) -
 216                  2 * Length (Intersection (Left, Right)) <= Count_Type'Last;
 217
 218    function "xor" (Left, Right : Set) return Set
 219      renames Symmetric_Difference;
 220
 221    function Overlap (Left, Right : Set) return Boolean with
 222      Global => null;
 223
 224    function Is_Subset (Subset : Set; Of_Set : Set) return Boolean with
 225      Global => null;
 226
 227    function First (Container : Set) return Cursor with
 228      Global => null;
 229
 230    function Next (Container : Set; Position : Cursor) return Cursor with
 231      Global => null,
 232      Pre    => Has_Element (Container, Position) or else Position = No_Element;
 233
 234    procedure Next (Container : Set; Position : in out Cursor) with
 235      Global => null,
 236      Pre    => Has_Element (Container, Position) or else Position = No_Element;
 237
 238    function Find
 239      (Container : Set;
 240       Item      : Element_Type) return Cursor
 241    with
 242      Global => null;
 243
 244    function Contains (Container : Set; Item : Element_Type) return Boolean with
 245      Global => null;
 246
 247    function Has_Element (Container : Set; Position : Cursor) return Boolean
 248    with
 249      Global => null;
 250
 251    function Equivalent_Elements (Left  : Set; CLeft : Cursor;
 252                                  Right : Set; CRight : Cursor) return Boolean
 253    with
 254      Global => null;
 255
 256    function Equivalent_Elements
 257      (Left  : Set; CLeft : Cursor;
 258       Right : Element_Type) return Boolean
 259    with
 260      Global => null;
 261
 262    function Equivalent_Elements
 263      (Left  : Element_Type;
 264       Right : Set; CRight : Cursor) return Boolean
 265    with
 266      Global => null;
 267
 268    function Default_Modulus (Capacity : Count_Type) return Hash_Type with
 269      Global => null;
 270
 271    generic
 272       type Key_Type (<>) is private;
 273
 274       with function Key (Element : Element_Type) return Key_Type;
 275
 276       with function Hash (Key : Key_Type) return Hash_Type;
 277
 278       with function Equivalent_Keys (Left, Right : Key_Type) return Boolean;
 279
 280    package Generic_Keys is
 281
 282       function Key (Container : Set; Position : Cursor) return Key_Type with
 283         Global => null;
 284
 285       function Element (Container : Set; Key : Key_Type) return Element_Type
 286       with
 287           Global => null;
 288
 289       procedure Replace
 290         (Container : in out Set;
 291          Key       : Key_Type;
 292          New_Item  : Element_Type)
 293       with
 294           Global => null;
 295
 296       procedure Exclude (Container : in out Set; Key : Key_Type) with
 297         Global => null;
 298
 299       procedure Delete (Container : in out Set; Key : Key_Type) with
 300         Global => null;
 301
 302       function Find (Container : Set; Key : Key_Type) return Cursor with
 303         Global => null;
 304
 305       function Contains (Container : Set; Key : Key_Type) return Boolean with
 306         Global => null;
 307
 308    end Generic_Keys;
 309
 310    function Strict_Equal (Left, Right : Set) return Boolean with
 311      Global => null;
 312    --  Strict_Equal returns True if the containers are physically equal, i.e.
 313    --  they are structurally equal (function "=" returns True) and that they
 314    --  have the same set of cursors.
 315
 316    function First_To_Previous  (Container : Set; Current : Cursor) return Set
 317    with
 318      Global => null,
 319      Pre    => Has_Element (Container, Current) or else Current = No_Element;
 320    function Current_To_Last (Container : Set; Current : Cursor) return Set
 321    with
 322      Global => null,
 323      Pre    => Has_Element (Container, Current) or else Current = No_Element;
 324    --  First_To_Previous returns a container containing all elements preceding
 325    --  Current (excluded) in Container. Current_To_Last returns a container
 326    --  containing all elements following Current (included) in Container.
 327    --  These two new functions can be used to express invariant properties in
 328    --  loops which iterate over containers. First_To_Previous returns the part
 329    --  of the container already scanned and Current_To_Last the part not
 330    --  scanned yet.
 331
 332 private
 333    pragma Inline (Next);
 334    pragma SPARK_Mode (Off);
 335
 336    type Node_Type is
 337       record
 338          Element     : Element_Type;
 339          Next        : Count_Type;
 340          Has_Element : Boolean := False;
 341       end record;
 342
 343    package HT_Types is new
 344      Ada.Containers.Hash_Tables.Generic_Bounded_Hash_Table_Types (Node_Type);
 345
 346    type Set (Capacity : Count_Type; Modulus : Hash_Type) is
 347      new HT_Types.Hash_Table_Type (Capacity, Modulus) with null record;
 348
 349    use HT_Types;
 350
 351    type Cursor is record
 352       Node : Count_Type;
 353    end record;
 354
 355    No_Element : constant Cursor := (Node => 0);
 356
 357    Empty_Set : constant Set := (Capacity => 0, Modulus => 0, others => <>);
 358
 359 end Ada.Containers.Formal_Hashed_Sets;