libgfortran/configure.ac

   1 # Process this file with autoconf to produce a configure script, like so:
   2 # aclocal && autoconf && autoheader && automake
   3
   4 AC_PREREQ(2.64)
   5 AC_INIT([GNU Fortran Runtime Library], 0.3,,[libgfortran])
   6 AC_CONFIG_HEADER(config.h)
   7 GCC_TOPLEV_SUBDIRS
   8
   9 # -------
  10 # Options
  11 # -------
  12
  13 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  14 AC_ARG_ENABLE(version-specific-runtime-libs,
  15 AS_HELP_STRING([--enable-version-specific-runtime-libs],
  16   [specify that runtime libraries should be installed in a compiler-specific directory]),
  17 [case "$enableval" in
  18  yes) version_specific_libs=yes ;;
  19  no)  version_specific_libs=no ;;
  20  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  21  esac],
  22 [version_specific_libs=no])
  23 AC_MSG_RESULT($version_specific_libs)
  24
  25 # Build with intermodule optimisations
  26 AC_MSG_CHECKING([for --enable-intermodule])
  27 AC_ARG_ENABLE(intermodule,
  28 AS_HELP_STRING([--enable-intermodule],[build the library in one step]),
  29 [case "$enable_intermodule" in
  30   yes) onestep="-onestep";;
  31     *) onestep="";;
  32 esac],
  33 [onestep=""])
  34 AC_MSG_RESULT($enable_intermodule)
  35 AM_CONDITIONAL(onestep,[test x$onestep = x-onestep])
  36 AC_SUBST(onestep)
  37
  38 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  39 #
  40 # You will slowly go insane if you do not grok the following fact:  when
  41 # building this library, the top-level /target/ becomes the library's /host/.
  42 #
  43 # configure then causes --target to default to --host, exactly like any
  44 # other package using autoconf.  Therefore, 'target' and 'host' will
  45 # always be the same.  This makes sense both for native and cross compilers
  46 # just think about it for a little while.  :-)
  47 #
  48 # Also, if this library is being configured as part of a cross compiler, the
  49 # top-level configure script will pass the "real" host as $with_cross_host.
  50 #
  51 # Do not delete or change the following two lines.  For why, see
  52 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  53 AC_CANONICAL_SYSTEM
  54 ACX_NONCANONICAL_TARGET
  55
  56 target_alias=${target_alias-$host_alias}
  57 AC_SUBST(target_alias)
  58
  59 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  60 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  61 #  1.9.6:  minimum required version
  62 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  63 #              of other PACKAGE_* variables will, however, and there's nothing
  64 #              we can do about that; they come from AC_INIT).
  65 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  66 #            file in the top srcdir, etc, etc), so stop complaining.
  67 #  no-dist:  we don't want 'dist' and related rules.
  68 #  -Wall:  turns on all automake warnings...
  69 #  -Wno-portability:  ...except this one, since GNU make is required.
  70 AM_INIT_AUTOMAKE([1.9.6 no-define foreign no-dist -Wall -Wno-portability])
  71
  72 AM_MAINTAINER_MODE
  73 AM_ENABLE_MULTILIB(, ..)
  74
  75 # Handy for debugging:
  76 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  77
  78 # Are we being configured with some form of cross compiler?
  79 # NB: We don't actually need to know this just now, but when, say, a test
  80 #     suite is included, we'll have to know.
  81 if test "$build" != "$host"; then
  82   LIBGFOR_IS_NATIVE=false
  83   GCC_NO_EXECUTABLES
  84 else
  85   LIBGFOR_IS_NATIVE=true
  86 fi
  87
  88 AC_USE_SYSTEM_EXTENSIONS
  89
  90 # Calculate toolexeclibdir
  91 # Also toolexecdir, though it's only used in toolexeclibdir
  92 case ${version_specific_libs} in
  93   yes)
  94     # Need the gcc compiler version to know where to install libraries
  95     # and header files if --enable-version-specific-runtime-libs option
  96     # is selected.
  97     toolexecdir='$(libdir)/gcc/$(target_alias)'
  98     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  99     ;;
 100   no)
 101     if test -n "$with_cross_host" &&
 102        test x"$with_cross_host" != x"no"; then
 103       # Install a library built with a cross compiler in tooldir, not libdir.
 104       toolexecdir='$(exec_prefix)/$(target_alias)'
 105       toolexeclibdir='$(toolexecdir)/lib'
 106     else
 107       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 108       toolexeclibdir='$(libdir)'
 109     fi
 110     multi_os_directory=`$CC -print-multi-os-directory`
 111     case $multi_os_directory in
 112       .) ;; # Avoid trailing /.
 113       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 114     esac
 115     ;;
 116 esac
 117 AC_SUBST(toolexecdir)
 118 AC_SUBST(toolexeclibdir)
 119
 120 # Create a spec file, so that compile/link tests don't fail
 121 test -f libgfortran.spec || touch libgfortran.spec
 122
 123 AC_LANG_C
 124 # Check the compiler.
 125 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
 126 # We must force CC to /not/ be precious variables; otherwise
 127 # the wrong, non-multilib-adjusted value will be used in multilibs.
 128 # As a side effect, we have to subst CFLAGS ourselves.
 129
 130 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 131 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 132 AC_PROG_CC
 133 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 134
 135 AC_SUBST(CFLAGS)
 136
 137 AM_PROG_CC_C_O
 138
 139 # Add -Wall -fno-repack-arrays -fno-underscoring if we are using GCC.
 140 if test "x$GCC" = "xyes"; then
 141   AM_FCFLAGS="-I . -Wall -Werror -fimplicit-none -fno-repack-arrays -fno-underscoring"
 142   ## We like to use C11 and C99 routines when available.  This makes
 143   ## sure that
 144   ## __STDC_VERSION__ is set such that libc includes make them available.
 145   AM_CFLAGS="-std=gnu11 -Wall -Wstrict-prototypes -Wmissing-prototypes -Wold-style-definition -Wextra -Wwrite-strings -Werror=implicit-function-declaration -Werror=vla"
 146   ## Compile the following tests with the same system header contents
 147   ## that we'll encounter when compiling our own source files.
 148   CFLAGS="-std=gnu11 $CFLAGS"
 149 fi
 150
 151 # Add CET specific flags if CET is enabled
 152 GCC_CET_FLAGS(CET_FLAGS)
 153 AM_FCFLAGS="$AM_FCFLAGS $CET_FLAGS"
 154 AM_CFLAGS="$AM_CFLAGS $CET_FLAGS"
 155 CFLAGS="$CFLAGS $CET_FLAGS"
 156
 157 AC_SUBST(AM_FCFLAGS)
 158 AC_SUBST(AM_CFLAGS)
 159 AC_SUBST(CFLAGS)
 160
 161 # Check for symbol versioning (copied from libssp).
 162 AC_MSG_CHECKING([whether symbol versioning is supported])
 163 AC_ARG_ENABLE(symvers,
 164 AS_HELP_STRING([--disable-symvers],
 165   [disable symbol versioning for libgfortran]),
 166 gfortran_use_symver=$enableval,
 167 gfortran_use_symver=yes)
 168 if test "x$gfortran_use_symver" != xno; then
 169   save_LDFLAGS="$LDFLAGS"
 170   LDFLAGS="$LDFLAGS -fPIC -shared -Wl,--version-script,./conftest.map"
 171   cat > conftest.map <<EOF
 172 FOO_1.0 {
 173   global: *foo*; bar; local: *;
 174 };
 175 EOF
 176   AC_LINK_IFELSE([AC_LANG_PROGRAM([[int foo;]],[[]])],[gfortran_use_symver=gnu],[gfortran_use_symver=no])
 177   if test x$gfortran_use_symver = xno; then
 178     case "$target_os" in
 179       solaris2*)
 180         LDFLAGS="$save_LDFLAGS"
 181         LDFLAGS="$LDFLAGS -fPIC -shared -Wl,-M,./conftest.map"
 182         # Sun ld cannot handle wildcards and treats all entries as undefined.
 183         cat > conftest.map <<EOF
 184 FOO_1.0 {
 185   global: foo; local: *;
 186 };
 187 EOF
 188         AC_LINK_IFELSE([AC_LANG_PROGRAM([[int foo;]],[[]])],[gfortran_use_symver=sun],[gfortran_use_symver=no])
 189         ;;
 190     esac
 191   fi
 192   LDFLAGS="$save_LDFLAGS"
 193 fi
 194 AC_MSG_RESULT($gfortran_use_symver)
 195 AM_CONDITIONAL(LIBGFOR_USE_SYMVER, [test "x$gfortran_use_symver" != xno])
 196 AM_CONDITIONAL(LIBGFOR_USE_SYMVER_GNU, [test "x$gfortran_use_symver" = xgnu])
 197 AM_CONDITIONAL(LIBGFOR_USE_SYMVER_SUN, [test "x$gfortran_use_symver" = xsun])
 198
 199 # For GPU offloading, not everything in libfortran can be supported.
 200 # Currently, the only target that has this problem is nvptx.  The
 201 # following is a (partial) list of features that are unsupportable on
 202 # this particular target:
 203 # * Constructors
 204 # * alloca
 205 # * C library support for I/O, with printf as the one notable exception
 206 # * C library support for other features such as signal, environment
 207 #   variables, time functions
 208
 209 AM_CONDITIONAL(LIBGFOR_MINIMAL, [test "x${target_cpu}" = xnvptx])
 210
 211 # Figure out whether the compiler supports "-ffunction-sections -fdata-sections",
 212 # similarly to how libstdc++ does it
 213 ac_test_CFLAGS="${CFLAGS+set}"
 214 ac_save_CFLAGS="$CFLAGS"
 215
 216 # Check for -ffunction-sections -fdata-sections
 217 AC_MSG_CHECKING([for gcc that supports -ffunction-sections -fdata-sections])
 218 CFLAGS='-Werror -ffunction-sections -fdata-sections'
 219 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[int foo;]])], [ac_fdsections=yes], [ac_fdsections=no])
 220 if test "$ac_test_CFLAGS" = set; then
 221   CFLAGS="$ac_save_CFLAGS"
 222 else
 223   # this is the suspicious part
 224   CFLAGS=""
 225 fi
 226 if test x"$ac_fdsections" = x"yes"; then
 227   SECTION_FLAGS='-ffunction-sections -fdata-sections'
 228 fi
 229 AC_MSG_RESULT($ac_fdsections)
 230 AC_SUBST(SECTION_FLAGS)
 231
 232 # Check linker hardware capability support.
 233 GCC_CHECK_LINKER_HWCAP
 234
 235 # Find other programs we need.
 236 AC_CHECK_TOOL(AS, as)
 237 AC_CHECK_TOOL(AR, ar)
 238 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 239 AC_PROG_MAKE_SET
 240 AC_PROG_INSTALL
 241
 242 # Configure libtool
 243 #AC_MSG_NOTICE([====== Starting libtool configuration])
 244 AC_LIBTOOL_DLOPEN
 245 AM_PROG_LIBTOOL
 246 ACX_LT_HOST_FLAGS
 247 AC_SUBST(enable_shared)
 248 AC_SUBST(enable_static)
 249 #AC_MSG_NOTICE([====== Finished libtool configuration]) ; sleep 10
 250
 251 # We need gfortran to compile parts of the library
 252 #AC_PROG_FC(gfortran)
 253 FC="$GFORTRAN"
 254 AC_PROG_FC(gfortran)
 255
 256 # extra LD Flags which are required for targets
 257 case "${host}" in
 258   *-darwin*)
 259     # Darwin needs -single_module when linking libgfortran
 260     extra_ldflags_libgfortran=-Wl,-single_module
 261     ;;
 262 esac
 263 AC_SUBST(extra_ldflags_libgfortran)
 264
 265 # We need a working compiler at that point, otherwise give a clear
 266 # error message and bail out.
 267 LIBGFOR_WORKING_GFORTRAN
 268
 269 AC_SYS_LARGEFILE
 270
 271 # Types
 272 AC_TYPE_OFF_T
 273 AC_TYPE_INTPTR_T
 274 AC_TYPE_UINTPTR_T
 275 AC_CHECK_TYPES([ptrdiff_t])
 276
 277 # check header files (we assume C89 is available, so don't check for that)
 278 AC_CHECK_HEADERS_ONCE(unistd.h sys/time.h sys/times.h sys/resource.h \
 279 sys/types.h sys/stat.h sys/wait.h floatingpoint.h ieeefp.h fenv.h fptrap.h \
 280 fpxcp.h pwd.h complex.h xlocale.h)
 281
 282 GCC_HEADER_STDINT(gstdint.h)
 283
 284 AC_CHECK_MEMBERS([struct stat.st_blksize, struct stat.st_blocks, struct stat.st_rdev])
 285
 286 case "${host}--x${with_newlib}" in
 287   mips*--xyes)
 288     hardwire_newlib=1;;
 289   nvptx*--xyes)
 290     hardwire_newlib=1;;
 291 esac
 292
 293 # Check for library functions.
 294 if test "${hardwire_newlib:-0}" -eq 1; then
 295    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 296    # may not work correctly, because the compiler may not be able to
 297    # link executables.
 298    AC_DEFINE(HAVE_MKSTEMP, 1, [Define if you have mkstemp.])
 299    AC_DEFINE(HAVE_STRTOF, 1, [Define if you have strtof.])
 300    AC_DEFINE(HAVE_SNPRINTF, 1, [Define if you have snprintf.])
 301    AC_DEFINE(HAVE_VSNPRINTF, 1, [Define if you have vsnprintf.])
 302    AC_DEFINE(HAVE_LOCALTIME_R, 1, [Define if you have localtime_r.])
 303    AC_DEFINE(HAVE_GMTIME_R, 1, [Define if you have gmtime_r.])
 304    AC_DEFINE(HAVE_STRNLEN, 1, [Define if you have strnlen.])
 305    AC_DEFINE(HAVE_STRNDUP, 1, [Define if you have strndup.])
 306
 307    # At some point, we should differentiate between architectures
 308    # like x86, which have long double versions, and alpha/powerpc/etc.,
 309    # which don't. For the time being, punt.
 310    if test x"long_double_math_on_this_cpu" = x"yes"; then
 311      AC_DEFINE(HAVE_STRTOLD, 1, [Define if you have strtold.])
 312    fi
 313 else
 314    AC_CHECK_FUNCS_ONCE(getrusage times mkstemp strtof strtold snprintf \
 315    ftruncate chsize chdir getlogin gethostname kill link symlink sleep ttyname \
 316    alarm access fork setmode fcntl \
 317    gettimeofday stat fstat lstat getpwuid vsnprintf dup \
 318    getcwd localtime_r gmtime_r getpwuid_r ttyname_r clock_gettime \
 319    getgid getpid getuid geteuid umask getegid \
 320    secure_getenv __secure_getenv mkostemp strnlen strndup newlocale \
 321    freelocale uselocale strerror_l)
 322 fi
 323
 324 # Check strerror_r, cannot be above as versions with two and three arguments exist
 325 LIBGFOR_CHECK_STRERROR_R
 326
 327 # Check for C99 (and other IEEE) math functions
 328 GCC_CHECK_MATH_FUNC([acosf])
 329 GCC_CHECK_MATH_FUNC([acos])
 330 GCC_CHECK_MATH_FUNC([acosl])
 331 GCC_CHECK_MATH_FUNC([acoshf])
 332 GCC_CHECK_MATH_FUNC([acosh])
 333 GCC_CHECK_MATH_FUNC([acoshl])
 334 GCC_CHECK_MATH_FUNC([asinf])
 335 GCC_CHECK_MATH_FUNC([asin])
 336 GCC_CHECK_MATH_FUNC([asinl])
 337 GCC_CHECK_MATH_FUNC([asinhf])
 338 GCC_CHECK_MATH_FUNC([asinh])
 339 GCC_CHECK_MATH_FUNC([asinhl])
 340 GCC_CHECK_MATH_FUNC([atan2f])
 341 GCC_CHECK_MATH_FUNC([atan2])
 342 GCC_CHECK_MATH_FUNC([atan2l])
 343 GCC_CHECK_MATH_FUNC([atanf])
 344 GCC_CHECK_MATH_FUNC([atan])
 345 GCC_CHECK_MATH_FUNC([atanl])
 346 GCC_CHECK_MATH_FUNC([atanhf])
 347 GCC_CHECK_MATH_FUNC([atanh])
 348 GCC_CHECK_MATH_FUNC([atanhl])
 349 GCC_CHECK_MATH_FUNC([cargf])
 350 GCC_CHECK_MATH_FUNC([carg])
 351 GCC_CHECK_MATH_FUNC([cargl])
 352 GCC_CHECK_MATH_FUNC([ceilf])
 353 GCC_CHECK_MATH_FUNC([ceil])
 354 GCC_CHECK_MATH_FUNC([ceill])
 355 GCC_CHECK_MATH_FUNC([copysignf])
 356 GCC_CHECK_MATH_FUNC([copysign])
 357 GCC_CHECK_MATH_FUNC([copysignl])
 358 GCC_CHECK_MATH_FUNC([cosf])
 359 GCC_CHECK_MATH_FUNC([cos])
 360 GCC_CHECK_MATH_FUNC([cosl])
 361 GCC_CHECK_MATH_FUNC([ccosf])
 362 GCC_CHECK_MATH_FUNC([ccos])
 363 GCC_CHECK_MATH_FUNC([ccosl])
 364 GCC_CHECK_MATH_FUNC([coshf])
 365 GCC_CHECK_MATH_FUNC([cosh])
 366 GCC_CHECK_MATH_FUNC([coshl])
 367 GCC_CHECK_MATH_FUNC([ccoshf])
 368 GCC_CHECK_MATH_FUNC([ccosh])
 369 GCC_CHECK_MATH_FUNC([ccoshl])
 370 GCC_CHECK_MATH_FUNC([expf])
 371 GCC_CHECK_MATH_FUNC([exp])
 372 GCC_CHECK_MATH_FUNC([expl])
 373 GCC_CHECK_MATH_FUNC([cexpf])
 374 GCC_CHECK_MATH_FUNC([cexp])
 375 GCC_CHECK_MATH_FUNC([cexpl])
 376 GCC_CHECK_MATH_FUNC([fabsf])
 377 GCC_CHECK_MATH_FUNC([fabs])
 378 GCC_CHECK_MATH_FUNC([fabsl])
 379 GCC_CHECK_MATH_FUNC([cabsf])
 380 GCC_CHECK_MATH_FUNC([cabs])
 381 GCC_CHECK_MATH_FUNC([cabsl])
 382 GCC_CHECK_MATH_FUNC([floorf])
 383 GCC_CHECK_MATH_FUNC([floor])
 384 GCC_CHECK_MATH_FUNC([floorl])
 385 GCC_CHECK_MATH_FUNC([fmodf])
 386 GCC_CHECK_MATH_FUNC([fmod])
 387 GCC_CHECK_MATH_FUNC([fmodl])
 388 GCC_CHECK_MATH_FUNC([frexpf])
 389 GCC_CHECK_MATH_FUNC([frexp])
 390 GCC_CHECK_MATH_FUNC([frexpl])
 391 GCC_CHECK_MATH_FUNC([hypotf])
 392 GCC_CHECK_MATH_FUNC([hypot])
 393 GCC_CHECK_MATH_FUNC([hypotl])
 394 GCC_CHECK_MATH_FUNC([ldexpf])
 395 GCC_CHECK_MATH_FUNC([ldexp])
 396 GCC_CHECK_MATH_FUNC([ldexpl])
 397 GCC_CHECK_MATH_FUNC([logf])
 398 GCC_CHECK_MATH_FUNC([log])
 399 GCC_CHECK_MATH_FUNC([logl])
 400 GCC_CHECK_MATH_FUNC([clogf])
 401 GCC_CHECK_MATH_FUNC([clog])
 402 GCC_CHECK_MATH_FUNC([clogl])
 403 GCC_CHECK_MATH_FUNC([log10f])
 404 GCC_CHECK_MATH_FUNC([log10])
 405 GCC_CHECK_MATH_FUNC([log10l])
 406 GCC_CHECK_MATH_FUNC([clog10f])
 407 GCC_CHECK_MATH_FUNC([clog10])
 408 GCC_CHECK_MATH_FUNC([clog10l])
 409 GCC_CHECK_MATH_FUNC([nextafterf])
 410 GCC_CHECK_MATH_FUNC([nextafter])
 411 GCC_CHECK_MATH_FUNC([nextafterl])
 412 GCC_CHECK_MATH_FUNC([powf])
 413 GCC_CHECK_MATH_FUNC([pow])
 414 GCC_CHECK_MATH_FUNC([cpowf])
 415 GCC_CHECK_MATH_FUNC([cpow])
 416 GCC_CHECK_MATH_FUNC([cpowl])
 417 GCC_CHECK_MATH_FUNC([roundf])
 418 GCC_CHECK_MATH_FUNC([round])
 419 GCC_CHECK_MATH_FUNC([roundl])
 420 GCC_CHECK_MATH_FUNC([lroundf])
 421 GCC_CHECK_MATH_FUNC([lround])
 422 GCC_CHECK_MATH_FUNC([lroundl])
 423 GCC_CHECK_MATH_FUNC([llroundf])
 424 GCC_CHECK_MATH_FUNC([llround])
 425 GCC_CHECK_MATH_FUNC([llroundl])
 426 GCC_CHECK_MATH_FUNC([scalbnf])
 427 GCC_CHECK_MATH_FUNC([scalbn])
 428 GCC_CHECK_MATH_FUNC([scalbnl])
 429 GCC_CHECK_MATH_FUNC([sinf])
 430 GCC_CHECK_MATH_FUNC([sin])
 431 GCC_CHECK_MATH_FUNC([sinl])
 432 GCC_CHECK_MATH_FUNC([csinf])
 433 GCC_CHECK_MATH_FUNC([csin])
 434 GCC_CHECK_MATH_FUNC([csinl])
 435 GCC_CHECK_MATH_FUNC([sinhf])
 436 GCC_CHECK_MATH_FUNC([sinh])
 437 GCC_CHECK_MATH_FUNC([sinhl])
 438 GCC_CHECK_MATH_FUNC([csinhf])
 439 GCC_CHECK_MATH_FUNC([csinh])
 440 GCC_CHECK_MATH_FUNC([csinhl])
 441 GCC_CHECK_MATH_FUNC([sqrtf])
 442 GCC_CHECK_MATH_FUNC([sqrt])
 443 GCC_CHECK_MATH_FUNC([sqrtl])
 444 GCC_CHECK_MATH_FUNC([csqrtf])
 445 GCC_CHECK_MATH_FUNC([csqrt])
 446 GCC_CHECK_MATH_FUNC([csqrtl])
 447 GCC_CHECK_MATH_FUNC([tanf])
 448 GCC_CHECK_MATH_FUNC([tan])
 449 GCC_CHECK_MATH_FUNC([tanl])
 450 GCC_CHECK_MATH_FUNC([ctanf])
 451 GCC_CHECK_MATH_FUNC([ctan])
 452 GCC_CHECK_MATH_FUNC([ctanl])
 453 GCC_CHECK_MATH_FUNC([tanhf])
 454 GCC_CHECK_MATH_FUNC([tanh])
 455 GCC_CHECK_MATH_FUNC([tanhl])
 456 GCC_CHECK_MATH_FUNC([ctanhf])
 457 GCC_CHECK_MATH_FUNC([ctanh])
 458 GCC_CHECK_MATH_FUNC([ctanhl])
 459 GCC_CHECK_MATH_FUNC([truncf])
 460 GCC_CHECK_MATH_FUNC([trunc])
 461 GCC_CHECK_MATH_FUNC([truncl])
 462 GCC_CHECK_MATH_FUNC([erff])
 463 GCC_CHECK_MATH_FUNC([erf])
 464 GCC_CHECK_MATH_FUNC([erfcf])
 465 GCC_CHECK_MATH_FUNC([erfc])
 466 GCC_CHECK_MATH_FUNC([erfcl])
 467 GCC_CHECK_MATH_FUNC([j0f])
 468 GCC_CHECK_MATH_FUNC([j0])
 469 GCC_CHECK_MATH_FUNC([j1f])
 470 GCC_CHECK_MATH_FUNC([j1])
 471 GCC_CHECK_MATH_FUNC([jnf])
 472 GCC_CHECK_MATH_FUNC([jn])
 473 GCC_CHECK_MATH_FUNC([jnl])
 474 GCC_CHECK_MATH_FUNC([y0f])
 475 GCC_CHECK_MATH_FUNC([y0])
 476 GCC_CHECK_MATH_FUNC([y1f])
 477 GCC_CHECK_MATH_FUNC([y1])
 478 GCC_CHECK_MATH_FUNC([ynf])
 479 GCC_CHECK_MATH_FUNC([yn])
 480 GCC_CHECK_MATH_FUNC([ynl])
 481 GCC_CHECK_MATH_FUNC([tgamma])
 482 GCC_CHECK_MATH_FUNC([tgammaf])
 483 GCC_CHECK_MATH_FUNC([lgamma])
 484 GCC_CHECK_MATH_FUNC([lgammaf])
 485
 486 # Check for GFORTRAN_C99_1.1 funcs
 487 GCC_CHECK_MATH_FUNC([cacos])
 488 GCC_CHECK_MATH_FUNC([cacosf])
 489 GCC_CHECK_MATH_FUNC([cacosh])
 490 GCC_CHECK_MATH_FUNC([cacoshf])
 491 GCC_CHECK_MATH_FUNC([cacoshl])
 492 GCC_CHECK_MATH_FUNC([cacosl])
 493 GCC_CHECK_MATH_FUNC([casin])
 494 GCC_CHECK_MATH_FUNC([casinf])
 495 GCC_CHECK_MATH_FUNC([casinh])
 496 GCC_CHECK_MATH_FUNC([casinhf])
 497 GCC_CHECK_MATH_FUNC([casinhl])
 498 GCC_CHECK_MATH_FUNC([casinl])
 499 GCC_CHECK_MATH_FUNC([catan])
 500 GCC_CHECK_MATH_FUNC([catanf])
 501 GCC_CHECK_MATH_FUNC([catanh])
 502 GCC_CHECK_MATH_FUNC([catanhf])
 503 GCC_CHECK_MATH_FUNC([catanhl])
 504 GCC_CHECK_MATH_FUNC([catanl])
 505
 506 # On AIX, clog is present in libm as __clog
 507 AC_CHECK_LIB([m],[__clog],[AC_DEFINE([HAVE_CLOG],[1],[libm includes clog])])
 508
 509 # Check whether the system has a working stat()
 510 LIBGFOR_CHECK_WORKING_STAT
 511
 512 # Check whether __mingw_snprintf() is present
 513 LIBGFOR_CHECK_MINGW_SNPRINTF
 514
 515 # Check whether libquadmath should be used
 516 AC_ARG_ENABLE(libquadmath-support,
 517 AS_HELP_STRING([--disable-libquadmath-support],
 518   [disable libquadmath support for Fortran]),
 519 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 520 ENABLE_LIBQUADMATH_SUPPORT=yes)
 521 enable_libquadmath_support=
 522 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 523   enable_libquadmath_support=no
 524 fi
 525
 526 # Check whether we have a __float128 type, depends on enable_libquadmath_support
 527 LIBGFOR_CHECK_FLOAT128
 528
 529 # Check for GNU libc feenableexcept
 530 AC_CHECK_LIB([m],[feenableexcept],[have_feenableexcept=yes AC_DEFINE([HAVE_FEENABLEEXCEPT],[1],[libm includes feenableexcept])])
 531
 532 # At least for glibc, clock_gettime is in librt.  But don't
 533 # pull that in if it still doesn't give us the function we want.  This
 534 # test is copied from libgomp, and modified to not link in -lrt as
 535 # libgfortran calls clock_gettime via a weak reference if it's found
 536 # in librt.
 537 if test "$ac_cv_func_clock_gettime" = no; then
 538   AC_CHECK_LIB(rt, clock_gettime,
 539     [AC_DEFINE(HAVE_CLOCK_GETTIME_LIBRT, 1,
 540                [Define to 1 if you have the `clock_gettime' function in librt.])])
 541 fi
 542
 543 # Check for SysV fpsetmask
 544 LIBGFOR_CHECK_FPSETMASK
 545 AC_CHECK_TYPES([fp_except,fp_except_t], [], [], [[
 546 #ifdef HAVE_IEEEFP_H
 547 #include <ieeefp.h>
 548 #endif
 549 #include <math.h>
 550 ]])
 551 AC_CHECK_TYPES([fp_rnd,fp_rnd_t], [], [], [[
 552 #ifdef HAVE_IEEEFP_H
 553 #include <ieeefp.h>
 554 #endif
 555 #include <math.h>
 556 ]])
 557
 558 # Check whether we have fpsetsticky or fpresetsticky
 559 AC_CHECK_FUNC([fpsetsticky],[have_fpsetsticky=yes AC_DEFINE([HAVE_FPSETSTICKY],[1],[fpsetsticky is present])])
 560 AC_CHECK_FUNC([fpresetsticky],[have_fpresetsticky=yes AC_DEFINE([HAVE_FPRESETSTICKY],[1],[fpresetsticky is present])])
 561
 562 # Check for AIX fp_trap and fp_enable
 563 AC_CHECK_FUNC([fp_trap],[have_fp_trap=yes AC_DEFINE([HAVE_FP_TRAP],[1],[fp_trap is present])])
 564 AC_CHECK_FUNC([fp_enable],[have_fp_enable=yes AC_DEFINE([HAVE_FP_ENABLE],[1],[fp_enable is present])])
 565
 566 # Check if _SOFT_FLOAT is defined
 567 AC_CHECK_DEFINE([_SOFT_FLOAT],[have_soft_float=yes])
 568
 569 # Runs configure.host to set up necessary host-dependent shell variables.
 570 # We then display a message about it, and propagate them through the
 571 # build chain.
 572 . ${srcdir}/configure.host
 573 AC_MSG_NOTICE([FPU dependent file will be ${fpu_host}.h])
 574 AC_MSG_NOTICE([Support for IEEE modules: ${ieee_support}])
 575 FPU_HOST_HEADER=config/${fpu_host}.h
 576 AC_SUBST(FPU_HOST_HEADER)
 577
 578 # Whether we will build the IEEE modules
 579 AM_CONDITIONAL(IEEE_SUPPORT,[test x${ieee_support} = xyes])
 580 AC_SUBST(IEEE_SUPPORT)
 581
 582 # Some targets require additional compiler options for IEEE compatibility.
 583 IEEE_FLAGS="${ieee_flags}"
 584 AC_SUBST(IEEE_FLAGS)
 585
 586
 587 # Check for POSIX getpwuid_r
 588 #
 589 # There are two versions of getpwuid_r, the POSIX one with 5
 590 # arguments, and another one with 4 arguments used by at least HP-UX
 591 # 10.2.
 592 if test "$ac_cv_func_getpwuid_r" = "yes"; then
 593    AC_CACHE_CHECK([POSIX version of getpwuid_r with 5 arguments], libgfor_cv_posix_getpwuid_r, [
 594    AC_LINK_IFELSE([AC_LANG_PROGRAM([
 595 #include <stdio.h>
 596 #include <sys/types.h>
 597 #include <pwd.h>], [
 598     getpwuid_r(0, NULL, NULL, 0, NULL);
 599     ])],  [libgfor_cv_posix_getpwuid_r="yes"], [libgfor_cv_posix_getpwuid_r="no"])])
 600 fi
 601 if test "$libgfor_cv_posix_getpwuid_r" = "yes"; then
 602     AC_DEFINE([HAVE_POSIX_GETPWUID_R], [1], [Define to 1 if we have POSIX getpwuid_r which takes 5 arguments.])
 603 fi
 604
 605
 606 # Check out attribute support.
 607 LIBGFOR_CHECK_ATTRIBUTE_VISIBILITY
 608 LIBGFOR_CHECK_ATTRIBUTE_ALIAS
 609
 610 # Check out sync builtins support.
 611 LIBGFOR_CHECK_SYNC_FETCH_AND_ADD
 612
 613 # Check out #pragma weak.
 614 LIBGFOR_GTHREAD_WEAK
 615
 616 # Check out weakref support.
 617 LIBGFOR_CHECK_WEAKREF
 618
 619 # Various other checks on target
 620 LIBGFOR_CHECK_UNLINK_OPEN_FILE
 621
 622 # Check whether line terminator is LF or CRLF
 623 LIBGFOR_CHECK_CRLF
 624
 625 # Check whether we support AVX extensions
 626 LIBGFOR_CHECK_AVX
 627
 628 # Check wether we support AVX2 extensions
 629 LIBGFOR_CHECK_AVX2
 630
 631 # Check wether we support AVX512f extensions
 632 LIBGFOR_CHECK_AVX512F
 633
 634 # Check for FMA3 extensions
 635 LIBGFOR_CHECK_FMA3
 636
 637 # Check for FMA4 extensions
 638 LIBGFOR_CHECK_FMA4
 639
 640 # Check if AVX128 works
 641 LIBGFOR_CHECK_AVX128
 642
 643 # Determine what GCC version number to use in filesystem paths.
 644 GCC_BASE_VER
 645
 646 AC_CACHE_SAVE
 647
 648 if test ${multilib} = yes; then
 649   multilib_arg="--enable-multilib"
 650 else
 651   multilib_arg=
 652 fi
 653
 654 # Write our Makefile and spec file.
 655 AC_CONFIG_FILES([
 656 Makefile
 657 libgfortran.spec
 658 ])
 659 AC_OUTPUT