libcc1/configure.ac

   1 dnl   Copyright (C) 2014-2018 Free Software Foundation, Inc.
   2 dnl
   3 dnl This file is part of GCC.
   4 dnl
   5 dnl GCC is free software; you can redistribute it and/or modify it under
   6 dnl the terms of the GNU General Public License as published by the Free
   7 dnl Software Foundation; either version 3, or (at your option) any later
   8 dnl version.
   9 dnl
  10 dnl GCC is distributed in the hope that it will be useful, but WITHOUT ANY
  11 dnl WARRANTY; without even the implied warranty of MERCHANTABILITY or
  12 dnl FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  13 dnl for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU General Public License
  16 dnl along with GCC; see the file COPYING3.  If not see
  17 dnl <http://www.gnu.org/licenses/>.
  18
  19 AC_PREREQ(2.64)
  20 AC_INIT([libcc1], [version-unused])
  21 AC_CONFIG_SRCDIR([libcc1.cc])
  22 AC_CONFIG_HEADER(cc1plugin-config.h)
  23
  24 AC_CANONICAL_SYSTEM
  25 AC_USE_SYSTEM_EXTENSIONS
  26 # Determine the noncanonical target name, for directory use.
  27 ACX_NONCANONICAL_TARGET
  28 GCC_TOPLEV_SUBDIRS
  29
  30 # 1.11.1: Require that version of automake.
  31 # foreign: Don't require README, INSTALL, NEWS, etc.
  32 # no-define: Don't define PACKAGE and VERSION.
  33 # -Wall: Issue all automake warnings.
  34 # -Wno-portability: Don't warn about constructs supported by GNU make.
  35 #    (because GCC requires GNU make anyhow).
  36 AM_INIT_AUTOMAKE([1.11.1 foreign no-dist no-define -Wall -Wno-portability])
  37 AM_MAINTAINER_MODE
  38
  39 LT_INIT([disable-static])
  40 AM_PROG_LIBTOOL
  41 AC_PROG_CXX
  42
  43 visibility=
  44 if test "$GXX" = yes; then
  45   visibility=-fvisibility=hidden
  46 fi
  47 AC_SUBST(visibility)
  48
  49 AC_CHECK_DECLS([basename])
  50
  51 GCC_BASE_VER
  52
  53 if test x$with_gcc_major_version_only = xyes ; then
  54   changequote(,)dnl
  55   gcc_version=`sed -e 's/^\([0-9]*\).*$/\1/' $srcdir/../gcc/BASE-VER`
  56   changequote([,])dnl
  57 else
  58   gcc_version=`cat $srcdir/../gcc/BASE-VER`
  59 fi
  60 AC_SUBST(gcc_version)
  61 AC_SUBST([CONFIG_STATUS_DEPENDENCIES], ['$(top_srcdir)/../gcc/BASE-VER'])
  62
  63 ACX_PROG_CC_WARNING_OPTS([-W -Wall], [WARN_FLAGS])
  64 AC_SUBST(WARN_FLAGS)
  65 ACX_PROG_CC_WARNINGS_ARE_ERRORS([manual])
  66
  67 AC_ARG_VAR(GMPINC,[How to find GMP include files])
  68
  69 libsuffix=
  70 if test "$GXX" = yes; then
  71   libsuffix=`$CXX -print-multi-os-directory`
  72 fi
  73 AC_SUBST(libsuffix)
  74
  75 dnl Test for -lsocket and -lnsl.  Copied from libgo/configure.ac.
  76 AC_CACHE_CHECK([for socket libraries], libcc1_cv_lib_sockets,
  77   [libcc1_cv_lib_sockets=
  78    libcc1_check_both=no
  79    AC_CHECK_FUNC(connect, libcc1_check_socket=no, libcc1_check_socket=yes)
  80    if test "$libcc1_check_socket" = "yes"; then
  81      unset ac_cv_func_connect
  82      AC_CHECK_LIB(socket, main, libcc1_cv_lib_sockets="-lsocket",
  83                   libcc1_check_both=yes)
  84    fi
  85    if test "$libcc1_check_both" = "yes"; then
  86      libcc1_old_libs=$LIBS
  87      LIBS="$LIBS -lsocket -lnsl"
  88      unset ac_cv_func_accept
  89      AC_CHECK_FUNC(accept,
  90                    [libcc1_check_nsl=no
  91                     libcc1_cv_lib_sockets="-lsocket -lnsl"])
  92      unset ac_cv_func_accept
  93      LIBS=$libcc1_old_libs
  94    fi
  95    unset ac_cv_func_gethostbyname
  96    libcc1_old_libs="$LIBS"
  97    AC_CHECK_FUNC(gethostbyname, ,
  98                  [AC_CHECK_LIB(nsl, main,
  99                         [libcc1_cv_lib_sockets="$libcc1_cv_lib_sockets -lnsl"])])
 100    unset ac_cv_func_gethostbyname
 101    LIBS=$libcc1_old_libs
 102 ])
 103 LIBS="$LIBS $libcc1_cv_lib_sockets"
 104
 105 # If any of these functions are missing, simply don't bother building
 106 # this plugin.
 107 GCC_ENABLE_PLUGINS
 108 AC_CHECK_FUNC(socketpair, , enable_plugin=no)
 109 AC_CHECK_FUNC(select, , enable_plugin=no)
 110 AC_CHECK_FUNC(fork, , enable_plugin=no)
 111 AM_CONDITIONAL(ENABLE_PLUGIN, test $enable_plugin = yes)
 112
 113 AC_CONFIG_FILES([Makefile])
 114 AC_OUTPUT