libobjc/configure.ac

   1 # Process this file with autoconf to produce a configure script.
   2 #   Copyright 1994, 1995, 1996, 1997, 1998, 1999, 2001, 2002, 2003, 2004
   3 #   2005, 2006 Free Software Foundation, Inc.
   4 #   Originally contributed by Dave Love (d.love@dl.ac.uk).
   5 #
   6 #This file is part of GCC.
   7 #
   8 #GCC is free software; you can redistribute it and/or modify
   9 #it under the terms of the GNU General Public License as published by
  10 #the Free Software Foundation; either version 2, or (at your option)
  11 #any later version.
  12 #
  13 #GCC is distributed in the hope that it will be useful,
  14 #but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 #MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  16 #GNU General Public License for more details.
  17 #
  18 #You should have received a copy of the GNU General Public License
  19 #along with GCC; see the file COPYING.  If not, write to
  20 #the Free Software Foundation, 51 Franklin Street, Fifth Floor, Boston, MA
  21 #02110-1301, USA.
  22
  23 AC_PREREQ(2.59)
  24 AC_INIT(package-unused, version-unused,, libobjc)
  25 AC_CONFIG_SRCDIR([objc/objc.h])
  26 GCC_TOPLEV_SUBDIRS
  27
  28 # We need the following definitions because AC_PROG_LIBTOOL relies on them
  29 PACKAGE=libobjc
  30 # Version is pulled out to make it a bit easier to change using sed.
  31 VERSION=2:0:0
  32 AC_SUBST(VERSION)
  33
  34 # This works around the fact that libtool configuration may change LD
  35 # for this particular configuration, but some shells, instead of
  36 # keeping the changes in LD private, export them just because LD is
  37 # exported.
  38 ORIGINAL_LD_FOR_MULTILIBS=$LD
  39
  40 # -------
  41 # Options
  42 # -------
  43
  44 # Default to --enable-multilib
  45 AC_ARG_ENABLE(multilib,
  46   [  --enable-multilib       build hella library versions (default)],
  47   [case "${enableval}" in
  48     yes) multilib=yes ;;
  49     no)  multilib=no ;;
  50     *)   AC_MSG_ERROR(bad value ${enableval} for multilib option) ;;
  51    esac],
  52   [multilib=yes])
  53
  54 # We use these options to decide which functions to include.
  55 AC_ARG_WITH(target-subdir,
  56 [  --with-target-subdir=SUBDIR
  57                            configuring in a subdirectory])
  58 AC_ARG_WITH(cross-host,
  59 [  --with-cross-host=HOST  configuring with a cross compiler])
  60
  61 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  62 AC_ARG_ENABLE(version-specific-runtime-libs,
  63 [  --enable-version-specific-runtime-libs    Specify that runtime libraries should be installed in a compiler-specific directory ],
  64 [case "$enableval" in
  65  yes) version_specific_libs=yes ;;
  66  no)  version_specific_libs=no ;;
  67  *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  68  esac],
  69 [version_specific_libs=no])
  70 AC_MSG_RESULT($version_specific_libs)
  71
  72 AC_ARG_ENABLE(objc-gc,
  73 [  --enable-objc-gc       enable the use of Boehm's garbage collector with
  74                           the GNU Objective-C runtime.],
  75 [case $enable_objc_gc in
  76   no)
  77     OBJC_BOEHM_GC=''
  78     OBJC_BOEHM_GC_INCLUDES=''
  79     ;;
  80   *)
  81     OBJC_BOEHM_GC=libobjc_gc.la
  82     OBJC_BOEHM_GC_INCLUDES='-I$(top_srcdir)/../boehm-gc/include -I../boehm-gc/include'
  83     ;;
  84 esac],
  85 [OBJC_BOEHM_GC=''; OBJC_BOEHM_GC_INCLUDES=''])
  86 AC_SUBST(OBJC_BOEHM_GC)
  87 AC_SUBST(OBJC_BOEHM_GC_INCLUDES)
  88
  89 # -----------
  90 # Directories
  91 # -----------
  92
  93 # When building with srcdir == objdir, links to the source files will
  94 # be created in directories within the target_subdir.  We have to
  95 # adjust toplevel_srcdir accordingly, so that configure finds
  96 # install-sh and other auxiliary files that live in the top-level
  97 # source directory.
  98 if test "${srcdir}" = "."; then
  99   if test -z "${with_target_subdir}"; then
 100     toprel=".."
 101   else
 102     if test "${with_target_subdir}" != "."; then
 103       toprel="${with_multisrctop}../.."
 104     else
 105       toprel="${with_multisrctop}.."
 106     fi
 107   fi
 108 else
 109   toprel=".."
 110 fi
 111 AC_CONFIG_AUX_DIR(${srcdir}/$toprel)
 112 toplevel_srcdir=\${srcdir}/$toprel
 113 AC_SUBST(toplevel_srcdir)
 114
 115 AC_CANONICAL_SYSTEM
 116 ACX_NONCANONICAL_TARGET
 117
 118 # Export source directory.
 119 # These need to be absolute paths, yet at the same time need to
 120 # canonicalize only relative paths, because then amd will not unmount
 121 # drives. Thus the use of PWDCMD: set it to 'pawd' or 'amq -w' if using amd.
 122 case $srcdir in
 123   [\\/$]* | ?:[\\/]*) glibcpp_srcdir=${srcdir} ;;
 124   *) glibcpp_srcdir=`cd "$srcdir" && ${PWDCMD-pwd} || echo "$srcdir"` ;;
 125 esac
 126 AC_SUBST(glibcpp_srcdir)
 127
 128 # Calculate toolexeclibdir
 129 # Also toolexecdir, though it's only used in toolexeclibdir
 130 case ${version_specific_libs} in
 131   yes)
 132     # Need the gcc compiler version to know where to install libraries
 133     # and header files if --enable-version-specific-runtime-libs option
 134     # is selected.
 135     toolexecdir='$(libdir)/gcc/$(target_noncanonical)'
 136     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
 137     ;;
 138   no)
 139     if test -n "$with_cross_host" &&
 140        test x"$with_cross_host" != x"no"; then
 141       # Install a library built with a cross compiler in tooldir, not libdir.
 142       toolexecdir='$(exec_prefix)/$(target_noncanonical)'
 143       toolexeclibdir='$(toolexecdir)/lib'
 144     else
 145       toolexecdir='$(libdir)/gcc-lib/$(target_noncanonical)'
 146       toolexeclibdir='$(libdir)'
 147     fi
 148     multi_os_directory=`$CC -print-multi-os-directory`
 149     case $multi_os_directory in
 150       .) ;; # Avoid trailing /.
 151       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 152     esac
 153     ;;
 154 esac
 155 AC_SUBST(toolexecdir)
 156 AC_SUBST(toolexeclibdir)
 157
 158 # Figure out if we want to name the include directory and the
 159 #  library name changes differently.
 160 includedirname=include
 161 libext=
 162 case "${host}" in
 163   *-darwin*)
 164     # Darwin is the only target so far that needs a different include directory.
 165     includedirname=include-gnu-runtime
 166     libext=-gnu
 167     ;;
 168 esac
 169 AC_SUBST(includedirname)
 170 AC_SUBST(libext)
 171
 172 AC_CONFIG_HEADERS(config.h)
 173
 174 # --------
 175 # Programs
 176 # --------
 177
 178 GCC_NO_EXECUTABLES
 179
 180 # We must force CC to /not/ be a precious variable; otherwise
 181 # the wrong, non-multilib-adjusted value will be used in multilibs.
 182 # As a side effect, we have to subst CFLAGS ourselves.
 183 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 184 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 185 AC_PROG_CC
 186 m4_rename([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 187
 188 # extra LD Flags which are required for targets
 189 case "${host}" in
 190   *-darwin*)
 191     # Darwin needs -single_module when linking libobjc
 192     extra_ldflags_libobjc=-Wl,-single_module
 193     ;;
 194 esac
 195 AC_SUBST(extra_ldflags_libobjc)
 196
 197 AC_SUBST(CFLAGS)
 198
 199 AC_CHECK_TOOL(AS, as)
 200 AC_CHECK_TOOL(AR, ar)
 201 AC_CHECK_TOOL(RANLIB, ranlib, :)
 202 AC_PROG_INSTALL
 203
 204 AM_MAINTAINER_MODE
 205
 206 # Enable Win32 DLL on MS Windows - FIXME
 207 AC_LIBTOOL_WIN32_DLL
 208
 209 AC_PROG_LIBTOOL
 210
 211 AM_PROG_CC_C_O
 212
 213 AC_PROG_MAKE_SET
 214
 215 # -------
 216 # Headers
 217 # -------
 218
 219 # Sanity check for the cross-compilation case:
 220 AC_CHECK_HEADER(stdio.h,:,
 221   [AC_MSG_ERROR([Can't find stdio.h.
 222 You must have a usable C system for the target already installed, at least
 223 including headers and, preferably, the library, before you can configure
 224 the Objective C runtime system.  If necessary, install gcc now with
 225 \`LANGUAGES=c', then the target library, then build with \`LANGUAGES=objc'.])])
 226
 227 AC_HEADER_STDC
 228
 229 AC_CHECK_HEADERS(sched.h)
 230
 231 # -----------
 232 # Miscellanea
 233 # -----------
 234
 235 AC_MSG_CHECKING([for thread model used by GCC])
 236 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 237 AC_MSG_RESULT([$target_thread_file])
 238
 239 if test $target_thread_file != single; then
 240   AC_DEFINE(HAVE_GTHR_DEFAULT, 1,
 241         [Define if the compiler has a thread header that is non single.])
 242 fi
 243
 244
 245 AC_MSG_CHECKING([for exception model to use])
 246 AC_LANG_PUSH(C)
 247 AC_ARG_ENABLE(sjlj-exceptions,
 248   AS_HELP_STRING([--enable-sjlj-exceptions],
 249                  [force use of builtin_setjmp for exceptions]),
 250 [:],
 251 [dnl Botheration.  Now we've got to detect the exception model.
 252 dnl Link tests against libgcc.a are problematic since -- at least
 253 dnl as of this writing -- we've not been given proper -L bits for
 254 dnl single-tree newlib and libgloss.
 255 dnl
 256 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 257 dnl conftest files before we got a change to grep them first.
 258 cat > conftest.$ac_ext << EOF
 259 [#]line __oline__ "configure"
 260 @interface Frob
 261 @end
 262 @implementation Frob
 263 @end
 264 int proc();
 265 int foo()
 266 {
 267   @try {
 268    return proc();
 269   }
 270   @catch (Frob* ex) {
 271     return 0;
 272   }
 273 }
 274 EOF
 275 old_CFLAGS="$CFLAGS"
 276 dnl work around that we don't have Objective-C support in autoconf
 277 CFLAGS="-x objective-c -fgnu-runtime -fobjc-exceptions -S"
 278 if AC_TRY_EVAL(ac_compile); then
 279   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 280     enable_sjlj_exceptions=yes
 281   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 282     enable_sjlj_exceptions=no
 283   fi
 284 fi
 285 CFLAGS="$old_CFLAGS"
 286 rm -f conftest*])
 287 if test x$enable_sjlj_exceptions = xyes; then
 288   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 289         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 290   ac_exception_model_name=sjlj
 291 elif test x$enable_sjlj_exceptions = xno; then
 292   ac_exception_model_name="call frame"
 293 else
 294   AC_MSG_ERROR([unable to detect exception model])
 295 fi
 296 AC_LANG_POP(C)
 297 AC_MSG_RESULT($ac_exception_model_name)
 298
 299 # ------
 300 # Output
 301 # ------
 302
 303 AC_CONFIG_FILES([Makefile])
 304
 305 AC_CONFIG_COMMANDS([default],
 306 [[if test -n "$CONFIG_FILES"; then
 307   if test -n "${with_target_subdir}"; then
 308     # FIXME: We shouldn't need to set ac_file
 309     ac_file=Makefile
 310     LD="${ORIGINAL_LD_FOR_MULTILIBS}"
 311     . ${toplevel_srcdir}/config-ml.in
 312   fi
 313 fi]],
 314 [[srcdir=${srcdir}
 315 host=${host}
 316 target=${target}
 317 with_target_subdir=${with_target_subdir}
 318 with_multisubdir=${with_multisubdir}
 319 ac_configure_args="--enable-multilib ${ac_configure_args}"
 320 toplevel_srcdir=${toplevel_srcdir}
 321 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 322 ORIGINAL_LD_FOR_MULTILIBS="${ORIGINAL_LD_FOR_MULTILIBS}"
 323 ]])
 324
 325 AC_OUTPUT