configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include([libtool.m4])
  27 m4_include([ltoptions.m4])
  28 m4_include([ltsugar.m4])
  29 m4_include([ltversion.m4])
  30 m4_include([lt~obsolete.m4])
  31 m4_include([config/isl.m4])
  32
  33 AC_INIT(move-if-change)
  34 AC_DISABLE_OPTION_CHECKING
  35
  36 progname=$0
  37 # if PWD already has a value, it is probably wrong.
  38 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  39
  40 # Export original configure arguments for use by sub-configures.
  41 # Quote arguments with shell meta charatcers.
  42 TOPLEVEL_CONFIGURE_ARGUMENTS=
  43 set -- "$progname" "$@"
  44 for ac_arg
  45 do
  46   case "$ac_arg" in
  47   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  48     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  49     # if the argument is of the form -foo=baz, quote the baz part only
  50     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  51   *) ;;
  52   esac
  53   # Add the quoted argument to the list.
  54   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  55 done
  56 if test "$silent" = yes; then
  57   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  58 fi
  59 # Remove the initial space we just introduced and, as these will be
  60 # expanded by make, quote '$'.
  61 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  62 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  63
  64 # Find the build, host, and target systems.
  65 ACX_NONCANONICAL_BUILD
  66 ACX_NONCANONICAL_HOST
  67 ACX_NONCANONICAL_TARGET
  68
  69 dnl Autoconf 2.5x and later will set a default program prefix if
  70 dnl --target was used, even if it was the same as --host.  Disable
  71 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  72 dnl to take effect.
  73 test "$host_noncanonical" = "$target_noncanonical" &&
  74   test "$program_prefix$program_suffix$program_transform_name" = \
  75     NONENONEs,x,x, &&
  76   program_transform_name=s,y,y,
  77
  78 AC_CANONICAL_SYSTEM
  79 AC_ARG_PROGRAM
  80
  81 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  82 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  83
  84 # Get 'install' or 'install-sh' and its variants.
  85 AC_PROG_INSTALL
  86 ACX_PROG_LN
  87 AC_PROG_LN_S
  88 AC_PROG_SED
  89 AC_PROG_AWK
  90
  91 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  92
  93 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  94 # a relative path.
  95 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  96   INSTALL="${srcpwd}/install-sh -c"
  97 fi
  98
  99 # Set srcdir to "." if that's what it is.
 100 # This is important for multilib support.
 101 pwd=`${PWDCMD-pwd}`
 102 if test "${pwd}" = "${srcpwd}" ; then
 103   srcdir=.
 104 fi
 105
 106 topsrcdir=$srcpwd
 107
 108 extra_host_args=
 109
 110 ### To add a new directory to the tree, first choose whether it is a target
 111 ### or a host dependent tool.  Then put it into the appropriate list
 112 ### (library or tools, host or target), doing a dependency sort.
 113
 114 # Subdirs will be configured in the order listed in build_configdirs,
 115 # configdirs, or target_configdirs; see the serialization section below.
 116
 117 # Dependency sorting is only needed when *configuration* must be done in
 118 # a particular order.  In all cases a dependency should be specified in
 119 # the Makefile, whether or not it's implicitly specified here.
 120
 121 # Double entries in build_configdirs, configdirs, or target_configdirs may
 122 # cause circular dependencies and break everything horribly.
 123
 124 # these library is used by various programs built for the build
 125 # environment
 126 #
 127 build_libs="build-libiberty build-libcpp"
 128
 129 # these tools are built for the build environment
 130 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 131
 132 # these libraries are used by various programs built for the host environment
 133 #f
 134 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libdecnumber gmp mpfr mpc isl libelf libiconv libctf"
 135
 136 # these tools are built for the host environment
 137 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 138 # know that we are building the simulator.
 139 # binutils, gas and ld appear in that order because it makes sense to run
 140 # "make check" in that particular order.
 141 # If --enable-gold is used, "gold" may replace "ld".
 142 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools"
 143
 144 # these libraries are built for the target environment, and are built after
 145 # the host libraries and the host tools (which may be a cross compiler)
 146 # Note that libiberty is not a target library.
 147 target_libraries="target-libgcc \
 148                 target-libbacktrace \
 149                 target-libgloss \
 150                 target-newlib \
 151                 target-libgomp \
 152                 target-liboffloadmic \
 153                 target-libhsail-rt \
 154                 target-libatomic \
 155                 target-libitm \
 156                 target-libstdc++-v3 \
 157                 target-libsanitizer \
 158                 target-libvtv \
 159                 target-libssp \
 160                 target-libquadmath \
 161                 target-libgfortran \
 162                 target-libffi \
 163                 target-libobjc \
 164                 target-libada \
 165                 target-libgo \
 166                 target-libphobos \
 167                 target-zlib"
 168
 169 # these tools are built using the target libraries, and are intended to
 170 # run only in the target environment
 171 #
 172 # note: any program that *uses* libraries that are in the "target_libraries"
 173 # list belongs in this list.
 174 #
 175 target_tools="target-rda"
 176
 177 ################################################################################
 178
 179 ## All tools belong in one of the four categories, and are assigned above
 180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 181 ## is important because configure will choke if they ever get through.
 182 ## ${configdirs} is directories we build using the host tools.
 183 ## ${target_configdirs} is directories we build using the target tools.
 184 configdirs=`echo ${host_libs} ${host_tools}`
 185 target_configdirs=`echo ${target_libraries} ${target_tools}`
 186 build_configdirs=`echo ${build_libs} ${build_tools}`
 187
 188 m4_divert_text([PARSE_ARGS],
 189 [case $srcdir in
 190   *" "*)
 191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 194     ;;
 195 esac
 196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 197 ])
 198
 199 ################################################################################
 200
 201 srcname="gnu development package"
 202
 203 # This gets set non-empty for some net releases of packages.
 204 appdirs=""
 205
 206 # Define is_cross_compiler to save on calls to 'test'.
 207 is_cross_compiler=
 208 if test x"${host}" = x"${target}" ; then
 209   is_cross_compiler=no
 210 else
 211   is_cross_compiler=yes
 212 fi
 213
 214 # Find the build and target subdir names.
 215 GCC_TOPLEV_SUBDIRS
 216 # Be sure to cover against remnants of an in-tree build.
 217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 219 Use a pristine source tree when building in a separate tree])
 220 fi
 221
 222 # Skipdirs are removed silently.
 223 skipdirs=
 224 # Noconfigdirs are removed loudly.
 225 noconfigdirs=""
 226
 227 use_gnu_ld=
 228 # Make sure we don't let GNU ld be added if we didn't want it.
 229 if test x$with_gnu_ld = xno ; then
 230   use_gnu_ld=no
 231   noconfigdirs="$noconfigdirs ld gold"
 232 fi
 233
 234 use_gnu_as=
 235 # Make sure we don't let GNU as be added if we didn't want it.
 236 if test x$with_gnu_as = xno ; then
 237   use_gnu_as=no
 238   noconfigdirs="$noconfigdirs gas"
 239 fi
 240
 241 use_included_zlib=
 242 AC_ARG_WITH(system-zlib,
 243 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 244 # Make sure we don't let ZLIB be added if we didn't want it.
 245 if test x$with_system_zlib = xyes ; then
 246   use_included_zlib=no
 247   noconfigdirs="$noconfigdirs zlib"
 248 fi
 249
 250 # some tools are so dependent upon X11 that if we're not building with X,
 251 # it's not even worth trying to configure, much less build, that tool.
 252
 253 case ${with_x} in
 254   yes | "") ;; # the default value for this tree is that X11 is available
 255   no)
 256     skipdirs="${skipdirs} tk itcl libgui"
 257     # We won't be able to build gdbtk without X.
 258     enable_gdbtk=no
 259     ;;
 260   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 261 esac
 262
 263 # Some are only suitable for cross toolchains.
 264 # Remove these if host=target.
 265 cross_only="target-libgloss target-newlib target-opcodes"
 266
 267 case $is_cross_compiler in
 268   no) skipdirs="${skipdirs} ${cross_only}" ;;
 269 esac
 270
 271 # If both --with-headers and --with-libs are specified, default to
 272 # --without-newlib.
 273 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 274    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 275   if test x"${with_newlib}" = x ; then
 276     with_newlib=no
 277   fi
 278 fi
 279
 280 # Recognize --with-newlib/--without-newlib.
 281 case ${with_newlib} in
 282   no) skipdirs="${skipdirs} target-newlib" ;;
 283   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 284 esac
 285
 286 AC_ARG_ENABLE(as-accelerator-for,
 287 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 288                 [build as offload target compiler.
 289                 Specify offload host triple by ARG])])
 290
 291 AC_ARG_ENABLE(offload-targets,
 292 [AS_HELP_STRING([--enable-offload-targets=LIST],
 293                 [enable offloading to devices from comma-separated LIST of
 294                 TARGET[=DIR]. Use optional path to find offload target compiler
 295                 during the build])],
 296 [
 297   if test x"$enable_offload_targets" = x; then
 298     AC_MSG_ERROR([no offload targets specified])
 299   fi
 300 ], [enable_offload_targets=])
 301
 302 # Handle --enable-gold, --enable-ld.
 303 # --disable-gold [--enable-ld]
 304 #     Build only ld.  Default option.
 305 # --enable-gold [--enable-ld]
 306 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 307 #     as "ld.bfd" and "ld".
 308 # --enable-gold=default [--enable-ld]
 309 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 310 #     install ld as "ld.bfd".
 311 # --enable-gold[=default] --disable-ld
 312 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 313 # --enable-gold --enable-ld=default
 314 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 315 #     and ld.bfd).
 316 #     In other words, ld is default
 317 # --enable-gold=default --enable-ld=default
 318 #     Error.
 319
 320 default_ld=
 321 AC_ARG_ENABLE(gold,
 322 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 323                 [build gold @<:@ARG={default,yes,no}@:>@])],
 324 ENABLE_GOLD=$enableval,
 325 ENABLE_GOLD=no)
 326 case "${ENABLE_GOLD}" in
 327   yes|default)
 328     # Check for ELF target.
 329     is_elf=no
 330     case "${target}" in
 331       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 332       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 333       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 334       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 335         case "${target}" in
 336           *-*-linux*aout* | *-*-linux*oldld*)
 337             ;;
 338           *)
 339             is_elf=yes
 340             ;;
 341         esac
 342     esac
 343
 344     if test "$is_elf" = "yes"; then
 345       # Check for target supported by gold.
 346       case "${target}" in
 347         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 348         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 349           configdirs="$configdirs gold"
 350           if test x${ENABLE_GOLD} = xdefault; then
 351             default_ld=gold
 352           fi
 353           ENABLE_GOLD=yes
 354           ;;
 355       esac
 356     fi
 357     ;;
 358   no)
 359     ;;
 360   *)
 361     AC_MSG_ERROR([invalid --enable-gold argument])
 362     ;;
 363 esac
 364
 365 AC_ARG_ENABLE(ld,
 366 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 367                 [build ld @<:@ARG={default,yes,no}@:>@])],
 368 ENABLE_LD=$enableval,
 369 ENABLE_LD=yes)
 370
 371 case "${ENABLE_LD}" in
 372   default)
 373     if test x${default_ld} != x; then
 374       AC_MSG_ERROR([either gold or ld can be the default ld])
 375     fi
 376     ;;
 377   yes)
 378     ;;
 379   no)
 380     if test x${ENABLE_GOLD} != xyes; then
 381       AC_MSG_WARN([neither ld nor gold are enabled])
 382     fi
 383     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 384     ;;
 385   *)
 386     AC_MSG_ERROR([invalid --enable-ld argument])
 387     ;;
 388 esac
 389
 390 # PR gas/19109
 391 # Decide the default method for compressing debug sections.
 392 # Provide a configure time option to override our default.
 393 AC_ARG_ENABLE(compressed_debug_sections,
 394 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 395                 [Enable compressed debug sections for gas, gold or ld by
 396                  default])],
 397 [
 398   if test x"$enable_compressed_debug_sections" = xyes; then
 399     AC_MSG_ERROR([no program with compressed debug sections specified])
 400   fi
 401 ], [enable_compressed_debug_sections=])
 402
 403 # Configure extra directories which are host specific
 404
 405 case "${host}" in
 406   *-cygwin*)
 407     configdirs="$configdirs libtermcap" ;;
 408 esac
 409
 410 # A target can indicate whether a language isn't supported for some reason.
 411 # Only spaces may be used in this macro; not newlines or tabs.
 412 unsupported_languages=
 413
 414 # Remove more programs from consideration, based on the host or
 415 # target this usually means that a port of the program doesn't
 416 # exist yet.
 417
 418 case "${host}" in
 419   i[[3456789]]86-*-msdosdjgpp*)
 420     noconfigdirs="$noconfigdirs tcl tk itcl"
 421     ;;
 422 esac
 423
 424
 425 AC_ARG_ENABLE(libquadmath,
 426 AS_HELP_STRING([--disable-libquadmath],
 427   [do not build libquadmath directory]),
 428 ENABLE_LIBQUADMATH=$enableval,
 429 ENABLE_LIBQUADMATH=yes)
 430 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 431   noconfigdirs="$noconfigdirs target-libquadmath"
 432 fi
 433
 434
 435 AC_ARG_ENABLE(libquadmath-support,
 436 AS_HELP_STRING([--disable-libquadmath-support],
 437   [disable libquadmath support for Fortran]),
 438 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 439 ENABLE_LIBQUADMATH_SUPPORT=yes)
 440 enable_libquadmath_support=
 441 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 442   enable_libquadmath_support=no
 443 fi
 444
 445
 446 AC_ARG_ENABLE(libada,
 447 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 448 ENABLE_LIBADA=$enableval,
 449 ENABLE_LIBADA=yes)
 450 if test "${ENABLE_LIBADA}" != "yes" ; then
 451   noconfigdirs="$noconfigdirs gnattools"
 452 fi
 453
 454 AC_ARG_ENABLE(libssp,
 455 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 456 ENABLE_LIBSSP=$enableval,
 457 ENABLE_LIBSSP=yes)
 458
 459 AC_ARG_ENABLE(libstdcxx,
 460 AS_HELP_STRING([--disable-libstdcxx],
 461   [do not build libstdc++-v3 directory]),
 462 ENABLE_LIBSTDCXX=$enableval,
 463 ENABLE_LIBSTDCXX=default)
 464 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 465   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 466 fi]
 467
 468 # If this is accelerator compiler and its target is intelmic we enable
 469 # target liboffloadmic by default.  If this is compiler with offloading
 470 # for intelmic we enable host liboffloadmic by default.  Otherwise
 471 # liboffloadmic is disabled by default.
 472 AC_ARG_ENABLE([liboffloadmic],
 473 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 474                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 475 [case "$enableval" in
 476   no | host | target)
 477     enable_liboffloadmic=$enableval ;;
 478   *)
 479     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 480 esac],
 481 [if test x"$enable_as_accelerator_for" != x; then
 482   case "${target}" in
 483     *-intelmic-* | *-intelmicemul-*)
 484       enable_liboffloadmic=target
 485       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 486       ;;
 487     *)
 488       enable_liboffloadmic=no
 489       ;;
 490   esac
 491 else
 492   case "${enable_offload_targets}" in
 493     *-intelmic-* | *-intelmicemul-*)
 494       enable_liboffloadmic=host
 495       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 496       ;;
 497     *)
 498       enable_liboffloadmic=no
 499       ;;
 500     esac
 501 fi])
 502 AC_SUBST(extra_liboffloadmic_configure_flags)
 503
 504 # Enable libgomp by default on hosted POSIX systems, and a few others.
 505 if test x$enable_libgomp = x ; then
 506     case "${target}" in
 507     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 508         ;;
 509     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 510         ;;
 511     *-*-solaris2* | *-*-hpux11*)
 512         ;;
 513     *-*-darwin* | *-*-aix*)
 514         ;;
 515     nvptx*-*-* | amdgcn*-*-*)
 516         ;;
 517     *)
 518         noconfigdirs="$noconfigdirs target-libgomp"
 519         ;;
 520     esac
 521 fi
 522
 523 # Disable libatomic on unsupported systems.
 524 if test -d ${srcdir}/libatomic; then
 525     if test x$enable_libatomic = x; then
 526         AC_MSG_CHECKING([for libatomic support])
 527         if (srcdir=${srcdir}/libatomic; \
 528                 . ${srcdir}/configure.tgt; \
 529                 test -n "$UNSUPPORTED")
 530         then
 531             AC_MSG_RESULT([no])
 532             noconfigdirs="$noconfigdirs target-libatomic"
 533         else
 534             AC_MSG_RESULT([yes])
 535         fi
 536     fi
 537 fi
 538
 539 # Disable liboffloadmic on unsupported systems.
 540 if test -d ${srcdir}/liboffloadmic; then
 541     if test x$enable_liboffloadmic != xno; then
 542         AC_MSG_CHECKING([for liboffloadmic support])
 543         if (srcdir=${srcdir}/liboffloadmic; \
 544                 . ${srcdir}/configure.tgt; \
 545                 test -n "$UNSUPPORTED")
 546         then
 547             AC_MSG_RESULT([no])
 548             noconfigdirs="$noconfigdirs target-liboffloadmic"
 549         else
 550             AC_MSG_RESULT([yes])
 551         fi
 552     fi
 553 fi
 554
 555 # Disable libitm on unsupported systems.
 556 if test -d ${srcdir}/libitm; then
 557     if test x$enable_libitm = x; then
 558         AC_MSG_CHECKING([for libitm support])
 559         if (srcdir=${srcdir}/libitm; \
 560                 . ${srcdir}/configure.tgt; \
 561                 test -n "$UNSUPPORTED")
 562         then
 563             AC_MSG_RESULT([no])
 564             noconfigdirs="$noconfigdirs target-libitm"
 565         else
 566             AC_MSG_RESULT([yes])
 567         fi
 568     fi
 569 fi
 570
 571 # Disable libsanitizer on unsupported systems.
 572 if test -d ${srcdir}/libsanitizer; then
 573     if test x$enable_libsanitizer = x; then
 574         AC_MSG_CHECKING([for libsanitizer support])
 575         if (srcdir=${srcdir}/libsanitizer; \
 576                 . ${srcdir}/configure.tgt; \
 577                 test -n "$UNSUPPORTED")
 578         then
 579             AC_MSG_RESULT([no])
 580             noconfigdirs="$noconfigdirs target-libsanitizer"
 581         else
 582             AC_MSG_RESULT([yes])
 583         fi
 584     fi
 585 fi
 586
 587 # Disable libvtv on unsupported systems.
 588 if test -d ${srcdir}/libvtv; then
 589     if test x$enable_libvtv = x; then
 590         AC_MSG_CHECKING([for libvtv support])
 591         if (srcdir=${srcdir}/libvtv; \
 592                 . ${srcdir}/configure.tgt; \
 593                 test "$VTV_SUPPORTED" != "yes")
 594         then
 595             AC_MSG_RESULT([no])
 596             noconfigdirs="$noconfigdirs target-libvtv"
 597         else
 598             AC_MSG_RESULT([yes])
 599         fi
 600     fi
 601 fi
 602
 603
 604 # Disable libhsail-rt on unsupported systems.
 605 if test -d ${srcdir}/libhsail-rt; then
 606     if test x$enable_libhsail_rt = x; then
 607         AC_MSG_CHECKING([for libhsail-rt support])
 608         if (srcdir=${srcdir}/libhsail-rt; \
 609                 . ${srcdir}/configure.tgt; \
 610                 test -n "$UNSUPPORTED")
 611         then
 612             AC_MSG_RESULT([no])
 613             unsupported_languages="$unsupported_languages brig"
 614             # This implicitly disables also target-libhsail-rt as it won't
 615             # get added to the build without BRIG FE.
 616         else
 617             AC_MSG_RESULT([yes])
 618         fi
 619     fi
 620 fi
 621
 622
 623 # Disable libquadmath for some systems.
 624 case "${target}" in
 625   avr-*-*)
 626     noconfigdirs="$noconfigdirs target-libquadmath"
 627     ;;
 628   # libquadmath is unused on AIX and libquadmath build process use of
 629   # LD_LIBRARY_PATH can break AIX bootstrap.
 630   powerpc-*-aix* | rs6000-*-aix*)
 631     noconfigdirs="$noconfigdirs target-libquadmath"
 632     ;;
 633 esac
 634
 635 # Disable libssp for some systems.
 636 case "${target}" in
 637   avr-*-*)
 638     # No hosted I/O support.
 639     noconfigdirs="$noconfigdirs target-libssp"
 640     ;;
 641   bpf-*-*)
 642     noconfigdirs="$noconfigdirs target-libssp"
 643     ;;
 644   powerpc-*-aix* | rs6000-*-aix*)
 645     noconfigdirs="$noconfigdirs target-libssp"
 646     ;;
 647   pru-*-*)
 648     # No hosted I/O support.
 649     noconfigdirs="$noconfigdirs target-libssp"
 650     ;;
 651   rl78-*-*)
 652     # libssp uses a misaligned load to trigger a fault, but the RL78
 653     # doesn't fault for those - instead, it gives a build-time error
 654     # for explicit misaligned loads.
 655     noconfigdirs="$noconfigdirs target-libssp"
 656     ;;
 657   visium-*-*)
 658     # No hosted I/O support.
 659     noconfigdirs="$noconfigdirs target-libssp"
 660     ;;
 661 esac
 662
 663 # Disable libstdc++-v3 for some systems.
 664 # Allow user to override this if they pass --enable-libstdc++-v3
 665 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 666   case "${target}" in
 667     *-*-vxworks*)
 668       # VxWorks uses the Dinkumware C++ library.
 669       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 670       ;;
 671     arm*-wince-pe*)
 672       # the C++ libraries don't build on top of CE's C libraries
 673       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 674       ;;
 675     avr-*-*)
 676       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 677       ;;
 678     bpf-*-*)
 679       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 680       ;;
 681     ft32-*-*)
 682       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 683       ;;
 684   esac
 685 fi
 686
 687 # Disable C++ on systems where it is known to not work.
 688 # For testing, you can override this with --enable-languages=c++.
 689 case ,${enable_languages}, in
 690   *,c++,*)
 691     ;;
 692   *)
 693       case "${target}" in
 694         bpf-*-*)
 695           unsupported_languages="$unsupported_languages c++"
 696           ;;
 697       esac
 698       ;;
 699 esac
 700
 701 # Disable Objc on systems where it is known to not work.
 702 # For testing, you can override this with --enable-languages=objc.
 703 case ,${enable_languages}, in
 704   *,objc,*)
 705     ;;
 706   *)
 707       case "${target}" in
 708         bpf-*-*)
 709           unsupported_languages="$unsupported_languages objc"
 710           ;;
 711       esac
 712       ;;
 713 esac
 714
 715 # Disable D on systems where it is known to not work.
 716 # For testing, you can override this with --enable-languages=d.
 717 case ,${enable_languages}, in
 718   *,d,*)
 719     ;;
 720   *)
 721     case "${target}" in
 722       *-*-darwin*)
 723         unsupported_languages="$unsupported_languages d"
 724         ;;
 725       bpf-*-*)
 726         unsupported_languages="$unsupported_languages d"
 727         ;;
 728     esac
 729     ;;
 730 esac
 731
 732 # Disable libphobos on unsupported systems.
 733 # For testing, you can override this with --enable-libphobos.
 734 if test -d ${srcdir}/libphobos; then
 735     if test x$enable_libphobos = x; then
 736         AC_MSG_CHECKING([for libphobos support])
 737         if (srcdir=${srcdir}/libphobos; \
 738                 . ${srcdir}/configure.tgt; \
 739                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 740         then
 741             AC_MSG_RESULT([no])
 742             noconfigdirs="$noconfigdirs target-libphobos"
 743         else
 744             AC_MSG_RESULT([yes])
 745         fi
 746     fi
 747 fi
 748
 749 # Disable Fortran for some systems.
 750 case "${target}" in
 751   mmix-*-*)
 752     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 753     unsupported_languages="$unsupported_languages fortran"
 754     ;;
 755   bpf-*-*)
 756     unsupported_languages="$unsupported_languages fortran"
 757     ;;
 758 esac
 759
 760 # Disable libffi for some systems.
 761 case "${target}" in
 762   powerpc-*-darwin*)
 763     ;;
 764   i[[3456789]]86-*-darwin*)
 765     ;;
 766   x86_64-*-darwin[[912]]*)
 767     ;;
 768   *-*-darwin*)
 769     noconfigdirs="$noconfigdirs target-libffi"
 770     ;;
 771   *-*-netware*)
 772     noconfigdirs="$noconfigdirs target-libffi"
 773     ;;
 774   *-*-phoenix*)
 775     noconfigdirs="$noconfigdirs target-libffi"
 776     ;;
 777   *-*-rtems*)
 778     noconfigdirs="$noconfigdirs target-libffi"
 779     ;;
 780   *-*-tpf*)
 781     noconfigdirs="$noconfigdirs target-libffi"
 782     ;;
 783   *-*-uclinux*)
 784     noconfigdirs="$noconfigdirs target-libffi"
 785     ;;
 786   *-*-vxworks*)
 787     noconfigdirs="$noconfigdirs target-libffi"
 788     ;;
 789   aarch64*-*-freebsd*)
 790     noconfigdirs="$noconfigdirs target-libffi"
 791     ;;
 792   alpha*-*-*vms*)
 793     noconfigdirs="$noconfigdirs target-libffi"
 794     ;;
 795   arm*-*-freebsd*)
 796     noconfigdirs="$noconfigdirs target-libffi"
 797     ;;
 798   arm-wince-pe)
 799     noconfigdirs="$noconfigdirs target-libffi"
 800     ;;
 801   arm*-*-symbianelf*)
 802     noconfigdirs="$noconfigdirs target-libffi"
 803     ;;
 804   bpf-*-*)
 805     noconfigdirs="$noconfigdirs target-libffi"
 806     ;;
 807   cris-*-* | crisv32-*-*)
 808     case "${target}" in
 809       *-*-linux*)
 810         ;;
 811       *) # See PR46792 regarding target-libffi.
 812         noconfigdirs="$noconfigdirs target-libffi";;
 813     esac
 814     ;;
 815   hppa*64*-*-hpux*)
 816     noconfigdirs="$noconfigdirs target-libffi"
 817     ;;
 818   hppa*-hp-hpux11*)
 819     ;;
 820   hppa*-*-hpux*)
 821     noconfigdirs="$noconfigdirs target-libffi"
 822     ;;
 823   ia64*-*-*vms*)
 824     noconfigdirs="$noconfigdirs target-libffi"
 825     ;;
 826   i[[3456789]]86-w64-mingw*)
 827     noconfigdirs="$noconfigdirs target-libffi"
 828     ;;
 829   i[[3456789]]86-*-mingw*)
 830     noconfigdirs="$noconfigdirs target-libffi"
 831     ;;
 832   x86_64-*-mingw*)
 833     noconfigdirs="$noconfigdirs target-libffi"
 834     ;;
 835   mmix-*-*)
 836     noconfigdirs="$noconfigdirs target-libffi"
 837     ;;
 838   powerpc-*-aix*)
 839     ;;
 840   rs6000-*-aix*)
 841     ;;
 842   ft32-*-*)
 843     noconfigdirs="$noconfigdirs target-libffi"
 844     ;;
 845   *-*-lynxos*)
 846     noconfigdirs="$noconfigdirs target-libffi"
 847     ;;
 848 esac
 849
 850 # Disable the go frontend on systems where it is known to not work. Please keep
 851 # this in sync with contrib/config-list.mk.
 852 case "${target}" in
 853 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 854     unsupported_languages="$unsupported_languages go"
 855     ;;
 856 esac
 857
 858 # Disable libgo for some systems where it is known to not work.
 859 # For testing, you can easily override this with --enable-libgo.
 860 if test x$enable_libgo = x; then
 861     case "${target}" in
 862     *-*-darwin*)
 863         # PR 46986
 864         noconfigdirs="$noconfigdirs target-libgo"
 865         ;;
 866     *-*-cygwin* | *-*-mingw*)
 867         noconfigdirs="$noconfigdirs target-libgo"
 868         ;;
 869     bpf-*-*)
 870         noconfigdirs="$noconfigdirs target-libgo"
 871         ;;
 872     esac
 873 fi
 874
 875 # Default libgloss CPU subdirectory.
 876 libgloss_dir="$target_cpu"
 877
 878 case "${target}" in
 879   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 880     libgloss_dir=wince
 881     ;;
 882   aarch64*-*-* )
 883     libgloss_dir=aarch64
 884     ;;
 885   arm*-*-*)
 886     libgloss_dir=arm
 887     ;;
 888   cris-*-* | crisv32-*-*)
 889     libgloss_dir=cris
 890     ;;
 891   hppa*-*-*)
 892     libgloss_dir=pa
 893     ;;
 894   i[[3456789]]86-*-*)
 895     libgloss_dir=i386
 896     ;;
 897   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 898     libgloss_dir=m68hc11
 899     ;;
 900   m68*-*-* | fido-*-*)
 901     libgloss_dir=m68k
 902     ;;
 903   mips*-*-*)
 904     libgloss_dir=mips
 905     ;;
 906   powerpc*-*-*)
 907     libgloss_dir=rs6000
 908     ;;
 909   pru-*-*)
 910     libgloss_dir=pru
 911     ;;
 912   sparc*-*-*)
 913     libgloss_dir=sparc
 914     ;;
 915 esac
 916
 917 # Disable newlib and libgloss for various target OSes.
 918 case "${target}" in
 919   alpha*-dec-osf*)
 920     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 921     ;;
 922   i[[3456789]]86-*-linux*)
 923     # This section makes it possible to build newlib natively on linux.
 924     # If we are using a cross compiler then don't configure newlib.
 925     if test x${is_cross_compiler} != xno ; then
 926       noconfigdirs="$noconfigdirs target-newlib"
 927     fi
 928     noconfigdirs="$noconfigdirs target-libgloss"
 929     # If we are not using a cross compiler, do configure newlib.
 930     # Note however, that newlib will only be configured in this situation
 931     # if the --with-newlib option has been given, because otherwise
 932     # 'target-newlib' will appear in skipdirs.
 933     ;;
 934   i[[3456789]]86-*-rdos*)
 935     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 936     ;;
 937   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 938     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 939     ;;
 940   sparc-*-sunos4*)
 941     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 942     ;;
 943   bpf-*-*)
 944     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 945     ;;
 946   *-*-aix*)
 947     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 948     ;;
 949   *-*-beos*)
 950     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 951     ;;
 952   *-*-chorusos)
 953     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 954     ;;
 955   *-*-dragonfly*)
 956     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 957     ;;
 958   *-*-freebsd*)
 959     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 960     ;;
 961   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 962     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 963     ;;
 964   *-*-lynxos*)
 965     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 966     ;;
 967   *-*-mingw*)
 968     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 969     ;;
 970   *-*-netbsd*)
 971     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 972     ;;
 973   *-*-netware*)
 974     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 975     ;;
 976   *-*-tpf*)
 977     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 978     ;;
 979   *-*-uclinux*)
 980     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 981     ;;
 982   *-*-vxworks*)
 983     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 984     ;;
 985 esac
 986
 987 case "${target}" in
 988   *-*-chorusos)
 989     ;;
 990   aarch64-*-darwin*)
 991     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 992     noconfigdirs="$noconfigdirs sim target-rda"
 993     ;;
 994   amdgcn*-*-*)
 995     ;;
 996   arm-*-darwin*)
 997     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 998     noconfigdirs="$noconfigdirs sim target-rda"
 999     ;;
1000   powerpc-*-darwin*)
1001     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1002     noconfigdirs="$noconfigdirs sim target-rda"
1003     ;;
1004   i[[3456789]]86-*-darwin*)
1005     noconfigdirs="$noconfigdirs ld gprof"
1006     noconfigdirs="$noconfigdirs sim target-rda"
1007     ;;
1008   x86_64-*-darwin[[912]]*)
1009     noconfigdirs="$noconfigdirs ld gas gprof"
1010     noconfigdirs="$noconfigdirs sim target-rda"
1011     ;;
1012   *-*-darwin*)
1013     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1014     noconfigdirs="$noconfigdirs sim target-rda"
1015     ;;
1016   *-*-dragonfly*)
1017     ;;
1018   *-*-freebsd*)
1019     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
1020         && test -f /usr/local/include/gmp.h; then
1021       with_gmp=/usr/local
1022     fi
1023     ;;
1024   *-*-kaos*)
1025     # Remove unsupported stuff on all kaOS configurations.
1026     noconfigdirs="$noconfigdirs target-libgloss"
1027     ;;
1028   *-*-netbsd*)
1029     ;;
1030   *-*-netware*)
1031     ;;
1032   *-*-phoenix*)
1033     noconfigdirs="$noconfigdirs target-libgloss"
1034     ;;
1035   *-*-rtems*)
1036     noconfigdirs="$noconfigdirs target-libgloss"
1037     ;;
1038     # The tpf target doesn't support gdb yet.
1039   *-*-tpf*)
1040     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1041     ;;
1042   *-*-uclinux*)
1043     noconfigdirs="$noconfigdirs target-rda"
1044     ;;
1045   *-*-vxworks*)
1046     ;;
1047   alpha*-dec-osf*)
1048     # ld works, but does not support shared libraries.
1049     # gas doesn't generate exception information.
1050     noconfigdirs="$noconfigdirs gas ld"
1051     ;;
1052   alpha*-*-*vms*)
1053     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1054     ;;
1055   alpha*-*-*)
1056     # newlib is not 64 bit ready
1057     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1058     ;;
1059   bpf-*-*)
1060     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1061     ;;
1062   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1063     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1064     ;;
1065   arc*-*-*)
1066     noconfigdirs="$noconfigdirs sim"
1067     ;;
1068   arm-*-pe*)
1069     noconfigdirs="$noconfigdirs target-libgloss"
1070     ;;
1071   arm-*-riscix*)
1072     noconfigdirs="$noconfigdirs ld target-libgloss"
1073     ;;
1074   avr-*-*)
1075     if test x${with_avrlibc} != xno; then
1076       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1077     fi
1078     ;;
1079   c4x-*-* | tic4x-*-*)
1080     noconfigdirs="$noconfigdirs target-libgloss"
1081     ;;
1082   tic54x-*-*)
1083     noconfigdirs="$noconfigdirs target-libgloss gdb"
1084     ;;
1085   d10v-*-*)
1086     noconfigdirs="$noconfigdirs target-libgloss"
1087     ;;
1088   d30v-*-*)
1089     noconfigdirs="$noconfigdirs gdb"
1090     ;;
1091   fr30-*-elf*)
1092     noconfigdirs="$noconfigdirs gdb"
1093     ;;
1094   ft32-*-*)
1095     noconfigdirs="$noconfigdirs target-rda gprof"
1096     ;;
1097   moxie-*-*)
1098     noconfigdirs="$noconfigdirs"
1099     ;;
1100   h8300*-*-*)
1101     noconfigdirs="$noconfigdirs target-libgloss"
1102     ;;
1103   h8500-*-*)
1104     noconfigdirs="$noconfigdirs target-libgloss"
1105     ;;
1106   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1107     ;;
1108   hppa*64*-*-hpux*)
1109     noconfigdirs="$noconfigdirs gdb"
1110     ;;
1111   hppa*-*-hpux11*)
1112     noconfigdirs="$noconfigdirs gdb ld"
1113     ;;
1114   hppa*64*-*-linux*)
1115     ;;
1116   hppa*-*-linux*)
1117     ;;
1118   hppa*-*-*elf* | \
1119   hppa*-*-lites* | \
1120   hppa*-*-openbsd* | \
1121   hppa*64*-*-*)
1122     ;;
1123   hppa*-*-pro*)
1124     ;;
1125   hppa*-*-*)
1126     noconfigdirs="$noconfigdirs ld"
1127     ;;
1128   i960-*-*)
1129     noconfigdirs="$noconfigdirs gdb"
1130     ;;
1131   ia64*-*-elf*)
1132     # No gdb support yet.
1133     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1134     ;;
1135   ia64*-**-hpux*)
1136     # No ld support yet.
1137     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1138     ;;
1139   ia64*-*-*vms*)
1140     # No ld support yet.
1141     noconfigdirs="$noconfigdirs libgui itcl ld"
1142     ;;
1143   i[[3456789]]86-w64-mingw*)
1144     ;;
1145   i[[3456789]]86-*-mingw*)
1146     target_configdirs="$target_configdirs target-winsup"
1147     ;;
1148   *-*-cygwin*)
1149     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1150     noconfigdirs="$noconfigdirs target-libgloss"
1151     # always build newlib if winsup directory is present.
1152     if test -d "$srcdir/winsup/cygwin"; then
1153       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1154     elif test -d "$srcdir/newlib"; then
1155       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1156     fi
1157     ;;
1158   i[[3456789]]86-*-pe)
1159     noconfigdirs="$noconfigdirs target-libgloss"
1160     ;;
1161   i[[3456789]]86-*-sco3.2v5*)
1162     # The linker does not yet know about weak symbols in COFF,
1163     # and is not configured to handle mixed ELF and COFF.
1164     noconfigdirs="$noconfigdirs ld target-libgloss"
1165     ;;
1166   i[[3456789]]86-*-sco*)
1167     noconfigdirs="$noconfigdirs gprof target-libgloss"
1168     ;;
1169   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1170     noconfigdirs="$noconfigdirs target-libgloss"
1171     ;;
1172   i[[3456789]]86-*-sysv4*)
1173     noconfigdirs="$noconfigdirs target-libgloss"
1174     ;;
1175   i[[3456789]]86-*-beos*)
1176     noconfigdirs="$noconfigdirs gdb"
1177     ;;
1178   i[[3456789]]86-*-rdos*)
1179     noconfigdirs="$noconfigdirs gdb"
1180     ;;
1181   mmix-*-*)
1182     noconfigdirs="$noconfigdirs gdb"
1183     ;;
1184   mt-*-*)
1185     noconfigdirs="$noconfigdirs sim"
1186     ;;
1187   nfp-*-*)
1188     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1189     noconfigdirs="$noconfigdirs $target_libraries"
1190     ;;
1191   powerpc-*-aix*)
1192     # copied from rs6000-*-* entry
1193     noconfigdirs="$noconfigdirs gprof"
1194     ;;
1195   powerpc*-*-winnt* | powerpc*-*-pe*)
1196     target_configdirs="$target_configdirs target-winsup"
1197     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1198     # always build newlib.
1199     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1200     ;;
1201     # This is temporary until we can link against shared libraries
1202   powerpcle-*-solaris*)
1203     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1204     ;;
1205   powerpc-*-beos*)
1206     noconfigdirs="$noconfigdirs gdb"
1207     ;;
1208   rs6000-*-lynxos*)
1209     noconfigdirs="$noconfigdirs gprof"
1210     ;;
1211   rs6000-*-aix*)
1212     noconfigdirs="$noconfigdirs gprof"
1213     ;;
1214   rs6000-*-*)
1215     noconfigdirs="$noconfigdirs gprof"
1216     ;;
1217   m68k-apollo-*)
1218     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1219     ;;
1220   microblaze*)
1221     noconfigdirs="$noconfigdirs gprof"
1222     ;;
1223   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1224     if test x$with_newlib = xyes; then
1225       noconfigdirs="$noconfigdirs gprof"
1226     fi
1227     ;;
1228   mips*-*-irix5*)
1229     noconfigdirs="$noconfigdirs gprof target-libgloss"
1230     ;;
1231   mips*-*-irix6*)
1232     noconfigdirs="$noconfigdirs gprof target-libgloss"
1233     ;;
1234   mips*-*-bsd*)
1235     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1236     ;;
1237   mips*-*-linux*)
1238     ;;
1239   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1240   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1241     noconfigdirs="$noconfigdirs ld gas gprof"
1242     ;;
1243   mips*-*-*)
1244     noconfigdirs="$noconfigdirs gprof"
1245     ;;
1246   nvptx*-*-*)
1247     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1248     ;;
1249   sh-*-*)
1250     case "${target}" in
1251       sh*-*-elf)
1252          ;;
1253       *)
1254          noconfigdirs="$noconfigdirs target-libgloss" ;;
1255     esac
1256     ;;
1257   sparc-*-sunos4*)
1258     if test x${is_cross_compiler} = xno ; then
1259            use_gnu_ld=no
1260     fi
1261     ;;
1262   tic6x-*-*)
1263     noconfigdirs="$noconfigdirs sim"
1264     ;;
1265   tilepro*-*-* | tilegx*-*-*)
1266     noconfigdirs="$noconfigdirs sim"
1267     ;;
1268   v810-*-*)
1269     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1270     ;;
1271   vax-*-*)
1272     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1273     ;;
1274   wasm32-*-*)
1275     noconfigdirs="$noconfigdirs ld"
1276     ;;
1277 esac
1278
1279 # If we aren't building newlib, then don't build libgloss, since libgloss
1280 # depends upon some newlib header files.
1281 case "${noconfigdirs}" in
1282   *target-libgloss*) ;;
1283   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1284 esac
1285
1286 # Work in distributions that contain no compiler tools, like Autoconf.
1287 host_makefile_frag=/dev/null
1288 if test -d ${srcdir}/config ; then
1289 case "${host}" in
1290   i[[3456789]]86-*-msdosdjgpp*)
1291     host_makefile_frag="config/mh-djgpp"
1292     ;;
1293   *-cygwin*)
1294     ACX_CHECK_CYGWIN_CAT_WORKS
1295     host_makefile_frag="config/mh-cygwin"
1296     ;;
1297   *-mingw*)
1298     host_makefile_frag="config/mh-mingw"
1299     ;;
1300   alpha*-linux*)
1301     host_makefile_frag="config/mh-alpha-linux"
1302     ;;
1303   hppa*-hp-hpux10*)
1304     host_makefile_frag="config/mh-pa-hpux10"
1305     ;;
1306   hppa*-hp-hpux*)
1307     host_makefile_frag="config/mh-pa"
1308     ;;
1309   hppa*-*)
1310     host_makefile_frag="config/mh-pa"
1311     ;;
1312   *-*-darwin*)
1313     host_makefile_frag="config/mh-darwin"
1314     ;;
1315   powerpc-*-aix*)
1316     host_makefile_frag="config/mh-ppc-aix"
1317     ;;
1318   rs6000-*-aix*)
1319     host_makefile_frag="config/mh-ppc-aix"
1320     ;;
1321 esac
1322 fi
1323
1324 if test "${build}" != "${host}" ; then
1325   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1326   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1327   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1328   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1329   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1330   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1331   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1332   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1333   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1334   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1335   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1336   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1337   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1338 else
1339   AR_FOR_BUILD="\$(AR)"
1340   AS_FOR_BUILD="\$(AS)"
1341   CC_FOR_BUILD="\$(CC)"
1342   CXX_FOR_BUILD="\$(CXX)"
1343   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1344   GOC_FOR_BUILD="\$(GOC)"
1345   GDC_FOR_BUILD="\$(GDC)"
1346   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1347   LD_FOR_BUILD="\$(LD)"
1348   NM_FOR_BUILD="\$(NM)"
1349   RANLIB_FOR_BUILD="\$(RANLIB)"
1350   WINDRES_FOR_BUILD="\$(WINDRES)"
1351   WINDMC_FOR_BUILD="\$(WINDMC)"
1352 fi
1353
1354 AC_PROG_CC
1355 AC_PROG_CXX
1356
1357 # We must set the default linker to the linker used by gcc for the correct
1358 # operation of libtool.  If LD is not defined and we are using gcc, try to
1359 # set the LD default to the ld used by gcc.
1360 if test -z "$LD"; then
1361   if test "$GCC" = yes; then
1362     case $build in
1363     *-*-mingw*)
1364       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1365     *)
1366       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1367     esac
1368     case $gcc_prog_ld in
1369     # Accept absolute paths.
1370     [[\\/]* | [A-Za-z]:[\\/]*)]
1371       LD="$gcc_prog_ld" ;;
1372     esac
1373   fi
1374 fi
1375
1376 # Check whether -static-libstdc++ -static-libgcc is supported.
1377 have_static_libs=no
1378 if test "$GCC" = yes; then
1379   saved_LDFLAGS="$LDFLAGS"
1380
1381   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1382   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1383   AC_LANG_PUSH(C++)
1384   AC_LINK_IFELSE([AC_LANG_SOURCE([
1385 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1386 #error -static-libstdc++ not implemented
1387 #endif
1388 int main() {}])],
1389     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1390     [AC_MSG_RESULT([no])])
1391   AC_LANG_POP(C++)
1392
1393   LDFLAGS="$saved_LDFLAGS"
1394 fi
1395
1396 ACX_PROG_GNAT
1397 ACX_PROG_CMP_IGNORE_INITIAL
1398
1399 AC_ARG_ENABLE([bootstrap],
1400 [AS_HELP_STRING([--enable-bootstrap],
1401                 [enable bootstrapping @<:@yes if native build@:>@])],,
1402 enable_bootstrap=default)
1403
1404 # Issue errors and warnings for invalid/strange bootstrap combinations.
1405 if test -r $srcdir/gcc/configure; then
1406   have_compiler=yes
1407 else
1408   have_compiler=no
1409 fi
1410
1411 case "$have_compiler:$host:$target:$enable_bootstrap" in
1412   *:*:*:no) ;;
1413
1414   # Default behavior.  Enable bootstrap if we have a compiler
1415   # and we are in a native configuration.
1416   yes:$build:$build:default)
1417     enable_bootstrap=yes ;;
1418
1419   *:*:*:default)
1420     enable_bootstrap=no ;;
1421
1422   # We have a compiler and we are in a native configuration, bootstrap is ok
1423   yes:$build:$build:yes)
1424     ;;
1425
1426   # Other configurations, but we have a compiler.  Assume the user knows
1427   # what he's doing.
1428   yes:*:*:yes)
1429     AC_MSG_WARN([trying to bootstrap a cross compiler])
1430     ;;
1431
1432   # No compiler: if they passed --enable-bootstrap explicitly, fail
1433   no:*:*:yes)
1434     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1435
1436   # Fail if wrong command line
1437   *)
1438     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1439     ;;
1440 esac
1441
1442 # When bootstrapping with GCC, build stage 1 in C++98 mode to ensure that a
1443 # C++98 compiler can still start the bootstrap.
1444 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1445   CXX="$CXX -std=gnu++98"
1446 fi
1447
1448 # Used for setting $lt_cv_objdir
1449 _LT_CHECK_OBJDIR
1450
1451 # Check for GMP, MPFR and MPC
1452 gmplibs="-lmpc -lmpfr -lgmp"
1453 gmpinc=
1454 have_gmp=no
1455
1456 # Specify a location for mpc
1457 # check for this first so it ends up on the link line before mpfr.
1458 AC_ARG_WITH(mpc,
1459 [AS_HELP_STRING([--with-mpc=PATH],
1460                 [specify prefix directory for installed MPC package.
1461                  Equivalent to --with-mpc-include=PATH/include
1462                  plus --with-mpc-lib=PATH/lib])])
1463 AC_ARG_WITH(mpc-include,
1464 [AS_HELP_STRING([--with-mpc-include=PATH],
1465                 [specify directory for installed MPC include files])])
1466 AC_ARG_WITH(mpc-lib,
1467 [AS_HELP_STRING([--with-mpc-lib=PATH],
1468                 [specify directory for the installed MPC library])])
1469
1470 if test "x$with_mpc" != x; then
1471   gmplibs="-L$with_mpc/lib $gmplibs"
1472   gmpinc="-I$with_mpc/include $gmpinc"
1473 fi
1474 if test "x$with_mpc_include" != x; then
1475   gmpinc="-I$with_mpc_include $gmpinc"
1476 fi
1477 if test "x$with_mpc_lib" != x; then
1478   gmplibs="-L$with_mpc_lib $gmplibs"
1479 fi
1480 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1481   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1482   gmpinc='-I$$s/mpc/src '"$gmpinc"
1483   # Do not test the mpc version.  Assume that it is sufficient, since
1484   # it is in the source tree, and the library has not been built yet
1485   # but it would be included on the link line in the version check below
1486   # hence making the test fail.
1487   have_gmp=yes
1488 fi
1489
1490 # Specify a location for mpfr
1491 # check for this first so it ends up on the link line before gmp.
1492 AC_ARG_WITH(mpfr-dir,
1493 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1494 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1495 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1496
1497 AC_ARG_WITH(mpfr,
1498 [AS_HELP_STRING([--with-mpfr=PATH],
1499                 [specify prefix directory for installed MPFR package.
1500                  Equivalent to --with-mpfr-include=PATH/include
1501                  plus --with-mpfr-lib=PATH/lib])])
1502 AC_ARG_WITH(mpfr-include,
1503 [AS_HELP_STRING([--with-mpfr-include=PATH],
1504                 [specify directory for installed MPFR include files])])
1505 AC_ARG_WITH(mpfr-lib,
1506 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1507                 [specify directory for the installed MPFR library])])
1508
1509 if test "x$with_mpfr" != x; then
1510   gmplibs="-L$with_mpfr/lib $gmplibs"
1511   gmpinc="-I$with_mpfr/include $gmpinc"
1512 fi
1513 if test "x$with_mpfr_include" != x; then
1514   gmpinc="-I$with_mpfr_include $gmpinc"
1515 fi
1516 if test "x$with_mpfr_lib" != x; then
1517   gmplibs="-L$with_mpfr_lib $gmplibs"
1518 fi
1519 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1520   # MPFR v3.1.0 moved the sources into a src sub-directory.
1521   if ! test -d ${srcdir}/mpfr/src; then
1522     AC_MSG_ERROR([dnl
1523 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1524   fi
1525   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1526   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1527   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1528   # Do not test the mpfr version.  Assume that it is sufficient, since
1529   # it is in the source tree, and the library has not been built yet
1530   # but it would be included on the link line in the version check below
1531   # hence making the test fail.
1532   have_gmp=yes
1533 fi
1534
1535 # Specify a location for gmp
1536 AC_ARG_WITH(gmp-dir,
1537 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1538 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1539 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1540
1541 AC_ARG_WITH(gmp,
1542 [AS_HELP_STRING([--with-gmp=PATH],
1543                 [specify prefix directory for the installed GMP package.
1544                  Equivalent to --with-gmp-include=PATH/include
1545                  plus --with-gmp-lib=PATH/lib])])
1546 AC_ARG_WITH(gmp-include,
1547 [AS_HELP_STRING([--with-gmp-include=PATH],
1548                 [specify directory for installed GMP include files])])
1549 AC_ARG_WITH(gmp-lib,
1550 [AS_HELP_STRING([--with-gmp-lib=PATH],
1551                 [specify directory for the installed GMP library])])
1552
1553
1554 if test "x$with_gmp" != x; then
1555   gmplibs="-L$with_gmp/lib $gmplibs"
1556   gmpinc="-I$with_gmp/include $gmpinc"
1557 fi
1558 if test "x$with_gmp_include" != x; then
1559   gmpinc="-I$with_gmp_include $gmpinc"
1560 fi
1561 if test "x$with_gmp_lib" != x; then
1562   gmplibs="-L$with_gmp_lib $gmplibs"
1563 fi
1564 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1565   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1566   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1567   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1568   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1569   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1570   # Do not test the gmp version.  Assume that it is sufficient, since
1571   # it is in the source tree, and the library has not been built yet
1572   # but it would be included on the link line in the version check below
1573   # hence making the test fail.
1574   have_gmp=yes
1575 fi
1576
1577 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1578   have_gmp=yes
1579   saved_CFLAGS="$CFLAGS"
1580   CFLAGS="$CFLAGS $gmpinc"
1581   # Check for the recommended and required versions of GMP.
1582   AC_MSG_CHECKING([for the correct version of gmp.h])
1583   AC_TRY_COMPILE([#include "gmp.h"],[
1584   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1585   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1586   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1587   choke me
1588   #endif
1589   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1590   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1591   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1592   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1593   choke me
1594   #endif
1595   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1596    [AC_MSG_RESULT([no]); have_gmp=no])
1597
1598   # If we have GMP, check the MPFR version.
1599   if test x"$have_gmp" = xyes; then
1600     # Check for the recommended and required versions of MPFR.
1601     AC_MSG_CHECKING([for the correct version of mpfr.h])
1602     AC_TRY_COMPILE([#include <gmp.h>
1603     #include <mpfr.h>],[
1604     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1605     choke me
1606     #endif
1607     ], [AC_TRY_COMPILE([#include <gmp.h>
1608     #include <mpfr.h>],[
1609     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1610     choke me
1611     #endif
1612     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1613      [AC_MSG_RESULT([no]); have_gmp=no])
1614   fi
1615
1616   # Check for the MPC header version.
1617   if test x"$have_gmp" = xyes ; then
1618     # Check for the recommended and required versions of MPC.
1619     AC_MSG_CHECKING([for the correct version of mpc.h])
1620     AC_TRY_COMPILE([#include <mpc.h>],[
1621     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1622     choke me
1623     #endif
1624     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1625     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1626     choke me
1627     #endif
1628     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1629      [AC_MSG_RESULT([no]); have_gmp=no])
1630   fi
1631
1632   # Now check the MPFR library.
1633   if test x"$have_gmp" = xyes; then
1634     saved_LIBS="$LIBS"
1635     LIBS="$LIBS $gmplibs"
1636     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1637     AC_TRY_LINK([#include <mpc.h>],[
1638     mpfr_t n;
1639     mpfr_t x;
1640     mpc_t c;
1641     int t;
1642     mpfr_init (n);
1643     mpfr_init (x);
1644     mpfr_atan2 (n, n, x, MPFR_RNDN);
1645     mpfr_erfc (n, x, MPFR_RNDN);
1646     mpfr_subnormalize (x, t, MPFR_RNDN);
1647     mpfr_clear(n);
1648     mpfr_clear(x);
1649     mpc_init2 (c, 53);
1650     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1651     mpc_cosh (c, c, MPC_RNDNN);
1652     mpc_pow (c, c, c, MPC_RNDNN);
1653     mpc_acosh (c, c, MPC_RNDNN);
1654     mpc_clear (c);
1655     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1656     LIBS="$saved_LIBS"
1657   fi
1658
1659   CFLAGS="$saved_CFLAGS"
1660
1661 # The library versions listed in the error message below should match
1662 # the HARD-minimums enforced above.
1663   if test x$have_gmp != xyes; then
1664     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1665 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1666 their locations.  Source code for these libraries can be found at
1667 their respective hosting sites as well as at
1668 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1669 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1670 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1671 make sure that you have installed both the libraries and the header
1672 files.  They may be located in separate packages.])
1673   fi
1674 fi
1675
1676 # Flags needed for both GMP, MPFR and/or MPC.
1677 AC_SUBST(gmplibs)
1678 AC_SUBST(gmpinc)
1679 AC_SUBST(extra_mpfr_configure_flags)
1680 AC_SUBST(extra_mpc_gmp_configure_flags)
1681 AC_SUBST(extra_mpc_mpfr_configure_flags)
1682 AC_SUBST(extra_isl_gmp_configure_flags)
1683
1684 # Libraries to use for stage1 or when not bootstrapping.
1685 AC_ARG_WITH(stage1-libs,
1686 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1687 [if test "$withval" = "no" -o "$withval" = "yes"; then
1688    stage1_libs=
1689  else
1690    stage1_libs=$withval
1691  fi],
1692 [stage1_libs=])
1693 AC_SUBST(stage1_libs)
1694
1695 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1696 # default is yes if gcc is being built; no otherwise.  The reason for
1697 # this default is that gdb is sometimes linked against GNU Source
1698 # Highlight, which is a shared library that uses C++ exceptions.  In
1699 # this case, -static-libstdc++ will cause crashes.
1700 AC_ARG_WITH(static-standard-libraries,
1701 [AS_HELP_STRING([--with-static-standard-libraries],
1702                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1703 [], [with_static_standard_libraries=auto])
1704 if test "$with_static_standard_libraries" = auto; then
1705   with_static_standard_libraries=$have_compiler
1706 fi
1707
1708 # Linker flags to use for stage1 or when not bootstrapping.
1709 AC_ARG_WITH(stage1-ldflags,
1710 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1711 [if test "$withval" = "no" -o "$withval" = "yes"; then
1712    stage1_ldflags=
1713  else
1714    stage1_ldflags=$withval
1715  fi],
1716 [stage1_ldflags=
1717  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1718  # if supported.  But if the user explicitly specified the libraries to use,
1719  # trust that they are doing what they want.
1720  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1721      -a "$have_static_libs" = yes; then
1722    stage1_ldflags="-static-libstdc++ -static-libgcc"
1723  fi])
1724 AC_SUBST(stage1_ldflags)
1725
1726 # Libraries to use for stage2 and later builds.
1727 AC_ARG_WITH(boot-libs,
1728 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1729 [if test "$withval" = "no" -o "$withval" = "yes"; then
1730    poststage1_libs=
1731  else
1732    poststage1_libs=$withval
1733  fi],
1734 [poststage1_libs=])
1735 AC_SUBST(poststage1_libs)
1736
1737 # Linker flags to use for stage2 and later builds.
1738 AC_ARG_WITH(boot-ldflags,
1739 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1740                 [linker flags for stage2 and later])],
1741 [if test "$withval" = "no" -o "$withval" = "yes"; then
1742    poststage1_ldflags=
1743  else
1744    poststage1_ldflags=$withval
1745  fi],
1746 [poststage1_ldflags=
1747  # In stages 2 and 3, default to linking libstdc++ and libgcc
1748  # statically.  But if the user explicitly specified the libraries to
1749  # use, trust that they are doing what they want.
1750  if test "$poststage1_libs" = ""; then
1751    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1752  fi])
1753 AC_SUBST(poststage1_ldflags)
1754
1755 # GCC GRAPHITE dependency isl.
1756 # Basic setup is inlined here, actual checks are in config/isl.m4
1757
1758 AC_ARG_WITH(isl,
1759   [AS_HELP_STRING(
1760    [--with-isl=PATH],
1761    [Specify prefix directory for the installed isl package.
1762     Equivalent to --with-isl-include=PATH/include
1763     plus --with-isl-lib=PATH/lib])])
1764
1765 # Treat --without-isl as a request to disable
1766 # GRAPHITE support and skip all following checks.
1767 if test "x$with_isl" != "xno"; then
1768   # Check for isl
1769   dnl Provide configure switches and initialize islinc & isllibs
1770   dnl with user input.
1771   ISL_INIT_FLAGS
1772   dnl The versions of isl that work for Graphite
1773   ISL_CHECK_VERSION()
1774   dnl Only execute fail-action, if isl has been requested.
1775   ISL_IF_FAILED([
1776     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1777 fi
1778
1779 # If the isl check failed, disable builds of in-tree variant of isl
1780 if test "x$with_isl" = xno ||
1781    test "x$gcc_cv_isl" = xno; then
1782   noconfigdirs="$noconfigdirs isl"
1783   islinc=
1784 fi
1785
1786 AC_SUBST(isllibs)
1787 AC_SUBST(islinc)
1788
1789 # Check for LTO support.
1790 AC_ARG_ENABLE(lto,
1791 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1792 enable_lto=$enableval,
1793 enable_lto=yes; default_enable_lto=yes)
1794
1795 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1796   build_lto_plugin=yes
1797 ],[if test x"$default_enable_lto" = x"yes" ; then
1798     case $target in
1799       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1800       # On other non-ELF platforms, LTO has yet to be validated.
1801       *) enable_lto=no ;;
1802     esac
1803   else
1804   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1805   # It would also be nice to check the binutils support, but we don't
1806   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1807   # warn during gcc/ subconfigure; unless you're bootstrapping with
1808   # -flto it won't be needed until after installation anyway.
1809     case $target in
1810       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1811       *) if test x"$enable_lto" = x"yes"; then
1812         AC_MSG_ERROR([LTO support is not enabled for this target.])
1813         fi
1814       ;;
1815     esac
1816   fi
1817   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1818   # Build it unless LTO was explicitly disabled.
1819   case $target in
1820     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1821     *) ;;
1822   esac
1823 ])
1824
1825 AC_ARG_ENABLE(linker-plugin-configure-flags,
1826   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1827     [additional flags for configuring linker plugins @<:@none@:>@])],
1828   extra_linker_plugin_configure_flags=$enableval,
1829   extra_linker_plugin_configure_flags=)
1830 AC_SUBST(extra_linker_plugin_configure_flags)
1831 AC_ARG_ENABLE(linker-plugin-flags,
1832   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1833     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1834   extra_linker_plugin_flags=$enableval,
1835   extra_linker_plugin_flags=)
1836 AC_SUBST(extra_linker_plugin_flags)
1837
1838 # Enable --enable-host-shared.
1839 # Checked early to determine whether jit is an 'all' language
1840 AC_ARG_ENABLE(host-shared,
1841 [AS_HELP_STRING([--enable-host-shared],
1842                 [build host code as shared libraries])],
1843 [host_shared=$enableval], [host_shared=no])
1844 AC_SUBST(host_shared)
1845
1846 # By default, C and C++ are the only stage 1 languages.
1847 stage1_languages=,c,
1848
1849 # Target libraries that we bootstrap.
1850 bootstrap_target_libs=,target-libgcc,
1851
1852 # Figure out what language subdirectories are present.
1853 # Look if the user specified --enable-languages="..."; if not, use
1854 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1855 # go away some day.
1856 # NB:  embedded tabs in this IF block -- do not untabify
1857 if test -d ${srcdir}/gcc; then
1858   if test x"${enable_languages+set}" != xset; then
1859     if test x"${LANGUAGES+set}" = xset; then
1860       enable_languages="${LANGUAGES}"
1861         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1862     else
1863       enable_languages=default
1864     fi
1865   else
1866     if test x"${enable_languages}" = x ||
1867        test x"${enable_languages}" = xyes;
1868        then
1869       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1870       exit 1
1871     fi
1872   fi
1873   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1874
1875   # 'f95' is the old name for the 'fortran' language. We issue a warning
1876   # and make the substitution.
1877   case ,${enable_languages}, in
1878     *,f95,*)
1879       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1880       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1881       ;;
1882   esac
1883
1884   # If bootstrapping, C++ must be enabled.
1885   case ",$enable_languages,:$enable_bootstrap" in
1886     *,c++,*:*) ;;
1887     *:yes)
1888       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1889         enable_languages="${enable_languages},c++"
1890       else
1891         AC_MSG_ERROR([bootstrapping requires c++ sources])
1892       fi
1893       ;;
1894   esac
1895
1896   # First scan to see if an enabled language requires some other language.
1897   # We assume that a given config-lang.in will list all the language
1898   # front ends it requires, even if some are required indirectly.
1899   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1900     case ${lang_frag} in
1901       ..) ;;
1902       # The odd quoting in the next line works around
1903       # an apparent bug in bash 1.12 on linux.
1904       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1905       *)
1906         # From the config-lang.in, get $language, $lang_requires, and
1907         # $lang_requires_boot_languages.
1908         language=
1909         lang_requires=
1910         lang_requires_boot_languages=
1911         # set srcdir during sourcing lang_frag to the gcc dir.
1912         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
1913         # polutes this shell
1914         saved_srcdir=${srcdir}
1915         srcdir=${srcdir}/gcc . ${lang_frag}
1916         srcdir=${saved_srcdir}
1917         for other in ${lang_requires} ${lang_requires_boot_languages}; do
1918           case ,${enable_languages}, in
1919             *,$other,*) ;;
1920             *,default,*) ;;
1921             *,all,*) ;;
1922             *,$language,*)
1923               echo " \`$other' language required by \`$language'; enabling" 1>&2
1924               enable_languages="${enable_languages},${other}"
1925               ;;
1926           esac
1927         done
1928         for other in ${lang_requires_boot_languages} ; do
1929           if test "$other" != "c"; then
1930             case ,${enable_stage1_languages}, in
1931               *,$other,*) ;;
1932               *,default,*) ;;
1933               *,all,*) ;;
1934               *)
1935                 case ,${enable_languages}, in
1936                   *,$language,*)
1937                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
1938                     enable_stage1_languages="$enable_stage1_languages,${other}"
1939                     ;;
1940                 esac
1941                 ;;
1942             esac
1943           fi
1944         done
1945         ;;
1946     esac
1947   done
1948
1949   new_enable_languages=,c,
1950
1951   # If LTO is enabled, add the LTO front end.
1952   if test "$enable_lto" = "yes" ; then
1953     case ,${enable_languages}, in
1954       *,lto,*) ;;
1955       *) enable_languages="${enable_languages},lto" ;;
1956     esac
1957     if test "${build_lto_plugin}" = "yes" ; then
1958       configdirs="$configdirs lto-plugin"
1959     fi
1960   fi
1961
1962   # If we're building an offloading compiler, add the LTO front end.
1963   if test x"$enable_as_accelerator_for" != x ; then
1964     case ,${enable_languages}, in
1965       *,lto,*) ;;
1966       *) enable_languages="${enable_languages},lto" ;;
1967     esac
1968   fi
1969
1970   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
1971   potential_languages=,c,
1972
1973   enabled_target_libs=
1974   disabled_target_libs=
1975
1976   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1977     case ${lang_frag} in
1978       ..) ;;
1979       # The odd quoting in the next line works around
1980       # an apparent bug in bash 1.12 on linux.
1981       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1982       *)
1983         # From the config-lang.in, get $language, $target_libs,
1984         # $lang_dirs, $boot_language, and $build_by_default
1985         language=
1986         target_libs=
1987         lang_dirs=
1988         subdir_requires=
1989         boot_language=no
1990         build_by_default=yes
1991         # set srcdir during sourcing.  See above about save & restore
1992         saved_srcdir=${srcdir}
1993         srcdir=${srcdir}/gcc . ${lang_frag}
1994         srcdir=${saved_srcdir}
1995         if test x${language} = x; then
1996           echo "${lang_frag} doesn't set \$language." 1>&2
1997           exit 1
1998         fi
1999
2000         if test "$language" = "c++"; then
2001           boot_language=yes
2002         fi
2003
2004         add_this_lang=no
2005         # C is always enabled, so no need to add it again
2006         if test "$language" != "c"; then
2007           case ,${enable_languages}, in
2008             *,${language},*)
2009               # Language was explicitly selected; include it
2010               add_this_lang=yes
2011               ;;
2012             *,all,*)
2013               # All languages are enabled
2014               add_this_lang=all
2015               ;;
2016             *,default,*)
2017               # 'default' was selected, select it if it is a default language
2018               add_this_lang=${build_by_default}
2019               ;;
2020           esac
2021         fi
2022
2023         # Disable languages that need other directories if these aren't available.
2024         for i in $subdir_requires; do
2025           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2026           case ${add_this_lang} in
2027             yes)
2028               # Specifically requested language; tell them.
2029               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2030               ;;
2031             all)
2032               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2033               add_this_lang=unsupported
2034               ;;
2035             *)
2036               # Silently disable.
2037               add_this_lang=unsupported
2038               ;;
2039           esac
2040         done
2041
2042         # Disable Ada if no preexisting GNAT is available.
2043         case ${add_this_lang}:${language}:${have_gnat} in
2044           yes:ada:no)
2045             # Specifically requested language; tell them.
2046             AC_MSG_ERROR([GNAT is required to build $language])
2047             ;;
2048           all:ada:no)
2049             AC_MSG_WARN([GNAT is required to build $language])
2050             add_this_lang=unsupported
2051             ;;
2052           *:ada:no)
2053             # Silently disable.
2054             add_this_lang=unsupported
2055             ;;
2056         esac
2057
2058         # Disable jit if -enable-host-shared not specified
2059         case ${add_this_lang}:${language}:${host_shared} in
2060           yes:jit:no)
2061             # PR jit/64780: explicitly specify --enable-host-shared
2062             AC_MSG_ERROR([
2063 Enabling language "jit" requires --enable-host-shared.
2064
2065 --enable-host-shared typically slows the rest of the compiler down by
2066 a few %, so you must explicitly enable it.
2067
2068 If you want to build both the jit and the regular compiler, it is often
2069 best to do this via two separate configure/builds, in separate
2070 directories, to avoid imposing the performance cost of
2071 --enable-host-shared on the regular compiler.])
2072             ;;
2073           all:jit:no)
2074             AC_MSG_WARN([--enable-host-shared required to build $language])
2075             add_this_lang=unsupported
2076             ;;
2077           *:jit:no)
2078             # Silently disable.
2079             add_this_lang=unsupported
2080             ;;
2081         esac
2082
2083         # Disable a language that is unsupported by the target.
2084         case "${add_this_lang}: $unsupported_languages " in
2085           no:*) ;;
2086           unsupported:*) ;;
2087           *:*" $language "*)
2088             AC_MSG_WARN([${language} not supported for this target])
2089             add_this_lang=unsupported
2090             ;;
2091         esac
2092
2093         case $add_this_lang in
2094           unsupported)
2095             # Remove language-dependent dirs.
2096             disabled_target_libs="$disabled_target_libs $target_libs"
2097             noconfigdirs="$noconfigdirs $lang_dirs"
2098             ;;
2099           no)
2100             # Remove language-dependent dirs; still show language as supported.
2101             disabled_target_libs="$disabled_target_libs $target_libs"
2102             noconfigdirs="$noconfigdirs $lang_dirs"
2103             potential_languages="${potential_languages}${language},"
2104             ;;
2105           all|yes)
2106             new_enable_languages="${new_enable_languages}${language},"
2107             potential_languages="${potential_languages}${language},"
2108             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2109             enabled_target_libs="$enabled_target_libs $target_libs"
2110             case "${boot_language}:,$enable_stage1_languages," in
2111               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2112                 # Add to (comma-separated) list of stage 1 languages.
2113                 case ",$stage1_languages," in
2114                   *,$language,* | ,yes, | ,all,) ;;
2115                   *) stage1_languages="${stage1_languages}${language}," ;;
2116                 esac
2117                 # We need to bootstrap any supporting libraries.
2118                 bootstrap_target_libs="${bootstrap_target_libs}${target_libs},"
2119                 ;;
2120             esac
2121             ;;
2122         esac
2123         ;;
2124     esac
2125   done
2126
2127   # Add target libraries which are only needed for disabled languages
2128   # to noconfigdirs.
2129   if test -n "$disabled_target_libs"; then
2130     for dir in $disabled_target_libs; do
2131       case " $enabled_target_libs " in
2132       *" ${dir} "*) ;;
2133       *) noconfigdirs="$noconfigdirs $dir" ;;
2134       esac
2135     done
2136   fi
2137
2138   AC_ARG_ENABLE(stage1-languages,
2139   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2140                   [choose additional languages to build during
2141                   stage1.  Mostly useful for compiler development])],
2142   [case ,${enable_stage1_languages}, in
2143     ,no,|,,)
2144       # Set it to something that will have no effect in the loop below
2145       enable_stage1_languages=c ;;
2146     ,yes,)
2147       enable_stage1_languages=`echo $new_enable_languages | \
2148         sed -e "s/^,//" -e "s/,$//" ` ;;
2149     *,all,*)
2150       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2151         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2152   esac
2153
2154   # Add "good" languages from enable_stage1_languages to stage1_languages,
2155   # while "bad" languages go in missing_languages.  Leave no duplicates.
2156   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2157     case $potential_languages in
2158       *,$i,*)
2159         case $stage1_languages in
2160           *,$i,*) ;;
2161           *) stage1_languages="$stage1_languages$i," ;;
2162         esac ;;
2163       *)
2164         case $missing_languages in
2165           *,$i,*) ;;
2166           *) missing_languages="$missing_languages$i," ;;
2167         esac ;;
2168      esac
2169   done])
2170
2171   # Remove leading/trailing commas that were added for simplicity
2172   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2173   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2174   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2175   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2176
2177   if test "x$missing_languages" != x; then
2178     AC_MSG_ERROR([
2179 The following requested languages could not be built: ${missing_languages}
2180 Supported languages are: ${potential_languages}])
2181   fi
2182   if test "x$new_enable_languages" != "x$enable_languages"; then
2183     echo The following languages will be built: ${new_enable_languages}
2184     enable_languages="$new_enable_languages"
2185   fi
2186
2187   AC_SUBST(stage1_languages)
2188   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2189 fi
2190
2191 # Handle --disable-<component> generically.
2192 for dir in $configdirs $build_configdirs $target_configdirs ; do
2193   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2194   varname=`echo $dirname | sed -e s/+/_/g`
2195   if eval test x\${enable_${varname}} "=" xno ; then
2196     noconfigdirs="$noconfigdirs $dir"
2197   fi
2198 done
2199
2200 # Check for Boehm's garbage collector
2201 AC_ARG_ENABLE(objc-gc,
2202 [AS_HELP_STRING([--enable-objc-gc],
2203                 [enable use of Boehm's garbage collector with the
2204                  GNU Objective-C runtime])])
2205 AC_ARG_WITH([target-bdw-gc],
2206 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2207                 [specify prefix directory for installed bdw-gc package.
2208                  Equivalent to --with-target-bdw-gc-include=PATH/include
2209                  plus --with-target-bdw-gc-lib=PATH/lib])])
2210 AC_ARG_WITH([target-bdw-gc-include],
2211 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2212                 [specify directories for installed bdw-gc include files])])
2213 AC_ARG_WITH([target-bdw-gc-lib],
2214 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2215                 [specify directories for installed bdw-gc library])])
2216
2217 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2218   AC_MSG_CHECKING([for bdw garbage collector])
2219   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2220     dnl no bdw-gw options, assume default locations
2221     AC_MSG_RESULT([using bdw-gc in default locations])
2222   else
2223     dnl bdw-gw options, first error checking, complete checking in libobjc
2224     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2225       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2226     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2227       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2228     else
2229       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2230     fi
2231   fi
2232 esac
2233
2234 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2235 case ,${enable_languages}, in
2236   *,c++,*)
2237     # Disable libitm, libsanitizer if we're not building libstdc++
2238     case "${noconfigdirs}" in
2239       *target-libstdc++-v3*)
2240         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2241         ;;
2242       *) ;;
2243     esac
2244     ;;
2245   *)
2246     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2247     ;;
2248 esac
2249
2250 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2251 # $build_configdirs and $target_configdirs.
2252 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2253
2254 notsupp=""
2255 for dir in . $skipdirs $noconfigdirs ; do
2256   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2257   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2258     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2259     if test -r $srcdir/$dirname/configure ; then
2260       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2261         true
2262       else
2263         notsupp="$notsupp $dir"
2264       fi
2265     fi
2266   fi
2267   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2268     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2269     if test -r $srcdir/$dirname/configure ; then
2270       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2271         true
2272       else
2273         notsupp="$notsupp $dir"
2274       fi
2275     fi
2276   fi
2277   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2278     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2279     if test -r $srcdir/$dirname/configure ; then
2280       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2281         true
2282       else
2283         notsupp="$notsupp $dir"
2284       fi
2285     fi
2286   fi
2287 done
2288
2289 # Quietly strip out all directories which aren't configurable in this tree.
2290 # This relies on all configurable subdirectories being autoconfiscated, which
2291 # is now the case.
2292 build_configdirs_all="$build_configdirs"
2293 build_configdirs=
2294 for i in ${build_configdirs_all} ; do
2295   j=`echo $i | sed -e s/build-//g`
2296   if test -f ${srcdir}/$j/configure ; then
2297     build_configdirs="${build_configdirs} $i"
2298   fi
2299 done
2300
2301 configdirs_all="$configdirs"
2302 configdirs=
2303 for i in ${configdirs_all} ; do
2304   if test -f ${srcdir}/$i/configure ; then
2305     configdirs="${configdirs} $i"
2306   fi
2307 done
2308
2309 target_configdirs_all="$target_configdirs"
2310 target_configdirs=
2311 for i in ${target_configdirs_all} ; do
2312   j=`echo $i | sed -e s/target-//g`
2313   if test -f ${srcdir}/$j/configure ; then
2314     target_configdirs="${target_configdirs} $i"
2315   fi
2316 done
2317
2318 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2319 # so we have to add it after the preceding checks.
2320 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2321 then
2322   case " $configdirs " in
2323     *" libiberty "*)
2324       # If we can build libiberty, we can also build libiberty-linker-plugin.
2325       configdirs="$configdirs libiberty-linker-plugin"
2326       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2327         --with-libiberty=../libiberty-linker-plugin";;
2328     *)
2329       AC_MSG_ERROR([libiberty missing]);;
2330   esac
2331 fi
2332
2333 # Sometimes we have special requirements for the host libiberty.
2334 extra_host_libiberty_configure_flags=
2335 extra_host_zlib_configure_flags=
2336 case " $configdirs " in
2337   *" lto-plugin "* | *" libcc1 "*)
2338     # When these are to be built as shared libraries, the same applies to
2339     # libiberty.
2340     extra_host_libiberty_configure_flags=--enable-shared
2341     ;;
2342   *" bfd "*)
2343     # When bfd is to be built as a shared library, the same applies to
2344     # zlib.
2345     if test "$enable_shared" = "yes"; then
2346       extra_host_zlib_configure_flags=--enable-host-shared
2347     fi
2348     ;;
2349 esac
2350 AC_SUBST(extra_host_libiberty_configure_flags)
2351 AC_SUBST(extra_host_zlib_configure_flags)
2352
2353 # Produce a warning message for the subdirs we can't configure.
2354 # This isn't especially interesting in the Cygnus tree, but in the individual
2355 # FSF releases, it's important to let people know when their machine isn't
2356 # supported by the one or two programs in a package.
2357
2358 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2359   # If $appdirs is non-empty, at least one of those directories must still
2360   # be configured, or we error out.  (E.g., if the gas release supports a
2361   # specified target in some subdirs but not the gas subdir, we shouldn't
2362   # pretend that all is well.)
2363   if test -n "$appdirs" ; then
2364     for dir in $appdirs ; do
2365       if test -r $dir/Makefile.in ; then
2366         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2367           appdirs=""
2368           break
2369         fi
2370         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2371           appdirs=""
2372           break
2373         fi
2374       fi
2375     done
2376     if test -n "$appdirs" ; then
2377       echo "*** This configuration is not supported by this package." 1>&2
2378       exit 1
2379     fi
2380   fi
2381   # Okay, some application will build, or we don't care to check.  Still
2382   # notify of subdirs not getting built.
2383   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2384   echo "    ${notsupp}" 1>&2
2385   echo "    (Any other directories should still work fine.)" 1>&2
2386 fi
2387
2388 case "$host" in
2389   *msdosdjgpp*)
2390     enable_gdbtk=no ;;
2391 esac
2392
2393 # To find our prefix, in gcc_cv_tool_prefix.
2394 ACX_TOOL_DIRS
2395
2396 copy_dirs=
2397
2398 AC_ARG_WITH([build-sysroot],
2399   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2400                   [use sysroot as the system root during the build])],
2401   [if test x"$withval" != x ; then
2402      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2403    fi],
2404   [SYSROOT_CFLAGS_FOR_TARGET=])
2405 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2406
2407 AC_ARG_WITH([debug-prefix-map],
2408   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2409                   [map A to B, C to D ... in debug information])],
2410   [if test x"$withval" != x; then
2411      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2412      for debug_map in $withval; do
2413        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2414      done
2415    fi],
2416   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2417 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2418
2419 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2420 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2421 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2422 # We want to ensure that TARGET libraries (which we know are built with
2423 # gcc) are built with "-O2 -g", so include those options when setting
2424 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2425 if test "x$CFLAGS_FOR_TARGET" = x; then
2426   if test "x${is_cross_compiler}" = xyes; then
2427     CFLAGS_FOR_TARGET="-g -O2"
2428   else
2429     CFLAGS_FOR_TARGET=$CFLAGS
2430     case " $CFLAGS " in
2431       *" -O2 "*) ;;
2432       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2433     esac
2434     case " $CFLAGS " in
2435       *" -g "* | *" -g3 "*) ;;
2436       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2437     esac
2438   fi
2439 fi
2440 AC_SUBST(CFLAGS_FOR_TARGET)
2441
2442 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2443   if test "x${is_cross_compiler}" = xyes; then
2444     CXXFLAGS_FOR_TARGET="-g -O2"
2445   else
2446     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2447     case " $CXXFLAGS " in
2448       *" -O2 "*) ;;
2449       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2450     esac
2451     case " $CXXFLAGS " in
2452       *" -g "* | *" -g3 "*) ;;
2453       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2454     esac
2455   fi
2456 fi
2457 AC_SUBST(CXXFLAGS_FOR_TARGET)
2458
2459 AC_SUBST(LDFLAGS_FOR_TARGET)
2460
2461 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2462 # the named directory are copied to $(tooldir)/sys-include.
2463 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2464   if test x${is_cross_compiler} = xno ; then
2465     echo 1>&2 '***' --with-headers is only supported when cross compiling
2466     exit 1
2467   fi
2468   if test x"${with_headers}" != xyes ; then
2469     x=${gcc_cv_tool_prefix}
2470     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2471   fi
2472 fi
2473
2474 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2475 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2476 # are permitted.
2477 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2478   if test x${is_cross_compiler} = xno ; then
2479     echo 1>&2 '***' --with-libs is only supported when cross compiling
2480     exit 1
2481   fi
2482   if test x"${with_libs}" != xyes ; then
2483     # Copy the libraries in reverse order, so that files in the first named
2484     # library override files in subsequent libraries.
2485     x=${gcc_cv_tool_prefix}
2486     for l in ${with_libs}; do
2487       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2488     done
2489   fi
2490 fi
2491
2492 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2493 #
2494 # This is done by determining whether or not the appropriate directory
2495 # is available, and by checking whether or not specific configurations
2496 # have requested that this magic not happen.
2497 #
2498 # The command line options always override the explicit settings in
2499 # configure.ac, and the settings in configure.ac override this magic.
2500 #
2501 # If the default for a toolchain is to use GNU as and ld, and you don't
2502 # want to do that, then you should use the --without-gnu-as and
2503 # --without-gnu-ld options for the configure script.  Similarly, if
2504 # the default is to use the included zlib and you don't want to do that,
2505 # you should use the --with-system-zlib option for the configure script.
2506
2507 if test x${use_gnu_as} = x &&
2508    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2509   with_gnu_as=yes
2510   extra_host_args="$extra_host_args --with-gnu-as"
2511 fi
2512
2513 if test x${use_gnu_ld} = x &&
2514    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2515   with_gnu_ld=yes
2516   extra_host_args="$extra_host_args --with-gnu-ld"
2517 fi
2518
2519 if test x${use_included_zlib} = x &&
2520    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2521   :
2522 else
2523   with_system_zlib=yes
2524   extra_host_args="$extra_host_args --with-system-zlib"
2525 fi
2526
2527 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2528 # can detect this case.
2529
2530 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2531   with_newlib=yes
2532   extra_host_args="$extra_host_args --with-newlib"
2533 fi
2534
2535 # Handle ${copy_dirs}
2536 set fnord ${copy_dirs}
2537 shift
2538 while test $# != 0 ; do
2539   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2540     :
2541   else
2542     echo Copying $1 to $2
2543
2544     # Use the install script to create the directory and all required
2545     # parent directories.
2546     if test -d $2 ; then
2547       :
2548     else
2549       echo >config.temp
2550       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2551     fi
2552
2553     # Copy the directory, assuming we have tar.
2554     # FIXME: Should we use B in the second tar?  Not all systems support it.
2555     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2556
2557     # It is the responsibility of the user to correctly adjust all
2558     # symlinks.  If somebody can figure out how to handle them correctly
2559     # here, feel free to add the code.
2560
2561     echo $1 > $2/COPIED
2562   fi
2563   shift; shift
2564 done
2565
2566 # Determine a target-dependent exec_prefix that the installed
2567 # gcc will search in.  Keep this list sorted by triplet, with
2568 # the *-*-osname triplets last.
2569 md_exec_prefix=
2570 case "${target}" in
2571   i[[34567]]86-pc-msdosdjgpp*)
2572     md_exec_prefix=/dev/env/DJDIR/bin
2573     ;;
2574   *-*-hpux* | \
2575   *-*-nto-qnx* | \
2576   *-*-solaris2*)
2577     md_exec_prefix=/usr/ccs/bin
2578     ;;
2579 esac
2580
2581 extra_arflags_for_target=
2582 extra_nmflags_for_target=
2583 extra_ranlibflags_for_target=
2584 target_makefile_frag=/dev/null
2585 case "${target}" in
2586   spu-*-*)
2587     target_makefile_frag="config/mt-spu"
2588     ;;
2589   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2590     target_makefile_frag="config/mt-sde"
2591     ;;
2592   mipsisa*-*-elfoabi*)
2593     target_makefile_frag="config/mt-mips-elfoabi"
2594     ;;
2595   mips*-*-*linux* | mips*-*-gnu*)
2596     target_makefile_frag="config/mt-mips-gnu"
2597     ;;
2598   nios2-*-elf*)
2599     target_makefile_frag="config/mt-nios2-elf"
2600     ;;
2601   *-*-linux-android*)
2602     target_makefile_frag="config/mt-android"
2603     ;;
2604   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2605     target_makefile_frag="config/mt-gnu"
2606     ;;
2607   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2608     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2609     # commands to handle both 32-bit and 64-bit objects.  These flags are
2610     # harmless if we're using GNU nm or ar.
2611     extra_arflags_for_target=" -X32_64"
2612     extra_nmflags_for_target=" -B -X32_64"
2613     ;;
2614 esac
2615
2616 alphaieee_frag=/dev/null
2617 case $target in
2618   alpha*-*-*)
2619     # This just makes sure to use the -mieee option to build target libs.
2620     # This should probably be set individually by each library.
2621     alphaieee_frag="config/mt-alphaieee"
2622     ;;
2623 esac
2624
2625 # If --enable-target-optspace always use -Os instead of -O2 to build
2626 # the target libraries, similarly if it is not specified, use -Os
2627 # on selected platforms.
2628 ospace_frag=/dev/null
2629 case "${enable_target_optspace}:${target}" in
2630   yes:*)
2631     ospace_frag="config/mt-ospace"
2632     ;;
2633   :d30v-*)
2634     ospace_frag="config/mt-d30v"
2635     ;;
2636   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2637     ospace_frag="config/mt-ospace"
2638     ;;
2639   no:* | :*)
2640     ;;
2641   *)
2642     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2643     ;;
2644 esac
2645
2646 # Some systems (e.g., one of the i386-aix systems the gas testers are
2647 # using) don't handle "\$" correctly, so don't use it here.
2648 tooldir='${exec_prefix}'/${target_noncanonical}
2649 build_tooldir=${tooldir}
2650
2651 # Create a .gdbinit file which runs the one in srcdir
2652 # and tells GDB to look there for source files.
2653
2654 if test -r ${srcdir}/.gdbinit ; then
2655   case ${srcdir} in
2656     .) ;;
2657     *) cat > ./.gdbinit <<EOF
2658 # ${NO_EDIT}
2659 dir ${srcdir}
2660 dir .
2661 source ${srcdir}/.gdbinit
2662 EOF
2663     ;;
2664   esac
2665 fi
2666
2667 # Make sure that the compiler is able to generate an executable.  If it
2668 # can't, we are probably in trouble.  We don't care whether we can run the
2669 # executable--we might be using a cross compiler--we only care whether it
2670 # can be created.  At this point the main configure script has set CC.
2671 we_are_ok=no
2672 echo "int main () { return 0; }" > conftest.c
2673 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2674 if test $? = 0 ; then
2675   if test -s conftest || test -s conftest.exe ; then
2676     we_are_ok=yes
2677   fi
2678 fi
2679 case $we_are_ok in
2680   no)
2681     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2682     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2683     rm -f conftest*
2684     exit 1
2685     ;;
2686 esac
2687 rm -f conftest*
2688
2689 # Decide which environment variable is used to find dynamic libraries.
2690 case "${host}" in
2691   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2692   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2693   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2694   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2695 esac
2696
2697 # On systems where the dynamic library environment variable is PATH,
2698 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2699 # built executables to PATH.
2700 if test "$RPATH_ENVVAR" = PATH; then
2701   GCC_SHLIB_SUBDIR=/shlib
2702 else
2703   GCC_SHLIB_SUBDIR=
2704 fi
2705
2706 # Adjust the toplevel makefile according to whether bootstrap was selected.
2707 case $enable_bootstrap in
2708   yes)
2709     bootstrap_suffix=bootstrap
2710     BUILD_CONFIG=bootstrap-debug
2711     ;;
2712   no)
2713     bootstrap_suffix=no-bootstrap
2714     BUILD_CONFIG=
2715     ;;
2716 esac
2717
2718 AC_MSG_CHECKING(for default BUILD_CONFIG)
2719
2720 AC_ARG_WITH([build-config],
2721   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2722                   [use config/NAME.mk build configuration])],
2723   [case $with_build_config in
2724    yes) with_build_config= ;;
2725    no) with_build_config= BUILD_CONFIG= ;;
2726    esac])
2727
2728 if test "x${with_build_config}" != x; then
2729   BUILD_CONFIG=$with_build_config
2730 else
2731   case $BUILD_CONFIG in
2732   bootstrap-debug)
2733     if echo "int f (void) { return 0; }" > conftest.c &&
2734        ${CC} -c conftest.c &&
2735        mv conftest.o conftest.o.g0 &&
2736        ${CC} -c -g conftest.c &&
2737        mv conftest.o conftest.o.g &&
2738        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2739       :
2740     else
2741       BUILD_CONFIG=
2742     fi
2743     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2744     ;;
2745   esac
2746 fi
2747 AC_MSG_RESULT($BUILD_CONFIG)
2748 AC_SUBST(BUILD_CONFIG)
2749
2750 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2751 AC_MSG_CHECKING([for --enable-vtable-verify])
2752 AC_ARG_ENABLE(vtable-verify,
2753 [AS_HELP_STRING([--enable-vtable-verify],
2754                 [Enable vtable verification feature])],
2755 [case "$enableval" in
2756  yes) enable_vtable_verify=yes ;;
2757  no)  enable_vtable_verify=no ;;
2758  *)   enable_vtable_verify=no;;
2759  esac],
2760 [enable_vtable_verify=no])
2761 AC_MSG_RESULT($enable_vtable_verify)
2762
2763 # Record target_configdirs and the configure arguments for target and
2764 # build configuration in Makefile.
2765 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2766 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2767 bootstrap_fixincludes=no
2768
2769 # If we are building libgomp, bootstrap it.
2770 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2771   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2772 fi
2773
2774 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2775 # or bootstrap-ubsan, bootstrap it.
2776 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2777   case "$BUILD_CONFIG" in
2778     *bootstrap-asan* | *bootstrap-ubsan* )
2779       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2780       bootstrap_fixincludes=yes
2781       ;;
2782   esac
2783 fi
2784
2785 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2786 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2787    test "$enable_vtable_verify" != no; then
2788   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2789 fi
2790
2791 # Determine whether gdb needs tk/tcl or not.
2792 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2793 # and in that case we want gdb to be built without tk.  Ugh!
2794 # In fact I believe gdb is the *only* package directly dependent on tk,
2795 # so we should be able to put the 'maybe's in unconditionally and
2796 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2797 # 100% sure that that's safe though.
2798
2799 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2800 case "$enable_gdbtk" in
2801   no)
2802     GDB_TK="" ;;
2803   yes)
2804     GDB_TK="${gdb_tk}" ;;
2805   *)
2806     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2807     # distro.  Eventually someone will fix this and move Insight, nee
2808     # gdbtk to a separate directory.
2809     if test -d ${srcdir}/gdb/gdbtk ; then
2810       GDB_TK="${gdb_tk}"
2811     else
2812       GDB_TK=""
2813     fi
2814     ;;
2815 esac
2816 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2817 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2818
2819 # gdb depends on gnulib, but as nothing else does, only include it if
2820 # gdb is built.
2821 if echo " ${configdirs} " | grep " gdb " > /dev/null 2>&1 ; then
2822   # The Makefile provides the ordering, so it's enough here to add
2823   # gnulib to the list.
2824   configdirs="${configdirs} gnulib"
2825 fi
2826
2827 # Strip out unwanted targets.
2828
2829 # While at that, we remove Makefiles if we were started for recursive
2830 # configuration, so that the top-level Makefile reconfigures them,
2831 # like we used to do when configure itself was recursive.
2832
2833 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2834 # but now we're fixing up the Makefile ourselves with the additional
2835 # commands passed to AC_CONFIG_FILES.  Use separate variables
2836 # extrasub-{build,host,target} not because there is any reason to split
2837 # the substitutions up that way, but only to remain below the limit of
2838 # 99 commands in a script, for HP-UX sed.
2839
2840 # Do not nest @if/@endif or @unless/@endunless pairs, because
2841 # configure will not warn you at all.
2842
2843 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2844   yes:yes:*\ gold\ *:*,c++,*) ;;
2845   yes:yes:*\ gold\ *:*)
2846     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2847     ;;
2848 esac
2849
2850 extrasub_build=
2851 for module in ${build_configdirs} ; do
2852   if test -z "${no_recursion}" \
2853      && test -f ${build_subdir}/${module}/Makefile; then
2854     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2855     rm -f ${build_subdir}/${module}/Makefile
2856   fi
2857   extrasub_build="$extrasub_build
2858 /^@if build-$module\$/d
2859 /^@endif build-$module\$/d
2860 /^@unless build-$module\$/,/^@endunless build-$module\$/d
2861 /^@if build-$module-$bootstrap_suffix\$/d
2862 /^@endif build-$module-$bootstrap_suffix\$/d
2863 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
2864 done
2865 extrasub_host=
2866 for module in ${configdirs} ; do
2867   if test -z "${no_recursion}"; then
2868     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
2869       if test -f ${file}; then
2870         echo 1>&2 "*** removing ${file} to force reconfigure"
2871         rm -f ${file}
2872       fi
2873     done
2874   fi
2875   case ${module},${bootstrap_fixincludes} in
2876     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
2877     *) host_bootstrap_suffix=$bootstrap_suffix ;;
2878   esac
2879   extrasub_host="$extrasub_host
2880 /^@if $module\$/d
2881 /^@endif $module\$/d
2882 /^@unless $module\$/,/^@endunless $module\$/d
2883 /^@if $module-$host_bootstrap_suffix\$/d
2884 /^@endif $module-$host_bootstrap_suffix\$/d
2885 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
2886 done
2887 extrasub_target=
2888 for module in ${target_configdirs} ; do
2889   if test -z "${no_recursion}" \
2890      && test -f ${target_subdir}/${module}/Makefile; then
2891     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
2892     rm -f ${target_subdir}/${module}/Makefile
2893   fi
2894
2895   # We only bootstrap target libraries listed in bootstrap_target_libs.
2896   case $bootstrap_target_libs in
2897     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
2898     *) target_bootstrap_suffix=no-bootstrap ;;
2899   esac
2900
2901   extrasub_target="$extrasub_target
2902 /^@if target-$module\$/d
2903 /^@endif target-$module\$/d
2904 /^@unless target-$module\$/,/^@endunless target-$module\$/d
2905 /^@if target-$module-$target_bootstrap_suffix\$/d
2906 /^@endif target-$module-$target_bootstrap_suffix\$/d
2907 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
2908 done
2909
2910 # Do the final fixup along with target modules.
2911 extrasub_target="$extrasub_target
2912 /^@if /,/^@endif /d
2913 /^@unless /d
2914 /^@endunless /d"
2915
2916 # Create the serialization dependencies.  This uses a temporary file.
2917
2918 AC_ARG_ENABLE([serial-configure],
2919 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
2920                 [force sequential configuration of
2921                  sub-packages for the host, target or build
2922                  machine, or all sub-packages])])
2923
2924 case ${enable_serial_configure} in
2925   yes)
2926     enable_serial_build_configure=yes
2927     enable_serial_host_configure=yes
2928     enable_serial_target_configure=yes
2929     ;;
2930 esac
2931
2932 # These force 'configure's to be done one at a time, to avoid problems
2933 # with contention over a shared config.cache.
2934 rm -f serdep.tmp
2935 echo '# serdep.tmp' > serdep.tmp
2936 olditem=
2937 test "x${enable_serial_build_configure}" = xyes &&
2938 for item in ${build_configdirs} ; do
2939   case ${olditem} in
2940     "") ;;
2941     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
2942   esac
2943   olditem=${item}
2944 done
2945 olditem=
2946 test "x${enable_serial_host_configure}" = xyes &&
2947 for item in ${configdirs} ; do
2948   case ${olditem} in
2949     "") ;;
2950     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
2951   esac
2952   olditem=${item}
2953 done
2954 olditem=
2955 test "x${enable_serial_target_configure}" = xyes &&
2956 for item in ${target_configdirs} ; do
2957   case ${olditem} in
2958     "") ;;
2959     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
2960   esac
2961   olditem=${item}
2962 done
2963 serialization_dependencies=serdep.tmp
2964 AC_SUBST_FILE(serialization_dependencies)
2965
2966 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
2967 # target, nonopt, and variable assignments.  These are the ones we
2968 # might not want to pass down to subconfigures.  The exception being
2969 # --cache-file=/dev/null, which is used to turn off the use of cache
2970 # files altogether, and which should be passed on to subconfigures.
2971 # Also strip program-prefix, program-suffix, and program-transform-name,
2972 # so that we can pass down a consistent program-transform-name.
2973 baseargs=
2974 tbaseargs=
2975 keep_next=no
2976 skip_next=no
2977 eval "set -- $ac_configure_args"
2978 for ac_arg
2979 do
2980   if test X"$skip_next" = X"yes"; then
2981     skip_next=no
2982     continue
2983   fi
2984   if test X"$keep_next" = X"yes"; then
2985     case $ac_arg in
2986       *\'*)
2987         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
2988     esac
2989     baseargs="$baseargs '$ac_arg'"
2990     tbaseargs="$tbaseargs '$ac_arg'"
2991     keep_next=no
2992     continue
2993   fi
2994
2995   # Handle separated arguments.  Based on the logic generated by
2996   # autoconf 2.59.
2997   case $ac_arg in
2998     *=* | --config-cache | -C | -disable-* | --disable-* \
2999       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3000       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3001       | -with-* | --with-* | -without-* | --without-* | --x)
3002       separate_arg=no
3003       ;;
3004     -*)
3005       separate_arg=yes
3006       ;;
3007     *)
3008       separate_arg=no
3009       ;;
3010   esac
3011
3012   skip_targ=no
3013   case $ac_arg in
3014 changequote(,)
3015   --with-* | --without-*)
3016     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3017
3018     case $libopt in
3019     *[-_]include)
3020       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3021       ;;
3022     *[-_]lib)
3023       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3024       ;;
3025     *)
3026       lib=$libopt
3027       ;;
3028     esac
3029 changequote([,])
3030
3031     case $lib in
3032     mpc | mpfr | gmp | isl)
3033       # If we're processing --with-$lib, --with-$lib-include or
3034       # --with-$lib-lib, for one of the libs above, and target is
3035       # different from host, don't pass the current argument to any
3036       # target library's configure.
3037       if test x$is_cross_compiler = xyes; then
3038         skip_targ=yes
3039       fi
3040       ;;
3041     esac
3042     ;;
3043   esac
3044
3045   case "$ac_arg" in
3046     --cache-file=/dev/null | \
3047     -cache-file=/dev/null )
3048       # Handled here to avoid the test to skip args below.
3049       baseargs="$baseargs '$ac_arg'"
3050       tbaseargs="$tbaseargs '$ac_arg'"
3051       # Assert: $separate_arg should always be no.
3052       keep_next=$separate_arg
3053       ;;
3054     --no*)
3055       continue
3056       ;;
3057     --c* | \
3058     --sr* | \
3059     --ho* | \
3060     --bu* | \
3061     --t* | \
3062     --program-* | \
3063     -cache_file* | \
3064     -srcdir* | \
3065     -host* | \
3066     -build* | \
3067     -target* | \
3068     -program-prefix* | \
3069     -program-suffix* | \
3070     -program-transform-name* )
3071       skip_next=$separate_arg
3072       continue
3073       ;;
3074     -*)
3075       # An option.  Add it.
3076       case $ac_arg in
3077         *\'*)
3078           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3079       esac
3080       baseargs="$baseargs '$ac_arg'"
3081       if test X"$skip_targ" = Xno; then
3082         tbaseargs="$tbaseargs '$ac_arg'"
3083       fi
3084       keep_next=$separate_arg
3085       ;;
3086     *)
3087       # Either a variable assignment, or a nonopt (triplet).  Don't
3088       # pass it down; let the Makefile handle this.
3089       continue
3090       ;;
3091   esac
3092 done
3093 # Remove the initial space we just introduced and, as these will be
3094 # expanded by make, quote '$'.
3095 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3096
3097 # Add in --program-transform-name, after --program-prefix and
3098 # --program-suffix have been applied to it.  Autoconf has already
3099 # doubled dollar signs and backslashes in program_transform_name; we want
3100 # the backslashes un-doubled, and then the entire thing wrapped in single
3101 # quotes, because this will be expanded first by make and then by the shell.
3102 # Also, because we want to override the logic in subdir configure scripts to
3103 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3104 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3105 ${program_transform_name}
3106 EOF_SED
3107 gcc_transform_name=`cat conftestsed.out`
3108 rm -f conftestsed.out
3109 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3110 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3111 if test "$silent" = yes; then
3112   baseargs="$baseargs --silent"
3113   tbaseargs="$tbaseargs --silent"
3114 fi
3115 baseargs="$baseargs --disable-option-checking"
3116 tbaseargs="$tbaseargs --disable-option-checking"
3117
3118 # Record and document user additions to sub configure arguments.
3119 AC_ARG_VAR([build_configargs],
3120            [additional configure arguments for build directories])
3121 AC_ARG_VAR([host_configargs],
3122            [additional configure arguments for host directories])
3123 AC_ARG_VAR([target_configargs],
3124            [additional configure arguments for target directories])
3125
3126 # For the build-side libraries, we just need to pretend we're native,
3127 # and not use the same cache file.  Multilibs are neither needed nor
3128 # desired.  We can't even use the same cache file for all build-side
3129 # libraries, as they're compiled differently; some with C, some with
3130 # C++ or with different feature-enabling options.
3131 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3132
3133 # For host modules, accept cache file option, or specification as blank.
3134 case "${cache_file}" in
3135 "") # empty
3136   cache_file_option="" ;;
3137 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3138   cache_file_option="--cache-file=${cache_file}" ;;
3139 *) # relative path
3140   cache_file_option="--cache-file=../${cache_file}" ;;
3141 esac
3142
3143 # Host dirs don't like to share a cache file either, horribly enough.
3144 # This seems to be due to autoconf 2.5x stupidity.
3145 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3146
3147 target_configargs="$target_configargs ${tbaseargs}"
3148
3149 # Passing a --with-cross-host argument lets the target libraries know
3150 # whether they are being built with a cross-compiler or being built
3151 # native.  However, it would be better to use other mechanisms to make the
3152 # sorts of decisions they want to make on this basis.  Please consider
3153 # this option to be deprecated.  FIXME.
3154 if test x${is_cross_compiler} = xyes ; then
3155   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3156 fi
3157
3158 # Special user-friendly check for native x86_64-linux build, if
3159 # multilib is not explicitly enabled.
3160 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3161   x86_64-*linux*:yes:$build:$build:)
3162     # Make sure we have a development environment that handles 32-bit
3163     dev64=no
3164     echo "int main () { return 0; }" > conftest.c
3165     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3166     if test $? = 0 ; then
3167       if test -s conftest || test -s conftest.exe ; then
3168         dev64=yes
3169       fi
3170     fi
3171     rm -f conftest*
3172     if test x${dev64} != xyes ; then
3173       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3174     fi
3175     ;;
3176 esac
3177
3178 # Default to --enable-multilib.
3179 if test x${enable_multilib} = x ; then
3180   target_configargs="--enable-multilib ${target_configargs}"
3181 fi
3182
3183 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3184 # changed from the earlier setting of with_newlib.
3185 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3186   target_configargs="--with-newlib ${target_configargs}"
3187 fi
3188
3189 # Different target subdirs use different values of certain variables
3190 # (notably CXX).  Worse, multilibs use *lots* of different values.
3191 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3192 # it doesn't automatically accept command-line overrides of them.
3193 # This means it's not safe for target subdirs to share a cache file,
3194 # which is disgusting, but there you have it.  Hopefully this can be
3195 # fixed in future.  It's still worthwhile to use a cache file for each
3196 # directory.  I think.
3197
3198 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3199 # We need to pass --target, as newer autoconf's requires consistency
3200 # for target_alias and gcc doesn't manage it consistently.
3201 target_configargs="--cache-file=./config.cache ${target_configargs}"
3202
3203 FLAGS_FOR_TARGET=
3204 case " $target_configdirs " in
3205  *" newlib "*)
3206   case " $target_configargs " in
3207   *" --with-newlib "*)
3208    case "$target" in
3209     *-cygwin*)
3210       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3211       ;;
3212    esac
3213
3214    # If we're not building GCC, don't discard standard headers.
3215    if test -d ${srcdir}/gcc; then
3216      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3217
3218      if test "${build}" != "${host}"; then
3219        # On Canadian crosses, CC_FOR_TARGET will have already been set
3220        # by `configure', so we won't have an opportunity to add -Bgcc/
3221        # to it.  This is right: we don't want to search that directory
3222        # for binaries, but we want the header files in there, so add
3223        # them explicitly.
3224        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3225
3226        # Someone might think of using the pre-installed headers on
3227        # Canadian crosses, in case the installed compiler is not fully
3228        # compatible with the compiler being built.  In this case, it
3229        # would be better to flag an error than risking having
3230        # incompatible object files being constructed.  We can't
3231        # guarantee that an error will be flagged, but let's hope the
3232        # compiler will do it, when presented with incompatible header
3233        # files.
3234      fi
3235    fi
3236
3237    case "${target}-${is_cross_compiler}" in
3238    i[[3456789]]86-*-linux*-no)
3239       # Here host == target, so we don't need to build gcc,
3240       # so we don't want to discard standard headers.
3241       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3242       ;;
3243    *)
3244       # If we're building newlib, use its generic headers last, but search
3245       # for any libc-related directories first (so make it the last -B
3246       # switch).
3247       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3248
3249       # If we're building libgloss, find the startup file, simulator library
3250       # and linker script.
3251       case " $target_configdirs " in
3252         *" libgloss "*)
3253         # Look for startup file, simulator library and maybe linker script.
3254         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3255         # Look for libnosys.a in case the target needs it.
3256         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3257         # Most targets have the linker script in the source directory.
3258         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3259         ;;
3260       esac
3261       ;;
3262    esac
3263    ;;
3264   esac
3265   ;;
3266 esac
3267
3268 case "$target" in
3269   x86_64-*mingw* | *-w64-mingw*)
3270   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3271   # however, use a symlink named 'mingw' in ${prefix} .
3272     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3273     ;;
3274   *-mingw*)
3275   # MinGW can't be handled as Cygwin above since it does not use newlib.
3276     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3277     ;;
3278 esac
3279
3280 # Allow the user to override the flags for
3281 # our build compiler if desired.
3282 if test x"${build}" = x"${host}" ; then
3283   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3284   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3285   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3286 fi
3287
3288 # On Canadian crosses, we'll be searching the right directories for
3289 # the previously-installed cross compiler, so don't bother to add
3290 # flags for directories within the install tree of the compiler
3291 # being built; programs in there won't even run.
3292 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3293   # Search for pre-installed headers if nothing else fits.
3294   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3295 fi
3296
3297 if test "x${use_gnu_ld}" = x &&
3298    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3299   # Arrange for us to find uninstalled linker scripts.
3300   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3301 fi
3302
3303 # Search for other target-specific linker scripts and such.
3304 case "${target}" in
3305   mep*)
3306     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3307     ;;
3308 esac
3309
3310 # Makefile fragments.
3311 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3312 do
3313   eval fragval=\$$frag
3314   if test $fragval != /dev/null; then
3315     eval $frag=${srcdir}/$fragval
3316   fi
3317 done
3318 AC_SUBST_FILE(host_makefile_frag)
3319 AC_SUBST_FILE(target_makefile_frag)
3320 AC_SUBST_FILE(alphaieee_frag)
3321 AC_SUBST_FILE(ospace_frag)
3322
3323 # Miscellanea: directories, flags, etc.
3324 AC_SUBST(RPATH_ENVVAR)
3325 AC_SUBST(GCC_SHLIB_SUBDIR)
3326 AC_SUBST(tooldir)
3327 AC_SUBST(build_tooldir)
3328 AC_SUBST(CONFIGURE_GDB_TK)
3329 AC_SUBST(GDB_TK)
3330 AC_SUBST(INSTALL_GDB_TK)
3331
3332 # Build module lists & subconfigure args.
3333 AC_SUBST(build_configargs)
3334 AC_SUBST(build_configdirs)
3335
3336 # Host module lists & subconfigure args.
3337 AC_SUBST(host_configargs)
3338 AC_SUBST(configdirs)
3339 AC_SUBST(target_configdirs)
3340
3341 # Target module lists & subconfigure args.
3342 AC_SUBST(target_configargs)
3343
3344
3345 # Build tools.
3346 AC_SUBST(AR_FOR_BUILD)
3347 AC_SUBST(AS_FOR_BUILD)
3348 AC_SUBST(CC_FOR_BUILD)
3349 AC_SUBST(CFLAGS_FOR_BUILD)
3350 AC_SUBST(CXXFLAGS_FOR_BUILD)
3351 AC_SUBST(CXX_FOR_BUILD)
3352 AC_SUBST(DLLTOOL_FOR_BUILD)
3353 AC_SUBST(GFORTRAN_FOR_BUILD)
3354 AC_SUBST(GOC_FOR_BUILD)
3355 AC_SUBST(GDC_FOR_BUILD)
3356 AC_SUBST(LDFLAGS_FOR_BUILD)
3357 AC_SUBST(LD_FOR_BUILD)
3358 AC_SUBST(NM_FOR_BUILD)
3359 AC_SUBST(RANLIB_FOR_BUILD)
3360 AC_SUBST(WINDMC_FOR_BUILD)
3361 AC_SUBST(WINDRES_FOR_BUILD)
3362
3363 # Generate default definitions for YACC, M4, LEX and other programs that run
3364 # on the build machine.  These are used if the Makefile can't locate these
3365 # programs in objdir.
3366 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3367
3368 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3369 case " $build_configdirs " in
3370   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3371 esac
3372
3373 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3374 case " $build_configdirs " in
3375   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3376 esac
3377
3378 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3379 case " $build_configdirs " in
3380   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3381 esac
3382
3383 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3384 case " $build_configdirs " in
3385   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3386   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3387 esac
3388
3389 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3390 case " $build_configdirs " in
3391   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3392 esac
3393
3394 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3395 case " $build_configdirs " in
3396   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3397   *)
3398 changequote(,)
3399     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3400     # higher, else we use the "missing" dummy.
3401     if ${MAKEINFO} --version \
3402        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3403       :
3404     else
3405       MAKEINFO="$MISSING makeinfo"
3406     fi
3407     ;;
3408 changequote([,])
3409 esac
3410
3411 # FIXME: expect and dejagnu may become build tools?
3412
3413 AC_CHECK_PROGS(EXPECT, expect, expect)
3414 case " $configdirs " in
3415   *" expect "*)
3416     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3417     ;;
3418 esac
3419
3420 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3421 case " $configdirs " in
3422   *" dejagnu "*)
3423     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3424     ;;
3425 esac
3426
3427
3428 # Host tools.
3429 NCN_STRICT_CHECK_TOOLS(AR, ar)
3430 NCN_STRICT_CHECK_TOOLS(AS, as)
3431 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3432 NCN_STRICT_CHECK_TOOLS(LD, ld)
3433 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3434 NCN_STRICT_CHECK_TOOLS(NM, nm)
3435 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3436 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3437 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3438 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3439 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3440 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3441 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3442 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3443 AC_SUBST(CC)
3444 AC_SUBST(CXX)
3445 AC_SUBST(CFLAGS)
3446 AC_SUBST(CXXFLAGS)
3447
3448 # Target tools.
3449 AC_ARG_WITH([build-time-tools],
3450   [AS_HELP_STRING([--with-build-time-tools=PATH],
3451                   [use given path to find target tools during the build])],
3452   [case x"$withval" in
3453      x/*) ;;
3454      *)
3455        with_build_time_tools=
3456        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3457        ;;
3458    esac],
3459   [with_build_time_tools=])
3460
3461 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3462 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3463 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3464 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3465 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3466 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3467
3468 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3469 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3470 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3471 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3472 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3473 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3474 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3475 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3476 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3477 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3478 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3479 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3480 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3481 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3482
3483 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3484
3485 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3486 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3487 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3488 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3489 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3490                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3491                 c++)
3492 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3493                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3494                 c++)
3495 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3496 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3497 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3498                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3499 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3500                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3501 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3502                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3503 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3504 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3505 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3506 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3507 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3508 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3509 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3510 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3511 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3512 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3513 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3514
3515 AC_SUBST(FLAGS_FOR_TARGET)
3516 AC_SUBST(RAW_CXX_FOR_TARGET)
3517
3518 # Certain tools may need extra flags.
3519 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3520 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3521 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3522
3523 # When building target libraries, except in a Canadian cross, we use
3524 # the same toolchain as the compiler we just built.
3525 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3526 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3527 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3528 if test $host = $build; then
3529   case " $configdirs " in
3530     *" gcc "*)
3531       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3532       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3533       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3534       ;;
3535   esac
3536 fi
3537
3538 AC_SUBST(COMPILER_AS_FOR_TARGET)
3539 AC_SUBST(COMPILER_LD_FOR_TARGET)
3540 AC_SUBST(COMPILER_NM_FOR_TARGET)
3541
3542 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3543 AC_ARG_ENABLE(maintainer-mode,
3544 [AS_HELP_STRING([--enable-maintainer-mode],
3545                 [enable make rules and dependencies not useful
3546                  (and sometimes confusing) to the casual installer])],
3547       USE_MAINTAINER_MODE=$enableval,
3548       USE_MAINTAINER_MODE=no)
3549 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3550 AC_SUBST(MAINTAINER_MODE_TRUE)
3551 AC_SUBST(MAINTAINER_MODE_FALSE)
3552 if test "$USE_MAINTAINER_MODE" = yes; then
3553   MAINTAINER_MODE_TRUE=
3554   MAINTAINER_MODE_FALSE='#'
3555 else
3556   MAINTAINER_MODE_TRUE='#'
3557   MAINTAINER_MODE_FALSE=
3558 fi
3559 MAINT=$MAINTAINER_MODE_TRUE
3560 AC_SUBST(MAINT)dnl
3561
3562 # ---------------------
3563 # GCC bootstrap support
3564 # ---------------------
3565
3566 # Stage specific cflags for build.
3567 stage1_cflags="-g"
3568 case $build in
3569   vax-*-*)
3570     case ${GCC} in
3571       yes) stage1_cflags="-g -Wa,-J" ;;
3572       *) stage1_cflags="-g -J" ;;
3573     esac ;;
3574 esac
3575
3576 AC_SUBST(stage1_cflags)
3577
3578 # Enable --enable-checking in stage1 of the compiler.
3579 AC_ARG_ENABLE(stage1-checking,
3580 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3581                 [choose additional checking for stage1 of the compiler])],
3582 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3583 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3584   # For --disable-checking or implicit --enable-checking=release, avoid
3585   # setting --enable-checking=gc in the default stage1 checking for LTO
3586   # bootstraps.  See PR62077.
3587   case $BUILD_CONFIG in
3588     *lto*)
3589       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3590     *)
3591       stage1_checking=--enable-checking=yes,types;;
3592   esac
3593   if test "x$enable_checking" = x && \
3594      test -d ${srcdir}/gcc && \
3595      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3596     stage1_checking=--enable-checking=yes,types,extra
3597   fi
3598 else
3599   stage1_checking=--enable-checking=$enable_checking,types
3600 fi])
3601 AC_SUBST(stage1_checking)
3602
3603 # Enable -Werror in bootstrap stage2 and later.
3604 AC_ARG_ENABLE(werror,
3605 [AS_HELP_STRING([--enable-werror],
3606                 [enable -Werror in bootstrap stage2 and later])],
3607 [
3608 case ${enable_werror} in
3609   yes) stage2_werror_flag="--enable-werror-always" ;;
3610   *) stage2_werror_flag="" ;;
3611 esac
3612 ],
3613 [
3614 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3615   case $BUILD_CONFIG in
3616   bootstrap-debug)
3617       stage2_werror_flag="--enable-werror-always" ;;
3618   "")
3619       stage2_werror_flag="--enable-werror-always" ;;
3620   esac
3621 fi
3622 ])
3623
3624 AC_SUBST(stage2_werror_flag)
3625
3626 # Specify what files to not compare during bootstrap.
3627
3628 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3629 case "$target" in
3630   hppa*64*-*-hpux*) ;;
3631   hppa*-*-hpux*) compare_exclusions="$compare_exclusions | */libgcc/lib2funcs* | gcc/function-tests.o" ;;
3632   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3633 esac
3634 AC_SUBST(compare_exclusions)
3635
3636 AC_CONFIG_FILES([Makefile],
3637   [sed "$extrasub_build" Makefile |
3638    sed "$extrasub_host" |
3639    sed "$extrasub_target" > mf$$
3640    mv -f mf$$ Makefile],
3641   [extrasub_build="$extrasub_build"
3642    extrasub_host="$extrasub_host"
3643    extrasub_target="$extrasub_target"])
3644 AC_OUTPUT