libatomic/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2 #  Copyright (C) 2012-2017 Free Software Foundation, Inc.
   3 #
   4 #  This file is part of the GNU Atomic Library (libatomic).
   5 #
   6 #  Libatomic is free software; you can redistribute it and/or modify it
   7 #  under the terms of the GNU General Public License as published by
   8 #  the Free Software Foundation; either version 3 of the License, or
   9 #  (at your option) any later version.
  10 #
  11 #  Libatomic is distributed in the hope that it will be useful, but WITHOUT ANY
  12 #  WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  13 #  FOR A PARTICULAR PURPOSE.  See the GNU General Public License for
  14 #  more details.
  15 #
  16 #  Under Section 7 of GPL version 3, you are granted additional
  17 #  permissions described in the GCC Runtime Library Exception, version
  18 #  3.1, as published by the Free Software Foundation.
  19 #
  20 #  You should have received a copy of the GNU General Public License and
  21 #  a copy of the GCC Runtime Library Exception along with this program;
  22 #  see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see
  23 #  <http://www.gnu.org/licenses/>.
  24
  25 AC_PREREQ(2.59)
  26 AC_INIT([GNU Atomic Library], 1.0,,[libatomic])
  27 AC_CONFIG_HEADER(auto-config.h)
  28
  29 # -------
  30 # Options
  31 # -------
  32
  33 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  34 LIBAT_ENABLE(version-specific-runtime-libs, no, ,
  35    [Specify that runtime libraries should be installed in a compiler-specific directory],
  36    permit yes|no)
  37 AC_MSG_RESULT($enable_version_specific_runtime_libs)
  38
  39 # We would like our source tree to be readonly. However when releases or
  40 # pre-releases are generated, the flex/bison generated files as well as the
  41 # various formats of manuals need to be included along with the rest of the
  42 # sources.  Therefore we have --enable-generated-files-in-srcdir to do
  43 # just that.
  44 AC_MSG_CHECKING([for --enable-generated-files-in-srcdir])
  45 LIBAT_ENABLE(generated-files-in-srcdir, no, ,
  46    [put copies of generated files in source dir intended for creating source
  47     tarballs for users without texinfo bison or flex.],
  48    permit yes|no)
  49 AC_MSG_RESULT($enable_generated_files_in_srcdir)
  50 AM_CONDITIONAL(GENINSRC, test "$enable_generated_files_in_srcdir" = yes)
  51
  52
  53 # -------
  54
  55 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  56 #
  57 # You will slowly go insane if you do not grok the following fact:  when
  58 # building this library, the top-level /target/ becomes the library's /host/.
  59 #
  60 # configure then causes --target to default to --host, exactly like any
  61 # other package using autoconf.  Therefore, 'target' and 'host' will
  62 # always be the same.  This makes sense both for native and cross compilers
  63 # just think about it for a little while.  :-)
  64 #
  65 # Also, if this library is being configured as part of a cross compiler, the
  66 # top-level configure script will pass the "real" host as $with_cross_host.
  67 #
  68 # Do not delete or change the following two lines.  For why, see
  69 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  70 AC_CANONICAL_SYSTEM
  71 target_alias=${target_alias-$host_alias}
  72
  73 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  74 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  75 #  1.9.0:  minimum required version
  76 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  77 #              of other PACKAGE_* variables will, however, and there's nothing
  78 #              we can do about that; they come from AC_INIT).
  79 #  no-dist:  we don't want 'dist' and related rules.
  80 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  81 #            file in the top srcdir, etc, etc), so stop complaining.
  82 #  -Wall:  turns on all automake warnings...
  83 #  -Wno-portability:  ...except this one, since GNU make is required.
  84 #  -Wno-override: ... and this one, since we do want this in testsuite.
  85 AM_INIT_AUTOMAKE([1.9.0 foreign no-dist -Wall -Wno-portability -Wno-override])
  86 AM_ENABLE_MULTILIB(, ..)
  87
  88 # Calculate toolexeclibdir
  89 # Also toolexecdir, though it's only used in toolexeclibdir
  90 case ${enable_version_specific_runtime_libs} in
  91   yes)
  92     # Need the gcc compiler version to know where to install libraries
  93     # and header files if --enable-version-specific-runtime-libs option
  94     # is selected.
  95     toolexecdir='$(libdir)/gcc/$(target_alias)'
  96     toolexeclibdir='$(toolexecdir)/$(gcc_version)$(MULTISUBDIR)'
  97     ;;
  98   no)
  99     if test -n "$with_cross_host" &&
 100        test x"$with_cross_host" != x"no"; then
 101       # Install a library built with a cross compiler in tooldir, not libdir.
 102       toolexecdir='$(exec_prefix)/$(target_alias)'
 103       toolexeclibdir='$(toolexecdir)/lib'
 104     else
 105       toolexecdir='$(libdir)/gcc-lib/$(target_alias)'
 106       toolexeclibdir='$(libdir)'
 107     fi
 108     multi_os_directory=`$CC -print-multi-os-directory`
 109     case $multi_os_directory in
 110       .) ;; # Avoid trailing /.
 111       *) toolexeclibdir=$toolexeclibdir/$multi_os_directory ;;
 112     esac
 113     ;;
 114 esac
 115 AC_SUBST(toolexecdir)
 116 AC_SUBST(toolexeclibdir)
 117
 118 # Check the compiler.
 119 # The same as in boehm-gc and libstdc++. Have to borrow it from there.
 120 # We must force CC to /not/ be precious variables; otherwise
 121 # the wrong, non-multilib-adjusted value will be used in multilibs.
 122 # As a side effect, we have to subst CFLAGS ourselves.
 123
 124 m4_rename([_AC_ARG_VAR_PRECIOUS],[real_PRECIOUS])
 125 m4_define([_AC_ARG_VAR_PRECIOUS],[])
 126 AC_PROG_CC
 127 AM_PROG_AS
 128 m4_rename_force([real_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
 129
 130 AC_SUBST(CFLAGS)
 131
 132 # In order to override CFLAGS_FOR_TARGET, all of our special flags go
 133 # in XCFLAGS.  But we need them in CFLAGS during configury.  So put them
 134 # in both places for now and restore CFLAGS at the end of config.
 135 save_CFLAGS="$CFLAGS"
 136
 137 # Find other programs we need.
 138 AC_CHECK_TOOL(AR, ar)
 139 AC_CHECK_TOOL(NM, nm)
 140 AC_CHECK_TOOL(RANLIB, ranlib, ranlib-not-found-in-path-error)
 141 AC_PATH_PROG(PERL, perl, perl-not-found-in-path-error)
 142 AC_PROG_INSTALL
 143
 144 # Configure libtool
 145 AM_PROG_LIBTOOL
 146 ACX_LT_HOST_FLAGS
 147 AC_SUBST(enable_shared)
 148 AC_SUBST(enable_static)
 149 AM_MAINTAINER_MODE
 150
 151 # For libtool versioning info, format is CURRENT:REVISION:AGE
 152 libtool_VERSION=3:0:2
 153 AC_SUBST(libtool_VERSION)
 154
 155 # Check for used threading-model
 156 AC_MSG_CHECKING([for thread model used by GCC])
 157 target_thread_file=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 158 AC_MSG_RESULT([$target_thread_file])
 159
 160 # Get target configury.
 161 . ${srcdir}/configure.tgt
 162 if test -n "$UNSUPPORTED"; then
 163   AC_MSG_ERROR([Configuration ${target} is unsupported.])
 164 fi
 165
 166 # Disable fallbacks to __sync routines from libgcc.  Otherwise we'll
 167 # make silly decisions about what the cpu can do.
 168 CFLAGS="$save_CFLAGS -fno-sync-libcalls $XCFLAGS"
 169
 170 # Check header files.
 171 AC_STDC_HEADERS
 172 ACX_HEADER_STRING
 173 GCC_HEADER_STDINT(gstdint.h)
 174 AC_CHECK_HEADERS([fenv.h])
 175
 176 # Check for common type sizes
 177 LIBAT_FORALL_MODES([LIBAT_HAVE_INT_MODE])
 178
 179 # Check for compiler builtins of atomic operations.
 180 LIBAT_TEST_ATOMIC_INIT
 181 LIBAT_FORALL_MODES([LIBAT_HAVE_ATOMIC_LOADSTORE])
 182 LIBAT_FORALL_MODES([LIBAT_HAVE_ATOMIC_TAS])
 183 LIBAT_FORALL_MODES([LIBAT_HAVE_ATOMIC_EXCHANGE])
 184 LIBAT_FORALL_MODES([LIBAT_HAVE_ATOMIC_CAS])
 185 LIBAT_FORALL_MODES([LIBAT_HAVE_ATOMIC_FETCH_ADD])
 186 LIBAT_FORALL_MODES([LIBAT_HAVE_ATOMIC_FETCH_OP])
 187
 188 AC_C_BIGENDIAN
 189 # I don't like the default behaviour of WORDS_BIGENDIAN undefined for LE.
 190 AH_BOTTOM(
 191 [#ifndef WORDS_BIGENDIAN
 192 #define WORDS_BIGENDIAN 0
 193 #endif])
 194
 195 LIBAT_WORDSIZE
 196
 197 # Check to see if -pthread or -lpthread is needed.  Prefer the former.
 198 # In case the pthread.h system header is not found, this test will fail.
 199 case " $config_path " in
 200  *" posix "*)
 201   XPCFLAGS=""
 202   CFLAGS="$CFLAGS -pthread"
 203   AC_LINK_IFELSE(
 204     [AC_LANG_PROGRAM(
 205      [#include <pthread.h>
 206       void *g(void *d) { return NULL; }],
 207      [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 208     [XPCFLAGS=" -pthread"],
 209     [CFLAGS="$save_CFLAGS $XCFLAGS" LIBS="-lpthread $LIBS"
 210      AC_LINK_IFELSE(
 211       [AC_LANG_PROGRAM(
 212        [#include <pthread.h>
 213         void *g(void *d) { return NULL; }],
 214        [pthread_t t; pthread_create(&t,NULL,g,NULL);])],
 215       [],
 216       [AC_MSG_ERROR([Pthreads are required to build libatomic])])])
 217   CFLAGS="$save_CFLAGS $XPCFLAGS"
 218   ;;
 219 esac
 220
 221 # See what sort of export controls are available.
 222 LIBAT_CHECK_ATTRIBUTE_VISIBILITY
 223 LIBAT_CHECK_ATTRIBUTE_DLLEXPORT
 224 LIBAT_CHECK_ATTRIBUTE_ALIAS
 225 if test x$try_ifunc = xyes; then
 226   LIBAT_CHECK_IFUNC
 227 fi
 228
 229 # Check linker support.
 230 LIBAT_ENABLE_SYMVERS
 231
 232 # Cleanup and exit.
 233 CFLAGS="$save_CFLAGS"
 234 AC_CACHE_SAVE
 235
 236 # Add -Wall -Werror if we are using GCC.
 237 if test "x$GCC" = "xyes"; then
 238   XCFLAGS="$XCFLAGS -Wall -Werror"
 239 fi
 240
 241 XCFLAGS="$XCFLAGS $XPCFLAGS"
 242
 243 AC_SUBST(config_path)
 244 AC_SUBST(XCFLAGS)
 245 AC_SUBST(XLDFLAGS)
 246 AC_SUBST(LIBS)
 247 AC_SUBST(SIZES)
 248
 249 AM_CONDITIONAL(HAVE_IFUNC, test x$libat_cv_have_ifunc = xyes)
 250 AM_CONDITIONAL(ARCH_ARM_LINUX,
 251                [expr "$config_path" : ".* linux/arm .*" > /dev/null])
 252 AM_CONDITIONAL(ARCH_I386,
 253                [test "$ARCH" = x86 && test x$libat_cv_wordsize = x4])
 254 AM_CONDITIONAL(ARCH_X86_64,
 255                [test "$ARCH" = x86 && test x$libat_cv_wordsize = x8])
 256
 257 if test ${multilib} = yes; then
 258   multilib_arg="--enable-multilib"
 259 else
 260   multilib_arg=
 261 fi
 262
 263 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 264 AC_OUTPUT