gcc/ada/7straceb.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                     S Y S T E M . T R A C E B A C K                      --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --           Copyright (C) 1999-2000 Ada Core Technologies, Inc.            --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNAT;  see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNAT was originally developed  by the GNAT team at  New York University. --
  30 -- It is now maintained by Ada Core Technologies Inc (http://www.gnat.com). --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This version assumes that System.Machine_State_Operations.Pop_Frame can
  35 --  work with the Info parameter being null.
  36
  37 with System.Machine_State_Operations;
  38
  39 package body System.Traceback is
  40
  41    use System.Machine_State_Operations;
  42
  43    ----------------
  44    -- Call_Chain --
  45    ----------------
  46
  47    procedure Call_Chain
  48      (Traceback : System.Address;
  49       Max_Len   : Natural;
  50       Len       : out Natural;
  51       Exclude_Min,
  52       Exclude_Max : System.Address := System.Null_Address)
  53    is
  54       type Tracebacks_Array is array (1 .. Max_Len) of Code_Loc;
  55       pragma Suppress_Initialization (Tracebacks_Array);
  56
  57       M     : Machine_State;
  58       Code  : Code_Loc;
  59       J     : Natural := 1;
  60       Trace : Tracebacks_Array;
  61       for Trace'Address use Traceback;
  62
  63    begin
  64       M := Allocate_Machine_State;
  65       Set_Machine_State (M);
  66
  67       loop
  68          Code := Get_Code_Loc (M);
  69
  70          exit when Code = Null_Address or else J = Max_Len + 1;
  71
  72          if Code < Exclude_Min or else Code > Exclude_Max then
  73             Trace (J) := Code;
  74             J := J + 1;
  75          end if;
  76
  77          Pop_Frame (M, System.Null_Address);
  78       end loop;
  79
  80       Len := J - 1;
  81       Free_Machine_State (M);
  82    end Call_Chain;
  83
  84    ------------------
  85    -- C_Call_Chain --
  86    ------------------
  87
  88    function C_Call_Chain
  89      (Traceback   : System.Address;
  90       Max_Len     : Natural) return Natural
  91    is
  92       Val : Natural;
  93    begin
  94       Call_Chain (Traceback, Max_Len, Val);
  95       return Val;
  96    end C_Call_Chain;
  97
  98 end System.Traceback;