configure.ac

   1 #   Copyright (C) 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999, 2000,
   2 #   2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009, 2010, 2011, 2012,
   3 #   2014, 2015, 2016, 2019 Free Software Foundation, Inc.
   4 #
   5 # This file is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 # General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with this program; see the file COPYING3.  If not see
  17 # <http://www.gnu.org/licenses/>.
  18
  19 ##############################################################################
  20 ### WARNING: this file contains embedded tabs.  Do not run untabify on this file.
  21
  22 m4_include(config/acx.m4)
  23 m4_include(config/override.m4)
  24 m4_include(config/proginstall.m4)
  25 m4_include(config/elf.m4)
  26 m4_include(config/ax_cxx_compile_stdcxx.m4)
  27 m4_include([libtool.m4])
  28 m4_include([ltoptions.m4])
  29 m4_include([ltsugar.m4])
  30 m4_include([ltversion.m4])
  31 m4_include([lt~obsolete.m4])
  32 m4_include([config/isl.m4])
  33
  34 AC_INIT(move-if-change)
  35 AC_DISABLE_OPTION_CHECKING
  36
  37 progname=$0
  38 # if PWD already has a value, it is probably wrong.
  39 if test -n "$PWD" ; then PWD=`${PWDCMD-pwd}`; fi
  40
  41 # Export original configure arguments for use by sub-configures.
  42 # Quote arguments with shell meta charatcers.
  43 TOPLEVEL_CONFIGURE_ARGUMENTS=
  44 set -- "$progname" "$@"
  45 for ac_arg
  46 do
  47   case "$ac_arg" in
  48   *" "*|*"      "*|*[[\[\]\~\#\$\^\&\*\(\)\{\}\\\|\;\<\>\?\']]*)
  49     ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"`
  50     # if the argument is of the form -foo=baz, quote the baz part only
  51     ac_arg=`echo "'$ac_arg'" | sed "s/^'\([[-a-zA-Z0-9]]*=\)/\\1'/"` ;;
  52   *) ;;
  53   esac
  54   # Add the quoted argument to the list.
  55   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS $ac_arg"
  56 done
  57 if test "$silent" = yes; then
  58   TOPLEVEL_CONFIGURE_ARGUMENTS="$TOPLEVEL_CONFIGURE_ARGUMENTS --silent"
  59 fi
  60 # Remove the initial space we just introduced and, as these will be
  61 # expanded by make, quote '$'.
  62 TOPLEVEL_CONFIGURE_ARGUMENTS=`echo "x$TOPLEVEL_CONFIGURE_ARGUMENTS" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
  63 AC_SUBST(TOPLEVEL_CONFIGURE_ARGUMENTS)
  64
  65 # Find the build, host, and target systems.
  66 ACX_NONCANONICAL_BUILD
  67 ACX_NONCANONICAL_HOST
  68 ACX_NONCANONICAL_TARGET
  69
  70 dnl Autoconf 2.5x and later will set a default program prefix if
  71 dnl --target was used, even if it was the same as --host.  Disable
  72 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  73 dnl to take effect.
  74 test "$host_noncanonical" = "$target_noncanonical" &&
  75   test "$program_prefix$program_suffix$program_transform_name" = \
  76     NONENONEs,x,x, &&
  77   program_transform_name=s,y,y,
  78
  79 AC_CANONICAL_SYSTEM
  80 AC_ARG_PROGRAM
  81
  82 m4_pattern_allow([^AS_FOR_TARGET$])dnl
  83 m4_pattern_allow([^AS_FOR_BUILD$])dnl
  84
  85 # Get 'install' or 'install-sh' and its variants.
  86 AC_PROG_INSTALL
  87 ACX_PROG_LN
  88 AC_PROG_LN_S
  89 AC_PROG_SED
  90 AC_PROG_AWK
  91
  92 srcpwd=`cd ${srcdir} ; ${PWDCMD-pwd}`
  93
  94 # We pass INSTALL explicitly to sub-makes.  Make sure that it is not
  95 # a relative path.
  96 if test "$INSTALL" = "${srcdir}/install-sh -c"; then
  97   INSTALL="${srcpwd}/install-sh -c"
  98 fi
  99
 100 # Set srcdir to "." if that's what it is.
 101 # This is important for multilib support.
 102 pwd=`${PWDCMD-pwd}`
 103 if test "${pwd}" = "${srcpwd}" ; then
 104   srcdir=.
 105 fi
 106
 107 topsrcdir=$srcpwd
 108
 109 extra_host_args=
 110
 111 ### To add a new directory to the tree, first choose whether it is a target
 112 ### or a host dependent tool.  Then put it into the appropriate list
 113 ### (library or tools, host or target), doing a dependency sort.
 114
 115 # Subdirs will be configured in the order listed in build_configdirs,
 116 # configdirs, or target_configdirs; see the serialization section below.
 117
 118 # Dependency sorting is only needed when *configuration* must be done in
 119 # a particular order.  In all cases a dependency should be specified in
 120 # the Makefile, whether or not it's implicitly specified here.
 121
 122 # Double entries in build_configdirs, configdirs, or target_configdirs may
 123 # cause circular dependencies and break everything horribly.
 124
 125 # these library is used by various programs built for the build
 126 # environment
 127 #
 128 build_libs="build-libiberty build-libcpp"
 129
 130 # these tools are built for the build environment
 131 build_tools="build-texinfo build-flex build-bison build-m4 build-fixincludes"
 132
 133 # these libraries are used by various programs built for the host environment
 134 #f
 135 host_libs="intl libiberty opcodes bfd readline tcl tk itcl libgui zlib libbacktrace libcpp libcody libdecnumber gmp mpfr mpc isl libelf libiconv libctf"
 136
 137 # these tools are built for the host environment
 138 # Note, the powerpc-eabi build depends on sim occurring before gdb in order to
 139 # know that we are building the simulator.
 140 # binutils, gas and ld appear in that order because it makes sense to run
 141 # "make check" in that particular order.
 142 # If --enable-gold is used, "gold" may replace "ld".
 143 host_tools="texinfo flex bison binutils gas ld fixincludes gcc cgen sid sim gdb gdbserver gprof etc expect dejagnu m4 utils guile fastjar gnattools libcc1 gotools c++tools"
 144
 145 # these libraries are built for the target environment, and are built after
 146 # the host libraries and the host tools (which may be a cross compiler)
 147 # Note that libiberty is not a target library.
 148 target_libraries="target-libgcc \
 149                 target-libbacktrace \
 150                 target-libgloss \
 151                 target-newlib \
 152                 target-libgomp \
 153                 target-liboffloadmic \
 154                 target-libatomic \
 155                 target-libitm \
 156                 target-libstdc++-v3 \
 157                 target-libsanitizer \
 158                 target-libvtv \
 159                 target-libssp \
 160                 target-libquadmath \
 161                 target-libgfortran \
 162                 target-libffi \
 163                 target-libobjc \
 164                 target-libada \
 165                 target-libgo \
 166                 target-libphobos \
 167                 target-zlib"
 168
 169 # these tools are built using the target libraries, and are intended to
 170 # run only in the target environment
 171 #
 172 # note: any program that *uses* libraries that are in the "target_libraries"
 173 # list belongs in this list.
 174 #
 175 target_tools="target-rda"
 176
 177 ################################################################################
 178
 179 ## All tools belong in one of the four categories, and are assigned above
 180 ## We assign ${configdirs} this way to remove all embedded newlines.  This
 181 ## is important because configure will choke if they ever get through.
 182 ## ${configdirs} is directories we build using the host tools.
 183 ## ${target_configdirs} is directories we build using the target tools.
 184 configdirs=`echo ${host_libs} ${host_tools}`
 185 target_configdirs=`echo ${target_libraries} ${target_tools}`
 186 build_configdirs=`echo ${build_libs} ${build_tools}`
 187
 188 m4_divert_text([PARSE_ARGS],
 189 [case $srcdir in
 190   *" "*)
 191 m4_pushdef([AS_MESSAGE_LOG_FD], [])dnl
 192     AC_MSG_ERROR([path to source, $srcdir, contains spaces])
 193 m4_popdef([AS_MESSAGE_LOG_FD])dnl
 194     ;;
 195 esac
 196 ac_subdirs_all=`cd $srcdir && echo */configure | sed 's,/configure,,g'`
 197 ])
 198
 199 ################################################################################
 200
 201 srcname="gnu development package"
 202
 203 # This gets set non-empty for some net releases of packages.
 204 appdirs=""
 205
 206 # Define is_cross_compiler to save on calls to 'test'.
 207 is_cross_compiler=
 208 if test x"${host}" = x"${target}" ; then
 209   is_cross_compiler=no
 210 else
 211   is_cross_compiler=yes
 212 fi
 213
 214 # Find the build and target subdir names.
 215 GCC_TOPLEV_SUBDIRS
 216 # Be sure to cover against remnants of an in-tree build.
 217 if test $srcdir != .  && test -d $srcdir/host-${host_noncanonical}; then
 218   AC_MSG_ERROR([building out of tree but $srcdir contains host-${host_noncanonical}.
 219 Use a pristine source tree when building in a separate tree])
 220 fi
 221
 222 # Skipdirs are removed silently.
 223 skipdirs=
 224 # Noconfigdirs are removed loudly.
 225 noconfigdirs=""
 226
 227 use_gnu_ld=
 228 # Make sure we don't let GNU ld be added if we didn't want it.
 229 if test x$with_gnu_ld = xno ; then
 230   use_gnu_ld=no
 231   noconfigdirs="$noconfigdirs ld gold"
 232 fi
 233
 234 use_gnu_as=
 235 # Make sure we don't let GNU as be added if we didn't want it.
 236 if test x$with_gnu_as = xno ; then
 237   use_gnu_as=no
 238   noconfigdirs="$noconfigdirs gas"
 239 fi
 240
 241 use_included_zlib=
 242 AC_ARG_WITH(system-zlib,
 243 [AS_HELP_STRING([--with-system-zlib], [use installed libz])])
 244 # Make sure we don't let ZLIB be added if we didn't want it.
 245 if test x$with_system_zlib = xyes ; then
 246   use_included_zlib=no
 247   noconfigdirs="$noconfigdirs zlib"
 248 fi
 249
 250 # some tools are so dependent upon X11 that if we're not building with X,
 251 # it's not even worth trying to configure, much less build, that tool.
 252
 253 case ${with_x} in
 254   yes | "") ;; # the default value for this tree is that X11 is available
 255   no)
 256     skipdirs="${skipdirs} tk itcl libgui"
 257     # We won't be able to build gdbtk without X.
 258     enable_gdbtk=no
 259     ;;
 260   *)  echo "*** bad value \"${with_x}\" for -with-x flag; ignored" 1>&2 ;;
 261 esac
 262
 263 # Some are only suitable for cross toolchains.
 264 # Remove these if host=target.
 265 cross_only="target-libgloss target-newlib target-opcodes"
 266
 267 case $is_cross_compiler in
 268   no) skipdirs="${skipdirs} ${cross_only}" ;;
 269 esac
 270
 271 # If both --with-headers and --with-libs are specified, default to
 272 # --without-newlib.
 273 if test x"${with_headers}" != x && test x"${with_headers}" != xno \
 274    && test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
 275   if test x"${with_newlib}" = x ; then
 276     with_newlib=no
 277   fi
 278 fi
 279
 280 # Recognize --with-newlib/--without-newlib.
 281 case ${with_newlib} in
 282   no) skipdirs="${skipdirs} target-newlib" ;;
 283   yes) skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'` ;;
 284 esac
 285
 286 AC_ARG_ENABLE(as-accelerator-for,
 287 [AS_HELP_STRING([--enable-as-accelerator-for=ARG],
 288                 [build as offload target compiler.
 289                 Specify offload host triple by ARG])])
 290
 291 AC_ARG_ENABLE(offload-targets,
 292 [AS_HELP_STRING([--enable-offload-targets=LIST],
 293                 [enable offloading to devices from comma-separated LIST of
 294                 TARGET[=DIR]. Use optional path to find offload target compiler
 295                 during the build])],
 296 [
 297   if test x"$enable_offload_targets" = x; then
 298     AC_MSG_ERROR([no offload targets specified])
 299   fi
 300 ], [enable_offload_targets=])
 301
 302 AC_ARG_ENABLE(offload-defaulted,
 303 [AS_HELP_STRING([--enable-offload-defaulted]
 304                 [If enabled, configured but not installed offload compilers and
 305                 libgomp plugins are silently ignored.  Useful for distribution
 306                 compilers where those are in separate optional packages.])],
 307 [enable_offload_defaulted=$enableval],
 308 [enable_offload_defaulted=])
 309
 310 # Handle --enable-gold, --enable-ld.
 311 # --disable-gold [--enable-ld]
 312 #     Build only ld.  Default option.
 313 # --enable-gold [--enable-ld]
 314 #     Build both gold and ld.  Install gold as "ld.gold", install ld
 315 #     as "ld.bfd" and "ld".
 316 # --enable-gold=default [--enable-ld]
 317 #     Build both gold and ld.  Install gold as "ld.gold" and "ld",
 318 #     install ld as "ld.bfd".
 319 # --enable-gold[=default] --disable-ld
 320 #     Build only gold, which is then installed as both "ld.gold" and "ld".
 321 # --enable-gold --enable-ld=default
 322 #     Build both gold (installed as "ld.gold") and ld (installed as "ld"
 323 #     and ld.bfd).
 324 #     In other words, ld is default
 325 # --enable-gold=default --enable-ld=default
 326 #     Error.
 327
 328 default_ld=
 329 AC_ARG_ENABLE(gold,
 330 [AS_HELP_STRING([[--enable-gold[=ARG]]],
 331                 [build gold @<:@ARG={default,yes,no}@:>@])],
 332 ENABLE_GOLD=$enableval,
 333 ENABLE_GOLD=no)
 334 case "${ENABLE_GOLD}" in
 335   yes|default)
 336     # Check for ELF target.
 337     is_elf=no
 338     case "${target}" in
 339       *-*-elf* | *-*-sysv4* | *-*-unixware* | *-*-eabi* | hppa*64*-*-hpux* \
 340       | *-*-linux* | *-*-gnu* | frv-*-uclinux* | *-*-irix5* | *-*-irix6* \
 341       | *-*-netbsd* | *-*-openbsd* | *-*-freebsd* | *-*-dragonfly* \
 342       | *-*-solaris2* | *-*-nto* | *-*-nacl*)
 343         case "${target}" in
 344           *-*-linux*aout* | *-*-linux*oldld*)
 345             ;;
 346           *)
 347             is_elf=yes
 348             ;;
 349         esac
 350     esac
 351
 352     if test "$is_elf" = "yes"; then
 353       # Check for target supported by gold.
 354       case "${target}" in
 355         i?86-*-* | x86_64-*-* | sparc*-*-* | powerpc*-*-* | arm*-*-* \
 356         | aarch64*-*-* | tilegx*-*-* | mips*-*-* | s390*-*-*)
 357           configdirs="$configdirs gold"
 358           if test x${ENABLE_GOLD} = xdefault; then
 359             default_ld=gold
 360           fi
 361           ENABLE_GOLD=yes
 362           ;;
 363       esac
 364     fi
 365     ;;
 366   no)
 367     ;;
 368   *)
 369     AC_MSG_ERROR([invalid --enable-gold argument])
 370     ;;
 371 esac
 372
 373 AC_ARG_ENABLE(ld,
 374 [AS_HELP_STRING([[--enable-ld[=ARG]]],
 375                 [build ld @<:@ARG={default,yes,no}@:>@])],
 376 ENABLE_LD=$enableval,
 377 ENABLE_LD=yes)
 378
 379 case "${ENABLE_LD}" in
 380   default)
 381     if test x${default_ld} != x; then
 382       AC_MSG_ERROR([either gold or ld can be the default ld])
 383     fi
 384     ;;
 385   yes)
 386     ;;
 387   no)
 388     if test x${ENABLE_GOLD} != xyes; then
 389       AC_MSG_WARN([neither ld nor gold are enabled])
 390     fi
 391     configdirs=`echo " ${configdirs} " | sed -e 's/ ld / /'`
 392     ;;
 393   *)
 394     AC_MSG_ERROR([invalid --enable-ld argument])
 395     ;;
 396 esac
 397
 398 # PR gas/19109
 399 # Decide the default method for compressing debug sections.
 400 # Provide a configure time option to override our default.
 401 AC_ARG_ENABLE(compressed_debug_sections,
 402 [AS_HELP_STRING([--enable-compressed-debug-sections={all,gas,gold,ld,none}],
 403                 [Enable compressed debug sections for gas, gold or ld by
 404                  default])],
 405 [
 406   if test x"$enable_compressed_debug_sections" = xyes; then
 407     AC_MSG_ERROR([no program with compressed debug sections specified])
 408   fi
 409 ], [enable_compressed_debug_sections=])
 410
 411 # Configure extra directories which are host specific
 412
 413 case "${host}" in
 414   *-cygwin*)
 415     configdirs="$configdirs libtermcap" ;;
 416 esac
 417
 418 # A target can indicate whether a language isn't supported for some reason.
 419 # Only spaces may be used in this macro; not newlines or tabs.
 420 unsupported_languages=
 421
 422 # Remove more programs from consideration, based on the host or
 423 # target this usually means that a port of the program doesn't
 424 # exist yet.
 425
 426 case "${host}" in
 427   i[[3456789]]86-*-msdosdjgpp*)
 428     noconfigdirs="$noconfigdirs tcl tk itcl"
 429     ;;
 430 esac
 431
 432
 433 AC_ARG_ENABLE(libquadmath,
 434 AS_HELP_STRING([--disable-libquadmath],
 435   [do not build libquadmath directory]),
 436 ENABLE_LIBQUADMATH=$enableval,
 437 ENABLE_LIBQUADMATH=yes)
 438 if test "${ENABLE_LIBQUADMATH}" = "no" ; then
 439   noconfigdirs="$noconfigdirs target-libquadmath"
 440 fi
 441
 442
 443 AC_ARG_ENABLE(libquadmath-support,
 444 AS_HELP_STRING([--disable-libquadmath-support],
 445   [disable libquadmath support for Fortran]),
 446 ENABLE_LIBQUADMATH_SUPPORT=$enableval,
 447 ENABLE_LIBQUADMATH_SUPPORT=yes)
 448 enable_libquadmath_support=
 449 if test "${ENABLE_LIBQUADMATH_SUPPORT}" = "no" ; then
 450   enable_libquadmath_support=no
 451 fi
 452
 453
 454 AC_ARG_ENABLE(libada,
 455 [AS_HELP_STRING([--enable-libada], [build libada directory])],
 456 ENABLE_LIBADA=$enableval,
 457 ENABLE_LIBADA=yes)
 458 if test "${ENABLE_LIBADA}" != "yes" ; then
 459   noconfigdirs="$noconfigdirs gnattools"
 460 fi
 461
 462 AC_ARG_ENABLE(libssp,
 463 [AS_HELP_STRING([--enable-libssp], [build libssp directory])],
 464 ENABLE_LIBSSP=$enableval,
 465 ENABLE_LIBSSP=yes)
 466
 467 AC_ARG_ENABLE(libstdcxx,
 468 AS_HELP_STRING([--disable-libstdcxx],
 469   [do not build libstdc++-v3 directory]),
 470 ENABLE_LIBSTDCXX=$enableval,
 471 ENABLE_LIBSTDCXX=default)
 472 [if test "${ENABLE_LIBSTDCXX}" = "no" ; then
 473   noconfigdirs="$noconfigdirs target-libstdc++-v3"
 474 fi]
 475
 476 # If this is accelerator compiler and its target is intelmic we enable
 477 # target liboffloadmic by default.  If this is compiler with offloading
 478 # for intelmic we enable host liboffloadmic by default.  Otherwise
 479 # liboffloadmic is disabled by default.
 480 AC_ARG_ENABLE([liboffloadmic],
 481 AC_HELP_STRING([[--enable-liboffloadmic[=ARG]]],
 482                [build liboffloadmic @<:@ARG={no,host,target}@:>@]),
 483 [case "$enableval" in
 484   no | host | target)
 485     enable_liboffloadmic=$enableval ;;
 486   *)
 487     AC_MSG_ERROR([--enable-liboffloadmic=no/host/target]) ;;
 488 esac],
 489 [if test x"$enable_as_accelerator_for" != x; then
 490   case "${target}" in
 491     *-intelmic-* | *-intelmicemul-*)
 492       enable_liboffloadmic=target
 493       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=target"
 494       ;;
 495     *)
 496       enable_liboffloadmic=no
 497       ;;
 498   esac
 499 else
 500   case "${enable_offload_targets}" in
 501     *-intelmic-* | *-intelmicemul-*)
 502       enable_liboffloadmic=host
 503       extra_liboffloadmic_configure_flags="--enable-liboffloadmic=host"
 504       ;;
 505     *)
 506       enable_liboffloadmic=no
 507       ;;
 508     esac
 509 fi])
 510 AC_SUBST(extra_liboffloadmic_configure_flags)
 511
 512 # Enable libgomp by default on hosted POSIX systems, and a few others.
 513 if test x$enable_libgomp = x ; then
 514     case "${target}" in
 515     *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 516         ;;
 517     *-*-netbsd* | *-*-freebsd* | *-*-openbsd* | *-*-dragonfly*)
 518         ;;
 519     *-*-solaris2* | *-*-hpux11*)
 520         ;;
 521     *-*-darwin* | *-*-aix*)
 522         ;;
 523     nvptx*-*-* | amdgcn*-*-*)
 524         ;;
 525     *)
 526         noconfigdirs="$noconfigdirs target-libgomp"
 527         ;;
 528     esac
 529 fi
 530
 531 # Disable libatomic on unsupported systems.
 532 if test -d ${srcdir}/libatomic; then
 533     if test x$enable_libatomic = x; then
 534         AC_MSG_CHECKING([for libatomic support])
 535         if (srcdir=${srcdir}/libatomic; \
 536                 . ${srcdir}/configure.tgt; \
 537                 test -n "$UNSUPPORTED")
 538         then
 539             AC_MSG_RESULT([no])
 540             noconfigdirs="$noconfigdirs target-libatomic"
 541         else
 542             AC_MSG_RESULT([yes])
 543         fi
 544     fi
 545 fi
 546
 547 # Disable liboffloadmic on unsupported systems.
 548 if test -d ${srcdir}/liboffloadmic; then
 549     if test x$enable_liboffloadmic != xno; then
 550         AC_MSG_CHECKING([for liboffloadmic support])
 551         if (srcdir=${srcdir}/liboffloadmic; \
 552                 . ${srcdir}/configure.tgt; \
 553                 test -n "$UNSUPPORTED")
 554         then
 555             AC_MSG_RESULT([no])
 556             noconfigdirs="$noconfigdirs target-liboffloadmic"
 557         else
 558             AC_MSG_RESULT([yes])
 559         fi
 560     fi
 561 fi
 562
 563 # Disable libitm on unsupported systems.
 564 if test -d ${srcdir}/libitm; then
 565     if test x$enable_libitm = x; then
 566         AC_MSG_CHECKING([for libitm support])
 567         if (srcdir=${srcdir}/libitm; \
 568                 . ${srcdir}/configure.tgt; \
 569                 test -n "$UNSUPPORTED")
 570         then
 571             AC_MSG_RESULT([no])
 572             noconfigdirs="$noconfigdirs target-libitm"
 573         else
 574             AC_MSG_RESULT([yes])
 575         fi
 576     fi
 577 fi
 578
 579 # Disable libsanitizer on unsupported systems.
 580 if test -d ${srcdir}/libsanitizer; then
 581     if test x$enable_libsanitizer = x; then
 582         AC_MSG_CHECKING([for libsanitizer support])
 583         if (srcdir=${srcdir}/libsanitizer; \
 584                 . ${srcdir}/configure.tgt; \
 585                 test -n "$UNSUPPORTED")
 586         then
 587             AC_MSG_RESULT([no])
 588             noconfigdirs="$noconfigdirs target-libsanitizer"
 589         else
 590             AC_MSG_RESULT([yes])
 591         fi
 592     fi
 593 fi
 594
 595 # Disable libvtv on unsupported systems.
 596 if test -d ${srcdir}/libvtv; then
 597     if test x$enable_libvtv = x; then
 598         AC_MSG_CHECKING([for libvtv support])
 599         if (srcdir=${srcdir}/libvtv; \
 600                 . ${srcdir}/configure.tgt; \
 601                 test "$VTV_SUPPORTED" != "yes")
 602         then
 603             AC_MSG_RESULT([no])
 604             noconfigdirs="$noconfigdirs target-libvtv"
 605         else
 606             AC_MSG_RESULT([yes])
 607         fi
 608     fi
 609 fi
 610
 611 # Disable libquadmath for some systems.
 612 case "${target}" in
 613   avr-*-*)
 614     noconfigdirs="$noconfigdirs target-libquadmath"
 615     ;;
 616   # libquadmath is unused on AIX and libquadmath build process use of
 617   # LD_LIBRARY_PATH can break AIX bootstrap.
 618   powerpc-*-aix* | rs6000-*-aix*)
 619     noconfigdirs="$noconfigdirs target-libquadmath"
 620     ;;
 621 esac
 622
 623 # Disable libssp for some systems.
 624 case "${target}" in
 625   avr-*-*)
 626     # No hosted I/O support.
 627     noconfigdirs="$noconfigdirs target-libssp"
 628     ;;
 629   bpf-*-*)
 630     noconfigdirs="$noconfigdirs target-libssp"
 631     ;;
 632   powerpc-*-aix* | rs6000-*-aix*)
 633     noconfigdirs="$noconfigdirs target-libssp"
 634     ;;
 635   pru-*-*)
 636     # No hosted I/O support.
 637     noconfigdirs="$noconfigdirs target-libssp"
 638     ;;
 639   rl78-*-*)
 640     # libssp uses a misaligned load to trigger a fault, but the RL78
 641     # doesn't fault for those - instead, it gives a build-time error
 642     # for explicit misaligned loads.
 643     noconfigdirs="$noconfigdirs target-libssp"
 644     ;;
 645   visium-*-*)
 646     # No hosted I/O support.
 647     noconfigdirs="$noconfigdirs target-libssp"
 648     ;;
 649 esac
 650
 651 # Disable libstdc++-v3 for some systems.
 652 # Allow user to override this if they pass --enable-libstdc++-v3
 653 if test "${ENABLE_LIBSTDCXX}" = "default" ; then
 654   case "${target}" in
 655     *-*-vxworks*)
 656       # VxWorks uses the Dinkumware C++ library.
 657       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 658       ;;
 659     amdgcn*-*-*)
 660       # Not ported/fails to build when using newlib.
 661       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 662       ;;
 663     arm*-wince-pe*)
 664       # the C++ libraries don't build on top of CE's C libraries
 665       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 666       ;;
 667     avr-*-*)
 668       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 669       ;;
 670     bpf-*-*)
 671       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 672       ;;
 673     ft32-*-*)
 674       noconfigdirs="$noconfigdirs target-libstdc++-v3"
 675       ;;
 676   esac
 677 fi
 678
 679 # Disable C++ on systems where it is known to not work.
 680 # For testing, you can override this with --enable-languages=c++.
 681 case ,${enable_languages}, in
 682   *,c++,*)
 683     ;;
 684   *)
 685       case "${target}" in
 686         bpf-*-*)
 687           unsupported_languages="$unsupported_languages c++"
 688           ;;
 689       esac
 690       ;;
 691 esac
 692
 693 # Disable Objc on systems where it is known to not work.
 694 # For testing, you can override this with --enable-languages=objc.
 695 case ,${enable_languages}, in
 696   *,objc,*)
 697     ;;
 698   *)
 699       case "${target}" in
 700         bpf-*-*)
 701           unsupported_languages="$unsupported_languages objc"
 702           ;;
 703       esac
 704       ;;
 705 esac
 706
 707 # Disable D on systems where it is known to not work.
 708 # For testing, you can override this with --enable-languages=d.
 709 case ,${enable_languages}, in
 710   *,d,*)
 711     ;;
 712   *)
 713     case "${target}" in
 714       bpf-*-*)
 715         unsupported_languages="$unsupported_languages d"
 716         ;;
 717     esac
 718     ;;
 719 esac
 720
 721 # Disable libphobos on unsupported systems.
 722 # For testing, you can override this with --enable-libphobos.
 723 if test -d ${srcdir}/libphobos; then
 724     if test x$enable_libphobos = x; then
 725         AC_MSG_CHECKING([for libphobos support])
 726         if (srcdir=${srcdir}/libphobos; \
 727                 . ${srcdir}/configure.tgt; \
 728                 test "$LIBPHOBOS_SUPPORTED" != "yes")
 729         then
 730             AC_MSG_RESULT([no])
 731             noconfigdirs="$noconfigdirs target-libphobos"
 732         else
 733             AC_MSG_RESULT([yes])
 734         fi
 735     fi
 736 fi
 737
 738 # Disable Fortran for some systems.
 739 case "${target}" in
 740   mmix-*-*)
 741     # See <http://gcc.gnu.org/ml/gcc-patches/2004-11/msg00572.html>.
 742     unsupported_languages="$unsupported_languages fortran"
 743     ;;
 744   bpf-*-*)
 745     unsupported_languages="$unsupported_languages fortran"
 746     ;;
 747 esac
 748
 749 # Disable libffi for some systems.
 750 case "${target}" in
 751   powerpc-*-darwin*)
 752     ;;
 753   i[[3456789]]86-*-darwin*)
 754     ;;
 755   x86_64-*-darwin[[912]]*)
 756     ;;
 757   *-*-darwin*)
 758     noconfigdirs="$noconfigdirs target-libffi"
 759     ;;
 760   *-*-netware*)
 761     noconfigdirs="$noconfigdirs target-libffi"
 762     ;;
 763   *-*-phoenix*)
 764     noconfigdirs="$noconfigdirs target-libffi"
 765     ;;
 766   *-*-rtems*)
 767     noconfigdirs="$noconfigdirs target-libffi"
 768     ;;
 769   *-*-tpf*)
 770     noconfigdirs="$noconfigdirs target-libffi"
 771     ;;
 772   *-*-uclinux*)
 773     noconfigdirs="$noconfigdirs target-libffi"
 774     ;;
 775   *-*-vxworks*)
 776     noconfigdirs="$noconfigdirs target-libffi"
 777     ;;
 778   aarch64*-*-freebsd*)
 779     noconfigdirs="$noconfigdirs target-libffi"
 780     ;;
 781   alpha*-*-*vms*)
 782     noconfigdirs="$noconfigdirs target-libffi"
 783     ;;
 784   arm*-*-freebsd*)
 785     noconfigdirs="$noconfigdirs target-libffi"
 786     ;;
 787   arm-wince-pe)
 788     noconfigdirs="$noconfigdirs target-libffi"
 789     ;;
 790   arm*-*-symbianelf*)
 791     noconfigdirs="$noconfigdirs target-libffi"
 792     ;;
 793   bpf-*-*)
 794     noconfigdirs="$noconfigdirs target-libffi"
 795     ;;
 796   cris-*-* | crisv32-*-*)
 797     case "${target}" in
 798       *-*-linux*)
 799         ;;
 800       *) # See PR46792 regarding target-libffi.
 801         noconfigdirs="$noconfigdirs target-libffi";;
 802     esac
 803     ;;
 804   hppa*64*-*-hpux*)
 805     noconfigdirs="$noconfigdirs target-libffi"
 806     ;;
 807   hppa*-hp-hpux11*)
 808     ;;
 809   hppa*-*-hpux*)
 810     noconfigdirs="$noconfigdirs target-libffi"
 811     ;;
 812   ia64*-*-*vms*)
 813     noconfigdirs="$noconfigdirs target-libffi"
 814     ;;
 815   i[[3456789]]86-w64-mingw*)
 816     noconfigdirs="$noconfigdirs target-libffi"
 817     ;;
 818   i[[3456789]]86-*-mingw*)
 819     noconfigdirs="$noconfigdirs target-libffi"
 820     ;;
 821   x86_64-*-mingw*)
 822     noconfigdirs="$noconfigdirs target-libffi"
 823     ;;
 824   mmix-*-*)
 825     noconfigdirs="$noconfigdirs target-libffi"
 826     ;;
 827   powerpc-*-aix*)
 828     ;;
 829   rs6000-*-aix*)
 830     ;;
 831   ft32-*-*)
 832     noconfigdirs="$noconfigdirs target-libffi"
 833     ;;
 834   *-*-lynxos*)
 835     noconfigdirs="$noconfigdirs target-libffi"
 836     ;;
 837 esac
 838
 839 # Disable the go frontend on systems where it is known to not work. Please keep
 840 # this in sync with contrib/config-list.mk.
 841 case "${target}" in
 842 *-*-darwin* | *-*-cygwin* | *-*-mingw* | bpf-* )
 843     unsupported_languages="$unsupported_languages go"
 844     ;;
 845 esac
 846
 847 # Only allow gdbserver on some systems.
 848 if test -d ${srcdir}/gdbserver; then
 849     if test x$enable_gdbserver = x; then
 850         AC_MSG_CHECKING([for gdbserver support])
 851         if (srcdir=${srcdir}/gdbserver; \
 852                 . ${srcdir}/configure.srv; \
 853                 test -n "$UNSUPPORTED")
 854         then
 855             AC_MSG_RESULT([no])
 856             noconfigdirs="$noconfigdirs gdbserver"
 857         else
 858             AC_MSG_RESULT([yes])
 859         fi
 860     fi
 861 fi
 862
 863 # Disable libgo for some systems where it is known to not work.
 864 # For testing, you can easily override this with --enable-libgo.
 865 if test x$enable_libgo = x; then
 866     case "${target}" in
 867     *-*-darwin*)
 868         # PR 46986
 869         noconfigdirs="$noconfigdirs target-libgo"
 870         ;;
 871     *-*-cygwin* | *-*-mingw*)
 872         noconfigdirs="$noconfigdirs target-libgo"
 873         ;;
 874     bpf-*-*)
 875         noconfigdirs="$noconfigdirs target-libgo"
 876         ;;
 877     esac
 878 fi
 879
 880 # Default libgloss CPU subdirectory.
 881 libgloss_dir="$target_cpu"
 882
 883 case "${target}" in
 884   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
 885     libgloss_dir=wince
 886     ;;
 887   aarch64*-*-* )
 888     libgloss_dir=aarch64
 889     ;;
 890   arm*-*-*)
 891     libgloss_dir=arm
 892     ;;
 893   cris-*-* | crisv32-*-*)
 894     libgloss_dir=cris
 895     ;;
 896   hppa*-*-*)
 897     libgloss_dir=pa
 898     ;;
 899   i[[3456789]]86-*-*)
 900     libgloss_dir=i386
 901     ;;
 902   m68hc11-*-*|m6811-*-*|m68hc12-*-*|m6812-*-*)
 903     libgloss_dir=m68hc11
 904     ;;
 905   m68*-*-* | fido-*-*)
 906     libgloss_dir=m68k
 907     ;;
 908   mips*-*-*)
 909     libgloss_dir=mips
 910     ;;
 911   powerpc*-*-*)
 912     libgloss_dir=rs6000
 913     ;;
 914   pru-*-*)
 915     libgloss_dir=pru
 916     ;;
 917   sparc*-*-*)
 918     libgloss_dir=sparc
 919     ;;
 920 esac
 921
 922 # Disable newlib and libgloss for various target OSes.
 923 case "${target}" in
 924   alpha*-dec-osf*)
 925     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 926     ;;
 927   i[[3456789]]86-*-linux*)
 928     # This section makes it possible to build newlib natively on linux.
 929     # If we are using a cross compiler then don't configure newlib.
 930     if test x${is_cross_compiler} != xno ; then
 931       noconfigdirs="$noconfigdirs target-newlib"
 932     fi
 933     noconfigdirs="$noconfigdirs target-libgloss"
 934     # If we are not using a cross compiler, do configure newlib.
 935     # Note however, that newlib will only be configured in this situation
 936     # if the --with-newlib option has been given, because otherwise
 937     # 'target-newlib' will appear in skipdirs.
 938     ;;
 939   i[[3456789]]86-*-rdos*)
 940     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 941     ;;
 942   sh*-*-pe|mips*-*-pe|arm-wince-pe)
 943     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 944     ;;
 945   sparc-*-sunos4*)
 946     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 947     ;;
 948   bpf-*-*)
 949     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 950     ;;
 951   *-*-aix*)
 952     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 953     ;;
 954   *-*-beos*)
 955     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 956     ;;
 957   *-*-chorusos)
 958     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 959     ;;
 960   *-*-dragonfly*)
 961     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 962     ;;
 963   *-*-freebsd*)
 964     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 965     ;;
 966   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
 967     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 968     ;;
 969   *-*-lynxos*)
 970     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 971     ;;
 972   *-*-mingw*)
 973     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 974     ;;
 975   *-*-netbsd*)
 976     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 977     ;;
 978   *-*-netware*)
 979     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 980     ;;
 981   *-*-tpf*)
 982     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 983     ;;
 984   *-*-uclinux*)
 985     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 986     ;;
 987   *-*-vxworks*)
 988     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
 989     ;;
 990 esac
 991
 992 case "${target}" in
 993   *-*-chorusos)
 994     ;;
 995   aarch64-*-darwin*)
 996     noconfigdirs="$noconfigdirs ld gas gdb gprof"
 997     noconfigdirs="$noconfigdirs sim target-rda"
 998     ;;
 999   amdgcn*-*-*)
1000     ;;
1001   arm-*-darwin*)
1002     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1003     noconfigdirs="$noconfigdirs sim target-rda"
1004     ;;
1005   powerpc-*-darwin*)
1006     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1007     noconfigdirs="$noconfigdirs sim target-rda"
1008     ;;
1009   i[[3456789]]86-*-darwin*)
1010     noconfigdirs="$noconfigdirs ld gprof"
1011     noconfigdirs="$noconfigdirs sim target-rda"
1012     ;;
1013   x86_64-*-darwin[[912]]*)
1014     noconfigdirs="$noconfigdirs ld gas gprof"
1015     noconfigdirs="$noconfigdirs sim target-rda"
1016     ;;
1017   *-*-darwin*)
1018     noconfigdirs="$noconfigdirs ld gas gdb gprof"
1019     noconfigdirs="$noconfigdirs sim target-rda"
1020     ;;
1021   *-*-dragonfly*)
1022     ;;
1023   *-*-freebsd*)
1024     if test "x$with_gmp" = x && test "x$with_gmp_dir" = x \
1025         && ! test -d ${srcdir}/gmp \
1026         && test -f /usr/local/include/gmp.h; then
1027       with_gmp=/usr/local
1028     fi
1029     ;;
1030   *-*-kaos*)
1031     # Remove unsupported stuff on all kaOS configurations.
1032     noconfigdirs="$noconfigdirs target-libgloss"
1033     ;;
1034   *-*-netbsd*)
1035     ;;
1036   *-*-netware*)
1037     ;;
1038   *-*-phoenix*)
1039     noconfigdirs="$noconfigdirs target-libgloss"
1040     ;;
1041   *-*-rtems*)
1042     noconfigdirs="$noconfigdirs target-libgloss"
1043     ;;
1044     # The tpf target doesn't support gdb yet.
1045   *-*-tpf*)
1046     noconfigdirs="$noconfigdirs gdb tcl tk libgui itcl"
1047     ;;
1048   *-*-uclinux*)
1049     noconfigdirs="$noconfigdirs target-rda"
1050     ;;
1051   *-*-vxworks*)
1052     ;;
1053   alpha*-dec-osf*)
1054     # ld works, but does not support shared libraries.
1055     # gas doesn't generate exception information.
1056     noconfigdirs="$noconfigdirs gas ld"
1057     ;;
1058   alpha*-*-*vms*)
1059     noconfigdirs="$noconfigdirs gdb target-newlib target-libgloss"
1060     ;;
1061   alpha*-*-*)
1062     # newlib is not 64 bit ready
1063     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1064     ;;
1065   bpf-*-*)
1066     noconfigdirs="$noconfigdirs target-libobjc target-libbacktrace"
1067     ;;
1068   sh*-*-pe|mips*-*-pe|*arm-wince-pe)
1069     noconfigdirs="$noconfigdirs tcl tk itcl libgui sim"
1070     ;;
1071   arc*-*-*)
1072     noconfigdirs="$noconfigdirs sim"
1073     ;;
1074   arm-*-pe*)
1075     noconfigdirs="$noconfigdirs target-libgloss"
1076     ;;
1077   arm-*-riscix*)
1078     noconfigdirs="$noconfigdirs ld target-libgloss"
1079     ;;
1080   avr-*-*)
1081     if test x${with_avrlibc} != xno; then
1082       noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1083     fi
1084     ;;
1085   c4x-*-* | tic4x-*-*)
1086     noconfigdirs="$noconfigdirs target-libgloss"
1087     ;;
1088   tic54x-*-*)
1089     noconfigdirs="$noconfigdirs target-libgloss gdb"
1090     ;;
1091   d10v-*-*)
1092     noconfigdirs="$noconfigdirs target-libgloss"
1093     ;;
1094   d30v-*-*)
1095     noconfigdirs="$noconfigdirs gdb"
1096     ;;
1097   fr30-*-elf*)
1098     noconfigdirs="$noconfigdirs gdb"
1099     ;;
1100   ft32-*-*)
1101     noconfigdirs="$noconfigdirs target-rda gprof"
1102     ;;
1103   moxie-*-*)
1104     noconfigdirs="$noconfigdirs"
1105     ;;
1106   h8300*-*-*)
1107     noconfigdirs="$noconfigdirs target-libgloss"
1108     ;;
1109   h8500-*-*)
1110     noconfigdirs="$noconfigdirs target-libgloss"
1111     ;;
1112   hppa1.1-*-osf* | hppa1.1-*-bsd* )
1113     ;;
1114   hppa*64*-*-hpux*)
1115     noconfigdirs="$noconfigdirs gdb"
1116     ;;
1117   hppa*-*-hpux11*)
1118     noconfigdirs="$noconfigdirs gdb ld"
1119     ;;
1120   hppa*64*-*-linux*)
1121     ;;
1122   hppa*-*-linux*)
1123     ;;
1124   hppa*-*-*elf* | \
1125   hppa*-*-lites* | \
1126   hppa*-*-openbsd* | \
1127   hppa*64*-*-*)
1128     ;;
1129   hppa*-*-pro*)
1130     ;;
1131   hppa*-*-*)
1132     noconfigdirs="$noconfigdirs ld"
1133     ;;
1134   i960-*-*)
1135     noconfigdirs="$noconfigdirs gdb"
1136     ;;
1137   ia64*-*-elf*)
1138     # No gdb support yet.
1139     noconfigdirs="$noconfigdirs readline libgui itcl gdb"
1140     ;;
1141   ia64*-**-hpux*)
1142     # No ld support yet.
1143     noconfigdirs="$noconfigdirs gdb libgui itcl ld"
1144     ;;
1145   ia64*-*-*vms*)
1146     # No ld support yet.
1147     noconfigdirs="$noconfigdirs libgui itcl ld"
1148     ;;
1149   i[[3456789]]86-w64-mingw*)
1150     ;;
1151   i[[3456789]]86-*-mingw*)
1152     target_configdirs="$target_configdirs target-winsup"
1153     ;;
1154   *-*-cygwin*)
1155     target_configdirs="$target_configdirs target-libtermcap target-winsup"
1156     noconfigdirs="$noconfigdirs target-libgloss"
1157     # always build newlib if winsup directory is present.
1158     if test -d "$srcdir/winsup/cygwin"; then
1159       skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1160     elif test -d "$srcdir/newlib"; then
1161       echo "Warning: winsup/cygwin is missing so newlib can't be built."
1162     fi
1163     ;;
1164   i[[3456789]]86-*-pe)
1165     noconfigdirs="$noconfigdirs target-libgloss"
1166     ;;
1167   i[[3456789]]86-*-sco3.2v5*)
1168     # The linker does not yet know about weak symbols in COFF,
1169     # and is not configured to handle mixed ELF and COFF.
1170     noconfigdirs="$noconfigdirs ld target-libgloss"
1171     ;;
1172   i[[3456789]]86-*-sco*)
1173     noconfigdirs="$noconfigdirs gprof target-libgloss"
1174     ;;
1175   i[[3456789]]86-*-solaris2* | x86_64-*-solaris2.1[[0-9]]*)
1176     noconfigdirs="$noconfigdirs target-libgloss"
1177     ;;
1178   i[[3456789]]86-*-sysv4*)
1179     noconfigdirs="$noconfigdirs target-libgloss"
1180     ;;
1181   i[[3456789]]86-*-beos*)
1182     noconfigdirs="$noconfigdirs gdb"
1183     ;;
1184   i[[3456789]]86-*-rdos*)
1185     noconfigdirs="$noconfigdirs gdb"
1186     ;;
1187   mmix-*-*)
1188     noconfigdirs="$noconfigdirs gdb"
1189     ;;
1190   mt-*-*)
1191     noconfigdirs="$noconfigdirs sim"
1192     ;;
1193   nfp-*-*)
1194     noconfigdirs="$noconfigdirs ld gas gdb gprof sim"
1195     noconfigdirs="$noconfigdirs $target_libraries"
1196     ;;
1197   pdp11-*-*)
1198     noconfigdirs="$noconfigdirs gdb gprof"
1199     ;;
1200   powerpc-*-aix*)
1201     # copied from rs6000-*-* entry
1202     noconfigdirs="$noconfigdirs gprof"
1203     ;;
1204   powerpc*-*-winnt* | powerpc*-*-pe*)
1205     target_configdirs="$target_configdirs target-winsup"
1206     noconfigdirs="$noconfigdirs gdb tcl tk target-libgloss itcl"
1207     # always build newlib.
1208     skipdirs=`echo " ${skipdirs} " | sed -e 's/ target-newlib / /'`
1209     ;;
1210     # This is temporary until we can link against shared libraries
1211   powerpcle-*-solaris*)
1212     noconfigdirs="$noconfigdirs gdb sim tcl tk itcl"
1213     ;;
1214   powerpc-*-beos*)
1215     noconfigdirs="$noconfigdirs gdb"
1216     ;;
1217   rs6000-*-lynxos*)
1218     noconfigdirs="$noconfigdirs gprof"
1219     ;;
1220   rs6000-*-aix*)
1221     noconfigdirs="$noconfigdirs gprof"
1222     ;;
1223   rs6000-*-*)
1224     noconfigdirs="$noconfigdirs gprof"
1225     ;;
1226   m68k-apollo-*)
1227     noconfigdirs="$noconfigdirs ld binutils gprof target-libgloss"
1228     ;;
1229   microblaze*)
1230     noconfigdirs="$noconfigdirs gprof"
1231     ;;
1232   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
1233     if test x$with_newlib = xyes; then
1234       noconfigdirs="$noconfigdirs gprof"
1235     fi
1236     ;;
1237   mips*-*-irix5*)
1238     noconfigdirs="$noconfigdirs gprof target-libgloss"
1239     ;;
1240   mips*-*-irix6*)
1241     noconfigdirs="$noconfigdirs gprof target-libgloss"
1242     ;;
1243   mips*-*-bsd*)
1244     noconfigdirs="$noconfigdirs ld gas gprof target-libgloss"
1245     ;;
1246   mips*-*-linux*)
1247     ;;
1248   mips*-*-ultrix* | mips*-*-osf* | mips*-*-ecoff* | mips*-*-pe* \
1249   | mips*-*-irix* | mips*-*-lnews* | mips*-*-riscos*)
1250     noconfigdirs="$noconfigdirs ld gas gprof"
1251     ;;
1252   mips*-*-*)
1253     noconfigdirs="$noconfigdirs gprof"
1254     ;;
1255   nvptx*-*-*)
1256     noconfigdirs="$noconfigdirs target-libssp target-libstdc++-v3 target-libobjc"
1257     ;;
1258   sh-*-*)
1259     case "${target}" in
1260       sh*-*-elf)
1261          ;;
1262       *)
1263          noconfigdirs="$noconfigdirs target-libgloss" ;;
1264     esac
1265     ;;
1266   sparc-*-sunos4*)
1267     if test x${is_cross_compiler} = xno ; then
1268            use_gnu_ld=no
1269     fi
1270     ;;
1271   tic6x-*-*)
1272     noconfigdirs="$noconfigdirs sim"
1273     ;;
1274   tilepro*-*-* | tilegx*-*-*)
1275     noconfigdirs="$noconfigdirs sim"
1276     ;;
1277   v810-*-*)
1278     noconfigdirs="$noconfigdirs bfd binutils gas gdb ld opcodes target-libgloss"
1279     ;;
1280   vax-*-*)
1281     noconfigdirs="$noconfigdirs target-newlib target-libgloss"
1282     ;;
1283   wasm32-*-*)
1284     noconfigdirs="$noconfigdirs ld"
1285     ;;
1286 esac
1287
1288 # If we aren't building newlib, then don't build libgloss, since libgloss
1289 # depends upon some newlib header files.
1290 case "${noconfigdirs}" in
1291   *target-libgloss*) ;;
1292   *target-newlib*) noconfigdirs="$noconfigdirs target-libgloss" ;;
1293 esac
1294
1295 # Work in distributions that contain no compiler tools, like Autoconf.
1296 host_makefile_frag=/dev/null
1297 if test -d ${srcdir}/config ; then
1298 case "${host}" in
1299   i[[3456789]]86-*-msdosdjgpp*)
1300     host_makefile_frag="config/mh-djgpp"
1301     ;;
1302   *-cygwin*)
1303     ACX_CHECK_CYGWIN_CAT_WORKS
1304     host_makefile_frag="config/mh-cygwin"
1305     ;;
1306   *-mingw*)
1307     host_makefile_frag="config/mh-mingw"
1308     ;;
1309   alpha*-linux*)
1310     host_makefile_frag="config/mh-alpha-linux"
1311     ;;
1312   hppa*-hp-hpux10*)
1313     host_makefile_frag="config/mh-pa-hpux10"
1314     ;;
1315   hppa*-hp-hpux*)
1316     host_makefile_frag="config/mh-pa"
1317     ;;
1318   hppa*-*)
1319     host_makefile_frag="config/mh-pa"
1320     ;;
1321   i?86-*-darwin[[89]]* | i?86-*-darwin1[[0-7]]* | powerpc*-*-darwin*)
1322     host_makefile_frag="config/mh-darwin"
1323     ;;
1324   powerpc-*-aix*)
1325     host_makefile_frag="config/mh-ppc-aix"
1326     ;;
1327   rs6000-*-aix*)
1328     host_makefile_frag="config/mh-ppc-aix"
1329     ;;
1330 esac
1331 fi
1332
1333 if test "${build}" != "${host}" ; then
1334   AR_FOR_BUILD=${AR_FOR_BUILD-ar}
1335   AS_FOR_BUILD=${AS_FOR_BUILD-as}
1336   CC_FOR_BUILD=${CC_FOR_BUILD-gcc}
1337   CPP_FOR_BUILD="${CPP_FOR_BUILD-\$(CC_FOR_BUILD) -E}"
1338   CXX_FOR_BUILD=${CXX_FOR_BUILD-g++}
1339   DSYMUTIL_FOR_BUILD=${DSYMUTIL_FOR_BUILD-dsymutil}
1340   GFORTRAN_FOR_BUILD=${GFORTRAN_FOR_BUILD-gfortran}
1341   GOC_FOR_BUILD=${GOC_FOR_BUILD-gccgo}
1342   GDC_FOR_BUILD=${GDC_FOR_BUILD-gdc}
1343   DLLTOOL_FOR_BUILD=${DLLTOOL_FOR_BUILD-dlltool}
1344   LD_FOR_BUILD=${LD_FOR_BUILD-ld}
1345   NM_FOR_BUILD=${NM_FOR_BUILD-nm}
1346   RANLIB_FOR_BUILD=${RANLIB_FOR_BUILD-ranlib}
1347   WINDRES_FOR_BUILD=${WINDRES_FOR_BUILD-windres}
1348   WINDMC_FOR_BUILD=${WINDMC_FOR_BUILD-windmc}
1349 else
1350   AR_FOR_BUILD="\$(AR)"
1351   AS_FOR_BUILD="\$(AS)"
1352   CC_FOR_BUILD="\$(CC)"
1353   CXX_FOR_BUILD="\$(CXX)"
1354   DSYMUTIL_FOR_BUILD="\$(DSYMUTIL)"
1355   GFORTRAN_FOR_BUILD="\$(GFORTRAN)"
1356   GOC_FOR_BUILD="\$(GOC)"
1357   GDC_FOR_BUILD="\$(GDC)"
1358   DLLTOOL_FOR_BUILD="\$(DLLTOOL)"
1359   LD_FOR_BUILD="\$(LD)"
1360   NM_FOR_BUILD="\$(NM)"
1361   RANLIB_FOR_BUILD="\$(RANLIB)"
1362   WINDRES_FOR_BUILD="\$(WINDRES)"
1363   WINDMC_FOR_BUILD="\$(WINDMC)"
1364 fi
1365
1366 AC_PROG_CC_C99
1367 AC_PROG_CXX
1368
1369 # We must set the default linker to the linker used by gcc for the correct
1370 # operation of libtool.  If LD is not defined and we are using gcc, try to
1371 # set the LD default to the ld used by gcc.
1372 if test -z "$LD"; then
1373   if test "$GCC" = yes; then
1374     case $build in
1375     *-*-mingw*)
1376       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1 | tr -d '\015'` ;;
1377     *)
1378       gcc_prog_ld=`$CC -print-prog-name=ld 2>&1` ;;
1379     esac
1380     case $gcc_prog_ld in
1381     # Accept absolute paths.
1382     [[\\/]* | [A-Za-z]:[\\/]*)]
1383       LD="$gcc_prog_ld" ;;
1384     esac
1385   fi
1386 fi
1387
1388 # Check whether -static-libstdc++ -static-libgcc is supported.
1389 have_static_libs=no
1390 if test "$GCC" = yes; then
1391   saved_LDFLAGS="$LDFLAGS"
1392
1393   LDFLAGS="$LDFLAGS -static-libstdc++ -static-libgcc"
1394   AC_MSG_CHECKING([whether g++ accepts -static-libstdc++ -static-libgcc])
1395   AC_LANG_PUSH(C++)
1396   AC_LINK_IFELSE([AC_LANG_SOURCE([
1397 #if (__GNUC__ < 4) || (__GNUC__ == 4 && __GNUC_MINOR__ < 5)
1398 #error -static-libstdc++ not implemented
1399 #endif
1400 int main() {}])],
1401     [AC_MSG_RESULT([yes]); have_static_libs=yes],
1402     [AC_MSG_RESULT([no])])
1403   AC_LANG_POP(C++)
1404
1405   LDFLAGS="$saved_LDFLAGS"
1406 fi
1407
1408 ACX_PROG_GNAT
1409 ACX_PROG_GDC
1410 ACX_PROG_CMP_IGNORE_INITIAL
1411
1412 AC_ARG_ENABLE([bootstrap],
1413 [AS_HELP_STRING([--enable-bootstrap],
1414                 [enable bootstrapping @<:@yes if native build@:>@])],,
1415 enable_bootstrap=default)
1416
1417 # Issue errors and warnings for invalid/strange bootstrap combinations.
1418 if test -r $srcdir/gcc/configure; then
1419   have_compiler=yes
1420 else
1421   have_compiler=no
1422 fi
1423
1424 case "$have_compiler:$host:$target:$enable_bootstrap" in
1425   *:*:*:no) ;;
1426
1427   # Default behavior.  Enable bootstrap if we have a compiler
1428   # and we are in a native configuration.
1429   yes:$build:$build:default)
1430     enable_bootstrap=yes ;;
1431
1432   *:*:*:default)
1433     enable_bootstrap=no ;;
1434
1435   # We have a compiler and we are in a native configuration, bootstrap is ok
1436   yes:$build:$build:yes)
1437     ;;
1438
1439   # Other configurations, but we have a compiler.  Assume the user knows
1440   # what he's doing.
1441   yes:*:*:yes)
1442     AC_MSG_WARN([trying to bootstrap a cross compiler])
1443     ;;
1444
1445   # No compiler: if they passed --enable-bootstrap explicitly, fail
1446   no:*:*:yes)
1447     AC_MSG_ERROR([cannot bootstrap without a compiler]) ;;
1448
1449   # Fail if wrong command line
1450   *)
1451     AC_MSG_ERROR([invalid option for --enable-bootstrap])
1452     ;;
1453 esac
1454
1455 # When bootstrapping with GCC, build stage 1 in C++11 mode to ensure that a
1456 # C++11 compiler can still start the bootstrap.  Otherwise, if building GCC,
1457 # require C++11 (or higher).
1458 if test "$enable_bootstrap:$GXX" = "yes:yes"; then
1459   CXX="$CXX -std=c++11"
1460 elif test "$have_compiler" = yes; then
1461   AX_CXX_COMPILE_STDCXX(11)
1462
1463   if test "${build}" != "${host}"; then
1464     AX_CXX_COMPILE_STDCXX(11, [], [], [_FOR_BUILD])
1465   fi
1466 fi
1467
1468 AC_ARG_ENABLE([pgo-build],
1469 [AS_HELP_STRING([--enable-pgo-build[[=lto]]],
1470                 [enable the PGO build])],
1471 [enable_pgo_build=$enableval],
1472 [enable_pgo_build=no])
1473
1474 # Issue errors and warnings for invalid/strange PGO build combinations.
1475 case "$have_compiler:$host:$target:$enable_pgo_build" in
1476   *:*:*:no) ;;
1477
1478   # Allow the PGO build only if we aren't building a compiler and
1479   # we are in a native configuration.
1480   no:$build:$build:yes | no:$build:$build:lto) ;;
1481
1482   # Disallow the PGO bootstrap if we are building a compiler.
1483   yes:*:*:yes | yes:*:*:lto)
1484     AC_MSG_ERROR([cannot perform the PGO bootstrap when building a compiler]) ;;
1485
1486   *)
1487     AC_MSG_ERROR([invalid option for --enable-pgo-build])
1488     ;;
1489 esac
1490
1491 if test "$enable_pgo_build" != "no"; then
1492   AC_MSG_CHECKING([whether the compiler supports -fprofile-generate])
1493   old_CFLAGS="$CFLAGS"
1494   PGO_BUILD_GEN_CFLAGS="-fprofile-generate"
1495   CFLAGS="$CFLAGS $PGO_BUILD_CFLAGS"
1496   AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1497                     [PGO_BUILD_GEN_CFLAGS=])
1498   CFLAGS="$old_CFLAGS"
1499   if test -n "$PGO_BUILD_GEN_CFLAGS"; then
1500     AC_MSG_RESULT([yes])
1501     PGO_BUILD_USE_CFLAGS="-fprofile-use"
1502   else
1503     AC_MSG_RESULT([no])
1504     AC_MSG_ERROR([cannot perform the PGO build without -fprofile-generate])
1505   fi
1506
1507   if test "$enable_pgo_build" = "lto"; then
1508     AC_MSG_CHECKING([whether the compiler supports -flto=jobserver -ffat-lto-objects])
1509     old_CFLAGS="$CFLAGS"
1510     PGO_BUILD_LTO_CFLAGS="-flto=jobserver -ffat-lto-objects"
1511     CFLAGS="$CFLAGS $PGO_BUILD_LTO_CFLAGS"
1512     AC_COMPILE_IFELSE([AC_LANG_SOURCE([int foo;])],,
1513                       [PGO_BUILD_LTO_CFLAGS=])
1514     CFLAGS="$old_CFLAGS"
1515     if test -n "$PGO_BUILD_LTO_CFLAGS"; then
1516       AC_MSG_RESULT([yes])
1517     else
1518       AC_MSG_RESULT([no])
1519       AC_MSG_WARN([LTO is disabled for the PGO build])
1520     fi
1521   fi
1522 fi
1523 AC_SUBST(PGO_BUILD_GEN_CFLAGS)
1524 AC_SUBST(PGO_BUILD_USE_CFLAGS)
1525 AC_SUBST(PGO_BUILD_LTO_CFLAGS)
1526
1527 # Used for setting $lt_cv_objdir
1528 _LT_CHECK_OBJDIR
1529
1530 # Check for GMP, MPFR and MPC
1531 gmplibs="-lmpc -lmpfr -lgmp"
1532 gmpinc=
1533 have_gmp=no
1534
1535 # Specify a location for mpc
1536 # check for this first so it ends up on the link line before mpfr.
1537 AC_ARG_WITH(mpc,
1538 [AS_HELP_STRING([--with-mpc=PATH],
1539                 [specify prefix directory for installed MPC package.
1540                  Equivalent to --with-mpc-include=PATH/include
1541                  plus --with-mpc-lib=PATH/lib])])
1542 AC_ARG_WITH(mpc-include,
1543 [AS_HELP_STRING([--with-mpc-include=PATH],
1544                 [specify directory for installed MPC include files])])
1545 AC_ARG_WITH(mpc-lib,
1546 [AS_HELP_STRING([--with-mpc-lib=PATH],
1547                 [specify directory for the installed MPC library])])
1548
1549 if test "x$with_mpc" != x; then
1550   gmplibs="-L$with_mpc/lib $gmplibs"
1551   gmpinc="-I$with_mpc/include $gmpinc"
1552 fi
1553 if test "x$with_mpc_include" != x; then
1554   gmpinc="-I$with_mpc_include $gmpinc"
1555 fi
1556 if test "x$with_mpc_lib" != x; then
1557   gmplibs="-L$with_mpc_lib $gmplibs"
1558 fi
1559 if test "x$with_mpc$with_mpc_include$with_mpc_lib" = x && test -d ${srcdir}/mpc; then
1560   gmplibs='-L$$r/$(HOST_SUBDIR)/mpc/src/'"$lt_cv_objdir $gmplibs"
1561   gmpinc='-I$$s/mpc/src '"$gmpinc"
1562   # Do not test the mpc version.  Assume that it is sufficient, since
1563   # it is in the source tree, and the library has not been built yet
1564   # but it would be included on the link line in the version check below
1565   # hence making the test fail.
1566   have_gmp=yes
1567 fi
1568
1569 # Specify a location for mpfr
1570 # check for this first so it ends up on the link line before gmp.
1571 AC_ARG_WITH(mpfr-dir,
1572 [AS_HELP_STRING([--with-mpfr-dir=PATH], [this option has been REMOVED])],
1573 [AC_MSG_ERROR([The --with-mpfr-dir=PATH option has been removed.
1574 Use --with-mpfr=PATH or --with-mpfr-include=PATH plus --with-mpfr-lib=PATH])])
1575
1576 AC_ARG_WITH(mpfr,
1577 [AS_HELP_STRING([--with-mpfr=PATH],
1578                 [specify prefix directory for installed MPFR package.
1579                  Equivalent to --with-mpfr-include=PATH/include
1580                  plus --with-mpfr-lib=PATH/lib])])
1581 AC_ARG_WITH(mpfr-include,
1582 [AS_HELP_STRING([--with-mpfr-include=PATH],
1583                 [specify directory for installed MPFR include files])])
1584 AC_ARG_WITH(mpfr-lib,
1585 [AS_HELP_STRING([--with-mpfr-lib=PATH],
1586                 [specify directory for the installed MPFR library])])
1587
1588 if test "x$with_mpfr" != x; then
1589   gmplibs="-L$with_mpfr/lib $gmplibs"
1590   gmpinc="-I$with_mpfr/include $gmpinc"
1591 fi
1592 if test "x$with_mpfr_include" != x; then
1593   gmpinc="-I$with_mpfr_include $gmpinc"
1594 fi
1595 if test "x$with_mpfr_lib" != x; then
1596   gmplibs="-L$with_mpfr_lib $gmplibs"
1597 fi
1598 if test "x$with_mpfr$with_mpfr_include$with_mpfr_lib" = x && test -d ${srcdir}/mpfr; then
1599   # MPFR v3.1.0 moved the sources into a src sub-directory.
1600   if ! test -d ${srcdir}/mpfr/src; then
1601     AC_MSG_ERROR([dnl
1602 Building GCC with MPFR in the source tree is only handled for MPFR 3.1.0+.])
1603   fi
1604   gmplibs='-L$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir $gmplibs"
1605   gmpinc='-I$$r/$(HOST_SUBDIR)/mpfr/src -I$$s/mpfr/src '"$gmpinc"
1606   extra_mpc_mpfr_configure_flags='--with-mpfr-include=$$s/mpfr/src --with-mpfr-lib=$$r/$(HOST_SUBDIR)/mpfr/src/'"$lt_cv_objdir"
1607   # Do not test the mpfr version.  Assume that it is sufficient, since
1608   # it is in the source tree, and the library has not been built yet
1609   # but it would be included on the link line in the version check below
1610   # hence making the test fail.
1611   have_gmp=yes
1612 fi
1613
1614 # Specify a location for gmp
1615 AC_ARG_WITH(gmp-dir,
1616 [AS_HELP_STRING([--with-gmp-dir=PATH], [this option has been REMOVED])],
1617 [AC_MSG_ERROR([The --with-gmp-dir=PATH option has been removed.
1618 Use --with-gmp=PATH or --with-gmp-include=PATH plus --with-gmp-lib=PATH])])
1619
1620 AC_ARG_WITH(gmp,
1621 [AS_HELP_STRING([--with-gmp=PATH],
1622                 [specify prefix directory for the installed GMP package.
1623                  Equivalent to --with-gmp-include=PATH/include
1624                  plus --with-gmp-lib=PATH/lib])])
1625 AC_ARG_WITH(gmp-include,
1626 [AS_HELP_STRING([--with-gmp-include=PATH],
1627                 [specify directory for installed GMP include files])])
1628 AC_ARG_WITH(gmp-lib,
1629 [AS_HELP_STRING([--with-gmp-lib=PATH],
1630                 [specify directory for the installed GMP library])])
1631
1632
1633 if test "x$with_gmp" != x; then
1634   gmplibs="-L$with_gmp/lib $gmplibs"
1635   gmpinc="-I$with_gmp/include $gmpinc"
1636 fi
1637 if test "x$with_gmp_include" != x; then
1638   gmpinc="-I$with_gmp_include $gmpinc"
1639 fi
1640 if test "x$with_gmp_lib" != x; then
1641   gmplibs="-L$with_gmp_lib $gmplibs"
1642 fi
1643 if test "x$with_gmp$with_gmp_include$with_gmp_lib" = x && test -d ${srcdir}/gmp; then
1644   gmplibs='-L$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir $gmplibs"
1645   gmpinc='-I$$r/$(HOST_SUBDIR)/gmp -I$$s/gmp '"$gmpinc"
1646   extra_mpfr_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1647   extra_mpc_gmp_configure_flags='--with-gmp-include=$$r/$(HOST_SUBDIR)/gmp --with-gmp-lib=$$r/$(HOST_SUBDIR)/gmp/'"$lt_cv_objdir"
1648   extra_isl_gmp_configure_flags='--with-gmp-builddir=$$r/$(HOST_SUBDIR)/gmp'
1649   # Do not test the gmp version.  Assume that it is sufficient, since
1650   # it is in the source tree, and the library has not been built yet
1651   # but it would be included on the link line in the version check below
1652   # hence making the test fail.
1653   have_gmp=yes
1654 fi
1655
1656 if test -d ${srcdir}/gcc && test "x$have_gmp" = xno; then
1657   have_gmp=yes
1658   saved_CFLAGS="$CFLAGS"
1659   CFLAGS="$CFLAGS $gmpinc"
1660   # Check for the recommended and required versions of GMP.
1661   AC_MSG_CHECKING([for the correct version of gmp.h])
1662   AC_TRY_COMPILE([#include "gmp.h"],[
1663   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1664   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1665   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,2,3)
1666   choke me
1667   #endif
1668   ], [AC_TRY_COMPILE([#include <gmp.h>],[
1669   #define GCC_GMP_VERSION_NUM(a,b,c) (((a) << 16L) | ((b) << 8) | (c))
1670   #define GCC_GMP_VERSION GCC_GMP_VERSION_NUM(__GNU_MP_VERSION,__GNU_MP_VERSION_MINOR,__GNU_MP_VERSION_PATCHLEVEL)
1671   #if GCC_GMP_VERSION < GCC_GMP_VERSION_NUM(4,3,2)
1672   choke me
1673   #endif
1674   ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1675    [AC_MSG_RESULT([no]); have_gmp=no])
1676
1677   # If we have GMP, check the MPFR version.
1678   if test x"$have_gmp" = xyes; then
1679     # Check for the recommended and required versions of MPFR.
1680     AC_MSG_CHECKING([for the correct version of mpfr.h])
1681     AC_TRY_COMPILE([#include <gmp.h>
1682     #include <mpfr.h>],[
1683     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,0)
1684     choke me
1685     #endif
1686     ], [AC_TRY_COMPILE([#include <gmp.h>
1687     #include <mpfr.h>],[
1688     #if MPFR_VERSION < MPFR_VERSION_NUM(3,1,6)
1689     choke me
1690     #endif
1691     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1692      [AC_MSG_RESULT([no]); have_gmp=no])
1693   fi
1694
1695   # Check for the MPC header version.
1696   if test x"$have_gmp" = xyes ; then
1697     # Check for the recommended and required versions of MPC.
1698     AC_MSG_CHECKING([for the correct version of mpc.h])
1699     AC_TRY_COMPILE([#include <mpc.h>],[
1700     #if MPC_VERSION < MPC_VERSION_NUM(0,8,0)
1701     choke me
1702     #endif
1703     ], [AC_TRY_COMPILE([#include <mpc.h>],[
1704     #if MPC_VERSION < MPC_VERSION_NUM(0,8,1)
1705     choke me
1706     #endif
1707     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([buggy but acceptable])])],
1708      [AC_MSG_RESULT([no]); have_gmp=no])
1709   fi
1710
1711   # Now check the MPFR library.
1712   if test x"$have_gmp" = xyes; then
1713     saved_LIBS="$LIBS"
1714     LIBS="$LIBS $gmplibs"
1715     AC_MSG_CHECKING([for the correct version of the gmp/mpfr/mpc libraries])
1716     AC_TRY_LINK([#include <mpc.h>],[
1717     mpfr_t n;
1718     mpfr_t x;
1719     mpc_t c;
1720     int t;
1721     mpfr_init (n);
1722     mpfr_init (x);
1723     mpfr_atan2 (n, n, x, MPFR_RNDN);
1724     mpfr_erfc (n, x, MPFR_RNDN);
1725     mpfr_subnormalize (x, t, MPFR_RNDN);
1726     mpfr_clear(n);
1727     mpfr_clear(x);
1728     mpc_init2 (c, 53);
1729     mpc_set_ui_ui (c, 1, 1, MPC_RNDNN);
1730     mpc_cosh (c, c, MPC_RNDNN);
1731     mpc_pow (c, c, c, MPC_RNDNN);
1732     mpc_acosh (c, c, MPC_RNDNN);
1733     mpc_clear (c);
1734     ], [AC_MSG_RESULT([yes])], [AC_MSG_RESULT([no]); have_gmp=no])
1735     LIBS="$saved_LIBS"
1736   fi
1737
1738   CFLAGS="$saved_CFLAGS"
1739
1740 # The library versions listed in the error message below should match
1741 # the HARD-minimums enforced above.
1742   if test x$have_gmp != xyes; then
1743     AC_MSG_ERROR([Building GCC requires GMP 4.2+, MPFR 3.1.0+ and MPC 0.8.0+.
1744 Try the --with-gmp, --with-mpfr and/or --with-mpc options to specify
1745 their locations.  Source code for these libraries can be found at
1746 their respective hosting sites as well as at
1747 https://gcc.gnu.org/pub/gcc/infrastructure/.  See also
1748 http://gcc.gnu.org/install/prerequisites.html for additional info.  If
1749 you obtained GMP, MPFR and/or MPC from a vendor distribution package,
1750 make sure that you have installed both the libraries and the header
1751 files.  They may be located in separate packages.])
1752   fi
1753 fi
1754
1755 # Flags needed for both GMP, MPFR and/or MPC.
1756 AC_SUBST(gmplibs)
1757 AC_SUBST(gmpinc)
1758 AC_SUBST(extra_mpfr_configure_flags)
1759 AC_SUBST(extra_mpc_gmp_configure_flags)
1760 AC_SUBST(extra_mpc_mpfr_configure_flags)
1761 AC_SUBST(extra_isl_gmp_configure_flags)
1762
1763 # Libraries to use for stage1 or when not bootstrapping.
1764 AC_ARG_WITH(stage1-libs,
1765 [AS_HELP_STRING([--with-stage1-libs=LIBS], [libraries for stage1])],
1766 [if test "$withval" = "no" -o "$withval" = "yes"; then
1767    stage1_libs=
1768  else
1769    stage1_libs=$withval
1770  fi],
1771 [stage1_libs=])
1772 AC_SUBST(stage1_libs)
1773
1774 # Whether or not to use -static-libstdc++ and -static-libgcc.  The
1775 # default is yes if gcc is being built; no otherwise.  The reason for
1776 # this default is that gdb is sometimes linked against GNU Source
1777 # Highlight, which is a shared library that uses C++ exceptions.  In
1778 # this case, -static-libstdc++ will cause crashes.
1779 AC_ARG_WITH(static-standard-libraries,
1780 [AS_HELP_STRING([--with-static-standard-libraries],
1781                 [use -static-libstdc++ and -static-libgcc (default=auto)])],
1782 [], [with_static_standard_libraries=auto])
1783 if test "$with_static_standard_libraries" = auto; then
1784   with_static_standard_libraries=$have_compiler
1785 fi
1786
1787 # Linker flags to use for stage1 or when not bootstrapping.
1788 AC_ARG_WITH(stage1-ldflags,
1789 [AS_HELP_STRING([--with-stage1-ldflags=FLAGS], [linker flags for stage1])],
1790 [if test "$withval" = "no" -o "$withval" = "yes"; then
1791    stage1_ldflags=
1792  else
1793    stage1_ldflags=$withval
1794  fi],
1795 [stage1_ldflags=
1796  # In stage 1, default to linking libstdc++ and libgcc statically with GCC
1797  # if supported.  But if the user explicitly specified the libraries to use,
1798  # trust that they are doing what they want.
1799  if test "$with_static_standard_libraries" = yes -a "$stage1_libs" = "" \
1800      -a "$have_static_libs" = yes; then
1801    stage1_ldflags="-static-libstdc++ -static-libgcc"
1802  fi])
1803 AC_SUBST(stage1_ldflags)
1804
1805 # Libraries to use for stage2 and later builds.
1806 AC_ARG_WITH(boot-libs,
1807 [AS_HELP_STRING([--with-boot-libs=LIBS], [libraries for stage2 and later])],
1808 [if test "$withval" = "no" -o "$withval" = "yes"; then
1809    poststage1_libs=
1810  else
1811    poststage1_libs=$withval
1812  fi],
1813 [poststage1_libs=])
1814 AC_SUBST(poststage1_libs)
1815
1816 # Linker flags to use for stage2 and later builds.
1817 AC_ARG_WITH(boot-ldflags,
1818 [AS_HELP_STRING([--with-boot-ldflags=FLAGS],
1819                 [linker flags for stage2 and later])],
1820 [if test "$withval" = "no" -o "$withval" = "yes"; then
1821    poststage1_ldflags=
1822  else
1823    poststage1_ldflags=$withval
1824  fi],
1825 [poststage1_ldflags=
1826  # In stages 2 and 3, default to linking libstdc++ and libgcc
1827  # statically.  But if the user explicitly specified the libraries to
1828  # use, trust that they are doing what they want.
1829  if test "$poststage1_libs" = ""; then
1830    poststage1_ldflags="-static-libstdc++ -static-libgcc"
1831  fi])
1832 AC_SUBST(poststage1_ldflags)
1833
1834 # GCC GRAPHITE dependency isl.
1835 # Basic setup is inlined here, actual checks are in config/isl.m4
1836
1837 AC_ARG_WITH(isl,
1838   [AS_HELP_STRING(
1839    [--with-isl=PATH],
1840    [Specify prefix directory for the installed isl package.
1841     Equivalent to --with-isl-include=PATH/include
1842     plus --with-isl-lib=PATH/lib])])
1843
1844 # Treat --without-isl as a request to disable
1845 # GRAPHITE support and skip all following checks.
1846 if test "x$with_isl" != "xno"; then
1847   # Check for isl
1848   dnl Provide configure switches and initialize islinc & isllibs
1849   dnl with user input.
1850   ISL_INIT_FLAGS
1851   dnl The versions of isl that work for Graphite
1852   ISL_CHECK_VERSION()
1853   dnl Only execute fail-action, if isl has been requested.
1854   ISL_IF_FAILED([
1855     AC_MSG_ERROR([Unable to find a usable isl.  See config.log for details.])])
1856 fi
1857
1858 # If the isl check failed, disable builds of in-tree variant of isl
1859 if test "x$with_isl" = xno ||
1860    test "x$gcc_cv_isl" = xno; then
1861   noconfigdirs="$noconfigdirs isl"
1862   islinc=
1863 fi
1864
1865 AC_SUBST(isllibs)
1866 AC_SUBST(islinc)
1867
1868 # Check for LTO support.
1869 AC_ARG_ENABLE(lto,
1870 [AS_HELP_STRING([--enable-lto], [enable link time optimization support])],
1871 enable_lto=$enableval,
1872 enable_lto=yes; default_enable_lto=yes)
1873
1874 ACX_ELF_TARGET_IFELSE([# ELF platforms build the lto-plugin always.
1875   build_lto_plugin=yes
1876 ],[if test x"$default_enable_lto" = x"yes" ; then
1877     case $target in
1878       *-apple-darwin[[912]]* | *-cygwin* | *-mingw* | *djgpp*) ;;
1879       # On other non-ELF platforms, LTO has yet to be validated.
1880       *) enable_lto=no ;;
1881     esac
1882   else
1883   # Apart from ELF platforms, only Windows and Darwin support LTO so far.
1884   # It would also be nice to check the binutils support, but we don't
1885   # have gcc_GAS_CHECK_FEATURE available here.  For now, we'll just
1886   # warn during gcc/ subconfigure; unless you're bootstrapping with
1887   # -flto it won't be needed until after installation anyway.
1888     case $target in
1889       *-cygwin* | *-mingw* | *-apple-darwin* | *djgpp*) ;;
1890       *) if test x"$enable_lto" = x"yes"; then
1891         AC_MSG_ERROR([LTO support is not enabled for this target.])
1892         fi
1893       ;;
1894     esac
1895   fi
1896   # Among non-ELF, only Windows platforms support the lto-plugin so far.
1897   # Build it unless LTO was explicitly disabled.
1898   case $target in
1899     *-cygwin* | *-mingw*) build_lto_plugin=$enable_lto ;;
1900     *) ;;
1901   esac
1902 ])
1903
1904 AC_ARG_ENABLE(linker-plugin-configure-flags,
1905   [AS_HELP_STRING([[--enable-linker-plugin-configure-flags=FLAGS]],
1906     [additional flags for configuring linker plugins @<:@none@:>@])],
1907   extra_linker_plugin_configure_flags=$enableval,
1908   extra_linker_plugin_configure_flags=)
1909 AC_SUBST(extra_linker_plugin_configure_flags)
1910 AC_ARG_ENABLE(linker-plugin-flags,
1911   [AS_HELP_STRING([[--enable-linker-plugin-flags=FLAGS]],
1912     [additional flags for configuring and building linker plugins @<:@none@:>@])],
1913   extra_linker_plugin_flags=$enableval,
1914   extra_linker_plugin_flags=)
1915 AC_SUBST(extra_linker_plugin_flags)
1916
1917 # Enable --enable-host-shared.
1918 # Checked early to determine whether jit is an 'all' language
1919 AC_ARG_ENABLE(host-shared,
1920 [AS_HELP_STRING([--enable-host-shared],
1921                 [build host code as shared libraries])],
1922 [host_shared=$enableval
1923  case $target in
1924    x86_64-*-darwin* | aarch64-*-darwin*)
1925      if test x$host_shared != xyes ; then
1926        # PIC is the default, and actually cannot be switched off.
1927        echo configure.ac: warning: PIC code is required for the configured target, host-shared setting ignored. 1>&2
1928        host_shared=yes
1929      fi ;;
1930   *) ;;
1931  esac],
1932 [case $target in
1933   x86_64-*-darwin* | aarch64-*-darwin*) host_shared=yes ;;
1934   *) host_shared=no ;;
1935  esac])
1936 AC_SUBST(host_shared)
1937
1938 # By default, C and C++ are the only stage 1 languages.
1939 stage1_languages=,c,
1940
1941 # Target libraries that we bootstrap.
1942 bootstrap_target_libs=,target-libgcc,
1943
1944 # Figure out what language subdirectories are present.
1945 # Look if the user specified --enable-languages="..."; if not, use
1946 # the environment variable $LANGUAGES if defined. $LANGUAGES might
1947 # go away some day.
1948 # NB:  embedded tabs in this IF block -- do not untabify
1949 if test -d ${srcdir}/gcc; then
1950   if test x"${enable_languages+set}" != xset; then
1951     if test x"${LANGUAGES+set}" = xset; then
1952       enable_languages="${LANGUAGES}"
1953         echo configure.ac: warning: setting LANGUAGES is deprecated, use --enable-languages instead 1>&2
1954     else
1955       enable_languages=default
1956     fi
1957   else
1958     if test x"${enable_languages}" = x ||
1959        test x"${enable_languages}" = xyes;
1960        then
1961       echo configure.ac: --enable-languages needs at least one language argument 1>&2
1962       exit 1
1963     fi
1964   fi
1965   enable_languages=`echo "${enable_languages}" | sed -e 's/[[   ,]][[   ,]]*/,/g' -e 's/,$//'`
1966
1967   # 'f95' is the old name for the 'fortran' language. We issue a warning
1968   # and make the substitution.
1969   case ,${enable_languages}, in
1970     *,f95,*)
1971       echo configure.ac: warning: 'f95' as language name is deprecated, use 'fortran' instead 1>&2
1972       enable_languages=`echo "${enable_languages}" | sed -e 's/f95/fortran/g'`
1973       ;;
1974   esac
1975
1976   # If bootstrapping, C++ must be enabled.
1977   case ",$enable_languages,:$enable_bootstrap" in
1978     *,c++,*:*) ;;
1979     *:yes)
1980       if test -f ${srcdir}/gcc/cp/config-lang.in; then
1981         enable_languages="${enable_languages},c++"
1982       else
1983         AC_MSG_ERROR([bootstrapping requires c++ sources])
1984       fi
1985       ;;
1986   esac
1987
1988   # First scan to see if an enabled language requires some other language.
1989   # We assume that a given config-lang.in will list all the language
1990   # front ends it requires, even if some are required indirectly.
1991   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
1992     case ${lang_frag} in
1993       ..) ;;
1994       # The odd quoting in the next line works around
1995       # an apparent bug in bash 1.12 on linux.
1996       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
1997       *)
1998         # From the config-lang.in, get $language, $lang_requires, and
1999         # $lang_requires_boot_languages.
2000         language=
2001         lang_requires=
2002         lang_requires_boot_languages=
2003         # set srcdir during sourcing lang_frag to the gcc dir.
2004         # Sadly overriding srcdir on the . line doesn't work in plain sh as it
2005         # polutes this shell
2006         saved_srcdir=${srcdir}
2007         srcdir=${srcdir}/gcc . ${lang_frag}
2008         srcdir=${saved_srcdir}
2009         for other in ${lang_requires} ${lang_requires_boot_languages}; do
2010           case ,${enable_languages}, in
2011             *,$other,*) ;;
2012             *,default,*) ;;
2013             *,all,*) ;;
2014             *,$language,*)
2015               echo " \`$other' language required by \`$language'; enabling" 1>&2
2016               enable_languages="${enable_languages},${other}"
2017               ;;
2018           esac
2019         done
2020         for other in ${lang_requires_boot_languages} ; do
2021           if test "$other" != "c"; then
2022             case ,${enable_stage1_languages}, in
2023               *,$other,*) ;;
2024               *,default,*) ;;
2025               *,all,*) ;;
2026               *)
2027                 case ,${enable_languages}, in
2028                   *,$language,*)
2029                     echo " '$other' language required by '$language' in stage 1; enabling" 1>&2
2030                     enable_stage1_languages="$enable_stage1_languages,${other}"
2031                     ;;
2032                 esac
2033                 ;;
2034             esac
2035           fi
2036         done
2037         ;;
2038     esac
2039   done
2040
2041   new_enable_languages=,c,
2042
2043   # If LTO is enabled, add the LTO front end.
2044   if test "$enable_lto" = "yes" ; then
2045     case ,${enable_languages}, in
2046       *,lto,*) ;;
2047       *) enable_languages="${enable_languages},lto" ;;
2048     esac
2049     if test "${build_lto_plugin}" = "yes" ; then
2050       configdirs="$configdirs lto-plugin"
2051     fi
2052   fi
2053
2054   # If we're building an offloading compiler, add the LTO front end.
2055   if test x"$enable_as_accelerator_for" != x ; then
2056     case ,${enable_languages}, in
2057       *,lto,*) ;;
2058       *) enable_languages="${enable_languages},lto" ;;
2059     esac
2060   fi
2061
2062   missing_languages=`echo ",$enable_languages," | sed -e s/,default,/,/ -e s/,all,/,/ -e s/,c,/,/ `
2063   potential_languages=,c,
2064
2065   enabled_target_libs=
2066   disabled_target_libs=
2067
2068   for lang_frag in ${srcdir}/gcc/*/config-lang.in .. ; do
2069     case ${lang_frag} in
2070       ..) ;;
2071       # The odd quoting in the next line works around
2072       # an apparent bug in bash 1.12 on linux.
2073       ${srcdir}/gcc/[[*]]/config-lang.in) ;;
2074       *)
2075         # From the config-lang.in, get $language, $target_libs,
2076         # $lang_dirs, $boot_language, and $build_by_default
2077         language=
2078         target_libs=
2079         lang_dirs=
2080         subdir_requires=
2081         boot_language=no
2082         build_by_default=yes
2083         # set srcdir during sourcing.  See above about save & restore
2084         saved_srcdir=${srcdir}
2085         srcdir=${srcdir}/gcc . ${lang_frag}
2086         srcdir=${saved_srcdir}
2087         if test x${language} = x; then
2088           echo "${lang_frag} doesn't set \$language." 1>&2
2089           exit 1
2090         fi
2091
2092         if test "$language" = "c++"; then
2093           boot_language=yes
2094         fi
2095
2096         add_this_lang=no
2097         # C is always enabled, so no need to add it again
2098         if test "$language" != "c"; then
2099           case ,${enable_languages}, in
2100             *,${language},*)
2101               # Language was explicitly selected; include it
2102               add_this_lang=yes
2103               ;;
2104             *,all,*)
2105               # All languages are enabled
2106               add_this_lang=all
2107               ;;
2108             *,default,*)
2109               # 'default' was selected, select it if it is a default language
2110               add_this_lang=${build_by_default}
2111               ;;
2112           esac
2113         fi
2114
2115         # Disable languages that need other directories if these aren't available.
2116         for i in $subdir_requires; do
2117           test -f "$srcdir/gcc/$i/config-lang.in" && continue
2118           case ${add_this_lang} in
2119             yes)
2120               # Specifically requested language; tell them.
2121               AC_MSG_ERROR([The gcc/$i directory contains parts of $language but is missing])
2122               ;;
2123             all)
2124               AC_MSG_WARN([The gcc/$i directory contains parts of $language but is missing])
2125               add_this_lang=unsupported
2126               ;;
2127             *)
2128               # Silently disable.
2129               add_this_lang=unsupported
2130               ;;
2131           esac
2132         done
2133
2134         # Disable Ada if no preexisting GNAT is available.
2135         case ${add_this_lang}:${language}:${have_gnat} in
2136           yes:ada:no)
2137             # Specifically requested language; tell them.
2138             AC_MSG_ERROR([GNAT is required to build $language])
2139             ;;
2140           all:ada:no)
2141             AC_MSG_WARN([GNAT is required to build $language])
2142             add_this_lang=unsupported
2143             ;;
2144           *:ada:no)
2145             # Silently disable.
2146             add_this_lang=unsupported
2147             ;;
2148         esac
2149
2150         # Disable D if no preexisting GDC is available.
2151         case ${add_this_lang}:${language}:${have_gdc} in
2152           yes:d:no)
2153             # Specifically requested language; tell them.
2154             AC_MSG_ERROR([GDC is required to build $language])
2155            ;;
2156           all:d:no)
2157             AC_MSG_WARN([GDC is required to build $language])
2158             add_this_lang=unsupported
2159             ;;
2160           *:d:no)
2161             # Silently disable.
2162             add_this_lang=unsupported
2163             ;;
2164         esac
2165
2166         # Disable jit if -enable-host-shared not specified
2167         # but not if building for Mingw. All code in Windows
2168         # is position independent code (PIC).
2169         case $target in
2170           *mingw*) ;;
2171           *)
2172           case ${add_this_lang}:${language}:${host_shared} in
2173             yes:jit:no)
2174                    # PR jit/64780: explicitly specify --enable-host-shared
2175             AC_MSG_ERROR([
2176 Enabling language "jit" requires --enable-host-shared.
2177
2178 --enable-host-shared typically slows the rest of the compiler down by
2179 a few %, so you must explicitly enable it.
2180
2181 If you want to build both the jit and the regular compiler, it is often
2182 best to do this via two separate configure/builds, in separate
2183 directories, to avoid imposing the performance cost of
2184 --enable-host-shared on the regular compiler.])
2185                     ;;
2186             all:jit:no)
2187               AC_MSG_WARN([--enable-host-shared required to build $language])
2188               add_this_lang=unsupported
2189               ;;
2190             *:jit:no)
2191               # Silently disable.
2192               add_this_lang=unsupported
2193               ;;
2194                 esac
2195           ;;
2196         esac
2197
2198         # Disable a language that is unsupported by the target.
2199         case "${add_this_lang}: $unsupported_languages " in
2200           no:*) ;;
2201           unsupported:*) ;;
2202           *:*" $language "*)
2203             AC_MSG_WARN([${language} not supported for this target])
2204             add_this_lang=unsupported
2205             ;;
2206         esac
2207
2208         case $add_this_lang in
2209           unsupported)
2210             # Remove language-dependent dirs.
2211             disabled_target_libs="$disabled_target_libs $target_libs"
2212             noconfigdirs="$noconfigdirs $lang_dirs"
2213             ;;
2214           no)
2215             # Remove language-dependent dirs; still show language as supported.
2216             disabled_target_libs="$disabled_target_libs $target_libs"
2217             noconfigdirs="$noconfigdirs $lang_dirs"
2218             potential_languages="${potential_languages}${language},"
2219             ;;
2220           all|yes)
2221             new_enable_languages="${new_enable_languages}${language},"
2222             potential_languages="${potential_languages}${language},"
2223             missing_languages=`echo "$missing_languages" | sed "s/,$language,/,/"`
2224             enabled_target_libs="$enabled_target_libs $target_libs"
2225             case "${boot_language}:,$enable_stage1_languages," in
2226               yes:* | *:*,$language,* | *:*,yes, | *:*,all,)
2227                 # Add to (comma-separated) list of stage 1 languages.
2228                 case ",$stage1_languages," in
2229                   *,$language,* | ,yes, | ,all,) ;;
2230                   *) stage1_languages="${stage1_languages}${language}," ;;
2231                 esac
2232                 # We need to bootstrap any supporting libraries.
2233                 bootstrap_target_libs=`echo "${bootstrap_target_libs}${target_libs}," | sed "s/ /,/g"`
2234                 ;;
2235             esac
2236             ;;
2237         esac
2238         ;;
2239     esac
2240   done
2241
2242   # Add target libraries which are only needed for disabled languages
2243   # to noconfigdirs.
2244   if test -n "$disabled_target_libs"; then
2245     for dir in $disabled_target_libs; do
2246       case " $enabled_target_libs " in
2247       *" ${dir} "*) ;;
2248       *) noconfigdirs="$noconfigdirs $dir" ;;
2249       esac
2250     done
2251   fi
2252
2253   AC_ARG_ENABLE(stage1-languages,
2254   [AS_HELP_STRING([[--enable-stage1-languages[=all]]],
2255                   [choose additional languages to build during
2256                   stage1.  Mostly useful for compiler development])],
2257   [case ,${enable_stage1_languages}, in
2258     ,no,|,,)
2259       # Set it to something that will have no effect in the loop below
2260       enable_stage1_languages=c ;;
2261     ,yes,)
2262       enable_stage1_languages=`echo $new_enable_languages | \
2263         sed -e "s/^,//" -e "s/,$//" ` ;;
2264     *,all,*)
2265       enable_stage1_languages=`echo ,$enable_stage1_languages, | \
2266         sed -e "s/,all,/$new_enable_languages/" -e "s/^,//" -e "s/,$//" ` ;;
2267   esac
2268
2269   # Add "good" languages from enable_stage1_languages to stage1_languages,
2270   # while "bad" languages go in missing_languages.  Leave no duplicates.
2271   for i in `echo $enable_stage1_languages | sed 's/,/ /g' `; do
2272     case $potential_languages in
2273       *,$i,*)
2274         case $stage1_languages in
2275           *,$i,*) ;;
2276           *) stage1_languages="$stage1_languages$i," ;;
2277         esac ;;
2278       *)
2279         case $missing_languages in
2280           *,$i,*) ;;
2281           *) missing_languages="$missing_languages$i," ;;
2282         esac ;;
2283      esac
2284   done])
2285
2286   # Remove leading/trailing commas that were added for simplicity
2287   potential_languages=`echo "$potential_languages" | sed -e "s/^,//" -e "s/,$//"`
2288   missing_languages=`echo "$missing_languages" | sed -e "s/^,//" -e "s/,$//"`
2289   stage1_languages=`echo "$stage1_languages" | sed -e "s/^,//" -e "s/,$//"`
2290   new_enable_languages=`echo "$new_enable_languages" | sed -e "s/^,//" -e "s/,$//"`
2291
2292   if test "x$missing_languages" != x; then
2293     AC_MSG_ERROR([
2294 The following requested languages could not be built: ${missing_languages}
2295 Supported languages are: ${potential_languages}])
2296   fi
2297   if test "x$new_enable_languages" != "x$enable_languages"; then
2298     echo The following languages will be built: ${new_enable_languages}
2299     enable_languages="$new_enable_languages"
2300   fi
2301
2302   AC_SUBST(stage1_languages)
2303   ac_configure_args=`echo " $ac_configure_args" | sed -e "s/ '--enable-languages=[[^ ]]*'//g" -e "s/$/ '--enable-languages="$enable_languages"'/" `
2304 fi
2305
2306 # Handle --disable-<component> generically.
2307 for dir in $configdirs $build_configdirs $target_configdirs ; do
2308   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g -e s/-/_/g`
2309   varname=`echo $dirname | sed -e s/+/_/g`
2310   if eval test x\${enable_${varname}} "=" xno ; then
2311     noconfigdirs="$noconfigdirs $dir"
2312   fi
2313 done
2314
2315 # Check for Boehm's garbage collector
2316 AC_ARG_ENABLE(objc-gc,
2317 [AS_HELP_STRING([--enable-objc-gc],
2318                 [enable use of Boehm's garbage collector with the
2319                  GNU Objective-C runtime])])
2320 AC_ARG_WITH([target-bdw-gc],
2321 [AS_HELP_STRING([--with-target-bdw-gc=PATHLIST],
2322                 [specify prefix directory for installed bdw-gc package.
2323                  Equivalent to --with-target-bdw-gc-include=PATH/include
2324                  plus --with-target-bdw-gc-lib=PATH/lib])])
2325 AC_ARG_WITH([target-bdw-gc-include],
2326 [AS_HELP_STRING([--with-target-bdw-gc-include=PATHLIST],
2327                 [specify directories for installed bdw-gc include files])])
2328 AC_ARG_WITH([target-bdw-gc-lib],
2329 [AS_HELP_STRING([--with-target-bdw-gc-lib=PATHLIST],
2330                 [specify directories for installed bdw-gc library])])
2331
2332 case ,${enable_languages},:${enable_objc_gc} in *,objc,*:yes|*,objc,*:auto)
2333   AC_MSG_CHECKING([for bdw garbage collector])
2334   if test "x$with_target_bdw_gc$with_target_bdw_gc_include$with_target_bdw_gc_lib" = x; then
2335     dnl no bdw-gw options, assume default locations
2336     AC_MSG_RESULT([using bdw-gc in default locations])
2337   else
2338     dnl bdw-gw options, first error checking, complete checking in libobjc
2339     if test "x$with_target_bdw_gc_include" = x && test "x$with_target_bdw_gc_lib" != x; then
2340       AC_MSG_ERROR([found --with-target-bdw-gc-lib but --with-target-bdw-gc-include missing])
2341     elif test "x$with_target_bdw_gc_include" != x && test "x$with_target_bdw_gc_lib" = x; then
2342       AC_MSG_ERROR([found --with-target-bdw-gc-include but --with-target-bdw-gc-lib missing])
2343     else
2344       AC_MSG_RESULT([using paths configured with --with-target-bdw-gc options])
2345     fi
2346   fi
2347 esac
2348
2349 # Disable libitm, libsanitizer, libvtv, liboffloadmic if we're not building C++
2350 case ,${enable_languages}, in
2351   *,c++,*)
2352     # Disable libitm, libsanitizer if we're not building libstdc++
2353     case "${noconfigdirs}" in
2354       *target-libstdc++-v3*)
2355         noconfigdirs="$noconfigdirs target-libitm target-libsanitizer"
2356         ;;
2357       *) ;;
2358     esac
2359     ;;
2360   *)
2361     noconfigdirs="$noconfigdirs target-liboffloadmic target-libitm target-libsanitizer target-libvtv"
2362     ;;
2363 esac
2364
2365 # If gcc/ is not in the source tree then we'll not be building a
2366 # target compiler, assume in that case we don't want to build any
2367 # target libraries or tools.
2368 #
2369 # This was added primarily for the benefit for binutils-gdb who reuse
2370 # this configure script, but don't always have target tools available.
2371 if test ! -d ${srcdir}/gcc; then
2372    skipdirs="${skipdirs} ${target_configdirs}"
2373 fi
2374
2375 # Remove the entries in $skipdirs and $noconfigdirs from $configdirs,
2376 # $build_configdirs and $target_configdirs.
2377 # If we have the source for $noconfigdirs entries, add them to $notsupp.
2378
2379 notsupp=""
2380 for dir in . $skipdirs $noconfigdirs ; do
2381   dirname=`echo $dir | sed -e s/target-//g -e s/build-//g`
2382   if test $dir != .  && echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2383     configdirs=`echo " ${configdirs} " | sed -e "s/ ${dir} / /"`
2384     if test -r $srcdir/$dirname/configure ; then
2385       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2386         true
2387       else
2388         notsupp="$notsupp $dir"
2389       fi
2390     fi
2391   fi
2392   if test $dir != .  && echo " ${build_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2393     build_configdirs=`echo " ${build_configdirs} " | sed -e "s/ ${dir} / /"`
2394     if test -r $srcdir/$dirname/configure ; then
2395       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2396         true
2397       else
2398         notsupp="$notsupp $dir"
2399       fi
2400     fi
2401   fi
2402   if test $dir != . && echo " ${target_configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2403     target_configdirs=`echo " ${target_configdirs} " | sed -e "s/ ${dir} / /"`
2404     if test -r $srcdir/$dirname/configure ; then
2405       if echo " ${skipdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2406         true
2407       else
2408         notsupp="$notsupp $dir"
2409       fi
2410     fi
2411   fi
2412 done
2413
2414 # Quietly strip out all directories which aren't configurable in this tree.
2415 # This relies on all configurable subdirectories being autoconfiscated, which
2416 # is now the case.
2417 build_configdirs_all="$build_configdirs"
2418 build_configdirs=
2419 for i in ${build_configdirs_all} ; do
2420   j=`echo $i | sed -e s/build-//g`
2421   if test -f ${srcdir}/$j/configure ; then
2422     build_configdirs="${build_configdirs} $i"
2423   fi
2424 done
2425
2426 configdirs_all="$configdirs"
2427 configdirs=
2428 for i in ${configdirs_all} ; do
2429   if test -f ${srcdir}/$i/configure ; then
2430     configdirs="${configdirs} $i"
2431   fi
2432 done
2433
2434 target_configdirs_all="$target_configdirs"
2435 target_configdirs=
2436 for i in ${target_configdirs_all} ; do
2437   j=`echo $i | sed -e s/target-//g`
2438   if test -f ${srcdir}/$j/configure ; then
2439     target_configdirs="${target_configdirs} $i"
2440   fi
2441 done
2442
2443 # libiberty-linker-plugin is special: it doesn't have its own source directory,
2444 # so we have to add it after the preceding checks.
2445 if test x"$extra_linker_plugin_flags$extra_linker_plugin_configure_flags" != x
2446 then
2447   case " $configdirs " in
2448     *" libiberty "*)
2449       # If we can build libiberty, we can also build libiberty-linker-plugin.
2450       configdirs="$configdirs libiberty-linker-plugin"
2451       extra_linker_plugin_configure_flags="$extra_linker_plugin_configure_flags \
2452         --with-libiberty=../libiberty-linker-plugin";;
2453     *)
2454       AC_MSG_ERROR([libiberty missing]);;
2455   esac
2456 fi
2457
2458 # Sometimes we have special requirements for the host libiberty.
2459 extra_host_libiberty_configure_flags=
2460 extra_host_zlib_configure_flags=
2461 case " $configdirs " in
2462   *" lto-plugin "* | *" libcc1 "*)
2463     # When these are to be built as shared libraries, the same applies to
2464     # libiberty.
2465     extra_host_libiberty_configure_flags=--enable-shared
2466     ;;
2467   *" bfd "*)
2468     # When bfd is to be built as a shared library, the same applies to
2469     # zlib.
2470     if test "$enable_shared" = "yes"; then
2471       extra_host_zlib_configure_flags=--enable-host-shared
2472     fi
2473     ;;
2474 esac
2475 AC_SUBST(extra_host_libiberty_configure_flags)
2476 AC_SUBST(extra_host_zlib_configure_flags)
2477
2478 # Produce a warning message for the subdirs we can't configure.
2479 # This isn't especially interesting in the Cygnus tree, but in the individual
2480 # FSF releases, it's important to let people know when their machine isn't
2481 # supported by the one or two programs in a package.
2482
2483 if test -n "${notsupp}" && test -z "${norecursion}" ; then
2484   # If $appdirs is non-empty, at least one of those directories must still
2485   # be configured, or we error out.  (E.g., if the gas release supports a
2486   # specified target in some subdirs but not the gas subdir, we shouldn't
2487   # pretend that all is well.)
2488   if test -n "$appdirs" ; then
2489     for dir in $appdirs ; do
2490       if test -r $dir/Makefile.in ; then
2491         if echo " ${configdirs} " | grep " ${dir} " >/dev/null 2>&1; then
2492           appdirs=""
2493           break
2494         fi
2495         if echo " ${target_configdirs} " | grep " target-${dir} " >/dev/null 2>&1; then
2496           appdirs=""
2497           break
2498         fi
2499       fi
2500     done
2501     if test -n "$appdirs" ; then
2502       echo "*** This configuration is not supported by this package." 1>&2
2503       exit 1
2504     fi
2505   fi
2506   # Okay, some application will build, or we don't care to check.  Still
2507   # notify of subdirs not getting built.
2508   echo "*** This configuration is not supported in the following subdirectories:" 1>&2
2509   echo "    ${notsupp}" 1>&2
2510   echo "    (Any other directories should still work fine.)" 1>&2
2511 fi
2512
2513 case "$host" in
2514   *msdosdjgpp*)
2515     enable_gdbtk=no ;;
2516 esac
2517
2518 # To find our prefix, in gcc_cv_tool_prefix.
2519 ACX_TOOL_DIRS
2520
2521 copy_dirs=
2522
2523 AC_ARG_WITH([build-sysroot],
2524   [AS_HELP_STRING([--with-build-sysroot=SYSROOT],
2525                   [use sysroot as the system root during the build])],
2526   [if test x"$withval" != x ; then
2527      SYSROOT_CFLAGS_FOR_TARGET="--sysroot=$withval"
2528    fi],
2529   [SYSROOT_CFLAGS_FOR_TARGET=])
2530 AC_SUBST(SYSROOT_CFLAGS_FOR_TARGET)
2531
2532 AC_ARG_WITH([debug-prefix-map],
2533   [AS_HELP_STRING([--with-debug-prefix-map='A=B C=D ...'],
2534                   [map A to B, C to D ... in debug information])],
2535   [if test x"$withval" != x; then
2536      DEBUG_PREFIX_CFLAGS_FOR_TARGET=
2537      for debug_map in $withval; do
2538        DEBUG_PREFIX_CFLAGS_FOR_TARGET="$DEBUG_PREFIX_CFLAGS_FOR_TARGET -fdebug-prefix-map=$debug_map"
2539      done
2540    fi],
2541   [DEBUG_PREFIX_CFLAGS_FOR_TARGET=])
2542 AC_SUBST(DEBUG_PREFIX_CFLAGS_FOR_TARGET)
2543
2544 # During gcc bootstrap, if we use some random cc for stage1 then CFLAGS
2545 # might be empty or "-g".  We don't require a C++ compiler, so CXXFLAGS
2546 # might also be empty (or "-g", if a non-GCC C++ compiler is in the path).
2547 # We want to ensure that TARGET libraries (which we know are built with
2548 # gcc) are built with "-O2 -g", so include those options when setting
2549 # CFLAGS_FOR_TARGET and CXXFLAGS_FOR_TARGET.
2550 if test "x$CFLAGS_FOR_TARGET" = x; then
2551   if test "x${is_cross_compiler}" = xyes; then
2552     CFLAGS_FOR_TARGET="-g -O2"
2553   else
2554     CFLAGS_FOR_TARGET=$CFLAGS
2555     case " $CFLAGS " in
2556       *" -O2 "*) ;;
2557       *) CFLAGS_FOR_TARGET="-O2 $CFLAGS_FOR_TARGET" ;;
2558     esac
2559     case " $CFLAGS " in
2560       *" -g "* | *" -g3 "*) ;;
2561       *) CFLAGS_FOR_TARGET="-g $CFLAGS_FOR_TARGET" ;;
2562     esac
2563   fi
2564 fi
2565 AC_SUBST(CFLAGS_FOR_TARGET)
2566
2567 if test "x$CXXFLAGS_FOR_TARGET" = x; then
2568   if test "x${is_cross_compiler}" = xyes; then
2569     CXXFLAGS_FOR_TARGET="-g -O2"
2570   else
2571     CXXFLAGS_FOR_TARGET=$CXXFLAGS
2572     case " $CXXFLAGS " in
2573       *" -O2 "*) ;;
2574       *) CXXFLAGS_FOR_TARGET="-O2 $CXXFLAGS_FOR_TARGET" ;;
2575     esac
2576     case " $CXXFLAGS " in
2577       *" -g "* | *" -g3 "*) ;;
2578       *) CXXFLAGS_FOR_TARGET="-g $CXXFLAGS_FOR_TARGET" ;;
2579     esac
2580   fi
2581 fi
2582 AC_SUBST(CXXFLAGS_FOR_TARGET)
2583
2584 AC_SUBST(LDFLAGS_FOR_TARGET)
2585
2586 # Handle --with-headers=XXX.  If the value is not "yes", the contents of
2587 # the named directory are copied to $(tooldir)/sys-include.
2588 if test x"${with_headers}" != x && test x"${with_headers}" != xno ; then
2589   if test x${is_cross_compiler} = xno ; then
2590     echo 1>&2 '***' --with-headers is only supported when cross compiling
2591     exit 1
2592   fi
2593   if test x"${with_headers}" != xyes ; then
2594     x=${gcc_cv_tool_prefix}
2595     copy_dirs="${copy_dirs} ${with_headers} $x/${target_noncanonical}/sys-include"
2596   fi
2597 fi
2598
2599 # Handle --with-libs=XXX.  If the value is not "yes", the contents of
2600 # the name directories are copied to $(tooldir)/lib.  Multiple directories
2601 # are permitted.
2602 if test x"${with_libs}" != x && test x"${with_libs}" != xno ; then
2603   if test x${is_cross_compiler} = xno ; then
2604     echo 1>&2 '***' --with-libs is only supported when cross compiling
2605     exit 1
2606   fi
2607   if test x"${with_libs}" != xyes ; then
2608     # Copy the libraries in reverse order, so that files in the first named
2609     # library override files in subsequent libraries.
2610     x=${gcc_cv_tool_prefix}
2611     for l in ${with_libs}; do
2612       copy_dirs="$l $x/${target_noncanonical}/lib ${copy_dirs}"
2613     done
2614   fi
2615 fi
2616
2617 # Set with_gnu_as, with_gnu_ld, and with_system_zlib as appropriate.
2618 #
2619 # This is done by determining whether or not the appropriate directory
2620 # is available, and by checking whether or not specific configurations
2621 # have requested that this magic not happen.
2622 #
2623 # The command line options always override the explicit settings in
2624 # configure.ac, and the settings in configure.ac override this magic.
2625 #
2626 # If the default for a toolchain is to use GNU as and ld, and you don't
2627 # want to do that, then you should use the --without-gnu-as and
2628 # --without-gnu-ld options for the configure script.  Similarly, if
2629 # the default is to use the included zlib and you don't want to do that,
2630 # you should use the --with-system-zlib option for the configure script.
2631
2632 if test x${use_gnu_as} = x &&
2633    echo " ${configdirs} " | grep " gas " > /dev/null 2>&1 ; then
2634   with_gnu_as=yes
2635   extra_host_args="$extra_host_args --with-gnu-as"
2636 fi
2637
2638 if test x${use_gnu_ld} = x &&
2639    echo " ${configdirs} " | egrep " (go)?ld " > /dev/null 2>&1 ; then
2640   with_gnu_ld=yes
2641   extra_host_args="$extra_host_args --with-gnu-ld"
2642 fi
2643
2644 if test x${use_included_zlib} = x &&
2645    echo " ${configdirs} " | grep " zlib " > /dev/null 2>&1 ; then
2646   :
2647 else
2648   with_system_zlib=yes
2649   extra_host_args="$extra_host_args --with-system-zlib"
2650 fi
2651
2652 # If using newlib, add --with-newlib to the extra_host_args so that gcc/configure
2653 # can detect this case.
2654
2655 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " target-newlib " > /dev/null 2>&1 ; then
2656   with_newlib=yes
2657   extra_host_args="$extra_host_args --with-newlib"
2658 fi
2659
2660 # Handle ${copy_dirs}
2661 set fnord ${copy_dirs}
2662 shift
2663 while test $# != 0 ; do
2664   if test -f $2/COPIED && test x"`cat $2/COPIED`" = x"$1" ; then
2665     :
2666   else
2667     echo Copying $1 to $2
2668
2669     # Use the install script to create the directory and all required
2670     # parent directories.
2671     if test -d $2 ; then
2672       :
2673     else
2674       echo >config.temp
2675       ${srcdir}/install-sh -c -m 644 config.temp $2/COPIED
2676     fi
2677
2678     # Copy the directory, assuming we have tar.
2679     # FIXME: Should we use B in the second tar?  Not all systems support it.
2680     (cd $1; tar -cf - .) | (cd $2; tar -xpf -)
2681
2682     # It is the responsibility of the user to correctly adjust all
2683     # symlinks.  If somebody can figure out how to handle them correctly
2684     # here, feel free to add the code.
2685
2686     echo $1 > $2/COPIED
2687   fi
2688   shift; shift
2689 done
2690
2691 # Determine a target-dependent exec_prefix that the installed
2692 # gcc will search in.  Keep this list sorted by triplet, with
2693 # the *-*-osname triplets last.
2694 md_exec_prefix=
2695 case "${target}" in
2696   i[[34567]]86-pc-msdosdjgpp*)
2697     md_exec_prefix=/dev/env/DJDIR/bin
2698     ;;
2699   *-*-hpux* | \
2700   *-*-nto-qnx* | \
2701   *-*-solaris2*)
2702     md_exec_prefix=/usr/ccs/bin
2703     ;;
2704 esac
2705
2706 extra_arflags_for_target=
2707 extra_nmflags_for_target=
2708 extra_ranlibflags_for_target=
2709 target_makefile_frag=/dev/null
2710 case "${target}" in
2711   spu-*-*)
2712     target_makefile_frag="config/mt-spu"
2713     ;;
2714   mips*-sde-elf* | mips*-mti-elf* | mips*-img-elf*)
2715     target_makefile_frag="config/mt-sde"
2716     ;;
2717   mipsisa*-*-elfoabi*)
2718     target_makefile_frag="config/mt-mips-elfoabi"
2719     ;;
2720   mips*-*-*linux* | mips*-*-gnu*)
2721     target_makefile_frag="config/mt-mips-gnu"
2722     ;;
2723   nios2-*-elf*)
2724     target_makefile_frag="config/mt-nios2-elf"
2725     ;;
2726   *-*-linux-android*)
2727     target_makefile_frag="config/mt-android"
2728     ;;
2729   *-*-linux* | *-*-gnu* | *-*-k*bsd*-gnu | *-*-kopensolaris*-gnu)
2730     target_makefile_frag="config/mt-gnu"
2731     ;;
2732   *-*-aix4.[[3456789]]* | *-*-aix[[56789]].*)
2733     # nm and ar from AIX 4.3 and above require -X32_64 flag to all ar and nm
2734     # commands to handle both 32-bit and 64-bit objects.  These flags are
2735     # harmless if we're using GNU nm or ar.
2736     extra_arflags_for_target=" -X32_64"
2737     extra_nmflags_for_target=" -B -X32_64"
2738     ;;
2739 esac
2740
2741 alphaieee_frag=/dev/null
2742 case $target in
2743   alpha*-*-*)
2744     # This just makes sure to use the -mieee option to build target libs.
2745     # This should probably be set individually by each library.
2746     alphaieee_frag="config/mt-alphaieee"
2747     ;;
2748 esac
2749
2750 # If --enable-target-optspace always use -Os instead of -O2 to build
2751 # the target libraries, similarly if it is not specified, use -Os
2752 # on selected platforms.
2753 ospace_frag=/dev/null
2754 case "${enable_target_optspace}:${target}" in
2755   yes:*)
2756     ospace_frag="config/mt-ospace"
2757     ;;
2758   :d30v-*)
2759     ospace_frag="config/mt-d30v"
2760     ;;
2761   :m32r-* | :d10v-* | :fr30-* | :i?86*-*-elfiamcu)
2762     ospace_frag="config/mt-ospace"
2763     ;;
2764   no:* | :*)
2765     ;;
2766   *)
2767     echo "*** bad value \"${enable_target_optspace}\" for --enable-target-optspace flag; ignored" 1>&2
2768     ;;
2769 esac
2770
2771 # Some systems (e.g., one of the i386-aix systems the gas testers are
2772 # using) don't handle "\$" correctly, so don't use it here.
2773 tooldir='${exec_prefix}'/${target_noncanonical}
2774 build_tooldir=${tooldir}
2775
2776 # Create a .gdbinit file which runs the one in srcdir
2777 # and tells GDB to look there for source files.
2778
2779 if test -r ${srcdir}/.gdbinit ; then
2780   case ${srcdir} in
2781     .) ;;
2782     *) cat > ./.gdbinit <<EOF
2783 # ${NO_EDIT}
2784 dir ${srcdir}
2785 dir .
2786 source ${srcdir}/.gdbinit
2787 EOF
2788     ;;
2789   esac
2790 fi
2791
2792 # Make sure that the compiler is able to generate an executable.  If it
2793 # can't, we are probably in trouble.  We don't care whether we can run the
2794 # executable--we might be using a cross compiler--we only care whether it
2795 # can be created.  At this point the main configure script has set CC.
2796 we_are_ok=no
2797 echo "int main () { return 0; }" > conftest.c
2798 ${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
2799 if test $? = 0 ; then
2800   if test -s conftest || test -s conftest.exe ; then
2801     we_are_ok=yes
2802   fi
2803 fi
2804 case $we_are_ok in
2805   no)
2806     echo 1>&2 "*** The command '${CC} -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c' failed."
2807     echo 1>&2 "*** You must set the environment variable CC to a working compiler."
2808     rm -f conftest*
2809     exit 1
2810     ;;
2811 esac
2812 rm -f conftest*
2813
2814 # Decide which environment variable is used to find dynamic libraries.
2815 case "${host}" in
2816   *-*-hpux*) RPATH_ENVVAR=SHLIB_PATH ;;
2817   *-*-darwin*) RPATH_ENVVAR=DYLD_LIBRARY_PATH ;;
2818   *-*-mingw* | *-*-cygwin ) RPATH_ENVVAR=PATH ;;
2819   *) RPATH_ENVVAR=LD_LIBRARY_PATH ;;
2820 esac
2821
2822 # On systems where the dynamic library environment variable is PATH,
2823 # gcc/ will put dynamic libraries into a subdirectory to avoid adding
2824 # built executables to PATH.
2825 if test "$RPATH_ENVVAR" = PATH; then
2826   GCC_SHLIB_SUBDIR=/shlib
2827 else
2828   GCC_SHLIB_SUBDIR=
2829 fi
2830
2831 # Adjust the toplevel makefile according to whether bootstrap was selected.
2832 case $enable_bootstrap in
2833   yes)
2834     bootstrap_suffix=bootstrap
2835     BUILD_CONFIG=bootstrap-debug
2836     ;;
2837   no)
2838     bootstrap_suffix=no-bootstrap
2839     BUILD_CONFIG=
2840     ;;
2841 esac
2842
2843 AC_MSG_CHECKING(for default BUILD_CONFIG)
2844
2845 AC_ARG_WITH([build-config],
2846   [AS_HELP_STRING([--with-build-config='NAME NAME2...'],
2847                   [use config/NAME.mk build configuration])],
2848   [case $with_build_config in
2849    yes) with_build_config= ;;
2850    no) with_build_config= BUILD_CONFIG= ;;
2851    esac])
2852
2853 if test "x${with_build_config}" != x; then
2854   BUILD_CONFIG=$with_build_config
2855 else
2856   case $BUILD_CONFIG in
2857   bootstrap-debug)
2858     if echo "int f (void) { return 0; }" > conftest.c &&
2859        ${CC} -c conftest.c &&
2860        mv conftest.o conftest.o.g0 &&
2861        ${CC} -c -g conftest.c &&
2862        mv conftest.o conftest.o.g &&
2863        ${srcdir}/contrib/compare-debug conftest.o.g0 conftest.o.g > /dev/null 2>&1; then
2864       :
2865     else
2866       BUILD_CONFIG=
2867     fi
2868     rm -f conftest.c conftest.o conftest.o.g0 conftest.o.g
2869     ;;
2870   esac
2871 fi
2872 AC_MSG_RESULT($BUILD_CONFIG)
2873 AC_SUBST(BUILD_CONFIG)
2874
2875 # Use same top-level configure hooks in libgcc/libstdc++/libvtv.
2876 AC_MSG_CHECKING([for --enable-vtable-verify])
2877 AC_ARG_ENABLE(vtable-verify,
2878 [AS_HELP_STRING([--enable-vtable-verify],
2879                 [Enable vtable verification feature])],
2880 [case "$enableval" in
2881  yes) enable_vtable_verify=yes ;;
2882  no)  enable_vtable_verify=no ;;
2883  *)   enable_vtable_verify=no;;
2884  esac],
2885 [enable_vtable_verify=no])
2886 AC_MSG_RESULT($enable_vtable_verify)
2887
2888 # Record target_configdirs and the configure arguments for target and
2889 # build configuration in Makefile.
2890 target_configdirs=`echo "${target_configdirs}" | sed -e 's/target-//g'`
2891 build_configdirs=`echo "${build_configdirs}" | sed -e 's/build-//g'`
2892 bootstrap_fixincludes=no
2893
2894 # If we are building libgomp, bootstrap it.
2895 if echo " ${target_configdirs} " | grep " libgomp " > /dev/null 2>&1 ; then
2896   bootstrap_target_libs=${bootstrap_target_libs}target-libgomp,
2897 fi
2898
2899 # If we are building libsanitizer and $BUILD_CONFIG contains bootstrap-asan
2900 # or bootstrap-ubsan, bootstrap it.
2901 if echo " ${target_configdirs} " | grep " libsanitizer " > /dev/null 2>&1; then
2902   case "$BUILD_CONFIG" in
2903     *bootstrap-hwasan* | *bootstrap-asan* | *bootstrap-ubsan* )
2904       bootstrap_target_libs=${bootstrap_target_libs}target-libsanitizer,
2905       bootstrap_fixincludes=yes
2906       ;;
2907   esac
2908 fi
2909
2910 # If we are building libvtv and --enable-vtable-verify, bootstrap it.
2911 if echo " ${target_configdirs} " | grep " libvtv " > /dev/null 2>&1 &&
2912    test "$enable_vtable_verify" != no; then
2913   bootstrap_target_libs=${bootstrap_target_libs}target-libvtv,
2914 fi
2915
2916 # If we are building libatomic and the list of enabled languages includes the
2917 # D frontend, bootstrap it.
2918 if echo " ${target_configdirs} " | grep " libatomic " > /dev/null 2>&1; then
2919   case ,${enable_languages}, in
2920     *,d,*)
2921       bootstrap_target_libs=${bootstrap_target_libs}target-libatomic,
2922       ;;
2923   esac
2924 fi
2925
2926 # Determine whether gdb needs tk/tcl or not.
2927 # Use 'maybe' since enable_gdbtk might be true even if tk isn't available
2928 # and in that case we want gdb to be built without tk.  Ugh!
2929 # In fact I believe gdb is the *only* package directly dependent on tk,
2930 # so we should be able to put the 'maybe's in unconditionally and
2931 # leave out the maybe dependencies when enable_gdbtk is false.  I'm not
2932 # 100% sure that that's safe though.
2933
2934 gdb_tk="maybe-all-tcl maybe-all-tk maybe-all-itcl maybe-all-libgui"
2935 case "$enable_gdbtk" in
2936   no)
2937     GDB_TK="" ;;
2938   yes)
2939     GDB_TK="${gdb_tk}" ;;
2940   *)
2941     # Only add the dependency on gdbtk when GDBtk is part of the gdb
2942     # distro.  Eventually someone will fix this and move Insight, nee
2943     # gdbtk to a separate directory.
2944     if test -d ${srcdir}/gdb/gdbtk ; then
2945       GDB_TK="${gdb_tk}"
2946     else
2947       GDB_TK=""
2948     fi
2949     ;;
2950 esac
2951 CONFIGURE_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-configure-/g`
2952 INSTALL_GDB_TK=`echo ${GDB_TK} | sed s/-all-/-install-/g`
2953
2954 # gdb and gdbserver depend on gnulib and gdbsupport, but as nothing
2955 # else does, only include them if one of these is built.  The Makefile
2956 # provides the ordering, so it's enough here to add to the list.
2957 case " ${configdirs} " in
2958   *\ gdb\ *)
2959     configdirs="${configdirs} gnulib gdbsupport"
2960     ;;
2961   *\ gdbserver\ *)
2962     configdirs="${configdirs} gnulib gdbsupport"
2963     ;;
2964   *\ sim\ *)
2965     configdirs="${configdirs} gnulib"
2966     ;;
2967 esac
2968
2969 # Strip out unwanted targets.
2970
2971 # While at that, we remove Makefiles if we were started for recursive
2972 # configuration, so that the top-level Makefile reconfigures them,
2973 # like we used to do when configure itself was recursive.
2974
2975 # Loop over modules.  We used to use the "$extrasub" feature from Autoconf
2976 # but now we're fixing up the Makefile ourselves with the additional
2977 # commands passed to AC_CONFIG_FILES.  Use separate variables
2978 # extrasub-{build,host,target} not because there is any reason to split
2979 # the substitutions up that way, but only to remain below the limit of
2980 # 99 commands in a script, for HP-UX sed.
2981
2982 # Do not nest @if/@endif or @unless/@endunless pairs, because
2983 # configure will not warn you at all.
2984
2985 case "$enable_bootstrap:$ENABLE_GOLD: $configdirs :,$stage1_languages," in
2986   yes:yes:*\ gold\ *:*,c++,*) ;;
2987   yes:yes:*\ gold\ *:*)
2988     AC_MSG_ERROR([in a combined tree, bootstrapping with --enable-gold requires c++ in stage1_languages])
2989     ;;
2990 esac
2991
2992 extrasub_build=
2993 for module in ${build_configdirs} ; do
2994   if test -z "${no_recursion}" \
2995      && test -f ${build_subdir}/${module}/Makefile; then
2996     echo 1>&2 "*** removing ${build_subdir}/${module}/Makefile to force reconfigure"
2997     rm -f ${build_subdir}/${module}/Makefile
2998   fi
2999   extrasub_build="$extrasub_build
3000 /^@if build-$module\$/d
3001 /^@endif build-$module\$/d
3002 /^@unless build-$module\$/,/^@endunless build-$module\$/d
3003 /^@if build-$module-$bootstrap_suffix\$/d
3004 /^@endif build-$module-$bootstrap_suffix\$/d
3005 /^@unless build-$module-$bootstrap_suffix\$/,/^@endunless build-$module-$bootstrap_suffix\$/d"
3006 done
3007 extrasub_host=
3008 for module in ${configdirs} ; do
3009   if test -z "${no_recursion}"; then
3010     for file in stage*-${module}/Makefile prev-${module}/Makefile ${module}/Makefile; do
3011       if test -f ${file}; then
3012         echo 1>&2 "*** removing ${file} to force reconfigure"
3013         rm -f ${file}
3014       fi
3015     done
3016   fi
3017   case ${module},${bootstrap_fixincludes} in
3018     fixincludes,no) host_bootstrap_suffix=no-bootstrap ;;
3019     *) host_bootstrap_suffix=$bootstrap_suffix ;;
3020   esac
3021   extrasub_host="$extrasub_host
3022 /^@if $module\$/d
3023 /^@endif $module\$/d
3024 /^@unless $module\$/,/^@endunless $module\$/d
3025 /^@if $module-$host_bootstrap_suffix\$/d
3026 /^@endif $module-$host_bootstrap_suffix\$/d
3027 /^@unless $module-$host_bootstrap_suffix\$/,/^@endunless $module-$host_bootstrap_suffix\$/d"
3028 done
3029 extrasub_target=
3030 for module in ${target_configdirs} ; do
3031   if test -z "${no_recursion}" \
3032      && test -f ${target_subdir}/${module}/Makefile; then
3033     echo 1>&2 "*** removing ${target_subdir}/${module}/Makefile to force reconfigure"
3034     rm -f ${target_subdir}/${module}/Makefile
3035   fi
3036
3037   # We only bootstrap target libraries listed in bootstrap_target_libs.
3038   case $bootstrap_target_libs in
3039     *,target-$module,*) target_bootstrap_suffix=$bootstrap_suffix ;;
3040     *) target_bootstrap_suffix=no-bootstrap ;;
3041   esac
3042
3043   extrasub_target="$extrasub_target
3044 /^@if target-$module\$/d
3045 /^@endif target-$module\$/d
3046 /^@unless target-$module\$/,/^@endunless target-$module\$/d
3047 /^@if target-$module-$target_bootstrap_suffix\$/d
3048 /^@endif target-$module-$target_bootstrap_suffix\$/d
3049 /^@unless target-$module-$target_bootstrap_suffix\$/,/^@endunless target-$module-$target_bootstrap_suffix\$/d"
3050 done
3051
3052 # Do the final fixup along with target modules.
3053 extrasub_target="$extrasub_target
3054 /^@if /,/^@endif /d
3055 /^@unless /d
3056 /^@endunless /d"
3057
3058 if test "$enable_pgo_build" != "no"; then
3059   extrasub_build="$extrasub_build
3060 /^@if pgo-build\$/d
3061 /^@endif pgo-build\$/d"
3062 fi
3063
3064 # Create the serialization dependencies.  This uses a temporary file.
3065
3066 AC_ARG_ENABLE([serial-configure],
3067 [AS_HELP_STRING([[--enable-serial-[{host,target,build}-]configure]],
3068                 [force sequential configuration of
3069                  sub-packages for the host, target or build
3070                  machine, or all sub-packages])])
3071
3072 case ${enable_serial_configure} in
3073   yes)
3074     enable_serial_build_configure=yes
3075     enable_serial_host_configure=yes
3076     enable_serial_target_configure=yes
3077     ;;
3078 esac
3079
3080 # These force 'configure's to be done one at a time, to avoid problems
3081 # with contention over a shared config.cache.
3082 rm -f serdep.tmp
3083 echo '# serdep.tmp' > serdep.tmp
3084 olditem=
3085 test "x${enable_serial_build_configure}" = xyes &&
3086 for item in ${build_configdirs} ; do
3087   case ${olditem} in
3088     "") ;;
3089     *) echo "configure-build-${item}: configure-build-${olditem}" >> serdep.tmp ;;
3090   esac
3091   olditem=${item}
3092 done
3093 olditem=
3094 test "x${enable_serial_host_configure}" = xyes &&
3095 for item in ${configdirs} ; do
3096   case ${olditem} in
3097     "") ;;
3098     *) echo "configure-${item}: configure-${olditem}" >> serdep.tmp ;;
3099   esac
3100   olditem=${item}
3101 done
3102 olditem=
3103 test "x${enable_serial_target_configure}" = xyes &&
3104 for item in ${target_configdirs} ; do
3105   case ${olditem} in
3106     "") ;;
3107     *) echo "configure-target-${item}: configure-target-${olditem}" >> serdep.tmp ;;
3108   esac
3109   olditem=${item}
3110 done
3111 serialization_dependencies=serdep.tmp
3112 AC_SUBST_FILE(serialization_dependencies)
3113
3114 # Base args.  Strip norecursion, cache-file, srcdir, host, build,
3115 # target, nonopt, and variable assignments.  These are the ones we
3116 # might not want to pass down to subconfigures.  The exception being
3117 # --cache-file=/dev/null, which is used to turn off the use of cache
3118 # files altogether, and which should be passed on to subconfigures.
3119 # Also strip program-prefix, program-suffix, and program-transform-name,
3120 # so that we can pass down a consistent program-transform-name.
3121 baseargs=
3122 tbaseargs=
3123 keep_next=no
3124 skip_next=no
3125 eval "set -- $ac_configure_args"
3126 for ac_arg
3127 do
3128   if test X"$skip_next" = X"yes"; then
3129     skip_next=no
3130     continue
3131   fi
3132   if test X"$keep_next" = X"yes"; then
3133     case $ac_arg in
3134       *\'*)
3135         ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3136     esac
3137     baseargs="$baseargs '$ac_arg'"
3138     tbaseargs="$tbaseargs '$ac_arg'"
3139     keep_next=no
3140     continue
3141   fi
3142
3143   # Handle separated arguments.  Based on the logic generated by
3144   # autoconf 2.59.
3145   case $ac_arg in
3146     *=* | --config-cache | -C | -disable-* | --disable-* \
3147       | -enable-* | --enable-* | -gas | --g* | -nfp | --nf* \
3148       | -q | -quiet | --q* | -silent | --sil* | -v | -verb* \
3149       | -with-* | --with-* | -without-* | --without-* | --x)
3150       separate_arg=no
3151       ;;
3152     -*)
3153       separate_arg=yes
3154       ;;
3155     *)
3156       separate_arg=no
3157       ;;
3158   esac
3159
3160   skip_targ=no
3161   case $ac_arg in
3162 changequote(,)
3163   --with-* | --without-*)
3164     libopt=`echo "$ac_arg" | sed -e 's,^--[^-_]*[-_],,' -e 's,=.*$,,'`
3165
3166     case $libopt in
3167     *[-_]include)
3168       lib=`echo "$libopt" | sed 's,[-_]include$,,'`
3169       ;;
3170     *[-_]lib)
3171       lib=`echo "$libopt" | sed 's,[-_]lib$,,'`
3172       ;;
3173     *)
3174       lib=$libopt
3175       ;;
3176     esac
3177 changequote([,])
3178
3179     case $lib in
3180     mpc | mpfr | gmp | isl)
3181       # If we're processing --with-$lib, --with-$lib-include or
3182       # --with-$lib-lib, for one of the libs above, and target is
3183       # different from host, don't pass the current argument to any
3184       # target library's configure.
3185       if test x$is_cross_compiler = xyes; then
3186         skip_targ=yes
3187       fi
3188       ;;
3189     esac
3190     ;;
3191   esac
3192
3193   case "$ac_arg" in
3194     --cache-file=/dev/null | \
3195     -cache-file=/dev/null )
3196       # Handled here to avoid the test to skip args below.
3197       baseargs="$baseargs '$ac_arg'"
3198       tbaseargs="$tbaseargs '$ac_arg'"
3199       # Assert: $separate_arg should always be no.
3200       keep_next=$separate_arg
3201       ;;
3202     --no*)
3203       continue
3204       ;;
3205     --c* | \
3206     --sr* | \
3207     --ho* | \
3208     --bu* | \
3209     --t* | \
3210     --program-* | \
3211     -cache_file* | \
3212     -srcdir* | \
3213     -host* | \
3214     -build* | \
3215     -target* | \
3216     -program-prefix* | \
3217     -program-suffix* | \
3218     -program-transform-name* )
3219       skip_next=$separate_arg
3220       continue
3221       ;;
3222     -*)
3223       # An option.  Add it.
3224       case $ac_arg in
3225         *\'*)
3226           ac_arg=`echo "$ac_arg" | sed "s/'/'\\\\\\\\''/g"` ;;
3227       esac
3228       baseargs="$baseargs '$ac_arg'"
3229       if test X"$skip_targ" = Xno; then
3230         tbaseargs="$tbaseargs '$ac_arg'"
3231       fi
3232       keep_next=$separate_arg
3233       ;;
3234     *)
3235       # Either a variable assignment, or a nonopt (triplet).  Don't
3236       # pass it down; let the Makefile handle this.
3237       continue
3238       ;;
3239   esac
3240 done
3241 # Remove the initial space we just introduced and, as these will be
3242 # expanded by make, quote '$'.
3243 baseargs=`echo "x$baseargs" | sed -e 's/^x *//' -e 's,\\$,$$,g'`
3244
3245 # Add in --program-transform-name, after --program-prefix and
3246 # --program-suffix have been applied to it.  Autoconf has already
3247 # doubled dollar signs and backslashes in program_transform_name; we want
3248 # the backslashes un-doubled, and then the entire thing wrapped in single
3249 # quotes, because this will be expanded first by make and then by the shell.
3250 # Also, because we want to override the logic in subdir configure scripts to
3251 # choose program_transform_name, replace any s,x,x, with s,y,y,.
3252 sed -e "s,\\\\\\\\,\\\\,g; s,','\\\\'',g; s/s,x,x,/s,y,y,/" <<EOF_SED > conftestsed.out
3253 ${program_transform_name}
3254 EOF_SED
3255 gcc_transform_name=`cat conftestsed.out`
3256 rm -f conftestsed.out
3257 baseargs="$baseargs --program-transform-name='${gcc_transform_name}'"
3258 tbaseargs="$tbaseargs --program-transform-name='${gcc_transform_name}'"
3259 if test "$silent" = yes; then
3260   baseargs="$baseargs --silent"
3261   tbaseargs="$tbaseargs --silent"
3262 fi
3263 baseargs="$baseargs --disable-option-checking"
3264 tbaseargs="$tbaseargs --disable-option-checking"
3265
3266 # Record and document user additions to sub configure arguments.
3267 AC_ARG_VAR([build_configargs],
3268            [additional configure arguments for build directories])
3269 AC_ARG_VAR([host_configargs],
3270            [additional configure arguments for host directories])
3271 AC_ARG_VAR([target_configargs],
3272            [additional configure arguments for target directories])
3273
3274 # For the build-side libraries, we just need to pretend we're native,
3275 # and not use the same cache file.  Multilibs are neither needed nor
3276 # desired.  We can't even use the same cache file for all build-side
3277 # libraries, as they're compiled differently; some with C, some with
3278 # C++ or with different feature-enabling options.
3279 build_configargs="$build_configargs --cache-file=./config.cache ${baseargs}"
3280
3281 # For host modules, accept cache file option, or specification as blank.
3282 case "${cache_file}" in
3283 "") # empty
3284   cache_file_option="" ;;
3285 /* | [[A-Za-z]]:[[\\/]]* ) # absolute path
3286   cache_file_option="--cache-file=${cache_file}" ;;
3287 *) # relative path
3288   cache_file_option="--cache-file=../${cache_file}" ;;
3289 esac
3290
3291 # Host dirs don't like to share a cache file either, horribly enough.
3292 # This seems to be due to autoconf 2.5x stupidity.
3293 host_configargs="$host_configargs --cache-file=./config.cache ${extra_host_args} ${baseargs}"
3294
3295 target_configargs="$target_configargs ${tbaseargs}"
3296
3297 # Passing a --with-cross-host argument lets the target libraries know
3298 # whether they are being built with a cross-compiler or being built
3299 # native.  However, it would be better to use other mechanisms to make the
3300 # sorts of decisions they want to make on this basis.  Please consider
3301 # this option to be deprecated.  FIXME.
3302 if test x${is_cross_compiler} = xyes ; then
3303   target_configargs="--with-cross-host=${host_noncanonical} ${target_configargs}"
3304 fi
3305
3306 # Special user-friendly check for native x86_64-linux build, if
3307 # multilib is not explicitly enabled.
3308 case "$target:$have_compiler:$host:$target:$enable_multilib" in
3309   x86_64-*linux*:yes:$build:$build:)
3310     # Make sure we have a development environment that handles 32-bit
3311     dev64=no
3312     echo "int main () { return 0; }" > conftest.c
3313     ${CC} -m32 -o conftest ${CFLAGS} ${CPPFLAGS} ${LDFLAGS} conftest.c
3314     if test $? = 0 ; then
3315       if test -s conftest || test -s conftest.exe ; then
3316         dev64=yes
3317       fi
3318     fi
3319     rm -f conftest*
3320     if test x${dev64} != xyes ; then
3321       AC_MSG_ERROR([I suspect your system does not have 32-bit development libraries (libc and headers). If you have them, rerun configure with --enable-multilib. If you do not have them, and want to build a 64-bit-only compiler, rerun configure with --disable-multilib.])
3322     fi
3323     ;;
3324 esac
3325
3326 # Default to --enable-multilib.
3327 if test x${enable_multilib} = x ; then
3328   target_configargs="--enable-multilib ${target_configargs}"
3329 fi
3330
3331 # Pass --with-newlib if appropriate.  Note that target_configdirs has
3332 # changed from the earlier setting of with_newlib.
3333 if test x${with_newlib} != xno && echo " ${target_configdirs} " | grep " newlib " > /dev/null 2>&1 && test -d ${srcdir}/newlib ; then
3334   target_configargs="--with-newlib ${target_configargs}"
3335 fi
3336
3337 # Different target subdirs use different values of certain variables
3338 # (notably CXX).  Worse, multilibs use *lots* of different values.
3339 # Worse yet, autoconf 2.5x makes some of these 'precious', meaning that
3340 # it doesn't automatically accept command-line overrides of them.
3341 # This means it's not safe for target subdirs to share a cache file,
3342 # which is disgusting, but there you have it.  Hopefully this can be
3343 # fixed in future.  It's still worthwhile to use a cache file for each
3344 # directory.  I think.
3345
3346 # Pass the appropriate --build, --host, --target and --cache-file arguments.
3347 # We need to pass --target, as newer autoconf's requires consistency
3348 # for target_alias and gcc doesn't manage it consistently.
3349 target_configargs="--cache-file=./config.cache ${target_configargs}"
3350
3351 FLAGS_FOR_TARGET=
3352 case " $target_configdirs " in
3353  *" newlib "*)
3354   case " $target_configargs " in
3355   *" --with-newlib "*)
3356    case "$target" in
3357     *-cygwin*)
3358       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/cygwin -isystem $$s/winsup/cygwin/include'
3359       ;;
3360    esac
3361
3362    # If we're not building GCC, don't discard standard headers.
3363    if test -d ${srcdir}/gcc; then
3364      FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -nostdinc'
3365
3366      if test "${build}" != "${host}"; then
3367        # On Canadian crosses, CC_FOR_TARGET will have already been set
3368        # by `configure', so we won't have an opportunity to add -Bgcc/
3369        # to it.  This is right: we don't want to search that directory
3370        # for binaries, but we want the header files in there, so add
3371        # them explicitly.
3372        FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -isystem $$r/$(HOST_SUBDIR)/gcc/include -isystem $$r/$(HOST_SUBDIR)/gcc/include-fixed'
3373
3374        # Someone might think of using the pre-installed headers on
3375        # Canadian crosses, in case the installed compiler is not fully
3376        # compatible with the compiler being built.  In this case, it
3377        # would be better to flag an error than risking having
3378        # incompatible object files being constructed.  We can't
3379        # guarantee that an error will be flagged, but let's hope the
3380        # compiler will do it, when presented with incompatible header
3381        # files.
3382      fi
3383    fi
3384
3385    case "${target}-${is_cross_compiler}" in
3386    i[[3456789]]86-*-linux*-no)
3387       # Here host == target, so we don't need to build gcc,
3388       # so we don't want to discard standard headers.
3389       FLAGS_FOR_TARGET=`echo " $FLAGS_FOR_TARGET " | sed -e 's/ -nostdinc / /'`
3390       ;;
3391    *)
3392       # If we're building newlib, use its generic headers last, but search
3393       # for any libc-related directories first (so make it the last -B
3394       # switch).
3395       FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/newlib/ -isystem $$r/$(TARGET_SUBDIR)/newlib/targ-include -isystem $$s/newlib/libc/include'
3396
3397       # If we're building libgloss, find the startup file, simulator library
3398       # and linker script.
3399       case " $target_configdirs " in
3400         *" libgloss "*)
3401         # Look for startup file, simulator library and maybe linker script.
3402         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$$r/$(TARGET_SUBDIR)/libgloss/'"$libgloss_dir"
3403         # Look for libnosys.a in case the target needs it.
3404         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/libgloss/libnosys'
3405         # Most targets have the linker script in the source directory.
3406         FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$s/libgloss/'"$libgloss_dir"
3407         ;;
3408       esac
3409       ;;
3410    esac
3411    ;;
3412   esac
3413   ;;
3414 esac
3415
3416 case "$target" in
3417   x86_64-*mingw* | *-w64-mingw*)
3418   # MinGW-w64 does not use newlib, nor does it use winsup. It may,
3419   # however, use a symlink named 'mingw' in ${prefix} .
3420     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L${prefix}/${target}/lib -L${prefix}/mingw/lib -isystem ${prefix}/${target}/include -isystem ${prefix}/mingw/include'
3421     ;;
3422   *-mingw*)
3423   # MinGW can't be handled as Cygwin above since it does not use newlib.
3424     FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(TARGET_SUBDIR)/winsup/mingw -L$$r/$(TARGET_SUBDIR)/winsup/w32api/lib -isystem $$s/winsup/mingw/include -isystem $$s/winsup/w32api/include'
3425     ;;
3426 esac
3427
3428 # Allow the user to override the flags for
3429 # our build compiler if desired.
3430 if test x"${build}" = x"${host}" ; then
3431   CFLAGS_FOR_BUILD=${CFLAGS_FOR_BUILD-${CFLAGS}}
3432   CPPFLAGS_FOR_BUILD=${CPPFLAGS_FOR_BUILD-${CPPFLAGS}}
3433   CXXFLAGS_FOR_BUILD=${CXXFLAGS_FOR_BUILD-${CXXFLAGS}}
3434   LDFLAGS_FOR_BUILD=${LDFLAGS_FOR_BUILD-${LDFLAGS}}
3435 fi
3436
3437 # On Canadian crosses, we'll be searching the right directories for
3438 # the previously-installed cross compiler, so don't bother to add
3439 # flags for directories within the install tree of the compiler
3440 # being built; programs in there won't even run.
3441 if test "${build}" = "${host}" && test -d ${srcdir}/gcc; then
3442   # Search for pre-installed headers if nothing else fits.
3443   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -B$(build_tooldir)/bin/ -B$(build_tooldir)/lib/ -isystem $(build_tooldir)/include -isystem $(build_tooldir)/sys-include'
3444 fi
3445
3446 if test "x${use_gnu_ld}" = x &&
3447    echo " ${configdirs} " | grep " ld " > /dev/null ; then
3448   # Arrange for us to find uninstalled linker scripts.
3449   FLAGS_FOR_TARGET=$FLAGS_FOR_TARGET' -L$$r/$(HOST_SUBDIR)/ld'
3450 fi
3451
3452 # Search for other target-specific linker scripts and such.
3453 case "${target}" in
3454   mep*)
3455     FLAGS_FOR_TARGET="$FLAGS_FOR_TARGET -mlibrary"
3456     ;;
3457 esac
3458
3459 # Makefile fragments.
3460 for frag in host_makefile_frag target_makefile_frag alphaieee_frag ospace_frag;
3461 do
3462   eval fragval=\$$frag
3463   if test $fragval != /dev/null; then
3464     eval $frag=${srcdir}/$fragval
3465   fi
3466 done
3467 AC_SUBST_FILE(host_makefile_frag)
3468 AC_SUBST_FILE(target_makefile_frag)
3469 AC_SUBST_FILE(alphaieee_frag)
3470 AC_SUBST_FILE(ospace_frag)
3471
3472 # Miscellanea: directories, flags, etc.
3473 AC_SUBST(RPATH_ENVVAR)
3474 AC_SUBST(GCC_SHLIB_SUBDIR)
3475 AC_SUBST(tooldir)
3476 AC_SUBST(build_tooldir)
3477 AC_SUBST(CONFIGURE_GDB_TK)
3478 AC_SUBST(GDB_TK)
3479 AC_SUBST(INSTALL_GDB_TK)
3480
3481 # Build module lists & subconfigure args.
3482 AC_SUBST(build_configargs)
3483 AC_SUBST(build_configdirs)
3484
3485 # Host module lists & subconfigure args.
3486 AC_SUBST(host_configargs)
3487 AC_SUBST(configdirs)
3488 AC_SUBST(target_configdirs)
3489
3490 # Target module lists & subconfigure args.
3491 AC_SUBST(target_configargs)
3492
3493
3494 # Build tools.
3495 AC_SUBST(AR_FOR_BUILD)
3496 AC_SUBST(AS_FOR_BUILD)
3497 AC_SUBST(CC_FOR_BUILD)
3498 AC_SUBST(CFLAGS_FOR_BUILD)
3499 AC_SUBST(CPP_FOR_BUILD)
3500 AC_SUBST(CPPFLAGS_FOR_BUILD)
3501 AC_SUBST(CXXFLAGS_FOR_BUILD)
3502 AC_SUBST(CXX_FOR_BUILD)
3503 AC_SUBST(DLLTOOL_FOR_BUILD)
3504 AC_SUBST(DSYMUTIL_FOR_BUILD)
3505 AC_SUBST(GFORTRAN_FOR_BUILD)
3506 AC_SUBST(GOC_FOR_BUILD)
3507 AC_SUBST(GDC_FOR_BUILD)
3508 AC_SUBST(LDFLAGS_FOR_BUILD)
3509 AC_SUBST(LD_FOR_BUILD)
3510 AC_SUBST(NM_FOR_BUILD)
3511 AC_SUBST(RANLIB_FOR_BUILD)
3512 AC_SUBST(WINDMC_FOR_BUILD)
3513 AC_SUBST(WINDRES_FOR_BUILD)
3514
3515 # Generate default definitions for YACC, M4, LEX and other programs that run
3516 # on the build machine.  These are used if the Makefile can't locate these
3517 # programs in objdir.
3518 MISSING=`cd $ac_aux_dir && ${PWDCMD-pwd}`/missing
3519
3520 AC_CHECK_PROGS([YACC], ['bison -y' byacc yacc], [$MISSING bison -y])
3521 case " $build_configdirs " in
3522   *" bison "*) YACC='$$r/$(BUILD_SUBDIR)/bison/tests/bison -y' ;;
3523 esac
3524
3525 AC_CHECK_PROGS([BISON], [bison], [$MISSING bison])
3526 case " $build_configdirs " in
3527   *" bison "*) BISON='$$r/$(BUILD_SUBDIR)/bison/tests/bison' ;;
3528 esac
3529
3530 AC_CHECK_PROGS([M4], [gm4 gnum4 m4], [$MISSING m4])
3531 case " $build_configdirs " in
3532   *" m4 "*) M4='$$r/$(BUILD_SUBDIR)/m4/m4' ;;
3533 esac
3534
3535 AC_CHECK_PROGS([LEX], [flex lex], [$MISSING flex])
3536 case " $build_configdirs " in
3537   *" flex "*) LEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3538   *" lex "*) LEX='$$r/$(BUILD_SUBDIR)/lex/lex' ;;
3539 esac
3540
3541 AC_CHECK_PROGS([FLEX], [flex], [$MISSING flex])
3542 case " $build_configdirs " in
3543   *" flex "*) FLEX='$$r/$(BUILD_SUBDIR)/flex/flex' ;;
3544 esac
3545
3546 AC_CHECK_PROGS([MAKEINFO], makeinfo, [$MISSING makeinfo])
3547 case " $build_configdirs " in
3548   *" texinfo "*) MAKEINFO='$$r/$(BUILD_SUBDIR)/texinfo/makeinfo/makeinfo' ;;
3549   *)
3550 changequote(,)
3551     # For an installed makeinfo, we require it to be from texinfo 4.7 or
3552     # higher, else we use the "missing" dummy.
3553     if ${MAKEINFO} --version \
3554        | egrep 'texinfo[^0-9]*(4\.([7-9]|[1-9][0-9])|[5-9]|[1-9][0-9])' >/dev/null 2>&1; then
3555       :
3556     else
3557       MAKEINFO="$MISSING makeinfo"
3558     fi
3559     ;;
3560 changequote([,])
3561 esac
3562
3563 # FIXME: expect and dejagnu may become build tools?
3564
3565 AC_CHECK_PROGS(EXPECT, expect, expect)
3566 case " $configdirs " in
3567   *" expect "*)
3568     test $host = $build && EXPECT='$$r/$(HOST_SUBDIR)/expect/expect'
3569     ;;
3570 esac
3571
3572 AC_CHECK_PROGS(RUNTEST, runtest, runtest)
3573 case " $configdirs " in
3574   *" dejagnu "*)
3575     test $host = $build && RUNTEST='$$s/$(HOST_SUBDIR)/dejagnu/runtest'
3576     ;;
3577 esac
3578
3579
3580 # Host tools.
3581 NCN_STRICT_CHECK_TOOLS(AR, ar)
3582 NCN_STRICT_CHECK_TOOLS(AS, as)
3583 NCN_STRICT_CHECK_TOOLS(DLLTOOL, dlltool)
3584 NCN_STRICT_CHECK_TOOLS(DSYMUTIL, dsymutil)
3585 NCN_STRICT_CHECK_TOOLS(LD, ld)
3586 NCN_STRICT_CHECK_TOOLS(LIPO, lipo)
3587 NCN_STRICT_CHECK_TOOLS(NM, nm)
3588 NCN_STRICT_CHECK_TOOLS(RANLIB, ranlib, true)
3589 NCN_STRICT_CHECK_TOOLS(STRIP, strip, true)
3590 NCN_STRICT_CHECK_TOOLS(WINDRES, windres)
3591 NCN_STRICT_CHECK_TOOLS(WINDMC, windmc)
3592 NCN_STRICT_CHECK_TOOLS(OBJCOPY, objcopy)
3593 NCN_STRICT_CHECK_TOOLS(OBJDUMP, objdump)
3594 NCN_STRICT_CHECK_TOOLS(OTOOL, otool)
3595 NCN_STRICT_CHECK_TOOLS(READELF, readelf)
3596 AC_SUBST(CC)
3597 AC_SUBST(CXX)
3598 AC_SUBST(CFLAGS)
3599 AC_SUBST(CXXFLAGS)
3600 AC_SUBST(GDC)
3601 AC_SUBST(GDCFLAGS)
3602
3603 # Target tools.
3604 AC_ARG_WITH([build-time-tools],
3605   [AS_HELP_STRING([--with-build-time-tools=PATH],
3606                   [use given path to find target tools during the build])],
3607   [case x"$withval" in
3608      x/*) ;;
3609      *)
3610        with_build_time_tools=
3611        AC_MSG_WARN([argument to --with-build-time-tools must be an absolute path])
3612        ;;
3613    esac],
3614   [with_build_time_tools=])
3615
3616 NCN_STRICT_CHECK_TARGET_TOOLS(CC_FOR_TARGET, cc gcc)
3617 NCN_STRICT_CHECK_TARGET_TOOLS(CXX_FOR_TARGET, c++ g++ cxx gxx)
3618 NCN_STRICT_CHECK_TARGET_TOOLS(GCC_FOR_TARGET, gcc, ${CC_FOR_TARGET})
3619 NCN_STRICT_CHECK_TARGET_TOOLS(GFORTRAN_FOR_TARGET, gfortran)
3620 NCN_STRICT_CHECK_TARGET_TOOLS(GOC_FOR_TARGET, gccgo)
3621 NCN_STRICT_CHECK_TARGET_TOOLS(GDC_FOR_TARGET, gdc)
3622
3623 ACX_CHECK_INSTALLED_TARGET_TOOL(AR_FOR_TARGET, ar)
3624 ACX_CHECK_INSTALLED_TARGET_TOOL(AS_FOR_TARGET, as)
3625 ACX_CHECK_INSTALLED_TARGET_TOOL(DLLTOOL_FOR_TARGET, dlltool)
3626 ACX_CHECK_INSTALLED_TARGET_TOOL(DSYMUTIL_FOR_TARGET, dsymutil)
3627 ACX_CHECK_INSTALLED_TARGET_TOOL(LD_FOR_TARGET, ld)
3628 ACX_CHECK_INSTALLED_TARGET_TOOL(LIPO_FOR_TARGET, lipo)
3629 ACX_CHECK_INSTALLED_TARGET_TOOL(NM_FOR_TARGET, nm)
3630 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJCOPY_FOR_TARGET, objcopy)
3631 ACX_CHECK_INSTALLED_TARGET_TOOL(OBJDUMP_FOR_TARGET, objdump)
3632 ACX_CHECK_INSTALLED_TARGET_TOOL(OTOOL_FOR_TARGET, otool)
3633 ACX_CHECK_INSTALLED_TARGET_TOOL(RANLIB_FOR_TARGET, ranlib)
3634 ACX_CHECK_INSTALLED_TARGET_TOOL(READELF_FOR_TARGET, readelf)
3635 ACX_CHECK_INSTALLED_TARGET_TOOL(STRIP_FOR_TARGET, strip)
3636 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDRES_FOR_TARGET, windres)
3637 ACX_CHECK_INSTALLED_TARGET_TOOL(WINDMC_FOR_TARGET, windmc)
3638
3639 RAW_CXX_FOR_TARGET="$CXX_FOR_TARGET"
3640
3641 GCC_TARGET_TOOL(ar, AR_FOR_TARGET, AR, [binutils/ar])
3642 GCC_TARGET_TOOL(as, AS_FOR_TARGET, AS, [gas/as-new])
3643 GCC_TARGET_TOOL(cc, CC_FOR_TARGET, CC, [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3644 dnl see comments for CXX_FOR_TARGET_FLAG_TO_PASS
3645 GCC_TARGET_TOOL(c++, CXX_FOR_TARGET, CXX,
3646                 [gcc/xg++ -B$$r/$(HOST_SUBDIR)/gcc/ -nostdinc++ `if test -f $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags; then $(SHELL) $$r/$(TARGET_SUBDIR)/libstdc++-v3/scripts/testsuite_flags --build-includes; else echo -funconfigured-libstdc++-v3 ; fi` -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3647                 c++)
3648 GCC_TARGET_TOOL(c++ for libstdc++, RAW_CXX_FOR_TARGET, CXX,
3649                 [gcc/xgcc -shared-libgcc -B$$r/$(HOST_SUBDIR)/gcc -nostdinc++ -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/src/.libs -L$$r/$(TARGET_SUBDIR)/libstdc++-v3/libsupc++/.libs],
3650                 c++)
3651 GCC_TARGET_TOOL(dlltool, DLLTOOL_FOR_TARGET, DLLTOOL, [binutils/dlltool])
3652 GCC_TARGET_TOOL(dsymutil, DSYMUTIL_FOR_TARGET, DSYMUTIL)
3653 GCC_TARGET_TOOL(gcc, GCC_FOR_TARGET, , [gcc/xgcc -B$$r/$(HOST_SUBDIR)/gcc/])
3654 GCC_TARGET_TOOL(gfortran, GFORTRAN_FOR_TARGET, GFORTRAN,
3655                 [gcc/gfortran -B$$r/$(HOST_SUBDIR)/gcc/], fortran)
3656 GCC_TARGET_TOOL(gccgo, GOC_FOR_TARGET, GOC,
3657                 [gcc/gccgo -B$$r/$(HOST_SUBDIR)/gcc/], go)
3658 GCC_TARGET_TOOL(gdc, GDC_FOR_TARGET, GDC,
3659                 [gcc/gdc -B$$r/$(HOST_SUBDIR)/gcc/], d)
3660 GCC_TARGET_TOOL(ld, LD_FOR_TARGET, LD, [ld/ld-new])
3661 GCC_TARGET_TOOL(lipo, LIPO_FOR_TARGET, LIPO)
3662 GCC_TARGET_TOOL(nm, NM_FOR_TARGET, NM, [binutils/nm-new])
3663 GCC_TARGET_TOOL(objcopy, OBJCOPY_FOR_TARGET, OBJCOPY, [binutils/objcopy])
3664 GCC_TARGET_TOOL(objdump, OBJDUMP_FOR_TARGET, OBJDUMP, [binutils/objdump])
3665 GCC_TARGET_TOOL(otool, OTOOL_FOR_TARGET, OTOOL)
3666 GCC_TARGET_TOOL(ranlib, RANLIB_FOR_TARGET, RANLIB, [binutils/ranlib])
3667 GCC_TARGET_TOOL(readelf, READELF_FOR_TARGET, READELF, [binutils/readelf])
3668 GCC_TARGET_TOOL(strip, STRIP_FOR_TARGET, STRIP, [binutils/strip-new])
3669 GCC_TARGET_TOOL(windres, WINDRES_FOR_TARGET, WINDRES, [binutils/windres])
3670 GCC_TARGET_TOOL(windmc, WINDMC_FOR_TARGET, WINDMC, [binutils/windmc])
3671
3672 AC_SUBST(FLAGS_FOR_TARGET)
3673 AC_SUBST(RAW_CXX_FOR_TARGET)
3674
3675 # Certain tools may need extra flags.
3676 AR_FOR_TARGET=${AR_FOR_TARGET}${extra_arflags_for_target}
3677 RANLIB_FOR_TARGET=${RANLIB_FOR_TARGET}${extra_ranlibflags_for_target}
3678 NM_FOR_TARGET=${NM_FOR_TARGET}${extra_nmflags_for_target}
3679
3680 # When building target libraries, except in a Canadian cross, we use
3681 # the same toolchain as the compiler we just built.
3682 COMPILER_AS_FOR_TARGET='$(AS_FOR_TARGET)'
3683 COMPILER_LD_FOR_TARGET='$(LD_FOR_TARGET)'
3684 COMPILER_NM_FOR_TARGET='$(NM_FOR_TARGET)'
3685 if test $host = $build; then
3686   case " $configdirs " in
3687     *" gcc "*)
3688       COMPILER_AS_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/as'
3689       COMPILER_LD_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/collect-ld'
3690       COMPILER_NM_FOR_TARGET='$$r/$(HOST_SUBDIR)/gcc/nm'${extra_nmflags_for_target}
3691       ;;
3692   esac
3693 fi
3694
3695 AC_SUBST(COMPILER_AS_FOR_TARGET)
3696 AC_SUBST(COMPILER_LD_FOR_TARGET)
3697 AC_SUBST(COMPILER_NM_FOR_TARGET)
3698
3699 AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
3700 AC_ARG_ENABLE(maintainer-mode,
3701 [AS_HELP_STRING([--enable-maintainer-mode],
3702                 [enable make rules and dependencies not useful
3703                  (and sometimes confusing) to the casual installer])],
3704       USE_MAINTAINER_MODE=$enableval,
3705       USE_MAINTAINER_MODE=no)
3706 AC_MSG_RESULT($USE_MAINTAINER_MODE)
3707 AC_SUBST(MAINTAINER_MODE_TRUE)
3708 AC_SUBST(MAINTAINER_MODE_FALSE)
3709 if test "$USE_MAINTAINER_MODE" = yes; then
3710   MAINTAINER_MODE_TRUE=
3711   MAINTAINER_MODE_FALSE='#'
3712 else
3713   MAINTAINER_MODE_TRUE='#'
3714   MAINTAINER_MODE_FALSE=
3715 fi
3716 MAINT=$MAINTAINER_MODE_TRUE
3717 AC_SUBST(MAINT)dnl
3718
3719 # ---------------------
3720 # GCC bootstrap support
3721 # ---------------------
3722
3723 # Stage specific cflags for build.
3724 stage1_cflags="-g"
3725 case $build in
3726   vax-*-*)
3727     case ${GCC} in
3728       yes) stage1_cflags="-g -Wa,-J" ;;
3729       *) stage1_cflags="-g -J" ;;
3730     esac ;;
3731 esac
3732
3733 AC_SUBST(stage1_cflags)
3734
3735 # Enable --enable-checking in stage1 of the compiler.
3736 AC_ARG_ENABLE(stage1-checking,
3737 [AS_HELP_STRING([[--enable-stage1-checking[=all]]],
3738                 [choose additional checking for stage1 of the compiler])],
3739 [stage1_checking=--enable-checking=${enable_stage1_checking}],
3740 [if test "x$enable_checking" = xno || test "x$enable_checking" = x; then
3741   # For --disable-checking or implicit --enable-checking=release, avoid
3742   # setting --enable-checking=gc in the default stage1 checking for LTO
3743   # bootstraps.  See PR62077.
3744   case $BUILD_CONFIG in
3745     *lto*)
3746       stage1_checking=--enable-checking=release,misc,gimple,rtlflag,tree,types;;
3747     *)
3748       stage1_checking=--enable-checking=yes,types;;
3749   esac
3750   if test "x$enable_checking" = x && \
3751      test -d ${srcdir}/gcc && \
3752      test x"`cat ${srcdir}/gcc/DEV-PHASE`" = xexperimental; then
3753     stage1_checking=--enable-checking=yes,types,extra
3754   fi
3755 else
3756   stage1_checking=--enable-checking=$enable_checking,types
3757 fi])
3758 AC_SUBST(stage1_checking)
3759
3760 # Enable -Werror in bootstrap stage2 and later.
3761 AC_ARG_ENABLE(werror,
3762 [AS_HELP_STRING([--enable-werror],
3763                 [enable -Werror in bootstrap stage2 and later])],
3764 [
3765 case ${enable_werror} in
3766   yes) stage2_werror_flag="--enable-werror-always" ;;
3767   *) stage2_werror_flag="" ;;
3768 esac
3769 ],
3770 [
3771 if test -d ${srcdir}/gcc && test x"`cat $srcdir/gcc/DEV-PHASE`" = xexperimental; then
3772   case $BUILD_CONFIG in
3773   bootstrap-debug)
3774       stage2_werror_flag="--enable-werror-always" ;;
3775   "")
3776       stage2_werror_flag="--enable-werror-always" ;;
3777   esac
3778 fi
3779 ])
3780
3781 AC_SUBST(stage2_werror_flag)
3782
3783 # Specify what files to not compare during bootstrap.
3784
3785 compare_exclusions="gcc/cc*-checksum\$(objext) | gcc/ada/*tools/*"
3786 case "$target" in
3787   hppa*64*-*-hpux*) ;;
3788   hppa*-*-hpux*) compare_exclusions="$compare_exclusions | */libgcc/lib2funcs* | gcc/function-tests.o" ;;
3789   powerpc*-ibm-aix*) compare_exclusions="$compare_exclusions | *libgomp*\$(objext)" ;;
3790 esac
3791 AC_SUBST(compare_exclusions)
3792
3793 AC_CONFIG_FILES([Makefile],
3794   [sed "$extrasub_build" Makefile |
3795    sed "$extrasub_host" |
3796    sed "$extrasub_target" > mf$$
3797    mv -f mf$$ Makefile],
3798   [extrasub_build="$extrasub_build"
3799    extrasub_host="$extrasub_host"
3800    extrasub_target="$extrasub_target"])
3801 AC_OUTPUT