gotools/configure.ac

   1 # Configure script for gotools.
   2 #   Copyright (C) 2015-2016 Free Software Foundation, Inc.
   3 #
   4 # This file is free software; you can redistribute it and/or modify it
   5 # under the terms of the GNU General Public License as published by
   6 # the Free Software Foundation; either version 3 of the License, or
   7 # (at your option) any later version.
   8 #
   9 # This program is distributed in the hope that it will be useful, but
  10 # WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License
  15 # along with this program; see the file COPYING3.  If not see
  16 # <http://www.gnu.org/licenses/>.
  17
  18 AC_INIT(package-unused, version-unused,, gotools)
  19 AC_CONFIG_SRCDIR(Makefile.am)
  20
  21 # Determine the noncanonical names used for directories.
  22 ACX_NONCANONICAL_BUILD
  23 ACX_NONCANONICAL_HOST
  24 ACX_NONCANONICAL_TARGET
  25
  26 dnl Autoconf 2.5x and later will set a default program prefix if
  27 dnl --target was used, even if it was the same as --host.  Disable
  28 dnl that behavior.  This must be done before AC_CANONICAL_SYSTEM
  29 dnl to take effect.
  30 test "$host_noncanonical" = "$target_noncanonical" &&
  31   test "$program_prefix$program_suffix$program_transform_name" = \
  32     NONENONEs,x,x, &&
  33   program_transform_name=s,y,y,
  34
  35 AC_CANONICAL_SYSTEM
  36 AC_ARG_PROGRAM
  37
  38 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dist -Wall -Wno-portability])
  39 AM_MAINTAINER_MODE
  40
  41 AC_PROG_INSTALL
  42
  43 AC_PROG_CC
  44 AC_PROG_GO
  45
  46 # These should be defined by the top-level configure.
  47 # Copy them into Makefile.
  48 AC_SUBST(GOC_FOR_TARGET)
  49 AC_SUBST(GCC_FOR_TARGET)
  50
  51 AM_CONDITIONAL(NATIVE, test "$host_alias" = "$target_alias")
  52
  53 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
  54 AC_CACHE_CHECK([for socket libraries], gotools_cv_lib_sockets,
  55   [gotools_cv_lib_sockets=
  56    gotools_check_both=no
  57    AC_CHECK_FUNC(connect, gotools_check_socket=no, gotools_check_socket=yes)
  58    if test "$gotools_check_socket" = "yes"; then
  59      unset ac_cv_func_connect
  60      AC_CHECK_LIB(socket, main, gotools_cv_lib_sockets="-lsocket",
  61                   gotools_check_both=yes)
  62    fi
  63    if test "$gotools_check_both" = "yes"; then
  64      gotools_old_libs=$LIBS
  65      LIBS="$LIBS -lsocket -lnsl"
  66      unset ac_cv_func_accept
  67      AC_CHECK_FUNC(accept,
  68                    [gotools_check_nsl=no
  69                     gotools_cv_lib_sockets="-lsocket -lnsl"])
  70      unset ac_cv_func_accept
  71      LIBS=$gotools_old_libs
  72    fi
  73    unset ac_cv_func_gethostbyname
  74    gotools_old_libs="$LIBS"
  75    AC_CHECK_FUNC(gethostbyname, ,
  76                  [AC_CHECK_LIB(nsl, main,
  77                         [gotools_cv_lib_sockets="$gotools_cv_lib_sockets -lnsl"])])
  78    unset ac_cv_func_gethostbyname
  79    LIBS=$gotools_old_libs
  80 ])
  81 NET_LIBS="$gotools_cv_lib_sockets"
  82 AC_SUBST(NET_LIBS)
  83
  84 dnl Test if -lrt is required for sched_yield and/or nanosleep.
  85 AC_SEARCH_LIBS([sched_yield], [rt])
  86 AC_SEARCH_LIBS([nanosleep], [rt])
  87
  88 AC_CONFIG_FILES(Makefile)
  89
  90 AC_OUTPUT