libgo/configure.ac

   1 # configure.ac -- Go library configure script.
   2
   3 # Copyright 2009 The Go Authors. All rights reserved.
   4 # Use of this source code is governed by a BSD-style
   5 # license that can be found in the LICENSE file.
   6
   7 # Process this file with autoreconf to produce configure.
   8
   9 AC_PREREQ(2.64)
  10 AC_INIT(package-unused, version-unused,, libgo)
  11 AC_CONFIG_SRCDIR(Makefile.am)
  12 AC_CONFIG_HEADER(config.h)
  13
  14 libtool_VERSION=10:0:0
  15 AC_SUBST(libtool_VERSION)
  16
  17 AM_ENABLE_MULTILIB(, ..)
  18
  19 AC_CANONICAL_SYSTEM
  20 target_alias=${target_alias-$host_alias}
  21
  22 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dist -Wall -Wno-portability])
  23 AH_TEMPLATE(PACKAGE, [Name of package])
  24 AH_TEMPLATE(VERSION, [Version number of package])
  25
  26 m4_rename([_AC_ARG_VAR_PRECIOUS],[glibgo_PRECIOUS])
  27 m4_define([_AC_ARG_VAR_PRECIOUS],[])
  28 AC_PROG_CC
  29 AC_PROG_GO
  30 m4_rename_force([glibgo_PRECIOUS],[_AC_ARG_VAR_PRECIOUS])
  31
  32 AC_SUBST(CFLAGS)
  33
  34 AM_MAINTAINER_MODE
  35
  36 AC_PROG_LD
  37 AC_PROG_RANLIB
  38 AC_CHECK_TOOL(OBJCOPY, objcopy, missing-objcopy)
  39
  40 AC_LIBTOOL_DLOPEN
  41 AM_PROG_LIBTOOL
  42 AC_SUBST(enable_shared)
  43 AC_SUBST(enable_static)
  44
  45 CC_FOR_BUILD=${CC_FOR_BUILD:-gcc}
  46 AC_SUBST(CC_FOR_BUILD)
  47
  48 AC_PROG_AWK
  49
  50 WARN_FLAGS='-Wall -Wextra -Wwrite-strings -Wcast-qual'
  51 AC_SUBST(WARN_FLAGS)
  52
  53 AC_ARG_ENABLE(werror, [AS_HELP_STRING([--enable-werror],
  54                                       [turns on -Werror @<:@default=yes@:>@])])
  55 if test "x$enable_werror" != "xno"; then
  56   WERROR="-Werror"
  57 fi
  58 AC_SUBST(WERROR)
  59
  60 glibgo_toolexecdir=no
  61 glibgo_toolexeclibdir=no
  62
  63 AC_MSG_CHECKING([for --enable-version-specific-runtime-libs])
  64 AC_ARG_ENABLE([version-specific-runtime-libs],
  65   AC_HELP_STRING([--enable-version-specific-runtime-libs],
  66                  [Specify that runtime libraries should be installed in a compiler-specific directory]),
  67   [case "$enableval" in
  68     yes) version_specific_libs=yes ;;
  69     no)  version_specific_libs=no ;;
  70     *)   AC_MSG_ERROR([Unknown argument to enable/disable version-specific libs]);;
  71    esac],
  72   [version_specific_libs=no])
  73 AC_MSG_RESULT($version_specific_libs)
  74
  75 # Version-specific runtime libs processing.
  76 if test $version_specific_libs = yes; then
  77   glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  78   glibgo_toolexeclibdir='${toolexecdir}/${gcc_version}$(MULTISUBDIR)'
  79 fi
  80
  81 # Calculate glibgo_toolexecdir, glibgo_toolexeclibdir
  82 # Install a library built with a cross compiler in tooldir, not libdir.
  83 if test -n "$with_cross_host" &&
  84    test x"$with_cross_host" != x"no"; then
  85   nover_glibgo_toolexecdir='${exec_prefix}/${host_alias}'
  86   nover_glibgo_toolexeclibdir='${toolexecdir}/lib'
  87 else
  88   nover_glibgo_toolexecdir='${libdir}/gcc/${host_alias}'
  89   nover_glibgo_toolexeclibdir='${libdir}'
  90 fi
  91 multi_os_directory=`$GOC -print-multi-os-directory`
  92 case $multi_os_directory in
  93   .) ;; # Avoid trailing /.
  94   *) nover_glibgo_toolexeclibdir=${nover_glibgo_toolexeclibdir}/${multi_os_directory} ;;
  95 esac
  96
  97 if test x"$glibgo_toolexecdir" = x"no"; then
  98   glibgo_toolexecdir="${nover_glibgo_toolexecdir}"
  99   glibgo_toolexeclibdir="${nover_glibgo_toolexeclibdir}"
 100 fi
 101
 102 AC_SUBST(glibgo_toolexecdir)
 103 AC_SUBST(glibgo_toolexeclibdir)
 104 AC_SUBST(nover_glibgo_toolexeclibdir)
 105
 106 # See if the user wants to configure without libffi.  Some
 107 # architectures don't support it.  FIXME: We should set a default
 108 # based on the host.
 109 AC_ARG_WITH(libffi,
 110   AS_HELP_STRING([--without-libffi],
 111                  [don't use libffi]),
 112   [:],
 113   [with_libffi=${with_libffi_default-yes}])
 114
 115 LIBFFI=
 116 LIBFFIINCS=
 117 if test "$with_libffi" != no; then
 118    AC_DEFINE(USE_LIBFFI, 1, [Define if we're to use libffi.])
 119    LIBFFI=../libffi/libffi_convenience.la
 120    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I../libffi/include'
 121 fi
 122 AC_SUBST(LIBFFI)
 123 AC_SUBST(LIBFFIINCS)
 124
 125 # See if the user wants to configure without libatomic. This is useful if we are
 126 # on an architecture for which libgo does not need an atomic support library and
 127 # libatomic does not support our C compiler.
 128 AC_ARG_WITH(libatomic,
 129   AS_HELP_STRING([--without-libatomic],
 130                  [don't use libatomic]),
 131   [:],
 132   [with_libatomic=${with_libatomic_default-yes}])
 133
 134 LIBATOMIC=
 135 if test "$with_libatomic" != no; then
 136    LIBATOMIC=../libatomic/libatomic_convenience.la
 137 fi
 138 AC_SUBST(LIBATOMIC)
 139
 140 # Used to tell GNU make to include a file without telling automake to
 141 # include it.
 142 go_include="-include"
 143 AC_SUBST(go_include)
 144
 145 # All known GOOS values.  This is the union of all operating systems
 146 # supported by the gofrontend and all operating systems supported by
 147 # the gc toolchain.
 148 ALLGOOS="android darwin dragonfly freebsd irix linux netbsd openbsd plan9 rtems solaris windows"
 149
 150 is_darwin=no
 151 is_freebsd=no
 152 is_irix=no
 153 is_linux=no
 154 is_netbsd=no
 155 is_openbsd=no
 156 is_dragonfly=no
 157 is_rtems=no
 158 is_solaris=no
 159 GOOS=unknown
 160 case ${host} in
 161   *-*-darwin*)   is_darwin=yes;  GOOS=darwin ;;
 162   *-*-freebsd*)  is_freebsd=yes; GOOS=freebsd ;;
 163   *-*-irix6*)    is_irix=yes;    GOOS=irix ;;
 164   *-*-linux*)    is_linux=yes;   GOOS=linux ;;
 165   *-*-netbsd*)   is_netbsd=yes;  GOOS=netbsd ;;
 166   *-*-openbsd*)  is_openbsd=yes; GOOS=openbsd ;;
 167   *-*-dragonfly*) is_dragonfly=yes; GOOS=dragonfly ;;
 168   *-*-rtems*)    is_rtems=yes;   GOOS=rtems ;;
 169   *-*-solaris2*) is_solaris=yes; GOOS=solaris ;;
 170 esac
 171 AM_CONDITIONAL(LIBGO_IS_DARWIN, test $is_darwin = yes)
 172 AM_CONDITIONAL(LIBGO_IS_FREEBSD, test $is_freebsd = yes)
 173 AM_CONDITIONAL(LIBGO_IS_IRIX, test $is_irix = yes)
 174 AM_CONDITIONAL(LIBGO_IS_LINUX, test $is_linux = yes)
 175 AM_CONDITIONAL(LIBGO_IS_NETBSD, test $is_netbsd = yes)
 176 AM_CONDITIONAL(LIBGO_IS_OPENBSD, test $is_openbsd = yes)
 177 AM_CONDITIONAL(LIBGO_IS_DRAGONFLY, test $is_dragonfly = yes)
 178 AM_CONDITIONAL(LIBGO_IS_RTEMS, test $is_rtems = yes)
 179 AM_CONDITIONAL(LIBGO_IS_SOLARIS, test $is_solaris = yes)
 180 AM_CONDITIONAL(LIBGO_IS_BSD, test $is_darwin = yes -o $is_dragonfly = yes -o $is_freebsd = yes -o $is_netbsd = yes -o $is_openbsd = yes)
 181 AC_SUBST(GOOS)
 182 AC_SUBST(ALLGOOS)
 183
 184 dnl Test whether we need to use DejaGNU or whether we can use the
 185 dnl simpler gotest approach.  We can only use gotest for a native
 186 dnl build.
 187 USE_DEJAGNU=no
 188 case ${host} in
 189   *-*-rtems*) USE_DEJAGNU=yes ;;
 190   ${build}) ;;
 191   *) USE_DEJAGNU=yes ;;
 192 esac
 193 AC_SUBST(USE_DEJAGNU)
 194
 195 # All known GOARCH values.  This is the union of all architectures
 196 # supported by the gofrontend and all architectures supported by the
 197 # gc toolchain.
 198 # N.B. Keep in sync with gcc/testsuite/go.test/go-test.exp (go-set-goarch).
 199 ALLGOARCH="386 alpha amd64 amd64p32 arm armbe arm64 arm64be ia64 m68k mipso32 mipsn32 mipso64 mipsn64 mips mipsle mips64 mips64le mips64p32 mips64pe32le ppc ppc64 ppc64le s390 s390x sparc sparc64"
 200
 201 # All known GOARCH_FAMILY values.
 202 ALLGOARCHFAMILY="I386 ALPHA AMD64 ARM ARM64 IA64 M68K MIPS MIPS64 PPC PPC64 S390 S390X SPARC SPARC64"
 203
 204 GOARCH=unknown
 205 GOARCH_FAMILY=unknown
 206 GOARCH_BIGENDIAN=0
 207 GOARCH_CACHELINESIZE=64
 208 GOARCH_PHYSPAGESIZE=4096
 209 GOARCH_PCQUANTUM=1
 210 GOARCH_INT64ALIGN=8
 211 GOARCH_HUGEPAGESIZE=0
 212 GOARCH_MINFRAMESIZE=0
 213 case ${host} in
 214   alpha*-*-*)
 215     GOARCH=alpha
 216     GOARCH_FAMILY=ALPHA
 217     GOARCH_PHYSPAGESIZE=8192
 218     GOARCH_PCQUANTUM=4
 219     ;;
 220   aarch64-*-*)
 221     GOARCH=arm64
 222     GOARCH_FAMILY=ARM64
 223     GOARCH_CACHELINESIZE=32
 224     GOARCH_PHYSPAGESIZE=65536
 225     GOARCH_PCQUANTUM=4
 226     GOARCH_MINFRAMESIZE=8
 227     ;;
 228   arm*-*-* | strongarm*-*-* | ep9312*-*-* | xscale-*-*)
 229     GOARCH=arm
 230     GOARCH_FAMILY=ARM
 231     GOARCH_CACHELINESIZE=32
 232     GOARCH_PCQUANTUM=4
 233     GOARCH_MINFRAMESIZE=4
 234     ;;
 235 changequote(,)dnl
 236   i[34567]86-*-* | x86_64-*-*)
 237 changequote([,])dnl
 238     AC_COMPILE_IFELSE([
 239 #ifdef __x86_64__
 240 #error 64-bit
 241 #endif],
 242 [GOARCH=386
 243 GOARCH_FAMILY=I386
 244 GOARCH_INT64ALIGN=4
 245 GOARCH_HUGEPAGESIZE="1 << 21"
 246 ],
 247 [GOARCH=amd64
 248 GOARCH_FAMILY=AMD64
 249 GOARCH_HUGEPAGESIZE="1 << 21"
 250 ])
 251     ;;
 252   ia64-*-*)
 253     GOARCH=ia64
 254     GOARCH_FAMILY=IA64
 255     GOARCH_CACHELINESIZE=16384
 256     GOARCH_PHYSPAGESIZE=65536
 257     ;;
 258   m68k*-*-*)
 259     GOARCH=m68k
 260     GOARCH_FAMILY=M68K
 261     GOARCH_BIGENDIAN=1
 262     GOARCH_CACHELINESIZE=16
 263     GOARCH_PCQUANTUM=4
 264     GOARCH_INT64ALIGN=2
 265     ;;
 266   mips*-*-*)
 267     AC_COMPILE_IFELSE([
 268 #if _MIPS_SIM != _ABIO32
 269 #error not o32
 270 #endif],
 271 [mips_abi="o32"],
 272         [AC_COMPILE_IFELSE([
 273 #if _MIPS_SIM != _ABIN32
 274 #error not n32
 275 #endif],
 276 [mips_abi="n32"],
 277         [AC_COMPILE_IFELSE([
 278 #if _MIPS_SIM != _ABI64
 279 #error not n64
 280 #endif],
 281 [mips_abi="n64"],
 282         [AC_COMPILE_IFELSE([
 283 #if _MIPS_SIM != _ABIO64
 284 #error not o64
 285 #endif],
 286 [mips_abi="o64"],
 287         [AC_MSG_ERROR([unknown MIPS ABI])
 288 [mips_abi="n32"]])])])])
 289     case "$mips_abi" in
 290     "o32") GOARCH=mipso32 ;;
 291     "n32") GOARCH=mipsn32 ;;
 292     "n64") GOARCH=mipsn64 ;;
 293     "o64") GOARCH=mipso64 ;;
 294     esac
 295     case "$mips_abi" in
 296     "o32" | "n32")
 297         GOARCH_FAMILY=MIPS
 298         GOARCH_MINFRAMESIZE=4
 299         ;;
 300     "n64" | "o64")
 301         GOARCH_FAMILY=MIPS64
 302         GOARCH_MINFRAMESIZE=8
 303         ;;
 304     esac
 305     case "${host}" in
 306     mips*el)
 307         ;;
 308     *)
 309         GOARCH_BIGENDIAN=1
 310         ;;
 311     esac
 312     GOARCH_CACHELINESIZE=32
 313     GOARCH_PHYSPAGESIZE=16384
 314     GOARCH_PCQUANTUM=4
 315     ;;
 316   rs6000*-*-* | powerpc*-*-*)
 317     AC_COMPILE_IFELSE([
 318 #ifdef _ARCH_PPC64
 319 #error 64-bit
 320 #endif],
 321 [GOARCH=ppc
 322 GOARCH_FAMILY=PPC
 323 GOARCH_BIGENDIAN=1
 324 ],
 325     [
 326 GOARCH_FAMILY=PPC64
 327 AC_COMPILE_IFELSE([
 328 #if defined(_BIG_ENDIAN) || defined(__BIG_ENDIAN__)
 329 #error 64be
 330 #endif],
 331 [GOARCH=ppc64le
 332 ],
 333 [GOARCH=ppc64
 334 GOARCH_BIGENDIAN=1
 335 ])])
 336     GOARCH_PHYSPAGESIZE=65536
 337     GOARCH_PCQUANTUM=4
 338     GOARCH_MINFRAMESIZE=32
 339     ;;
 340   s390*-*-*)
 341     AC_COMPILE_IFELSE([
 342 #if defined(__s390x__)
 343 #error 64-bit
 344 #endif],
 345 [GOARCH=s390
 346 GOARCH_FAMILY=S390
 347 GOARCH_MINFRAMESIZE=4
 348 ], [GOARCH=s390x
 349 GOARCH_FAMILY=S390X
 350 GOARCH_MINFRAMESIZE=8
 351 ])
 352     GOARCH_BIGENDIAN=1
 353     GOARCH_CACHELINESIZE=256
 354     GOARCH_PCQUANTUM=2
 355     ;;
 356   sparc*-*-*)
 357     AC_COMPILE_IFELSE([
 358 #if defined(__sparcv9) || defined(__arch64__)
 359 #error 64-bit
 360 #endif],
 361 [GOARCH=sparc
 362 GOARCH_FAMILY=SPARC
 363 ],
 364 [GOARCH=sparc64
 365 GOARCH_FAMILY=SPARC64
 366 ])
 367     GOARCH_BIGENDIAN=1
 368     GOARCH_PHYSPAGESIZE=8192
 369     GOARCH_PCQUANTUM=4
 370     ;;
 371 esac
 372 AC_SUBST(GOARCH)
 373 AC_SUBST(GOARCH_FAMILY)
 374 AC_SUBST(GOARCH_BIGENDIAN)
 375 AC_SUBST(GOARCH_CACHELINESIZE)
 376 AC_SUBST(GOARCH_PHYSPAGESIZE)
 377 AC_SUBST(GOARCH_PCQUANTUM)
 378 AC_SUBST(GOARCH_INT64ALIGN)
 379 AC_SUBST(GOARCH_HUGEPAGESIZE)
 380 AC_SUBST(GOARCH_MINFRAMESIZE)
 381 AC_SUBST(ALLGOARCH)
 382 AC_SUBST(ALLGOARCHFAMILY)
 383
 384 dnl Some files are only present when needed for specific architectures.
 385 GO_LIBCALL_OS_FILE=
 386 GO_LIBCALL_OS_ARCH_FILE=
 387 GO_SYSCALL_OS_FILE=
 388 GO_SYSCALL_OS_ARCH_FILE=
 389 if test -f "${srcdir}/go/syscall/libcall_${GOOS}.go"; then
 390   GO_LIBCALL_OS_FILE="go/syscall/libcall_${GOOS}.go"
 391 fi
 392 if test -f "${srcdir}/go/syscall/libcall_${GOOS}_${GOARCH}.go"; then
 393   GO_LIBCALL_OS_ARCH_FILE="go/syscall/libcall_${GOOS}_${GOARCH}.go"
 394 fi
 395 if test -f "${srcdir}/go/syscall/syscall_${GOOS}.go"; then
 396   GO_SYSCALL_OS_FILE="go/syscall/syscall_${GOOS}.go"
 397 fi
 398 if test -f "${srcdir}/go/syscall/syscall_${GOOS}_${GOARCH}.go"; then
 399   GO_SYSCALL_OS_ARCH_FILE="go/syscall/syscall_${GOOS}_${GOARCH}.go"
 400 fi
 401 AC_SUBST(GO_LIBCALL_OS_FILE)
 402 AC_SUBST(GO_LIBCALL_OS_ARCH_FILE)
 403 AC_SUBST(GO_SYSCALL_OS_FILE)
 404 AC_SUBST(GO_SYSCALL_OS_ARCH_FILE)
 405
 406 dnl Special flags used to generate sysinfo.go.
 407 OSCFLAGS="-D_GNU_SOURCE -D_LARGEFILE_SOURCE -D_FILE_OFFSET_BITS=64"
 408 case "$target" in
 409     mips-sgi-irix6.5*)
 410         # IRIX 6 needs _XOPEN_SOURCE=500 for the XPG5 version of struct
 411         # msghdr in <sys/socket.h>.
 412         OSCFLAGS="$OSCFLAGS -D_XOPEN_SOURCE=500"
 413         ;;
 414     *-*-solaris2.1[[01]])
 415         # Solaris 10+ needs this so struct msghdr gets the msg_control
 416         # etc. fields in <sys/socket.h> (_XPG4_2).  _XOPEN_SOURCE=600 as
 417         # above doesn't work with C99.
 418         OSCFLAGS="$OSCFLAGS -std=gnu99 -D_XOPEN_SOURCE=600 -D__EXTENSIONS__"
 419         ;;
 420 esac
 421 AC_SUBST(OSCFLAGS)
 422
 423 dnl Use -fsplit-stack when compiling C code if available.
 424 AC_CACHE_CHECK([whether -fsplit-stack is supported],
 425 [libgo_cv_c_split_stack_supported],
 426 [CFLAGS_hold=$CFLAGS
 427 CFLAGS="$CFLAGS -fsplit-stack"
 428 AC_COMPILE_IFELSE([[int i;]],
 429 [libgo_cv_c_split_stack_supported=yes],
 430 [libgo_cv_c_split_stack_supported=no])
 431 CFLAGS=$CFLAGS_hold])
 432
 433 dnl Make sure the linker permits -fsplit-stack.  Old versions of gold will
 434 dnl reject split-stack code calling non-split-stack code on targets
 435 dnl they don't support.
 436 AC_CACHE_CHECK([whether linker supports split/non-split linked together],
 437 [libgo_cv_c_linker_split_non_split],
 438 [cat > conftest1.c << EOF
 439 extern void f();
 440 int main() { f(); return 0; }
 441 EOF
 442 cat > conftest2.c << EOF
 443 void f() {}
 444 EOF
 445 $CC -c -fsplit-stack $CFLAGS $CPPFLAGS conftest1.c >/dev/null 2>&1
 446 $CC -c $CFLAGS $CPPFLAGS conftest2.c > /dev/null 2>&1
 447 if $CC -o conftest conftest1.$ac_objext conftest2.$ac_objext > /dev/null 2>&1; then
 448   libgo_cv_c_linker_split_non_split=yes
 449 else
 450   libgo_cv_c_linker_split_non_split=no
 451 fi
 452 rm -f conftest1.* conftest2.* conftest])
 453
 454 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes; then
 455   SPLIT_STACK=-fsplit-stack
 456   AC_DEFINE(USING_SPLIT_STACK, 1,
 457                 [Define if the compiler supports -fsplit-stack])
 458 else
 459   SPLIT_STACK=
 460 fi
 461 AC_SUBST(SPLIT_STACK)
 462 AM_CONDITIONAL(USING_SPLIT_STACK,
 463         test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = yes)
 464
 465 dnl If the compiler supports split-stack but the linker does not, then
 466 dnl we need to explicitly disable split-stack for Go.
 467 if test "$libgo_cv_c_split_stack_supported" = yes -a "$libgo_cv_c_linker_split_non_split" = no; then
 468   GO_SPLIT_STACK=-fno-split-stack
 469 else
 470   GO_SPLIT_STACK=
 471 fi
 472 AC_SUBST(GO_SPLIT_STACK)
 473
 474 dnl Check whether the linker does stack munging when calling from
 475 dnl split-stack into non-split-stack code.  We check this by looking
 476 dnl at the --help output.  FIXME: This is only half right: it's
 477 dnl possible for the linker to support this for some targets but not
 478 dnl others.
 479 dnl This is slightly different from the above check, which is whether
 480 dnl the linker permits the call at all.
 481 AC_CACHE_CHECK([whether linker supports split stack],
 482 [libgo_cv_c_linker_supports_split_stack],
 483 [libgo_cv_c_linker_supports_split_stack=no
 484 if $GOC -Wl,--help 2>/dev/null | grep split-stack-adjust-size >/dev/null 2>&1; then
 485   libgo_cv_c_linker_supports_split_stack=yes
 486 fi])
 487 if test "$libgo_cv_c_linker_supports_split_stack" = yes; then
 488   AC_DEFINE(LINKER_SUPPORTS_SPLIT_STACK, 1,
 489             [Define if the linker support split stack adjustments])
 490 fi
 491
 492 AC_CACHE_CHECK([whether compiler is llgo],
 493 [libgo_cv_c_goc_is_llgo],
 494 [libgo_cv_c_goc_is_llgo=no
 495 if $GOC -dumpversion 2>/dev/null | grep llgo >/dev/null 2>&1; then
 496   libgo_cv_c_goc_is_llgo=yes
 497 fi])
 498 AM_CONDITIONAL(GOC_IS_LLGO, test "$libgo_cv_c_goc_is_llgo" = yes)
 499
 500 dnl Test for the -lm library.
 501 MATH_LIBS=
 502 AC_CHECK_LIB([m], [sqrt], MATH_LIBS=-lm)
 503 AC_SUBST(MATH_LIBS)
 504
 505 dnl Test for -lsocket and -lnsl.  Copied from libjava/configure.ac.
 506 AC_CACHE_CHECK([for socket libraries], libgo_cv_lib_sockets,
 507   [libgo_cv_lib_sockets=
 508    libgo_check_both=no
 509    AC_CHECK_FUNC(connect, libgo_check_socket=no, libgo_check_socket=yes)
 510    if test "$libgo_check_socket" = "yes"; then
 511      unset ac_cv_func_connect
 512      AC_CHECK_LIB(socket, main, libgo_cv_lib_sockets="-lsocket",
 513                   libgo_check_both=yes)
 514    fi
 515    if test "$libgo_check_both" = "yes"; then
 516      libgo_old_libs=$LIBS
 517      LIBS="$LIBS -lsocket -lnsl"
 518      unset ac_cv_func_accept
 519      AC_CHECK_FUNC(accept,
 520                    [libgo_check_nsl=no
 521                     libgo_cv_lib_sockets="-lsocket -lnsl"])
 522      unset ac_cv_func_accept
 523      LIBS=$libgo_old_libs
 524    fi
 525    unset ac_cv_func_gethostbyname
 526    libgo_old_libs="$LIBS"
 527    AC_CHECK_FUNC(gethostbyname, ,
 528                  [AC_CHECK_LIB(nsl, main,
 529                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lnsl"])])
 530    unset ac_cv_func_gethostbyname
 531    AC_CHECK_FUNC(sendfile, ,
 532                  [AC_CHECK_LIB(sendfile, main,
 533                         [libgo_cv_lib_sockets="$libgo_cv_lib_sockets -lsendfile"])])
 534    LIBS=$libgo_old_libs
 535 ])
 536 NET_LIBS="$libgo_cv_lib_sockets"
 537 AC_SUBST(NET_LIBS)
 538
 539 dnl Test whether the compiler supports the -pthread option.
 540 AC_CACHE_CHECK([whether -pthread is supported],
 541 [libgo_cv_lib_pthread],
 542 [CFLAGS_hold=$CFLAGS
 543 CFLAGS="$CFLAGS -pthread"
 544 AC_COMPILE_IFELSE([[int i;]],
 545 [libgo_cv_lib_pthread=yes],
 546 [libgo_cv_lib_pthread=no])
 547 CFLAGS=$CFLAGS_hold])
 548 PTHREAD_CFLAGS=
 549 if test "$libgo_cv_lib_pthread" = yes; then
 550   PTHREAD_CFLAGS=-pthread
 551 fi
 552 AC_SUBST(PTHREAD_CFLAGS)
 553
 554 dnl Test for the -lpthread library.
 555 PTHREAD_LIBS=
 556 AC_CHECK_LIB([pthread], [pthread_create], PTHREAD_LIBS=-lpthread)
 557 AC_SUBST(PTHREAD_LIBS)
 558
 559 dnl Test if -lrt is required for sched_yield or nanosleep or clock_gettime.
 560 AC_SEARCH_LIBS([sched_yield], [rt])
 561 AC_SEARCH_LIBS([nanosleep], [rt])
 562 AC_SEARCH_LIBS([clock_gettime], [rt])
 563
 564 AC_C_BIGENDIAN
 565
 566 GCC_CHECK_UNWIND_GETIPINFO
 567
 568 AC_CHECK_HEADERS(port.h sched.h semaphore.h sys/file.h sys/mman.h syscall.h sys/epoll.h sys/event.h sys/inotify.h sys/ptrace.h sys/syscall.h sys/user.h sys/utsname.h sys/select.h sys/socket.h net/if.h net/if_arp.h net/route.h netpacket/packet.h sys/prctl.h sys/mount.h sys/vfs.h sys/statfs.h sys/timex.h sys/sysinfo.h utime.h linux/ether.h linux/fs.h linux/reboot.h netinet/icmp6.h netinet/in_syst.h netinet/ip.h netinet/ip_mroute.h netinet/if_ether.h)
 569
 570 AC_CHECK_HEADERS([linux/filter.h linux/if_addr.h linux/if_ether.h linux/if_tun.h linux/netlink.h linux/rtnetlink.h], [], [],
 571 [#ifdef HAVE_SYS_SOCKET_H
 572 #include <sys/socket.h>
 573 #endif
 574 ])
 575
 576 AC_CACHE_CHECK([whether <ustat.h> can be used],
 577 [libgo_cv_c_ustat_h],
 578 [CFLAGS_hold=$CFLAGS
 579 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE $OSCFLAGS"
 580 AC_COMPILE_IFELSE(
 581 [AC_LANG_SOURCE([
 582 #include <sys/types.h>
 583 #ifdef HAVE_LINUX_FILTER_H
 584 #include <linux/filter.h>
 585 #endif
 586 #include <ustat.h>
 587 ])], [libgo_cv_c_ustat_h=yes], [libgo_cv_c_ustat_h=no])
 588 CFLAGS=$CFLAGS_hold])
 589 if test $libgo_cv_c_ustat_h = yes; then
 590   AC_DEFINE(HAVE_USTAT_H, 1,
 591     [Define to 1 if you have the <ustat.h> header file and it works.])
 592 fi
 593
 594 AM_CONDITIONAL(HAVE_SYS_MMAN_H, test "$ac_cv_header_sys_mman_h" = yes)
 595
 596 AC_CHECK_FUNCS(strerror_r strsignal wait4 mincore setenv unsetenv dl_iterate_phdr)
 597 AM_CONDITIONAL(HAVE_STRERROR_R, test "$ac_cv_func_strerror_r" = yes)
 598 AM_CONDITIONAL(HAVE_WAIT4, test "$ac_cv_func_wait4" = yes)
 599
 600 AC_CHECK_FUNCS(accept4 dup3 epoll_create1 faccessat fallocate fchmodat fchownat futimesat getxattr inotify_add_watch inotify_init inotify_init1 inotify_rm_watch listxattr mkdirat mknodat open64 openat pipe2 removexattr renameat setxattr sync_file_range splice tee unlinkat unshare utimensat)
 601 AC_TYPE_OFF_T
 602 AC_CHECK_TYPES([loff_t])
 603
 604 LIBS_hold="$LIBS"
 605 LIBS="$LIBS -lm"
 606 AC_CHECK_FUNCS(cosl expl logl sinl tanl acosl asinl atanl atan2l expm1l ldexpl log10l log1pl)
 607 LIBS="$LIBS_hold"
 608
 609 CFLAGS_hold="$CFLAGS"
 610 CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
 611 LIBS_hold="$LIBS"
 612 LIBS="$LIBS $PTHREAD_LIBS"
 613 AC_CHECK_FUNCS(sem_timedwait)
 614 CFLAGS="$CFLAGS_hold"
 615 LIBS="$LIBS_hold"
 616
 617 LIBS_hold="$LIBS"
 618 LIBS="$LIBS $MATH_LIBS"
 619 AC_CHECK_FUNCS(matherr)
 620 LIBS="$LIBS_hold"
 621
 622 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_4],
 623 [libgo_cv_func___sync_bool_compare_and_swap_4],
 624 [AC_LINK_IFELSE([
 625 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 626 uint32 i;
 627 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 628 ],
 629 [libgo_cv_func___sync_bool_compare_and_swap_4=yes],
 630 [libgo_cv_func___sync_bool_compare_and_swap_4=no])])
 631 if test "$libgo_cv_func___sync_bool_compare_and_swap_4" = "yes"; then
 632   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_4, 1,
 633     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint32])
 634 fi
 635
 636 AC_CACHE_CHECK([for __sync_bool_compare_and_swap_8],
 637 [libgo_cv_func___sync_bool_compare_and_swap_8],
 638 [AC_LINK_IFELSE([
 639 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 640 uint64 i;
 641 int main() { return __sync_bool_compare_and_swap (&i, 0, 1); }
 642 ],
 643 [libgo_cv_func___sync_bool_compare_and_swap_8=yes],
 644 [libgo_cv_func___sync_bool_compare_and_swap_8=no])])
 645 if test "$libgo_cv_func___sync_bool_compare_and_swap_8" = "yes"; then
 646   AC_DEFINE(HAVE_SYNC_BOOL_COMPARE_AND_SWAP_8, 1,
 647     [Define to 1 if the compiler provides the __sync_bool_compare_and_swap function for uint64])
 648 fi
 649
 650 AC_CACHE_CHECK([for __sync_fetch_and_add_4],
 651 [libgo_cv_func___sync_fetch_and_add_4],
 652 [AC_LINK_IFELSE([
 653 typedef unsigned int uint32  __attribute__ ((mode (SI)));
 654 uint32 i;
 655 int main() { return __sync_fetch_and_add (&i, 1); }
 656 ],
 657 [libgo_cv_func___sync_fetch_and_add_4=yes],
 658 [libgo_cv_func___sync_fetch_and_add_4=no])])
 659 if test "$libgo_cv_func___sync_fetch_and_add_4" = "yes"; then
 660   AC_DEFINE(HAVE_SYNC_FETCH_AND_ADD_4, 1,
 661     [Define to 1 if the compiler provides the __sync_fetch_and_add function for uint32])
 662 fi
 663
 664 AC_CACHE_CHECK([for __sync_add_and_fetch_8],
 665 [libgo_cv_func___sync_add_and_fetch_8],
 666 [AC_LINK_IFELSE([
 667 typedef unsigned int uint64  __attribute__ ((mode (DI)));
 668 uint64 i;
 669 int main() { return __sync_add_and_fetch (&i, 1); }
 670 ],
 671 [libgo_cv_func___sync_add_and_fetch_8=yes],
 672 [libgo_cv_func___sync_add_and_fetch_8=no])])
 673 if test "$libgo_cv_func___sync_add_and_fetch_8" = "yes"; then
 674   AC_DEFINE(HAVE_SYNC_ADD_AND_FETCH_8, 1,
 675     [Define to 1 if the compiler provides the __sync_add_and_fetch function for uint64])
 676 fi
 677
 678 dnl For x86 we want to use the -minline-all-stringops option to avoid
 679 dnl forcing a stack split when calling memcpy and friends.
 680 AC_CACHE_CHECK([whether compiler supports -minline-all-stringops],
 681 [libgo_cv_c_stringops],
 682 [CFLAGS_hold=$CFLAGS
 683 CFLAGS="$CFLAGS -minline-all-stringops"
 684 AC_COMPILE_IFELSE([int i;],
 685 [libgo_cv_c_stringops=yes],
 686 [libgo_cv_c_stringops=no])
 687 CFLAGS=$CFLAGS_hold])
 688 STRINGOPS_FLAG=
 689 if test "$libgo_cv_c_stringops" = yes; then
 690   STRINGOPS_FLAG=-minline-all-stringops
 691 fi
 692 AC_SUBST(STRINGOPS_FLAG)
 693
 694 dnl For x86 we want to compile the math library with -mfancy-math-387
 695 dnl -funsafe-math-optimizations so that we can use the builtin
 696 dnl instructions directly.
 697 AC_CACHE_CHECK([whether compiler supports -mfancy-math-387],
 698 [libgo_cv_c_fancymath],
 699 [CFLAGS_hold=$CFLAGS
 700 CFLAGS="$CFLAGS -mfancy-math-387"
 701 AC_COMPILE_IFELSE([int i;],
 702 [libgo_cv_c_fancymath=yes],
 703 [libgo_cv_c_fancymath=no])
 704 CFLAGS=$CFLAGS_hold])
 705 MATH_FLAG=
 706 if test "$libgo_cv_c_fancymath" = yes; then
 707   MATH_FLAG="-mfancy-math-387 -funsafe-math-optimizations"
 708 else
 709   MATH_FLAG="-ffp-contract=off"
 710 fi
 711 AC_SUBST(MATH_FLAG)
 712
 713 CFLAGS_hold=$CFLAGS
 714 CFLAGS="$CFLAGS -D_LARGEFILE_SOURCE -D_LARGEFILE64_SOURCE"
 715 AC_CHECK_TYPES([off64_t])
 716 CFLAGS=$CFLAGS_hold
 717
 718 dnl Work out the size of the epoll_events struct on GNU/Linux.
 719 AC_CACHE_CHECK([epoll_event size],
 720 [libgo_cv_c_epoll_event_size],
 721 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_size,
 722 [sizeof (struct epoll_event)],
 723 [#include <sys/epoll.h>],
 724 [libgo_cv_c_epoll_event_size=0])])
 725 SIZEOF_STRUCT_EPOLL_EVENT=${libgo_cv_c_epoll_event_size}
 726 AC_SUBST(SIZEOF_STRUCT_EPOLL_EVENT)
 727
 728 dnl Work out the offset of the fd field in the epoll_events struct on
 729 dnl GNU/Linux.
 730 AC_CACHE_CHECK([epoll_event data.fd offset],
 731 [libgo_cv_c_epoll_event_fd_offset],
 732 [AC_COMPUTE_INT(libgo_cv_c_epoll_event_fd_offset,
 733 [offsetof (struct epoll_event, data.fd)],
 734 [#include <stddef.h>
 735 #include <sys/epoll.h>],
 736 [libgo_cv_c_epoll_event_fd_offset=0])])
 737 STRUCT_EPOLL_EVENT_FD_OFFSET=${libgo_cv_c_epoll_event_fd_offset}
 738 AC_SUBST(STRUCT_EPOLL_EVENT_FD_OFFSET)
 739
 740 dnl Check if <sys/stat.h> uses timespec_t for st_?tim members.  Introduced
 741 dnl in Solaris 12 for XPG7 compatibility.
 742 AC_EGREP_HEADER([timespec_t.*st_atim], [sys/stat.h],
 743                 [have_stat_timespec=yes], [have_stat_timespec=no])
 744 AM_CONDITIONAL(HAVE_STAT_TIMESPEC, test $have_stat_timespec = yes)
 745
 746 dnl See if struct exception is defined in <math.h>.
 747 AC_CHECK_TYPE([struct exception],
 748 [libgo_has_struct_exception=yes],
 749 [libgo_has_struct_exception=no],
 750 [#include <math.h>])
 751 if test "$libgo_has_struct_exception" = "yes"; then
 752   AC_DEFINE(HAVE_STRUCT_EXCEPTION, 1,
 753             [Define to 1 if <math.h> defines struct exception])
 754 fi
 755
 756 dnl See whether setcontext changes the value of TLS variables.
 757 AC_CACHE_CHECK([whether setcontext clobbers TLS variables],
 758 [libgo_cv_lib_setcontext_clobbers_tls],
 759 [CFLAGS_hold="$CFLAGS"
 760 CFLAGS="$PTHREAD_CFLAGS"
 761 LIBS_hold="$LIBS"
 762 LIBS="$LIBS $PTHREAD_LIBS"
 763 AC_CHECK_SIZEOF([void *])
 764 AS_VAR_ARITH([ptr_type_size], [$ac_cv_sizeof_void_p \* 8])
 765 AC_RUN_IFELSE(
 766   [AC_LANG_SOURCE([
 767 #include <pthread.h>
 768 #include <stdlib.h>
 769 #include <ucontext.h>
 770 #include <unistd.h>
 771
 772 __thread int tls;
 773
 774 static char stack[[10 * 1024 * 1024]];
 775 static ucontext_t c;
 776
 777 /* Called via makecontext/setcontext.  */
 778
 779 static void
 780 cfn (void)
 781 {
 782   exit (tls);
 783 }
 784
 785 /* Called via pthread_create.  */
 786
 787 static void *
 788 tfn (void *dummy)
 789 {
 790   /* The thread should still see this value after calling
 791      setcontext.  */
 792   tls = 0;
 793
 794   setcontext (&c);
 795
 796   /* The call to setcontext should not return.  */
 797   abort ();
 798 }
 799
 800 int
 801 main ()
 802 {
 803   pthread_t tid;
 804
 805   /* The thread should not see this value.  */
 806   tls = 1;
 807
 808   if (getcontext (&c) < 0)
 809     abort ();
 810
 811   c.uc_stack.ss_sp = stack;
 812 #ifdef MAKECONTEXT_STACK_TOP
 813   c.uc_stack.ss_sp += sizeof stack;
 814 #endif
 815   c.uc_stack.ss_flags = 0;
 816   c.uc_stack.ss_size = sizeof stack;
 817   c.uc_link = NULL;
 818   makecontext (&c, cfn, 0);
 819
 820   if (pthread_create (&tid, NULL, tfn, NULL) != 0)
 821     abort ();
 822
 823   if (pthread_join (tid, NULL) != 0)
 824     abort ();
 825
 826   /* The thread should have called exit.  */
 827   abort ();
 828 }
 829 ])],
 830 [libgo_cv_lib_setcontext_clobbers_tls=no],
 831 [libgo_cv_lib_setcontext_clobbers_tls=yes],
 832 [case "$target:$ptr_type_size" in
 833   i?86-*-solaris2.1[[01]]:64 | x86_64*-*-solaris2.1[[01]]:64)
 834     libgo_cv_lib_setcontext_clobbers_tls=yes ;;
 835   *)
 836     libgo_cv_lib_setcontext_clobbers_tls=no ;;
 837  esac
 838 ])
 839 CFLAGS="$CFLAGS_hold"
 840 LIBS="$LIBS_hold"
 841 ])
 842 if test "$libgo_cv_lib_setcontext_clobbers_tls" = "yes"; then
 843   AC_DEFINE(SETCONTEXT_CLOBBERS_TLS, 1,
 844             [Define if setcontext clobbers TLS variables])
 845 fi
 846
 847 AC_CACHE_CHECK([whether .eh_frame section should be read-only],
 848 libgo_cv_ro_eh_frame, [
 849 libgo_cv_ro_eh_frame=no
 850 echo 'extern void foo (void); void bar (void) { foo (); foo (); }' > conftest.c
 851 if $CC $CFLAGS -S -fpic -fexceptions -o conftest.s conftest.c > /dev/null 2>&1; then
 852   if grep '.section.*eh_frame.*"a"' conftest.s > /dev/null; then
 853     libgo_cv_ro_eh_frame=yes
 854   elif grep '.section.*eh_frame.*#alloc' conftest.c \
 855        | grep -v '#write' > /dev/null; then
 856     libgo_cv_ro_eh_frame=yes
 857   fi
 858 fi
 859 rm -f conftest.*
 860 ])
 861 if test "x$libgo_cv_ro_eh_frame" = xyes; then
 862   AC_DEFINE(EH_FRAME_FLAGS, "a",
 863             [Define to the flags needed for the .section .eh_frame directive.])
 864 else
 865   AC_DEFINE(EH_FRAME_FLAGS, "aw",
 866             [Define to the flags needed for the .section .eh_frame directive.])
 867 fi
 868
 869 AC_CACHE_CHECK([if compiler supports -Qunused-arguments],
 870 [libgo_cv_c_unused_arguments],
 871 [CFLAGS_hold=$CFLAGS
 872 CFLAGS="$CFLAGS -Qunused-arguments"
 873 AC_COMPILE_IFELSE([[int i;]],
 874 [libgo_cv_c_unused_arguments=yes],
 875 [libgo_cv_c_unused_arguments=no])
 876 CFLAGS=$CFLAGS_hold])
 877
 878 AC_CACHE_CHECK([if assembler supports GNU comdat group syntax],
 879 libgo_cv_as_comdat_gnu, [
 880 echo '.section .text,"axG",@progbits,.foo,comdat' > conftest.s
 881 CFLAGS_hold=$CFLAGS
 882 if test "$libgo_cv_c_unused_arguments" = yes; then
 883   CFLAGS="$CFLAGS -Qunused-arguments"
 884 fi
 885 if $CC $CFLAGS -c conftest.s > /dev/null 2>&1; then
 886   libgo_cv_as_comdat_gnu=yes
 887 else
 888   libgo_cv_as_comdat_gnu=no
 889 fi
 890 CFLAGS=$CFLAGS_hold
 891 ])
 892 if test "x$libgo_cv_as_comdat_gnu" = xyes; then
 893   AC_DEFINE(HAVE_AS_COMDAT_GAS, 1,
 894             [Define if your assembler supports GNU comdat group syntax.])
 895 fi
 896
 897 AC_CACHE_CHECK([assembler supports pc related relocs],
 898 libgo_cv_as_x86_pcrel, [
 899 libgo_cv_as_x86_pcrel=yes
 900 echo '.text; foo: nop; .data; .long foo-.; .text' > conftest.s
 901 CFLAGS_hold=$CFLAGS
 902 if test "$libgo_cv_c_unused_arguments" = yes; then
 903   CFLAGS="$CFLAGS -Qunused-arguments"
 904 fi
 905 if $CC $CFLAGS -c conftest.s 2>&1 | $EGREP -i 'illegal|warning' > /dev/null; then
 906     libgo_cv_as_x86_pcrel=no
 907 fi
 908 CFLAGS=$CFLAGS_hold
 909 ])
 910 if test "x$libgo_cv_as_x86_pcrel" = xyes; then
 911   AC_DEFINE(HAVE_AS_X86_PCREL, 1,
 912             [Define if your assembler supports PC relative relocs.])
 913 fi
 914
 915 AC_CACHE_CHECK([assembler supports unwind section type],
 916 libgo_cv_as_x86_64_unwind_section_type, [
 917 libgo_cv_as_x86_64_unwind_section_type=yes
 918 echo '.section .eh_frame,"a",@unwind' > conftest.s
 919 CFLAGS_hold=$CFLAGS
 920 if test "$libgo_cv_c_unused_arguments" = yes; then
 921   CFLAGS="$CFLAGS -Qunused-arguments"
 922 fi
 923 if $CC $CFLAGS -c conftest.s 2>&1 | grep -i warning > /dev/null; then
 924     libgo_cv_as_x86_64_unwind_section_type=no
 925 fi
 926 CFLAGS=$CFLAGS_hold
 927 ])
 928 if test "x$libgo_cv_as_x86_64_unwind_section_type" = xyes; then
 929   AC_DEFINE(HAVE_AS_X86_64_UNWIND_SECTION_TYPE, 1,
 930             [Define if your assembler supports unwind section type.])
 931 fi
 932
 933 AC_CACHE_SAVE
 934
 935 if test ${multilib} = yes; then
 936   multilib_arg="--enable-multilib"
 937 else
 938   multilib_arg=
 939 fi
 940
 941 AC_CONFIG_FILES(Makefile testsuite/Makefile)
 942
 943 AC_CONFIG_COMMANDS([default],
 944 [if test -n "$CONFIG_FILES"; then
 945    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 946    # that multilib installs will end up installed in the correct place.
 947    # The testsuite needs it for multilib-aware ABI baseline files.
 948    # To work around this not being passed down from config-ml.in ->
 949    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 950    # append it here.  Only modify Makefiles that have just been created.
 951    #
 952    # Also, get rid of this simulated-VPATH thing that automake does.
 953    cat > vpsed << \_EOF
 954 s!`test -f '$<' || echo '$(srcdir)/'`!!
 955 _EOF
 956    for i in $SUBDIRS; do
 957     case $CONFIG_FILES in
 958      *${i}/Makefile*)
 959        #echo "Adding MULTISUBDIR to $i/Makefile"
 960        sed -f vpsed $i/Makefile > tmp
 961        grep '^MULTISUBDIR =' Makefile >> tmp
 962        mv tmp $i/Makefile
 963        ;;
 964     esac
 965    done
 966    rm vpsed
 967  fi
 968 ],
 969 [
 970 # Variables needed in config.status (file generation) which aren't already
 971 # passed by autoconf.
 972 SUBDIRS="$SUBDIRS"
 973 ])
 974
 975 AC_OUTPUT