libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_INIT(package-unused, version-unused,, libstdc++)
   4 AC_CONFIG_SRCDIR(src/shared/hashtable-aux.cc)
   5 AC_CONFIG_HEADER(config.h)
   6
   7 # This works around the fact that libtool configuration may change LD
   8 # for this particular configuration, but some shells, instead of
   9 # keeping the changes in LD private, export them just because LD is
  10 # exported.  Only used at the end of this file.
  11 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  12
  13 # Find the rest of the source tree framework.
  14 AM_ENABLE_MULTILIB(, ..)
  15
  16 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  17 #
  18 # You will slowly go insane if you do not grok the following fact:  when
  19 # building v3 as part of the compiler, the top-level /target/ becomes the
  20 # library's /host/.  configure then causes --target to default to --host,
  21 # exactly like any other package using autoconf.  Therefore, 'target' and
  22 # 'host' will always be the same.  This makes sense both for native and
  23 # cross compilers, just think about it for a little while.  :-)
  24 #
  25 # Also, if v3 is being configured as part of a cross compiler, the top-level
  26 # configure script will pass the "real" host as $with_cross_host.
  27 #
  28 # Do not delete or change the following two lines.  For why, see
  29 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  30 AC_CANONICAL_SYSTEM
  31 target_alias=${target_alias-$host_alias}
  32
  33 # Handy for debugging:
  34 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  35
  36 if test "$build" != "$host"; then
  37   # We are being configured with some form of cross compiler.
  38   GLIBCXX_IS_NATIVE=false
  39   case "$host","$target" in
  40     # Darwin crosses can use the host system's libraries and headers,
  41     # because of the fat library support.  Of course, it must be the
  42     # same version of Darwin on both sides.  Allow the user to
  43     # just say --target=foo-darwin without a version number to mean
  44     # "the version on this system".
  45       *-*-darwin*,*-*-darwin*)
  46         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  47         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  48         if test $hostos = $targetos -o $targetos = darwin ; then
  49           GLIBCXX_IS_NATIVE=true
  50         fi
  51         ;;
  52
  53       *)
  54         GCC_NO_EXECUTABLES
  55         ;;
  56   esac
  57 else
  58   GLIBCXX_IS_NATIVE=true
  59 fi
  60
  61 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  62 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  63 #  1.x:  minimum required version
  64 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  65 #              of other PACKAGE_* variables will, however, and there's nothing
  66 #              we can do about that; they come from AC_INIT).
  67 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  68 #            file in the top srcdir, etc, etc), so stop complaining.
  69 #  no-dependencies:  turns off auto dependency generation (just for now)
  70 #  no-dist:  we don't want 'dist' and related rules.
  71 #  -Wall:  turns on all automake warnings...
  72 #  -Wno-portability:  ...except this one, since GNU make is now required.
  73 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
  74 AH_TEMPLATE(PACKAGE, [Name of package])
  75 AH_TEMPLATE(VERSION, [Version number of package])
  76
  77 # -fno-builtin must be present here so that a non-conflicting form of
  78 # std::exit can be guessed by AC_PROG_CXX, and used in later tests.
  79
  80 save_CXXFLAGS="$CXXFLAGS"
  81 CXXFLAGS="$CXXFLAGS -fno-builtin"
  82 AC_PROG_CC
  83 AC_PROG_CXX
  84 CXXFLAGS="$save_CXXFLAGS"
  85
  86 # Runs configure.host, and assorted other critical bits.  Sets
  87 # up critical shell variables.
  88 GLIBCXX_CONFIGURE
  89
  90 # Libtool setup.
  91 if test "x${with_newlib}" != "xyes"; then
  92   AC_LIBTOOL_DLOPEN
  93 fi
  94 AM_PROG_LIBTOOL
  95 ACX_LT_HOST_FLAGS
  96 AC_SUBST(enable_shared)
  97 AC_SUBST(enable_static)
  98
  99 if test "$enable_vtable_verify" = yes; then
 100   predep_objects_CXX="${predep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_start.o"
 101   postdep_objects_CXX="${postdep_objects_CXX} ${glibcxx_builddir}/../libgcc/vtv_end.o"
 102 fi
 103
 104
 105 # libtool variables for C++ shared and position-independent compiles.
 106 #
 107 # Use glibcxx_lt_pic_flag to designate the automake variable
 108 # used to encapsulate the default libtool approach to creating objects
 109 # with position-independent code. Default: -prefer-pic.
 110 #
 111 # Use glibcxx_compiler_shared_flag to designate a compile-time flags for
 112 # creating shared objects. Default: -D_GLIBCXX_SHARED.
 113 #
 114 # Use glibcxx_compiler_pic_flag to designate a compile-time flags for
 115 # creating position-independent objects. This varies with the target
 116 # hardware and operating system, but is often: -DPIC -fPIC.
 117 if test "$enable_shared" = yes; then
 118   glibcxx_lt_pic_flag="-prefer-pic"
 119   glibcxx_compiler_pic_flag="$lt_prog_compiler_pic_CXX"
 120   glibcxx_compiler_shared_flag="-D_GLIBCXX_SHARED"
 121
 122 else
 123   glibcxx_lt_pic_flag=
 124   glibcxx_compiler_pic_flag=
 125   glibcxx_compiler_shared_flag=
 126 fi
 127 AC_SUBST(glibcxx_lt_pic_flag)
 128 AC_SUBST(glibcxx_compiler_pic_flag)
 129 AC_SUBST(glibcxx_compiler_shared_flag)
 130
 131 # Override the libtool's pic_flag and pic_mode.
 132 # Do this step after AM_PROG_LIBTOOL, but before AC_OUTPUT.
 133 # NB: this impacts --with-pic and --without-pic.
 134 lt_prog_compiler_pic_CXX="$glibcxx_compiler_pic_flag $glibcxx_compiler_shared_flag"
 135 pic_mode='default'
 136
 137 # Eliminate -lstdc++ addition to postdeps for cross compiles.
 138 postdeps_CXX=`echo " $postdeps_CXX " | sed 's, -lstdc++ ,,g'`
 139
 140 # Possibly disable most of the library.
 141 ## TODO: Consider skipping unncessary tests altogether in this case, rather
 142 ## than just ignoring the results.  Faster /and/ more correct, win win.
 143 GLIBCXX_ENABLE_HOSTED
 144
 145 # Enable descriptive messages to standard output on termination.
 146 GLIBCXX_ENABLE_VERBOSE
 147
 148 # Enable compiler support that doesn't require linking.
 149 GLIBCXX_ENABLE_PCH($is_hosted)
 150 GLIBCXX_ENABLE_THREADS
 151 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 152 GLIBCXX_ENABLE_LOCK_POLICY
 153 GLIBCXX_ENABLE_DECIMAL_FLOAT
 154 GLIBCXX_ENABLE_INT128_FLOAT128
 155 if test "$enable_float128" = yes; then
 156   port_specific_symbol_files="$port_specific_symbol_files \$(top_srcdir)/config/abi/pre/float128.ver"
 157 fi
 158
 159 # Checks for compiler support that doesn't require linking.
 160 GLIBCXX_CHECK_COMPILER_FEATURES
 161
 162 # Enable all the variable C++ runtime options that don't require linking.
 163 GLIBCXX_ENABLE_CSTDIO
 164 GLIBCXX_ENABLE_CLOCALE
 165 GLIBCXX_ENABLE_ALLOCATOR
 166 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 167 GLIBCXX_ENABLE_LONG_LONG([yes])
 168 GLIBCXX_ENABLE_WCHAR_T([yes])
 169 GLIBCXX_ENABLE_C99([yes])
 170 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 171 GLIBCXX_ENABLE_DEBUG_FLAGS(["-gdwarf-4 -g3 -O0 -D_GLIBCXX_ASSERTIONS"])
 172 GLIBCXX_ENABLE_DEBUG([no])
 173 GLIBCXX_ENABLE_PARALLEL([yes])
 174 GLIBCXX_ENABLE_CXX_FLAGS
 175 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 176 GLIBCXX_ENABLE_EXTERN_TEMPLATE([yes])
 177 GLIBCXX_ENABLE_PYTHON
 178 GLIBCXX_ENABLE_WERROR([no])
 179 GLIBCXX_ENABLE_VTABLE_VERIFY([no])
 180
 181 # Checks for operating systems support that doesn't require linking.
 182 GLIBCXX_CHECK_STDIO_PROTO
 183 GLIBCXX_CHECK_MATH11_PROTO
 184 GLIBCXX_CHECK_SYSTEM_ERROR
 185 GLIBCXX_CHECK_UCHAR_H
 186
 187 # For the streamoff typedef.
 188 GLIBCXX_CHECK_INT64_T
 189
 190 # For LFS support.
 191 GLIBCXX_CHECK_LFS
 192
 193 # For showmanyc_helper().
 194 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 195 GLIBCXX_CHECK_POLL
 196 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 197
 198 # For xsputn_2().
 199 AC_CHECK_HEADERS(sys/uio.h)
 200 GLIBCXX_CHECK_WRITEV
 201
 202 # Check for fenv.h and complex.h before GLIBCXX_CHECK_C99_TR1
 203 # so that the check is done with the C compiler (not C++).
 204 # Checking with C++ can break a canadian cross build if either
 205 # file does not exist in C but does in C++.
 206 AC_CHECK_HEADERS(fenv.h complex.h)
 207
 208 # For C99 support to TR1.
 209 GLIBCXX_CHECK_C99_TR1
 210
 211 # For the EOF, SEEK_CUR, and SEEK_END integer constants.
 212 GLIBCXX_COMPUTE_STDIO_INTEGER_CONSTANTS
 213
 214 # For gettimeofday support.
 215 GLIBCXX_CHECK_GETTIMEOFDAY
 216
 217 # For clock_gettime, nanosleep and sched_yield support.
 218 GLIBCXX_ENABLE_LIBSTDCXX_TIME
 219
 220 # Check for tmpnam which is obsolescent in POSIX.1-2008
 221 GLIBCXX_CHECK_TMPNAM
 222
 223 AC_LC_MESSAGES
 224
 225 # For hardware_concurrency
 226 AC_CHECK_HEADERS(sys/sysinfo.h)
 227 GLIBCXX_CHECK_GET_NPROCS
 228 AC_CHECK_HEADERS(unistd.h)
 229 GLIBCXX_CHECK_SC_NPROCESSORS_ONLN
 230 GLIBCXX_CHECK_SC_NPROC_ONLN
 231 GLIBCXX_CHECK_PTHREADS_NUM_PROCESSORS_NP
 232 GLIBCXX_CHECK_SYSCTL_HW_NCPU
 233 GLIBCXX_CHECK_SDT_H
 234
 235 # Check for available headers.
 236 AC_CHECK_HEADERS([endian.h execinfo.h float.h fp.h ieeefp.h inttypes.h \
 237 locale.h machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
 238 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
 239 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
 240 wchar.h wctype.h linux/types.h])
 241
 242 AC_CHECK_HEADERS([linux/random.h], [], [],
 243 [[#ifdef HAVE_LINUX_TYPES_H
 244 # include <linux/types.h>
 245 #endif
 246 ]])
 247
 248 # Only do link tests if native. Else, hardcode.
 249 if $GLIBCXX_IS_NATIVE; then
 250
 251   # We can do more elaborate tests that assume a working linker.
 252   CANADIAN=no
 253
 254   GLIBCXX_CHECK_LINKER_FEATURES
 255   GLIBCXX_CHECK_MATH_SUPPORT
 256   GLIBCXX_CHECK_STDLIB_SUPPORT
 257
 258   # For /dev/random and /dev/urandom for std::random_device.
 259   GLIBCXX_CHECK_DEV_RANDOM
 260
 261   # For TLS support.
 262   GCC_CHECK_TLS
 263
 264   AC_CHECK_FUNCS(__cxa_thread_atexit_impl __cxa_thread_atexit)
 265   AC_CHECK_FUNCS(aligned_alloc posix_memalign memalign _aligned_malloc)
 266   AC_CHECK_FUNCS(_wfopen)
 267
 268   # C11 functions for C++17 library
 269   AC_CHECK_FUNCS(timespec_get)
 270
 271   # For Networking TS.
 272   AC_CHECK_FUNCS(sockatmark)
 273
 274   # For iconv support.
 275   AM_ICONV
 276
 277 else
 278
 279   # This lets us hard-code the functionality we know we'll have in the cross
 280   # target environment.  "Let" is a sugar-coated word placed on an especially
 281   # dull and tedious hack, actually.
 282   #
 283   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 284   # that involve linking, can't be used:
 285   #    "cannot open sim-crt0.o"
 286   #    "cannot open crt0.o"
 287   # etc.  All this is because there currently exists no unified, consistent
 288   # way for top level CC information to be passed down to target directories:
 289   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 290   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 291   # crosses can be removed.
 292
 293   # If Canadian cross, then don't pick up tools from the build directory.
 294   # Used only in GLIBCXX_EXPORT_INCLUDES.
 295   if test -n "$with_cross_host" &&
 296      test x"$build_alias" != x"$with_cross_host" &&
 297      test x"$build" != x"$target";
 298   then
 299     CANADIAN=yes
 300   else
 301     CANADIAN=no
 302   fi
 303
 304   # Construct crosses by hand, eliminating bits that need ld...
 305   # GLIBCXX_CHECK_MATH_SUPPORT
 306
 307   # First, test for "known" system libraries.  We may be using newlib even
 308   # on a hosted environment.
 309   if test "x${with_newlib}" = "xyes"; then
 310     os_include_dir="os/newlib"
 311     AC_DEFINE(HAVE_HYPOT)
 312
 313     # GLIBCXX_CHECK_STDLIB_SUPPORT
 314     AC_DEFINE(HAVE_STRTOF)
 315
 316     AC_DEFINE(HAVE_ACOSF)
 317     AC_DEFINE(HAVE_ASINF)
 318     AC_DEFINE(HAVE_ATAN2F)
 319     AC_DEFINE(HAVE_ATANF)
 320     AC_DEFINE(HAVE_CEILF)
 321     AC_DEFINE(HAVE_COSF)
 322     AC_DEFINE(HAVE_COSHF)
 323     AC_DEFINE(HAVE_EXPF)
 324     AC_DEFINE(HAVE_FABSF)
 325     AC_DEFINE(HAVE_FLOORF)
 326     AC_DEFINE(HAVE_FMODF)
 327     AC_DEFINE(HAVE_FREXPF)
 328     AC_DEFINE(HAVE_LDEXPF)
 329     AC_DEFINE(HAVE_LOG10F)
 330     AC_DEFINE(HAVE_LOGF)
 331     AC_DEFINE(HAVE_MODFF)
 332     AC_DEFINE(HAVE_POWF)
 333     AC_DEFINE(HAVE_SINF)
 334     AC_DEFINE(HAVE_SINHF)
 335     AC_DEFINE(HAVE_SQRTF)
 336     AC_DEFINE(HAVE_TANF)
 337     AC_DEFINE(HAVE_TANHF)
 338
 339     AC_DEFINE(HAVE_ICONV)
 340     AC_DEFINE(HAVE_MEMALIGN)
 341   else
 342     GLIBCXX_CROSSCONFIG
 343   fi
 344
 345   # At some point, we should differentiate between architectures
 346   # like x86, which have long double versions, and alpha/powerpc/etc.,
 347   # which don't. For the time being, punt.
 348   if test x"long_double_math_on_this_cpu" = x"yes"; then
 349     AC_DEFINE(HAVE_ACOSL)
 350     AC_DEFINE(HAVE_ASINL)
 351     AC_DEFINE(HAVE_ATAN2L)
 352     AC_DEFINE(HAVE_ATANL)
 353     AC_DEFINE(HAVE_CEILL)
 354     AC_DEFINE(HAVE_COSL)
 355     AC_DEFINE(HAVE_COSHL)
 356     AC_DEFINE(HAVE_EXPL)
 357     AC_DEFINE(HAVE_FABSL)
 358     AC_DEFINE(HAVE_FLOORL)
 359     AC_DEFINE(HAVE_FMODL)
 360     AC_DEFINE(HAVE_FREXPL)
 361     AC_DEFINE(HAVE_LDEXPL)
 362     AC_DEFINE(HAVE_LOG10L)
 363     AC_DEFINE(HAVE_LOGL)
 364     AC_DEFINE(HAVE_MODFL)
 365     AC_DEFINE(HAVE_POWL)
 366     AC_DEFINE(HAVE_SINCOSL)
 367     AC_DEFINE(HAVE_SINL)
 368     AC_DEFINE(HAVE_SINHL)
 369     AC_DEFINE(HAVE_SQRTL)
 370     AC_DEFINE(HAVE_TANL)
 371     AC_DEFINE(HAVE_TANHL)
 372   fi
 373 fi
 374
 375 # Check for _Unwind_GetIPInfo.
 376 GCC_CHECK_UNWIND_GETIPINFO
 377
 378 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
 379
 380 GCC_HEADER_STDINT(include/gstdint.h)
 381
 382 GLIBCXX_ENABLE_SYMVERS([yes])
 383 AC_SUBST(libtool_VERSION)
 384
 385 GLIBCXX_ENABLE_LIBSTDCXX_VISIBILITY([yes])
 386
 387 GLIBCXX_ENABLE_LIBSTDCXX_DUAL_ABI([yes])
 388 GLIBCXX_DEFAULT_ABI
 389
 390 ac_ldbl_compat=no
 391 LONG_DOUBLE_COMPAT_FLAGS="-mlong-double-64"
 392 case "$target" in
 393   powerpc*-*-linux* | \
 394   sparc*-*-linux* | \
 395   s390*-*-linux* | \
 396   alpha*-*-linux*)
 397   AC_TRY_COMPILE(, [
 398 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 399 #error no need for long double compatibility
 400 #endif
 401   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 402   if test "$ac_ldbl_compat" = yes; then
 403     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 404               [Define if compatibility should be provided for -mlong-double-64.])
 405     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 406     case "$target" in
 407       powerpc*-*-linux*)
 408         LONG_DOUBLE_COMPAT_FLAGS="$LONG_DOUBLE_COMPAT_FLAGS -mno-gnu-attribute" ;;
 409     esac
 410   fi
 411 esac
 412 AC_SUBST(LONG_DOUBLE_COMPAT_FLAGS)
 413 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 414
 415 # Check if assembler supports disabling hardware capability support.
 416 GCC_CHECK_ASSEMBLER_HWCAP
 417
 418 # Check if assembler supports rdrand opcode.
 419 GLIBCXX_CHECK_X86_RDRAND
 420
 421 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 422 GLIBCXX_CONFIGURE_TESTSUITE
 423
 424 # For gthread support.  Depends on GLIBCXX_ENABLE_SYMVERS.
 425 GLIBCXX_CHECK_GTHREADS
 426
 427 # For Filesystem TS.
 428 AC_CHECK_HEADERS([fcntl.h dirent.h sys/statvfs.h utime.h])
 429 GLIBCXX_ENABLE_FILESYSTEM_TS
 430 GLIBCXX_CHECK_FILESYSTEM_DEPS
 431
 432 # For Networking TS.
 433 AC_CHECK_HEADERS([fcntl.h sys/ioctl.h sys/socket.h sys/uio.h poll.h netdb.h arpa/inet.h netinet/in.h netinet/tcp.h])
 434
 435 # For Transactional Memory TS
 436 GLIBCXX_CHECK_SIZE_T_MANGLING
 437
 438 # Check which release added std::exception_ptr for the target
 439 GLIBCXX_CHECK_EXCEPTION_PTR_SYMVER
 440
 441 # Define documentation rules conditionally.
 442
 443 # See if makeinfo has been installed and is modern enough
 444 # that we can use it.
 445 ACX_CHECK_PROG_VER([MAKEINFO], [makeinfo], [--version],
 446                    [GNU texinfo.* \([0-9][0-9.]*\)],
 447                    [4.[4-9]*|4.[1-9][0-9]*|[5-9]*|[1-9][0-9]*])
 448 AM_CONDITIONAL(BUILD_INFO, test $gcc_cv_prog_makeinfo_modern = "yes")
 449
 450 # Check for doxygen
 451 AC_CHECK_PROG([DOXYGEN], doxygen, yes, no)
 452 AC_CHECK_PROG([DOT], dot, yes, no)
 453
 454 # Check for docbook
 455 AC_CHECK_PROG([XMLCATALOG], xmlcatalog, yes, no)
 456 AC_CHECK_PROG([XSLTPROC], xsltproc, yes, no)
 457 AC_CHECK_PROG([XMLLINT], xmllint, yes, no)
 458 GLIBCXX_CONFIGURE_DOCBOOK
 459
 460 # Check for xml/html dependencies.
 461 AM_CONDITIONAL(BUILD_XML,
 462                test $ac_cv_prog_DOXYGEN = "yes" &&
 463                test $ac_cv_prog_DOT = "yes" &&
 464                test $ac_cv_prog_XSLTPROC = "yes" &&
 465                test $ac_cv_prog_XMLLINT = "yes" &&
 466                test $glibcxx_stylesheets = "yes")
 467
 468 AM_CONDITIONAL(BUILD_HTML,
 469                test $ac_cv_prog_DOXYGEN = "yes" &&
 470                test $ac_cv_prog_DOT = "yes" &&
 471                test $ac_cv_prog_XSLTPROC = "yes" &&
 472                test $ac_cv_prog_XMLLINT = "yes" &&
 473                test $glibcxx_stylesheets = "yes")
 474
 475 # Check for man dependencies.
 476 AM_CONDITIONAL(BUILD_MAN,
 477                test $ac_cv_prog_DOXYGEN = "yes" &&
 478                test $ac_cv_prog_DOT = "yes")
 479
 480 # Check for pdf dependencies.
 481 AC_CHECK_PROG([DBLATEX], dblatex, yes, no)
 482 AC_CHECK_PROG([PDFLATEX], pdflatex, yes, no)
 483 AM_CONDITIONAL(BUILD_PDF,
 484                test $ac_cv_prog_DBLATEX = "yes" &&
 485                test $ac_cv_prog_PDFLATEX = "yes")
 486
 487 case "$build" in
 488  *-*-darwin* ) glibcxx_include_dir_notparallel=yes ;;
 489  * ) glibcxx_include_dir_notparallel=no ;;
 490 esac
 491 AM_CONDITIONAL(INCLUDE_DIR_NOTPARALLEL,
 492                test $glibcxx_include_dir_notparallel = "yes")
 493
 494 # Propagate the target-specific source directories through the build chain.
 495 ATOMICITY_SRCDIR=config/${atomicity_dir}
 496 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 497 ATOMIC_FLAGS=${atomic_flags}
 498 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 499 OS_INC_SRCDIR=config/${os_include_dir}
 500 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 501 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 502 CPU_OPT_EXT_RANDOM=config/${cpu_opt_ext_random}
 503 CPU_OPT_BITS_RANDOM=config/${cpu_opt_bits_random}
 504 AC_SUBST(ATOMICITY_SRCDIR)
 505 AC_SUBST(ATOMIC_WORD_SRCDIR)
 506 AC_SUBST(ATOMIC_FLAGS)
 507 AC_SUBST(CPU_DEFINES_SRCDIR)
 508 AC_SUBST(ABI_TWEAKS_SRCDIR)
 509 AC_SUBST(OS_INC_SRCDIR)
 510 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 511 AC_SUBST(CPU_OPT_EXT_RANDOM)
 512 AC_SUBST(CPU_OPT_BITS_RANDOM)
 513
 514
 515 # Add CET specific flags if Intel CET is enabled.
 516 GCC_CET_FLAGS(CET_FLAGS)
 517 EXTRA_CXX_FLAGS="$EXTRA_CXX_FLAGS $CET_FLAGS"
 518 EXTRA_CFLAGS="$EXTRA_CFLAGS $CET_FLAGS"
 519 AC_SUBST(EXTRA_CFLAGS)
 520 AC_SUBST(EXTRA_CXX_FLAGS)
 521
 522 # Determine cross-compile flags and AM_CONDITIONALs.
 523 #AC_SUBST(GLIBCXX_IS_NATIVE)
 524 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 525 GLIBCXX_EVALUATE_CONDITIONALS
 526
 527 AC_CACHE_SAVE
 528
 529 if test ${multilib} = yes; then
 530   multilib_arg="--enable-multilib"
 531 else
 532   multilib_arg=
 533 fi
 534
 535 # Export all the install information.
 536 GLIBCXX_EXPORT_INSTALL_INFO
 537
 538 # Export all the include and flag information to Makefiles.
 539 GLIBCXX_EXPORT_INCLUDES
 540 GLIBCXX_EXPORT_FLAGS
 541
 542 # Determine what GCC version number to use in filesystem paths.
 543 GCC_BASE_VER
 544
 545 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 546 dnl which can all be called multiple times as needed, plus one (different)
 547 dnl AC_OUTPUT macro.  This one lists the files to be created:
 548 AC_CONFIG_FILES(Makefile)
 549 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 550 AC_CONFIG_FILES([scripts/extract_symvers],[chmod +x scripts/extract_symvers])
 551 AC_CONFIG_FILES([doc/xsl/customization.xsl])
 552
 553 # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 554 # that multilib installs will end up installed in the correct place.
 555 # The testsuite needs it for multilib-aware ABI baseline files.
 556 # To work around this not being passed down from config-ml.in ->
 557 # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 558 # append it here.  Only modify Makefiles that have just been created.
 559 #
 560 # Also, get rid of this simulated-VPATH thing that automake does.
 561 AC_CONFIG_FILES(AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ]),
 562   [cat > vpsed$$ << \_EOF
 563 s!`test -f '$<' || echo '$(srcdir)/'`!!
 564 _EOF
 565    sed -f vpsed$$ $ac_file > tmp$$
 566    mv tmp$$ $ac_file
 567    rm vpsed$$
 568    echo 'MULTISUBDIR =' >> $ac_file
 569    ml_norecursion=yes
 570    . ${multi_basedir}/config-ml.in
 571    AS_UNSET([ml_norecursion])
 572 ])
 573
 574 AC_CONFIG_COMMANDS([generate-headers],
 575   [(cd include && ${MAKE-make} pch_build= )])
 576
 577 dnl And this actually makes things happen:
 578 AC_OUTPUT