gcc/ada/a-exextr.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                         GNAT COMPILER COMPONENTS                         --
   4 --                                                                          --
   5 --                      ADA.EXCEPTIONS.EXCEPTION_TRACES                     --
   6 --                                                                          --
   7 --                                 B o d y                                  --
   8 --                                                                          --
   9 --          Copyright (C) 1992-2012, Free Software Foundation, Inc.         --
  10 --                                                                          --
  11 -- GNAT is free software;  you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 3,  or (at your option) any later ver- --
  14 -- sion.  GNAT is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.                                     --
  17 --                                                                          --
  18 -- As a special exception under Section 7 of GPL version 3, you are granted --
  19 -- additional permissions described in the GCC Runtime Library Exception,   --
  20 -- version 3.1, as published by the Free Software Foundation.               --
  21 --                                                                          --
  22 -- You should have received a copy of the GNU General Public License and    --
  23 -- a copy of the GCC Runtime Library Exception along with this program;     --
  24 -- see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see    --
  25 -- <http://www.gnu.org/licenses/>.                                          --
  26 --                                                                          --
  27 -- GNAT was originally developed  by the GNAT team at  New York University. --
  28 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  29 --                                                                          --
  30 ------------------------------------------------------------------------------
  31
  32 with Ada.Unchecked_Conversion;
  33
  34 pragma Warnings (Off);
  35 with Ada.Exceptions.Last_Chance_Handler;
  36 pragma Warnings (On);
  37 --  Bring last chance handler into closure
  38
  39 separate (Ada.Exceptions)
  40 package body Exception_Traces is
  41
  42    Nline : constant String := String'(1 => ASCII.LF);
  43    --  Convenient shortcut
  44
  45    type Exception_Action is access procedure (E : Exception_Occurrence);
  46    Global_Action : Exception_Action := null;
  47    pragma Export
  48      (Ada, Global_Action, "__gnat_exception_actions_global_action");
  49    --  Global action, executed whenever an exception is raised.  Changing the
  50    --  export name must be coordinated with code in g-excact.adb.
  51
  52    Raise_Hook_Initialized : Boolean := False;
  53    pragma Export
  54      (Ada, Raise_Hook_Initialized, "__gnat_exception_actions_initialized");
  55
  56    procedure Last_Chance_Handler (Except : Exception_Occurrence);
  57    pragma Import (C, Last_Chance_Handler, "__gnat_last_chance_handler");
  58    pragma No_Return (Last_Chance_Handler);
  59    --  Users can replace the default version of this routine,
  60    --  Ada.Exceptions.Last_Chance_Handler.
  61
  62    function To_Action is new Ada.Unchecked_Conversion
  63      (Raise_Action, Exception_Action);
  64
  65    -----------------------
  66    -- Local Subprograms --
  67    -----------------------
  68
  69    procedure Notify_Exception (Excep : EOA; Is_Unhandled : Boolean);
  70    --  Factorizes the common processing for Notify_Handled_Exception and
  71    --  Notify_Unhandled_Exception. Is_Unhandled is set to True only in the
  72    --  latter case because Notify_Handled_Exception may be called for an
  73    --  actually unhandled occurrence in the Front-End-SJLJ case.
  74
  75    --------------------------------
  76    -- Import Run-Time C Routines --
  77    --------------------------------
  78
  79    --  The purpose of the following pragma Import is to ensure that we
  80    --  generate appropriate subprogram descriptors for all C routines in
  81    --  the standard GNAT library that can raise exceptions. This ensures
  82    --  that the exception propagation can properly find these routines
  83
  84    pragma Propagate_Exceptions;
  85
  86    ----------------------
  87    -- Notify_Exception --
  88    ----------------------
  89
  90    procedure Notify_Exception (Excep : EOA; Is_Unhandled : Boolean) is
  91    begin
  92       --  Output the exception information required by the Exception_Trace
  93       --  configuration. Take care not to output information about internal
  94       --  exceptions.
  95
  96       if not Excep.Id.Not_Handled_By_Others
  97         and then
  98           (Exception_Trace = Every_Raise
  99             or else (Exception_Trace = Unhandled_Raise and then Is_Unhandled))
 100       then
 101          --  Exception trace messages need to be protected when several tasks
 102          --  can issue them at the same time.
 103
 104          Lock_Task.all;
 105          To_Stderr (Nline);
 106
 107          if Is_Unhandled then
 108             To_Stderr ("Unhandled ");
 109          end if;
 110
 111          To_Stderr ("Exception raised");
 112          To_Stderr (Nline);
 113          To_Stderr (Tailored_Exception_Information (Excep.all));
 114          Unlock_Task.all;
 115       end if;
 116
 117       --  Call the user-specific actions
 118       --  ??? We should presumably look at the reraise status here.
 119
 120       if Raise_Hook_Initialized
 121         and then Exception_Data_Ptr (Excep.Id).Raise_Hook /= null
 122       then
 123          To_Action (Exception_Data_Ptr (Excep.Id).Raise_Hook) (Excep.all);
 124       end if;
 125
 126       if Global_Action /= null then
 127          Global_Action (Excep.all);
 128       end if;
 129    end Notify_Exception;
 130
 131    ------------------------------
 132    -- Notify_Handled_Exception --
 133    ------------------------------
 134
 135    procedure Notify_Handled_Exception is
 136    begin
 137       Notify_Exception (Get_Current_Excep.all, Is_Unhandled => False);
 138    end Notify_Handled_Exception;
 139
 140    --------------------------------
 141    -- Notify_Unhandled_Exception --
 142    --------------------------------
 143
 144    procedure Notify_Unhandled_Exception is
 145       Excep : constant EOA := Get_Current_Excep.all;
 146
 147    begin
 148       --  Check whether there is any termination handler to be executed for
 149       --  the environment task, and execute it if needed. Here we handle both
 150       --  the Abnormal and Unhandled_Exception task termination. Normal
 151       --  task termination routine is executed elsewhere (either in the
 152       --  Task_Wrapper or in the Adafinal routine for the environment task).
 153
 154       Task_Termination_Handler.all (Excep.all);
 155
 156       Notify_Exception (Excep, Is_Unhandled => True);
 157       Debug_Unhandled_Exception (SSL.Exception_Data_Ptr (Excep.Id));
 158    end Notify_Unhandled_Exception;
 159
 160    -----------------------------------
 161    -- Unhandled_Exception_Terminate --
 162    -----------------------------------
 163
 164    procedure Unhandled_Exception_Terminate is
 165       Excep : Exception_Occurrence;
 166       --  This occurrence will be used to display a message after finalization.
 167       --  It is necessary to save a copy here, or else the designated value
 168       --  could be overwritten if an exception is raised during finalization
 169       --  (even if that exception is caught). The occurrence is saved on the
 170       --  stack to avoid dynamic allocation (if this exception is due to lack
 171       --  of space in the heap, we therefore avoid a second failure). We assume
 172       --  that there is enough room on the stack however.
 173
 174    begin
 175       Save_Occurrence (Excep, Get_Current_Excep.all.all);
 176       Last_Chance_Handler (Excep);
 177    end Unhandled_Exception_Terminate;
 178
 179    ------------------------------------
 180    -- Handling GNAT.Exception_Traces --
 181    ------------------------------------
 182
 183    --  The bulk of exception traces output is centralized in Notify_Exception,
 184    --  for both the Handled and Unhandled cases. Extra task specific output is
 185    --  triggered in the task wrapper for unhandled occurrences in tasks. It is
 186    --  not performed in this unit to avoid dragging dependencies against the
 187    --  tasking units here.
 188
 189    --  We used to rely on the output performed by Unhanded_Exception_Terminate
 190    --  for the case of an unhandled occurrence in the environment thread, and
 191    --  the task wrapper was responsible for the whole output in the tasking
 192    --  case.
 193
 194    --  This initial scheme had a drawback: the output from Terminate only
 195    --  occurs after finalization is done, which means possibly never if some
 196    --  tasks keep hanging around.
 197
 198    --  The first "presumably obvious" fix consists in moving the Terminate
 199    --  output before the finalization. It has not been retained because it
 200    --  introduces annoying changes in output orders when the finalization
 201    --  itself issues outputs, this also in "regular" cases not resorting to
 202    --  Exception_Traces.
 203
 204    --  Today's solution has the advantage of simplicity and better isolates
 205    --  the Exception_Traces machinery.
 206
 207    --  It currently outputs the information about unhandled exceptions twice
 208    --  in the environment thread, once in the notification routine and once in
 209    --  the termination routine. Avoiding the second output is possible but so
 210    --  far has been considered undesirable. It would mean changing the order
 211    --  of outputs between the two runs with or without exception traces, while
 212    --  it seems preferable to only have additional outputs in the former
 213    --  case.
 214
 215 end Exception_Traces;