libjava/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(java/lang/System.java)
   3
   4 dnl Can't be done in LIBGCJ_CONFIGURE because that confuses automake.
   5 AC_CONFIG_AUX_DIR(..)
   6
   7 AC_CANONICAL_SYSTEM
   8 AC_PROG_LN_S
   9
  10 dnl We use these options to decide which functions to include.
  11 AC_ARG_WITH(target-subdir,
  12 [  --with-target-subdir=SUBDIR
  13                            configuring in a subdirectory])
  14 AC_ARG_WITH(cross-host,
  15 [  --with-cross-host=HOST  configuring with a cross compiler])
  16
  17 LIBGCJ_CONFIGURE(.)
  18
  19 AM_CONFIG_HEADER(include/config.h gcj/libgcj-config.h)
  20
  21 # Only use libltdl for native builds.
  22 if test -z "${with_cross_host}"; then
  23    AC_LIBLTDL_CONVENIENCE
  24    AC_LIBTOOL_DLOPEN
  25    DIRLTDL=libltdl
  26    AC_DEFINE(USE_LTDL)
  27    # Sigh.  Libtool's macro doesn't do the right thing.
  28    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
  29 fi
  30 AC_SUBST(INCLTDL)
  31 AC_SUBST(LIBLTDL)
  32 AC_SUBST(DIRLTDL)
  33 AM_PROG_LIBTOOL
  34 AC_CONFIG_SUBDIRS($DIRLTDL)
  35
  36 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  37    COMPPATH=.
  38 else
  39    COMPPATH=..
  40 fi
  41 AC_SUBST(COMPPATH)
  42
  43 dnl The -no-testsuite modules omit the test subdir.
  44 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  45
  46 dnl See whether the user prefers size or speed for Character.
  47 dnl The default is size.
  48 AC_ARG_ENABLE(fast-character,
  49 [  --enable-fast-character prefer speed over size for Character],
  50 # Nothing
  51 , AC_DEFINE(COMPACT_CHARACTER))
  52
  53 dnl Should the runtime set system properties by examining the
  54 dnl environment variable GCJ_PROPERTIES?
  55 AC_ARG_ENABLE(getenv-properties,
  56 [  --disable-getenv-properties
  57                           don't set system properties from GCJ_PROPERTIES])
  58
  59 dnl Whether GCJ_PROPERTIES is used depends on the target.
  60 if test -z "$enable_getenv_properties"; then
  61    enable_getenv_properties=${enable_getenv_properties_default-yes}
  62 fi
  63 if test "$enable_getenv_properties" = no; then
  64    AC_DEFINE(DISABLE_GETENV_PROPERTIES)
  65 fi
  66
  67
  68 dnl Should we use hashtable-based synchronization?
  69 dnl Currently works only for Linux X86/ia64
  70 dnl Typically faster and more space-efficient
  71 AC_ARG_ENABLE(hash-synchronization,
  72 [  --enable-hash-synchronization
  73                           Use global hash table for monitor locks])
  74
  75 if test -z "$enable_hash_synchronization"; then
  76    enable_hash_synchronization=$enable_hash_synchronization_default
  77 fi
  78 HASH_SYNC_SPEC=
  79 if test "$enable_hash_synchronization" = yes; then
  80    HASH_SYNC_SPEC=-fhash-synchronization
  81    AC_DEFINE(JV_HASH_SYNCHRONIZATION)
  82 fi
  83 AC_SUBST(HASH_SYNC_SPEC)
  84
  85
  86 dnl See if the user has requested runtime debugging.
  87 LIBGCJDEBUG="false"
  88 AC_SUBST(LIBGCJDEBUG)
  89 AC_ARG_ENABLE(libgcj-debug,
  90 [  --enable-libgcj-debug   enable runtime debugging code],
  91   if test "$enable_libgcj_debug" = yes; then
  92     AC_DEFINE(DEBUG)
  93     LIBGCJDEBUG="true"
  94   fi)
  95
  96 dnl See if the user has the interpreter included.
  97 AC_ARG_ENABLE(interpreter,
  98 [  --enable-interpreter    enable interpreter],
  99   if test "$enable_interpreter" = yes; then
 100     # This can also be set in configure.host.
 101     libgcj_interpreter=yes
 102   elif test "$enable_interpreter" = no; then
 103     libgcj_interpreter=no
 104   fi)
 105
 106 if test "$libgcj_interpreter" = yes; then
 107    AC_DEFINE(INTERPRETER)
 108 fi
 109
 110 AC_MSG_CHECKING([for exception model to use])
 111 AC_LANG_SAVE
 112 AC_LANG_CPLUSPLUS
 113 AC_ARG_ENABLE(sjlj-exceptions,
 114 [  --enable-sjlj-exceptions  force use of builtin_setjmp for exceptions],
 115 [:],
 116 [dnl Botheration.  Now we've got to detect the exception model.
 117 dnl Link tests against libgcc.a are problematic since -- at least
 118 dnl as of this writing -- we've not been given proper -L bits for
 119 dnl single-tree newlib and libgloss.
 120 dnl
 121 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 122 dnl conftest files before we got a change to grep them first.
 123 cat > conftest.$ac_ext << EOF
 124 [#]line __oline__ "configure"
 125 struct S { ~S(); };
 126 void bar();
 127 void foo()
 128 {
 129   S s;
 130   bar();
 131 }
 132 EOF
 133 old_CXXFLAGS="$CXXFLAGS"
 134 CXXFLAGS=-S
 135 if AC_TRY_EVAL(ac_compile); then
 136   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 137     enable_sjlj_exceptions=yes
 138   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 139     enable_sjlj_exceptions=no
 140   fi
 141 fi
 142 CXXFLAGS="$old_CXXFLAGS"
 143 rm -f conftest*])
 144 if test x$enable_sjlj_exceptions = xyes; then
 145   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 146         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 147   ac_exception_model_name=sjlj
 148 elif test x$enable_sjlj_exceptions = xno; then
 149   ac_exception_model_name="call frame"
 150 else
 151   AC_MSG_ERROR([unable to detect exception model])
 152 fi
 153 AC_LANG_RESTORE
 154 AC_MSG_RESULT($ac_exception_model_name)
 155
 156 AC_MSG_CHECKING([for data_start])
 157 LIBDATASTARTSPEC=
 158 NEEDS_DATA_START=
 159 AC_TRY_LINK([extern int data_start;], [return ((int) &data_start);],
 160   [AC_MSG_RESULT(found it)],
 161   [LIBDATASTARTSPEC="-u data_start libgcjdata.a%s"
 162    NEEDS_DATA_START=yes
 163    AC_MSG_RESULT(missing)])
 164 AC_SUBST(LIBDATASTARTSPEC)
 165
 166 dnl See if the user wants to disable java.net.  This is the mildly
 167 dnl ugly way that we admit that target-side configuration sucks.
 168 AC_ARG_ENABLE(java-net,
 169 [  --disable-java-net      disable java.net])
 170
 171 dnl Whether java.net is built by default can depend on the target.
 172 if test -z "$enable_java_net"; then
 173    enable_java_net=${enable_java_net_default-yes}
 174 fi
 175 if test "$enable_java_net" = no; then
 176    AC_DEFINE(DISABLE_JAVA_NET)
 177 fi
 178
 179 dnl See if the user wants to disable JVMPI support.
 180 AC_ARG_ENABLE(jvmpi,
 181 [  --disable-jvmpi         disable JVMPI support])
 182
 183 if test "$enable_jvmpi" != no; then
 184     AC_DEFINE(ENABLE_JVMPI)
 185 fi
 186
 187 dnl If the target is an eCos system, use the appropriate eCos
 188 dnl I/O routines.
 189 dnl FIXME: this should not be a local option but a global target
 190 dnl system; at present there is no eCos target.
 191 TARGET_ECOS="no"
 192 AC_ARG_WITH(ecos,
 193 [  --with-ecos             enable runtime eCos target support],
 194 TARGET_ECOS="$with_ecos"
 195 )
 196
 197 case "$TARGET_ECOS" in
 198    no)
 199       FILE_DESCRIPTOR=natFileDescriptorPosix.cc
 200       PROCESS=${PROCESS-Posix}
 201       ;;
 202    *)
 203       FILE_DESCRIPTOR=natFileDescriptorEcos.cc
 204       PROCESS=Ecos
 205       AC_DEFINE(ECOS)
 206       ;;
 207 esac
 208
 209 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED))
 210 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED))
 211 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 212 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 213
 214
 215 dnl These may not be defined in a non-ANS conformant embedded system.
 216 dnl FIXME: Should these case a runtime exception in that case?
 217 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME))
 218 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME))
 219
 220 dnl Create the subdirectory for natFileDescriptor.cc, or the attempt
 221 dnl to create the link will fail.
 222 test -d java || mkdir java
 223 test -d java/io || mkdir java/io
 224 test -d gnu || mkdir gnu
 225 AC_LINK_FILES(java/io/$FILE_DESCRIPTOR, java/io/natFileDescriptor.cc)
 226
 227 dnl Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 228 test -d java/lang || mkdir java/lang
 229 AC_LINK_FILES(java/lang/${PROCESS}Process.java, java/lang/ConcreteProcess.java)
 230 AC_LINK_FILES(java/lang/nat${PROCESS}Process.cc, java/lang/natConcreteProcess.cc)
 231
 232 SYSTEMSPEC=
 233 AC_SUBST(SYSTEMSPEC)
 234
 235 LIBGCJTESTSPEC="-L`pwd`/.libs -rpath `pwd`/.libs"
 236 AC_SUBST(LIBGCJTESTSPEC)
 237
 238 AC_ARG_WITH(system-zlib,
 239 [  --with-system-zlib      use installed libz])
 240 ZLIBSPEC=
 241 AC_SUBST(ZLIBSPEC)
 242 ZLIBTESTSPEC=
 243 AC_SUBST(ZLIBTESTSPEC)
 244
 245 dnl FIXME: this should be _libs on some hosts.
 246 libsubdir=.libs
 247
 248 dnl Allow the GC to be disabled.  Can be useful when debugging.
 249 AC_MSG_CHECKING([for garbage collector to use])
 250 AC_ARG_ENABLE(java-gc,
 251 changequote(<<,>>)dnl
 252 <<  --enable-java-gc=TYPE   choose garbage collector [boehm]>>,
 253 changequote([,])
 254   GC=$enableval,
 255   GC=boehm)
 256 GCLIBS=
 257 GCINCS=
 258 GCDEPS=
 259 GCOBJS=
 260 GCSPEC=
 261 JC1GCSPEC=
 262 GCTESTSPEC=
 263 case "$GC" in
 264  boehm)
 265     AC_MSG_RESULT(boehm)
 266     GCDEPS='$(top_builddir)/../boehm-gc/libgcjgc.la'
 267     # We include the path to the boehm-gc build directory.
 268     # See Makefile.am to understand why.
 269     GCLIBS="$GCDEPS -L\$(here)/../boehm-gc/$libsubdir"
 270     GCINCS='-I$(top_srcdir)/../boehm-gc/include'
 271     GCSPEC='-lgcjgc'
 272     JC1GCSPEC='-fuse-boehm-gc'
 273     GCTESTSPEC="-L`pwd`/../boehm-gc/.libs -rpath `pwd`/../boehm-gc/.libs"
 274     dnl We also want to pick up some cpp flags required when including
 275     dnl boehm-config.h.  Yuck.
 276     GCINCS="$GCINCS `cat ../boehm-gc/boehm-cflags`"
 277     GCOBJS=boehm.lo
 278     GCHDR=boehm-gc.h
 279     dnl The POSIX thread support needs to know this.
 280     AC_DEFINE(HAVE_BOEHM_GC)
 281     ;;
 282  no)
 283     AC_MSG_RESULT(none)
 284     GCOBJS=nogc.lo
 285     GCHDR=no-gc.h
 286     ;;
 287  *)
 288     AC_MSG_ERROR(unrecognized collector \"$GC\")
 289     ;;
 290 esac
 291 AC_SUBST(GCLIBS)
 292 AC_SUBST(GCINCS)
 293 AC_SUBST(GCDEPS)
 294 AC_SUBST(GCOBJS)
 295 AC_SUBST(GCSPEC)
 296 AC_SUBST(JC1GCSPEC)
 297 AC_SUBST(GCTESTSPEC)
 298 AC_LINK_FILES(include/$GCHDR, include/java-gc.h)
 299
 300
 301 AC_MSG_CHECKING([for thread model used by GCC])
 302 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 303 AC_MSG_RESULT([$THREADS])
 304
 305 case "$THREADS" in
 306  no | none | single)
 307     THREADS=none
 308     ;;
 309  posix | pthreads)
 310     THREADS=posix
 311     case "$host" in
 312      *-*-linux*)
 313         AC_DEFINE(LINUX_THREADS)
 314         ;;
 315     esac
 316     ;;
 317  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
 318     AC_MSG_ERROR(thread package $THREADS not yet supported)
 319     ;;
 320  *)
 321     AC_MSG_ERROR($THREADS is an unknown thread package)
 322     ;;
 323 esac
 324
 325 THREADLIBS=
 326 THREADINCS=
 327 THREADDEPS=
 328 THREADOBJS=
 329 THREADH=
 330 THREADSPEC=
 331 case "$THREADS" in
 332  posix)
 333     THREADLIBS=-lpthread
 334     THREADSPEC=-lpthread
 335     THREADOBJS=posix-threads.lo
 336     THREADH=posix-threads.h
 337     # MIT pthreads doesn't seem to have the mutexattr functions.
 338     # But for now we don't check for it.  We just assume you aren't
 339     # using MIT pthreads.
 340     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 341
 342     # If we're using the Boehm GC, then we happen to know that it
 343     # defines _REENTRANT, so we don't bother.  Eww.
 344     if test "$GC" != boehm; then
 345        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 346     fi
 347     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 348     ;;
 349
 350  none)
 351     THREADOBJS=no-threads.lo
 352     THREADH=no-threads.h
 353     ;;
 354 esac
 355 AC_LINK_FILES(include/$THREADH, include/java-threads.h)
 356 AC_SUBST(THREADLIBS)
 357 AC_SUBST(THREADINCS)
 358 AC_SUBST(THREADDEPS)
 359 AC_SUBST(THREADOBJS)
 360 AC_SUBST(THREADSPEC)
 361
 362 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 363
 364 CANADIAN=no
 365 NULL_TARGET=no
 366 NATIVE=yes
 367
 368 # We're in the tree with gcc, and need to include some of its headers.
 369 GCC_UNWIND_INCLUDE='-I$(top_srcdir)/../gcc'
 370
 371 if test -n "${with_cross_host}"; then
 372    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 373    # may not work correctly, because the compiler may not be able to
 374    # link executables.
 375
 376    # We assume newlib.  This lets us hard-code the functions we know
 377    # we'll have.
 378    AC_DEFINE(HAVE_MEMMOVE)
 379    AC_DEFINE(HAVE_MEMCPY)
 380    AC_DEFINE(HAVE_STRERROR)
 381    AC_DEFINE(HAVE_GMTIME_R)
 382    AC_DEFINE(HAVE_LOCALTIME_R)
 383    dnl This is only for POSIX threads.
 384    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 385    dnl We also assume we are using gcc, which provides alloca.
 386    AC_DEFINE(HAVE_ALLOCA)
 387
 388    dnl Assume we do not have getuid and friends.
 389    AC_DEFINE(NO_GETUID)
 390
 391    ZLIBSPEC=-lzgcj
 392    ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 393
 394    # If Canadian cross, then don't pick up tools from the build
 395    # directory.
 396    if test x"$build" != x"$with_cross_host" && x"$build" != x"$target"; then
 397       CANADIAN=yes
 398       GCC_UNWIND_INCLUDE=
 399       GCJ="${target_alias}-gcj"
 400    fi
 401    NATIVE=no
 402 else
 403    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep)
 404    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r getcwd)
 405    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath utime chmod)
 406    AC_CHECK_FUNCS(iconv nl_langinfo setlocale)
 407    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 408    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 409    AC_CHECK_FUNCS(backtrace fork execvp pipe)
 410    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 411    AC_CHECK_LIB(dl, dladdr, [
 412      AC_DEFINE(HAVE_DLADDR)])
 413    AC_CHECK_FILES(/proc/self/exe, [
 414      AC_DEFINE(HAVE_PROC_SELF_EXE)])
 415
 416    AC_CHECK_FUNCS(gethostbyname_r, [
 417      AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 418      # There are two different kinds of gethostbyname_r.
 419      # We look for the one that returns `int'.
 420      # Hopefully this check is robust enough.
 421      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 422        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT)])
 423
 424      case " $GCINCS " in
 425      *" -D_REENTRANT "*) ;;
 426      *)
 427         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 428         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 429         [libjava_cv_gethostbyname_r_needs_reentrant],
 430         [ AC_LANG_SAVE
 431           AC_LANG_CPLUSPLUS
 432           AC_TRY_COMPILE([#include <netdb.h>],
 433             [gethostbyname_r("", 0, 0);],
 434             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 435                 CPPFLAGS_SAVE="$CPPFLAGS"
 436                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 437                 AC_TRY_COMPILE([#include <netdb.h>], [gethostbyname_r("", 0, 0);],
 438                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 439                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 440                 CPPFLAGS="$CPPFLAGS_SAVE"
 441           ])
 442           AC_LANG_RESTORE
 443         ])
 444         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 445           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 446         fi
 447      ;;
 448      esac
 449
 450      AC_CACHE_CHECK([for struct hostent_data],
 451         [libjava_cv_struct_hostent_data], [dnl
 452         AC_TRY_COMPILE([
 453 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 454 # define _REENTRANT 1
 455 #endif
 456 #include <netdb.h>], [struct hostent_data data;],
 457           [libjava_cv_struct_hostent_data=yes],
 458           [libjava_cv_struct_hostent_data=no])])
 459      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 460        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 461          [Define if struct hostent_data is defined in netdb.h])
 462      fi
 463    ])
 464
 465    AC_CHECK_FUNCS(gethostbyaddr_r, [
 466      AC_DEFINE(HAVE_GETHOSTBYADDR_R)
 467      # There are two different kinds of gethostbyaddr_r.
 468      # We look for the one that returns `int'.
 469      # Hopefully this check is robust enough.
 470      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 471        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT)])])
 472
 473    AC_CHECK_FUNCS(gethostname, [
 474      AC_DEFINE(HAVE_GETHOSTNAME)
 475      AC_EGREP_HEADER(gethostname, unistd.h, [
 476        AC_DEFINE(HAVE_GETHOSTNAME_DECL)])])
 477
 478    # Look for these functions in the thread library, but only bother
 479    # if using POSIX threads.
 480    if test "$THREADS" = posix; then
 481       save_LIBS="$LIBS"
 482       LIBS="$LIBS $THREADLIBS"
 483       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 484       # E.g., Solaris.
 485       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 486
 487       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 488       # Solaris 7 the name librt is preferred.
 489       AC_CHECK_FUNCS(sched_yield, , [
 490         AC_CHECK_LIB(rt, sched_yield, [
 491           AC_DEFINE(HAVE_SCHED_YIELD)
 492           THREADLIBS="$THREADLIBS -lrt"
 493           THREADSPEC="$THREADSPEC -lrt"], [
 494           AC_CHECK_LIB(posix4, sched_yield, [
 495             AC_DEFINE(HAVE_SCHED_YIELD)
 496             THREADLIBS="$THREADLIBS -lposix4"
 497             THREADSPEC="$THREADSPEC -lposix4"])])])
 498       LIBS="$save_LIBS"
 499
 500       # We can save a little space at runtime if the mutex has m_count
 501       # or __m_count.  This is a nice hack for Linux.
 502       AC_TRY_COMPILE([#include <pthread.h>], [
 503           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 504         ], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT), [
 505         AC_TRY_COMPILE([#include <pthread.h>], [
 506             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 507           ], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT))])
 508    fi
 509
 510    # We require a way to get the time.
 511    time_found=no
 512    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 513    if test "$time_found" = no; then
 514       AC_MSG_ERROR([no function found to get the time])
 515    fi
 516
 517    AC_CHECK_FUNCS(memmove)
 518
 519    # We require memcpy.
 520    memcpy_found=no
 521    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 522    if test "$memcpy_found" = no; then
 523       AC_MSG_ERROR([memcpy is required])
 524    fi
 525
 526    # Some library-finding code we stole from Tcl.
 527    #--------------------------------------------------------------------
 528    #    Check for the existence of the -lsocket and -lnsl libraries.
 529    #    The order here is important, so that they end up in the right
 530    #    order in the command line generated by make.  Here are some
 531    #    special considerations:
 532    #    1. Use "connect" and "accept" to check for -lsocket, and
 533    #       "gethostbyname" to check for -lnsl.
 534    #    2. Use each function name only once:  can't redo a check because
 535    #       autoconf caches the results of the last check and won't redo it.
 536    #    3. Use -lnsl and -lsocket only if they supply procedures that
 537    #       aren't already present in the normal libraries.  This is because
 538    #       IRIX 5.2 has libraries, but they aren't needed and they're
 539    #       bogus:  they goof up name resolution if used.
 540    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 541    #       To get around this problem, check for both libraries together
 542    #       if -lsocket doesn't work by itself.
 543    #--------------------------------------------------------------------
 544
 545    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 546     [gcj_cv_lib_sockets=
 547      gcj_checkBoth=0
 548      unset ac_cv_func_connect
 549      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 550      if test "$gcj_checkSocket" = 1; then
 551          unset ac_cv_func_connect
 552          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 553                       gcj_checkBoth=1)
 554      fi
 555      if test "$gcj_checkBoth" = 1; then
 556          gcj_oldLibs=$LIBS
 557          LIBS="$LIBS -lsocket -lnsl"
 558          unset ac_cv_func_accept
 559          AC_CHECK_FUNC(accept,
 560                        [gcj_checkNsl=0
 561                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 562          unset ac_cv_func_accept
 563          LIBS=$gcj_oldLibs
 564      fi
 565      unset ac_cv_func_gethostbyname
 566      gcj_oldLibs=$LIBS
 567      LIBS="$LIBS $gcj_cv_lib_sockets"
 568      AC_CHECK_FUNC(gethostbyname, ,
 569                    [AC_CHECK_LIB(nsl, main,
 570                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 571      unset ac_cv_func_gethostbyname
 572      LIBS=$gcj_oldLIBS
 573    ])
 574    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 575
 576    if test "$with_system_zlib" = yes; then
 577       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=-lzgcj)
 578    else
 579       ZLIBSPEC=-lzgcj
 580       ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 581    fi
 582
 583    # On Solaris, and maybe other architectures, the Boehm collector
 584    # requires -ldl.
 585    if test "$GC" = boehm; then
 586       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
 587    fi
 588
 589    if test -z "${with_multisubdir}"; then
 590       builddotdot=.
 591    else
 592 changequote(<<,>>)
 593       builddotdot=`echo ${with_multisubdir} | sed -e 's:[^/][^/]*:..:g'`
 594 changequote([,])
 595    fi
 596    if test -x "${builddotdot}/../../gcc/gcj"; then
 597       dir="`cd ${builddotdot}/../../gcc && pwd`"
 598       GCJ="$dir/gcj -B`pwd`/ -B$dir/"
 599    else
 600       CANADIAN=yes
 601       NULL_TARGET=yes
 602       GCJ="gcj -B`pwd`/"
 603    fi
 604 fi
 605
 606 # Create it, so that compile/link tests don't fail
 607 test -f libgcj.spec || touch libgcj.spec
 608
 609 # We must search the source tree for java.lang, since we still don't
 610 # have libgcj.jar nor java/lang/*.class
 611 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
 612 CPPFLAGS="$CPPFLAGS -I`pwd` -I`cd $srcdir && pwd`"
 613
 614 # Since some classes depend on this one, we need its source available
 615 # before we can do any GCJ compilation test :-(
 616 if test ! -f gnu/classpath/Configuration.java; then
 617   test -d gnu || mkdir gnu
 618   test -d gnu/classpath || mkdir gnu/classpath
 619   sed 's,@LIBGCJDEBUG@,$LIBGCJDEBUG,' \
 620         < $srcdir/gnu/classpath/Configuration.java.in \
 621         > gnu/classpath/Configuration.java
 622   # We do not want to redirect the output of the grep below to /dev/null,
 623   # but we add /dev/null to the input list so that grep will print the
 624   # filename of Configuration.java in case it finds any matches.
 625   if grep @ gnu/classpath/Configuration.java /dev/null; then
 626     AC_MSG_ERROR([configure.in is missing the substitutions above])
 627   fi
 628 fi
 629
 630 LT_AC_PROG_GCJ
 631
 632 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
 633
 634 dnl FIXME: cross compilation
 635 AC_CHECK_SIZEOF(void *)
 636
 637 ZLIBS=
 638 ZDEPS=
 639 ZINCS=
 640 if test "x$ZLIBSPEC" = "x-lzgcj"; then
 641    # We include the path to the zlib build directory.
 642    # See Makefile.am to understand why.
 643    ZDEPS='$(top_builddir)/../zlib/libzgcj.la'
 644    ZLIBS="$ZDEPS -L\$(here)/../zlib/$libsubdir"
 645    ZINCS='-I$(top_srcdir)/../zlib'
 646 else
 647    ZLIBS="$ZLIBSPEC"
 648 fi
 649 AC_SUBST(ZLIBS)
 650 AC_SUBST(ZDEPS)
 651 AC_SUBST(ZINCS)
 652 AC_SUBST(DIVIDESPEC)
 653 AC_SUBST(EXCEPTIONSPEC)
 654
 655 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 656 AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
 657 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes || test "$NULL_TARGET" = yes)
 658 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 659 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
 660 AC_SUBST(GCC_UNWIND_INCLUDE)
 661
 662 # Determine gcj version number.
 663 changequote(<<,>>)
 664 gcjvers="`$GCJ -v 2>&1 | sed -n 's/^.*version \([^ ]*\).*$/\1/p'`"
 665 changequote([,])
 666 AC_DEFINE_UNQUOTED(GCJVERSION, "$gcjvers")
 667 AC_SUBST(GCJVERSION)
 668
 669 AC_SUBST(AM_RUNTESTFLAGS)
 670
 671 dnl Work around a g++ bug.  Reported to gcc-bugs@gcc.gnu.org on Jan 22, 2000.
 672 AC_MSG_CHECKING([for g++ -ffloat-store bug])
 673 save_CFLAGS="$CFLAGS"
 674 CFLAGS="-x c++ -O2 -ffloat-store"
 675 AC_TRY_COMPILE([#include <math.h>], ,
 676   [AC_MSG_RESULT(no)],
 677   [AC_DEFINE(__NO_MATH_INLINES)
 678    AC_MSG_RESULT(yes)])
 679 CFLAGS="$save_CFLAGS"
 680
 681 dnl We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
 682 dnl On that system, sys/ioctl.h will not include sys/filio.h unless
 683 dnl BSD_COMP is defined; just including sys/filio.h is simpler.
 684 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h pwd.h sys/config.h inttypes.h stdint.h langinfo.h locale.h)
 685 dnl We avoid AC_HEADER_DIRENT since we really only care about dirent.h
 686 dnl for now.  If you change this, you also must update natFile.cc.
 687 AC_CHECK_HEADERS(dirent.h)
 688
 689 AC_CHECK_TYPE([ssize_t], [int])
 690
 691 AC_MSG_CHECKING([for in_addr_t])
 692 AC_TRY_COMPILE([#include <sys/types.h>
 693 #if STDC_HEADERS
 694 #include <stdlib.h>
 695 #include <stddef.h>
 696 #endif
 697 #if HAVE_NETINET_IN_H
 698 #include <netinet/in.h>
 699 #endif], [in_addr_t foo;],
 700   [AC_DEFINE([HAVE_IN_ADDR_T])
 701    AC_MSG_RESULT(yes)],
 702   [AC_MSG_RESULT(no)])
 703
 704 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
 705 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ip_mreq mreq;],
 706   [AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 707    AC_MSG_RESULT(yes)],
 708   [AC_MSG_RESULT(no)])
 709
 710 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
 711 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
 712   [AC_DEFINE(HAVE_INET6)
 713    AC_MSG_RESULT(yes)],
 714   [AC_MSG_RESULT(no)])
 715
 716 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
 717 AC_TRY_COMPILE([#include <sys/types.h>
 718 #include <sys/socket.h>], [socklen_t x = 5;],
 719   [AC_DEFINE(HAVE_SOCKLEN_T)
 720    AC_MSG_RESULT(yes)],
 721   [AC_MSG_RESULT(no)])
 722
 723 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
 724 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
 725   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF)
 726    AC_MSG_RESULT(yes)],
 727   [AC_MSG_RESULT(no)
 728    AC_MSG_CHECKING([for global timezone variable])
 729    dnl FIXME: we don't want a link check here because that won't work
 730    dnl when cross-compiling.  So instead we make an assumption that
 731    dnl the header file will mention timezone if it exists.
 732    AC_TRY_COMPILE([#include <time.h>], [long z2 = timezone;],
 733      [AC_DEFINE(HAVE_TIMEZONE)
 734       AC_MSG_RESULT(yes)],
 735      [AC_MSG_RESULT(no)])])
 736
 737 AC_FUNC_ALLOCA
 738
 739 AC_CHECK_PROGS(PERL, perl, false)
 740
 741 SYSDEP_SOURCES=
 742
 743 case "${host}" in
 744  i?86-*-linux*)
 745     SIGNAL_HANDLER=include/i386-signal.h
 746     ;;
 747  sparc-sun-solaris*)
 748     SIGNAL_HANDLER=include/sparc-signal.h
 749     ;;
 750 # ia64-*)
 751 #    SYSDEP_SOURCES=sysdep/ia64.c
 752 #    test -d sysdep || mkdir sysdep
 753 #    ;;
 754  powerpc-*-linux*)
 755     SIGNAL_HANDLER=include/dwarf2-signal.h
 756     ;;
 757  *)
 758     SIGNAL_HANDLER=include/default-signal.h
 759     ;;
 760 esac
 761
 762 # If we're using sjlj exceptions, forget what we just learned.
 763 if test "$libgcj_sjlj" = yes; then
 764    SIGNAL_HANDLER=include/default-signal.h
 765 fi
 766
 767 AC_SUBST(SYSDEP_SOURCES)
 768
 769 AC_LINK_FILES($SIGNAL_HANDLER, include/java-signal.h)
 770
 771 if test "${multilib}" = "yes"; then
 772   multilib_arg="--enable-multilib"
 773 else
 774   multilib_arg=
 775 fi
 776
 777 AC_PATH_XTRA
 778
 779 dnl Determine which AWT peer libraries to build
 780 AC_ARG_ENABLE(java-awt,
 781 [  --enable-java-awt       list of AWT peer implementations to be built])
 782
 783 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 784 use_xlib_awt=""
 785 use_gtk_awt=""
 786
 787 for peer in $peerlibs ; do
 788   case $peer in
 789     xlib)
 790       if [test "$no_x" = yes]; then
 791         echo "*** xlib peers requested but no X library available" 1>&2
 792         exit 1
 793       else
 794         use_xlib_awt="yes"
 795       fi
 796       ;;
 797     gtk)
 798       # Nothing, yet...
 799       ;;
 800     *)
 801       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 802       exit 1
 803   esac
 804 done
 805
 806 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 807 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 808
 809
 810 here=`pwd`
 811 AC_SUBST(here)
 812
 813 # We get this from the environment.
 814 AC_SUBST(GCJFLAGS)
 815
 816 AC_OUTPUT(Makefile libgcj.spec libgcj-test.spec gnu/classpath/Configuration.java gcj/Makefile include/Makefile testsuite/Makefile,
 817 [if test -n "$CONFIG_FILES"; then
 818   ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
 819 fi
 820
 821 # Make subdirectories and `.d' files.  Look in both srcdir and
 822 # builddir for the .java files.
 823 h=`pwd`
 824 : > deps.mk
 825 ( (cd $srcdir && find . -name '*.java' -print) ;
 826   find . -name '*.java' -print) | \
 827    fgrep -v testsuite | \
 828    sed -e 's/\.java/.d/' | \
 829    while read f; do
 830       echo "include $f" >> deps.mk
 831       test -f $f || {
 832 changequote(<<,>>)
 833          d=`echo $f | sed -e 's,/[^/]*$,,'`
 834 changequote([,])
 835          $srcdir/../mkinstalldirs $d
 836          echo > $f
 837       }
 838    done
 839 ],
 840 srcdir=${srcdir}
 841 host=${host}
 842 target=${target}
 843 with_multisubdir=${with_multisubdir}
 844 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 845 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 846 libgcj_basedir=${libgcj_basedir}
 847 CC="${CC}"
 848 CXX="${CXX}"
 849 )