libjava/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(java/lang/System.java)
   3
   4 AC_PROG_LN_S
   5
   6 dnl We use these options to decide which functions to include.
   7 AC_ARG_WITH(target-subdir,
   8 [  --with-target-subdir=SUBDIR
   9                            configuring in a subdirectory])
  10 AC_ARG_WITH(cross-host,
  11 [  --with-cross-host=HOST  configuring with a cross compiler])
  12
  13 LIBGCJ_CONFIGURE(.)
  14
  15 AM_CONFIG_HEADER(include/config.h gcj/libgcj-config.h)
  16
  17 # Only use libltdl for native builds.
  18 if test -z "${with_cross_host}"; then
  19    AC_LIBLTDL_CONVENIENCE
  20    AC_LIBTOOL_DLOPEN
  21    DIRLTDL=libltdl
  22    AC_DEFINE(USE_LTDL)
  23    # Sigh.  Libtool's macro doesn't do the right thing.
  24    INCLTDL="-I\$(top_srcdir)/libltdl $INCLTDL"
  25    # FIXME: this is a hack.
  26    sub_auxdir="`cd $ac_aux_dir && pwd`"
  27    ac_configure_args="$ac_configure_args --with-auxdir=$sub_auxdir"
  28 fi
  29 AC_SUBST(INCLTDL)
  30 AC_SUBST(LIBLTDL)
  31 AC_SUBST(DIRLTDL)
  32 AM_PROG_LIBTOOL
  33 AC_CONFIG_SUBDIRS($DIRLTDL)
  34
  35 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  36    COMPPATH=.
  37 else
  38    COMPPATH=..
  39 fi
  40 AC_SUBST(COMPPATH)
  41
  42 dnl The -no-testsuite modules omit the test subdir.
  43 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  44
  45 dnl See whether the user prefers size or speed for Character.
  46 dnl The default is size.
  47 AC_ARG_ENABLE(fast-character,
  48 [  --enable-fast-character prefer speed over size for Character],
  49 # Nothing
  50 , AC_DEFINE(COMPACT_CHARACTER))
  51
  52 dnl Should the runtime set system properties by examining the
  53 dnl environment variable GCJ_PROPERTIES?
  54 AC_ARG_ENABLE(getenv-properties,
  55 [  --disable-getenv-properties
  56                           don't set system properties from GCJ_PROPERTIES])
  57
  58 dnl Whether GCJ_PROPERTIES is used depends on the target.
  59 if test -z "$enable_getenv_properties"; then
  60    enable_getenv_properties=${enable_getenv_properties_default-yes}
  61 fi
  62 if test "$enable_getenv_properties" = no; then
  63    AC_DEFINE(DISABLE_GETENV_PROPERTIES)
  64 fi
  65
  66
  67 dnl Should we use hashtable-based synchronization?
  68 dnl Currently works only for Linux X86/ia64
  69 dnl Typically faster and more space-efficient
  70 AC_ARG_ENABLE(hash-synchronization,
  71 [  --enable-hash-synchronization
  72                           Use global hash table for monitor locks])
  73
  74 if test -z "$enable_hash_synchronization"; then
  75    enable_hash_synchronization=$enable_hash_synchronization_default
  76 fi
  77
  78
  79 dnl See if the user has requested runtime debugging.
  80 LIBGCJDEBUG="false"
  81 AC_SUBST(LIBGCJDEBUG)
  82 AC_ARG_ENABLE(libgcj-debug,
  83 [  --enable-libgcj-debug   enable runtime debugging code],
  84   if test "$enable_libgcj_debug" = yes; then
  85     AC_DEFINE(DEBUG)
  86     LIBGCJDEBUG="true"
  87   fi)
  88
  89 dnl See if the user has the interpreter included.
  90 AC_ARG_ENABLE(interpreter,
  91 [  --enable-interpreter    enable interpreter],
  92   if test "$enable_interpreter" = yes; then
  93     # This can also be set in configure.host.
  94     libgcj_interpreter=yes
  95   elif test "$enable_interpreter" = no; then
  96     libgcj_interpreter=no
  97   fi)
  98
  99 if test "$libgcj_interpreter" = yes; then
 100    AC_DEFINE(INTERPRETER)
 101 fi
 102
 103 AC_MSG_CHECKING([for exception model to use])
 104 AC_LANG_SAVE
 105 AC_LANG_CPLUSPLUS
 106 AC_ARG_ENABLE(sjlj-exceptions,
 107 [  --enable-sjlj-exceptions  force use of builtin_setjmp for exceptions],
 108 [:],
 109 [dnl Botheration.  Now we've got to detect the exception model.
 110 dnl Link tests against libgcc.a are problematic since -- at least
 111 dnl as of this writing -- we've not been given proper -L bits for
 112 dnl single-tree newlib and libgloss.
 113 dnl
 114 dnl This is what AC_TRY_COMPILE would do if it didn't delete the
 115 dnl conftest files before we got a change to grep them first.
 116 cat > conftest.$ac_ext << EOF
 117 [#]line __oline__ "configure"
 118 struct S { ~S(); };
 119 void bar();
 120 void foo()
 121 {
 122   S s;
 123   bar();
 124 }
 125 EOF
 126 old_CXXFLAGS="$CXXFLAGS"
 127 CXXFLAGS=-S
 128 if AC_TRY_EVAL(ac_compile); then
 129   if grep _Unwind_SjLj_Resume conftest.s >/dev/null 2>&1 ; then
 130     enable_sjlj_exceptions=yes
 131   elif grep _Unwind_Resume conftest.s >/dev/null 2>&1 ; then
 132     enable_sjlj_exceptions=no
 133   fi
 134 fi
 135 CXXFLAGS="$old_CXXFLAGS"
 136 rm -f conftest*])
 137 if test x$enable_sjlj_exceptions = xyes; then
 138   AC_DEFINE(SJLJ_EXCEPTIONS, 1,
 139         [Define if the compiler is configured for setjmp/longjmp exceptions.])
 140   ac_exception_model_name=sjlj
 141 elif test x$enable_sjlj_exceptions = xno; then
 142   ac_exception_model_name="call frame"
 143 else
 144   AC_MSG_ERROR([unable to detect exception model])
 145 fi
 146 AC_LANG_RESTORE
 147 AC_MSG_RESULT($ac_exception_model_name)
 148
 149 dnl See if the user wants to disable java.net.  This is the mildly
 150 dnl ugly way that we admit that target-side configuration sucks.
 151 AC_ARG_ENABLE(java-net,
 152 [  --disable-java-net      disable java.net])
 153
 154 dnl Whether java.net is built by default can depend on the target.
 155 if test -z "$enable_java_net"; then
 156    enable_java_net=${enable_java_net_default-yes}
 157 fi
 158 if test "$enable_java_net" = no; then
 159    AC_DEFINE(DISABLE_JAVA_NET)
 160 fi
 161
 162 dnl See if the user wants to configure without libffi.  Some
 163 dnl architectures don't support it, and default values are set in
 164 dnl configure.host.
 165 AC_ARG_WITH(libffi,
 166 [  --without-libffi        don't use libffi],,with_libffi=${with_libffi_default-yes})
 167
 168 LIBFFI=
 169 LIBFFIINCS=
 170 if test "$with_libffi" != no; then
 171    AC_DEFINE(USE_LIBFFI)
 172    LIBFFI=../libffi/libfficonvenience.la
 173    LIBFFIINCS='-I$(top_srcdir)/../libffi/include -I$(MULTIBUILDTOP)../libffi/include'
 174 fi
 175 AC_SUBST(LIBFFI)
 176 AC_SUBST(LIBFFIINCS)
 177
 178 dnl See if the user wants to disable JVMPI support.
 179 AC_ARG_ENABLE(jvmpi,
 180 [  --disable-jvmpi         disable JVMPI support])
 181
 182 if test "$enable_jvmpi" != no; then
 183     AC_DEFINE(ENABLE_JVMPI)
 184 fi
 185
 186 dnl If the target is an eCos system, use the appropriate eCos
 187 dnl I/O routines.
 188 dnl FIXME: this should not be a local option but a global target
 189 dnl system; at present there is no eCos target.
 190 TARGET_ECOS="no"
 191 AC_ARG_WITH(ecos,
 192 [  --with-ecos             enable runtime eCos target support],
 193 TARGET_ECOS="$with_ecos"
 194 )
 195
 196 case "$TARGET_ECOS" in
 197    no) case "$host" in
 198       mingw)
 199             PLATFORM=Win32
 200       ;;
 201       *)
 202             PLATFORM=Posix
 203       ;;
 204       esac
 205       ;;
 206    *)
 207       PLATFORM=Ecos
 208       AC_DEFINE(ECOS)
 209       ;;
 210 esac
 211
 212 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED))
 213 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED))
 214 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 215 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 216
 217
 218 dnl These may not be defined in a non-ANS conformant embedded system.
 219 dnl FIXME: Should these case a runtime exception in that case?
 220 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME))
 221 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME))
 222
 223 dnl Create the subdirectory for natFileDescriptor.cc, or the attempt
 224 dnl to create the link will fail.
 225 test -d java || mkdir java
 226 test -d java/io || mkdir java/io
 227 test -d gnu || mkdir gnu
 228 AC_LINK_FILES(java/io/natFileDescriptor${PLATFORM}.cc, java/io/natFileDescriptor.cc)
 229
 230 dnl Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 231 test -d java/lang || mkdir java/lang
 232 AC_LINK_FILES(java/lang/${PLATFORM}Process.java, java/lang/ConcreteProcess.java)
 233 AC_LINK_FILES(java/lang/nat${PLATFORM}Process.cc, java/lang/natConcreteProcess.cc)
 234
 235 SYSTEMSPEC=
 236 AC_SUBST(SYSTEMSPEC)
 237
 238 LIBGCJTESTSPEC="-L`pwd`/.libs -rpath `pwd`/.libs"
 239 AC_SUBST(LIBGCJTESTSPEC)
 240
 241 AC_ARG_WITH(system-zlib,
 242 [  --with-system-zlib      use installed libz])
 243 ZLIBSPEC=
 244 AC_SUBST(ZLIBSPEC)
 245 ZLIBTESTSPEC=
 246 AC_SUBST(ZLIBTESTSPEC)
 247
 248 dnl FIXME: this should be _libs on some hosts.
 249 libsubdir=.libs
 250
 251 dnl Allow the GC to be disabled.  Can be useful when debugging.
 252 AC_MSG_CHECKING([for garbage collector to use])
 253 AC_ARG_ENABLE(java-gc,
 254 changequote(<<,>>)dnl
 255 <<  --enable-java-gc=TYPE   choose garbage collector [boehm]>>,
 256 changequote([,])
 257   GC=$enableval,
 258   GC=boehm)
 259 GCLIBS=
 260 GCINCS=
 261 GCDEPS=
 262 GCOBJS=
 263 GCSPEC=
 264 JC1GCSPEC=
 265 GCTESTSPEC=
 266 case "$GC" in
 267  boehm)
 268     AC_MSG_RESULT(boehm)
 269     GCDEPS='$(top_builddir)/../boehm-gc/libgcjgc.la'
 270     # We include the path to the boehm-gc build directory.
 271     # See Makefile.am to understand why.
 272     GCLIBS="$GCDEPS -L\$(here)/../boehm-gc/$libsubdir"
 273     GCINCS='-I$(top_srcdir)/../boehm-gc/include'
 274     GCSPEC='-lgcjgc'
 275     JC1GCSPEC='-fuse-boehm-gc'
 276     GCTESTSPEC="-L`pwd`/../boehm-gc/.libs -rpath `pwd`/../boehm-gc/.libs"
 277     dnl We also want to pick up some cpp flags required when including
 278     dnl boehm-config.h.  Yuck.
 279     GCINCS="$GCINCS `cat ../boehm-gc/boehm-cflags`"
 280     GCOBJS=boehm.lo
 281     GCHDR=boehm-gc.h
 282     dnl The POSIX thread support needs to know this.
 283     AC_DEFINE(HAVE_BOEHM_GC)
 284     ;;
 285  no)
 286     AC_MSG_RESULT(none)
 287     GCOBJS=nogc.lo
 288     GCHDR=no-gc.h
 289     ;;
 290  *)
 291     AC_MSG_ERROR(unrecognized collector \"$GC\")
 292     ;;
 293 esac
 294 AC_SUBST(GCLIBS)
 295 AC_SUBST(GCINCS)
 296 AC_SUBST(GCDEPS)
 297 AC_SUBST(GCOBJS)
 298 AC_SUBST(GCSPEC)
 299 AC_SUBST(JC1GCSPEC)
 300 AC_SUBST(GCTESTSPEC)
 301 AC_LINK_FILES(include/$GCHDR, include/java-gc.h)
 302
 303
 304 AC_MSG_CHECKING([for thread model used by GCC])
 305 THREADS=`$CC -v 2>&1 | sed -n 's/^Thread model: //p'`
 306 AC_MSG_RESULT([$THREADS])
 307
 308 case "$THREADS" in
 309  no | none | single)
 310     THREADS=none
 311     ;;
 312  posix | pthreads)
 313     THREADS=posix
 314     case "$host" in
 315      *-*-linux*)
 316         AC_DEFINE(LINUX_THREADS)
 317         ;;
 318     esac
 319     ;;
 320  win32)
 321     ;;
 322  decosf1 | irix | mach | os2 | solaris | dce | vxworks)
 323     AC_MSG_ERROR(thread package $THREADS not yet supported)
 324     ;;
 325  *)
 326     AC_MSG_ERROR($THREADS is an unknown thread package)
 327     ;;
 328 esac
 329
 330 THREADLIBS=
 331 THREADINCS=
 332 THREADDEPS=
 333 THREADOBJS=
 334 THREADH=
 335 THREADSPEC=
 336 case "$THREADS" in
 337  posix)
 338     case "$host" in
 339      *-*-cygwin*)
 340         # Don't set THREADLIBS here.  Cygwin doesn't have -lpthread.
 341         ;;
 342 changequote(<<,>>)
 343      *-*-freebsd[1234]*)
 344 changequote([,])
 345         # Before FreeBSD 5, it didn't have -lpthread (or any library which
 346         # merely adds pthread_* functions) but it does have a -pthread switch
 347         # which is required at link-time to select -lc_r *instead* of -lc.
 348         THREADLIBS=-pthread
 349         # Don't set THREADSPEC here as might be expected since -pthread is
 350         # not processed when found within a spec file, it must come from
 351         # the command line.  For now, the user must provide the -pthread
 352         # switch to link code compiled with gcj.  In future, consider adding
 353         # support for weak references to pthread_* functions ala gthr.h API.
 354         THREADSPEC='%{!pthread: %eUnder this configuration, the user must provide -pthread when linking.}'
 355         ;;
 356      *-*-freebsd*)
 357         # FreeBSD 5 implements a model much closer to other modern UNIX
 358         # which support threads.  However, it still does not support
 359         # -lpthread.
 360         THREADLIBS=-pthread
 361         THREADSPEC=-lc_r
 362         ;;
 363      *)
 364         THREADLIBS=-lpthread
 365         THREADSPEC=-lpthread
 366         ;;
 367     esac
 368     THREADOBJS=posix-threads.lo
 369     THREADH=posix-threads.h
 370     # MIT pthreads doesn't seem to have the mutexattr functions.
 371     # But for now we don't check for it.  We just assume you aren't
 372     # using MIT pthreads.
 373     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 374
 375     # If we're using the Boehm GC, then we happen to know that it
 376     # defines _REENTRANT, so we don't bother.  Eww.
 377     if test "$GC" != boehm; then
 378        AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 379     fi
 380     AC_DEFINE(_POSIX_PTHREAD_SEMANTICS, 1, [Required define if using POSIX threads])
 381     ;;
 382
 383  win32)
 384     THREADOBJS=win32-threads.lo
 385     THREADH=win32-threads.h
 386     ;;
 387
 388  none)
 389     THREADOBJS=no-threads.lo
 390     THREADH=no-threads.h
 391     ;;
 392 esac
 393 AC_LINK_FILES(include/$THREADH, include/java-threads.h)
 394 AC_SUBST(THREADLIBS)
 395 AC_SUBST(THREADINCS)
 396 AC_SUBST(THREADDEPS)
 397 AC_SUBST(THREADOBJS)
 398 AC_SUBST(THREADSPEC)
 399
 400 HASH_SYNC_SPEC=
 401 # Hash synchronization is only useful with posix threads right now.
 402 if test "$enable_hash_synchronization" = yes && test "$THREADS" = "posix"; then
 403    HASH_SYNC_SPEC=-fhash-synchronization
 404    AC_DEFINE(JV_HASH_SYNCHRONIZATION, 1, [Define if hash synchronization is in use])
 405 fi
 406 AC_SUBST(HASH_SYNC_SPEC)
 407
 408
 409 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 410
 411 CANADIAN=no
 412 NULL_TARGET=no
 413 NATIVE=yes
 414
 415 # We're in the tree with gcc, and need to include some of its headers.
 416 GCC_UNWIND_INCLUDE='-I$(libgcj_basedir)/../gcc'
 417
 418 if test -n "${with_cross_host}"; then
 419    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 420    # may not work correctly, because the compiler may not be able to
 421    # link executables.
 422
 423    # We assume newlib.  This lets us hard-code the functions we know
 424    # we'll have.
 425    AC_DEFINE(HAVE_MEMMOVE)
 426    AC_DEFINE(HAVE_MEMCPY)
 427    AC_DEFINE(HAVE_STRERROR)
 428    AC_DEFINE(HAVE_GMTIME_R)
 429    AC_DEFINE(HAVE_LOCALTIME_R)
 430    dnl This is only for POSIX threads.
 431    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 432    dnl We also assume we are using gcc, which provides alloca.
 433    AC_DEFINE(HAVE_ALLOCA)
 434
 435    dnl Assume we do not have getuid and friends.
 436    AC_DEFINE(NO_GETUID)
 437
 438    ZLIBSPEC=-lzgcj
 439    ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 440
 441    # If Canadian cross, then don't pick up tools from the build
 442    # directory.
 443    if test x"$build" != x"$with_cross_host" && x"$build" != x"$target"; then
 444       CANADIAN=yes
 445       GCC_UNWIND_INCLUDE=
 446       GCJ="${target_alias}-gcj"
 447    fi
 448    NATIVE=no
 449 else
 450    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep)
 451    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r getcwd)
 452    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath utime chmod)
 453    AC_CHECK_FUNCS(nl_langinfo setlocale)
 454    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 455    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 456    AC_CHECK_FUNCS(backtrace fork execvp pipe sigaction)
 457    AC_CHECK_HEADERS(execinfo.h unistd.h dlfcn.h)
 458    AC_CHECK_LIB(dl, dladdr, [
 459      AC_DEFINE(HAVE_DLADDR)])
 460    AC_CHECK_FILES(/proc/self/exe, [
 461      AC_DEFINE(HAVE_PROC_SELF_EXE)])
 462
 463    AM_ICONV
 464    AM_LC_MESSAGES
 465    AC_STRUCT_TIMEZONE
 466
 467    AC_CHECK_FUNCS(gethostbyname_r, [
 468      AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 469      # There are two different kinds of gethostbyname_r.
 470      # We look for the one that returns `int'.
 471      # Hopefully this check is robust enough.
 472      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 473        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT)])
 474
 475      case " $GCINCS " in
 476      *" -D_REENTRANT "*) ;;
 477      *)
 478         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 479         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 480         [libjava_cv_gethostbyname_r_needs_reentrant],
 481         [ AC_LANG_SAVE
 482           AC_LANG_CPLUSPLUS
 483           AC_TRY_COMPILE([#include <netdb.h>],
 484             [gethostbyname_r("", 0, 0);],
 485             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 486                 CPPFLAGS_SAVE="$CPPFLAGS"
 487                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 488                 AC_TRY_COMPILE([#include <netdb.h>], [gethostbyname_r("", 0, 0);],
 489                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 490                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 491                 CPPFLAGS="$CPPFLAGS_SAVE"
 492           ])
 493           AC_LANG_RESTORE
 494         ])
 495         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 496           AC_DEFINE(_REENTRANT, 1, [Required define if using POSIX threads])
 497         fi
 498      ;;
 499      esac
 500
 501      AC_CACHE_CHECK([for struct hostent_data],
 502         [libjava_cv_struct_hostent_data], [dnl
 503         AC_TRY_COMPILE([
 504 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 505 # define _REENTRANT 1
 506 #endif
 507 #include <netdb.h>], [struct hostent_data data;],
 508           [libjava_cv_struct_hostent_data=yes],
 509           [libjava_cv_struct_hostent_data=no])])
 510      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 511        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 512          [Define if struct hostent_data is defined in netdb.h])
 513      fi
 514    ])
 515
 516    # FIXME: libjava source code expects to find a prototype for
 517    # gethostbyaddr_r in netdb.h.  The outer check ensures that
 518    # HAVE_GETHOSTBYADDR_R will not be defined if the prototype fails
 519    # to exist where expected.  (The root issue: AC_CHECK_FUNCS assumes C
 520    # linkage check is enough, yet C++ code requires proper prototypes.)
 521    AC_EGREP_HEADER(gethostbyaddr_r, netdb.h, [
 522    AC_CHECK_FUNCS(gethostbyaddr_r, [
 523      AC_DEFINE(HAVE_GETHOSTBYADDR_R)
 524      # There are two different kinds of gethostbyaddr_r.
 525      # We look for the one that returns `int'.
 526      # Hopefully this check is robust enough.
 527      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 528        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT)])])])
 529
 530    AC_CHECK_FUNCS(gethostname, [
 531      AC_DEFINE(HAVE_GETHOSTNAME)
 532      AC_EGREP_HEADER(gethostname, unistd.h, [
 533        AC_DEFINE(HAVE_GETHOSTNAME_DECL)])])
 534
 535    # Look for these functions in the thread library, but only bother
 536    # if using POSIX threads.
 537    if test "$THREADS" = posix; then
 538       save_LIBS="$LIBS"
 539       LIBS="$LIBS $THREADLIBS"
 540       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 541       # E.g., Solaris.
 542       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 543
 544       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 545       # Solaris 7 the name librt is preferred.
 546       AC_CHECK_FUNCS(sched_yield, , [
 547         AC_CHECK_LIB(rt, sched_yield, [
 548           AC_DEFINE(HAVE_SCHED_YIELD)
 549           THREADLIBS="$THREADLIBS -lrt"
 550           THREADSPEC="$THREADSPEC -lrt"], [
 551           AC_CHECK_LIB(posix4, sched_yield, [
 552             AC_DEFINE(HAVE_SCHED_YIELD)
 553             THREADLIBS="$THREADLIBS -lposix4"
 554             THREADSPEC="$THREADSPEC -lposix4"])])])
 555       LIBS="$save_LIBS"
 556
 557       # We can save a little space at runtime if the mutex has m_count
 558       # or __m_count.  This is a nice hack for Linux.
 559       AC_TRY_COMPILE([#include <pthread.h>], [
 560           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 561         ], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT), [
 562         AC_TRY_COMPILE([#include <pthread.h>], [
 563             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 564           ], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT))])
 565    fi
 566
 567    # We require a way to get the time.
 568    time_found=no
 569    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 570    if test "$time_found" = no; then
 571       AC_MSG_ERROR([no function found to get the time])
 572    fi
 573
 574    AC_CHECK_FUNCS(memmove)
 575
 576    # We require memcpy.
 577    memcpy_found=no
 578    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 579    if test "$memcpy_found" = no; then
 580       AC_MSG_ERROR([memcpy is required])
 581    fi
 582
 583    AC_CHECK_LIB(dl, dlopen, [
 584        AC_DEFINE(HAVE_DLOPEN, 1, [Define if dlopen is available])])
 585
 586    # Some library-finding code we stole from Tcl.
 587    #--------------------------------------------------------------------
 588    #    Check for the existence of the -lsocket and -lnsl libraries.
 589    #    The order here is important, so that they end up in the right
 590    #    order in the command line generated by make.  Here are some
 591    #    special considerations:
 592    #    1. Use "connect" and "accept" to check for -lsocket, and
 593    #       "gethostbyname" to check for -lnsl.
 594    #    2. Use each function name only once:  can't redo a check because
 595    #       autoconf caches the results of the last check and won't redo it.
 596    #    3. Use -lnsl and -lsocket only if they supply procedures that
 597    #       aren't already present in the normal libraries.  This is because
 598    #       IRIX 5.2 has libraries, but they aren't needed and they're
 599    #       bogus:  they goof up name resolution if used.
 600    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 601    #       To get around this problem, check for both libraries together
 602    #       if -lsocket doesn't work by itself.
 603    #--------------------------------------------------------------------
 604
 605    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 606     [gcj_cv_lib_sockets=
 607      gcj_checkBoth=0
 608      unset ac_cv_func_connect
 609      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 610      if test "$gcj_checkSocket" = 1; then
 611          unset ac_cv_func_connect
 612          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 613                       gcj_checkBoth=1)
 614      fi
 615      if test "$gcj_checkBoth" = 1; then
 616          gcj_oldLibs=$LIBS
 617          LIBS="$LIBS -lsocket -lnsl"
 618          unset ac_cv_func_accept
 619          AC_CHECK_FUNC(accept,
 620                        [gcj_checkNsl=0
 621                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 622          unset ac_cv_func_accept
 623          LIBS=$gcj_oldLibs
 624      fi
 625      unset ac_cv_func_gethostbyname
 626      gcj_oldLibs=$LIBS
 627      LIBS="$LIBS $gcj_cv_lib_sockets"
 628      AC_CHECK_FUNC(gethostbyname, ,
 629                    [AC_CHECK_LIB(nsl, main,
 630                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 631      unset ac_cv_func_gethostbyname
 632      LIBS=$gcj_oldLIBS
 633    ])
 634    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 635
 636    if test "$with_system_zlib" = yes; then
 637       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=-lzgcj)
 638    else
 639       ZLIBSPEC=-lzgcj
 640       ZLIBTESTSPEC="-L`pwd`/../zlib/.libs -rpath `pwd`/../zlib/.libs"
 641    fi
 642
 643    # On Solaris, and maybe other architectures, the Boehm collector
 644    # requires -ldl.
 645    if test "$GC" = boehm; then
 646       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
 647    fi
 648
 649    if test -z "${with_multisubdir}"; then
 650       builddotdot=.
 651    else
 652 changequote(<<,>>)
 653       builddotdot=`echo ${with_multisubdir} | sed -e 's:[^/][^/]*:..:g'`
 654 changequote([,])
 655    fi
 656    if test -x "${builddotdot}/../../gcc/gcj"; then
 657       dir="`cd ${builddotdot}/../../gcc && pwd`"
 658       GCJ="$dir/gcj -B`pwd`/ -B$dir/"
 659    else
 660       CANADIAN=yes
 661       NULL_TARGET=yes
 662       GCJ="gcj -B`pwd`/"
 663    fi
 664 fi
 665
 666 # Create it, so that compile/link tests don't fail
 667 test -f libgcj.spec || touch libgcj.spec
 668
 669 # We must search the source tree for java.lang, since we still don't
 670 # have libgcj.jar nor java/lang/*.class
 671 GCJ_SAVE_CPPFLAGS=$CPPFLAGS
 672 CPPFLAGS="$CPPFLAGS -I`pwd` -I`cd $srcdir && pwd`"
 673
 674 # Since some classes depend on this one, we need its source available
 675 # before we can do any GCJ compilation test :-(
 676 if test ! -f gnu/classpath/Configuration.java; then
 677   test -d gnu || mkdir gnu
 678   test -d gnu/classpath || mkdir gnu/classpath
 679   sed 's,@LIBGCJDEBUG@,$LIBGCJDEBUG,' \
 680         < $srcdir/gnu/classpath/Configuration.java.in \
 681         > gnu/classpath/Configuration.java
 682   # We do not want to redirect the output of the grep below to /dev/null,
 683   # but we add /dev/null to the input list so that grep will print the
 684   # filename of Configuration.java in case it finds any matches.
 685   if grep @ gnu/classpath/Configuration.java /dev/null; then
 686     AC_MSG_ERROR([configure.in is missing the substitutions above])
 687   fi
 688 fi
 689
 690 LT_AC_PROG_GCJ
 691
 692 CPPFLAGS=$GCJ_SAVE_CPPFLAGS
 693
 694 dnl FIXME: cross compilation
 695 AC_CHECK_SIZEOF(void *)
 696
 697 ZLIBS=
 698 ZDEPS=
 699 ZINCS=
 700 if test "x$ZLIBSPEC" = "x-lzgcj"; then
 701    # We include the path to the zlib build directory.
 702    # See Makefile.am to understand why.
 703    ZDEPS='$(top_builddir)/../zlib/libzgcj.la'
 704    ZLIBS="$ZDEPS -L\$(here)/../zlib/$libsubdir"
 705    ZINCS='-I$(top_srcdir)/../zlib'
 706 else
 707    ZLIBS="$ZLIBSPEC"
 708 fi
 709 AC_SUBST(ZLIBS)
 710 AC_SUBST(ZDEPS)
 711 AC_SUBST(ZINCS)
 712 AC_SUBST(DIVIDESPEC)
 713 AC_SUBST(EXCEPTIONSPEC)
 714
 715 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 716 AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
 717 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes || test "$NULL_TARGET" = yes)
 718 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 719 AM_CONDITIONAL(NEEDS_DATA_START, test "$NEEDS_DATA_START" = yes && test "$NATIVE" = yes)
 720 AC_SUBST(GCC_UNWIND_INCLUDE)
 721
 722 # Determine gcj version number.
 723 changequote(<<,>>)
 724 gcjvers="`$GCJ -v 2>&1 | sed -n 's/^.*version \([^ ]*\).*$/\1/p'`"
 725 changequote([,])
 726 AC_DEFINE_UNQUOTED(GCJVERSION, "$gcjvers")
 727 AC_SUBST(GCJVERSION)
 728
 729 AC_SUBST(AM_RUNTESTFLAGS)
 730
 731 dnl Work around a g++ bug.  Reported to gcc-bugs@gcc.gnu.org on Jan 22, 2000.
 732 AC_MSG_CHECKING([for g++ -ffloat-store bug])
 733 save_CFLAGS="$CFLAGS"
 734 CFLAGS="-x c++ -O2 -ffloat-store"
 735 AC_TRY_COMPILE([#include <math.h>], ,
 736   [AC_MSG_RESULT(no)],
 737   [AC_DEFINE(__NO_MATH_INLINES)
 738    AC_MSG_RESULT(yes)])
 739 CFLAGS="$save_CFLAGS"
 740
 741 dnl We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
 742 dnl On that system, sys/ioctl.h will not include sys/filio.h unless
 743 dnl BSD_COMP is defined; just including sys/filio.h is simpler.
 744 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h pwd.h sys/config.h stdint.h langinfo.h locale.h)
 745 dnl We avoid AC_HEADER_DIRENT since we really only care about dirent.h
 746 dnl for now.  If you change this, you also must update natFile.cc.
 747 AC_CHECK_HEADERS(dirent.h)
 748 AC_CHECK_HEADERS(inttypes.h, [
 749     AC_DEFINE(HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
 750     AC_DEFINE(JV_HAVE_INTTYPES_H, 1, [Define if <inttypes.h> is available])
 751 ])
 752
 753 AC_CHECK_TYPE([ssize_t], [int])
 754
 755 AC_MSG_CHECKING([for in_addr_t])
 756 AC_TRY_COMPILE([#include <sys/types.h>
 757 #if STDC_HEADERS
 758 #include <stdlib.h>
 759 #include <stddef.h>
 760 #endif
 761 #if HAVE_NETINET_IN_H
 762 #include <netinet/in.h>
 763 #endif], [in_addr_t foo;],
 764   [AC_DEFINE([HAVE_IN_ADDR_T])
 765    AC_MSG_RESULT(yes)],
 766   [AC_MSG_RESULT(no)])
 767
 768 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
 769 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ip_mreq mreq;],
 770   [AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 771    AC_MSG_RESULT(yes)],
 772   [AC_MSG_RESULT(no)])
 773
 774 AC_MSG_CHECKING([whether struct ipv6_mreq is in netinet/in.h])
 775 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ipv6_mreq mreq6;],
 776   [AC_DEFINE(HAVE_STRUCT_IPV6_MREQ)
 777    AC_MSG_RESULT(yes)],
 778   [AC_MSG_RESULT(no)])
 779
 780 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
 781 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
 782   [AC_DEFINE(HAVE_INET6)
 783    AC_MSG_RESULT(yes)],
 784   [AC_MSG_RESULT(no)])
 785
 786 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
 787 AC_TRY_COMPILE([#define _POSIX_PII_SOCKET
 788 #include <sys/types.h>
 789 #include <sys/socket.h>], [socklen_t x = 5;],
 790   [AC_DEFINE(HAVE_SOCKLEN_T)
 791    AC_MSG_RESULT(yes)],
 792   [AC_MSG_RESULT(no)])
 793
 794 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
 795 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
 796   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF)
 797    AC_MSG_RESULT(yes)],
 798   [AC_MSG_RESULT(no)
 799    AC_MSG_CHECKING([for global timezone variable])
 800    dnl FIXME: we don't want a link check here because that won't work
 801    dnl when cross-compiling.  So instead we make an assumption that
 802    dnl the header file will mention timezone if it exists.
 803    AC_TRY_COMPILE([#include <time.h>], [long z2 = timezone;],
 804      [AC_DEFINE(HAVE_TIMEZONE)
 805       AC_MSG_RESULT(yes)],
 806      [AC_MSG_RESULT(no)])])
 807
 808 AC_FUNC_ALLOCA
 809
 810 AC_CHECK_PROGS(PERL, perl, false)
 811
 812 SYSDEP_SOURCES=
 813
 814 case "${host}" in
 815  i?86-*-linux*)
 816     SIGNAL_HANDLER=include/i386-signal.h
 817     ;;
 818  sparc-sun-solaris*)
 819     SIGNAL_HANDLER=include/sparc-signal.h
 820     ;;
 821 # ia64-*)
 822 #    SYSDEP_SOURCES=sysdep/ia64.c
 823 #    test -d sysdep || mkdir sysdep
 824 #    ;;
 825  powerpc-*-linux*)
 826     SIGNAL_HANDLER=include/dwarf2-signal.h
 827     ;;
 828  alpha*-*-linux*)
 829     SIGNAL_HANDLER=include/dwarf2-signal.h
 830     ;;
 831  mingw)
 832     SIGNAL_HANDLER=include/win32-signal.h
 833     ;;
 834  *)
 835     SIGNAL_HANDLER=include/default-signal.h
 836     ;;
 837 esac
 838
 839 # If we're using sjlj exceptions, forget what we just learned.
 840 if test "$enable_sjlj_exceptions" = yes; then
 841    SIGNAL_HANDLER=include/default-signal.h
 842 fi
 843
 844 AC_SUBST(SYSDEP_SOURCES)
 845
 846 AC_LINK_FILES($SIGNAL_HANDLER, include/java-signal.h)
 847
 848 if test "${multilib}" = "yes"; then
 849   multilib_arg="--enable-multilib"
 850 else
 851   multilib_arg=
 852 fi
 853
 854 AC_PATH_XTRA
 855
 856 dnl Determine which AWT peer libraries to build
 857 AC_ARG_ENABLE(java-awt,
 858 [  --enable-java-awt       list of AWT peer implementations to be built])
 859
 860 peerlibs="`echo ${enable_java_awt} | tr ',' ' '`"
 861 use_xlib_awt=""
 862 use_gtk_awt=""
 863
 864 for peer in $peerlibs ; do
 865   case $peer in
 866     xlib)
 867       if [test "$no_x" = yes]; then
 868         echo "*** xlib peers requested but no X library available" 1>&2
 869         exit 1
 870       else
 871         use_xlib_awt="yes"
 872       fi
 873       ;;
 874     gtk)
 875       # Nothing, yet...
 876       ;;
 877     no)
 878       use_xlib_awt=
 879       use_gtk_awt=
 880       break
 881       ;;
 882     *)
 883       echo "*** unrecognised argument \"${peer}\" for --enable-java-awt" 1>&2
 884       exit 1
 885   esac
 886 done
 887
 888 AM_CONDITIONAL(XLIB_AWT, test "$use_xlib_awt" = yes)
 889 AM_CONDITIONAL(GTK_AWT, test "$use_gtk_awt" = yes)
 890
 891
 892 here=`pwd`
 893 AC_SUBST(here)
 894
 895 # We get this from the environment.
 896 AC_SUBST(GCJFLAGS)
 897
 898 AC_OUTPUT(Makefile libgcj.spec libgcj-test.spec gnu/classpath/Configuration.java gcj/Makefile include/Makefile testsuite/Makefile,
 899 [# Only add multilib support code if we just rebuilt top-level Makefile.
 900 case " $CONFIG_FILES " in
 901  *" Makefile "*)
 902    ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
 903    ;;
 904 esac
 905
 906 # Make subdirectories and `.d' files.  Look in both srcdir and
 907 # builddir for the .java files.
 908 h=`pwd`
 909 : > deps.mk
 910 ( (cd $srcdir && find . \( -name '*.java' -o -name '*.cc' \) -print) ;
 911   find . \( -name '*.java' -o -name '*.cc' \) -print) | \
 912    fgrep -v testsuite | \
 913    sed -e 's/\.java/.d/'\;'s/\.cc/.d/' | \
 914    while read f; do
 915       echo "include $f" >> deps.mk
 916       test -f $f || {
 917 changequote(<<,>>)
 918          d=`echo $f | sed -e 's,/[^/]*$,,'`
 919 changequote([,])
 920          if test ! -d $d; then
 921            $libgcj_basedir/../mkinstalldirs $d
 922          fi;
 923          echo > $f
 924       }
 925    done
 926 ],
 927 srcdir=${srcdir}
 928 host=${host}
 929 target=${target}
 930 with_multisubdir=${with_multisubdir}
 931 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 932 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 933 libgcj_basedir=${libgcj_basedir}
 934 CC="${CC}"
 935 CXX="${CXX}"
 936 )