libjava/configure.in

   1 dnl Process this with autoconf to create configure
   2 AC_INIT(java/lang/System.java)
   3
   4 dnl Can't be done in LIBGCJ_CONFIGURE because that confuses automake.
   5 AC_CONFIG_AUX_DIR(..)
   6
   7 AC_CANONICAL_SYSTEM
   8
   9 dnl We use these options to decide which functions to include.
  10 AC_ARG_WITH(target-subdir,
  11 [  --with-target-subdir=SUBDIR
  12                            configuring in a subdirectory])
  13 AC_ARG_WITH(cross-host,
  14 [  --with-cross-host=HOST  configuring with a cross compiler])
  15
  16 LIBGCJ_CONFIGURE(.)
  17
  18 AM_CONFIG_HEADER(include/config.h)
  19
  20 AM_PROG_LIBTOOL
  21
  22 if test -z "$with_target_subdir" || test "$with_target_subdir" = "."; then
  23    COMPPATH=.
  24 else
  25    COMPPATH=..
  26 fi
  27 AC_SUBST(COMPPATH)
  28
  29 dnl The -no-testsuite modules omit the test subdir.
  30 AM_CONDITIONAL(TESTSUBDIR, test -d $srcdir/testsuite)
  31
  32 dnl See whether the user prefers size or speed for Character.
  33 dnl The default is size.
  34 AC_ARG_ENABLE(fast-character,
  35 [  --enable-fast-character prefer speed over size for Character],
  36 # Nothing
  37 , AC_DEFINE(COMPACT_CHARACTER))
  38
  39 dnl Should the runtime set system properties by examining the
  40 dnl environment variable GCJ_PROPERTIES?
  41 AC_ARG_ENABLE(getenv-properties,
  42 [  --disable-getenv-properties
  43                           don't set system properties from GCJ_PROPERTIES])
  44
  45 dnl Whether GCJ_PROPERTIES is used depends on the target.
  46 if test -n "$enable_getenv_properties"; then
  47    enable_getenv_properties=${enable_getenv_properties_default-yes}
  48 fi
  49 if test "$enable_getenv_properties" = no; then
  50    AC_DEFINE(DISABLE_GETENV_PROPERTIES)
  51 fi
  52
  53 dnl See if the user has requested runtime debugging.
  54 AC_ARG_ENABLE(libgcj-debug,
  55 [  --enable-libgcj-debug   enable runtime debugging code],
  56   if test "$enable_libgcj_debug" = yes; then
  57      AC_DEFINE(DEBUG)
  58   fi)
  59
  60 dnl See if the user has the interpreter included.
  61 AC_ARG_ENABLE(interpreter,
  62 [  --enable-interpreter    enable interpreter],
  63   if test "$enable_interpreter" = yes; then
  64      AC_DEFINE(INTERPRETER)
  65   fi)
  66
  67 EXCEPTIONSPEC=
  68 dnl See if we should use setjmp/longjmp exceptions
  69 AC_ARG_ENABLE(sjlj-exceptions,
  70 [  --enable-sjlj-exceptions    use setjmp/longjmp exceptions],
  71   if test "$enable_sjlj_exceptions" = yes; then
  72      # This can be set in configure.host.
  73      libgcj_sjlj=yes
  74   fi)
  75
  76 if test "$libgcj_sjlj" = yes; then
  77    EXCEPTIONSPEC="-fsjlj-exceptions"
  78    AC_DEFINE(SJLJ_EXCEPTIONS)
  79 fi
  80
  81 dnl See if the user wants to disable java.net.  This is the mildly
  82 dnl ugly way that we admit that target-side configuration sucks.
  83 AC_ARG_ENABLE(java-net,
  84 [  --disable-java-net      disable java.net])
  85
  86 dnl Whether java.net is built by default can depend on the target.
  87 if test -n "$enable_java_net"; then
  88    enable_java_net=${enable_java_net_default-yes}
  89 fi
  90 if test "$enable_java_net" = no; then
  91    AC_DEFINE(DISABLE_JAVA_NET)
  92 fi
  93
  94 dnl If the target is an eCos system, use the appropriate eCos
  95 dnl I/O routines.
  96 dnl FIXME: this should not be a local option but a global target
  97 dnl system; at present there is no eCos target.
  98 TARGET_ECOS="no"
  99 AC_ARG_WITH(ecos,
 100 [  --with-ecos             enable runtime eCos target support],
 101 TARGET_ECOS="$with_ecos"
 102 )
 103
 104 case "$TARGET_ECOS" in
 105    no)
 106       FILE_DESCRIPTOR=natFileDescriptorPosix.cc
 107       PROCESS=${PROCESS-Posix}
 108       ;;
 109    *)
 110       FILE_DESCRIPTOR=natFileDescriptorEcos.cc
 111       PROCESS=Ecos
 112       AC_DEFINE(ECOS)
 113       ;;
 114 esac
 115
 116 AC_EGREP_HEADER(uint32_t, stdint.h, AC_DEFINE(HAVE_INT32_DEFINED))
 117 AC_EGREP_HEADER(uint32_t, inttypes.h, AC_DEFINE(HAVE_INT32_DEFINED))
 118 AC_EGREP_HEADER(u_int32_t, sys/types.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 119 AC_EGREP_HEADER(u_int32_t, sys/config.h, AC_DEFINE(HAVE_BSD_INT32_DEFINED))
 120
 121
 122 dnl These may not be defined in a non-ANS conformant embedded system.
 123 dnl FIXME: Should these case a runtime exception in that case?
 124 AC_EGREP_HEADER(mktime, time.h, AC_DEFINE(HAVE_MKTIME))
 125 AC_EGREP_HEADER(localtime, time.h, AC_DEFINE(HAVE_LOCALTIME))
 126
 127 dnl Create the subdirectory for natFileDescriptor.cc, or the attempt
 128 dnl to create the link will fail.
 129 test -d java || mkdir java
 130 test -d java/io || mkdir java/io
 131 AC_LINK_FILES(java/io/$FILE_DESCRIPTOR, java/io/natFileDescriptor.cc)
 132
 133 dnl Likewise for ConcreteProcess.java and natConcreteProcess.cc.
 134 test -d java/lang || mkdir java/lang
 135 AC_LINK_FILES(java/lang/${PROCESS}Process.java, java/lang/ConcreteProcess.java)
 136 AC_LINK_FILES(java/lang/nat${PROCESS}Process.cc, java/lang/natConcreteProcess.cc)
 137
 138 SYSTEMSPEC=
 139 AC_SUBST(SYSTEMSPEC)
 140
 141 AC_ARG_WITH(system-zlib,
 142 [  --with-system-zlib      use installed libz])
 143 ZLIBSPEC=
 144 AC_SUBST(ZLIBSPEC)
 145
 146 dnl FIXME: this should be _libs on some hosts.
 147 libsubdir=.libs
 148
 149 dnl Allow the GC to be disabled.  Can be useful when debugging.
 150 AC_MSG_CHECKING([for garbage collector to use])
 151 AC_ARG_ENABLE(java-gc,
 152 changequote(<<,>>)dnl
 153 <<  --enable-java-gc=TYPE   choose garbage collector [boehm]>>,
 154 changequote([,])
 155   GC=$enableval,
 156   GC=boehm)
 157 GCLIBS=
 158 GCINCS=
 159 GCDEPS=
 160 GCOBJS=
 161 GCSPEC=
 162 case "$GC" in
 163  boehm)
 164     AC_MSG_RESULT(boehm)
 165     GCDEPS='$(top_builddir)/../boehm-gc/libgcjgc.la'
 166     # We include the path to the boehm-gc build directory.
 167     # See Makefile.am to understand why.
 168     GCLIBS="$GCDEPS -L\$(here)/../boehm-gc/$libsubdir"
 169     GCINCS='-I$(top_srcdir)/../boehm-gc -I$(top_builddir)/../boehm-gc'
 170     GCSPEC='-lgcjgc'
 171     dnl We also want to pick up some cpp flags required when including
 172     dnl boehm-config.h.  Yuck.
 173     GCINCS="$GCINCS `cat ../boehm-gc/boehm-cflags`"
 174     GCOBJS=boehm.lo
 175     GCHDR=boehm-gc.h
 176     dnl The POSIX thread support needs to know this.
 177     AC_DEFINE(HAVE_BOEHM_GC)
 178     ;;
 179  no)
 180     AC_MSG_RESULT(none)
 181     GCOBJS=nogc.lo
 182     GCHDR=no-gc.h
 183     ;;
 184  *)
 185     AC_MSG_ERROR(unrecognized collector \"$GC\")
 186     ;;
 187 esac
 188 AC_SUBST(GCLIBS)
 189 AC_SUBST(GCINCS)
 190 AC_SUBST(GCDEPS)
 191 AC_SUBST(GCOBJS)
 192 AC_SUBST(GCSPEC)
 193 AC_LINK_FILES(include/$GCHDR, include/java-gc.h)
 194
 195
 196 dnl Note that this code is kept in sync with similar code in gcc/configure.in.
 197 dnl In particular both packages must make the same decision about which
 198 dnl thread package to use.
 199 AC_MSG_CHECKING([for threads package to use])
 200 AC_ARG_ENABLE(threads, [  --enable-threads=TYPE   choose threading package],
 201   THREADS=$enableval,
 202   dnl FIXME: figure out native threads to use here.
 203   THREADS=no)
 204
 205 if test "$THREADS" = yes; then
 206    case "$host" in
 207     *-*-vxworks*)
 208        THREADS=vxworks
 209        ;;
 210     *-*-linux*)
 211        # FIXME: this isn't correct in all cases.
 212        THREADS=posix
 213        ;;
 214     *-*-win*)
 215        THREADS=win32
 216        ;;
 217     *-*-irix*)
 218        # FIXME: for now, choose POSIX, because we implement that.
 219        # Later, choose irix threads.
 220        THREADS=posix
 221        ;;
 222     *-*-solaris*)
 223        # FIXME: for now, choose POSIX, because we implement that.
 224        # Later, choose solaris threads.
 225        THREADS=posix
 226        ;;
 227     *)
 228        # For now.
 229        THREADS=none
 230        ;;
 231    esac
 232 fi
 233
 234 case "$THREADS" in
 235  no | none | single)
 236     THREADS=none
 237     ;;
 238  posix | pthreads)
 239     THREADS=posix
 240     case "$host" in
 241      *-*-linux*)
 242         AC_DEFINE(LINUX_THREADS)
 243         ;;
 244     esac
 245     ;;
 246  decosf1 | irix | mach | os2 | solaris | win32 | dce | vxworks)
 247     AC_MSG_ERROR(thread package $THREADS not yet supported)
 248     ;;
 249  *)
 250     AC_MSG_ERROR($THREADS is an unknown thread package)
 251     ;;
 252 esac
 253 AC_MSG_RESULT($THREADS)
 254
 255 THREADLIBS=
 256 THREADINCS=
 257 THREADDEPS=
 258 THREADOBJS=
 259 THREADH=
 260 THREADSPEC=
 261 case "$THREADS" in
 262  posix)
 263     THREADLIBS=-lpthread
 264     THREADSPEC=-lpthread
 265     THREADOBJS=posix-threads.lo
 266     THREADH=posix-threads.h
 267     # MIT pthreads doesn't seem to have the mutexattr functions.
 268     # But for now we don't check for it.  We just assume you aren't
 269     # using MIT pthreads.
 270     AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 271     ;;
 272
 273  none)
 274     THREADOBJS=no-threads.lo
 275     THREADH=no-threads.h
 276     ;;
 277 esac
 278 AC_LINK_FILES(include/$THREADH, include/java-threads.h)
 279 AC_SUBST(THREADLIBS)
 280 AC_SUBST(THREADINCS)
 281 AC_SUBST(THREADDEPS)
 282 AC_SUBST(THREADOBJS)
 283 AC_SUBST(THREADSPEC)
 284
 285 AM_CONDITIONAL(USING_GCC, test "$GCC" = yes)
 286
 287 CANADIAN=no
 288 NULL_TARGET=no
 289 NATIVE=yes
 290
 291 # Find eh-common.h and support headers.  If we're in the tree with
 292 # gcc, then look there.  Otherwise look in compat-include.  If all else
 293 # fails, just hope the user has set things up somehow.
 294 if test -r $srcdir/../gcc/eh-common.h; then
 295    EH_COMMON_INCLUDE='-I$(top_srcdir)/../gcc -I$(top_srcdir)/../include'
 296 else
 297    if test -d $srcdir/../compat-include; then
 298       EH_COMMON_INCLUDE='-I$(top_srcdir)/../compat-include'
 299    else
 300       EH_COMMON_INCLUDE=
 301    fi
 302 fi
 303
 304 if test -n "${with_cross_host}"; then
 305    # We are being configured with a cross compiler.  AC_REPLACE_FUNCS
 306    # may not work correctly, because the compiler may not be able to
 307    # link executables.
 308
 309    # We assume newlib.  This lets us hard-code the functions we know
 310    # we'll have.
 311    AC_DEFINE(HAVE_MEMMOVE)
 312    AC_DEFINE(HAVE_MEMCPY)
 313    AC_DEFINE(HAVE_STRERROR)
 314    AC_DEFINE(HAVE_GMTIME_R)
 315    AC_DEFINE(HAVE_LOCALTIME_R)
 316    dnl This is only for POSIX threads.
 317    AC_DEFINE(HAVE_PTHREAD_MUTEXATTR_INIT)
 318    dnl We also assume we are using gcc, which provides alloca.
 319    AC_DEFINE(HAVE_ALLOCA)
 320
 321    ZLIBSPEC=-lzgcj
 322
 323    # If Canadian cross, then don't pick up tools from the build
 324    # directory.
 325    if test "$build" != "$with_cross_host"; then
 326       CANADIAN=yes
 327       EH_COMMON_INCLUDE=
 328       GCJ="${target_alias}-gcj"
 329    else
 330       GCJ=
 331    fi
 332    NATIVE=no
 333 else
 334    AC_CHECK_FUNCS(strerror ioctl select fstat open fsync sleep)
 335    AC_CHECK_FUNCS(gmtime_r localtime_r readdir_r getpwuid_r)
 336    AC_CHECK_FUNCS(access stat mkdir rename rmdir unlink realpath)
 337    AC_CHECK_FUNCS(inet_aton inet_addr, break)
 338    AC_CHECK_FUNCS(inet_pton uname inet_ntoa)
 339
 340    AC_CHECK_FUNCS(gethostbyname_r, [
 341      AC_DEFINE(HAVE_GETHOSTBYNAME_R)
 342      # There are two different kinds of gethostbyname_r.
 343      # We look for the one that returns `int'.
 344      # Hopefully this check is robust enough.
 345      AC_EGREP_HEADER(int.*gethostbyname_r, netdb.h, [
 346        AC_DEFINE(GETHOSTBYNAME_R_RETURNS_INT)])
 347
 348      case " $GCINCS " in
 349      *" -D_REENTRANT "*) ;;
 350      *)
 351         dnl On DU4.0, gethostbyname_r is only declared with -D_REENTRANT
 352         AC_CACHE_CHECK([whether gethostbyname_r declaration requires -D_REENTRANT],
 353         [libjava_cv_gethostbyname_r_needs_reentrant],
 354         [ AC_LANG_SAVE
 355           AC_LANG_CPLUSPLUS
 356           AC_TRY_COMPILE([#include <netdb.h>],
 357             [gethostbyname_r("", 0, 0);],
 358             [libjava_cv_gethostbyname_r_needs_reentrant=no], [dnl
 359                 CPPFLAGS_SAVE="$CPPFLAGS"
 360                 CPPFLAGS="$CPPFLAGS -D_REENTRANT"
 361                 AC_TRY_COMPILE([#include <netdb.h>], [gethostbyname_r("", 0, 0);],
 362                     [libjava_cv_gethostbyname_r_needs_reentrant=yes],
 363                     [libjava_cv_gethostbyname_r_needs_reentrant=fail])
 364                 CPPFLAGS="$CPPFLAGS_SAVE"
 365           ])
 366           AC_LANG_RESTORE
 367         ])
 368         if test "x$libjava_cv_gethostbyname_r_needs_reentrant" = xyes; then
 369           AC_DEFINE(GETHOSTBYNAME_R_NEEDS_REENTRANT, 1, [Define if gethostbyname_r is only declared if _REENTRANT is defined])
 370         fi
 371      ;;
 372      esac
 373
 374      AC_CACHE_CHECK([for struct hostent_data],
 375         [libjava_cv_struct_hostent_data], [dnl
 376         AC_TRY_COMPILE([
 377 #if GETHOSTBYNAME_R_NEEDS_REENTRANT && !defined(_REENTRANT)
 378 # define _REENTRANT 1
 379 #endif
 380 #include <netdb.h>], [struct hostent_data data;],
 381           [libjava_cv_struct_hostent_data=yes],
 382           [libjava_cv_struct_hostent_data=no])])
 383      if test "x$libjava_cv_struct_hostent_data" = xyes; then
 384        AC_DEFINE(HAVE_STRUCT_HOSTENT_DATA, 1,
 385          [Define if struct hostent_data is defined in netdb.h])
 386      fi
 387    ])
 388
 389    AC_CHECK_FUNCS(gethostbyaddr_r, [
 390      AC_DEFINE(HAVE_GETHOSTBYADDR_R)
 391      # There are two different kinds of gethostbyaddr_r.
 392      # We look for the one that returns `int'.
 393      # Hopefully this check is robust enough.
 394      AC_EGREP_HEADER(int.*gethostbyaddr_r, netdb.h, [
 395        AC_DEFINE(GETHOSTBYADDR_R_RETURNS_INT)])])
 396
 397    AC_CHECK_FUNCS(gethostname, [
 398      AC_DEFINE(HAVE_GETHOSTNAME)
 399      AC_EGREP_HEADER(gethostname, unistd.h, [
 400        AC_DEFINE(HAVE_GETHOSTNAME_DECL)])])
 401
 402    # Look for these functions in the thread library, but only bother
 403    # if using POSIX threads.
 404    if test "$THREADS" = posix; then
 405       save_LIBS="$LIBS"
 406       LIBS="$LIBS $THREADLIBS"
 407       # Some POSIX thread systems don't have pthread_mutexattr_settype.
 408       # E.g., Solaris.
 409       AC_CHECK_FUNCS(pthread_mutexattr_settype pthread_mutexattr_setkind_np)
 410
 411       # Look for sched_yield.  Up to Solaris 2.6, it is in libposix4, since
 412       # Solaris 7 the name librt is preferred.
 413       AC_CHECK_FUNCS(sched_yield, , [
 414         AC_CHECK_LIB(rt, sched_yield, [
 415           AC_DEFINE(HAVE_SCHED_YIELD)
 416           THREADLIBS="$THREADLIBS -lrt"
 417           THREADSPEC="$THREADSPEC -lrt"], [
 418           AC_CHECK_LIB(posix4, sched_yield, [
 419             AC_DEFINE(HAVE_SCHED_YIELD)
 420             THREADLIBS="$THREADLIBS -lposix4"
 421             THREADSPEC="$THREADSPEC -lposix4"])])])
 422       LIBS="$save_LIBS"
 423
 424       # We can save a little space at runtime if the mutex has m_count
 425       # or __m_count.  This is a nice hack for Linux.
 426       AC_TRY_COMPILE([#include <pthread.h>], [
 427           extern pthread_mutex_t *mutex; int q = mutex->m_count;
 428         ], AC_DEFINE(PTHREAD_MUTEX_HAVE_M_COUNT), [
 429         AC_TRY_COMPILE([#include <pthread.h>], [
 430             extern pthread_mutex_t *mutex; int q = mutex->__m_count;
 431           ], AC_DEFINE(PTHREAD_MUTEX_HAVE___M_COUNT))])
 432    fi
 433
 434    # We require a way to get the time.
 435    time_found=no
 436    AC_CHECK_FUNCS(gettimeofday time ftime, time_found=yes)
 437    if test "$time_found" = no; then
 438       AC_MSG_ERROR([no function found to get the time])
 439    fi
 440
 441    AC_CHECK_FUNCS(memmove)
 442
 443    # We require memcpy.
 444    memcpy_found=no
 445    AC_CHECK_FUNCS(memcpy, memcpy_found=yes)
 446    if test "$memcpy_found" = no; then
 447       AC_MSG_ERROR([memcpy is required])
 448    fi
 449
 450    # Some library-finding code we stole from Tcl.
 451    #--------------------------------------------------------------------
 452    #    Check for the existence of the -lsocket and -lnsl libraries.
 453    #    The order here is important, so that they end up in the right
 454    #    order in the command line generated by make.  Here are some
 455    #    special considerations:
 456    #    1. Use "connect" and "accept" to check for -lsocket, and
 457    #       "gethostbyname" to check for -lnsl.
 458    #    2. Use each function name only once:  can't redo a check because
 459    #       autoconf caches the results of the last check and won't redo it.
 460    #    3. Use -lnsl and -lsocket only if they supply procedures that
 461    #       aren't already present in the normal libraries.  This is because
 462    #       IRIX 5.2 has libraries, but they aren't needed and they're
 463    #       bogus:  they goof up name resolution if used.
 464    #    4. On some SVR4 systems, can't use -lsocket without -lnsl too.
 465    #       To get around this problem, check for both libraries together
 466    #       if -lsocket doesn't work by itself.
 467    #--------------------------------------------------------------------
 468
 469    AC_CACHE_CHECK([for socket libraries], gcj_cv_lib_sockets,
 470     [gcj_cv_lib_sockets=
 471      gcj_checkBoth=0
 472      unset ac_cv_func_connect
 473      AC_CHECK_FUNC(connect, gcj_checkSocket=0, gcj_checkSocket=1)
 474      if test "$gcj_checkSocket" = 1; then
 475          unset ac_cv_func_connect
 476          AC_CHECK_LIB(socket, main, gcj_cv_lib_sockets="-lsocket",
 477                       gcj_checkBoth=1)
 478      fi
 479      if test "$gcj_checkBoth" = 1; then
 480          gcj_oldLibs=$LIBS
 481          LIBS="$LIBS -lsocket -lnsl"
 482          unset ac_cv_func_accept
 483          AC_CHECK_FUNC(accept,
 484                        [gcj_checkNsl=0
 485                         gcj_cv_lib_sockets="-lsocket -lnsl"])
 486          unset ac_cv_func_accept
 487          LIBS=$gcj_oldLibs
 488      fi
 489      unset ac_cv_func_gethostbyname
 490      gcj_oldLibs=$LIBS
 491      LIBS="$LIBS $gcj_cv_lib_sockets"
 492      AC_CHECK_FUNC(gethostbyname, ,
 493                    [AC_CHECK_LIB(nsl, main,
 494                                  [gcj_cv_lib_sockets="$gcj_cv_lib_sockets -lnsl"])])
 495      unset ac_cv_func_gethostbyname
 496      LIBS=$gcj_oldLIBS
 497    ])
 498    SYSTEMSPEC="$SYSTEMSPEC $gcj_cv_lib_sockets"
 499
 500    if test "$with_system_zlib" = yes; then
 501       AC_CHECK_LIB(z, deflate, ZLIBSPEC=-lz, ZLIBSPEC=-lzgcj)
 502    else
 503       ZLIBSPEC=-lzgcj
 504    fi
 505
 506    # On Solaris, and maybe other architectures, the Boehm collector
 507    # requires -ldl.
 508    if test "$GC" = boehm; then
 509       AC_CHECK_LIB(dl, main, SYSTEMSPEC="$SYSTEMSPEC -ldl")
 510    fi
 511
 512    if test -d "$libgcj_basedir/../gcc/java"; then
 513       GCJ=
 514    else
 515       CANADIAN=yes
 516       NULL_TARGET=yes
 517       GCJ=gcj
 518    fi
 519 fi
 520
 521 ZLIBS=
 522 ZDEPS=
 523 ZINCS=
 524 if test "x$ZLIBSPEC" = "x-lzgcj"; then
 525    # We include the path to the zlib build directory.
 526    # See Makefile.am to understand why.
 527    ZDEPS='$(top_builddir)/../zlib/libzgcj.la'
 528    ZLIBS="$ZDEPS -L\$(here)/../zlib/$libsubdir"
 529    ZINCS='-I$(top_srcdir)/../zlib'
 530 else
 531    ZLIBS="$ZLIBSPEC"
 532 fi
 533 AC_SUBST(ZLIBS)
 534 AC_SUBST(ZDEPS)
 535 AC_SUBST(ZINCS)
 536 AC_SUBST(DIVIDESPEC)
 537 AC_SUBST(EXCEPTIONSPEC)
 538
 539 AM_CONDITIONAL(CANADIAN, test "$CANADIAN" = yes)
 540 AM_CONDITIONAL(NULL_TARGET, test "$NULL_TARGET" = yes)
 541 AM_CONDITIONAL(NATIVE, test "$NATIVE" = yes || test "$NULL_TARGET" = yes)
 542 AM_CONDITIONAL(USE_LIBDIR, test -z "$with_cross_host")
 543 AC_SUBST(EH_COMMON_INCLUDE)
 544
 545 # Determine gcj version number.
 546 if test "$GCJ" = ""; then
 547    if test -z "${with_multisubdir}"; then
 548       builddotdot=.
 549    else
 550 changequote(<<,>>)
 551       builddotdot=`echo ${with_multisubdir} | sed -e 's:[^/][^/]*:..:g'`
 552 changequote([,])
 553    fi
 554    dir="`cd ${builddotdot}/../../gcc && pwd`"
 555    GCJ="$dir/gcj -B$dir/"
 556 fi
 557 changequote(<<,>>)
 558 gcjvers="`$GCJ -v 2>&1 | sed -n 's/^.*version \([^ ]*\).*$/\1/p'`"
 559 changequote([,])
 560 AC_DEFINE_UNQUOTED(GCJVERSION, "$gcjvers")
 561
 562 # See if gcj supports -fuse-divide-subroutine.  gcc 2.95 does not, and
 563 # we want to continue to support that version.
 564 AC_MSG_CHECKING([whether gcj supports -fuse-divide-subroutine])
 565 cat > conftest.java << 'END'
 566 public class conftest { }
 567 END
 568 use_fuse=yes
 569 $GCJ -classpath $srcdir -fuse-divide-subroutine -fsyntax-only \
 570    conftest.java > /dev/null 2>&1 \
 571    || use_fuse=no
 572 rm -f conftest.java
 573 if test "$use_fuse" = no; then
 574    DIVIDESPEC=
 575 fi
 576 AC_MSG_RESULT($use_fuse)
 577
 578 AC_SUBST(AM_RUNTESTFLAGS)
 579
 580 dnl We check for sys/filio.h because Solaris 2.5 defines FIONREAD there.
 581 dnl On that system, sys/ioctl.h will not include sys/filio.h unless
 582 dnl BSD_COMP is defined; just including sys/filio.h is simpler.
 583 AC_CHECK_HEADERS(unistd.h bstring.h sys/time.h sys/types.h fcntl.h sys/ioctl.h sys/filio.h sys/stat.h sys/select.h sys/socket.h netinet/in.h arpa/inet.h netdb.h pwd.h sys/config.h inttypes.h stdint.h)
 584 dnl We avoid AC_HEADER_DIRENT since we really only care about dirent.h
 585 dnl for now.  If you change this, you also must update natFile.cc.
 586 AC_CHECK_HEADERS(dirent.h)
 587
 588 AC_CHECK_TYPE([ssize_t], [int])
 589
 590 AC_MSG_CHECKING([for in_addr_t])
 591 AC_TRY_COMPILE([#include <sys/types.h>
 592 #if STDC_HEADERS
 593 #include <stdlib.h>
 594 #include <stddef.h>
 595 #endif
 596 #if HAVE_NETINET_IN_H
 597 #include <netinet/in.h>
 598 #endif], [in_addr_t foo;],
 599   [AC_DEFINE([HAVE_IN_ADDR_T])
 600    AC_MSG_RESULT(yes)],
 601   [AC_MSG_RESULT(no)])
 602
 603 AC_MSG_CHECKING([whether struct ip_mreq is in netinet/in.h])
 604 AC_TRY_COMPILE([#include <netinet/in.h>], [struct ip_mreq mreq;],
 605   [AC_DEFINE(HAVE_STRUCT_IP_MREQ)
 606    AC_MSG_RESULT(yes)],
 607   [AC_MSG_RESULT(no)])
 608
 609 AC_MSG_CHECKING([whether struct sockaddr_in6 is in netinet/in.h])
 610 AC_TRY_COMPILE([#include <netinet/in.h>], [struct sockaddr_in6 addr6;],
 611   [AC_DEFINE(HAVE_INET6)
 612    AC_MSG_RESULT(yes)],
 613   [AC_MSG_RESULT(no)])
 614
 615 AC_MSG_CHECKING([for socklen_t in sys/socket.h])
 616 AC_TRY_COMPILE([#include <sys/socket.h>], [socklen_t x = 5;],
 617   [AC_DEFINE(HAVE_SOCKLEN_T)
 618    AC_MSG_RESULT(yes)],
 619   [AC_MSG_RESULT(no)])
 620
 621 AC_MSG_CHECKING([for tm_gmtoff in struct tm])
 622 AC_TRY_COMPILE([#include <time.h>], [struct tm tim; tim.tm_gmtoff = 0;],
 623   [AC_DEFINE(STRUCT_TM_HAS_GMTOFF)
 624    AC_MSG_RESULT(yes)],
 625   [AC_MSG_RESULT(no)
 626    AC_MSG_CHECKING([for global timezone variable])
 627    dnl FIXME: we don't want a link check here because that won't work
 628    dnl when cross-compiling.  So instead we make an assumption that
 629    dnl the header file will mention timezone if it exists.
 630    AC_TRY_COMPILE([#include <time.h>], [long z2 = timezone;],
 631      [AC_DEFINE(HAVE_TIMEZONE)
 632       AC_MSG_RESULT(yes)],
 633      [AC_MSG_RESULT(no)])])
 634
 635 AC_FUNC_ALLOCA
 636
 637 AC_CHECK_PROGS(PERL, perl, false)
 638
 639 if test "$enable_sjlj_exceptions" = yes; then
 640    SIGNAL_HANDLER=include/default-signal.h
 641 else
 642    case "${host}" in
 643     i?86-*-linux*)
 644        SIGNAL_HANDLER=include/i386-signal.h
 645        ;;
 646     sparc-sun-solaris*)
 647        SIGNAL_HANDLER=include/sparc-signal.h
 648        ;;
 649     *)
 650        SIGNAL_HANDLER=include/default-signal.h
 651        ;;
 652    esac
 653 fi
 654
 655 AC_LINK_FILES($SIGNAL_HANDLER, include/java-signal.h)
 656
 657 if test "${multilib}" = "yes"; then
 658   multilib_arg="--enable-multilib"
 659 else
 660   multilib_arg=
 661 fi
 662
 663 here=`pwd`
 664 AC_SUBST(here)
 665
 666 AC_OUTPUT(Makefile libgcj.spec gcj/Makefile include/Makefile testsuite/Makefile,
 667 [if test -n "$CONFIG_FILES"; then
 668   ac_file=Makefile . ${libgcj_basedir}/../config-ml.in
 669 fi],
 670 srcdir=${srcdir}
 671 host=${host}
 672 target=${target}
 673 with_multisubdir=${with_multisubdir}
 674 ac_configure_args="${multilib_arg} ${ac_configure_args}"
 675 CONFIG_SHELL=${CONFIG_SHELL-/bin/sh}
 676 libgcj_basedir=${libgcj_basedir}
 677 CC="${CC}"
 678 CXX="${CXX}"
 679 )