gcc/ada/5zosprim.adb

   1 ------------------------------------------------------------------------------
   2 --                                                                          --
   3 --                GNU ADA RUN-TIME LIBRARY (GNARL) COMPONENTS               --
   4 --                                                                          --
   5 --                  S Y S T E M . O S _ P R I M I T I V E S                 --
   6 --                                                                          --
   7 --                                  B o d y                                 --
   8 --                                                                          --
   9 --          Copyright (C) 1998-2001 Free Software Foundation, Inc.          --
  10 --                                                                          --
  11 -- GNARL is free software; you can  redistribute it  and/or modify it under --
  12 -- terms of the  GNU General Public License as published  by the Free Soft- --
  13 -- ware  Foundation;  either version 2,  or (at your option) any later ver- --
  14 -- sion. GNARL is distributed in the hope that it will be useful, but WITH- --
  15 -- OUT ANY WARRANTY;  without even the  implied warranty of MERCHANTABILITY --
  16 -- or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License --
  17 -- for  more details.  You should have  received  a copy of the GNU General --
  18 -- Public License  distributed with GNARL; see file COPYING.  If not, write --
  19 -- to  the Free Software Foundation,  59 Temple Place - Suite 330,  Boston, --
  20 -- MA 02111-1307, USA.                                                      --
  21 --                                                                          --
  22 -- As a special exception,  if other files  instantiate  generics from this --
  23 -- unit, or you link  this unit with other files  to produce an executable, --
  24 -- this  unit  does not  by itself cause  the resulting  executable  to  be --
  25 -- covered  by the  GNU  General  Public  License.  This exception does not --
  26 -- however invalidate  any other reasons why  the executable file  might be --
  27 -- covered by the  GNU Public License.                                      --
  28 --                                                                          --
  29 -- GNARL was developed by the GNARL team at Florida State University.       --
  30 -- Extensive contributions were provided by Ada Core Technologies Inc.      --
  31 --                                                                          --
  32 ------------------------------------------------------------------------------
  33
  34 --  This version is for VxWorks targets
  35
  36 with System.OS_Interface;
  37 --  Since the thread library is part of the VxWorks kernel, using OS_Interface
  38 --  is not a problem here, as long as we only use System.OS_Interface as a
  39 --  set of C imported routines: using Ada routines from this package would
  40 --  create a dependency on libgnarl in libgnat, which is not desirable.
  41
  42 with Interfaces.C;
  43 --  used for type int
  44
  45 package body System.OS_Primitives is
  46
  47    use System.OS_Interface;
  48
  49    --------------------------
  50    --  Internal functions  --
  51    --------------------------
  52
  53    function To_Clock_Ticks (D : Duration) return int;
  54    --  Convert a duration value (in seconds) into clock ticks.
  55    --  Note that this routine is duplicated from System.OS_Interface since
  56    --  as explained above, we do not want to depend on libgnarl
  57
  58    function To_Clock_Ticks (D : Duration) return int is
  59       Ticks          : Long_Long_Integer;
  60       Rate_Duration  : Duration;
  61       Ticks_Duration : Duration;
  62    begin
  63       --  Ensure that the duration can be converted to ticks
  64       --  at the current clock tick rate without overflowing.
  65
  66       Rate_Duration := Duration (sysClkRateGet);
  67
  68       if D > (Duration'Last / Rate_Duration) then
  69          Ticks := Long_Long_Integer (int'Last);
  70       else
  71          --  We always want to round up to the nearest clock tick.
  72
  73          Ticks_Duration := D * Rate_Duration;
  74          Ticks := Long_Long_Integer (Ticks_Duration);
  75
  76          if Ticks_Duration > Duration (Ticks) then
  77             Ticks := Ticks + 1;
  78          end if;
  79
  80          if Ticks > Long_Long_Integer (int'Last) then
  81             Ticks := Long_Long_Integer (int'Last);
  82          end if;
  83       end if;
  84
  85       return int (Ticks);
  86    end To_Clock_Ticks;
  87
  88    -----------
  89    -- Clock --
  90    -----------
  91
  92    function Clock return Duration is
  93       TS     : aliased timespec;
  94       Result : int;
  95
  96       use type Interfaces.C.int;
  97    begin
  98       Result := clock_gettime (CLOCK_REALTIME, TS'Unchecked_Access);
  99       pragma Assert (Result = 0);
 100       return Duration (TS.ts_sec) + Duration (TS.ts_nsec) / 10#1#E9;
 101    end Clock;
 102
 103    ---------------------
 104    -- Monotonic_Clock --
 105    ---------------------
 106
 107    function Monotonic_Clock return Duration renames Clock;
 108
 109    -----------------
 110    -- Timed_Delay --
 111    -----------------
 112
 113    procedure Timed_Delay
 114      (Time : Duration;
 115       Mode : Integer)
 116    is
 117       Result     : int;
 118       Rel_Time   : Duration;
 119       Abs_Time   : Duration;
 120       Check_Time : Duration := Clock;
 121
 122    begin
 123       if Mode = Relative then
 124          Rel_Time := Time;
 125          Abs_Time := Time + Check_Time;
 126       else
 127          Rel_Time := Time - Check_Time;
 128          Abs_Time := Time;
 129       end if;
 130
 131       if Rel_Time > 0.0 then
 132          loop
 133             Result := taskDelay (To_Clock_Ticks (Rel_Time));
 134             Check_Time := Clock;
 135
 136             exit when Abs_Time <= Check_Time;
 137
 138             Rel_Time := Abs_Time - Check_Time;
 139          end loop;
 140       end if;
 141    end Timed_Delay;
 142
 143 end System.OS_Primitives;