libstdc++-v3/configure.ac

   1 # Process this file with autoreconf to produce a configure script.
   2
   3 AC_PREREQ(2.59)
   4 AC_INIT(package-unused, version-unused,, libstdc++)
   5 AC_CONFIG_SRCDIR(src/ios.cc)
   6 AC_CONFIG_HEADER(config.h)
   7
   8 # This works around the fact that libtool configuration may change LD
   9 # for this particular configuration, but some shells, instead of
  10 # keeping the changes in LD private, export them just because LD is
  11 # exported.  Only used at the end of this file.
  12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
  13
  14 # For libtool versioning info, format is CURRENT:REVISION:AGE
  15 libtool_VERSION=6:10:0
  16 AC_SUBST(libtool_VERSION)
  17
  18 # Find the rest of the source tree framework.
  19 AM_ENABLE_MULTILIB(, ..)
  20
  21 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
  22 #
  23 # You will slowly go insane if you do not grok the following fact:  when
  24 # building v3 as part of the compiler, the top-level /target/ becomes the
  25 # library's /host/.  configure then causes --target to default to --host,
  26 # exactly like any other package using autoconf.  Therefore, 'target' and
  27 # 'host' will always be the same.  This makes sense both for native and
  28 # cross compilers, just think about it for a little while.  :-)
  29 #
  30 # Also, if v3 is being configured as part of a cross compiler, the top-level
  31 # configure script will pass the "real" host as $with_cross_host.
  32 #
  33 # Do not delete or change the following two lines.  For why, see
  34 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
  35 AC_CANONICAL_SYSTEM
  36 target_alias=${target_alias-$host_alias}
  37
  38 # Handy for debugging:
  39 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
  40
  41 if test "$build" != "$host"; then
  42   # We are being configured with some form of cross compiler.
  43   GLIBCXX_IS_NATIVE=false
  44   case "$host","$target" in
  45     # Darwin crosses can use the host system's libraries and headers,
  46     # because of the fat library support.  Of course, it must be the
  47     # same version of Darwin on both sides.  Allow the user to
  48     # just say --target=foo-darwin without a version number to mean
  49     # "the version on this system".
  50       *-*-darwin*,*-*-darwin*)
  51         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
  52         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
  53         if test $hostos = $targetos -o $targetos = darwin ; then
  54           GLIBCXX_IS_NATIVE=true
  55         fi
  56         ;;
  57
  58       *)
  59         GCC_NO_EXECUTABLES
  60         ;;
  61   esac
  62 else
  63   GLIBCXX_IS_NATIVE=true
  64 fi
  65
  66 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
  67 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
  68 #  1.x:  minimum required version
  69 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
  70 #              of other PACKAGE_* variables will, however, and there's nothing
  71 #              we can do about that; they come from AC_INIT).
  72 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
  73 #            file in the top srcdir, etc, etc), so stop complaining.
  74 #  no-dependencies:  turns off auto dependency generation (just for now)
  75 #  -Wall:  turns on all automake warnings...
  76 #  -Wno-portability:  ...except this one, since GNU make is now required.
  77 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies -Wall -Wno-portability -Wno-override])
  78 AH_TEMPLATE(PACKAGE, [Name of package])
  79 AH_TEMPLATE(VERSION, [Version number of package])
  80
  81 # Runs configure.host, finds CC, CXX, and assorted other critical bits.  Sets
  82 # up critical shell variables.
  83 GLIBCXX_CONFIGURE
  84
  85 AC_LIBTOOL_DLOPEN
  86 AM_PROG_LIBTOOL
  87 AC_SUBST(enable_shared)
  88 AC_SUBST(enable_static)
  89
  90 # Possibly disable most of the library.
  91 ## TODO: Consider skipping unncessary tests altogether in this case, rather
  92 ## than just ignoring the results.  Faster /and/ more correct, win win.
  93 GLIBCXX_ENABLE_HOSTED
  94
  95 # Enable compiler support that doesn't require linking.
  96 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
  97 GLIBCXX_ENABLE_PCH($is_hosted)
  98
  99 # Enable all the variable C++ runtime options that doesn't require linking.
 100 GLIBCXX_ENABLE_CSTDIO
 101 GLIBCXX_ENABLE_CLOCALE
 102 GLIBCXX_ENABLE_ALLOCATOR
 103 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
 104 GLIBCXX_ENABLE_LONG_LONG([yes])
 105 GLIBCXX_ENABLE_WCHAR_T([yes])
 106 GLIBCXX_ENABLE_C99([yes])
 107 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
 108 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
 109 GLIBCXX_ENABLE_DEBUG([no])
 110 GLIBCXX_ENABLE_PARALLEL
 111 GLIBCXX_ENABLE_CXX_FLAGS
 112 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
 113
 114 # Checks for operating systems support that don't require linking.
 115 GLIBCXX_CHECK_SYSTEM_ERROR
 116
 117 # No surprises, no surprises...
 118 GLIBCXX_ENABLE_THREADS
 119 GLIBCXX_ENABLE_ATOMIC_BUILTINS
 120 if test $atomicity_dir = cpu/generic/atomicity_mutex ; then
 121   AC_MSG_WARN([No native atomic operations are provided for this platform.])
 122   if test $target_thread_file = single; then
 123     AC_MSG_WARN([They cannot be faked when thread support is disabled.])
 124     AC_MSG_WARN([Thread-safety of certain classes is not guaranteed.])
 125   else
 126     AC_MSG_WARN([They will be faked using a mutex.])
 127     AC_MSG_WARN([Performance of certain classes will degrade as a result.])
 128   fi
 129 fi
 130
 131 GLIBCXX_CHECK_COMPILER_FEATURES
 132
 133 if $GLIBCXX_IS_NATIVE; then
 134
 135   # We can do more elaborate tests that assume a working linker.
 136   CANADIAN=no
 137
 138   # Check for available headers.
 139   AC_CHECK_HEADERS([nan.h ieeefp.h endian.h sys/isa_defs.h machine/endian.h \
 140   machine/param.h sys/machine.h fp.h locale.h float.h inttypes.h gconv.h \
 141   sys/types.h sys/ipc.h sys/sem.h])
 142
 143   GLIBCXX_CHECK_LINKER_FEATURES
 144   GLIBCXX_CHECK_MATH_SUPPORT
 145   GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 146   GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT
 147   GLIBCXX_CHECK_STDLIB_SUPPORT
 148
 149   # For showmanyc_helper().
 150   AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
 151   GLIBCXX_CHECK_POLL
 152   GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
 153
 154   # For xsputn_2().
 155   AC_CHECK_HEADERS(sys/uio.h)
 156   GLIBCXX_CHECK_WRITEV
 157
 158   # For the __streamoff_base_type typedef.
 159   GLIBCXX_CHECK_INT64_T
 160
 161   # For LFS support.
 162   GLIBCXX_CHECK_LFS
 163
 164   # For C99 support to TR1.
 165   GLIBCXX_CHECK_C99_TR1
 166
 167   # For dev/random and dev/urandom for TR1.
 168   GLIBCXX_CHECK_RANDOM_TR1
 169
 170   # For TLS support.
 171   GCC_CHECK_TLS
 172
 173   # For _Unwind_GetIPInfo.
 174   GCC_CHECK_UNWIND_GETIPINFO
 175
 176   AC_LC_MESSAGES
 177
 178   AC_TRY_COMPILE(
 179     [#include <setjmp.h>],
 180     [sigjmp_buf env;
 181      while (! sigsetjmp (env, 1))
 182        siglongjmp (env, 1);
 183     ],
 184     [AC_DEFINE(HAVE_SIGSETJMP, 1, [Define if sigsetjmp is available.])])
 185
 186   AC_FUNC_MMAP
 187
 188   # For iconv support.
 189   AM_ICONV
 190
 191 else
 192
 193   # This lets us hard-code the functionality we know we'll have in the cross
 194   # target environment.  "Let" is a sugar-coated word placed on an especially
 195   # dull and tedious hack, actually.
 196   #
 197   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
 198   # that involve linking, can't be used:
 199   #    "cannot open sim-crt0.o"
 200   #    "cannot open crt0.o"
 201   # etc.  All this is because there currently exists no unified, consistent
 202   # way for top level CC information to be passed down to target directories:
 203   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
 204   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
 205   # crosses can be removed.
 206
 207   # If Canadian cross, then don't pick up tools from the build directory.
 208   # Used only in GLIBCXX_EXPORT_INCLUDES.
 209   if test -n "$with_cross_host" &&
 210      test x"$build_alias" != x"$with_cross_host" &&
 211      test x"$build" != x"$target";
 212   then
 213     CANADIAN=yes
 214   else
 215     CANADIAN=no
 216   fi
 217
 218   # Construct crosses by hand, eliminating bits that need ld...
 219   # GLIBCXX_CHECK_BUILTIN_MATH_SUPPORT
 220   # GLIBCXX_CHECK_MATH_SUPPORT
 221
 222   # First, test for "known" system libraries.  We may be using newlib even
 223   # on a hosted environment.
 224   if test "x${with_newlib}" = "xyes"; then
 225     os_include_dir="os/newlib"
 226     AC_DEFINE(HAVE_HYPOT)
 227
 228     # GLIBCXX_CHECK_STDLIB_SUPPORT
 229     AC_DEFINE(HAVE_STRTOF)
 230     # AC_FUNC_MMAP
 231     AC_DEFINE(HAVE_MMAP)
 232
 233     AC_DEFINE(HAVE_ACOSF)
 234     AC_DEFINE(HAVE_ASINF)
 235     AC_DEFINE(HAVE_ATAN2F)
 236     AC_DEFINE(HAVE_ATANF)
 237     AC_DEFINE(HAVE_CEILF)
 238     AC_DEFINE(HAVE_COPYSIGN)
 239     AC_DEFINE(HAVE_COPYSIGNF)
 240     AC_DEFINE(HAVE_COSF)
 241     AC_DEFINE(HAVE_COSHF)
 242     AC_DEFINE(HAVE_EXPF)
 243     AC_DEFINE(HAVE_FABSF)
 244     AC_DEFINE(HAVE_FLOORF)
 245     AC_DEFINE(HAVE_FMODF)
 246     AC_DEFINE(HAVE_FREXPF)
 247     AC_DEFINE(HAVE_LDEXPF)
 248     AC_DEFINE(HAVE_LOG10F)
 249     AC_DEFINE(HAVE_LOGF)
 250     AC_DEFINE(HAVE_MODFF)
 251     AC_DEFINE(HAVE_POWF)
 252     AC_DEFINE(HAVE_SINF)
 253     AC_DEFINE(HAVE_SINHF)
 254     AC_DEFINE(HAVE_SQRTF)
 255     AC_DEFINE(HAVE_TANF)
 256     AC_DEFINE(HAVE_TANHF)
 257
 258     AC_DEFINE(HAVE_S_ISREG)
 259     AC_DEFINE(HAVE_S_IFREG)
 260
 261     AC_DEFINE(HAVE_ICONV)
 262   else
 263     GLIBCXX_CROSSCONFIG
 264   fi
 265
 266   # At some point, we should differentiate between architectures
 267   # like x86, which have long double versions, and alpha/powerpc/etc.,
 268   # which don't. For the time being, punt.
 269   if test x"long_double_math_on_this_cpu" = x"yes"; then
 270     AC_DEFINE(HAVE_ACOSL)
 271     AC_DEFINE(HAVE_ASINL)
 272     AC_DEFINE(HAVE_ATAN2L)
 273     AC_DEFINE(HAVE_ATANL)
 274     AC_DEFINE(HAVE_CEILL)
 275     AC_DEFINE(HAVE_COPYSIGNL)
 276     AC_DEFINE(HAVE_COSL)
 277     AC_DEFINE(HAVE_COSHL)
 278     AC_DEFINE(HAVE_EXPL)
 279     AC_DEFINE(HAVE_FABSL)
 280     AC_DEFINE(HAVE_FLOORL)
 281     AC_DEFINE(HAVE_FMODL)
 282     AC_DEFINE(HAVE_FREXPL)
 283     AC_DEFINE(HAVE_LDEXPL)
 284     AC_DEFINE(HAVE_LOG10L)
 285     AC_DEFINE(HAVE_LOGL)
 286     AC_DEFINE(HAVE_MODFL)
 287     AC_DEFINE(HAVE_POWL)
 288     AC_DEFINE(HAVE_SINCOSL)
 289     AC_DEFINE(HAVE_SINL)
 290     AC_DEFINE(HAVE_SINHL)
 291     AC_DEFINE(HAVE_SQRTL)
 292     AC_DEFINE(HAVE_TANL)
 293     AC_DEFINE(HAVE_TANHL)
 294   fi
 295
 296   # Assume we have _Unwind_GetIPInfo for cross-compiles.
 297   AC_DEFINE(HAVE_GETIPINFO)
 298
 299 fi
 300
 301 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
 302 GLIBCXX_ENABLE_SYMVERS([yes])
 303 GLIBCXX_ENABLE_VISIBILITY([yes])
 304
 305 ac_ldbl_compat=no
 306 case "$target" in
 307   powerpc*-*-linux* | \
 308   powerpc*-*-gnu* | \
 309   sparc*-*-linux* | \
 310   s390*-*-linux* | \
 311   alpha*-*-linux*)
 312   AC_TRY_COMPILE(, [
 313 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
 314 #error no need for long double compatibility
 315 #endif
 316   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
 317   if test "$ac_ldbl_compat" = yes; then
 318     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
 319               [Define if compatibility should be provided for -mlong-double-64.])
 320     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
 321   fi
 322 esac
 323 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
 324
 325 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
 326 GLIBCXX_CONFIGURE_TESTSUITE
 327
 328 # Propagate the target-specific source directories through the build chain.
 329 ATOMICITY_SRCDIR=config/${atomicity_dir}
 330 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
 331 ATOMIC_FLAGS=${atomic_flags}
 332 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
 333 OS_INC_SRCDIR=config/${os_include_dir}
 334 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
 335 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
 336 AC_SUBST(ATOMICITY_SRCDIR)
 337 AC_SUBST(ATOMIC_WORD_SRCDIR)
 338 AC_SUBST(ATOMIC_FLAGS)
 339 AC_SUBST(CPU_DEFINES_SRCDIR)
 340 AC_SUBST(ABI_TWEAKS_SRCDIR)
 341 AC_SUBST(OS_INC_SRCDIR)
 342 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
 343
 344
 345 # Determine cross-compile flags and AM_CONDITIONALs.
 346 #AC_SUBST(GLIBCXX_IS_NATIVE)
 347 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
 348 # from GLIBCXX_CHECK_COMPLEX_MATH_SUPPORT:
 349 #AM_CONDITIONAL(GLIBCXX_BUILD_LIBMATH,  test $need_libmath = yes)
 350 GLIBCXX_EVALUATE_CONDITIONALS
 351
 352 AC_CACHE_SAVE
 353
 354 if test ${multilib} = yes; then
 355   multilib_arg="--enable-multilib"
 356 else
 357   multilib_arg=
 358 fi
 359
 360 # Export all the install information.
 361 GLIBCXX_EXPORT_INSTALL_INFO
 362
 363 # Export all the include and flag information to Makefiles.
 364 GLIBCXX_EXPORT_INCLUDES
 365 GLIBCXX_EXPORT_FLAGS
 366
 367 if test "$enable_shared" = yes; then
 368   LIBSUPCXX_PICFLAGS="-prefer-pic"
 369 else
 370   LIBSUPCXX_PICFLAGS=
 371 fi
 372 AC_SUBST(LIBSUPCXX_PICFLAGS)
 373
 374 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
 375 dnl which can all be called multiple times as needed, plus one (different)
 376 dnl AC_OUTPUT macro.  This one lists the files to be created:
 377 AC_CONFIG_FILES( \
 378   Makefile \
 379   AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ])
 380   )
 381 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
 382
 383 dnl These commands are run at the end of config.status:
 384 AC_CONFIG_COMMANDS([default],
 385 [if test -n "$CONFIG_FILES"; then
 386    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
 387    # that multilib installs will end up installed in the correct place.
 388    # The testsuite needs it for multilib-aware ABI baseline files.
 389    # To work around this not being passed down from config-ml.in ->
 390    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
 391    # append it here.  Only modify Makefiles that have just been created.
 392    #
 393    # Also, get rid of this simulated-VPATH thing that automake does.
 394    cat > vpsed << \_EOF
 395 s!`test -f '$<' || echo '$(srcdir)/'`!!
 396 _EOF
 397    for i in $SUBDIRS; do
 398     case $CONFIG_FILES in
 399      *${i}/Makefile*)
 400        #echo "Adding MULTISUBDIR to $i/Makefile"
 401        sed -f vpsed $i/Makefile > tmp
 402        grep '^MULTISUBDIR =' Makefile >> tmp
 403        mv tmp $i/Makefile
 404        ;;
 405     esac
 406    done
 407    rm vpsed
 408  fi
 409  (cd include && ${MAKE-make})
 410 ],
 411 [
 412 # Variables needed in config.status (file generation) which aren't already
 413 # passed by autoconf.
 414 SUBDIRS="$SUBDIRS"
 415 ])
 416
 417 dnl And this actually makes things happen:
 418 AC_OUTPUT